cgit.sxemacs.org Git - gnus/blob - lisp/shr.el

   1 ;;; shr.el --- Simple HTML Renderer
   2
   3 ;; Copyright (C) 2010 Free Software Foundation, Inc.
   4
   5 ;; Author: Lars Magne Ingebrigtsen <larsi@gnus.org>
   6 ;; Keywords: html
   7
   8 ;; This file is part of GNU Emacs.
   9
  10 ;; GNU Emacs is free software: you can redistribute it and/or modify
  11 ;; it under the terms of the GNU General Public License as published by
  12 ;; the Free Software Foundation, either version 3 of the License, or
  13 ;; (at your option) any later version.
  14
  15 ;; GNU Emacs is distributed in the hope that it will be useful,
  16 ;; but WITHOUT ANY WARRANTY; without even the implied warranty of
  17 ;; MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.  See the
  18 ;; GNU General Public License for more details.
  19
  20 ;; You should have received a copy of the GNU General Public License
  21 ;; along with GNU Emacs.  If not, see <http://www.gnu.org/licenses/>.
  22
  23 ;;; Commentary:
  24
  25 ;; This package takes a HTML parse tree (as provided by
  26 ;; libxml-parse-html-region) and renders it in the current buffer.  It
  27 ;; does not do CSS, JavaScript or anything advanced: It's geared
  28 ;; towards rendering typical short snippets of HTML, like what you'd
  29 ;; find in HTML email and the like.
  30
  31 ;;; Code:
  32
  33 (eval-when-compile (require 'cl))
  34 (require 'browse-url)
  35
  36 (defgroup shr nil
  37   "Simple HTML Renderer"
  38   :group 'mail)
  39
  40 (defcustom shr-max-image-proportion 0.9
  41   "How big pictures displayed are in relation to the window they're in.
  42 A value of 0.7 means that they are allowed to take up 70% of the
  43 width and height of the window.  If they are larger than this,
  44 and Emacs supports it, then the images will be rescaled down to
  45 fit these criteria."
  46   :version "24.1"
  47   :group 'shr
  48   :type 'float)
  49
  50 (defcustom shr-blocked-images nil
  51   "Images that have URLs matching this regexp will be blocked."
  52   :version "24.1"
  53   :group 'shr
  54   :type 'regexp)
  55
  56 (defcustom shr-table-horizontal-line ?-
  57   "Character used to draw horizontal table lines."
  58   :group 'shr
  59   :type 'character)
  60
  61 (defcustom shr-table-vertical-line ?|
  62   "Character used to draw vertical table lines."
  63   :group 'shr
  64   :type 'character)
  65
  66 (defcustom shr-table-corner ?+
  67   "Character used to draw table corners."
  68   :group 'shr
  69   :type 'character)
  70
  71 (defcustom shr-hr-line ?-
  72   "Character used to draw hr lines."
  73   :group 'shr
  74   :type 'character)
  75
  76 (defcustom shr-width fill-column
  77   "Frame width to use for rendering."
  78   :type 'integer
  79   :group 'shr)
  80
  81 (defvar shr-content-function nil
  82   "If bound, this should be a function that will return the content.
  83 This is used for cid: URLs, and the function is called with the
  84 cid: URL as the argument.")
  85
  86 ;;; Internal variables.
  87
  88 (defvar shr-folding-mode nil)
  89 (defvar shr-state nil)
  90 (defvar shr-start nil)
  91 (defvar shr-indentation 0)
  92 (defvar shr-inhibit-images nil)
  93 (defvar shr-list-mode nil)
  94 (defvar shr-content-cache nil)
  95 (defvar shr-kinsoku-shorten nil)
  96 (defvar shr-table-depth 0)
  97 (defvar shr-stylesheet nil)
  98
  99 (defvar shr-map
 100   (let ((map (make-sparse-keymap)))
 101     (define-key map "a" 'shr-show-alt-text)
 102     (define-key map "i" 'shr-browse-image)
 103     (define-key map "I" 'shr-insert-image)
 104     (define-key map "u" 'shr-copy-url)
 105     (define-key map "v" 'shr-browse-url)
 106     (define-key map "o" 'shr-save-contents)
 107     (define-key map "\r" 'shr-browse-url)
 108     map))
 109
 110 ;; Public functions and commands.
 111
 112 ;;;###autoload
 113 (defun shr-insert-document (dom)
 114   (setq shr-content-cache nil)
 115   (let ((shr-state nil)
 116         (shr-start nil))
 117     (shr-descend (shr-transform-dom dom))))
 118
 119 (defun shr-copy-url ()
 120   "Copy the URL under point to the kill ring.
 121 If called twice, then try to fetch the URL and see whether it
 122 redirects somewhere else."
 123   (interactive)
 124   (let ((url (get-text-property (point) 'shr-url)))
 125     (cond
 126      ((not url)
 127       (message "No URL under point"))
 128      ;; Resolve redirected URLs.
 129      ((equal url (car kill-ring))
 130       (url-retrieve
 131        url
 132        (lambda (a)
 133          (when (and (consp a)
 134                     (eq (car a) :redirect))
 135            (with-temp-buffer
 136              (insert (cadr a))
 137              (goto-char (point-min))
 138              ;; Remove common tracking junk from the URL.
 139              (when (re-search-forward ".utm_.*" nil t)
 140                (replace-match "" t t))
 141              (message "Copied %s" (buffer-string))
 142              (copy-region-as-kill (point-min) (point-max)))))))
 143      ;; Copy the URL to the kill ring.
 144      (t
 145       (with-temp-buffer
 146         (insert url)
 147         (copy-region-as-kill (point-min) (point-max))
 148         (message "Copied %s" url))))))
 149
 150 (defun shr-show-alt-text ()
 151   "Show the ALT text of the image under point."
 152   (interactive)
 153   (let ((text (get-text-property (point) 'shr-alt)))
 154     (if (not text)
 155         (message "No image under point")
 156       (message "%s" text))))
 157
 158 (defun shr-browse-image ()
 159   "Browse the image under point."
 160   (interactive)
 161   (let ((url (get-text-property (point) 'image-url)))
 162     (if (not url)
 163         (message "No image under point")
 164       (message "Browsing %s..." url)
 165       (browse-url url))))
 166
 167 (defun shr-insert-image ()
 168   "Insert the image under point into the buffer."
 169   (interactive)
 170   (let ((url (get-text-property (point) 'image-url)))
 171     (if (not url)
 172         (message "No image under point")
 173       (message "Inserting %s..." url)
 174       (url-retrieve url 'shr-image-fetched
 175                     (list (current-buffer) (1- (point)) (point-marker))
 176                     t))))
 177
 178 ;;; Utility functions.
 179
 180 (defun shr-transform-dom (dom)
 181   (let ((result (list (pop dom))))
 182     (dolist (arg (pop dom))
 183       (push (cons (intern (concat ":" (symbol-name (car arg))) obarray)
 184                   (cdr arg))
 185             result))
 186     (dolist (sub dom)
 187       (if (stringp sub)
 188           (push (cons 'text sub) result)
 189         (push (shr-transform-dom sub) result)))
 190     (nreverse result)))
 191
 192 (defun shr-descend (dom)
 193   (let ((function (intern (concat "shr-tag-" (symbol-name (car dom))) obarray))
 194         (style (cdr (assq :style (cdr dom))))
 195         (shr-stylesheet shr-stylesheet)
 196         (start (point)))
 197     (when (and style
 198                (string-match "color" style))
 199       (setq shr-stylesheet (nconc (shr-parse-style style)
 200                                   shr-stylesheet)))
 201     (if (fboundp function)
 202         (funcall function (cdr dom))
 203       (shr-generic (cdr dom)))
 204     (let ((color (cdr (assq 'color shr-stylesheet)))
 205           (background (cdr (assq 'background-color
 206                                  shr-stylesheet))))
 207       (when (and shr-stylesheet
 208                  (or color background))
 209         (shr-colorize-region start (point) color background)))))
 210
 211 (defun shr-generic (cont)
 212   (dolist (sub cont)
 213     (cond
 214      ((eq (car sub) 'text)
 215       (shr-insert (cdr sub)))
 216      ((listp (cdr sub))
 217       (shr-descend sub)))))
 218
 219 (defmacro shr-char-breakable-p (char)
 220   "Return non-nil if a line can be broken before and after CHAR."
 221   `(aref fill-find-break-point-function-table ,char))
 222 (defmacro shr-char-nospace-p (char)
 223   "Return non-nil if no space is required before and after CHAR."
 224   `(aref fill-nospace-between-words-table ,char))
 225
 226 ;; KINSOKU is a Japanese word meaning a rule that should not be violated.
 227 ;; In Emacs, it is a term used for characters, e.g. punctuation marks,
 228 ;; parentheses, and so on, that should not be placed in the beginning
 229 ;; of a line or the end of a line.
 230 (defmacro shr-char-kinsoku-bol-p (char)
 231   "Return non-nil if a line ought not to begin with CHAR."
 232   `(aref (char-category-set ,char) ?>))
 233 (defmacro shr-char-kinsoku-eol-p (char)
 234   "Return non-nil if a line ought not to end with CHAR."
 235   `(aref (char-category-set ,char) ?<))
 236 (unless (shr-char-kinsoku-bol-p (make-char 'japanese-jisx0208 33 35))
 237   (load "kinsoku" nil t))
 238
 239 (defun shr-insert (text)
 240   (when (and (eq shr-state 'image)
 241              (not (string-match "\\`[ \t\n]+\\'" text)))
 242     (insert "\n")
 243     (setq shr-state nil))
 244   (cond
 245    ((eq shr-folding-mode 'none)
 246     (insert text))
 247    (t
 248     (when (and (string-match "\\`[ \t\n]" text)
 249                (not (bolp))
 250                (not (eq (char-after (1- (point))) ? )))
 251       (insert " "))
 252     (dolist (elem (split-string text))
 253       (when (and (bolp)
 254                  (> shr-indentation 0))
 255         (shr-indent))
 256       ;; The shr-start is a special variable that is used to pass
 257       ;; upwards the first point in the buffer where the text really
 258       ;; starts.
 259       (unless shr-start
 260         (setq shr-start (point)))
 261       ;; No space is needed behind a wide character categorized as
 262       ;; kinsoku-bol, between characters both categorized as nospace,
 263       ;; or at the beginning of a line.
 264       (let (prev)
 265         (when (and (eq (preceding-char) ? )
 266                    (or (= (line-beginning-position) (1- (point)))
 267                        (and (shr-char-breakable-p
 268                              (setq prev (char-after (- (point) 2))))
 269                             (shr-char-kinsoku-bol-p prev))
 270                        (and (shr-char-nospace-p prev)
 271                             (shr-char-nospace-p (aref elem 0)))))
 272           (delete-char -1)))
 273       (insert elem)
 274       (let (found)
 275         (while (and (> (current-column) shr-width)
 276                     (progn
 277                       (setq found (shr-find-fill-point))
 278                       (not (eolp))))
 279           (when (eq (preceding-char) ? )
 280             (delete-char -1))
 281           (insert "\n")
 282           (unless found
 283             (put-text-property (1- (point)) (point) 'shr-break t)
 284             ;; No space is needed at the beginning of a line.
 285             (when (eq (following-char) ? )
 286               (delete-char 1)))
 287           (when (> shr-indentation 0)
 288             (shr-indent))
 289           (end-of-line))
 290         (insert " ")))
 291     (unless (string-match "[ \t\n]\\'" text)
 292       (delete-char -1)))))
 293
 294 (defun shr-find-fill-point ()
 295   (when (> (move-to-column shr-width) shr-width)
 296     (backward-char 1))
 297   (let ((bp (point))
 298         failed)
 299     (while (not (or (setq failed (= (current-column) shr-indentation))
 300                     (eq (preceding-char) ? )
 301                     (eq (following-char) ? )
 302                     (shr-char-breakable-p (preceding-char))
 303                     (shr-char-breakable-p (following-char))
 304                     (and (eq (preceding-char) ?')
 305                          (not (memq (char-after (- (point) 2))
 306                                     (list nil ?\n ? ))))
 307                     ;; There're some kinsoku CJK chars that aren't breakable.
 308                     (and (shr-char-kinsoku-bol-p (preceding-char))
 309                          (not (shr-char-kinsoku-bol-p (following-char))))
 310                     (shr-char-kinsoku-eol-p (following-char))))
 311       (backward-char 1))
 312     (if (and (not (or failed (eolp)))
 313              (eq (preceding-char) ?'))
 314         (while (not (or (setq failed (eolp))
 315                         (eq (following-char) ? )
 316                         (shr-char-breakable-p (following-char))
 317                         (shr-char-kinsoku-eol-p (following-char))))
 318           (forward-char 1)))
 319     (if failed
 320         ;; There's no breakable point, so we give it up.
 321         (let (found)
 322           (goto-char bp)
 323           (unless shr-kinsoku-shorten
 324             (while (and (setq found (re-search-forward
 325                                      "\\(\\c>\\)\\| \\|\\c<\\|\\c|"
 326                                      (line-end-position) 'move))
 327                         (eq (preceding-char) ?')))
 328             (if (and found (not (match-beginning 1)))
 329                 (goto-char (match-beginning 0)))))
 330       (or
 331        (eolp)
 332        ;; Don't put kinsoku-bol characters at the beginning of a line,
 333        ;; or kinsoku-eol characters at the end of a line.
 334        (cond
 335         (shr-kinsoku-shorten
 336          (while (and (not (memq (preceding-char) (list ?\C-@ ?\n ? )))
 337                      (shr-char-kinsoku-eol-p (preceding-char)))
 338            (backward-char 1))
 339          (when (setq failed (= (current-column) shr-indentation))
 340            ;; There's no breakable point that doesn't violate kinsoku,
 341            ;; so we look for the second best position.
 342            (while (and (progn
 343                          (forward-char 1)
 344                          (<= (current-column) shr-width))
 345                        (progn
 346                          (setq bp (point))
 347                          (shr-char-kinsoku-eol-p (following-char)))))
 348            (goto-char bp)))
 349         ((shr-char-kinsoku-eol-p (preceding-char))
 350          (if (shr-char-kinsoku-eol-p (following-char))
 351              ;; There are consecutive kinsoku-eol characters.
 352              (setq failed t)
 353            (let ((count 4))
 354              (while
 355                  (progn
 356                    (backward-char 1)
 357                    (and (> (setq count (1- count)) 0)
 358                         (not (memq (preceding-char) (list ?\C-@ ?\n ? )))
 359                         (or (shr-char-kinsoku-eol-p (preceding-char))
 360                             (shr-char-kinsoku-bol-p (following-char)))))))
 361            (if (setq failed (= (current-column) shr-indentation))
 362                ;; There's no breakable point that doesn't violate kinsoku,
 363                ;; so we go to the second best position.
 364                (if (looking-at "\\(\\c<+\\)\\c<")
 365                    (goto-char (match-end 1))
 366                  (forward-char 1)))))
 367         (t
 368          (if (shr-char-kinsoku-bol-p (preceding-char))
 369              ;; There are consecutive kinsoku-bol characters.
 370              (setq failed t)
 371            (let ((count 4))
 372              (while (and (>= (setq count (1- count)) 0)
 373                          (shr-char-kinsoku-bol-p (following-char))
 374                          (shr-char-breakable-p (following-char)))
 375                (forward-char 1))))))
 376        (when (eq (following-char) ? )
 377          (forward-char 1))))
 378     (not failed)))
 379
 380 (defun shr-ensure-newline ()
 381   (unless (zerop (current-column))
 382     (insert "\n")))
 383
 384 (defun shr-ensure-paragraph ()
 385   (unless (bobp)
 386     (if (<= (current-column) shr-indentation)
 387         (unless (save-excursion
 388                   (forward-line -1)
 389                   (looking-at " *$"))
 390           (insert "\n"))
 391       (if (save-excursion
 392             (beginning-of-line)
 393             (looking-at " *$"))
 394           (insert "\n")
 395         (insert "\n\n")))))
 396
 397 (defun shr-indent ()
 398   (when (> shr-indentation 0)
 399     (insert (make-string shr-indentation ? ))))
 400
 401 (defun shr-fontize-cont (cont &rest types)
 402   (let (shr-start)
 403     (shr-generic cont)
 404     (dolist (type types)
 405       (shr-add-font (or shr-start (point)) (point) type))))
 406
 407 ;; Add an overlay in the region, but avoid putting the font properties
 408 ;; on blank text at the start of the line, and the newline at the end,
 409 ;; to avoid ugliness.
 410 (defun shr-add-font (start end type)
 411   (save-excursion
 412     (goto-char start)
 413     (while (< (point) end)
 414       (when (bolp)
 415         (skip-chars-forward " "))
 416       (let ((overlay (make-overlay (point) (min (line-end-position) end))))
 417         (overlay-put overlay 'face type))
 418       (if (< (line-end-position) end)
 419           (forward-line 1)
 420         (goto-char end)))))
 421
 422 (defun shr-browse-url ()
 423   "Browse the URL under point."
 424   (interactive)
 425   (let ((url (get-text-property (point) 'shr-url)))
 426     (cond
 427      ((not url)
 428       (message "No link under point"))
 429      ((string-match "^mailto:" url)
 430       (browse-url-mailto url))
 431      (t
 432       (browse-url url)))))
 433
 434 (defun shr-save-contents (directory)
 435   "Save the contents from URL in a file."
 436   (interactive "DSave contents of URL to directory: ")
 437   (let ((url (get-text-property (point) 'shr-url)))
 438     (if (not url)
 439         (message "No link under point")
 440       (url-retrieve (shr-encode-url url)
 441                     'shr-store-contents (list url directory)))))
 442
 443 (defun shr-store-contents (status url directory)
 444   (unless (plist-get status :error)
 445     (when (or (search-forward "\n\n" nil t)
 446               (search-forward "\r\n\r\n" nil t))
 447       (write-region (point) (point-max)
 448                     (expand-file-name (file-name-nondirectory url)
 449                                       directory)))))
 450
 451 (defun shr-image-fetched (status buffer start end)
 452   (when (and (buffer-name buffer)
 453              (not (plist-get status :error)))
 454     (url-store-in-cache (current-buffer))
 455     (when (or (search-forward "\n\n" nil t)
 456               (search-forward "\r\n\r\n" nil t))
 457       (let ((data (buffer-substring (point) (point-max))))
 458         (with-current-buffer buffer
 459           (let ((alt (buffer-substring start end))
 460                 (inhibit-read-only t))
 461             (delete-region start end)
 462             (goto-char start)
 463             (shr-put-image data alt))))))
 464   (kill-buffer (current-buffer)))
 465
 466 (defun shr-put-image (data alt)
 467   (if (display-graphic-p)
 468       (let ((image (ignore-errors
 469                      (shr-rescale-image data))))
 470         (when image
 471           ;; When inserting big-ish pictures, put them at the
 472           ;; beginning of the line.
 473           (when (and (> (current-column) 0)
 474                      (> (car (image-size image t)) 400))
 475             (insert "\n"))
 476           (insert-image image (or alt "*"))))
 477     (insert alt)))
 478
 479 (defun shr-rescale-image (data)
 480   (if (or (not (fboundp 'imagemagick-types))
 481           (not (get-buffer-window (current-buffer))))
 482       (create-image data nil t)
 483     (let* ((image (create-image data nil t))
 484            (size (image-size image t))
 485            (width (car size))
 486            (height (cdr size))
 487            (edges (window-inside-pixel-edges
 488                    (get-buffer-window (current-buffer))))
 489            (window-width (truncate (* shr-max-image-proportion
 490                                       (- (nth 2 edges) (nth 0 edges)))))
 491            (window-height (truncate (* shr-max-image-proportion
 492                                        (- (nth 3 edges) (nth 1 edges)))))
 493            scaled-image)
 494       (when (> height window-height)
 495         (setq image (or (create-image data 'imagemagick t
 496                                       :height window-height)
 497                         image))
 498         (setq size (image-size image t)))
 499       (when (> (car size) window-width)
 500         (setq image (or
 501                      (create-image data 'imagemagick t
 502                                    :width window-width)
 503                      image)))
 504       image)))
 505
 506 ;; url-cache-extract autoloads url-cache.
 507 (declare-function url-cache-create-filename "url-cache" (url))
 508 (autoload 'mm-disable-multibyte "mm-util")
 509 (autoload 'browse-url-mailto "browse-url")
 510
 511 (defun shr-get-image-data (url)
 512   "Get image data for URL.
 513 Return a string with image data."
 514   (with-temp-buffer
 515     (mm-disable-multibyte)
 516     (when (ignore-errors
 517             (url-cache-extract (url-cache-create-filename (shr-encode-url url)))
 518             t)
 519       (when (or (search-forward "\n\n" nil t)
 520                 (search-forward "\r\n\r\n" nil t))
 521         (buffer-substring (point) (point-max))))))
 522
 523 (defun shr-image-displayer (content-function)
 524   "Return a function to display an image.
 525 CONTENT-FUNCTION is a function to retrieve an image for a cid url that
 526 is an argument.  The function to be returned takes three arguments URL,
 527 START, and END."
 528   `(lambda (url start end)
 529      (when url
 530        (if (string-match "\\`cid:" url)
 531            ,(when content-function
 532               `(let ((image (funcall ,content-function
 533                                      (substring url (match-end 0)))))
 534                  (when image
 535                    (goto-char start)
 536                    (shr-put-image image
 537                                   (prog1
 538                                       (buffer-substring-no-properties start end)
 539                                     (delete-region start end))))))
 540          (url-retrieve url 'shr-image-fetched
 541                        (list (current-buffer) start end)
 542                        t)))))
 543
 544 (defun shr-heading (cont &rest types)
 545   (shr-ensure-paragraph)
 546   (apply #'shr-fontize-cont cont types)
 547   (shr-ensure-paragraph))
 548
 549 (autoload 'widget-convert-button "wid-edit")
 550
 551 (defun shr-urlify (start url &optional title)
 552   (widget-convert-button
 553    'url-link start (point)
 554    :help-echo (if title (format "%s (%s)" url title) url)
 555    :keymap shr-map
 556    url)
 557   (put-text-property start (point) 'shr-url url))
 558
 559 (defun shr-encode-url (url)
 560   "Encode URL."
 561   (browse-url-url-encode-chars url "[)$ ]"))
 562
 563 (autoload 'shr-color-visible "shr-color")
 564 (autoload 'shr-color->hexadecimal "shr-color")
 565
 566 (defun shr-color-check (fg bg)
 567   "Check that FG is visible on BG.
 568 Returns (fg bg) with corrected values.
 569 Returns nil if the colors that would be used are the default
 570 ones, in case fg and bg are nil."
 571   (when (or fg bg)
 572     (let ((fixed (cond ((null fg) 'fg)
 573                        ((null bg) 'bg))))
 574       ;; Convert colors to hexadecimal, or set them to default.
 575       (let ((fg (or (shr-color->hexadecimal fg)
 576                     (frame-parameter nil 'foreground-color)))
 577             (bg (or (shr-color->hexadecimal bg)
 578                     (frame-parameter nil 'background-color))))
 579         (cond ((eq fixed 'bg)
 580                ;; Only return the new fg
 581                (list nil (cadr (shr-color-visible bg fg t))))
 582               ((eq fixed 'fg)
 583                ;; Invert args and results and return only the new bg
 584                (list (cadr (shr-color-visible fg bg t)) nil))
 585               (t
 586                (shr-color-visible bg fg)))))))
 587
 588 (defun shr-colorize-region (start end fg &optional bg)
 589   (when fg
 590     (let ((new-colors
 591            (shr-color-check fg (or bg
 592                                    (frame-parameter nil 'background-color)))))
 593       (when new-colors
 594         (shr-put-color start end :foreground (cadr new-colors))
 595         (when bg
 596           (shr-put-color start end :background (car new-colors)))))))
 597
 598 ;; Put a color in the region, but avoid putting colors on on blank
 599 ;; text at the start of the line, and the newline at the end, to avoid
 600 ;; ugliness.  Also, don't overwrite any existing color information,
 601 ;; since this can be called recursively, and we want the "inner" color
 602 ;; to win.
 603 (defun shr-put-color (start end type color)
 604   (save-excursion
 605     (goto-char start)
 606     (while (< (point) end)
 607       (when (bolp)
 608         (skip-chars-forward " "))
 609       (when (> (line-end-position) (point))
 610         (shr-put-color-1 (point) (min (line-end-position) end) type color))
 611       (if (< (line-end-position) end)
 612           (forward-line 1)
 613         (goto-char end)))))
 614
 615 (defun shr-put-color-1 (start end type color)
 616   (let* ((old-props (get-text-property start 'face))
 617          (do-put (not (memq type old-props)))
 618          change)
 619     (while (< start end)
 620       (setq change (next-single-property-change start 'face nil end))
 621       (when do-put
 622         (put-text-property start change 'face
 623                            (nconc (list type color) old-props)))
 624       (setq old-props (get-text-property change 'face))
 625       (setq do-put (not (memq type old-props)))
 626       (setq start change))
 627     (when (and do-put
 628                (> end start))
 629       (put-text-property start end 'face
 630                          (nconc (list type color old-props))))))
 631
 632 ;;; Tag-specific rendering rules.
 633
 634 (defun shr-tag-body (cont)
 635   (let* ((start (point))
 636          (fgcolor (cdr (assq :fgcolor cont)))
 637          (bgcolor (cdr (assq :bgcolor cont)))
 638          (shr-stylesheet (list (cons :color fgcolor)
 639                                (cons :background-color bgcolor))))
 640     (shr-generic cont)
 641     (shr-colorize-region start (point) fgcolor bgcolor)))
 642
 643 (defun shr-tag-p (cont)
 644   (shr-ensure-paragraph)
 645   (shr-indent)
 646   (shr-generic cont)
 647   (shr-ensure-paragraph))
 648
 649 (defun shr-tag-div (cont)
 650   (shr-ensure-newline)
 651   (shr-indent)
 652   (shr-generic cont)
 653   (shr-ensure-newline))
 654
 655 (defun shr-tag-b (cont)
 656   (shr-fontize-cont cont 'bold))
 657
 658 (defun shr-tag-i (cont)
 659   (shr-fontize-cont cont 'italic))
 660
 661 (defun shr-tag-em (cont)
 662   (shr-fontize-cont cont 'bold))
 663
 664 (defun shr-tag-strong (cont)
 665   (shr-fontize-cont cont 'bold))
 666
 667 (defun shr-tag-u (cont)
 668   (shr-fontize-cont cont 'underline))
 669
 670 (defun shr-tag-s (cont)
 671   (shr-fontize-cont cont 'strike-through))
 672
 673 (defun shr-parse-style (style)
 674   (when style
 675     (save-match-data
 676       (when (string-match "\n" style)
 677         (setq style (replace-match " " t t style))))
 678     (let ((plist nil))
 679       (dolist (elem (split-string style ";"))
 680         (when elem
 681           (setq elem (split-string elem ":"))
 682           (when (and (car elem)
 683                      (cadr elem))
 684             (let ((name (replace-regexp-in-string "^ +\\| +$" "" (car elem)))
 685                   (value (replace-regexp-in-string "^ +\\| +$" "" (cadr elem))))
 686               (when (string-match " *!important\\'" value)
 687                 (setq value (substring value 0 (match-beginning 0))))
 688               (push (cons (intern name obarray)
 689                           value)
 690                     plist)))))
 691       plist)))
 692
 693 (defun shr-tag-a (cont)
 694   (let ((url (cdr (assq :href cont)))
 695         (title (cdr (assq :title cont)))
 696         (start (point))
 697         shr-start)
 698     (shr-generic cont)
 699     (shr-urlify (or shr-start start) url title)))
 700
 701 (defun shr-tag-object (cont)
 702   (let ((start (point))
 703         url)
 704     (dolist (elem cont)
 705       (when (eq (car elem) 'embed)
 706         (setq url (or url (cdr (assq :src (cdr elem))))))
 707       (when (and (eq (car elem) 'param)
 708                  (equal (cdr (assq :name (cdr elem))) "movie"))
 709         (setq url (or url (cdr (assq :value (cdr elem)))))))
 710     (when url
 711       (shr-insert " [multimedia] ")
 712       (shr-urlify start url))
 713     (shr-generic cont)))
 714
 715 (defun shr-tag-video (cont)
 716   (let ((image (cdr (assq :poster cont)))
 717         (url (cdr (assq :src cont)))
 718         (start (point)))
 719     (shr-tag-img nil image)
 720     (shr-urlify start url)))
 721
 722 (defun shr-tag-img (cont &optional url)
 723   (when (or url
 724             (and cont
 725                  (cdr (assq :src cont))))
 726     (when (and (> (current-column) 0)
 727                (not (eq shr-state 'image)))
 728       (insert "\n"))
 729     (let ((alt (cdr (assq :alt cont)))
 730           (url (or url (cdr (assq :src cont)))))
 731       (let ((start (point-marker)))
 732         (when (zerop (length alt))
 733           (setq alt "*"))
 734         (cond
 735          ((or (member (cdr (assq :height cont)) '("0" "1"))
 736               (member (cdr (assq :width cont)) '("0" "1")))
 737           ;; Ignore zero-sized or single-pixel images.
 738           )
 739          ((and (not shr-inhibit-images)
 740                (string-match "\\`cid:" url))
 741           (let ((url (substring url (match-end 0)))
 742                 image)
 743             (if (or (not shr-content-function)
 744                     (not (setq image (funcall shr-content-function url))))
 745                 (insert alt)
 746               (shr-put-image image alt))))
 747          ((or shr-inhibit-images
 748               (and shr-blocked-images
 749                    (string-match shr-blocked-images url)))
 750           (setq shr-start (point))
 751           (let ((shr-state 'space))
 752             (if (> (string-width alt) 8)
 753                 (shr-insert (truncate-string-to-width alt 8))
 754               (shr-insert alt))))
 755          ((url-is-cached (shr-encode-url url))
 756           (shr-put-image (shr-get-image-data url) alt))
 757          (t
 758           (insert alt)
 759           (ignore-errors
 760             (url-retrieve (shr-encode-url url) 'shr-image-fetched
 761                           (list (current-buffer) start (point-marker))
 762                           t))))
 763         (put-text-property start (point) 'keymap shr-map)
 764         (put-text-property start (point) 'shr-alt alt)
 765         (put-text-property start (point) 'image-url url)
 766         (put-text-property start (point) 'image-displayer
 767                            (shr-image-displayer shr-content-function))
 768         (put-text-property start (point) 'help-echo alt)
 769         (setq shr-state 'image)))))
 770
 771 (defun shr-tag-pre (cont)
 772   (let ((shr-folding-mode 'none))
 773     (shr-ensure-newline)
 774     (shr-indent)
 775     (shr-generic cont)
 776     (shr-ensure-newline)))
 777
 778 (defun shr-tag-blockquote (cont)
 779   (shr-ensure-paragraph)
 780   (shr-indent)
 781   (let ((shr-indentation (+ shr-indentation 4)))
 782     (shr-generic cont))
 783   (shr-ensure-paragraph))
 784
 785 (defun shr-tag-ul (cont)
 786   (shr-ensure-paragraph)
 787   (let ((shr-list-mode 'ul))
 788     (shr-generic cont))
 789   (shr-ensure-paragraph))
 790
 791 (defun shr-tag-ol (cont)
 792   (shr-ensure-paragraph)
 793   (let ((shr-list-mode 1))
 794     (shr-generic cont))
 795   (shr-ensure-paragraph))
 796
 797 (defun shr-tag-li (cont)
 798   (shr-ensure-paragraph)
 799   (shr-indent)
 800   (let* ((bullet
 801           (if (numberp shr-list-mode)
 802               (prog1
 803                   (format "%d " shr-list-mode)
 804                 (setq shr-list-mode (1+ shr-list-mode)))
 805             "* "))
 806          (shr-indentation (+ shr-indentation (length bullet))))
 807     (insert bullet)
 808     (shr-generic cont)))
 809
 810 (defun shr-tag-br (cont)
 811   (unless (bobp)
 812     (insert "\n")
 813     (shr-indent))
 814   (shr-generic cont))
 815
 816 (defun shr-tag-h1 (cont)
 817   (shr-heading cont 'bold 'underline))
 818
 819 (defun shr-tag-h2 (cont)
 820   (shr-heading cont 'bold))
 821
 822 (defun shr-tag-h3 (cont)
 823   (shr-heading cont 'italic))
 824
 825 (defun shr-tag-h4 (cont)
 826   (shr-heading cont))
 827
 828 (defun shr-tag-h5 (cont)
 829   (shr-heading cont))
 830
 831 (defun shr-tag-h6 (cont)
 832   (shr-heading cont))
 833
 834 (defun shr-tag-hr (cont)
 835   (shr-ensure-newline)
 836   (insert (make-string shr-width shr-hr-line) "\n"))
 837
 838 (defun shr-tag-title (cont)
 839   (shr-heading cont 'bold 'underline))
 840
 841 (defun shr-tag-font (cont)
 842   (let ((start (point))
 843         (color (cdr (assq :color cont))))
 844     (shr-generic cont)
 845     (shr-colorize-region start (point) color)))
 846
 847 ;;; Table rendering algorithm.
 848
 849 ;; Table rendering is the only complicated thing here.  We do this by
 850 ;; first counting how many TDs there are in each TR, and registering
 851 ;; how wide they think they should be ("width=45%", etc).  Then we
 852 ;; render each TD separately (this is done in temporary buffers, so
 853 ;; that we can use all the rendering machinery as if we were in the
 854 ;; main buffer).  Now we know how much space each TD really takes, so
 855 ;; we then render everything again with the new widths, and finally
 856 ;; insert all these boxes into the main buffer.
 857 (defun shr-tag-table-1 (cont)
 858   (setq cont (or (cdr (assq 'tbody cont))
 859                  cont))
 860   (let* ((shr-inhibit-images t)
 861          (shr-table-depth (1+ shr-table-depth))
 862          (shr-kinsoku-shorten t)
 863          ;; Find all suggested widths.
 864          (columns (shr-column-specs cont))
 865          ;; Compute how many characters wide each TD should be.
 866          (suggested-widths (shr-pro-rate-columns columns))
 867          ;; Do a "test rendering" to see how big each TD is (this can
 868          ;; be smaller (if there's little text) or bigger (if there's
 869          ;; unbreakable text).
 870          (sketch (shr-make-table cont suggested-widths))
 871          (sketch-widths (shr-table-widths sketch suggested-widths)))
 872     ;; This probably won't work very well.
 873     (when (> (+ (loop for width across sketch-widths
 874                       summing (1+ width))
 875                 shr-indentation 1)
 876              (frame-width))
 877       (setq truncate-lines t))
 878     ;; Then render the table again with these new "hard" widths.
 879     (shr-insert-table (shr-make-table cont sketch-widths t) sketch-widths))
 880   ;; Finally, insert all the images after the table.  The Emacs buffer
 881   ;; model isn't strong enough to allow us to put the images actually
 882   ;; into the tables.
 883   (when (zerop shr-table-depth)
 884     (dolist (elem (shr-find-elements cont 'img))
 885       (shr-tag-img (cdr elem)))))
 886
 887 (defun shr-tag-table (cont)
 888   (shr-ensure-paragraph)
 889   (let* ((caption (cdr (assq 'caption cont)))
 890          (header (cdr (assq 'thead cont)))
 891          (body (or (cdr (assq 'tbody cont)) cont))
 892          (footer (cdr (assq 'tfoot cont)))
 893          (bgcolor (cdr (assq :bgcolor cont)))
 894          (nheader (if header (shr-max-columns header)))
 895          (nbody (if body (shr-max-columns body)))
 896          (nfooter (if footer (shr-max-columns footer))))
 897     (shr-tag-table-1
 898      (nconc
 899       (if caption `((tr (td ,@caption))))
 900       (if header
 901           (if footer
 902               ;; hader + body + footer
 903               (if (= nheader nbody)
 904                   (if (= nbody nfooter)
 905                       `((tr (td (table (tbody ,@header ,@body ,@footer)))))
 906                     (nconc `((tr (td (table (tbody ,@header ,@body)))))
 907                            (if (= nfooter 1)
 908                                footer
 909                              `((tr (td (table (tbody ,@footer))))))))
 910                 (nconc `((tr (td (table (tbody ,@header)))))
 911                        (if (= nbody nfooter)
 912                            `((tr (td (table (tbody ,@body ,@footer)))))
 913                          (nconc `((tr (td (table (tbody ,@body)))))
 914                                 (if (= nfooter 1)
 915                                     footer
 916                                   `((tr (td (table (tbody ,@footer))))))))))
 917             ;; header + body
 918             (if (= nheader nbody)
 919                 `((tr (td (table (tbody ,@header ,@body)))))
 920               (if (= nheader 1)
 921                   `(,@header (tr (td (table (tbody ,@body)))))
 922                 `((tr (td (table (tbody ,@header))))
 923                   (tr (td (table (tbody ,@body))))))))
 924         (if footer
 925             ;; body + footer
 926             (if (= nbody nfooter)
 927                 `((tr (td (table (tbody ,@body ,@footer)))))
 928               (nconc `((tr (td (table (tbody ,@body)))))
 929                      (if (= nfooter 1)
 930                          footer
 931                        `((tr (td (table (tbody ,@footer))))))))
 932           (if caption
 933               `((tr (td (table (tbody ,@body)))))
 934             body)))))))
 935
 936 (defun shr-find-elements (cont type)
 937   (let (result)
 938     (dolist (elem cont)
 939       (cond ((eq (car elem) type)
 940              (push elem result))
 941             ((consp (cdr elem))
 942              (setq result (nconc (shr-find-elements (cdr elem) type) result)))))
 943     (nreverse result)))
 944
 945 (defun shr-insert-table (table widths)
 946   (shr-insert-table-ruler widths)
 947   (dolist (row table)
 948     (let ((start (point))
 949           (height (let ((max 0))
 950                     (dolist (column row)
 951                       (setq max (max max (cadr column))))
 952                     max)))
 953       (dotimes (i height)
 954         (shr-indent)
 955         (insert shr-table-vertical-line "\n"))
 956       (dolist (column row)
 957         (goto-char start)
 958         (let ((lines (nth 2 column))
 959               (overlay-lines (nth 3 column))
 960               overlay overlay-line)
 961           (dolist (line lines)
 962             (setq overlay-line (pop overlay-lines))
 963             (end-of-line)
 964             (insert line shr-table-vertical-line)
 965             (dolist (overlay overlay-line)
 966               (let ((o (make-overlay (- (point) (nth 0 overlay) 1)
 967                                      (- (point) (nth 1 overlay) 1)))
 968                     (properties (nth 2 overlay)))
 969                 (while properties
 970                   (overlay-put o (pop properties) (pop properties)))))
 971             (forward-line 1))
 972           ;; Add blank lines at padding at the bottom of the TD,
 973           ;; possibly.
 974           (dotimes (i (- height (length lines)))
 975             (end-of-line)
 976             (insert (make-string (string-width (car lines)) ? )
 977                     shr-table-vertical-line)
 978             (forward-line 1)))))
 979     (shr-insert-table-ruler widths)))
 980
 981 (defun shr-insert-table-ruler (widths)
 982   (when (and (bolp)
 983              (> shr-indentation 0))
 984     (shr-indent))
 985   (insert shr-table-corner)
 986   (dotimes (i (length widths))
 987     (insert (make-string (aref widths i) shr-table-horizontal-line)
 988             shr-table-corner))
 989   (insert "\n"))
 990
 991 (defun shr-table-widths (table suggested-widths)
 992   (let* ((length (length suggested-widths))
 993          (widths (make-vector length 0))
 994          (natural-widths (make-vector length 0)))
 995     (dolist (row table)
 996       (let ((i 0))
 997         (dolist (column row)
 998           (aset widths i (max (aref widths i)
 999                               (car column)))
1000           (aset natural-widths i (max (aref natural-widths i)
1001                                       (cadr column)))
1002           (setq i (1+ i)))))
1003     (let ((extra (- (apply '+ (append suggested-widths nil))
1004                     (apply '+ (append widths nil))))
1005           (expanded-columns 0))
1006       (when (> extra 0)
1007         (dotimes (i length)
1008           ;; If the natural width is wider than the rendered width, we
1009           ;; want to allow the column to expand.
1010           (when (> (aref natural-widths i) (aref widths i))
1011             (setq expanded-columns (1+ expanded-columns))))
1012         (dotimes (i length)
1013           (when (> (aref natural-widths i) (aref widths i))
1014             (aset widths i (min
1015                             (1+ (aref natural-widths i))
1016                             (+ (/ extra expanded-columns)
1017                                (aref widths i))))))))
1018     widths))
1019
1020 (defun shr-make-table (cont widths &optional fill)
1021   (let ((trs nil))
1022     (dolist (row cont)
1023       (when (eq (car row) 'tr)
1024         (let ((tds nil)
1025               (columns (cdr row))
1026               (i 0)
1027               column)
1028           (while (< i (length widths))
1029             (setq column (pop columns))
1030             (when (or (memq (car column) '(td th))
1031                       (null column))
1032               (push (shr-render-td (cdr column) (aref widths i) fill)
1033                     tds)
1034               (setq i (1+ i))))
1035           (push (nreverse tds) trs))))
1036     (nreverse trs)))
1037
1038 (defun shr-render-td (cont width fill)
1039   (with-temp-buffer
1040     (let ((cache (cdr (assoc (cons width cont) shr-content-cache))))
1041       (if cache
1042           (insert cache)
1043         (let ((shr-width width)
1044               (shr-indentation 0))
1045           (shr-generic cont))
1046         (delete-region
1047          (point)
1048          (+ (point)
1049             (skip-chars-backward " \t\n")))
1050         (push (cons (cons width cont) (buffer-string))
1051               shr-content-cache)))
1052     (goto-char (point-min))
1053     (let ((max 0))
1054       (while (not (eobp))
1055         (end-of-line)
1056         (setq max (max max (current-column)))
1057         (forward-line 1))
1058       (when fill
1059         (goto-char (point-min))
1060         ;; If the buffer is totally empty, then put a single blank
1061         ;; line here.
1062         (if (zerop (buffer-size))
1063             (insert (make-string width ? ))
1064           ;; Otherwise, fill the buffer.
1065           (while (not (eobp))
1066             (end-of-line)
1067             (when (> (- width (current-column)) 0)
1068               (insert (make-string (- width (current-column)) ? )))
1069             (forward-line 1))))
1070       (if fill
1071           (list max
1072                 (count-lines (point-min) (point-max))
1073                 (split-string (buffer-string) "\n")
1074                 (shr-collect-overlays))
1075         (list max
1076               (shr-natural-width))))))
1077
1078 (defun shr-natural-width ()
1079   (goto-char (point-min))
1080   (let ((current 0)
1081         (max 0))
1082     (while (not (eobp))
1083       (end-of-line)
1084       (setq current (+ current (current-column)))
1085       (unless (get-text-property (point) 'shr-break)
1086         (setq max (max max current)
1087               current 0))
1088       (forward-line 1))
1089     max))
1090
1091 (defun shr-collect-overlays ()
1092   (save-excursion
1093     (goto-char (point-min))
1094     (let ((overlays nil))
1095       (while (not (eobp))
1096         (push (shr-overlays-in-region (point) (line-end-position))
1097               overlays)
1098         (forward-line 1))
1099       (nreverse overlays))))
1100
1101 (defun shr-overlays-in-region (start end)
1102   (let (result)
1103     (dolist (overlay (overlays-in start end))
1104       (push (list (if (> start (overlay-start overlay))
1105                       (- end start)
1106                     (- end (overlay-start overlay)))
1107                   (if (< end (overlay-end overlay))
1108                       0
1109                     (- end (overlay-end overlay)))
1110                   (overlay-properties overlay))
1111             result))
1112     (nreverse result)))
1113
1114 (defun shr-pro-rate-columns (columns)
1115   (let ((total-percentage 0)
1116         (widths (make-vector (length columns) 0)))
1117     (dotimes (i (length columns))
1118       (setq total-percentage (+ total-percentage (aref columns i))))
1119     (setq total-percentage (/ 1.0 total-percentage))
1120     (dotimes (i (length columns))
1121       (aset widths i (max (truncate (* (aref columns i)
1122                                        total-percentage
1123                                        (- shr-width (1+ (length columns)))))
1124                           10)))
1125     widths))
1126
1127 ;; Return a summary of the number and shape of the TDs in the table.
1128 (defun shr-column-specs (cont)
1129   (let ((columns (make-vector (shr-max-columns cont) 1)))
1130     (dolist (row cont)
1131       (when (eq (car row) 'tr)
1132         (let ((i 0))
1133           (dolist (column (cdr row))
1134             (when (memq (car column) '(td th))
1135               (let ((width (cdr (assq :width (cdr column)))))
1136                 (when (and width
1137                            (string-match "\\([0-9]+\\)%" width))
1138                   (aset columns i
1139                         (/ (string-to-number (match-string 1 width))
1140                            100.0))))
1141               (setq i (1+ i)))))))
1142     columns))
1143
1144 (defun shr-count (cont elem)
1145   (let ((i 0))
1146     (dolist (sub cont)
1147       (when (eq (car sub) elem)
1148         (setq i (1+ i))))
1149     i))
1150
1151 (defun shr-max-columns (cont)
1152   (let ((max 0))
1153     (dolist (row cont)
1154       (when (eq (car row) 'tr)
1155         (setq max (max max (+ (shr-count (cdr row) 'td)
1156                               (shr-count (cdr row) 'th))))))
1157     max))
1158
1159 (provide 'shr)
1160
1161 ;;; shr.el ends here