cgit.sxemacs.org Git - gnus/blob - lisp/spam-report.el

   1 ;;; spam-report.el --- Reporting spam
   2 ;; Copyright (C) 2002, 2003, 2004 Free Software Foundation, Inc.
   3
   4 ;; Author: Teodor Zlatanov <tzz@lifelogs.com>
   5 ;; Keywords: network
   6
   7 ;; This file is part of GNU Emacs.
   8
   9 ;; GNU Emacs is free software; you can redistribute it and/or modify
  10 ;; it under the terms of the GNU General Public License as published by
  11 ;; the Free Software Foundation; either version 2, or (at your option)
  12 ;; any later version.
  13
  14 ;; GNU Emacs is distributed in the hope that it will be useful,
  15 ;; but WITHOUT ANY WARRANTY; without even the implied warranty of
  16 ;; MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.  See the
  17 ;; GNU General Public License for more details.
  18
  19 ;; You should have received a copy of the GNU General Public License
  20 ;; along with GNU Emacs; see the file COPYING.  If not, write to the
  21 ;; Free Software Foundation, Inc., 59 Temple Place - Suite 330,
  22 ;; Boston, MA 02111-1307, USA.
  23
  24 ;;; Commentary:
  25
  26 ;;; This module addresses a few aspects of spam reporting under Gnus.  Page
  27 ;;; breaks are used for grouping declarations and documentation relating to
  28 ;;; each particular aspect.
  29
  30 ;;; Code:
  31 (require 'gnus)
  32 (require 'gnus-sum)
  33
  34 (eval-and-compile
  35   (autoload 'mm-url-insert "mm-url"))
  36
  37 (defgroup spam-report nil
  38   "Spam reporting configuration.")
  39
  40 (defcustom spam-report-gmane-regex nil
  41   "Regexp matching Gmane newsgroups, e.g. \"^nntp\\+.*:gmane\\.\"
  42 If you are using spam.el, consider setting gnus-spam-process-newsgroups
  43 or the gnus-group-spam-exit-processor-report-gmane group/topic parameter
  44 instead."
  45   :type '(radio (const nil)
  46                 (regexp :format "%t: %v\n" :size 0 :value "^nntp\+.*:gmane\."))
  47   :group 'spam-report)
  48
  49 (defcustom spam-report-gmane-spam-header
  50   "^X-Report-Spam: http://\\([^/]+\\)\\(.*\\)$"
  51   "String matching Gmane spam-reporting header.  Two match groups are needed."
  52   :type 'regexp
  53   :group 'spam-report)
  54
  55 (defcustom spam-report-gmane-use-article-number t
  56   "Whether the article number (faster!) or the header should be used."
  57   :type 'boolean
  58   :group 'spam-report)
  59
  60 (defcustom spam-report-url-ping-function
  61   'spam-report-url-ping-plain
  62   "Function to use for url ping spam reporting.
  63 The function must accept the arguments `host' and `report'."
  64   :type '(choice
  65           (const :tag "Connect directly"
  66                  spam-report-url-ping-plain)
  67           (const :tag "Use the external program specified in `mm-url-program'"
  68                  spam-report-url-ping-mm-url)
  69           (const :tag "Store request URLs in `spam-report-requests-file'"
  70                  spam-report-url-to-file)
  71           (function :tag "User defined function" nil))
  72   :group 'spam-report)
  73
  74 (defcustom spam-report-requests-file
  75   (nnheader-concat gnus-directory "spam/" "spam-report-requests.url")
  76   ;; Is there a convention for the extension of such a file?
  77   ;; Should we use `spam-directory'?
  78   "File where spam report request are stored."
  79   :type 'file
  80   :group 'spam-report)
  81
  82 (defvar spam-report-url-ping-temp-agent-function nil
  83   "This variable will store the value of
  84 spam-report-url-ping-function from before spam-report-agentize
  85 was run, so that spam-report-deagentize can undo that change.")
  86
  87 (defun spam-report-gmane (&rest articles)
  88   "Report an article as spam through Gmane"
  89   (dolist (article articles)
  90     (when (and gnus-newsgroup-name
  91                (or (null spam-report-gmane-regex)
  92                    (string-match spam-report-gmane-regex gnus-newsgroup-name)))
  93       (gnus-message 6 "Reporting spam article %d to spam.gmane.org..." article)
  94       (if spam-report-gmane-use-article-number
  95           (spam-report-url-ping "spam.gmane.org"
  96                                 (format "/%s:%d"
  97                                         (gnus-group-real-name gnus-newsgroup-name)
  98                                         article))
  99         (with-current-buffer nntp-server-buffer
 100           (gnus-request-head article gnus-newsgroup-name)
 101           (goto-char (point-min))
 102           (if (re-search-forward spam-report-gmane-spam-header nil t)
 103               (let* ((host (match-string 1))
 104                      (report (match-string 2))
 105                      (url (format "http://%s%s" host report)))
 106                 (gnus-message 7 "Reporting spam through URL %s..." url)
 107                 (spam-report-url-ping host report))
 108             (gnus-message 3 "Could not find X-Report-Spam in article %d..."
 109                           article)))))))
 110
 111 (defun spam-report-url-ping (host report)
 112   "Ping a host through HTTP, addressing a specific GET resource using
 113 the function specified by `spam-report-url-ping-function'."
 114   (funcall spam-report-url-ping-function host report))
 115
 116 (defun spam-report-url-ping-plain (host report)
 117   "Ping a host through HTTP, addressing a specific GET resource."
 118   (let ((tcp-connection))
 119     (with-temp-buffer
 120       (or (setq tcp-connection
 121                 (open-network-stream
 122                  "URL ping"
 123                  (buffer-name)
 124                  host
 125                  80))
 126           (error "Could not open connection to %s" host))
 127       (set-marker (process-mark tcp-connection) (point-min))
 128       (process-send-string
 129        tcp-connection
 130        (format "GET %s HTTP/1.1\nUser-Agent: %s (spam-report.el)\nHost: %s\n\n"
 131                report (gnus-emacs-version) host)))))
 132
 133 (defun spam-report-process-queue (&optional file keep)
 134   "Report all queued requests from `spam-report-requests-file'.
 135
 136 If FILE is given, use it instead of `spam-report-requests-file'.
 137 If KEEP is t, leave old requests in the file.  If KEEP is the
 138 symbol `ask', query before flushing the queue file."
 139   (interactive
 140    (list (read-file-name
 141           "File: "
 142           (file-name-directory spam-report-requests-file)
 143           spam-report-requests-file
 144           nil
 145           (file-name-nondirectory spam-report-requests-file)
 146           spam-report-requests-file)
 147          current-prefix-arg))
 148   (if (eq spam-report-url-ping-function 'spam-report-url-to-file)
 149       (error (concat "Cannot process requests when "
 150                      "`spam-report-url-ping-function' is "
 151                      "`spam-report-url-to-file'."))
 152     (gnus-message 7 "Processing requests using `%s'."
 153                   spam-report-url-ping-function))
 154   (or file (setq file spam-report-requests-file))
 155   (save-excursion
 156     (set-buffer (find-file-noselect file))
 157     (goto-char (point-min))
 158     (while (and (not (eobp))
 159                 (re-search-forward
 160                  "http://\\([^/]+\\)\\(/.*\\) *$" (point-at-eol) t))
 161       (funcall spam-report-url-ping-function (match-string 1) (match-string 2))
 162       (forward-line 1))
 163     (if (or (eq keep nil)
 164             (and (eq keep 'ask)
 165                  (y-or-n-p
 166                   (format
 167                    "Flush requests from `%s'? " (current-buffer)))))
 168         (progn
 169           (gnus-message 7 "Flushing request file `%s'"
 170                         spam-report-requests-file)
 171           (erase-buffer)
 172           (save-buffer)
 173           (kill-buffer (current-buffer)))
 174       (gnus-message 7 "Keeping requests in `%s'" spam-report-requests-file))))
 175
 176 (defun spam-report-url-ping-mm-url (host report)
 177   "Ping a host through HTTP, addressing a specific GET resource. Use
 178 the external program specified in `mm-url-program' to connect to
 179 server."
 180   (with-temp-buffer
 181     (let ((url (concat "http://" host report)))
 182       (mm-url-insert url t))))
 183
 184 (defun spam-report-url-to-file (host report)
 185   "Collect spam report requests in `spam-report-requests-file'.
 186 Customize `spam-report-url-ping-function' to use this function."
 187   (let ((url (concat "http://" host report))
 188         (file spam-report-requests-file))
 189     (gnus-make-directory (file-name-directory file))
 190     (gnus-message 9 "Writing URL `%s' to file `%s'" url file)
 191     (with-temp-buffer
 192       (insert url)
 193       (newline)
 194       (append-to-file (point-min) (point-max) file))))
 195
 196 (defun spam-report-agentize ()
 197   "Add spam-report support to the Agent.
 198 Spam reports will be queued with \\[spam-report-url-to-file] when
 199 the Agent is unplugged, and will be submitted in a batch when the
 200 Agent is plugged.."
 201   (interactive)
 202   (add-hook 'gnus-agent-plugged-hook 'spam-report-plug-agent)
 203   (add-hook 'gnus-agent-unplugged-hook 'spam-report-unplug-agent))
 204
 205 (defun spam-report-deagentize ()
 206   "Remove spam-report support from the Agent.
 207 Spam reports will be queued with the method used when
 208 \\[spam-report-agentize] was run."
 209   (interactive)
 210   (remove-hook 'gnus-agent-plugged-hook 'spam-report-plug-agent)
 211   (remove-hook 'gnus-agent-unplugged-hook 'spam-report-unplug-agent))
 212
 213 (defun spam-report-plug-agent ()
 214   ;; process the queue, unless the user only wanted to report to a file anyway
 215   (unless (equal spam-report-url-ping-temp-agent-function
 216                  spam-report-url-to-file)
 217     (spam-report-process-queue))
 218   ;; set the reporting function, if we have memorized something
 219   ;; otherwise, stick with plain URL reporting
 220   (setq spam-report-url-ping-function
 221         (or spam-report-url-ping-temp-agent-function
 222             spam-report-url-ping-plain)))
 223
 224 (defun spam-report-unplug-agent ()
 225   ;; save the old value
 226   (setq spam-report-url-ping-temp-agent-function
 227         spam-report-url-ping-function)
 228   ;; store all reports to file
 229   (setq spam-report-url-ping-function
 230         'spam-report-url-to-file))
 231
 232 (provide 'spam-report)
 233
 234 ;;; spam-report.el ends here.