cgit.sxemacs.org Git - gnus/blob - lisp/rfc2047.el

   1 ;;; rfc2047.el --- functions for encoding and decoding rfc2047 messages
   2
   3 ;; Copyright (C) 1998, 1999, 2000, 2002, 2003, 2004
   4 ;;        Free Software Foundation, Inc.
   5
   6 ;; Author: Lars Magne Ingebrigtsen <larsi@gnus.org>
   7 ;;      MORIOKA Tomohiko <morioka@jaist.ac.jp>
   8 ;; This file is part of GNU Emacs.
   9
  10 ;; GNU Emacs is free software; you can redistribute it and/or modify
  11 ;; it under the terms of the GNU General Public License as published by
  12 ;; the Free Software Foundation; either version 2, or (at your option)
  13 ;; any later version.
  14
  15 ;; GNU Emacs is distributed in the hope that it will be useful,
  16 ;; but WITHOUT ANY WARRANTY; without even the implied warranty of
  17 ;; MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.  See the
  18 ;; GNU General Public License for more details.
  19
  20 ;; You should have received a copy of the GNU General Public License
  21 ;; along with GNU Emacs; see the file COPYING.  If not, write to the
  22 ;; Free Software Foundation, Inc., 59 Temple Place - Suite 330,
  23 ;; Boston, MA 02111-1307, USA.
  24
  25 ;;; Commentary:
  26
  27 ;; RFC 2047 is "MIME (Multipurpose Internet Mail Extensions) Part
  28 ;; Three:  Message Header Extensions for Non-ASCII Text".
  29
  30 ;;; Code:
  31
  32 (eval-when-compile
  33   (require 'cl)
  34   (defvar message-posting-charset))
  35
  36 (require 'qp)
  37 (require 'mm-util)
  38 ;; Fixme: Avoid this (used for mail-parse-charset) mm dependence on gnus.
  39 (require 'mail-prsvr)
  40 (require 'base64)
  41 (autoload 'mm-body-7-or-8 "mm-bodies")
  42
  43 (defvar rfc2047-header-encoding-alist
  44   '(("Newsgroups" . nil)
  45     ("Followup-To" . nil)
  46     ("Message-ID" . nil)
  47     ("\\(Resent-\\)?\\(From\\|Cc\\|To\\|Bcc\\|Reply-To\\|Sender\
  48 \\|Mail-Followup-To\\|Mail-Copies-To\\|Approved\\)" . address-mime)
  49     (t . mime))
  50   "*Header/encoding method alist.
  51 The list is traversed sequentially.  The keys can either be
  52 header regexps or t.
  53
  54 The values can be:
  55
  56 1) nil, in which case no encoding is done;
  57 2) `mime', in which case the header will be encoded according to RFC2047;
  58 3) `address-mime', like `mime', but takes account of the rules for address
  59    fields (where quoted strings and comments must be treated separately);
  60 4) a charset, in which case it will be encoded as that charset;
  61 5) `default', in which case the field will be encoded as the rest
  62    of the article.")
  63
  64 (defvar rfc2047-charset-encoding-alist
  65   '((us-ascii . nil)
  66     (iso-8859-1 . Q)
  67     (iso-8859-2 . Q)
  68     (iso-8859-3 . Q)
  69     (iso-8859-4 . Q)
  70     (iso-8859-5 . B)
  71     (koi8-r . B)
  72     (iso-8859-7 . B)
  73     (iso-8859-8 . B)
  74     (iso-8859-9 . Q)
  75     (iso-8859-14 . Q)
  76     (iso-8859-15 . Q)
  77     (iso-2022-jp . B)
  78     (iso-2022-kr . B)
  79     (gb2312 . B)
  80     (big5 . B)
  81     (cn-big5 . B)
  82     (cn-gb . B)
  83     (cn-gb-2312 . B)
  84     (euc-kr . B)
  85     (iso-2022-jp-2 . B)
  86     (iso-2022-int-1 . B)
  87     (viscii . Q))
  88   "Alist of MIME charsets to RFC2047 encodings.
  89 Valid encodings are nil, `Q' and `B'.  These indicate binary (no) encoding,
  90 quoted-printable and base64 respectively.")
  91
  92 (defvar rfc2047-encode-function-alist
  93   '((Q . rfc2047-q-encode-string)
  94     (B . rfc2047-b-encode-string)
  95     (nil . identity))
  96   "Alist of RFC2047 encodings to encoding functions.")
  97
  98 (defvar rfc2047-encode-encoded-words t
  99   "Whether encoded words should be encoded again.")
 100
 101 ;;;
 102 ;;; Functions for encoding RFC2047 messages
 103 ;;;
 104
 105 (defun rfc2047-qp-or-base64 ()
 106   "Return the type with which to encode the buffer.
 107 This is either `base64' or `quoted-printable'."
 108   (save-excursion
 109     (let ((limit (min (point-max) (+ 2000 (point-min))))
 110           (n8bit 0))
 111       (goto-char (point-min))
 112       (skip-chars-forward "\x20-\x7f\r\n\t" limit)
 113       (while (< (point) limit)
 114         (incf n8bit)
 115         (forward-char 1)
 116         (skip-chars-forward "\x20-\x7f\r\n\t" limit))
 117       (if (or (< (* 6 n8bit) (- limit (point-min)))
 118               ;; Don't base64, say, a short line with a single
 119               ;; non-ASCII char when splitting parts by charset.
 120               (= n8bit 1))
 121           'quoted-printable
 122         'base64))))
 123
 124 (defun rfc2047-narrow-to-field ()
 125   "Narrow the buffer to the header on the current line."
 126   (beginning-of-line)
 127   (narrow-to-region
 128    (point)
 129    (progn
 130      (forward-line 1)
 131      (if (re-search-forward "^[^ \n\t]" nil t)
 132          (point-at-bol)
 133        (point-max))))
 134   (goto-char (point-min)))
 135
 136 (defun rfc2047-field-value ()
 137   "Return the value of the field at point."
 138   (save-excursion
 139     (save-restriction
 140       (rfc2047-narrow-to-field)
 141       (re-search-forward ":[ \t\n]*" nil t)
 142       (buffer-substring-no-properties (point) (point-max)))))
 143
 144 (defvar rfc2047-encoding-type 'address-mime
 145   "The type of encoding done by `rfc2047-encode-region'.
 146 This should be dynamically bound around calls to
 147 `rfc2047-encode-region' to either `mime' or `address-mime'.  See
 148 `rfc2047-header-encoding-alist', for definitions.")
 149
 150 (defun rfc2047-encode-message-header ()
 151   "Encode the message header according to `rfc2047-header-encoding-alist'.
 152 Should be called narrowed to the head of the message."
 153   (interactive "*")
 154   (save-excursion
 155     (goto-char (point-min))
 156     (let (alist elem method)
 157       (while (not (eobp))
 158         (save-restriction
 159           (rfc2047-narrow-to-field)
 160           (if (not (rfc2047-encodable-p))
 161               (prog1
 162                   (if (and (eq (mm-body-7-or-8) '8bit)
 163                            (mm-multibyte-p)
 164                            (mm-coding-system-p
 165                             (car message-posting-charset)))
 166                       ;; 8 bit must be decoded.
 167                       (mm-encode-coding-region
 168                        (point-min) (point-max)
 169                        (mm-charset-to-coding-system
 170                         (car message-posting-charset))))
 171                 ;; No encoding necessary, but folding is nice
 172                 (when nil
 173                   (rfc2047-fold-region
 174                    (save-excursion
 175                      (goto-char (point-min))
 176                      (skip-chars-forward "^:")
 177                      (when (looking-at ": ")
 178                        (forward-char 2))
 179                      (point))
 180                    (point-max))))
 181             ;; We found something that may perhaps be encoded.
 182             (setq method nil
 183                   alist rfc2047-header-encoding-alist)
 184             (while (setq elem (pop alist))
 185               (when (or (and (stringp (car elem))
 186                              (looking-at (car elem)))
 187                         (eq (car elem) t))
 188                 (setq alist nil
 189                       method (cdr elem))))
 190             (re-search-forward "^[^:]+: *" nil t)
 191             (cond
 192              ((eq method 'address-mime)
 193               (rfc2047-encode-region (point) (point-max)))
 194              ((eq method 'mime)
 195               (let ((rfc2047-encoding-type 'mime))
 196                 (rfc2047-encode-region (point) (point-max))))
 197              ((eq method 'default)
 198               (if (and (featurep 'mule)
 199                        (if (boundp 'default-enable-multibyte-characters)
 200                            default-enable-multibyte-characters)
 201                        mail-parse-charset)
 202                   (mm-encode-coding-region (point) (point-max)
 203                                            mail-parse-charset)))
 204              ;; We get this when CC'ing messsages to newsgroups with
 205              ;; 8-bit names.  The group name mail copy just got
 206              ;; unconditionally encoded.  Previously, it would ask
 207              ;; whether to encode, which was quite confusing for the
 208              ;; user.  If the new behaviour is wrong, tell me. I have
 209              ;; left the old code commented out below.
 210              ;; -- Per Abrahamsen <abraham@dina.kvl.dk> Date: 2001-10-07.
 211              ;; Modified by Dave Love, with the commented-out code changed
 212              ;; in accordance with changes elsewhere.
 213              ((null method)
 214               (rfc2047-encode-region (point) (point-max)))
 215 ;;;          ((null method)
 216 ;;;           (if (or (message-options-get
 217 ;;;                    'rfc2047-encode-message-header-encode-any)
 218 ;;;                   (message-options-set
 219 ;;;                    'rfc2047-encode-message-header-encode-any
 220 ;;;                    (y-or-n-p
 221 ;;;                     "Some texts are not encoded. Encode anyway?")))
 222 ;;;               (rfc2047-encode-region (point-min) (point-max))
 223 ;;;             (error "Cannot send unencoded text")))
 224              ((mm-coding-system-p method)
 225               (if (and (featurep 'mule)
 226                        (if (boundp 'default-enable-multibyte-characters)
 227                            default-enable-multibyte-characters))
 228                   (mm-encode-coding-region (point) (point-max) method)))
 229              ;; Hm.
 230              (t)))
 231           (goto-char (point-max)))))))
 232
 233 ;; Fixme: This, and the require below may not be the Right Thing, but
 234 ;; should be safe just before release.  -- fx 2001-02-08
 235 (eval-when-compile (defvar message-posting-charset))
 236
 237 (defun rfc2047-encodable-p ()
 238   "Return non-nil if any characters in current buffer need encoding in headers.
 239 The buffer may be narrowed."
 240   (require 'message)                    ; for message-posting-charset
 241   (let ((charsets
 242          (mm-find-mime-charset-region (point-min) (point-max))))
 243     (goto-char (point-min))
 244     (or (and rfc2047-encode-encoded-words
 245              (prog1
 246                  (search-forward "=?" nil t)
 247                (goto-char (point-min))))
 248         (and charsets
 249              (not (equal charsets (list (car message-posting-charset))))))))
 250
 251 ;; Use this syntax table when parsing into regions that may need
 252 ;; encoding.  Double quotes are string delimiters, backslash is
 253 ;; character quoting, and all other RFC 2822 special characters are
 254 ;; treated as punctuation so we can use forward-sexp/forward-word to
 255 ;; skip to the end of regions appropriately.  Nb. ietf-drums does
 256 ;; things differently.
 257 (defconst rfc2047-syntax-table
 258   ;; (make-char-table 'syntax-table '(2)) only works in Emacs.
 259   (let ((table (make-syntax-table)))
 260     ;; The following is done to work for setting all elements of the table
 261     ;; in Emacs 21 and 22 and XEmacs; it appears to be the cleanest way.
 262     ;; Play safe and don't assume the form of the word syntax entry --
 263     ;; copy it from ?a.
 264     (if (fboundp 'set-char-table-range) ; Emacs
 265         (funcall (intern "set-char-table-range")
 266                  table t (aref (standard-syntax-table) ?a))
 267       (if (fboundp 'put-char-table)
 268           (if (fboundp 'get-char-table) ; warning avoidance
 269               (put-char-table t (get-char-table ?a (standard-syntax-table))
 270                               table))))
 271     (modify-syntax-entry ?\\ "\\" table)
 272     (modify-syntax-entry ?\" "\"" table)
 273     (modify-syntax-entry ?\( "(" table)
 274     (modify-syntax-entry ?\) ")" table)
 275     (modify-syntax-entry ?\< "." table)
 276     (modify-syntax-entry ?\> "." table)
 277     (modify-syntax-entry ?\[ "." table)
 278     (modify-syntax-entry ?\] "." table)
 279     (modify-syntax-entry ?: "." table)
 280     (modify-syntax-entry ?\; "." table)
 281     (modify-syntax-entry ?, "." table)
 282     (modify-syntax-entry ?@ "." table)
 283     table))
 284
 285 (defun rfc2047-encode-region (b e)
 286   "Encode words in region B to E that need encoding.
 287 By default, the region is treated as containing RFC2822 addresses.
 288 Dynamically bind `rfc2047-encoding-type' to change that."
 289   (save-restriction
 290     (narrow-to-region b e)
 291     (let ((encodable-regexp (if rfc2047-encode-encoded-words
 292                                 "[^\000-\177]+\\|=\\?"
 293                               "[^\000-\177]+"))
 294           start                         ; start of current token
 295           end begin
 296           ;; Whether there's an encoded word before the current token,
 297           ;; either immediately or separated by space.
 298           last-encoded
 299           (orig-text (buffer-substring-no-properties b e)))
 300       (if (eq 'mime rfc2047-encoding-type)
 301           ;; Simple case.  Continuous words in which all those contain
 302           ;; non-ASCII characters are encoded collectively.  Encoding
 303           ;; ASCII words, including `Re:' used in Subject headers, is
 304           ;; avoided for interoperability with non-MIME clients and
 305           ;; for making it easy to find keywords.
 306           (progn
 307             (goto-char (point-min))
 308             (while (progn (skip-chars-forward " \t\n")
 309                           (not (eobp)))
 310               (setq start (point))
 311               (while (and (looking-at "[ \t\n]*\\([^ \t\n]+\\)")
 312                           (progn
 313                             (setq end (match-end 0))
 314                             (re-search-forward encodable-regexp end t)))
 315                 (goto-char end))
 316               (if (> (point) start)
 317                   (rfc2047-encode start (point))
 318                 (goto-char end))))
 319         ;; `address-mime' case -- take care of quoted words, comments.
 320         (with-syntax-table rfc2047-syntax-table
 321           (goto-char (point-min))
 322           (condition-case nil           ; in case of unbalanced quotes
 323               ;; Look for rfc2822-style: sequences of atoms, quoted
 324               ;; strings, specials, whitespace.  (Specials mustn't be
 325               ;; encoded.)
 326               (while (not (eobp))
 327                 ;; Skip whitespace.
 328                 (skip-chars-forward " \t\n")
 329                 (setq start (point))
 330                 (cond
 331                  ((not (char-after)))   ; eob
 332                  ;; else token start
 333                  ((eq ?\" (char-syntax (char-after)))
 334                   ;; Quoted word.
 335                   (forward-sexp)
 336                   (setq end (point))
 337                   ;; Does it need encoding?
 338                   (goto-char start)
 339                   (if (re-search-forward encodable-regexp end 'move)
 340                       ;; It needs encoding.  Strip the quotes first,
 341                       ;; since encoded words can't occur in quotes.
 342                       (progn
 343                         (goto-char end)
 344                         (delete-backward-char 1)
 345                         (goto-char start)
 346                         (delete-char 1)
 347                         (when last-encoded
 348                           ;; There was a preceding quoted word.  We need
 349                           ;; to include any separating whitespace in this
 350                           ;; word to avoid it getting lost.
 351                           (skip-chars-backward " \t")
 352                           ;; A space is needed between the encoded words.
 353                           (insert ? )
 354                           (setq start (point)
 355                                 end (1+ end)))
 356                         ;; Adjust the end position for the deleted quotes.
 357                         (rfc2047-encode start (- end 2))
 358                         (setq last-encoded t)) ; record that it was encoded
 359                     (setq last-encoded  nil)))
 360                  ((eq ?. (char-syntax (char-after)))
 361                   ;; Skip other delimiters, but record that they've
 362                   ;; potentially separated quoted words.
 363                   (forward-char)
 364                   (setq last-encoded nil))
 365                  ((eq ?\) (char-syntax (char-after)))
 366                   (error "Unbalanced parentheses"))
 367                  ((eq ?\( (char-syntax (char-after)))
 368                   ;; Look for the end of parentheses.
 369                   (forward-list)
 370                   ;; Encode text as an unstructured field.
 371                   (let ((rfc2047-encoding-type 'mime))
 372                     (rfc2047-encode-region (1+ start) (1- (point)))
 373                     (forward-char)))
 374                  (t                 ; normal token/whitespace sequence
 375                   ;; Find the end.
 376                   ;; Skip one ASCII word, or encode continuous words
 377                   ;; in which all those contain non-ASCII characters.
 378                   (setq end nil)
 379                   (while (not end)
 380                     (when (looking-at "[\000-\177]+")
 381                       (setq begin (point)
 382                             end (match-end 0))
 383                       (if (re-search-forward "[ \t\n]\\|\\Sw" end 'move)
 384                           (progn
 385                             (setq end (match-beginning 0))
 386                             (if rfc2047-encode-encoded-words
 387                                 (progn
 388                                   (goto-char begin)
 389                                   (when (search-forward "=?" end 'move)
 390                                     (goto-char (match-beginning 0))
 391                                     (setq end nil)))
 392                               (goto-char end)))
 393                         (setq end nil)))
 394                     (unless end
 395                       (setq end t)
 396                       (when (looking-at encodable-regexp)
 397                         (goto-char (match-end 0))
 398                         (while (and (looking-at "[ \t\n]+\\([^ \t\n]+\\)")
 399                                     (setq end (match-end 0))
 400                                     (string-match encodable-regexp
 401                                                   (match-string 1)))
 402                           (goto-char end))
 403                         (when (looking-at "[^ \t\n]+")
 404                           (setq end (match-end 0))
 405                           (if (re-search-forward "\\Sw+" end t)
 406                               ;; There are special characters better
 407                               ;; to be encoded so that MTAs may parse
 408                               ;; them safely.
 409                               (cond ((= end (point)))
 410                                     ((looking-at encodable-regexp)
 411                                      (setq end nil))
 412                                     (t
 413                                      (goto-char (1- (match-end 0)))
 414                                      (unless (= (point) (match-beginning 0))
 415                                        (insert " "))))
 416                             (goto-char end)
 417                             (skip-chars-forward " \t\n")
 418                             (if (and (looking-at "[^ \t\n]+")
 419                                      (string-match encodable-regexp
 420                                                    (match-string 0)))
 421                                 (setq end nil)
 422                               (goto-char end)))))))
 423                   (skip-chars-backward " \t\n")
 424                   (setq end (point))
 425                   (goto-char start)
 426                   (if (re-search-forward encodable-regexp end 'move)
 427                       (progn
 428                         (rfc2047-encode start end)
 429                         (setq last-encoded t))
 430                     (setq last-encoded nil)))))
 431             (error
 432              (error "Invalid data for rfc2047 encoding: %s"
 433                     (mm-replace-in-string orig-text "[ \t\n]+" " ")))))))
 434     (rfc2047-fold-region b (point))))
 435
 436 (defun rfc2047-encode-string (string)
 437   "Encode words in STRING.
 438 By default, the string is treated as containing addresses (see
 439 `rfc2047-encoding-type')."
 440   (with-temp-buffer
 441     (insert string)
 442     (rfc2047-encode-region (point-min) (point-max))
 443     (buffer-string)))
 444
 445 (defun rfc2047-encode-1 (column string cs encoder start space &optional eword)
 446   "Subroutine used by `rfc2047-encode'."
 447   (cond ((string-equal string "")
 448          (or eword ""))
 449         ((>= column 76)
 450          (when (and eword
 451                     (string-match "\n[ \t]+\\'" eword))
 452            ;; Reomove a superfluous empty line.
 453            (setq eword (substring eword 0 (match-beginning 0))))
 454          (rfc2047-encode-1 (length space) string cs encoder start " "
 455                            (concat eword "\n" space)))
 456         (t
 457          (let ((index 0)
 458                (limit (1- (length string)))
 459                (prev "")
 460                next)
 461            (while (and prev
 462                        (<= index limit))
 463              (setq next (concat start
 464                                 (funcall encoder
 465                                          (if cs
 466                                              (mm-encode-coding-string
 467                                               (substring string 0 (1+ index))
 468                                               cs)
 469                                            (substring string 0 (1+ index))))
 470                                 "?="))
 471              (if (<= (+ column (length next)) 76)
 472                  (setq prev next
 473                        index (1+ index))
 474                (setq next prev
 475                      prev nil)))
 476            (setq eword (concat eword next))
 477            (if (> index limit)
 478                eword
 479              (when (string-match "\n[ \t]+\\'" eword)
 480                ;; Reomove a superfluous empty line.
 481                (setq eword (substring eword 0 (match-beginning 0))))
 482              (rfc2047-encode-1 (length space) (substring string index)
 483                                cs encoder start " "
 484                                (concat eword "\n" space)))))))
 485
 486 (defun rfc2047-encode (b e)
 487   "Encode the word(s) in the region B to E.
 488 Point moves to the end of the region."
 489   (let ((mime-charset (or (mm-find-mime-charset-region b e) (list 'us-ascii)))
 490         cs encoding space eword)
 491     (cond ((> (length mime-charset) 1)
 492            (error "Can't rfc2047-encode `%s'"
 493                   (buffer-substring-no-properties b e)))
 494           ((= (length mime-charset) 1)
 495            (setq mime-charset (car mime-charset)
 496                  cs (mm-charset-to-coding-system mime-charset))
 497            (unless (and (mm-multibyte-p)
 498                         (mm-coding-system-p cs))
 499              (setq cs nil))
 500            (save-restriction
 501              (narrow-to-region b e)
 502              (setq encoding
 503                    (or (cdr (assq mime-charset
 504                                   rfc2047-charset-encoding-alist))
 505                        ;; For the charsets that don't have a preferred
 506                        ;; encoding, choose the one that's shorter.
 507                        (if (eq (rfc2047-qp-or-base64) 'base64)
 508                            'B
 509                          'Q)))
 510              (widen)
 511              (goto-char b)
 512              (setq b (point-marker)
 513                    e (set-marker (make-marker) e))
 514              (rfc2047-fold-region (point-at-bol) b)
 515              (unless (= 0 (skip-chars-backward " \t"))
 516                (setq space (buffer-substring-no-properties (point) b)))
 517              (setq eword (rfc2047-encode-1
 518                           (- b (point-at-bol))
 519                           (mm-replace-in-string
 520                            (buffer-substring-no-properties b e)
 521                            "\n\\([ \t]?\\)" "\\1")
 522                           cs
 523                           (or (cdr (assq encoding
 524                                          rfc2047-encode-function-alist))
 525                               'identity)
 526                           (concat "=?" (downcase (symbol-name mime-charset))
 527                                   "?" (upcase (symbol-name encoding)) "?")
 528                           (or space " ")))
 529              (delete-region (if (eq (aref eword 0) ?\n)
 530                                 (point)
 531                               (goto-char b))
 532                             e)
 533              (insert eword)
 534              (set-marker b nil)
 535              (set-marker e nil)
 536              (unless (or (eolp)
 537                          (looking-at "[ \t\n)]"))
 538                (insert " "))))
 539           (t
 540            (goto-char e)))))
 541
 542 (defun rfc2047-fold-field ()
 543   "Fold the current header field."
 544   (save-excursion
 545     (save-restriction
 546       (rfc2047-narrow-to-field)
 547       (rfc2047-fold-region (point-min) (point-max)))))
 548
 549 (defun rfc2047-fold-region (b e)
 550   "Fold long lines in region B to E."
 551   (save-restriction
 552     (narrow-to-region b e)
 553     (goto-char (point-min))
 554     (let ((break nil)
 555           (qword-break nil)
 556           (first t)
 557           (bol (save-restriction
 558                  (widen)
 559                  (point-at-bol))))
 560       (while (not (eobp))
 561         (when (and (or break qword-break)
 562                    (> (- (point) bol) 76))
 563           (goto-char (or break qword-break))
 564           (setq break nil
 565                 qword-break nil)
 566           (skip-chars-backward " \t")
 567           (if (looking-at "[ \t]")
 568               (insert ?\n)
 569             (insert "\n "))
 570           (setq bol (1- (point)))
 571           ;; Don't break before the first non-LWSP characters.
 572           (skip-chars-forward " \t")
 573           (unless (eobp)
 574             (forward-char 1)))
 575         (cond
 576          ((eq (char-after) ?\n)
 577           (forward-char 1)
 578           (setq bol (point)
 579                 break nil
 580                 qword-break nil)
 581           (skip-chars-forward " \t")
 582           (unless (or (eobp) (eq (char-after) ?\n))
 583             (forward-char 1)))
 584          ((eq (char-after) ?\r)
 585           (forward-char 1))
 586          ((memq (char-after) '(?  ?\t))
 587           (skip-chars-forward " \t")
 588           (unless first ;; Don't break just after the header name.
 589             (setq break (point))))
 590          ((not break)
 591           (if (not (looking-at "=\\?[^=]"))
 592               (if (eq (char-after) ?=)
 593                   (forward-char 1)
 594                 (skip-chars-forward "^ \t\n\r="))
 595             ;; Don't break at the start of the field.
 596             (unless (= (point) b)
 597               (setq qword-break (point)))
 598             (skip-chars-forward "^ \t\n\r")))
 599          (t
 600           (skip-chars-forward "^ \t\n\r")))
 601         (setq first nil))
 602       (when (and (or break qword-break)
 603                  (> (- (point) bol) 76))
 604         (goto-char (or break qword-break))
 605         (setq break nil
 606               qword-break nil)
 607           (if (looking-at "[ \t]")
 608               (insert ?\n)
 609             (insert "\n "))
 610         (setq bol (1- (point)))
 611         ;; Don't break before the first non-LWSP characters.
 612         (skip-chars-forward " \t")
 613         (unless (eobp)
 614           (forward-char 1))))))
 615
 616 (defun rfc2047-unfold-field ()
 617   "Fold the current line."
 618   (save-excursion
 619     (save-restriction
 620       (rfc2047-narrow-to-field)
 621       (rfc2047-unfold-region (point-min) (point-max)))))
 622
 623 (defun rfc2047-unfold-region (b e)
 624   "Unfold lines in region B to E."
 625   (save-restriction
 626     (narrow-to-region b e)
 627     (goto-char (point-min))
 628     (let ((bol (save-restriction
 629                  (widen)
 630                  (point-at-bol)))
 631           (eol (point-at-eol)))
 632       (forward-line 1)
 633       (while (not (eobp))
 634         (if (and (looking-at "[ \t]")
 635                  (< (- (point-at-eol) bol) 76))
 636             (delete-region eol (progn
 637                                  (goto-char eol)
 638                                  (skip-chars-forward "\r\n")
 639                                  (point)))
 640           (setq bol (point-at-bol)))
 641         (setq eol (point-at-eol))
 642         (forward-line 1)))))
 643
 644 (defun rfc2047-b-encode-string (string)
 645   "Base64-encode the header contained in STRING."
 646   (base64-encode-string string t))
 647
 648 (defun rfc2047-q-encode-string (string)
 649   "Quoted-printable-encode the header in STRING."
 650   (mm-with-unibyte-buffer
 651     (insert string)
 652     (quoted-printable-encode-region
 653      (point-min) (point-max) nil
 654      ;; = (\075), _ (\137), ? (\077) are used in the encoded word.
 655      ;; Avoid using 8bit characters.
 656      ;; This list excludes `especials' (see the RFC2047 syntax),
 657      ;; meaning that some characters in non-structured fields will
 658      ;; get encoded when they con't need to be.  The following is
 659      ;; what it used to be.
 660      ;;;  ;; Equivalent to "^\000-\007\011\013\015-\037\200-\377=_?"
 661      ;;;  "\010\012\014\040-\074\076\100-\136\140-\177")
 662      "-\b\n\f !#-'*+0-9A-Z\\^`-~\d")
 663     (subst-char-in-region (point-min) (point-max) ?  ?_)
 664     (buffer-string)))
 665
 666 ;;;
 667 ;;; Functions for decoding RFC2047 messages
 668 ;;;
 669
 670 (eval-and-compile
 671   (defconst rfc2047-encoded-word-regexp
 672     "=\\?\\([^][\000-\040()<>@,\;:*\\\"/?.=]+\\)\\(?:\\*[^?]+\\)?\
 673 \\?\\(B\\|Q\\)\\?\\([!->@-~ ]*\\)\\?="))
 674
 675 ;; Fixme: This should decode in place, not cons intermediate strings.
 676 ;; Also check whether it needs to worry about delimiting fields like
 677 ;; encoding.
 678
 679 ;; In fact it's reported that (invalid) encoding of mailboxes in
 680 ;; addr-specs is in use, so delimiting fields might help.  Probably
 681 ;; not decoding a word which isn't properly delimited is good enough
 682 ;; and worthwhile (is it more correct or not?), e.g. something like
 683 ;; `=?iso-8859-1?q?foo?=@'.
 684
 685 (defun rfc2047-decode-region (start end)
 686   "Decode MIME-encoded words in region between START and END."
 687   (interactive "r")
 688   (let ((case-fold-search t)
 689         b e)
 690     (save-excursion
 691       (save-restriction
 692         (narrow-to-region start end)
 693         (goto-char (point-min))
 694         ;; Remove whitespace between encoded words.
 695         (while (re-search-forward
 696                 (eval-when-compile
 697                   (concat "\\(" rfc2047-encoded-word-regexp "\\)"
 698                           "\\(\n?[ \t]\\)+"
 699                           "\\(" rfc2047-encoded-word-regexp "\\)"))
 700                 nil t)
 701           (delete-region (goto-char (match-end 1)) (match-beginning 6)))
 702         ;; Decode the encoded words.
 703         (setq b (goto-char (point-min)))
 704         (while (re-search-forward rfc2047-encoded-word-regexp nil t)
 705           (setq e (match-beginning 0))
 706           (insert (rfc2047-parse-and-decode
 707                    (prog1
 708                        (match-string 0)
 709                      (delete-region (match-beginning 0) (match-end 0)))))
 710           ;; Remove newlines between decoded words, though such things
 711           ;; essentially must not be there.
 712           (save-restriction
 713             (narrow-to-region e (point))
 714             (goto-char e)
 715             (while (re-search-forward "[\n\r]+" nil t)
 716               (replace-match " "))
 717             (goto-char (point-max)))
 718           (when (and (mm-multibyte-p)
 719                      mail-parse-charset
 720                      (not (eq mail-parse-charset 'us-ascii))
 721                      (not (eq mail-parse-charset 'gnus-decoded)))
 722             (mm-decode-coding-region b e mail-parse-charset))
 723           (setq b (point)))
 724         (when (and (mm-multibyte-p)
 725                    mail-parse-charset
 726                    (not (eq mail-parse-charset 'us-ascii))
 727                    (not (eq mail-parse-charset 'gnus-decoded)))
 728           (mm-decode-coding-region b (point-max) mail-parse-charset))))))
 729
 730 (defun rfc2047-decode-string (string)
 731   "Decode the quoted-printable-encoded STRING and return the results."
 732   (let ((m (mm-multibyte-p)))
 733     (if (string-match "=\\?" string)
 734         (with-temp-buffer
 735           ;; Fixme: This logic is wrong, but seems to be required by
 736           ;; Gnus summary buffer generation.  The value of `m' depends
 737           ;; on the current buffer, not global multibyteness or that
 738           ;; of the string.  Also the string returned should always be
 739           ;; multibyte in a multibyte session, i.e. the buffer should
 740           ;; be multibyte before `buffer-string' is called.
 741           (when m
 742             (mm-enable-multibyte))
 743           (insert string)
 744           (inline
 745             (rfc2047-decode-region (point-min) (point-max)))
 746           (buffer-string))
 747       ;; Fixme: As above, `m' here is inappropriate.
 748       (if (and m
 749                mail-parse-charset
 750                (not (eq mail-parse-charset 'us-ascii))
 751                (not (eq mail-parse-charset 'gnus-decoded)))
 752           ;; `decode-coding-string' in Emacs offers a third optional
 753           ;; arg NOCOPY to avoid consing a new string if the decoding
 754           ;; is "trivial".  Unfortunately it currently doesn't
 755           ;; consider anything else than a `nil' coding system
 756           ;; trivial.
 757           ;; `rfc2047-decode-string' is called multiple times for each
 758           ;; article during summary buffer generation, and we really
 759           ;; want to avoid unnecessary consing.  So we bypass
 760           ;; `decode-coding-string' if the string is purely ASCII.
 761           (if (and (fboundp 'detect-coding-string)
 762                    ;; string is purely ASCII
 763                    (eq (detect-coding-string string t) 'undecided))
 764               string
 765             (mm-decode-coding-string string mail-parse-charset))
 766         (mm-string-as-multibyte string)))))
 767
 768 (defun rfc2047-parse-and-decode (word)
 769   "Decode WORD and return it if it is an encoded word.
 770 Return WORD if it is not not an encoded word or if the charset isn't
 771 decodable."
 772   (if (not (string-match rfc2047-encoded-word-regexp word))
 773       word
 774     (or
 775      (condition-case nil
 776          (rfc2047-decode
 777           (match-string 1 word)
 778           (string-to-char (match-string 2 word))
 779           (match-string 3 word))
 780        (error word))
 781      word)))                            ; un-decodable
 782
 783 (defun rfc2047-pad-base64 (string)
 784   "Pad STRING to quartets."
 785   ;; Be more liberal to accept buggy base64 strings. If
 786   ;; base64-decode-string accepts buggy strings, this function could
 787   ;; be aliased to identity.
 788   (if (= 0 (mod (length string) 4))
 789       string
 790     (when (string-match "=+$" string)
 791       (setq string (substring string 0 (match-beginning 0))))
 792     (case (mod (length string) 4)
 793       (0 string)
 794       (1 string) ;; Error, don't pad it.
 795       (2 (concat string "=="))
 796       (3 (concat string "=")))))
 797
 798 (defun rfc2047-decode (charset encoding string)
 799   "Decode STRING from the given MIME CHARSET in the given ENCODING.
 800 Valid ENCODINGs are the characters \"B\" and \"Q\".
 801 If your Emacs implementation can't decode CHARSET, return nil."
 802   (if (stringp charset)
 803       (setq charset (intern (downcase charset))))
 804   (if (or (not charset)
 805           (eq 'gnus-all mail-parse-ignored-charsets)
 806           (memq 'gnus-all mail-parse-ignored-charsets)
 807           (memq charset mail-parse-ignored-charsets))
 808       (setq charset mail-parse-charset))
 809   (let ((cs (mm-charset-to-coding-system charset)))
 810     (if (and (not cs) charset
 811              (listp mail-parse-ignored-charsets)
 812              (memq 'gnus-unknown mail-parse-ignored-charsets))
 813         (setq cs (mm-charset-to-coding-system mail-parse-charset)))
 814     (when cs
 815       (when (eq cs 'ascii)
 816         (setq cs (or mail-parse-charset 'raw-text)))
 817       (mm-decode-coding-string
 818        (cond
 819         ((char-equal ?B encoding)
 820          (base64-decode-string
 821           (rfc2047-pad-base64 string)))
 822         ((char-equal ?Q encoding)
 823          (quoted-printable-decode-string
 824           (mm-subst-char-in-string ?_ ? string t)))
 825         (t (error "Invalid encoding: %c" encoding)))
 826        cs))))
 827
 828 (provide 'rfc2047)
 829
 830 ;;; arch-tag: a07fe3d4-22b5-4c4a-bd89-b1f82d5d36f6
 831 ;;; rfc2047.el ends here