cgit.sxemacs.org Git - gnus/blob - lisp/smiley-ems.el

   1 ;;; smiley-ems.el --- displaying smiley faces
   2
   3 ;; Copyright (C) 2000, 2001 Free Software Foundation, Inc.
   4
   5 ;; Author: Dave Love <fx@gnu.org>
   6 ;; Keywords: news mail multimedia
   7
   8 ;; This file is part of GNU Emacs.
   9
  10 ;; GNU Emacs is free software; you can redistribute it and/or modify
  11 ;; it under the terms of the GNU General Public License as published by
  12 ;; the Free Software Foundation; either version 2, or (at your option)
  13 ;; any later version.
  14
  15 ;; GNU Emacs is distributed in the hope that it will be useful,
  16 ;; but WITHOUT ANY WARRANTY; without even the implied warranty of
  17 ;; MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.  See the
  18 ;; GNU General Public License for more details.
  19
  20 ;; You should have received a copy of the GNU General Public License
  21 ;; along with GNU Emacs; see the file COPYING.  If not, write to the
  22 ;; Free Software Foundation, Inc., 59 Temple Place - Suite 330,
  23 ;; Boston, MA 02111-1307, USA.
  24
  25 ;;; Commentary:
  26
  27 ;; A re-written, simplified version of Wes Hardaker's XEmacs smiley.el
  28 ;; which might be merged back to smiley.el if we get an assignment for
  29 ;; that.  We don't have assignments for the images smiley.el uses, but
  30 ;; I'm not sure we need that degree of rococoness and defaults like a
  31 ;; yellow background.  Also, using PBM means we can display the images
  32 ;; more generally.  -- fx
  33
  34 ;;; Test smileys:  :-) :-\ :-( :-/
  35
  36 ;;; Code:
  37
  38 (eval-when-compile (require 'cl))
  39 (require 'nnheader)
  40
  41 (defgroup smiley nil
  42   "Turn :-)'s into real images."
  43   :group 'gnus-visual)
  44
  45 ;; Maybe this should go.
  46 (defcustom smiley-data-directory (nnheader-find-etc-directory "smilies")
  47   "*Location of the smiley faces files."
  48   :type 'directory
  49   :group 'smiley)
  50
  51 ;; The XEmacs version has a baroque, if not rococo, set of these.
  52 (defcustom smiley-regexp-alist
  53   '(("\\(:-?)\\)\\W" 1 "smile")
  54     ("\\(;-?)\\)\\W" 1 "blink")
  55     ("\\(:-]\\)\\W" 1 "forced")
  56     ("\\(8-)\\)\\W" 1 "braindamaged")
  57     ("\\(:-|\\)\\W" 1 "indifferent")
  58     ("\\(:-[/\\]\\)\\W" 1 "wry")
  59     ("\\(:-(\\)\\W" 1 "sad")
  60     ("\\(:-{\\)\\W" 1 "frown"))
  61   "*A list of regexps to map smilies to images.
  62 The elements are (REGEXP MATCH FILE), where MATCH is the submatch in
  63 regexp to replace with IMAGE.  IMAGE is the name of a PBM file in
  64 `smiley-data-directory'."
  65   :type '(repeat (list regexp
  66                        (integer :tag "Regexp match number")
  67                        (string :tag "Image name")))
  68   :set (lambda (symbol value)
  69          (set-default symbol value)
  70          (smiley-update-cache))
  71   :initialize 'custom-initialize-default
  72   :group 'smiley)
  73
  74 (defcustom gnus-smiley-file-types
  75   (let ((types (list "pbm")))
  76     (when (gnus-image-type-available-p 'xpm)
  77       (push "xpm" types))
  78     types)
  79   "*List of suffixes on picon file names to try."
  80   :type '(repeat string)
  81   :group 'smiley)
  82
  83 (defvar smiley-cached-regexp-alist nil)
  84
  85 (defun smiley-update-cache ()
  86   (dolist (elt (if (symbolp smiley-regexp-alist)
  87                    (symbol-value smiley-regexp-alist)
  88                  smiley-regexp-alist))
  89     (let ((types gnus-smiley-file-types)
  90           file type)
  91       (while (and (not file)
  92                   (setq type (pop types)))
  93         (unless (file-exists-p
  94                (setq file (expand-file-name (concat (nth 2 elt) "." type)
  95                                             smiley-data-directory)))
  96           (setq file nil)))
  97       (let ((image (find-image (list (list :type (intern type)
  98                                            :file file
  99                                            :ascent 'center)))))
 100         (when image
 101           (push (list (car elt) (cadr elt) image)
 102                 smiley-cached-regexp-alist))))))
 103
 104 (defvar smiley-active nil
 105   "Non-nil means smilies in the buffer will be displayed.")
 106 (make-variable-buffer-local 'smiley-active)
 107
 108 (defvar smiley-mouse-map
 109   (let ((map (make-sparse-keymap)))
 110     (define-key map [down-mouse-2] 'ignore) ; override widget
 111     (define-key map [mouse-2]
 112       'smiley-mouse-toggle-buffer)
 113     map))
 114
 115 ;;;###autoload
 116 (defun smiley-region (start end)
 117   "Replace in the region `smiley-regexp-alist' matches with corresponding images."
 118   (interactive "r")
 119   (when (and (fboundp 'display-graphic-p)
 120              (display-graphic-p))
 121     (mapcar (lambda (o)
 122               (if (eq 'smiley (overlay-get o 'smiley))
 123                   (delete-overlay o)))
 124             (overlays-in start end))
 125     (unless smiley-cached-regexp-alist
 126       (smiley-update-cache))
 127     (save-excursion
 128       (let ((beg (or start (point-min)))
 129             group overlay image)
 130         (dolist (entry smiley-cached-regexp-alist)
 131           (setq group (nth 1 entry)
 132                 image (nth 2 entry))
 133           (goto-char beg)
 134           (while (re-search-forward (car entry) end t)
 135             (when image
 136               (setq overlay (make-overlay (match-beginning group)
 137                                           (match-end group)))
 138               (overlay-put overlay
 139                            'display `(when smiley-active ,@image))
 140               (overlay-put overlay 'mouse-face 'highlight)
 141               (overlay-put overlay 'smiley t)
 142               (overlay-put overlay
 143                            'help-echo "mouse-2: toggle smilies in buffer")
 144               (overlay-put overlay 'keymap smiley-mouse-map))))))
 145     (setq smiley-active t)))
 146
 147 (defun smiley-toggle-buffer (&optional arg)
 148   "Toggle displaying smiley faces.
 149 With arg, turn displaying on if and only if arg is positive."
 150   (interactive "P")
 151   (if (numberp arg)
 152       (setq smiley-active (> arg 0))
 153     (setq smiley-active (not smiley-active))))
 154
 155 (defun smiley-mouse-toggle-buffer (event)
 156   "Toggle displaying smiley faces.
 157 With arg, turn displaying on if and only if arg is positive."
 158   (interactive "e")
 159   (save-excursion
 160     (save-window-excursion
 161       (mouse-set-point event)
 162       (smiley-toggle-buffer))))
 163
 164 (eval-when-compile (defvar gnus-article-buffer))
 165
 166 (defun gnus-smiley-display (&optional arg)
 167   "Display textual emoticaons (\"smilies\") as small graphical icons.
 168 With arg, turn displaying on if and only if arg is positive."
 169   (interactive "P")
 170   (save-excursion
 171     (article-goto-body)
 172     (smiley-region (point) (point-max))
 173     (if (and (numberp arg) (<= arg 0))
 174         (smiley-toggle-buffer arg))))
 175
 176 (provide 'smiley)
 177
 178 ;;; smiley-ems.el ends here