cgit.sxemacs.org Git - gnus/blob - aclocal.m4

   1 # serial 1
   2
   3 AC_DEFUN(AM_PATH_LISPDIR,
   4  [# If set to t, that means we are running in a shell under Emacs.
   5   # If you have an Emacs named "t", then use the full path.
   6   test "$EMACS" = t && EMACS=
   7   test "$EMACS" || AC_PATH_PROGS(EMACS, emacs xemacs, no)
   8   if test "$EMACS" != "no"; then
   9     AC_MSG_CHECKING([where .elc files should go])
  10     dnl Set default value
  11     lispdir="\$(datadir)/emacs/site-lisp"
  12     if test "x$prefix" = "xNONE"; then
  13       if test -d $ac_default_prefix/share/emacs/site-lisp; then
  14         lispdir="\$(prefix)/share/emacs/site-lisp"
  15       else
  16         if test -d $ac_default_prefix/lib/emacs/site-lisp; then
  17           lispdir="\$(prefix)/lib/emacs/site-lisp"
  18         fi
  19       fi
  20     else
  21       if test -d $prefix/share/emacs/site-lisp; then
  22         lispdir="\$(prefix)/share/emacs/site-lisp"
  23       else
  24         if test -d $prefix/lib/emacs/site-lisp; then
  25           lispdir="\$(prefix)/lib/emacs/site-lisp"
  26         fi
  27       fi
  28     fi
  29     AC_MSG_RESULT($lispdir)
  30   fi
  31   AC_SUBST(lispdir)])
  32
  33 dnl AC_EMACS_LIST AC_XEMACS_P AC_PATH_LISPDIR and AC_EMACS_CHECK_LIB
  34 dnl are stolen from w3.
  35 dnl AC_PATH_LISPDIR obsoletes AM_PATH_LISPDIR.
  36
  37 AC_DEFUN(AC_EMACS_LISP, [
  38 elisp="$2"
  39 if test -z "$3"; then
  40         AC_MSG_CHECKING(for $1)
  41 fi
  42 AC_CACHE_VAL(EMACS_cv_SYS_$1,[
  43         OUTPUT=./conftest-$$
  44         echo ${EMACS} -batch -eval "(let ((x ${elisp})) (write-region (if (stringp x) (princ x) (prin1-to-string x)) nil \"${OUTPUT}\"))" >& AC_FD_CC 2>&1
  45         ${EMACS} -batch -eval "(let ((x ${elisp})) (write-region (if (stringp x) (princ x 'ignore) (prin1-to-string x)) nil \"${OUTPUT}\"nil 5))" >& AC_FD_CC 2>&1
  46         retval=`cat ${OUTPUT}`
  47         echo "=> ${retval}" >& AC_FD_CC 2>&1
  48         rm -f ${OUTPUT}
  49         EMACS_cv_SYS_$1=$retval
  50 ])
  51 $1=${EMACS_cv_SYS_$1}
  52 if test -z "$3"; then
  53         AC_MSG_RESULT($$1)
  54 fi
  55 ])
  56
  57 AC_DEFUN(AC_XEMACS_P, [
  58   AC_MSG_CHECKING([if $EMACS is really XEmacs])
  59   AC_EMACS_LISP(xemacsp,(if (string-match \"XEmacs\" emacs-version) \"yes\" \"no\") ,"noecho")
  60   XEMACS=${EMACS_cv_SYS_xemacsp}
  61   EMACS_FLAVOR=emacs
  62   if test "$XEMACS" = "yes"; then
  63      EMACS_FLAVOR=xemacs
  64   fi
  65   AC_MSG_RESULT($XEMACS)
  66   AC_SUBST(XEMACS)
  67   AC_SUBST(EMACS_FLAVOR)
  68 ])
  69
  70 AC_DEFUN(AC_PATH_LISPDIR, [
  71   AC_XEMACS_P
  72   if test "$prefix" = "NONE"; then
  73         AC_MSG_CHECKING([prefix for your Emacs])
  74         AC_EMACS_LISP(prefix,(expand-file-name \"..\" invocation-directory),"noecho")
  75         prefix=${EMACS_cv_SYS_prefix}
  76         AC_MSG_RESULT($prefix)
  77   fi
  78   AC_ARG_WITH(lispdir,[  --with-lispdir=DIR      Where to install lisp files], lispdir=${withval})
  79   AC_MSG_CHECKING([where .elc files should go])
  80   if test -z "$lispdir"; then
  81     dnl Set default value
  82     theprefix=$prefix
  83     if test "x$theprefix" = "xNONE"; then
  84         theprefix=$ac_default_prefix
  85     fi
  86     if test "$EMACS_FLAVOR" = "xemacs"; then
  87         lispdir="\$(datadir)/${EMACS_FLAVOR}/site-packages/lisp/gnus"
  88     else
  89     lispdir="\$(datadir)/${EMACS_FLAVOR}/site-lisp"
  90     fi
  91     for thedir in share lib; do
  92         potential=
  93         if test -d ${theprefix}/${thedir}/${EMACS_FLAVOR}/site-lisp; then
  94            if test "$EMACS_FLAVOR" = "xemacs"; then
  95                lispdir="\$(prefix)/${thedir}/${EMACS_FLAVOR}/site-packages/lisp/gnus"
  96            else
  97                lispdir="\$(datadir)/${EMACS_FLAVOR}/site-lisp"
  98            fi
  99            break
 100         fi
 101     done
 102   fi
 103   AC_MSG_RESULT($lispdir)
 104   AC_SUBST(lispdir)
 105 ])
 106
 107 AC_DEFUN(AC_PATH_ETCDIR, [
 108   AC_ARG_WITH(etcdir,[  --with-etcdir=DIR       Where to install etc files], etcdir=${withval})
 109   AC_MSG_CHECKING([where etc files should go])
 110   if test -z "$etcdir"; then
 111     dnl Set default value.
 112     if test "$EMACS_FLAVOR" = "xemacs"; then
 113       etcdir="\$(lispdir)/../../etc"
 114     else
 115     etcdir="\$(lispdir)/../etc"
 116     fi
 117   fi
 118   AC_MSG_RESULT($etcdir)
 119   AC_SUBST(etcdir)
 120 ])
 121
 122 dnl
 123 dnl This is a bit on the "evil hack" side of things.  It is so we can
 124 dnl have a different default infodir for XEmacs.  A user can still specify
 125 dnl someplace else with '--infodir=DIR'.
 126 dnl
 127 AC_DEFUN(AC_PATH_INFO_DIR, [
 128   AC_MSG_CHECKING([where the TeXinfo docs should go])
 129   dnl Set default value.  This must be an absolute path.
 130   if test "$infodir" = "\${prefix}/info"; then
 131     if test "$EMACS_FLAVOR" = "xemacs"; then
 132       info_dir="\$(prefix)/${thedir}/${EMACS_FLAVOR}/site-packages/info"
 133     else
 134       info_dir="\$(prefix)/info"
 135     fi
 136   else
 137     info_dir=$infodir
 138   fi
 139   AC_MSG_RESULT($info_dir)
 140   AC_SUBST(info_dir)
 141 ])
 142
 143 dnl
 144 dnl Check whether a function exists in a library
 145 dnl All '_' characters in the first argument are converted to '-'
 146 dnl
 147 AC_DEFUN(AC_EMACS_CHECK_LIB, [
 148 if test -z "$3"; then
 149         AC_MSG_CHECKING(for $2 in $1)
 150 fi
 151 library=`echo $1 | tr _ -`
 152 AC_EMACS_LISP($1,(progn (fmakunbound '$2) (condition-case nil (progn (require '$library) (fboundp '$2)) (error (prog1 nil (message \"$library not found\"))))),"noecho")
 153 if test "${EMACS_cv_SYS_$1}" = "nil"; then
 154         EMACS_cv_SYS_$1=no
 155 fi
 156 if test "${EMACS_cv_SYS_$1}" = "t"; then
 157         EMACS_cv_SYS_$1=yes
 158 fi
 159 HAVE_$1=${EMACS_cv_SYS_$1}
 160 AC_SUBST(HAVE_$1)
 161 if test -z "$3"; then
 162         AC_MSG_RESULT($HAVE_$1)
 163 fi
 164 ])
 165
 166 dnl
 167 dnl Perform sanity checking and try to locate the W3 package
 168 dnl
 169 AC_DEFUN(AC_CHECK_W3, [
 170 AC_MSG_CHECKING(for acceptable W3 version)
 171 AC_CACHE_VAL(EMACS_cv_ACCEPTABLE_W3,[
 172 AC_EMACS_CHECK_LIB(w3_forms, w3-form-encode-xwfu,"noecho")
 173 if test "${HAVE_w3_forms}" = "yes"; then
 174         EMACS_cv_ACCEPTABLE_W3=yes
 175 else
 176         EMACS_cv_ACCEPTABLE_W3=no
 177 fi
 178
 179 if test "${EMACS_cv_ACCEPTABLE_W3}" = "yes"; then
 180         AC_EMACS_LISP(w3_dir,(file-name-directory (locate-library \"w3-forms\")),"noecho")
 181         EMACS_cv_ACCEPTABLE_W3=$EMACS_cv_SYS_w3_dir
 182 fi
 183 ])
 184    AC_ARG_WITH(w3,[  --with-w3=DIR           Specify where to find the w3 package], [ EMACS_cv_ACCEPTABLE_W3=`( cd $withval && pwd || echo "$withval" ) 2> /dev/null` ])
 185    W3=${EMACS_cv_ACCEPTABLE_W3}
 186    AC_SUBST(W3)
 187    AC_MSG_RESULT("${W3}")
 188 ])
 189
 190 dnl
 191 dnl Perform sanity checking and try to locate the W3 package
 192 dnl
 193 AC_DEFUN(AC_CHECK_URL, [
 194 AC_MSG_CHECKING(for acceptable URL version)
 195 AC_CACHE_VAL(EMACS_cv_ACCEPTABLE_URL,[
 196 AC_EMACS_CHECK_LIB(url, url-retrieve, "noecho")
 197 if test "${HAVE_url}" = "yes"; then
 198         EMACS_cv_ACCEPTABLE_URL=yes
 199 else
 200         EMACS_cv_ACCEPTABLE_URL=no
 201 fi
 202
 203 if test "${EMACS_cv_ACCEPTABLE_URL}" = "yes"; then
 204         AC_EMACS_LISP(url_dir,(file-name-directory (locate-library \"url\")),"noecho")
 205         EMACS_cv_ACCEPTABLE_URL=$EMACS_cv_SYS_url_dir
 206 fi
 207 ])
 208    AC_ARG_WITH(url,[  --with-url=DIR          Specify where to find the url package], [ EMACS_cv_ACCEPTABLE_URL=`( cd $withval && pwd || echo "$withval" ) 2> /dev/null` ])
 209    URL=${EMACS_cv_ACCEPTABLE_URL}
 210    AC_SUBST(URL)
 211    AC_MSG_RESULT("${URL}")
 212 ])
 213
 214 dnl
 215 dnl Perform checking available fonts: Adobe Bembo, Adobe Futura and
 216 dnl Bitstream Courier.
 217 dnl
 218
 219 AC_DEFUN(GNUS_CHECK_FONTS, [
 220 test "$LATEX" = t && LATEX=
 221 test "$LATEX" || AC_PATH_PROGS(LATEX, latex, no)
 222 AC_MSG_CHECKING(for available fonts)
 223 AC_ARG_WITH(fonts,[  --with-fonts            Assume all fonts required are available],[USE_FONTS="$withval"])
 224 WITH_FONTS_bembo='%'
 225 WITHOUT_FONTS_bembo=
 226 WITH_FONTS_pfu='%'
 227 WITHOUT_FONTS_pfu=
 228 WITH_FONTS_bcr='%'
 229 WITHOUT_FONTS_bcr=
 230 if test -z "${USE_FONTS}"; then
 231   if test "${LATEX}" = no; then
 232         :
 233   else
 234     OUTPUT=./conftest-$$
 235     echo '\nonstopmode\documentclass{article}\usepackage{bembo}\begin{document}\end{document}' > ${OUTPUT}
 236     if ${LATEX} ${OUTPUT} </dev/null >& AC_FD_CC 2>&1  ; then
 237       if test -z "${USE_FONTS}"; then
 238         USE_FONTS="Adobe Bembo"
 239       else
 240         USE_FONTS="${USE_FONTS}, Adobe Bembo"
 241       fi
 242       WITH_FONTS_bembo=
 243       WITHOUT_FONTS_bembo='%'
 244     fi
 245     echo '\nonstopmode\documentclass{article}\begin{document}{\fontfamily{pfu}\fontsize{10pt}{10}\selectfont test}\end{document}' > ${OUTPUT}
 246     if retval=`${LATEX} ${OUTPUT} </dev/null 2>& AC_FD_CC`; then
 247       if echo "$retval" | grep 'Some font shapes were not available' >& AC_FD_CC 2>&1  ; then
 248         :
 249       else
 250         if test -z "${USE_FONTS}"; then
 251           USE_FONTS="Adobe Futura"
 252         else
 253           USE_FONTS="${USE_FONTS}, Adobe Futura"
 254         fi
 255         WITH_FONTS_pfu=
 256         WITHOUT_FONTS_pfu='%'
 257       fi
 258     fi
 259     echo '\nonstopmode\documentclass{article}\begin{document}{\fontfamily{bcr}\fontsize{10pt}{10}\selectfont test}\end{document}' > ${OUTPUT}
 260     if retval=`${LATEX} ${OUTPUT} </dev/null 2>& AC_FD_CC`; then
 261       if echo "$retval" | grep 'Some font shapes were not available' >& AC_FD_CC 2>&1  ; then
 262         :
 263       else
 264         if test -z "${USE_FONTS}"; then
 265           USE_FONTS="Bitstream Courier"
 266         else
 267           USE_FONTS="${USE_FONTS}, Bitstream Courier"
 268         fi
 269         WITH_FONTS_bcr=
 270         WITHOUT_FONTS_bcr='%'
 271       fi
 272     fi
 273     rm -f ${OUTPUT} ${OUTPUT}.aux ${OUTPUT}.log ${OUTPUT}.dvi
 274   fi
 275 elif test "${USE_FONTS}" = yes ; then
 276   WITH_FONTS_bembo=
 277   WITHOUT_FONTS_bembo='%'
 278   WITH_FONTS_pfu=
 279   WITHOUT_FONTS_pfu='%'
 280   WITH_FONTS_bcr=
 281   WITHOUT_FONTS_bcr='%'
 282 fi
 283 AC_SUBST(WITH_FONTS_bembo)
 284 AC_SUBST(WITHOUT_FONTS_bembo)
 285 AC_SUBST(WITH_FONTS_pfu)
 286 AC_SUBST(WITHOUT_FONTS_pfu)
 287 AC_SUBST(WITH_FONTS_bcr)
 288 AC_SUBST(WITHOUT_FONTS_bcr)
 289 if test -z "${USE_FONTS}" ; then
 290   USE_FONTS=no
 291 fi
 292 USE_FONTS=`echo "${USE_FONTS}" | sed 's/,\([[^,]]*\)$/ and\1/'`
 293 AC_MSG_RESULT("${USE_FONTS}")
 294 if test "${USE_FONTS}" = yes ; then
 295   USE_FONTS='Set in Adobe Bembo, Adobe Futura and Bitstream Courier.'
 296 elif test "${USE_FONTS}" = no ; then
 297   USE_FONTS=''
 298 else
 299   USE_FONTS="Set in ${USE_FONTS}."
 300 fi
 301 AC_SUBST(USE_FONTS)
 302 ])