cgit.sxemacs.org Git - gnus/blob - lisp/rfc2047.el

   1 ;;; rfc2047.el --- functions for encoding and decoding rfc2047 messages
   2 ;; Copyright (C) 1998, 1999, 2000, 2002, 2003 Free Software Foundation, Inc.
   3
   4 ;; Author: Lars Magne Ingebrigtsen <larsi@gnus.org>
   5 ;;      MORIOKA Tomohiko <morioka@jaist.ac.jp>
   6 ;; This file is part of GNU Emacs.
   7
   8 ;; GNU Emacs is free software; you can redistribute it and/or modify
   9 ;; it under the terms of the GNU General Public License as published by
  10 ;; the Free Software Foundation; either version 2, or (at your option)
  11 ;; any later version.
  12
  13 ;; GNU Emacs is distributed in the hope that it will be useful,
  14 ;; but WITHOUT ANY WARRANTY; without even the implied warranty of
  15 ;; MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.  See the
  16 ;; GNU General Public License for more details.
  17
  18 ;; You should have received a copy of the GNU General Public License
  19 ;; along with GNU Emacs; see the file COPYING.  If not, write to the
  20 ;; Free Software Foundation, Inc., 59 Temple Place - Suite 330,
  21 ;; Boston, MA 02111-1307, USA.
  22
  23 ;;; Commentary:
  24
  25 ;; RFC 2047 is "MIME (Multipurpose Internet Mail Extensions) Part
  26 ;; Three:  Message Header Extensions for Non-ASCII Text".
  27
  28 ;;; Code:
  29
  30 (eval-when-compile
  31   (require 'cl)
  32   (defvar message-posting-charset)
  33   (unless (fboundp 'with-syntax-table)  ; not in Emacs 20
  34     (defmacro with-syntax-table (table &rest body)
  35       "Evaluate BODY with syntax table of current buffer set to TABLE.
  36 The syntax table of the current buffer is saved, BODY is evaluated, and the
  37 saved table is restored, even in case of an abnormal exit.
  38 Value is what BODY returns."
  39       (let ((old-table (make-symbol "table"))
  40             (old-buffer (make-symbol "buffer")))
  41         `(let ((,old-table (syntax-table))
  42                (,old-buffer (current-buffer)))
  43            (unwind-protect
  44                (progn
  45                  (set-syntax-table ,table)
  46                  ,@body)
  47              (save-current-buffer
  48                (set-buffer ,old-buffer)
  49                (set-syntax-table ,old-table))))))))
  50
  51 (require 'qp)
  52 (require 'mm-util)
  53 ;; Fixme: Avoid this (used for mail-parse-charset) mm dependence on gnus.
  54 (require 'mail-prsvr)
  55 (require 'base64)
  56 (autoload 'mm-body-7-or-8 "mm-bodies")
  57
  58 (eval-and-compile
  59   ;; Avoid gnus-util for mm- code.
  60   (defalias 'rfc2047-point-at-bol
  61     (if (fboundp 'point-at-bol)
  62         'point-at-bol
  63       'line-beginning-position))
  64
  65   (defalias 'rfc2047-point-at-eol
  66     (if (fboundp 'point-at-eol)
  67         'point-at-eol
  68       'line-end-position)))
  69
  70 (defvar rfc2047-header-encoding-alist
  71   '(("Newsgroups" . nil)
  72     ("Followup-To" . nil)
  73     ("Message-ID" . nil)
  74     ("\\(Resent-\\)?\\(From\\|Cc\\|To\\|Bcc\\|Reply-To\\|Sender\
  75 \\|Mail-Followup-To\\|Mail-Copies-To\\)" . address-mime)
  76     (t . mime))
  77   "*Header/encoding method alist.
  78 The list is traversed sequentially.  The keys can either be
  79 header regexps or t.
  80
  81 The values can be:
  82
  83 1) nil, in which case no encoding is done;
  84 2) `mime', in which case the header will be encoded according to RFC2047;
  85 3) `address-mime', like `mime', but takes account of the rules for address
  86    fields (where quoted strings and comments must be treated separately);
  87 4) a charset, in which case it will be encoded as that charset;
  88 5) `default', in which case the field will be encoded as the rest
  89    of the article.")
  90
  91 (defvar rfc2047-charset-encoding-alist
  92   '((us-ascii . nil)
  93     (iso-8859-1 . Q)
  94     (iso-8859-2 . Q)
  95     (iso-8859-3 . Q)
  96     (iso-8859-4 . Q)
  97     (iso-8859-5 . B)
  98     (koi8-r . B)
  99     (iso-8859-7 . B)
 100     (iso-8859-8 . B)
 101     (iso-8859-9 . Q)
 102     (iso-8859-14 . Q)
 103     (iso-8859-15 . Q)
 104     (iso-2022-jp . B)
 105     (iso-2022-kr . B)
 106     (gb2312 . B)
 107     (big5 . B)
 108     (cn-big5 . B)
 109     (cn-gb . B)
 110     (cn-gb-2312 . B)
 111     (euc-kr . B)
 112     (iso-2022-jp-2 . B)
 113     (iso-2022-int-1 . B))
 114   "Alist of MIME charsets to RFC2047 encodings.
 115 Valid encodings are nil, `Q' and `B'.  These indicate binary (no) encoding,
 116 quoted-printable and base64 respectively.")
 117
 118 (defvar rfc2047-encoding-function-alist
 119   '((Q . rfc2047-q-encode-region)
 120     (B . rfc2047-b-encode-region)
 121     (nil . ignore))
 122   "Alist of RFC2047 encodings to encoding functions.")
 123
 124 ;;;
 125 ;;; Functions for encoding RFC2047 messages
 126 ;;;
 127
 128 (defun rfc2047-narrow-to-field ()
 129   "Narrow the buffer to the header on the current line."
 130   (beginning-of-line)
 131   (narrow-to-region
 132    (point)
 133    (progn
 134      (forward-line 1)
 135      (if (re-search-forward "^[^ \n\t]" nil t)
 136          (rfc2047-point-at-bol)
 137        (point-max))))
 138   (goto-char (point-min)))
 139
 140 (defun rfc2047-field-value ()
 141   "Return the value of the field at point."
 142   (save-excursion
 143     (save-restriction
 144       (rfc2047-narrow-to-field)
 145       (re-search-forward ":[ \t\n]*" nil t)
 146       (buffer-substring (point) (point-max)))))
 147
 148 (defvar rfc2047-encoding-type 'address-mime
 149   "The type of encoding done by `rfc2047-encode-region'.
 150 This should be dynamically bound around calls to
 151 `rfc2047-encode-region' to either `mime' or `address-mime'.  See
 152 `rfc2047-header-encoding-alist', for definitions.")
 153
 154 (defun rfc2047-encode-message-header ()
 155   "Encode the message header according to `rfc2047-header-encoding-alist'.
 156 Should be called narrowed to the head of the message."
 157   (interactive "*")
 158   (save-excursion
 159     (goto-char (point-min))
 160     (let (alist elem method)
 161       (while (not (eobp))
 162         (save-restriction
 163           (rfc2047-narrow-to-field)
 164           (if (not (rfc2047-encodable-p))
 165               (prog1
 166                 (if (and (eq (mm-body-7-or-8) '8bit)
 167                          (mm-multibyte-p)
 168                          (mm-coding-system-p
 169                           (car message-posting-charset)))
 170                     ;; 8 bit must be decoded.
 171                     (mm-encode-coding-region
 172                      (point-min) (point-max)
 173                      (mm-charset-to-coding-system
 174                       (car message-posting-charset))))
 175                 ;; No encoding necessary, but folding is nice
 176                 (rfc2047-fold-region
 177                  (save-excursion
 178                    (goto-char (point-min))
 179                    (skip-chars-forward "^:")
 180                    (when (looking-at ": ")
 181                      (forward-char 2))
 182                    (point))
 183                  (point-max)))
 184             ;; We found something that may perhaps be encoded.
 185             (setq method nil
 186                   alist rfc2047-header-encoding-alist)
 187             (while (setq elem (pop alist))
 188               (when (or (and (stringp (car elem))
 189                              (looking-at (car elem)))
 190                         (eq (car elem) t))
 191                 (setq alist nil
 192                       method (cdr elem))))
 193             (goto-char (point-min))
 194             (re-search-forward "^[^:]+: *" nil t)
 195             (cond
 196              ((eq method 'address-mime)
 197               (rfc2047-encode-region (point) (point-max)))
 198              ((eq method 'mime)
 199               (let ((rfc2047-encoding-type 'mime))
 200                 (rfc2047-encode-region (point) (point-max))))
 201              ((eq method 'default)
 202               (if (and (featurep 'mule)
 203                        (if (boundp 'default-enable-multibyte-characters)
 204                            default-enable-multibyte-characters)
 205                        mail-parse-charset)
 206                   (mm-encode-coding-region (point) (point-max)
 207                                            mail-parse-charset)))
 208              ;; We get this when CC'ing messsages to newsgroups with
 209              ;; 8-bit names.  The group name mail copy just got
 210              ;; unconditionally encoded.  Previously, it would ask
 211              ;; whether to encode, which was quite confusing for the
 212              ;; user.  If the new behaviour is wrong, tell me. I have
 213              ;; left the old code commented out below.
 214              ;; -- Per Abrahamsen <abraham@dina.kvl.dk> Date: 2001-10-07.
 215              ;; Modified by Dave Love, with the commented-out code changed
 216              ;; in accordance with changes elsewhere.
 217              ((null method)
 218               (rfc2047-encode-region (point) (point-max)))
 219 ;;;          ((null method)
 220 ;;;           (if (or (message-options-get
 221 ;;;                    'rfc2047-encode-message-header-encode-any)
 222 ;;;                   (message-options-set
 223 ;;;                    'rfc2047-encode-message-header-encode-any
 224 ;;;                    (y-or-n-p
 225 ;;;                     "Some texts are not encoded. Encode anyway?")))
 226 ;;;               (rfc2047-encode-region (point-min) (point-max))
 227 ;;;             (error "Cannot send unencoded text")))
 228              ((mm-coding-system-p method)
 229               (if (and (featurep 'mule)
 230                        (if (boundp 'default-enable-multibyte-characters)
 231                            default-enable-multibyte-characters))
 232                   (mm-encode-coding-region (point) (point-max) method)))
 233              ;; Hm.
 234              (t)))
 235           (goto-char (point-max)))))))
 236
 237 ;; Fixme: This, and the require below may not be the Right Thing, but
 238 ;; should be safe just before release.  -- fx 2001-02-08
 239 (eval-when-compile (defvar message-posting-charset))
 240
 241 (defun rfc2047-encodable-p ()
 242   "Return non-nil if any characters in current buffer need encoding in headers.
 243 The buffer may be narrowed."
 244   (require 'message)                    ; for message-posting-charset
 245   (let ((charsets
 246          (mm-find-mime-charset-region (point-min) (point-max))))
 247     (and charsets
 248          (not (equal charsets (list (car message-posting-charset)))))))
 249
 250 ;; Use this syntax table when parsing into regions that may need
 251 ;; encoding.  Double quotes are string delimiters, backslash is
 252 ;; character quoting, and all other RFC 2822 special characters are
 253 ;; treated as punctuation so we can use forward-sexp/forward-word to
 254 ;; skip to the end of regions appropriately.  Nb. ietf-drums does
 255 ;; things differently.
 256 (defconst rfc2047-syntax-table
 257   ;; (make-char-table 'syntax-table '(2)) only works in Emacs.
 258   (let ((table (make-syntax-table)))
 259     ;; The following is done to work for setting all elements of the table
 260     ;; in Emacs 21 and 22 and XEmacs; it appears to be the cleanest way.
 261     ;; Play safe and don't assume the form of the word syntax entry --
 262     ;; copy it from ?a.
 263     (if (fboundp 'set-char-table-range) ; Emacs
 264         (funcall (intern "set-char-table-range")
 265                  table t (aref (standard-syntax-table) ?a))
 266       (if (fboundp 'put-char-table)
 267           (if (fboundp 'get-char-table) ; warning avoidance
 268               (put-char-table t (get-char-table ?a (standard-syntax-table))
 269                               table))))
 270     (modify-syntax-entry ?\\ "\\" table)
 271     (modify-syntax-entry ?\" "\"" table)
 272     (modify-syntax-entry ?\( "." table)
 273     (modify-syntax-entry ?\) "." table)
 274     (modify-syntax-entry ?\< "." table)
 275     (modify-syntax-entry ?\> "." table)
 276     (modify-syntax-entry ?\[ "." table)
 277     (modify-syntax-entry ?\] "." table)
 278     (modify-syntax-entry ?: "." table)
 279     (modify-syntax-entry ?\; "." table)
 280     (modify-syntax-entry ?, "." table)
 281     (modify-syntax-entry ?@ "." table)
 282     table))
 283
 284 (defun rfc2047-encode-region (b e)
 285   "Encode words in region B to E that need encoding.
 286 By default, the region is treated as containing RFC2822 addresses.
 287 Dynamically bind `rfc2047-encoding-type' to change that."
 288   (save-restriction
 289     (narrow-to-region b e)
 290     (if (eq 'mime rfc2047-encoding-type)
 291         ;; Simple case.  Treat as single word after any initial ASCII
 292         ;; part and before any tailing ASCII part.  The leading ASCII
 293         ;; is relevant for instance in Subject headers with `Re:' for
 294         ;; interoperability with non-MIME clients, and we might as
 295         ;; well avoid the tail too.
 296         (progn
 297           (goto-char (point-min))
 298           ;; Does it need encoding?
 299           (skip-chars-forward "\000-\177")
 300           (unless (eobp)
 301             (skip-chars-backward "^ \n") ; beginning of space-delimited word
 302             (rfc2047-encode (point) (progn
 303                                       (goto-char e)
 304                                       (skip-chars-backward "\000-\177")
 305                                       (skip-chars-forward "^ \n")
 306                                       ;; end of space-delimited word
 307                                       (point)))))
 308       ;; `address-mime' case -- take care of quoted words, comments.
 309       (with-syntax-table rfc2047-syntax-table
 310         (let ((start)                   ; start of current token
 311               end                       ; end of current token
 312               ;; Whether there's an encoded word before the current
 313               ;; token, either immediately or separated by space.
 314               last-encoded)
 315           (goto-char (point-min))
 316           (condition-case nil           ; in case of unbalanced quotes
 317               ;; Look for rfc2822-style: sequences of atoms, quoted
 318               ;; strings, specials, whitespace.  (Specials mustn't be
 319               ;; encoded.)
 320               (while (not (eobp))
 321                 (setq start (point))
 322                 ;; Skip whitespace.
 323                 (unless (= 0 (skip-chars-forward " \t\n"))
 324                   (setq start (point)))
 325                 (cond
 326                  ((not (char-after)))   ; eob
 327                  ;; else token start
 328                  ((eq ?\" (char-syntax (char-after)))
 329                   ;; Quoted word.
 330                   (forward-sexp)
 331                   (setq end (point))
 332                   ;; Does it need encoding?
 333                   (goto-char start)
 334                   (skip-chars-forward "\000-\177" end)
 335                   (if (= end (point))
 336                       (setq last-encoded  nil)
 337                     ;; It needs encoding.  Strip the quotes first,
 338                     ;; since encoded words can't occur in quotes.
 339                     (goto-char end)
 340                     (delete-backward-char 1)
 341                     (goto-char start)
 342                     (delete-char 1)
 343                     (when last-encoded
 344                       ;; There was a preceding quoted word.  We need
 345                       ;; to include any separating whitespace in this
 346                       ;; word to avoid it getting lost.
 347                       (skip-chars-backward " \t")
 348                       ;; A space is needed between the encoded words.
 349                       (insert ? )
 350                       (setq start (point)
 351                             end (1+ end)))
 352                     ;; Adjust the end position for the deleted quotes.
 353                     (rfc2047-encode start (- end 2))
 354                     (setq last-encoded t))) ; record that it was encoded
 355                  ((eq ?. (char-syntax (char-after)))
 356                   ;; Skip other delimiters, but record that they've
 357                   ;; potentially separated quoted words.
 358                   (forward-char)
 359                   (setq last-encoded nil))
 360                  (t                 ; normal token/whitespace sequence
 361                   ;; Find the end.
 362                   (forward-word 1)
 363                   (skip-chars-backward " \t")
 364                   (setq end (point))
 365                   ;; Deal with encoding and leading space as for
 366                   ;; quoted words.
 367                   (goto-char start)
 368                   (skip-chars-forward "\000-\177" end)
 369                   (if (= end (point))
 370                       (setq last-encoded  nil)
 371                     (when last-encoded
 372                       (goto-char start)
 373                       (skip-chars-backward " \t")
 374                       (insert ? )
 375                       (setq start (point)
 376                             end (1+ end)))
 377                     (rfc2047-encode start end)
 378                     (setq last-encoded t)))))
 379             (error
 380              (message "Invalid data for rfc2047 encoding: %s"
 381                       (buffer-substring b e)))))))
 382     (rfc2047-fold-region b (point))))
 383
 384 (defun rfc2047-encode-string (string)
 385   "Encode words in STRING.
 386 By default, the string is treated as containing addresses (see
 387 `rfc2047-encoding-type')."
 388   (with-temp-buffer
 389     (insert string)
 390     (rfc2047-encode-region (point-min) (point-max))
 391     (buffer-string)))
 392
 393 (defun rfc2047-encode (b e)
 394   "Encode the word(s) in the region B to E.
 395 By default, the region is treated as containing addresses (see
 396 `rfc2047-encoding-type')."
 397   (let* ((mime-charset (mm-find-mime-charset-region b e))
 398          (cs (if (> (length mime-charset) 1)
 399                  ;; Fixme: Instead of this, try to break region into
 400                  ;; parts that can be encoded separately.
 401                  (error "Can't rfc2047-encode `%s'"
 402                         (buffer-substring b e))
 403                (setq mime-charset (car mime-charset))
 404                (mm-charset-to-coding-system mime-charset)))
 405          ;; Fixme: Better, calculate the number of non-ASCII
 406          ;; characters, at least for 8-bit charsets.
 407          (encoding (if (assq mime-charset
 408                              rfc2047-charset-encoding-alist)
 409                        (cdr (assq mime-charset
 410                                   rfc2047-charset-encoding-alist))
 411                      'B))
 412          (start (concat
 413                  "=?" (downcase (symbol-name mime-charset)) "?"
 414                  (downcase (symbol-name encoding)) "?"))
 415          (first t))
 416     (if mime-charset
 417         (save-restriction
 418           (narrow-to-region b e)
 419           (when (eq encoding 'B)
 420             ;; break into lines before encoding
 421             (goto-char (point-min))
 422             (while (not (eobp))
 423               (goto-char (min (point-max) (+ 15 (point))))
 424               (unless (eobp)
 425                 (insert ?\n))))
 426           (if (and (mm-multibyte-p)
 427                    (mm-coding-system-p cs))
 428               (mm-encode-coding-region (point-min) (point-max) cs))
 429           (funcall (cdr (assq encoding rfc2047-encoding-function-alist))
 430                    (point-min) (point-max))
 431           (goto-char (point-min))
 432           (while (not (eobp))
 433             (unless first
 434               (insert ? ))
 435             (setq first nil)
 436             (insert start)
 437             (end-of-line)
 438             (insert "?=")
 439             (forward-line 1))))))
 440
 441 (defun rfc2047-fold-field ()
 442   "Fold the current header field."
 443   (save-excursion
 444     (save-restriction
 445       (rfc2047-narrow-to-field)
 446       (rfc2047-fold-region (point-min) (point-max)))))
 447
 448 (defun rfc2047-fold-region (b e)
 449   "Fold long lines in region B to E."
 450   (save-restriction
 451     (narrow-to-region b e)
 452     (goto-char (point-min))
 453     (let ((break nil)
 454           (qword-break nil)
 455           (first t)
 456           (bol (save-restriction
 457                  (widen)
 458                  (rfc2047-point-at-bol))))
 459       (while (not (eobp))
 460         (when (and (or break qword-break)
 461                    (> (- (point) bol) 76))
 462           (goto-char (or break qword-break))
 463           (setq break nil
 464                 qword-break nil)
 465           (if (looking-at "[ \t]")
 466               (insert ?\n)
 467             (insert "\n "))
 468           (setq bol (1- (point)))
 469           ;; Don't break before the first non-LWSP characters.
 470           (skip-chars-forward " \t")
 471           (unless (eobp)
 472             (forward-char 1)))
 473         (cond
 474          ((eq (char-after) ?\n)
 475           (forward-char 1)
 476           (setq bol (point)
 477                 break nil
 478                 qword-break nil)
 479           (skip-chars-forward " \t")
 480           (unless (or (eobp) (eq (char-after) ?\n))
 481             (forward-char 1)))
 482          ((eq (char-after) ?\r)
 483           (forward-char 1))
 484          ((memq (char-after) '(?  ?\t))
 485           (skip-chars-forward " \t")
 486           (if first
 487               ;; Don't break just after the header name.
 488               (setq first nil)
 489             (setq break (1- (point)))))
 490          ((not break)
 491           (if (not (looking-at "=\\?[^=]"))
 492               (if (eq (char-after) ?=)
 493                   (forward-char 1)
 494                 (skip-chars-forward "^ \t\n\r="))
 495             ;; Don't break at the start of the field.
 496             (unless (= (point) b)
 497               (setq qword-break (point)))
 498             (skip-chars-forward "^ \t\n\r")))
 499          (t
 500           (skip-chars-forward "^ \t\n\r"))))
 501       (when (and (or break qword-break)
 502                  (> (- (point) bol) 76))
 503         (goto-char (or break qword-break))
 504         (setq break nil
 505               qword-break nil)
 506           (if (looking-at "[ \t]")
 507               (insert ?\n)
 508             (insert "\n "))
 509         (setq bol (1- (point)))
 510         ;; Don't break before the first non-LWSP characters.
 511         (skip-chars-forward " \t")
 512         (unless (eobp)
 513           (forward-char 1))))))
 514
 515 (defun rfc2047-unfold-field ()
 516   "Fold the current line."
 517   (save-excursion
 518     (save-restriction
 519       (rfc2047-narrow-to-field)
 520       (rfc2047-unfold-region (point-min) (point-max)))))
 521
 522 (defun rfc2047-unfold-region (b e)
 523   "Unfold lines in region B to E."
 524   (save-restriction
 525     (narrow-to-region b e)
 526     (goto-char (point-min))
 527     (let ((bol (save-restriction
 528                  (widen)
 529                  (rfc2047-point-at-bol)))
 530           (eol (rfc2047-point-at-eol)))
 531       (forward-line 1)
 532       (while (not (eobp))
 533         (if (and (looking-at "[ \t]")
 534                  (< (- (rfc2047-point-at-eol) bol) 76))
 535             (delete-region eol (progn
 536                                  (goto-char eol)
 537                                  (skip-chars-forward "\r\n")
 538                                  (point)))
 539           (setq bol (rfc2047-point-at-bol)))
 540         (setq eol (rfc2047-point-at-eol))
 541         (forward-line 1)))))
 542
 543 (defun rfc2047-b-encode-region (b e)
 544   "Base64-encode the header contained in region B to E."
 545   (save-restriction
 546     (narrow-to-region (goto-char b) e)
 547     (while (not (eobp))
 548       (base64-encode-region (point) (progn (end-of-line) (point)) t)
 549       (if (and (bolp) (eolp))
 550           (delete-backward-char 1))
 551       (forward-line))))
 552
 553 (defun rfc2047-q-encode-region (b e)
 554   "Quoted-printable-encode the header in region B to E."
 555   (save-excursion
 556     (save-restriction
 557       (narrow-to-region (goto-char b) e)
 558       (let ((bol (save-restriction
 559                    (widen)
 560                    (rfc2047-point-at-bol))))
 561         (quoted-printable-encode-region
 562          b e nil
 563          ;; = (\075), _ (\137), ? (\077) are used in the encoded word.
 564          ;; Avoid using 8bit characters.
 565          ;; This list excludes `especials' (see the RFC2047 syntax),
 566          ;; meaning that some characters in non-structured fields will
 567          ;; get encoded when they con't need to be.  The following is
 568          ;; what it used to be.
 569 ;;;      ;; Equivalent to "^\000-\007\011\013\015-\037\200-\377=_?"
 570 ;;;      "\010\012\014\040-\074\076\100-\136\140-\177")
 571          "-\b\n\f !#-'*+0-9A-Z\\^`-~\d")
 572         (subst-char-in-region (point-min) (point-max) ?  ?_)
 573         ;; The size of QP encapsulation is about 20, so set limit to
 574         ;; 56=76-20.
 575         (unless (< (- (point-max) (point-min)) 56)
 576           ;; Don't break if it could fit in one line.
 577           ;; Let rfc2047-encode-region break it later.
 578           (goto-char (1+ (point-min)))
 579           (while (and (not (bobp)) (not (eobp)))
 580             (goto-char (min (point-max) (+ 56 bol)))
 581             (search-backward "=" (- (point) 2) t)
 582             (unless (or (bobp) (eobp))
 583               (insert ?\n)
 584               (setq bol (point)))))))))
 585
 586 ;;;
 587 ;;; Functions for decoding RFC2047 messages
 588 ;;;
 589
 590 (eval-and-compile
 591   (defconst rfc2047-encoded-word-regexp
 592     "=\\?\\([^][\000-\040()<>@,\;:\\\"/?.=]+\\)\\?\\(B\\|Q\\)\
 593 \\?\\([!->@-~ +]*\\)\\?="))
 594
 595 ;; Fixme: This should decode in place, not cons intermediate strings.
 596 ;; Also check whether it needs to worry about delimiting fields like
 597 ;; encoding.
 598
 599 ;; In fact it's reported that (invalid) encoding of mailboxes in
 600 ;; addr-specs is in use, so delimiting fields might help.  Probably
 601 ;; not decoding a word which isn't properly delimited is good enough
 602 ;; and worthwhile (is it more correct or not?), e.g. something like
 603 ;; `=?iso-8859-1?q?foo?=@'.
 604
 605 (defun rfc2047-decode-region (start end)
 606   "Decode MIME-encoded words in region between START and END."
 607   (interactive "r")
 608   (let ((case-fold-search t)
 609         b e)
 610     (save-excursion
 611       (save-restriction
 612         (narrow-to-region start end)
 613         (goto-char (point-min))
 614         ;; Remove whitespace between encoded words.
 615         (while (re-search-forward
 616                 (eval-when-compile
 617                   (concat "\\(" rfc2047-encoded-word-regexp "\\)"
 618                           "\\(\n?[ \t]\\)+"
 619                           "\\(" rfc2047-encoded-word-regexp "\\)"))
 620                 nil t)
 621           (delete-region (goto-char (match-end 1)) (match-beginning 6)))
 622         ;; Decode the encoded words.
 623         (setq b (goto-char (point-min)))
 624         (while (re-search-forward rfc2047-encoded-word-regexp nil t)
 625           (setq e (match-beginning 0))
 626           (insert (rfc2047-parse-and-decode
 627                    (prog1
 628                        (match-string 0)
 629                      (delete-region (match-beginning 0) (match-end 0)))))
 630           ;; Remove newlines between decoded words, though such things
 631           ;; essentially must not be there.
 632           (save-restriction
 633             (narrow-to-region e (point))
 634             (goto-char e)
 635             (while (re-search-forward "[\n\r]+" nil t)
 636               (replace-match " "))
 637             (goto-char (point-max)))
 638           (when (and (mm-multibyte-p)
 639                      mail-parse-charset
 640                      (not (eq mail-parse-charset 'us-ascii))
 641                      (not (eq mail-parse-charset 'gnus-decoded)))
 642             (mm-decode-coding-region b e mail-parse-charset))
 643           (setq b (point)))
 644         (when (and (mm-multibyte-p)
 645                    mail-parse-charset
 646                    (not (eq mail-parse-charset 'us-ascii))
 647                    (not (eq mail-parse-charset 'gnus-decoded)))
 648           (mm-decode-coding-region b (point-max) mail-parse-charset))))))
 649
 650 (defun rfc2047-decode-string (string)
 651   "Decode the quoted-printable-encoded STRING and return the results."
 652   (let ((m (mm-multibyte-p)))
 653     (if (string-match "=\\?" string)
 654         (with-temp-buffer
 655           ;; Fixme: This logic is wrong, but seems to be required by
 656           ;; Gnus summary buffer generation.  The value of `m' depends
 657           ;; on the current buffer, not global multibyteness or that
 658           ;; of the string.  Also the string returned should always be
 659           ;; multibyte in a multibyte session, i.e. the buffer should
 660           ;; be multibyte before `buffer-string' is called.
 661           (when m
 662             (mm-enable-multibyte))
 663           (insert string)
 664           (inline
 665             (rfc2047-decode-region (point-min) (point-max)))
 666           (buffer-string))
 667       ;; Fixme: As above, `m' here is inappropriate.
 668       (if (and m
 669                mail-parse-charset
 670                (not (eq mail-parse-charset 'us-ascii))
 671                (not (eq mail-parse-charset 'gnus-decoded)))
 672           (mm-decode-coding-string string mail-parse-charset)
 673         (mm-string-as-multibyte string)))))
 674
 675 (defun rfc2047-parse-and-decode (word)
 676   "Decode WORD and return it if it is an encoded word.
 677 Return WORD if it is not not an encoded word or if the charset isn't
 678 decodable."
 679   (if (not (string-match rfc2047-encoded-word-regexp word))
 680       word
 681     (or
 682      (condition-case nil
 683          (rfc2047-decode
 684           (match-string 1 word)
 685           (upcase (match-string 2 word))
 686           (match-string 3 word))
 687        (error word))
 688      word)))                            ; un-decodable
 689
 690 (defun rfc2047-pad-base64 (string)
 691   "Pad STRING to quartets."
 692   ;; Be more liberal to accept buggy base64 strings. If
 693   ;; base64-decode-string accepts buggy strings, this function could
 694   ;; be aliased to identity.
 695   (case (mod (length string) 4)
 696     (0 string)
 697     (1 string) ;; Error, don't pad it.
 698     (2 (concat string "=="))
 699     (3 (concat string "="))))
 700
 701 (defun rfc2047-decode (charset encoding string)
 702   "Decode STRING from the given MIME CHARSET in the given ENCODING.
 703 Valid ENCODINGs are \"B\" and \"Q\".
 704 If your Emacs implementation can't decode CHARSET, return nil."
 705   (if (stringp charset)
 706       (setq charset (intern (downcase charset))))
 707   (if (or (not charset)
 708           (eq 'gnus-all mail-parse-ignored-charsets)
 709           (memq 'gnus-all mail-parse-ignored-charsets)
 710           (memq charset mail-parse-ignored-charsets))
 711       (setq charset mail-parse-charset))
 712   (let ((cs (mm-charset-to-coding-system charset)))
 713     (if (and (not cs) charset
 714              (listp mail-parse-ignored-charsets)
 715              (memq 'gnus-unknown mail-parse-ignored-charsets))
 716         (setq cs (mm-charset-to-coding-system mail-parse-charset)))
 717     (when cs
 718       (when (and (eq cs 'ascii)
 719                  mail-parse-charset)
 720         (setq cs mail-parse-charset))
 721       (mm-decode-coding-string
 722        (cond
 723         ((equal "B" encoding)
 724          (base64-decode-string
 725           (rfc2047-pad-base64 string)))
 726         ((equal "Q" encoding)
 727          (quoted-printable-decode-string
 728           (mm-replace-chars-in-string string ?_ ? )))
 729         (t (error "Invalid encoding: %s" encoding)))
 730        cs))))
 731
 732 (provide 'rfc2047)
 733
 734 ;;; rfc2047.el ends here