cgit.sxemacs.org Git - gnus/blob - lisp/spam-report.el

   1 ;;; spam-report.el --- Reporting spam
   2
   3 ;; Copyright (C) 2002, 2003, 2004, 2005 Free Software Foundation, Inc.
   4
   5 ;; Author: Ted Zlatanov <tzz@lifelogs.com>
   6 ;; Keywords: network, spam, mail, gmane, report
   7
   8 ;; This file is part of GNU Emacs.
   9
  10 ;; GNU Emacs is free software; you can redistribute it and/or modify
  11 ;; it under the terms of the GNU General Public License as published by
  12 ;; the Free Software Foundation; either version 2, or (at your option)
  13 ;; any later version.
  14
  15 ;; GNU Emacs is distributed in the hope that it will be useful,
  16 ;; but WITHOUT ANY WARRANTY; without even the implied warranty of
  17 ;; MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.  See the
  18 ;; GNU General Public License for more details.
  19
  20 ;; You should have received a copy of the GNU General Public License
  21 ;; along with GNU Emacs; see the file COPYING.  If not, write to the
  22 ;; Free Software Foundation, Inc., 51 Franklin Street, Fifth Floor,
  23 ;; Boston, MA 02110-1301, USA.
  24
  25 ;;; Commentary:
  26
  27 ;;; This module addresses a few aspects of spam reporting under Gnus.  Page
  28 ;;; breaks are used for grouping declarations and documentation relating to
  29 ;;; each particular aspect.
  30
  31 ;;; Code:
  32 (require 'gnus)
  33 (require 'gnus-sum)
  34
  35 (eval-and-compile
  36   (autoload 'mm-url-insert "mm-url"))
  37
  38 (defgroup spam-report nil
  39   "Spam reporting configuration."
  40   :group 'mail
  41   :group 'news)
  42
  43 (defcustom spam-report-gmane-regex nil
  44   "Regexp matching Gmane newsgroups, e.g. \"^nntp\\+.*:gmane\\.\"
  45 If you are using spam.el, consider setting gnus-spam-process-newsgroups
  46 or the gnus-group-spam-exit-processor-report-gmane group/topic parameter
  47 instead."
  48   :type '(radio (const nil)
  49                 (regexp :value "^nntp\+.*:gmane\."))
  50   :group 'spam-report)
  51
  52 (defcustom spam-report-gmane-use-article-number t
  53   "Whether the article number (faster!) or the header should be used."
  54   :type 'boolean
  55   :group 'spam-report)
  56
  57 (defcustom spam-report-url-ping-function
  58   'spam-report-url-ping-plain
  59   "Function to use for url ping spam reporting.
  60 The function must accept the arguments `host' and `report'."
  61   :type '(choice
  62           (const :tag "Connect directly"
  63                  spam-report-url-ping-plain)
  64           (const :tag "Use the external program specified in `mm-url-program'"
  65                  spam-report-url-ping-mm-url)
  66           (const :tag "Store request URLs in `spam-report-requests-file'"
  67                  spam-report-url-to-file)
  68           (function :tag "User defined function" nil))
  69   :group 'spam-report)
  70
  71 (defcustom spam-report-requests-file
  72   (nnheader-concat gnus-directory "spam/" "spam-report-requests.url")
  73   ;; Is there a convention for the extension of such a file?
  74   ;; Should we use `spam-directory'?
  75   "File where spam report request are stored."
  76   :type 'file
  77   :group 'spam-report)
  78
  79 (defcustom spam-report-resend-to nil
  80   "Email address that spam articles are resent to when reporting.
  81 If not set, the user will be prompted to enter a value which will be
  82 saved for future use."
  83   :type 'string
  84   :group 'spam-report)
  85
  86 (defvar spam-report-url-ping-temp-agent-function nil
  87   "Internal variable for `spam-report-agentize' and `spam-report-deagentize'.
  88 This variable will store the value of `spam-report-url-ping-function' from
  89 before `spam-report-agentize' was run, so that `spam-report-deagentize' can
  90 undo that change.")
  91
  92 (defun spam-report-resend (articles &optional ham)
  93   "Report an article as spam by resending via email.
  94 Reports is as ham when HAM is set."
  95   (dolist (article articles)
  96     (gnus-message 6
  97                   "Reporting %s article %d to <%s>..."
  98                   (if ham "ham" "spam")
  99                   article spam-report-resend-to)
 100     (unless spam-report-resend-to
 101       (customize-set-variable
 102        spam-report-resend-to
 103        (read-from-minibuffer "email address to resend SPAM/HAM to? ")))
 104     ;; This is ganked from the `gnus-summary-resend-message' function.
 105     ;; It involves rendering the SPAM, which is undesirable, but there does
 106     ;; not seem to be a nicer way to achieve this.
 107     ;; select this particular article
 108     (gnus-summary-select-article nil nil nil article)
 109     ;; resend it to the destination address
 110     (save-excursion
 111       (set-buffer gnus-original-article-buffer)
 112       (message-resend spam-report-resend-to))))
 113
 114 (defun spam-report-resend-ham (articles)
 115   "Report an article as ham by resending via email."
 116   (spam-report-resend articles t))
 117
 118 (defun spam-report-gmane-unspam (&rest articles)
 119   "Report ARTICLES as not-spam (unregister) through Gmane."
 120   (interactive (gnus-summary-work-articles current-prefix-arg))
 121   (dolist (article articles)
 122     (spam-report-gmane t article)))
 123
 124 (defun spam-report-gmane-spam (&rest articles)
 125   "Report ARTICLES as spam through Gmane."
 126   (interactive (gnus-summary-work-articles current-prefix-arg))
 127   (dolist (article articles)
 128     (spam-report-gmane nil article)))
 129
 130 (defun spam-report-gmane (unspam article)
 131   "Report ARTICLE as spam or not-spam through Gmane, depending on UNSPAM."
 132   (when (and gnus-newsgroup-name
 133              (or (null spam-report-gmane-regex)
 134                  (string-match spam-report-gmane-regex gnus-newsgroup-name)))
 135     (gnus-message 6 "Reporting spam article %d to spam.gmane.org..." article)
 136     (if spam-report-gmane-use-article-number
 137         (spam-report-url-ping
 138          (if unspam "unspam.gmane.org" "spam.gmane.org")
 139          (format "/%s:%d"
 140                  (gnus-group-real-name gnus-newsgroup-name)
 141                  article))
 142       (with-current-buffer nntp-server-buffer
 143         (gnus-request-head article gnus-newsgroup-name)
 144         (let ((case-fold-search t)
 145               field host report url)
 146           ;; First check for X-Report-Spam because it's more specific to
 147           ;; spam reporting than Archived-At.  OTOH, all new articles on
 148           ;; Gmane don't have X-Report-Spam anymore (unless Lars changes his
 149           ;; mind :-)).
 150           ;;
 151           ;; There might be more than one Archived-At header so we need to
 152           ;; find (and transform) the one related to Gmane.
 153           (setq field (or (gnus-fetch-field "X-Report-Spam")
 154                           (gnus-fetch-field "Archived-At")))
 155           (setq host (progn
 156                        (string-match
 157                         (concat "http://\\([a-z]+\\.gmane\\.org\\)"
 158                                 "\\(/[^:/]+[:/][0-9]+\\)")
 159                         field)
 160                        (match-string 1 field)))
 161           (setq report (match-string 2 field))
 162           (when (string-equal "permalink.gmane.org" host)
 163             (setq host (if unspam "unspam.gmane.org" "spam.gmane.org"))
 164             (setq report (gnus-replace-in-string
 165                           report "/\\([0-9]+\\)$" ":\\1")))
 166           (setq url (format "http://%s%s" host report))
 167           (if (not (and host report url))
 168               (gnus-message
 169                3 "Could not find a spam report header in article %d..."
 170                article)
 171             (gnus-message 7 "Reporting %s through URL %s..." (if unspam "unspam" "spam") url)
 172             (spam-report-url-ping host report)))))))
 173
 174 (defun spam-report-url-ping (host report)
 175   "Ping a host through HTTP, addressing a specific GET resource using
 176 the function specified by `spam-report-url-ping-function'."
 177   ;; Example:
 178   ;; host: "spam.gmane.org"
 179   ;; report: "/gmane.some.group:123456"
 180   (funcall spam-report-url-ping-function host report))
 181
 182 (defun spam-report-url-ping-plain (host report)
 183   "Ping a host through HTTP, addressing a specific GET resource."
 184   (let ((tcp-connection))
 185     (with-temp-buffer
 186       (or (setq tcp-connection
 187                 (open-network-stream
 188                  "URL ping"
 189                  (buffer-name)
 190                  host
 191                  80))
 192           (error "Could not open connection to %s" host))
 193       (set-marker (process-mark tcp-connection) (point-min))
 194       (process-send-string
 195        tcp-connection
 196        (format "GET %s HTTP/1.1\nUser-Agent: %s (spam-report.el)\nHost: %s\n\n"
 197                report (gnus-emacs-version) host)))))
 198
 199 ;;;###autoload
 200 (defun spam-report-process-queue (&optional file keep)
 201   "Report all queued requests from `spam-report-requests-file'.
 202
 203 If FILE is given, use it instead of `spam-report-requests-file'.
 204 If KEEP is t, leave old requests in the file.  If KEEP is the
 205 symbol `ask', query before flushing the queue file."
 206   (interactive
 207    (list (read-file-name
 208           "File: "
 209           (file-name-directory spam-report-requests-file)
 210           spam-report-requests-file
 211           nil
 212           (file-name-nondirectory spam-report-requests-file))
 213          current-prefix-arg))
 214   (if (eq spam-report-url-ping-function 'spam-report-url-to-file)
 215       (error (concat "Cannot process requests when "
 216                      "`spam-report-url-ping-function' is "
 217                      "`spam-report-url-to-file'."))
 218     (gnus-message 7 "Processing requests using `%s'."
 219                   spam-report-url-ping-function))
 220   (or file (setq file spam-report-requests-file))
 221   (save-excursion
 222     (set-buffer (find-file-noselect file))
 223     (goto-char (point-min))
 224     (while (and (not (eobp))
 225                 (re-search-forward
 226                  "http://\\([^/]+\\)\\(/.*\\) *$" (point-at-eol) t))
 227       (funcall spam-report-url-ping-function (match-string 1) (match-string 2))
 228       (forward-line 1))
 229     (if (or (eq keep nil)
 230             (and (eq keep 'ask)
 231                  (y-or-n-p
 232                   (format
 233                    "Flush requests from `%s'? " (current-buffer)))))
 234         (progn
 235           (gnus-message 7 "Flushing request file `%s'"
 236                         spam-report-requests-file)
 237           (erase-buffer)
 238           (save-buffer)
 239           (kill-buffer (current-buffer)))
 240       (gnus-message 7 "Keeping requests in `%s'" spam-report-requests-file))))
 241
 242 ;;;###autoload
 243 (defun spam-report-url-ping-mm-url (host report)
 244   "Ping a host through HTTP, addressing a specific GET resource. Use
 245 the external program specified in `mm-url-program' to connect to
 246 server."
 247   (with-temp-buffer
 248     (let ((url (format "http://%s%s" host report)))
 249       (mm-url-insert url t))))
 250
 251 ;;;###autoload
 252 (defun spam-report-url-to-file (host report)
 253   "Collect spam report requests in `spam-report-requests-file'.
 254 Customize `spam-report-url-ping-function' to use this function."
 255   (let ((url (format "http://%s%s" host report))
 256         (file spam-report-requests-file))
 257     (gnus-make-directory (file-name-directory file))
 258     (gnus-message 9 "Writing URL `%s' to file `%s'" url file)
 259     (with-temp-buffer
 260       (insert url)
 261       (newline)
 262       (append-to-file (point-min) (point-max) file))))
 263
 264 ;;;###autoload
 265 (defun spam-report-agentize ()
 266   "Add spam-report support to the Agent.
 267 Spam reports will be queued with \\[spam-report-url-to-file] when
 268 the Agent is unplugged, and will be submitted in a batch when the
 269 Agent is plugged."
 270   (interactive)
 271   (add-hook 'gnus-agent-plugged-hook 'spam-report-plug-agent)
 272   (add-hook 'gnus-agent-unplugged-hook 'spam-report-unplug-agent))
 273
 274 ;;;###autoload
 275 (defun spam-report-deagentize ()
 276   "Remove spam-report support from the Agent.
 277 Spam reports will be queued with the method used when
 278 \\[spam-report-agentize] was run."
 279   (interactive)
 280   (remove-hook 'gnus-agent-plugged-hook 'spam-report-plug-agent)
 281   (remove-hook 'gnus-agent-unplugged-hook 'spam-report-unplug-agent))
 282
 283 (defun spam-report-plug-agent ()
 284   "Adjust spam report settings for plugged state.
 285 Process queued spam reports."
 286   ;; Process the queue, unless the user only wanted to report to a file
 287   ;; anyway.
 288   (unless (equal spam-report-url-ping-temp-agent-function
 289                  'spam-report-url-to-file)
 290     (spam-report-process-queue))
 291   ;; Set the reporting function, if we have memorized something otherwise,
 292   ;; stick with plain URL reporting.
 293   (setq spam-report-url-ping-function
 294         (or spam-report-url-ping-temp-agent-function
 295             'spam-report-url-ping-plain)))
 296
 297 (defun spam-report-unplug-agent ()
 298   "Restore spam report settings for unplugged state."
 299   ;; save the old value
 300   (setq spam-report-url-ping-temp-agent-function
 301         spam-report-url-ping-function)
 302   ;; store all reports to file
 303   (setq spam-report-url-ping-function
 304         'spam-report-url-to-file))
 305
 306 (provide 'spam-report)
 307
 308 ;;; arch-tag: f6683295-ec89-4ab5-8803-8cc842293022
 309 ;;; spam-report.el ends here.