cgit.sxemacs.org Git - gnus/blob - lisp/shr.el

   1 ;;; shr.el --- Simple HTML Renderer
   2
   3 ;; Copyright (C) 2010 Free Software Foundation, Inc.
   4
   5 ;; Author: Lars Magne Ingebrigtsen <larsi@gnus.org>
   6 ;; Keywords: html
   7
   8 ;; This file is part of GNU Emacs.
   9
  10 ;; GNU Emacs is free software: you can redistribute it and/or modify
  11 ;; it under the terms of the GNU General Public License as published by
  12 ;; the Free Software Foundation, either version 3 of the License, or
  13 ;; (at your option) any later version.
  14
  15 ;; GNU Emacs is distributed in the hope that it will be useful,
  16 ;; but WITHOUT ANY WARRANTY; without even the implied warranty of
  17 ;; MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.  See the
  18 ;; GNU General Public License for more details.
  19
  20 ;; You should have received a copy of the GNU General Public License
  21 ;; along with GNU Emacs.  If not, see <http://www.gnu.org/licenses/>.
  22
  23 ;;; Commentary:
  24
  25 ;; This package takes a HTML parse tree (as provided by
  26 ;; libxml-parse-html-region) and renders it in the current buffer.  It
  27 ;; does not do CSS, JavaScript or anything advanced: It's geared
  28 ;; towards rendering typical short snippets of HTML, like what you'd
  29 ;; find in HTML email and the like.
  30
  31 ;;; Code:
  32
  33 (eval-when-compile (require 'cl))
  34 (require 'browse-url)
  35 (unless (aref (char-category-set (make-char 'japanese-jisx0208 33 35)) ?>)
  36   (load "kinsoku" nil t))
  37
  38 (defgroup shr nil
  39   "Simple HTML Renderer"
  40   :group 'mail)
  41
  42 (defcustom shr-max-image-proportion 0.9
  43   "How big pictures displayed are in relation to the window they're in.
  44 A value of 0.7 means that they are allowed to take up 70% of the
  45 width and height of the window.  If they are larger than this,
  46 and Emacs supports it, then the images will be rescaled down to
  47 fit these criteria."
  48   :version "24.1"
  49   :group 'shr
  50   :type 'float)
  51
  52 (defcustom shr-blocked-images nil
  53   "Images that have URLs matching this regexp will be blocked."
  54   :version "24.1"
  55   :group 'shr
  56   :type 'regexp)
  57
  58 (defcustom shr-table-line ?-
  59   "Character used to draw table line."
  60   :group 'shr
  61   :type 'character)
  62
  63 (defcustom shr-table-corner ?+
  64   "Character used to draw table corner."
  65   :group 'shr
  66   :type 'character)
  67
  68 (defcustom shr-hr-line ?-
  69   "Character used to draw hr line."
  70   :group 'shr
  71   :type 'character)
  72
  73 (defcustom shr-width fill-column
  74   "Frame width to use for rendering."
  75   :type 'integer
  76   :group 'shr)
  77
  78 (defvar shr-content-function nil
  79   "If bound, this should be a function that will return the content.
  80 This is used for cid: URLs, and the function is called with the
  81 cid: URL as the argument.")
  82
  83 ;;; Internal variables.
  84
  85 (defvar shr-folding-mode nil)
  86 (defvar shr-state nil)
  87 (defvar shr-start nil)
  88 (defvar shr-indentation 0)
  89 (defvar shr-inhibit-images nil)
  90 (defvar shr-list-mode nil)
  91 (defvar shr-content-cache nil)
  92 (defvar shr-kinsoku-shorten nil)
  93 (defvar shr-table-depth 0)
  94
  95 (defvar shr-map
  96   (let ((map (make-sparse-keymap)))
  97     (define-key map "a" 'shr-show-alt-text)
  98     (define-key map "i" 'shr-browse-image)
  99     (define-key map "I" 'shr-insert-image)
 100     (define-key map "u" 'shr-copy-url)
 101     (define-key map "v" 'shr-browse-url)
 102     (define-key map "o" 'shr-save-contents)
 103     (define-key map "\r" 'shr-browse-url)
 104     map))
 105
 106 ;; Public functions and commands.
 107
 108 ;;;###autoload
 109 (defun shr-insert-document (dom)
 110   (setq shr-content-cache nil)
 111   (let ((shr-state nil)
 112         (shr-start nil))
 113     (shr-descend (shr-transform-dom dom))))
 114
 115 (defun shr-copy-url ()
 116   "Copy the URL under point to the kill ring.
 117 If called twice, then try to fetch the URL and see whether it
 118 redirects somewhere else."
 119   (interactive)
 120   (let ((url (get-text-property (point) 'shr-url)))
 121     (cond
 122      ((not url)
 123       (message "No URL under point"))
 124      ;; Resolve redirected URLs.
 125      ((equal url (car kill-ring))
 126       (url-retrieve
 127        url
 128        (lambda (a)
 129          (when (and (consp a)
 130                     (eq (car a) :redirect))
 131            (with-temp-buffer
 132              (insert (cadr a))
 133              (goto-char (point-min))
 134              ;; Remove common tracking junk from the URL.
 135              (when (re-search-forward ".utm_.*" nil t)
 136                (replace-match "" t t))
 137              (message "Copied %s" (buffer-string))
 138              (copy-region-as-kill (point-min) (point-max)))))))
 139      ;; Copy the URL to the kill ring.
 140      (t
 141       (with-temp-buffer
 142         (insert url)
 143         (copy-region-as-kill (point-min) (point-max))
 144         (message "Copied %s" url))))))
 145
 146 (defun shr-show-alt-text ()
 147   "Show the ALT text of the image under point."
 148   (interactive)
 149   (let ((text (get-text-property (point) 'shr-alt)))
 150     (if (not text)
 151         (message "No image under point")
 152       (message "%s" text))))
 153
 154 (defun shr-browse-image ()
 155   "Browse the image under point."
 156   (interactive)
 157   (let ((url (get-text-property (point) 'shr-image)))
 158     (if (not url)
 159         (message "No image under point")
 160       (message "Browsing %s..." url)
 161       (browse-url url))))
 162
 163 (defun shr-insert-image ()
 164   "Insert the image under point into the buffer."
 165   (interactive)
 166   (let ((url (get-text-property (point) 'shr-image)))
 167     (if (not url)
 168         (message "No image under point")
 169       (message "Inserting %s..." url)
 170       (url-retrieve url 'shr-image-fetched
 171                     (list (current-buffer) (1- (point)) (point-marker))
 172                     t))))
 173
 174 ;;; Utility functions.
 175
 176 (defun shr-transform-dom (dom)
 177   (let ((result (list (pop dom))))
 178     (dolist (arg (pop dom))
 179       (push (cons (intern (concat ":" (symbol-name (car arg))) obarray)
 180                   (cdr arg))
 181             result))
 182     (dolist (sub dom)
 183       (if (stringp sub)
 184           (push (cons :text sub) result)
 185         (push (shr-transform-dom sub) result)))
 186     (nreverse result)))
 187
 188 (defun shr-descend (dom)
 189   (let ((function (intern (concat "shr-tag-" (symbol-name (car dom))) obarray)))
 190     (if (fboundp function)
 191         (funcall function (cdr dom))
 192       (shr-generic (cdr dom)))))
 193
 194 (defun shr-generic (cont)
 195   (dolist (sub cont)
 196     (cond
 197      ((eq (car sub) :text)
 198       (shr-insert (cdr sub)))
 199      ((listp (cdr sub))
 200       (shr-descend sub)))))
 201
 202 (defun shr-insert (text)
 203   (when (and (eq shr-state 'image)
 204              (not (string-match "\\`[ \t\n]+\\'" text)))
 205     (insert "\n")
 206     (setq shr-state nil))
 207   (cond
 208    ((eq shr-folding-mode 'none)
 209     (insert text))
 210    (t
 211     (when (and (string-match "\\`[ \t\n]" text)
 212                (not (bolp))
 213                (not (eq (char-after (1- (point))) ? )))
 214       (insert " "))
 215     (dolist (elem (split-string text))
 216       (when (and (bolp)
 217                  (> shr-indentation 0))
 218         (shr-indent))
 219       ;; The shr-start is a special variable that is used to pass
 220       ;; upwards the first point in the buffer where the text really
 221       ;; starts.
 222       (unless shr-start
 223         (setq shr-start (point)))
 224       ;; No space is needed behind a wide character categorized as
 225       ;; kinsoku-bol, between characters both categorized as nospace,
 226       ;; or at the beginning of a line.
 227       (let (prev)
 228         (when (and (eq (preceding-char) ? )
 229                    (or (= (line-beginning-position) (1- (point)))
 230                        (and (aref fill-find-break-point-function-table
 231                                   (setq prev (char-after (- (point) 2))))
 232                             (aref (char-category-set prev) ?>))
 233                        (and (aref fill-nospace-between-words-table prev)
 234                             (aref fill-nospace-between-words-table
 235                                   (aref elem 0)))))
 236           (delete-char -1)))
 237       (insert elem)
 238       (while (> (current-column) shr-width)
 239         (unless (prog1
 240                     (shr-find-fill-point)
 241                   (when (eq (preceding-char) ? )
 242                     (delete-char -1))
 243                   (insert "\n"))
 244           (put-text-property (1- (point)) (point) 'shr-break t)
 245           ;; No space is needed at the beginning of a line.
 246           (when (eq (following-char) ? )
 247             (delete-char 1)))
 248         (when (> shr-indentation 0)
 249           (shr-indent))
 250         (end-of-line))
 251       (insert " "))
 252     (unless (string-match "[ \t\n]\\'" text)
 253       (delete-char -1)))))
 254
 255 (defun shr-find-fill-point ()
 256   (when (> (move-to-column shr-width) shr-width)
 257     (backward-char 1))
 258   (let (failed)
 259     (while (not
 260             (or (setq failed (= (current-column) shr-indentation))
 261                 (eq (preceding-char) ? )
 262                 (eq (following-char) ? )
 263                 (aref fill-find-break-point-function-table (preceding-char))))
 264       (backward-char 1))
 265     (if failed
 266         ;; There's no breakable point, so we give it up.
 267         (progn
 268           (end-of-line)
 269           (while (aref fill-find-break-point-function-table (preceding-char))
 270             (backward-char 1))
 271           nil)
 272       (or (eolp)
 273           ;; Don't put kinsoku-bol characters at the beginning of a line,
 274           ;; or kinsoku-eol characters at the end of a line,
 275           (let ((count 4))
 276             (if (or shr-kinsoku-shorten
 277                     (and (aref (char-category-set (preceding-char)) ?<)
 278                          (progn
 279                            (setq count (1- count))
 280                            (backward-char 1)
 281                            t)))
 282                 (while (and
 283                         (>= (setq count (1- count)) 0)
 284                         (not (memq (preceding-char) (list ?\C-@ ?\n ? )))
 285                         (or (aref (char-category-set (preceding-char)) ?<)
 286                             (aref (char-category-set (following-char)) ?>)))
 287                   (backward-char 1))
 288               (while (and (>= (setq count (1- count)) 0)
 289                           (aref (char-category-set (following-char)) ?>))
 290                 (forward-char 1)))
 291             (when (eq (following-char) ? )
 292               (forward-char 1))
 293             t)))))
 294
 295 (defun shr-ensure-newline ()
 296   (unless (zerop (current-column))
 297     (insert "\n")))
 298
 299 (defun shr-ensure-paragraph ()
 300   (unless (bobp)
 301     (if (<= (current-column) shr-indentation)
 302         (unless (save-excursion
 303                   (forward-line -1)
 304                   (looking-at " *$"))
 305           (insert "\n"))
 306       (if (save-excursion
 307             (beginning-of-line)
 308             (looking-at " *$"))
 309           (insert "\n")
 310         (insert "\n\n")))))
 311
 312 (defun shr-indent ()
 313   (when (> shr-indentation 0)
 314     (insert (make-string shr-indentation ? ))))
 315
 316 (defun shr-fontize-cont (cont &rest types)
 317   (let (shr-start)
 318     (shr-generic cont)
 319     (dolist (type types)
 320       (shr-add-font (or shr-start (point)) (point) type))))
 321
 322 ;; Add an overlay in the region, but avoid putting the font properties
 323 ;; on blank text at the start of the line, and the newline at the end,
 324 ;; to avoid ugliness.
 325 (defun shr-add-font (start end type)
 326   (save-excursion
 327     (goto-char start)
 328     (while (< (point) end)
 329       (when (bolp)
 330         (skip-chars-forward " "))
 331       (let ((overlay (make-overlay (point) (min (line-end-position) end))))
 332         (overlay-put overlay 'face type))
 333       (if (< (line-end-position) end)
 334           (forward-line 1)
 335         (goto-char end)))))
 336
 337 (defun shr-browse-url ()
 338   "Browse the URL under point."
 339   (interactive)
 340   (let ((url (get-text-property (point) 'shr-url)))
 341     (if (not url)
 342         (message "No link under point")
 343       (browse-url url))))
 344
 345 (defun shr-save-contents (directory)
 346   "Save the contents from URL in a file."
 347   (interactive "DSave contents of URL to directory: ")
 348   (let ((url (get-text-property (point) 'shr-url)))
 349     (if (not url)
 350         (message "No link under point")
 351       (url-retrieve (shr-encode-url url)
 352                     'shr-store-contents (list url directory)))))
 353
 354 (defun shr-store-contents (status url directory)
 355   (unless (plist-get status :error)
 356     (when (or (search-forward "\n\n" nil t)
 357               (search-forward "\r\n\r\n" nil t))
 358       (write-region (point) (point-max)
 359                     (expand-file-name (file-name-nondirectory url)
 360                                       directory)))))
 361
 362 (defun shr-image-fetched (status buffer start end)
 363   (when (and (buffer-name buffer)
 364              (not (plist-get status :error)))
 365     (url-store-in-cache (current-buffer))
 366     (when (or (search-forward "\n\n" nil t)
 367               (search-forward "\r\n\r\n" nil t))
 368       (let ((data (buffer-substring (point) (point-max))))
 369         (with-current-buffer buffer
 370           (let ((alt (buffer-substring start end))
 371                 (inhibit-read-only t))
 372             (delete-region start end)
 373             (shr-put-image data start alt))))))
 374   (kill-buffer (current-buffer)))
 375
 376 (defun shr-put-image (data point alt)
 377   (if (display-graphic-p)
 378       (let ((image (ignore-errors
 379                      (shr-rescale-image data))))
 380         (when image
 381           (put-image image point alt)))
 382     (save-excursion
 383       (goto-char point)
 384       (insert alt))))
 385
 386 (defun shr-rescale-image (data)
 387   (if (or (not (fboundp 'imagemagick-types))
 388           (not (get-buffer-window (current-buffer))))
 389       (create-image data nil t)
 390     (let* ((image (create-image data nil t))
 391            (size (image-size image t))
 392            (width (car size))
 393            (height (cdr size))
 394            (edges (window-inside-pixel-edges
 395                    (get-buffer-window (current-buffer))))
 396            (window-width (truncate (* shr-max-image-proportion
 397                                       (- (nth 2 edges) (nth 0 edges)))))
 398            (window-height (truncate (* shr-max-image-proportion
 399                                        (- (nth 3 edges) (nth 1 edges)))))
 400            scaled-image)
 401       (when (> height window-height)
 402         (setq image (or (create-image data 'imagemagick t
 403                                       :height window-height)
 404                         image))
 405         (setq size (image-size image t)))
 406       (when (> (car size) window-width)
 407         (setq image (or
 408                      (create-image data 'imagemagick t
 409                                    :width window-width)
 410                      image)))
 411       image)))
 412
 413 (defun shr-get-image-data (url)
 414   "Get image data for URL.
 415 Return a string with image data."
 416   (with-temp-buffer
 417     (mm-disable-multibyte)
 418     (when (ignore-errors
 419             (url-cache-extract (url-cache-create-filename (shr-encode-url url)))
 420             t)
 421       (when (or (search-forward "\n\n" nil t)
 422                 (search-forward "\r\n\r\n" nil t))
 423         (buffer-substring (point) (point-max))))))
 424
 425 (defun shr-heading (cont &rest types)
 426   (shr-ensure-paragraph)
 427   (apply #'shr-fontize-cont cont types)
 428   (shr-ensure-paragraph))
 429
 430 (defun shr-urlify (start url)
 431   (widget-convert-button
 432    'url-link start (point)
 433    :help-echo url
 434    :keymap shr-map
 435    url)
 436   (put-text-property start (point) 'shr-url url))
 437
 438 (defun shr-encode-url (url)
 439   "Encode URL."
 440   (browse-url-url-encode-chars url "[)$ ]"))
 441
 442 ;;; Tag-specific rendering rules.
 443
 444 (defun shr-tag-p (cont)
 445   (shr-ensure-paragraph)
 446   (shr-indent)
 447   (shr-generic cont)
 448   (shr-ensure-paragraph))
 449
 450 (defun shr-tag-div (cont)
 451   (shr-ensure-newline)
 452   (shr-indent)
 453   (shr-generic cont)
 454   (shr-ensure-newline))
 455
 456 (defun shr-tag-b (cont)
 457   (shr-fontize-cont cont 'bold))
 458
 459 (defun shr-tag-i (cont)
 460   (shr-fontize-cont cont 'italic))
 461
 462 (defun shr-tag-em (cont)
 463   (shr-fontize-cont cont 'bold))
 464
 465 (defun shr-tag-strong (cont)
 466   (shr-fontize-cont cont 'bold))
 467
 468 (defun shr-tag-u (cont)
 469   (shr-fontize-cont cont 'underline))
 470
 471 (defun shr-tag-s (cont)
 472   (shr-fontize-cont cont 'strike-through))
 473
 474 (defun shr-parse-style (style)
 475   (when style
 476     (let ((plist nil))
 477       (dolist (elem (split-string style ";"))
 478         (when elem
 479           (setq elem (split-string elem ":"))
 480           (when (and (car elem)
 481                      (cadr elem))
 482             (let ((name (replace-regexp-in-string "^ +\\| +$" "" (car elem)))
 483                   (value (replace-regexp-in-string "^ +\\| +$" "" (cadr elem))))
 484               (push (cons (intern name obarray)
 485                           value)
 486                     plist)))))
 487       plist)))
 488
 489 (defun shr-tag-a (cont)
 490   (let ((url (cdr (assq :href cont)))
 491         (start (point))
 492         shr-start)
 493     (shr-generic cont)
 494     (shr-urlify (or shr-start start) url)))
 495
 496 (defun shr-tag-object (cont)
 497   (let ((url (cdr (assq :src (cdr (assq 'embed cont)))))
 498         (start (point)))
 499     (when url
 500       (shr-insert " [multimedia] ")
 501       (shr-urlify start url))))
 502
 503 (defun shr-tag-img (cont)
 504   (when (and cont
 505              (cdr (assq :src cont)))
 506     (when (and (> (current-column) 0)
 507                (not (eq shr-state 'image)))
 508       (insert "\n"))
 509     (let ((alt (cdr (assq :alt cont)))
 510           (url (cdr (assq :src cont))))
 511       (let ((start (point-marker)))
 512         (when (zerop (length alt))
 513           (setq alt "[img]"))
 514         (cond
 515          ((and (not shr-inhibit-images)
 516                (string-match "\\`cid:" url))
 517           (let ((url (substring url (match-end 0)))
 518                 image)
 519             (if (or (not shr-content-function)
 520                     (not (setq image (funcall shr-content-function url))))
 521                 (insert alt)
 522               (shr-put-image image (point) alt))))
 523          ((or shr-inhibit-images
 524               (and shr-blocked-images
 525                    (string-match shr-blocked-images url)))
 526           (setq shr-start (point))
 527           (let ((shr-state 'space))
 528             (if (> (length alt) 8)
 529                 (shr-insert (substring alt 0 8))
 530               (shr-insert alt))))
 531          ((url-is-cached (shr-encode-url url))
 532           (shr-put-image (shr-get-image-data url) (point) alt))
 533          (t
 534           (insert alt)
 535           (ignore-errors
 536             (url-retrieve (shr-encode-url url) 'shr-image-fetched
 537                           (list (current-buffer) start (point-marker))
 538                           t))))
 539         (insert " ")
 540         (put-text-property start (point) 'keymap shr-map)
 541         (put-text-property start (point) 'shr-alt alt)
 542         (put-text-property start (point) 'shr-image url)
 543         (setq shr-state 'image)))))
 544
 545 (defun shr-tag-pre (cont)
 546   (let ((shr-folding-mode 'none))
 547     (shr-ensure-newline)
 548     (shr-indent)
 549     (shr-generic cont)
 550     (shr-ensure-newline)))
 551
 552 (defun shr-tag-blockquote (cont)
 553   (shr-ensure-paragraph)
 554   (shr-indent)
 555   (let ((shr-indentation (+ shr-indentation 4)))
 556     (shr-generic cont))
 557   (shr-ensure-paragraph))
 558
 559 (defun shr-tag-ul (cont)
 560   (shr-ensure-paragraph)
 561   (let ((shr-list-mode 'ul))
 562     (shr-generic cont))
 563   (shr-ensure-paragraph))
 564
 565 (defun shr-tag-ol (cont)
 566   (shr-ensure-paragraph)
 567   (let ((shr-list-mode 1))
 568     (shr-generic cont))
 569   (shr-ensure-paragraph))
 570
 571 (defun shr-tag-li (cont)
 572   (shr-ensure-paragraph)
 573   (shr-indent)
 574   (let* ((bullet
 575           (if (numberp shr-list-mode)
 576               (prog1
 577                   (format "%d " shr-list-mode)
 578                 (setq shr-list-mode (1+ shr-list-mode)))
 579             "* "))
 580          (shr-indentation (+ shr-indentation (length bullet))))
 581     (insert bullet)
 582     (shr-generic cont)))
 583
 584 (defun shr-tag-br (cont)
 585   (unless (bobp)
 586     (insert "\n")
 587     (shr-indent))
 588   (shr-generic cont))
 589
 590 (defun shr-tag-h1 (cont)
 591   (shr-heading cont 'bold 'underline))
 592
 593 (defun shr-tag-h2 (cont)
 594   (shr-heading cont 'bold))
 595
 596 (defun shr-tag-h3 (cont)
 597   (shr-heading cont 'italic))
 598
 599 (defun shr-tag-h4 (cont)
 600   (shr-heading cont))
 601
 602 (defun shr-tag-h5 (cont)
 603   (shr-heading cont))
 604
 605 (defun shr-tag-h6 (cont)
 606   (shr-heading cont))
 607
 608 (defun shr-tag-hr (cont)
 609   (shr-ensure-newline)
 610   (insert (make-string shr-width shr-hr-line) "\n"))
 611
 612 ;;; Table rendering algorithm.
 613
 614 ;; Table rendering is the only complicated thing here.  We do this by
 615 ;; first counting how many TDs there are in each TR, and registering
 616 ;; how wide they think they should be ("width=45%", etc).  Then we
 617 ;; render each TD separately (this is done in temporary buffers, so
 618 ;; that we can use all the rendering machinery as if we were in the
 619 ;; main buffer).  Now we know how much space each TD really takes, so
 620 ;; we then render everything again with the new widths, and finally
 621 ;; insert all these boxes into the main buffer.
 622 (defun shr-tag-table-1 (cont)
 623   (setq cont (or (cdr (assq 'tbody cont))
 624                  cont))
 625   (let* ((shr-inhibit-images t)
 626          (shr-table-depth (1+ shr-table-depth))
 627          (shr-kinsoku-shorten t)
 628          ;; Find all suggested widths.
 629          (columns (shr-column-specs cont))
 630          ;; Compute how many characters wide each TD should be.
 631          (suggested-widths (shr-pro-rate-columns columns))
 632          ;; Do a "test rendering" to see how big each TD is (this can
 633          ;; be smaller (if there's little text) or bigger (if there's
 634          ;; unbreakable text).
 635          (sketch (shr-make-table cont suggested-widths))
 636          (sketch-widths (shr-table-widths sketch suggested-widths)))
 637     ;; This probably won't work very well.
 638     (when (> (+ (loop for width across sketch-widths
 639                       summing (1+ width))
 640                 shr-indentation 1)
 641              (frame-width))
 642       (setq truncate-lines t))
 643     ;; Then render the table again with these new "hard" widths.
 644     (shr-insert-table (shr-make-table cont sketch-widths t) sketch-widths))
 645   ;; Finally, insert all the images after the table.  The Emacs buffer
 646   ;; model isn't strong enough to allow us to put the images actually
 647   ;; into the tables.
 648   (when (zerop shr-table-depth)
 649     (dolist (elem (shr-find-elements cont 'img))
 650       (shr-tag-img (cdr elem)))))
 651
 652 (defun shr-tag-table (cont)
 653   (shr-ensure-paragraph)
 654   (let* ((caption (cdr (assq 'caption cont)))
 655          (header (cdr (assq 'thead cont)))
 656          (body (or (cdr (assq 'tbody cont)) cont))
 657          (footer (cdr (assq 'tfoot cont)))
 658          (nheader (if header (shr-max-columns header)))
 659          (nbody (if body (shr-max-columns body)))
 660          (nfooter (if footer (shr-max-columns footer))))
 661     (shr-tag-table-1
 662      (nconc
 663       (if caption `((tr (td ,@caption))))
 664       (if header
 665           (if footer
 666               ;; hader + body + footer
 667               (if (= nheader nbody)
 668                   (if (= nbody nfooter)
 669                       `((tr (td (table (tbody ,@header ,@body ,@footer)))))
 670                     (nconc `((tr (td (table (tbody ,@header ,@body)))))
 671                            (if (= nfooter 1)
 672                                footer
 673                              `((tr (td (table (tbody ,@footer))))))))
 674                 (nconc `((tr (td (table (tbody ,@header)))))
 675                        (if (= nbody nfooter)
 676                            `((tr (td (table (tbody ,@body ,@footer)))))
 677                          (nconc `((tr (td (table (tbody ,@body)))))
 678                                 (if (= nfooter 1)
 679                                     footer
 680                                   `((tr (td (table (tbody ,@footer))))))))))
 681             ;; header + body
 682             (if (= nheader nbody)
 683                 `((tr (td (table (tbody ,@header ,@body)))))
 684               (if (= nheader 1)
 685                   `(,@header (tr (td (table (tbody ,@body)))))
 686                 `((tr (td (table (tbody ,@header))))
 687                   (tr (td (table (tbody ,@body))))))))
 688         (if footer
 689             ;; body + footer
 690             (if (= nbody nfooter)
 691                 `((tr (td (table (tbody ,@body ,@footer)))))
 692               (nconc `((tr (td (table (tbody ,@body)))))
 693                      (if (= nfooter 1)
 694                          footer
 695                        `((tr (td (table (tbody ,@footer))))))))
 696           (if caption
 697               `((tr (td (table (tbody ,@body)))))
 698             body)))))))
 699
 700 (defun shr-find-elements (cont type)
 701   (let (result)
 702     (dolist (elem cont)
 703       (cond ((eq (car elem) type)
 704              (push elem result))
 705             ((consp (cdr elem))
 706              (setq result (nconc (shr-find-elements (cdr elem) type) result)))))
 707     (nreverse result)))
 708
 709 (defun shr-insert-table (table widths)
 710   (shr-insert-table-ruler widths)
 711   (dolist (row table)
 712     (let ((start (point))
 713           (height (let ((max 0))
 714                     (dolist (column row)
 715                       (setq max (max max (cadr column))))
 716                     max)))
 717       (dotimes (i height)
 718         (shr-indent)
 719         (insert "|\n"))
 720       (dolist (column row)
 721         (goto-char start)
 722         (let ((lines (nth 2 column))
 723               (overlay-lines (nth 3 column))
 724               overlay overlay-line)
 725           (dolist (line lines)
 726             (setq overlay-line (pop overlay-lines))
 727             (end-of-line)
 728             (insert line "|")
 729             (dolist (overlay overlay-line)
 730               (let ((o (make-overlay (- (point) (nth 0 overlay) 1)
 731                                      (- (point) (nth 1 overlay) 1)))
 732                     (properties (nth 2 overlay)))
 733                 (while properties
 734                   (overlay-put o (pop properties) (pop properties)))))
 735             (forward-line 1))
 736           ;; Add blank lines at padding at the bottom of the TD,
 737           ;; possibly.
 738           (dotimes (i (- height (length lines)))
 739             (end-of-line)
 740             (insert (make-string (string-width (car lines)) ? ) "|")
 741             (forward-line 1)))))
 742     (shr-insert-table-ruler widths)))
 743
 744 (defun shr-insert-table-ruler (widths)
 745   (when (and (bolp)
 746              (> shr-indentation 0))
 747     (shr-indent))
 748   (insert shr-table-corner)
 749   (dotimes (i (length widths))
 750     (insert (make-string (aref widths i) shr-table-line) shr-table-corner))
 751   (insert "\n"))
 752
 753 (defun shr-table-widths (table suggested-widths)
 754   (let* ((length (length suggested-widths))
 755          (widths (make-vector length 0))
 756          (natural-widths (make-vector length 0)))
 757     (dolist (row table)
 758       (let ((i 0))
 759         (dolist (column row)
 760           (aset widths i (max (aref widths i)
 761                               (car column)))
 762           (aset natural-widths i (max (aref natural-widths i)
 763                                       (cadr column)))
 764           (setq i (1+ i)))))
 765     (let ((extra (- (apply '+ (append suggested-widths nil))
 766                     (apply '+ (append widths nil))))
 767           (expanded-columns 0))
 768       (when (> extra 0)
 769         (dotimes (i length)
 770           ;; If the natural width is wider than the rendered width, we
 771           ;; want to allow the column to expand.
 772           (when (> (aref natural-widths i) (aref widths i))
 773             (setq expanded-columns (1+ expanded-columns))))
 774         (dotimes (i length)
 775           (when (> (aref natural-widths i) (aref widths i))
 776             (aset widths i (min
 777                             (1+ (aref natural-widths i))
 778                             (+ (/ extra expanded-columns)
 779                                (aref widths i))))))))
 780     widths))
 781
 782 (defun shr-make-table (cont widths &optional fill)
 783   (let ((trs nil))
 784     (dolist (row cont)
 785       (when (eq (car row) 'tr)
 786         (let ((tds nil)
 787               (columns (cdr row))
 788               (i 0)
 789               column)
 790           (while (< i (length widths))
 791             (setq column (pop columns))
 792             (when (or (memq (car column) '(td th))
 793                       (null column))
 794               (push (shr-render-td (cdr column) (aref widths i) fill)
 795                     tds)
 796               (setq i (1+ i))))
 797           (push (nreverse tds) trs))))
 798     (nreverse trs)))
 799
 800 (defun shr-render-td (cont width fill)
 801   (with-temp-buffer
 802     (let ((cache (cdr (assoc (cons width cont) shr-content-cache))))
 803       (if cache
 804           (insert cache)
 805         (let ((shr-width width)
 806               (shr-indentation 0))
 807           (shr-generic cont))
 808         (delete-region
 809          (point)
 810          (+ (point)
 811             (skip-chars-backward " \t\n")))
 812         (push (cons (cons width cont) (buffer-string))
 813               shr-content-cache)))
 814     (goto-char (point-min))
 815     (let ((max 0))
 816       (while (not (eobp))
 817         (end-of-line)
 818         (setq max (max max (current-column)))
 819         (forward-line 1))
 820       (when fill
 821         (goto-char (point-min))
 822         ;; If the buffer is totally empty, then put a single blank
 823         ;; line here.
 824         (if (zerop (buffer-size))
 825             (insert (make-string width ? ))
 826           ;; Otherwise, fill the buffer.
 827           (while (not (eobp))
 828             (end-of-line)
 829             (when (> (- width (current-column)) 0)
 830               (insert (make-string (- width (current-column)) ? )))
 831             (forward-line 1))))
 832       (if fill
 833           (list max
 834                 (count-lines (point-min) (point-max))
 835                 (split-string (buffer-string) "\n")
 836                 (shr-collect-overlays))
 837         (list max
 838               (shr-natural-width))))))
 839
 840 (defun shr-natural-width ()
 841   (goto-char (point-min))
 842   (let ((current 0)
 843         (max 0))
 844     (while (not (eobp))
 845       (end-of-line)
 846       (setq current (+ current (current-column)))
 847       (unless (get-text-property (point) 'shr-break)
 848         (setq max (max max current)
 849               current 0))
 850       (forward-line 1))
 851     max))
 852
 853 (defun shr-collect-overlays ()
 854   (save-excursion
 855     (goto-char (point-min))
 856     (let ((overlays nil))
 857       (while (not (eobp))
 858         (push (shr-overlays-in-region (point) (line-end-position))
 859               overlays)
 860         (forward-line 1))
 861       (nreverse overlays))))
 862
 863 (defun shr-overlays-in-region (start end)
 864   (let (result)
 865     (dolist (overlay (overlays-in start end))
 866       (push (list (if (> start (overlay-start overlay))
 867                       (- end start)
 868                     (- end (overlay-start overlay)))
 869                   (if (< end (overlay-end overlay))
 870                       0
 871                     (- end (overlay-end overlay)))
 872                   (overlay-properties overlay))
 873             result))
 874     (nreverse result)))
 875
 876 (defun shr-pro-rate-columns (columns)
 877   (let ((total-percentage 0)
 878         (widths (make-vector (length columns) 0)))
 879     (dotimes (i (length columns))
 880       (setq total-percentage (+ total-percentage (aref columns i))))
 881     (setq total-percentage (/ 1.0 total-percentage))
 882     (dotimes (i (length columns))
 883       (aset widths i (max (truncate (* (aref columns i)
 884                                        total-percentage
 885                                        (- shr-width (1+ (length columns)))))
 886                           10)))
 887     widths))
 888
 889 ;; Return a summary of the number and shape of the TDs in the table.
 890 (defun shr-column-specs (cont)
 891   (let ((columns (make-vector (shr-max-columns cont) 1)))
 892     (dolist (row cont)
 893       (when (eq (car row) 'tr)
 894         (let ((i 0))
 895           (dolist (column (cdr row))
 896             (when (memq (car column) '(td th))
 897               (let ((width (cdr (assq :width (cdr column)))))
 898                 (when (and width
 899                            (string-match "\\([0-9]+\\)%" width))
 900                   (aset columns i
 901                         (/ (string-to-number (match-string 1 width))
 902                            100.0))))
 903               (setq i (1+ i)))))))
 904     columns))
 905
 906 (defun shr-count (cont elem)
 907   (let ((i 0))
 908     (dolist (sub cont)
 909       (when (eq (car sub) elem)
 910         (setq i (1+ i))))
 911     i))
 912
 913 (defun shr-max-columns (cont)
 914   (let ((max 0))
 915     (dolist (row cont)
 916       (when (eq (car row) 'tr)
 917         (setq max (max max (+ (shr-count (cdr row) 'td)
 918                               (shr-count (cdr row) 'th))))))
 919     max))
 920
 921 (provide 'shr)
 922
 923 ;;; shr.el ends here