cgit.sxemacs.org Git - gnus/blob - lisp/spam.el

   1 ;;; spam.el --- Identifying spam
   2 ;; Copyright (C) 2002, 2003 Free Software Foundation, Inc.
   3
   4 ;; Author: Lars Magne Ingebrigtsen <larsi@gnus.org>
   5 ;; Keywords: network
   6
   7 ;; This file is part of GNU Emacs.
   8
   9 ;; GNU Emacs is free software; you can redistribute it and/or modify
  10 ;; it under the terms of the GNU General Public License as published by
  11 ;; the Free Software Foundation; either version 2, or (at your option)
  12 ;; any later version.
  13
  14 ;; GNU Emacs is distributed in the hope that it will be useful,
  15 ;; but WITHOUT ANY WARRANTY; without even the implied warranty of
  16 ;; MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.  See the
  17 ;; GNU General Public License for more details.
  18
  19 ;; You should have received a copy of the GNU General Public License
  20 ;; along with GNU Emacs; see the file COPYING.  If not, write to the
  21 ;; Free Software Foundation, Inc., 59 Temple Place - Suite 330,
  22 ;; Boston, MA 02111-1307, USA.
  23
  24 ;;; Commentary:
  25
  26 ;;; This module addresses a few aspects of spam control under Gnus.  Page
  27 ;;; breaks are used for grouping declarations and documentation relating to
  28 ;;; each particular aspect.
  29
  30 ;;; The integration with Gnus is not yet complete.  See various `FIXME'
  31 ;;; comments, below, for supplementary explanations or discussions.
  32
  33 ;;; Several TODO items are marked as such
  34
  35 ;;; Code:
  36
  37 (require 'gnus-sum)
  38
  39 (require 'gnus-uu)                      ; because of key prefix issues
  40 (require 'gnus) ; for the definitions of group content classification and spam processors
  41 (require 'message)                      ;for the message-fetch-field functions
  42
  43 ;; autoload executable-find
  44 (eval-and-compile
  45   ;; executable-find is not autoloaded in Emacs 20
  46   (autoload 'executable-find "executable"))
  47
  48 ;; autoload query-dig
  49 (eval-and-compile
  50   (autoload 'query-dig "dig"))
  51
  52 ;; autoload query-dns
  53 (eval-and-compile
  54   (autoload 'query-dns "dns"))
  55
  56 ;;; Main parameters.
  57
  58 (defgroup spam nil
  59   "Spam configuration.")
  60
  61 (defcustom spam-directory "~/News/spam/"
  62   "Directory for spam whitelists and blacklists."
  63   :type 'directory
  64   :group 'spam)
  65
  66 (defcustom spam-move-spam-nonspam-groups-only t
  67   "Whether spam should be moved in non-spam groups only.
  68 When nil, only ham and unclassified groups will have their spam moved
  69 to the spam-process-destination.  When t, spam will also be moved from
  70 spam groups."
  71   :type 'boolean
  72   :group 'spam-ifile)
  73
  74 (defcustom spam-whitelist (expand-file-name "whitelist" spam-directory)
  75   "The location of the whitelist.
  76 The file format is one regular expression per line.
  77 The regular expression is matched against the address."
  78   :type 'file
  79   :group 'spam)
  80
  81 (defcustom spam-blacklist (expand-file-name "blacklist" spam-directory)
  82   "The location of the blacklist.
  83 The file format is one regular expression per line.
  84 The regular expression is matched against the address."
  85   :type 'file
  86   :group 'spam)
  87
  88 (defcustom spam-use-dig t
  89   "Whether query-dig should be used instead of query-dns."
  90   :type 'boolean
  91   :group 'spam)
  92
  93 (defcustom spam-use-blacklist nil
  94   "Whether the blacklist should be used by spam-split."
  95   :type 'boolean
  96   :group 'spam)
  97
  98 (defcustom spam-use-whitelist nil
  99   "Whether the whitelist should be used by spam-split."
 100   :type 'boolean
 101   :group 'spam)
 102
 103 (defcustom spam-use-whitelist-exclusive nil
 104   "Whether whitelist-exclusive should be used by spam-split.
 105 Exclusive whitelisting means that all messages from senders not in the whitelist
 106 are considered spam."
 107   :type 'boolean
 108   :group 'spam)
 109
 110 (defcustom spam-use-blackholes nil
 111   "Whether blackholes should be used by spam-split."
 112   :type 'boolean
 113   :group 'spam)
 114
 115 (defcustom spam-use-regex-headers nil
 116   "Whether a header regular expression match should be used by spam-split.
 117 Also see the variable `spam-spam-regex-headers' and `spam-ham-regex-headers'."
 118   :type 'boolean
 119   :group 'spam)
 120
 121 (defcustom spam-use-bogofilter-headers nil
 122   "Whether bogofilter headers should be used by spam-split.
 123 Enable this if you pre-process messages with Bogofilter BEFORE Gnus sees them."
 124   :type 'boolean
 125   :group 'spam)
 126
 127 (defcustom spam-use-bogofilter nil
 128   "Whether bogofilter should be invoked by spam-split.
 129 Enable this if you want Gnus to invoke Bogofilter on new messages."
 130   :type 'boolean
 131   :group 'spam)
 132
 133 (defcustom spam-use-BBDB nil
 134   "Whether BBDB should be used by spam-split."
 135   :type 'boolean
 136   :group 'spam)
 137
 138 (defcustom spam-use-BBDB-exclusive nil
 139   "Whether BBDB-exclusive should be used by spam-split.
 140 Exclusive BBDB means that all messages from senders not in the BBDB are
 141 considered spam."
 142   :type 'boolean
 143   :group 'spam)
 144
 145 (defcustom spam-use-ifile nil
 146   "Whether ifile should be used by spam-split."
 147   :type 'boolean
 148   :group 'spam)
 149
 150 (defcustom spam-use-stat nil
 151   "Whether spam-stat should be used by spam-split."
 152   :type 'boolean
 153   :group 'spam)
 154
 155 (defcustom spam-split-group "spam"
 156   "Group name where incoming spam should be put by spam-split."
 157   :type 'string
 158   :group 'spam)
 159
 160 (defcustom spam-junk-mailgroups (cons spam-split-group '("mail.junk" "poste.pourriel"))
 161   "Mailgroups with spam contents.
 162 All unmarked article in such group receive the spam mark on group entry."
 163   :type '(repeat (string :tag "Group"))
 164   :group 'spam)
 165
 166 (defcustom spam-blackhole-servers '("bl.spamcop.net" "relays.ordb.org"
 167                                     "dev.null.dk" "relays.visi.com")
 168   "List of blackhole servers."
 169   :type '(repeat (string :tag "Server"))
 170   :group 'spam)
 171
 172 (defcustom spam-blackhole-good-server-regex nil
 173   "String matching IP addresses that should not be checked in the blackholes"
 174   :type 'regexp
 175   :group 'spam)
 176
 177 (defcustom spam-ham-marks (list 'gnus-del-mark 'gnus-read-mark
 178                                 'gnus-killed-mark 'gnus-kill-file-mark
 179                                 'gnus-low-score-mark)
 180   "Marks considered as being ham (positively not spam).
 181 Such articles will be processed as ham (non-spam) on group exit."
 182   :type '(set
 183           (variable-item gnus-del-mark)
 184           (variable-item gnus-read-mark)
 185           (variable-item gnus-killed-mark)
 186           (variable-item gnus-kill-file-mark)
 187           (variable-item gnus-low-score-mark))
 188   :group 'spam)
 189
 190 (defcustom spam-spam-marks (list 'gnus-spam-mark)
 191   "Marks considered as being spam (positively spam).
 192 Such articles will be transmitted to `bogofilter -s' on group exit."
 193   :type '(set
 194           (variable-item gnus-spam-mark)
 195           (variable-item gnus-killed-mark)
 196           (variable-item gnus-kill-file-mark)
 197           (variable-item gnus-low-score-mark))
 198   :group 'spam)
 199
 200 (defcustom spam-face 'gnus-splash-face
 201   "Face for spam-marked articles"
 202   :type 'face
 203   :group 'spam)
 204
 205 (defcustom spam-regex-headers-spam '("^X-Spam-Flag: YES")
 206   "Regular expression for positive header spam matches"
 207   :type '(repeat (regexp :tag "Regular expression to match spam header"))
 208   :group 'spam)
 209
 210 (defcustom spam-regex-headers-ham '("^X-Spam-Flag: NO")
 211   "Regular expression for positive header ham matches"
 212   :type '(repeat (regexp :tag "Regular expression to match ham header"))
 213   :group 'spam)
 214
 215 (defgroup spam-ifile nil
 216   "Spam ifile configuration."
 217   :group 'spam)
 218
 219 (defcustom spam-ifile-path (executable-find "ifile")
 220   "File path of the ifile executable program."
 221   :type '(choice (file :tag "Location of ifile")
 222                  (const :tag "ifile is not installed"))
 223   :group 'spam-ifile)
 224
 225 (defcustom spam-ifile-database-path nil
 226   "File path of the ifile database."
 227   :type '(choice (file :tag "Location of the ifile database")
 228                  (const :tag "Use the default"))
 229   :group 'spam-ifile)
 230
 231 (defcustom spam-ifile-spam-category "spam"
 232   "Name of the spam ifile category."
 233   :type 'string
 234   :group 'spam-ifile)
 235
 236 (defcustom spam-ifile-ham-category nil
 237   "Name of the ham ifile category.  If nil, the current group name will
 238 be used."
 239   :type '(choice (string :tag "Use a fixed category")
 240                 (const :tag "Use the current group name"))
 241   :group 'spam-ifile)
 242
 243 (defcustom spam-ifile-all-categories nil
 244   "Whether the ifile check will return all categories, or just spam.
 245 Set this to t if you want to use the spam-split invocation of ifile as
 246 your main source of newsgroup names."
 247   :type 'boolean
 248   :group 'spam-ifile)
 249
 250 (defgroup spam-bogofilter nil
 251   "Spam bogofilter configuration."
 252   :group 'spam)
 253
 254 (defcustom spam-bogofilter-path (executable-find "bogofilter")
 255   "File path of the Bogofilter executable program."
 256   :type '(choice (file :tag "Location of bogofilter")
 257                  (const :tag "Bogofilter is not installed"))
 258   :group 'spam-bogofilter)
 259
 260 (defcustom spam-bogofilter-header "X-Bogosity"
 261   "The header that Bogofilter inserts in messages."
 262   :type 'string
 263   :group 'spam-bogofilter)
 264
 265 (defcustom spam-bogofilter-bogosity-positive-spam-header "^\\(Yes\\|Spam\\)"
 266   "The regex on `spam-bogofilter-header' for positive spam identification."
 267   :type 'regexp
 268   :group 'spam-bogofilter)
 269
 270 (defcustom spam-bogofilter-database-directory nil
 271   "Directory path of the Bogofilter databases."
 272   :type '(choice (directory :tag "Location of the Bogofilter database directory")
 273                  (const :tag "Use the default"))
 274   :group 'spam-ifile)
 275
 276 ;;; Key bindings for spam control.
 277
 278 (gnus-define-keys gnus-summary-mode-map
 279   "St" spam-bogofilter-score
 280   "Sx" gnus-summary-mark-as-spam
 281   "Mst" spam-bogofilter-score
 282   "Msx" gnus-summary-mark-as-spam
 283   "\M-d" gnus-summary-mark-as-spam)
 284
 285 ;;; How to highlight a spam summary line.
 286
 287 ;; TODO: How do we redo this every time spam-face is customized?
 288
 289 (push '((eq mark gnus-spam-mark) . spam-face)
 290       gnus-summary-highlight)
 291
 292 ;; convenience functions
 293 (defun spam-group-spam-contents-p (group)
 294   (if (stringp group)
 295       (or (member group spam-junk-mailgroups)
 296           (memq 'gnus-group-spam-classification-spam
 297                 (gnus-parameter-spam-contents group)))
 298     nil))
 299
 300 (defun spam-group-ham-contents-p (group)
 301   (if (stringp group)
 302       (memq 'gnus-group-spam-classification-ham
 303             (gnus-parameter-spam-contents group))
 304     nil))
 305
 306 (defun spam-group-processor-p (group processor)
 307   (if (and (stringp group)
 308            (symbolp processor))
 309       (member processor (car (gnus-parameter-spam-process group)))
 310     nil))
 311
 312 (defun spam-group-spam-processor-bogofilter-p (group)
 313   (spam-group-processor-p group 'gnus-group-spam-exit-processor-bogofilter))
 314
 315 (defun spam-group-spam-processor-blacklist-p (group)
 316   (spam-group-processor-p group 'gnus-group-spam-exit-processor-blacklist))
 317
 318 (defun spam-group-spam-processor-ifile-p (group)
 319   (spam-group-processor-p group 'gnus-group-spam-exit-processor-ifile))
 320
 321 (defun spam-group-ham-processor-ifile-p (group)
 322   (spam-group-processor-p group 'gnus-group-ham-exit-processor-ifile))
 323
 324 (defun spam-group-ham-processor-bogofilter-p (group)
 325   (spam-group-processor-p group 'gnus-group-ham-exit-processor-bogofilter))
 326
 327 (defun spam-group-spam-processor-stat-p (group)
 328   (spam-group-processor-p group 'gnus-group-spam-exit-processor-stat))
 329
 330 (defun spam-group-ham-processor-stat-p (group)
 331   (spam-group-processor-p group 'gnus-group-ham-exit-processor-stat))
 332
 333 (defun spam-group-ham-processor-whitelist-p (group)
 334   (spam-group-processor-p group 'gnus-group-ham-exit-processor-whitelist))
 335
 336 (defun spam-group-ham-processor-BBDB-p (group)
 337   (spam-group-processor-p group 'gnus-group-ham-exit-processor-BBDB))
 338
 339 ;;; Summary entry and exit processing.
 340
 341 (defun spam-summary-prepare ()
 342   (spam-mark-junk-as-spam-routine))
 343
 344 (add-hook 'gnus-summary-prepare-hook 'spam-summary-prepare)
 345
 346 (defun spam-summary-prepare-exit ()
 347   ;; The spam processors are invoked for any group, spam or ham or neither
 348   (gnus-message 6 "Exiting summary buffer and applying spam rules")
 349   (when (and spam-bogofilter-path
 350              (spam-group-spam-processor-bogofilter-p gnus-newsgroup-name))
 351     (gnus-message 5 "Registering spam with bogofilter")
 352     (spam-bogofilter-register-spam-routine))
 353
 354   (when (and spam-ifile-path
 355              (spam-group-spam-processor-ifile-p gnus-newsgroup-name))
 356     (gnus-message 5 "Registering spam with ifile")
 357     (spam-ifile-register-spam-routine))
 358
 359   (when (spam-group-spam-processor-stat-p gnus-newsgroup-name)
 360     (gnus-message 5 "Registering spam with spam-stat")
 361     (spam-stat-register-spam-routine))
 362
 363   (when (spam-group-spam-processor-blacklist-p gnus-newsgroup-name)
 364     (gnus-message 5 "Registering spam with the blacklist")
 365     (spam-blacklist-register-routine))
 366
 367   (if spam-move-spam-nonspam-groups-only
 368       (when (not (spam-group-spam-contents-p gnus-newsgroup-name))
 369         (spam-mark-spam-as-expired-and-move-routine
 370          (gnus-parameter-spam-process-destination gnus-newsgroup-name)))
 371     (gnus-message 5 "Marking spam as expired and moving it")
 372     (spam-mark-spam-as-expired-and-move-routine
 373      (gnus-parameter-spam-process-destination gnus-newsgroup-name)))
 374
 375   ;; now we redo spam-mark-spam-as-expired-and-move-routine to only
 376   ;; expire spam, in case the above did not expire them
 377   (spam-mark-spam-as-expired-and-move-routine nil)
 378
 379   (when (spam-group-ham-contents-p gnus-newsgroup-name)
 380     (when (spam-group-ham-processor-whitelist-p gnus-newsgroup-name)
 381       (gnus-message 5 "Registering ham with the whitelist")
 382       (spam-whitelist-register-routine))
 383     (when (spam-group-ham-processor-ifile-p gnus-newsgroup-name)
 384       (gnus-message 5 "Registering ham with ifile")
 385       (spam-ifile-register-ham-routine))
 386     (when (spam-group-ham-processor-bogofilter-p gnus-newsgroup-name)
 387       (gnus-message 5 "Registering ham with Bogofilter")
 388       (spam-bogofilter-register-ham-routine))
 389     (when (spam-group-ham-processor-stat-p gnus-newsgroup-name)
 390       (gnus-message 5 "Registering ham with spam-stat")
 391       (spam-stat-register-ham-routine))
 392     (when (spam-group-ham-processor-BBDB-p gnus-newsgroup-name)
 393       (gnus-message 5 "Registering ham with the BBDB")
 394       (spam-BBDB-register-routine)))
 395
 396   ;; now move all ham articles out of spam groups
 397   (when (spam-group-spam-contents-p gnus-newsgroup-name)
 398     (gnus-message 5 "Moving ham messages from spam group")
 399     (spam-ham-move-routine
 400      (gnus-parameter-ham-process-destination gnus-newsgroup-name))))
 401
 402 (add-hook 'gnus-summary-prepare-exit-hook 'spam-summary-prepare-exit)
 403
 404 (defun spam-mark-junk-as-spam-routine ()
 405   ;; check the global list of group names spam-junk-mailgroups and the
 406   ;; group parameters
 407   (when (spam-group-spam-contents-p gnus-newsgroup-name)
 408     (gnus-message 5 "Marking unread articles as spam")
 409     (let ((articles gnus-newsgroup-articles)
 410           article)
 411       (while articles
 412         (setq article (pop articles))
 413         (when (eq (gnus-summary-article-mark article) gnus-unread-mark)
 414           (gnus-summary-mark-article article gnus-spam-mark))))))
 415
 416 (defun spam-mark-spam-as-expired-and-move-routine (&optional group)
 417   (let ((articles gnus-newsgroup-articles)
 418         article)
 419     (while articles
 420       (setq article (pop articles))
 421       (when (eq (gnus-summary-article-mark article) gnus-spam-mark)
 422         (gnus-summary-mark-article article gnus-expirable-mark)
 423         (when (stringp group)
 424           (let ((gnus-current-article article))
 425             (gnus-summary-move-article nil group)))))))
 426
 427 (defun spam-ham-move-routine (&optional group)
 428   (let ((articles gnus-newsgroup-articles)
 429         article ham-mark-values mark)
 430
 431     (dolist (mark spam-ham-marks)
 432       (push (symbol-value mark) ham-mark-values))
 433     (dolist (article articles)
 434       (when (and (memq (gnus-summary-article-mark article) ham-mark-values)
 435                  (stringp group))
 436         (gnus-summary-set-process-mark article)
 437         (gnus-summary-move-article nil group)))))
 438
 439 (defun spam-generic-register-routine (spam-func ham-func)
 440   (let ((articles gnus-newsgroup-articles)
 441         article mark ham-articles spam-articles spam-mark-values
 442         ham-mark-values)
 443
 444     ;; marks are stored as symbolic values, so we have to dereference
 445     ;; them for memq to work.  we wouldn't have to do this if
 446     ;; gnus-summary-article-mark returned a symbol.
 447     (dolist (mark spam-ham-marks)
 448       (push (symbol-value mark) ham-mark-values))
 449
 450     (dolist (mark spam-spam-marks)
 451       (push (symbol-value mark) spam-mark-values))
 452
 453     (while articles
 454       (setq article (pop articles)
 455             mark (gnus-summary-article-mark article))
 456       (cond ((memq mark spam-mark-values) (push article spam-articles))
 457             ((memq article gnus-newsgroup-saved))
 458             ((memq mark ham-mark-values) (push article ham-articles))))
 459     (when (and ham-articles ham-func)
 460       (mapc ham-func ham-articles))     ; we use mapc because unlike
 461                                         ; mapcar it discards the
 462                                         ; return values
 463     (when (and spam-articles spam-func)
 464       (mapc spam-func spam-articles)))) ; we use mapc because unlike
 465                                         ; mapcar it discards the
 466                                         ; return values
 467
 468 (eval-and-compile
 469   (defalias 'spam-point-at-eol (if (fboundp 'point-at-eol)
 470                                    'point-at-eol
 471                                  'line-end-position)))
 472
 473 (defun spam-get-article-as-string (article)
 474   (let ((article-buffer (spam-get-article-as-buffer article))
 475                         article-string)
 476     (when article-buffer
 477       (save-window-excursion
 478         (set-buffer article-buffer)
 479         (setq article-string (buffer-string))))
 480   article-string))
 481
 482 (defun spam-get-article-as-buffer (article)
 483   (let ((article-buffer))
 484     (when (numberp article)
 485       (save-window-excursion
 486         (gnus-summary-goto-subject article)
 487         (gnus-summary-show-article t)
 488         (setq article-buffer (get-buffer gnus-article-buffer))))
 489     article-buffer))
 490
 491 (defun spam-get-article-as-filename (article)
 492   (let ((article-filename))
 493     (when (numberp article)
 494       (nnml-possibly-change-directory (gnus-group-real-name gnus-newsgroup-name))
 495       (setq article-filename (expand-file-name (int-to-string article) nnml-current-directory)))
 496     (if (file-exists-p article-filename)
 497         article-filename
 498       nil)))
 499
 500 (defun spam-fetch-field-from-fast (article)
 501   "Fetch the `from' field quickly, using the internal gnus-data-list function"
 502   (if (and (numberp article)
 503            (assoc article (gnus-data-list nil)))
 504       (mail-header-from (gnus-data-header (assoc article (gnus-data-list nil))))
 505     nil))
 506
 507 (defun spam-fetch-field-subject-fast (article)
 508   "Fetch the `subject' field quickly, using the internal gnus-data-list function"
 509   (if (and (numberp article)
 510            (assoc article (gnus-data-list nil)))
 511       (mail-header-subject (gnus-data-header (assoc article (gnus-data-list nil))))
 512     nil))
 513
 514 \f
 515 ;;;; Spam determination.
 516
 517 (defvar spam-list-of-checks
 518   '((spam-use-blacklist                 .       spam-check-blacklist)
 519     (spam-use-regex-headers             .       spam-check-regex-headers)
 520     (spam-use-whitelist                 .       spam-check-whitelist)
 521     (spam-use-BBDB                      .       spam-check-BBDB)
 522     (spam-use-ifile                     .       spam-check-ifile)
 523     (spam-use-stat                      .       spam-check-stat)
 524     (spam-use-blackholes                .       spam-check-blackholes)
 525     (spam-use-bogofilter-headers        .       spam-check-bogofilter-headers)
 526     (spam-use-bogofilter                .       spam-check-bogofilter))
 527 "The spam-list-of-checks list contains pairs associating a parameter
 528 variable with a spam checking function.  If the parameter variable is
 529 true, then the checking function is called, and its value decides what
 530 happens.  Each individual check may return nil, t, or a mailgroup
 531 name.  The value nil means that the check does not yield a decision,
 532 and so, that further checks are needed.  The value t means that the
 533 message is definitely not spam, and that further spam checks should be
 534 inhibited.  Otherwise, a mailgroup name is returned where the mail
 535 should go, and further checks are also inhibited.  The usual mailgroup
 536 name is the value of `spam-split-group', meaning that the message is
 537 definitely a spam.")
 538
 539 (defun spam-split ()
 540   "Split this message into the `spam' group if it is spam.
 541 This function can be used as an entry in `nnmail-split-fancy', for
 542 example like this: (: spam-split)
 543
 544 See the Info node `(gnus)Fancy Mail Splitting' for more details."
 545   (interactive)
 546
 547   ;; load the spam-stat tables if needed
 548   (when spam-use-stat (spam-stat-load))
 549
 550   (let ((list-of-checks spam-list-of-checks)
 551         decision)
 552     (while (and list-of-checks (not decision))
 553       (let ((pair (pop list-of-checks)))
 554         (when (symbol-value (car pair))
 555           (gnus-message 5 "spam-split: calling the %s function" (symbol-name (cdr pair)))
 556           (setq decision (funcall (cdr pair))))))
 557     (if (eq decision t)
 558         nil
 559       decision)))
 560 \f
 561 ;;;; Regex headers
 562
 563 (defun spam-check-regex-headers ()
 564   (let (ret found)
 565     (dolist (h-regex spam-regex-headers-ham)
 566       (unless found
 567         (goto-char (point-min))
 568         (when (re-search-forward h-regex nil t)
 569           (message "Ham regex header search positive.")
 570           (setq found t))))
 571     (dolist (s-regex spam-regex-headers-spam)
 572       (unless found
 573         (goto-char (point-min))
 574         (when (re-search-forward s-regex nil t)
 575           (message "Spam regex header search positive." (match-string 1))
 576           (setq found t)
 577           (setq ret spam-split-group))))
 578     ret))
 579
 580 \f
 581 ;;;; Blackholes.
 582
 583 (defun spam-check-blackholes ()
 584   "Check the Received headers for blackholed relays."
 585   (let ((headers (message-fetch-field "received"))
 586         ips matches)
 587     (when headers
 588       (with-temp-buffer
 589         (insert headers)
 590         (goto-char (point-min))
 591         (gnus-message 5 "Checking headers for relay addresses")
 592         (while (re-search-forward
 593                 "\\[\\([0-9]+.[0-9]+.[0-9]+.[0-9]+\\)\\]" nil t)
 594           (gnus-message 9 "Blackhole search found host IP %s." (match-string 1))
 595           (push (mapconcat 'identity
 596                            (nreverse (split-string (match-string 1) "\\."))
 597                            ".")
 598                 ips)))
 599       (dolist (server spam-blackhole-servers)
 600         (dolist (ip ips)
 601           (unless (and spam-blackhole-good-server-regex
 602                        (string-match spam-blackhole-good-server-regex ip))
 603             (let ((query-string (concat ip "." server)))
 604               (if spam-use-dig
 605                   (let ((query-result (query-dig query-string)))
 606                     (when query-result
 607                       (gnus-message 5 "(DIG): positive blackhole check '%s'" query-result)
 608                       (push (list ip server query-result)
 609                             matches)))
 610                 ;; else, if not using dig.el
 611                 (when (query-dns query-string)
 612                   (gnus-message 5 "positive blackhole check")
 613                   (push (list ip server (query-dns query-string 'TXT))
 614                         matches))))))))
 615     (when matches
 616       spam-split-group)))
 617 \f
 618 ;;;; BBDB
 619
 620 ;;; original idea for spam-check-BBDB from Alexander Kotelnikov
 621 ;;; <sacha@giotto.sj.ru>
 622
 623 ;; all this is done inside a condition-case to trap errors
 624
 625 (condition-case nil
 626     (progn
 627       (require 'bbdb)
 628       (require 'bbdb-com)
 629
 630   (defun spam-enter-ham-BBDB (from)
 631     "Enter an address into the BBDB; implies ham (non-spam) sender"
 632     (when (stringp from)
 633       (let* ((parsed-address (gnus-extract-address-components from))
 634              (name (or (car parsed-address) "Ham Sender"))
 635              (net-address (car (cdr parsed-address))))
 636         (gnus-message 5 "Adding address %s to BBDB" from)
 637         (when (and net-address
 638                    (not (bbdb-search-simple nil net-address)))
 639           (bbdb-create-internal name nil net-address nil nil
 640                                 "ham sender added by spam.el")))))
 641
 642   (defun spam-BBDB-register-routine ()
 643     (spam-generic-register-routine
 644      ;; spam function
 645      nil
 646      ;; ham function
 647      (lambda (article)
 648        (spam-enter-ham-BBDB (spam-fetch-field-from-fast article)))))
 649
 650   (defun spam-check-BBDB ()
 651     "Mail from people in the BBDB is classified as ham or non-spam"
 652     (let ((who (message-fetch-field "from")))
 653       (when who
 654         (setq who (cadr (gnus-extract-address-components who)))
 655         (if (bbdb-search-simple nil who)
 656             t
 657           (if spam-use-BBDB-exclusive
 658               spam-split-group
 659             nil))))))
 660
 661   (file-error (progn
 662                 (defalias 'bbdb-search-simple 'ignore)
 663                 (defalias 'spam-check-BBDB 'ignore)
 664                 (defalias 'spam-BBDB-register-routine 'ignore)
 665                 (defalias 'spam-enter-ham-BBDB 'ignore)
 666                 (defalias 'bbdb-create-internal 'ignore)
 667                 (defalias 'bbdb-records 'ignore))))
 668
 669 \f
 670 ;;;; ifile
 671
 672 ;;; check the ifile backend; return nil if the mail was NOT classified
 673 ;;; as spam
 674
 675 (defun spam-get-ifile-database-parameter ()
 676   "Get the command-line parameter for ifile's database from spam-ifile-database-path."
 677   (if spam-ifile-database-path
 678       (format "--db-file=%s" spam-ifile-database-path)
 679     nil))
 680
 681 (defun spam-check-ifile ()
 682   "Check the ifile backend for the classification of this message"
 683   (let ((article-buffer-name (buffer-name))
 684         category return)
 685     (with-temp-buffer
 686       (let ((temp-buffer-name (buffer-name))
 687             (db-param (spam-get-ifile-database-parameter)))
 688         (save-excursion
 689           (set-buffer article-buffer-name)
 690           (if db-param
 691               (call-process-region (point-min) (point-max) spam-ifile-path
 692                                    nil temp-buffer-name nil "-q" "-c" db-param)
 693             (call-process-region (point-min) (point-max) spam-ifile-path
 694                                  nil temp-buffer-name nil "-q" "-c")))
 695         (goto-char (point-min))
 696         (if (not (eobp))
 697             (setq category (buffer-substring (point) (spam-point-at-eol))))
 698         (when (not (zerop (length category))) ; we need a category here
 699           (if spam-ifile-all-categories
 700               (setq return category)
 701             ;; else, if spam-ifile-all-categories is not set...
 702             (when (string-equal spam-ifile-spam-category category)
 703               (setq return spam-split-group))))))
 704     return))
 705
 706 (defun spam-ifile-register-with-ifile (article-string category)
 707   "Register an article, given as a string, with a category.
 708 Uses `gnus-newsgroup-name' if category is nil (for ham registration)."
 709   (when (stringp article-string)
 710     (let ((category (or category gnus-newsgroup-name))
 711           (db-param (spam-get-ifile-database-parameter)))
 712       (with-temp-buffer
 713         (insert-string article-string)
 714         (if db-param
 715             (call-process-region (point-min) (point-max) spam-ifile-path
 716                                  nil nil nil
 717                                  "-h" "-i" category db-param)
 718           (call-process-region (point-min) (point-max) spam-ifile-path
 719                                nil nil nil
 720                                "-h" "-i" category))))))
 721
 722 (defun spam-ifile-register-spam-routine ()
 723   (spam-generic-register-routine
 724    (lambda (article)
 725      (spam-ifile-register-with-ifile
 726       (spam-get-article-as-string article) spam-ifile-spam-category))
 727    nil))
 728
 729 (defun spam-ifile-register-ham-routine ()
 730   (spam-generic-register-routine
 731    nil
 732    (lambda (article)
 733      (spam-ifile-register-with-ifile
 734       (spam-get-article-as-string article) spam-ifile-ham-category))))
 735
 736 \f
 737 ;;;; spam-stat
 738
 739 (condition-case nil
 740     (progn
 741       (let ((spam-stat-install-hooks nil))
 742         (require 'spam-stat))
 743
 744       (defun spam-check-stat ()
 745         "Check the spam-stat backend for the classification of this message"
 746         (let ((spam-stat-split-fancy-spam-group spam-split-group) ; override
 747               (spam-stat-buffer (buffer-name)) ; stat the current buffer
 748               category return)
 749           (spam-stat-split-fancy)))
 750
 751       (defun spam-stat-register-spam-routine ()
 752         (spam-generic-register-routine
 753          (lambda (article)
 754            (let ((article-string (spam-get-article-as-string article)))
 755              (with-temp-buffer
 756                (insert-string article-string)
 757                (spam-stat-buffer-is-spam))))
 758          nil)
 759         (spam-stat-save))
 760
 761       (defun spam-stat-register-ham-routine ()
 762         (spam-generic-register-routine
 763          nil
 764          (lambda (article)
 765            (let ((article-string (spam-get-article-as-string article)))
 766              (with-temp-buffer
 767                (insert-string article-string)
 768                (spam-stat-buffer-is-non-spam)))))
 769         (spam-stat-save)))
 770
 771   (file-error (progn
 772                 (defalias 'spam-stat-register-ham-routine 'ignore)
 773                 (defalias 'spam-stat-register-spam-routine 'ignore)
 774                 (defalias 'spam-stat-buffer-is-spam 'ignore)
 775                 (defalias 'spam-stat-buffer-is-non-spam 'ignore)
 776                 (defalias 'spam-stat-split-fancy 'ignore)
 777                 (defalias 'spam-stat-load 'ignore)
 778                 (defalias 'spam-stat-save 'ignore)
 779                 (defalias 'spam-check-stat 'ignore))))
 780
 781 \f
 782
 783 ;;;; Blacklists and whitelists.
 784
 785 (defvar spam-whitelist-cache nil)
 786 (defvar spam-blacklist-cache nil)
 787
 788 (defun spam-enter-whitelist (address)
 789   "Enter ADDRESS into the whitelist."
 790   (interactive "sAddress: ")
 791   (spam-enter-list address spam-whitelist)
 792   (setq spam-whitelist-cache nil))
 793
 794 (defun spam-enter-blacklist (address)
 795   "Enter ADDRESS into the blacklist."
 796   (interactive "sAddress: ")
 797   (spam-enter-list address spam-blacklist)
 798   (setq spam-blacklist-cache nil))
 799
 800 (defun spam-enter-list (address file)
 801   "Enter ADDRESS into the given FILE, either the whitelist or the blacklist."
 802   (unless (file-exists-p (file-name-directory file))
 803     (make-directory (file-name-directory file) t))
 804   (save-excursion
 805     (set-buffer
 806      (find-file-noselect file))
 807     (goto-char (point-max))
 808     (unless (bobp)
 809       (insert "\n"))
 810     (insert address "\n")
 811     (save-buffer)))
 812
 813 ;;; returns t if the sender is in the whitelist, nil or spam-split-group otherwise
 814 (defun spam-check-whitelist ()
 815   ;; FIXME!  Should it detect when file timestamps change?
 816   (unless spam-whitelist-cache
 817     (setq spam-whitelist-cache (spam-parse-list spam-whitelist)))
 818   (if (spam-from-listed-p spam-whitelist-cache)
 819       t
 820     (if spam-use-whitelist-exclusive
 821         spam-split-group
 822       nil)))
 823
 824 (defun spam-check-blacklist ()
 825   ;; FIXME!  Should it detect when file timestamps change?
 826   (unless spam-blacklist-cache
 827     (setq spam-blacklist-cache (spam-parse-list spam-blacklist)))
 828   (and (spam-from-listed-p spam-blacklist-cache) spam-split-group))
 829
 830 (defun spam-parse-list (file)
 831   (when (file-readable-p file)
 832     (let (contents address)
 833       (with-temp-buffer
 834         (insert-file-contents file)
 835         (while (not (eobp))
 836           (setq address (buffer-substring (point) (spam-point-at-eol)))
 837           (forward-line 1)
 838           (unless (zerop (length address))
 839             (setq address (regexp-quote address))
 840             (while (string-match "\\\\\\*" address)
 841               (setq address (replace-match ".*" t t address)))
 842             (push address contents))))
 843       (nreverse contents))))
 844
 845 (defun spam-from-listed-p (cache)
 846   (let ((from (message-fetch-field "from"))
 847         found)
 848     (while cache
 849       (when (string-match (pop cache) from)
 850         (setq found t
 851               cache nil)))
 852     found))
 853
 854 (defun spam-blacklist-register-routine ()
 855   (spam-generic-register-routine
 856    ;; the spam function
 857    (lambda (article)
 858      (let ((from (spam-fetch-field-from-fast article)))
 859        (when (stringp from)
 860            (spam-enter-blacklist from))))
 861    ;; the ham function
 862    nil))
 863
 864 (defun spam-whitelist-register-routine ()
 865   (spam-generic-register-routine
 866    ;; the spam function
 867    nil
 868    ;; the ham function
 869    (lambda (article)
 870      (let ((from (spam-fetch-field-from-fast article)))
 871        (when (stringp from)
 872            (spam-enter-whitelist from))))))
 873
 874 \f
 875 ;;;; Bogofilter
 876
 877 (defun spam-check-bogofilter-headers (&optional score)
 878   (let ((header (message-fetch-field spam-bogofilter-header)))
 879       (when (and header
 880                  (string-match spam-bogofilter-bogosity-positive-spam-header
 881                                header))
 882           (if score
 883               (when (string-match "spamicity=\\([0-9.]+\\)" header)
 884                 (match-string 1 header))
 885             spam-split-group))))
 886
 887 ;; return something sensible if the score can't be determined
 888 (defun spam-bogofilter-score ()
 889   "Get the Bogofilter spamicity score"
 890   (interactive)
 891   (save-window-excursion
 892     (gnus-summary-show-article t)
 893     (set-buffer gnus-article-buffer)
 894     (let ((score (spam-check-bogofilter t)))
 895       (message "Spamicity score %s" score)
 896       (or score "0"))))
 897
 898 (defun spam-check-bogofilter (&optional score)
 899   "Check the Bogofilter backend for the classification of this message"
 900   (let ((article-buffer-name (buffer-name))
 901         return)
 902     (with-temp-buffer
 903       (let ((temp-buffer-name (buffer-name)))
 904         (save-excursion
 905           (set-buffer article-buffer-name)
 906           (if spam-bogofilter-database-directory
 907               (call-process-region (point-min) (point-max)
 908                                    spam-bogofilter-path
 909                                    nil temp-buffer-name nil "-v"
 910                                    "-d" spam-bogofilter-database-directory)
 911             (call-process-region (point-min) (point-max) spam-bogofilter-path
 912                                  nil temp-buffer-name nil "-v")))
 913         (setq return (spam-check-bogofilter-headers score))))
 914     return))
 915
 916 (defun spam-bogofilter-register-with-bogofilter (article-string spam)
 917   "Register an article, given as a string, as spam or non-spam."
 918   (when (stringp article-string)
 919     (let ((switch (if spam "-s" "-n")))
 920       (with-temp-buffer
 921         (insert-string article-string)
 922         (if spam-bogofilter-database-directory
 923             (call-process-region (point-min) (point-max)
 924                                  spam-bogofilter-path
 925                                  nil nil nil "-v" switch
 926                                  "-d" spam-bogofilter-database-directory)
 927           (call-process-region (point-min) (point-max) spam-bogofilter-path
 928                                nil nil nil "-v" switch))))))
 929
 930 (defun spam-bogofilter-register-spam-routine ()
 931   (spam-generic-register-routine
 932    (lambda (article)
 933      (spam-bogofilter-register-with-bogofilter
 934       (spam-get-article-as-string article) t))
 935    nil))
 936
 937 (defun spam-bogofilter-register-ham-routine ()
 938   (spam-generic-register-routine
 939    nil
 940    (lambda (article)
 941      (spam-bogofilter-register-with-bogofilter
 942       (spam-get-article-as-string article) nil))))
 943
 944 (provide 'spam)
 945
 946 ;;; spam.el ends here.