cgit.sxemacs.org Git - gnus/blob - lisp/spam-report.el

   1 ;;; spam-report.el --- Reporting spam
   2
   3 ;; Copyright (C) 2002, 2003, 2004, 2005, 2006 Free Software Foundation, Inc.
   4
   5 ;; Author: Ted Zlatanov <tzz@lifelogs.com>
   6 ;; Keywords: network, spam, mail, gmane, report
   7
   8 ;; This file is part of GNU Emacs.
   9
  10 ;; GNU Emacs is free software; you can redistribute it and/or modify
  11 ;; it under the terms of the GNU General Public License as published by
  12 ;; the Free Software Foundation; either version 2, or (at your option)
  13 ;; any later version.
  14
  15 ;; GNU Emacs is distributed in the hope that it will be useful,
  16 ;; but WITHOUT ANY WARRANTY; without even the implied warranty of
  17 ;; MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.  See the
  18 ;; GNU General Public License for more details.
  19
  20 ;; You should have received a copy of the GNU General Public License
  21 ;; along with GNU Emacs; see the file COPYING.  If not, write to the
  22 ;; Free Software Foundation, Inc., 51 Franklin Street, Fifth Floor,
  23 ;; Boston, MA 02110-1301, USA.
  24
  25 ;;; Commentary:
  26
  27 ;;; This module addresses a few aspects of spam reporting under Gnus.  Page
  28 ;;; breaks are used for grouping declarations and documentation relating to
  29 ;;; each particular aspect.
  30
  31 ;;; Code:
  32 (require 'gnus)
  33 (require 'gnus-sum)
  34
  35 (eval-and-compile
  36   (autoload 'mm-url-insert "mm-url"))
  37
  38 (defgroup spam-report nil
  39   "Spam reporting configuration."
  40   :group 'mail
  41   :group 'news)
  42
  43 (defcustom spam-report-gmane-regex nil
  44   "Regexp matching Gmane newsgroups, e.g. \"^nntp\\+.*:gmane\\.\"
  45 If you are using spam.el, consider setting gnus-spam-process-newsgroups
  46 or the gnus-group-spam-exit-processor-report-gmane group/topic parameter
  47 instead."
  48   :type '(radio (const nil)
  49                 (regexp :value "^nntp\+.*:gmane\."))
  50   :group 'spam-report)
  51
  52 (defcustom spam-report-gmane-use-article-number t
  53   "Whether the article number (faster!) or the header should be used.
  54
  55 You must set this to nil if you don't read Gmane groups directly
  56 from news.gmane.org, e.g. when using local newsserver such as
  57 leafnode."
  58   :type 'boolean
  59   :group 'spam-report)
  60
  61 (defcustom spam-report-url-ping-function
  62   'spam-report-url-ping-plain
  63   "Function to use for url ping spam reporting.
  64 The function must accept the arguments `host' and `report'."
  65   :type '(choice
  66           (const :tag "Connect directly"
  67                  spam-report-url-ping-plain)
  68           (const :tag "Use the external program specified in `mm-url-program'"
  69                  spam-report-url-ping-mm-url)
  70           (const :tag "Store request URLs in `spam-report-requests-file'"
  71                  spam-report-url-to-file)
  72           (function :tag "User defined function" nil))
  73   :group 'spam-report)
  74
  75 (defcustom spam-report-requests-file
  76   (nnheader-concat gnus-directory "spam/" "spam-report-requests.url")
  77   ;; Is there a convention for the extension of such a file?
  78   ;; Should we use `spam-directory'?
  79   "File where spam report request are stored."
  80   :type 'file
  81   :group 'spam-report)
  82
  83 (defcustom spam-report-resend-to nil
  84   "Email address that spam articles are resent to when reporting.
  85 If not set, the user will be prompted to enter a value which will be
  86 saved for future use."
  87   :type 'string
  88   :group 'spam-report)
  89
  90 (defvar spam-report-url-ping-temp-agent-function nil
  91   "Internal variable for `spam-report-agentize' and `spam-report-deagentize'.
  92 This variable will store the value of `spam-report-url-ping-function' from
  93 before `spam-report-agentize' was run, so that `spam-report-deagentize' can
  94 undo that change.")
  95
  96 (defun spam-report-resend (articles &optional ham)
  97   "Report an article as spam by resending via email.
  98 Reports is as ham when HAM is set."
  99   (dolist (article articles)
 100     (gnus-message 6
 101                   "Reporting %s article %d to <%s>..."
 102                   (if ham "ham" "spam")
 103                   article spam-report-resend-to)
 104     (unless spam-report-resend-to
 105       (customize-set-variable
 106        spam-report-resend-to
 107        (read-from-minibuffer "email address to resend SPAM/HAM to? ")))
 108     ;; This is ganked from the `gnus-summary-resend-message' function.
 109     ;; It involves rendering the SPAM, which is undesirable, but there does
 110     ;; not seem to be a nicer way to achieve this.
 111     ;; select this particular article
 112     (gnus-summary-select-article nil nil nil article)
 113     ;; resend it to the destination address
 114     (save-excursion
 115       (set-buffer gnus-original-article-buffer)
 116       (message-resend spam-report-resend-to))))
 117
 118 (defun spam-report-resend-ham (articles)
 119   "Report an article as ham by resending via email."
 120   (spam-report-resend articles t))
 121
 122 (defun spam-report-gmane-ham (&rest articles)
 123   "Report ARTICLES as ham (unregister) through Gmane."
 124   (interactive (gnus-summary-work-articles current-prefix-arg))
 125   (dolist (article articles)
 126     (spam-report-gmane-internal t article)))
 127
 128 (defun spam-report-gmane-spam (&rest articles)
 129   "Report ARTICLES as spam through Gmane."
 130   (interactive (gnus-summary-work-articles current-prefix-arg))
 131   (dolist (article articles)
 132     (message "Reporting %s" article)
 133     (spam-report-gmane-internal nil article)))
 134
 135 ;; `spam-report-gmane' was an interactive entry point, so we should provide an
 136 ;; alias.
 137 (defalias 'spam-report-gmane 'spam-report-gmane-spam)
 138
 139 (defun spam-report-gmane-internal (unspam article)
 140   "Report ARTICLE as spam or not-spam through Gmane, depending on UNSPAM."
 141   (when (and gnus-newsgroup-name
 142              (or (null spam-report-gmane-regex)
 143                  (string-match spam-report-gmane-regex gnus-newsgroup-name)))
 144     (let ((rpt-host (if unspam "unspam.gmane.org" "spam.gmane.org")))
 145       (gnus-message 6 "Reporting article %d to %s..." article rpt-host)
 146       (if spam-report-gmane-use-article-number
 147           (spam-report-url-ping
 148            rpt-host
 149            (format "/%s:%d"
 150                    (gnus-group-real-name gnus-newsgroup-name)
 151                    article))
 152         (with-current-buffer nntp-server-buffer
 153           (gnus-request-head article gnus-newsgroup-name)
 154           (let ((case-fold-search t)
 155                 field host report url)
 156             ;; First check for X-Report-Spam because it's more specific to
 157             ;; spam reporting than Archived-At.  OTOH, all new articles on
 158             ;; Gmane don't have X-Report-Spam anymore (unless Lars changes his
 159             ;; mind :-)).
 160             ;;
 161             ;; There might be more than one Archived-At header so we need to
 162             ;; find (and transform) the one related to Gmane.
 163             (setq field (or (gnus-fetch-field "X-Report-Spam")
 164                             (gnus-fetch-field "X-Report-Unspam")
 165                             (gnus-fetch-field "Archived-At")))
 166             (if (not (stringp field))
 167                 (if (and (setq field (gnus-fetch-field "Xref"))
 168                          (string-match "[^ ]+ +\\([^ ]+\\)" field))
 169                     (setq report (match-string 1 field)
 170                           host rpt-host))
 171               (setq host
 172                     (progn
 173                       (string-match
 174                        (concat "http://\\([a-z]+\\.gmane\\.org\\)"
 175                                "\\(/[^:/]+[:/][0-9]+\\)")
 176                        field)
 177                       (match-string 1 field)))
 178               (setq report (match-string 2 field)))
 179             (when host
 180               (when (string-equal "permalink.gmane.org" host)
 181                 (setq host rpt-host)
 182                 (setq report (gnus-replace-in-string
 183                               report "/\\([0-9]+\\)$" ":\\1")))
 184               (setq url (format "http://%s%s" host report)))
 185             (if (not (and host report url))
 186                 (gnus-message
 187                  3 "Could not find a spam report header in article %d..."
 188                  article)
 189               (gnus-message 7 "Reporting article through URL %s..." url)
 190               (spam-report-url-ping host report))))))))
 191
 192 (defun spam-report-url-ping (host report)
 193   "Ping a host through HTTP, addressing a specific GET resource using
 194 the function specified by `spam-report-url-ping-function'."
 195   ;; Example:
 196   ;; host: "spam.gmane.org"
 197   ;; report: "/gmane.some.group:123456"
 198   (funcall spam-report-url-ping-function host report))
 199
 200 (defcustom spam-report-user-mail-address
 201   (and (stringp user-mail-address)
 202        (gnus-replace-in-string user-mail-address "@" "<at>"))
 203   "Mail address of this user used for spam reports to Gmane.
 204 This is initialized based on `user-mail-address'."
 205   :type '(choice string
 206                  (const :tag "Don't expose address" nil))
 207   :version "23.0" ;; No Gnus
 208   :group 'spam-report)
 209
 210 (defvar spam-report-user-agent
 211   (if spam-report-user-mail-address
 212       (format "%s (%s) %s" "spam-report.el"
 213               spam-report-user-mail-address
 214               (gnus-extended-version))
 215     (format "%s %s" "spam-report.el"
 216             (gnus-extended-version))))
 217
 218 (defun spam-report-url-ping-plain (host report)
 219   "Ping a host through HTTP, addressing a specific GET resource."
 220   (let ((tcp-connection))
 221     (with-temp-buffer
 222       (or (setq tcp-connection
 223                 (open-network-stream
 224                  "URL ping"
 225                  (buffer-name)
 226                  host
 227                  80))
 228           (error "Could not open connection to %s" host))
 229       (set-marker (process-mark tcp-connection) (point-min))
 230       (process-send-string
 231        tcp-connection
 232        (format "GET %s HTTP/1.1\nUser-Agent: %s\nHost: %s\n\n"
 233                report spam-report-user-agent host))
 234       ;; Wait until we get something so we don't DOS the host.
 235       (while (and (memq (process-status tcp-connection) '(open run))
 236                   (zerop (buffer-size)))
 237         (accept-process-output tcp-connection)))))
 238
 239 ;;;###autoload
 240 (defun spam-report-process-queue (&optional file keep)
 241   "Report all queued requests from `spam-report-requests-file'.
 242
 243 If FILE is given, use it instead of `spam-report-requests-file'.
 244 If KEEP is t, leave old requests in the file.  If KEEP is the
 245 symbol `ask', query before flushing the queue file."
 246   (interactive
 247    (list (read-file-name
 248           "File: "
 249           (file-name-directory spam-report-requests-file)
 250           spam-report-requests-file
 251           nil
 252           (file-name-nondirectory spam-report-requests-file))
 253          current-prefix-arg))
 254   (if (eq spam-report-url-ping-function 'spam-report-url-to-file)
 255       (error (concat "Cannot process requests when "
 256                      "`spam-report-url-ping-function' is "
 257                      "`spam-report-url-to-file'."))
 258     (gnus-message 7 "Processing requests using `%s'."
 259                   spam-report-url-ping-function))
 260   (or file (setq file spam-report-requests-file))
 261   (save-excursion
 262     (set-buffer (find-file-noselect file))
 263     (goto-char (point-min))
 264     (while (and (not (eobp))
 265                 (re-search-forward
 266                  "http://\\([^/]+\\)\\(/.*\\) *$" (point-at-eol) t))
 267       (funcall spam-report-url-ping-function (match-string 1) (match-string 2))
 268       (forward-line 1))
 269     (if (or (eq keep nil)
 270             (and (eq keep 'ask)
 271                  (y-or-n-p
 272                   (format
 273                    "Flush requests from `%s'? " (current-buffer)))))
 274         (progn
 275           (gnus-message 7 "Flushing request file `%s'"
 276                         spam-report-requests-file)
 277           (erase-buffer)
 278           (save-buffer)
 279           (kill-buffer (current-buffer)))
 280       (gnus-message 7 "Keeping requests in `%s'" spam-report-requests-file))))
 281
 282 ;;;###autoload
 283 (defun spam-report-url-ping-mm-url (host report)
 284   "Ping a host through HTTP, addressing a specific GET resource. Use
 285 the external program specified in `mm-url-program' to connect to
 286 server."
 287   (with-temp-buffer
 288     (let ((url (format "http://%s%s" host report)))
 289       (mm-url-insert url t))))
 290
 291 ;;;###autoload
 292 (defun spam-report-url-to-file (host report)
 293   "Collect spam report requests in `spam-report-requests-file'.
 294 Customize `spam-report-url-ping-function' to use this function."
 295   (let ((url (format "http://%s%s" host report))
 296         (file spam-report-requests-file))
 297     (gnus-make-directory (file-name-directory file))
 298     (gnus-message 9 "Writing URL `%s' to file `%s'" url file)
 299     (with-temp-buffer
 300       (insert url)
 301       (newline)
 302       (append-to-file (point-min) (point-max) file))))
 303
 304 ;;;###autoload
 305 (defun spam-report-agentize ()
 306   "Add spam-report support to the Agent.
 307 Spam reports will be queued with \\[spam-report-url-to-file] when
 308 the Agent is unplugged, and will be submitted in a batch when the
 309 Agent is plugged."
 310   (interactive)
 311   (add-hook 'gnus-agent-plugged-hook 'spam-report-plug-agent)
 312   (add-hook 'gnus-agent-unplugged-hook 'spam-report-unplug-agent))
 313
 314 ;;;###autoload
 315 (defun spam-report-deagentize ()
 316   "Remove spam-report support from the Agent.
 317 Spam reports will be queued with the method used when
 318 \\[spam-report-agentize] was run."
 319   (interactive)
 320   (remove-hook 'gnus-agent-plugged-hook 'spam-report-plug-agent)
 321   (remove-hook 'gnus-agent-unplugged-hook 'spam-report-unplug-agent))
 322
 323 (defun spam-report-plug-agent ()
 324   "Adjust spam report settings for plugged state.
 325 Process queued spam reports."
 326   ;; Process the queue, unless the user only wanted to report to a file
 327   ;; anyway.
 328   (unless (equal spam-report-url-ping-temp-agent-function
 329                  'spam-report-url-to-file)
 330     (spam-report-process-queue))
 331   ;; Set the reporting function, if we have memorized something otherwise,
 332   ;; stick with plain URL reporting.
 333   (setq spam-report-url-ping-function
 334         (or spam-report-url-ping-temp-agent-function
 335             'spam-report-url-ping-plain)))
 336
 337 (defun spam-report-unplug-agent ()
 338   "Restore spam report settings for unplugged state."
 339   ;; save the old value
 340   (setq spam-report-url-ping-temp-agent-function
 341         spam-report-url-ping-function)
 342   ;; store all reports to file
 343   (setq spam-report-url-ping-function
 344         'spam-report-url-to-file))
 345
 346 (provide 'spam-report)
 347
 348 ;;; arch-tag: f6683295-ec89-4ab5-8803-8cc842293022
 349 ;;; spam-report.el ends here.