cgit.sxemacs.org Git - gnus/blob - lisp/rfc2047.el

   1 ;;; rfc2047.el --- functions for encoding and decoding rfc2047 messages
   2
   3 ;; Copyright (C) 1998, 1999, 2000, 2002, 2003, 2004
   4 ;;        Free Software Foundation, Inc.
   5
   6 ;; Author: Lars Magne Ingebrigtsen <larsi@gnus.org>
   7 ;;      MORIOKA Tomohiko <morioka@jaist.ac.jp>
   8 ;; This file is part of GNU Emacs.
   9
  10 ;; GNU Emacs is free software; you can redistribute it and/or modify
  11 ;; it under the terms of the GNU General Public License as published by
  12 ;; the Free Software Foundation; either version 2, or (at your option)
  13 ;; any later version.
  14
  15 ;; GNU Emacs is distributed in the hope that it will be useful,
  16 ;; but WITHOUT ANY WARRANTY; without even the implied warranty of
  17 ;; MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.  See the
  18 ;; GNU General Public License for more details.
  19
  20 ;; You should have received a copy of the GNU General Public License
  21 ;; along with GNU Emacs; see the file COPYING.  If not, write to the
  22 ;; Free Software Foundation, Inc., 59 Temple Place - Suite 330,
  23 ;; Boston, MA 02111-1307, USA.
  24
  25 ;;; Commentary:
  26
  27 ;; RFC 2047 is "MIME (Multipurpose Internet Mail Extensions) Part
  28 ;; Three:  Message Header Extensions for Non-ASCII Text".
  29
  30 ;;; Code:
  31
  32 (eval-when-compile
  33   (require 'cl)
  34   (defvar message-posting-charset))
  35
  36 (require 'qp)
  37 (require 'mm-util)
  38 ;; Fixme: Avoid this (used for mail-parse-charset) mm dependence on gnus.
  39 (require 'mail-prsvr)
  40 (require 'base64)
  41 (autoload 'mm-body-7-or-8 "mm-bodies")
  42
  43 (defvar rfc2047-header-encoding-alist
  44   '(("Newsgroups" . nil)
  45     ("Followup-To" . nil)
  46     ("Message-ID" . nil)
  47     ("\\(Resent-\\)?\\(From\\|Cc\\|To\\|Bcc\\|Reply-To\\|Sender\
  48 \\|Mail-Followup-To\\|Mail-Copies-To\\|Approved\\)" . address-mime)
  49     (t . mime))
  50   "*Header/encoding method alist.
  51 The list is traversed sequentially.  The keys can either be
  52 header regexps or t.
  53
  54 The values can be:
  55
  56 1) nil, in which case no encoding is done;
  57 2) `mime', in which case the header will be encoded according to RFC2047;
  58 3) `address-mime', like `mime', but takes account of the rules for address
  59    fields (where quoted strings and comments must be treated separately);
  60 4) a charset, in which case it will be encoded as that charset;
  61 5) `default', in which case the field will be encoded as the rest
  62    of the article.")
  63
  64 (defvar rfc2047-charset-encoding-alist
  65   '((us-ascii . nil)
  66     (iso-8859-1 . Q)
  67     (iso-8859-2 . Q)
  68     (iso-8859-3 . Q)
  69     (iso-8859-4 . Q)
  70     (iso-8859-5 . B)
  71     (koi8-r . B)
  72     (iso-8859-7 . B)
  73     (iso-8859-8 . B)
  74     (iso-8859-9 . Q)
  75     (iso-8859-14 . Q)
  76     (iso-8859-15 . Q)
  77     (iso-2022-jp . B)
  78     (iso-2022-kr . B)
  79     (gb2312 . B)
  80     (big5 . B)
  81     (cn-big5 . B)
  82     (cn-gb . B)
  83     (cn-gb-2312 . B)
  84     (euc-kr . B)
  85     (iso-2022-jp-2 . B)
  86     (iso-2022-int-1 . B)
  87     (viscii . Q))
  88   "Alist of MIME charsets to RFC2047 encodings.
  89 Valid encodings are nil, `Q' and `B'.  These indicate binary (no) encoding,
  90 quoted-printable and base64 respectively.")
  91
  92 (defvar rfc2047-encode-function-alist
  93   '((Q . rfc2047-q-encode-string)
  94     (B . rfc2047-b-encode-string)
  95     (nil . identity))
  96   "Alist of RFC2047 encodings to encoding functions.")
  97
  98 (defvar rfc2047-encode-encoded-words t
  99   "Whether encoded words should be encoded again.")
 100
 101 ;;;
 102 ;;; Functions for encoding RFC2047 messages
 103 ;;;
 104
 105 (defun rfc2047-qp-or-base64 ()
 106   "Return the type with which to encode the buffer.
 107 This is either `base64' or `quoted-printable'."
 108   (save-excursion
 109     (let ((limit (min (point-max) (+ 2000 (point-min))))
 110           (n8bit 0))
 111       (goto-char (point-min))
 112       (skip-chars-forward "\x20-\x7f\r\n\t" limit)
 113       (while (< (point) limit)
 114         (incf n8bit)
 115         (forward-char 1)
 116         (skip-chars-forward "\x20-\x7f\r\n\t" limit))
 117       (if (or (< (* 6 n8bit) (- limit (point-min)))
 118               ;; Don't base64, say, a short line with a single
 119               ;; non-ASCII char when splitting parts by charset.
 120               (= n8bit 1))
 121           'quoted-printable
 122         'base64))))
 123
 124 (defun rfc2047-narrow-to-field ()
 125   "Narrow the buffer to the header on the current line."
 126   (beginning-of-line)
 127   (narrow-to-region
 128    (point)
 129    (progn
 130      (forward-line 1)
 131      (if (re-search-forward "^[^ \n\t]" nil t)
 132          (point-at-bol)
 133        (point-max))))
 134   (goto-char (point-min)))
 135
 136 (defun rfc2047-field-value ()
 137   "Return the value of the field at point."
 138   (save-excursion
 139     (save-restriction
 140       (rfc2047-narrow-to-field)
 141       (re-search-forward ":[ \t\n]*" nil t)
 142       (buffer-substring-no-properties (point) (point-max)))))
 143
 144 (defvar rfc2047-encoding-type 'address-mime
 145   "The type of encoding done by `rfc2047-encode-region'.
 146 This should be dynamically bound around calls to
 147 `rfc2047-encode-region' to either `mime' or `address-mime'.  See
 148 `rfc2047-header-encoding-alist', for definitions.")
 149
 150 (defun rfc2047-encode-message-header ()
 151   "Encode the message header according to `rfc2047-header-encoding-alist'.
 152 Should be called narrowed to the head of the message."
 153   (interactive "*")
 154   (save-excursion
 155     (goto-char (point-min))
 156     (let (alist elem method)
 157       (while (not (eobp))
 158         (save-restriction
 159           (rfc2047-narrow-to-field)
 160           (if (not (rfc2047-encodable-p))
 161               (prog1
 162                   (if (and (eq (mm-body-7-or-8) '8bit)
 163                            (mm-multibyte-p)
 164                            (mm-coding-system-p
 165                             (car message-posting-charset)))
 166                       ;; 8 bit must be decoded.
 167                       (mm-encode-coding-region
 168                        (point-min) (point-max)
 169                        (mm-charset-to-coding-system
 170                         (car message-posting-charset))))
 171                 ;; No encoding necessary, but folding is nice
 172                 (when nil
 173                   (rfc2047-fold-region
 174                    (save-excursion
 175                      (goto-char (point-min))
 176                      (skip-chars-forward "^:")
 177                      (when (looking-at ": ")
 178                        (forward-char 2))
 179                      (point))
 180                    (point-max))))
 181             ;; We found something that may perhaps be encoded.
 182             (setq method nil
 183                   alist rfc2047-header-encoding-alist)
 184             (while (setq elem (pop alist))
 185               (when (or (and (stringp (car elem))
 186                              (looking-at (car elem)))
 187                         (eq (car elem) t))
 188                 (setq alist nil
 189                       method (cdr elem))))
 190             (re-search-forward "^[^:]+: *" nil t)
 191             (cond
 192              ((eq method 'address-mime)
 193               (rfc2047-encode-region (point) (point-max)))
 194              ((eq method 'mime)
 195               (let ((rfc2047-encoding-type 'mime))
 196                 (rfc2047-encode-region (point) (point-max))))
 197              ((eq method 'default)
 198               (if (and (featurep 'mule)
 199                        (if (boundp 'default-enable-multibyte-characters)
 200                            default-enable-multibyte-characters)
 201                        mail-parse-charset)
 202                   (mm-encode-coding-region (point) (point-max)
 203                                            mail-parse-charset)))
 204              ;; We get this when CC'ing messsages to newsgroups with
 205              ;; 8-bit names.  The group name mail copy just got
 206              ;; unconditionally encoded.  Previously, it would ask
 207              ;; whether to encode, which was quite confusing for the
 208              ;; user.  If the new behaviour is wrong, tell me. I have
 209              ;; left the old code commented out below.
 210              ;; -- Per Abrahamsen <abraham@dina.kvl.dk> Date: 2001-10-07.
 211              ;; Modified by Dave Love, with the commented-out code changed
 212              ;; in accordance with changes elsewhere.
 213              ((null method)
 214               (rfc2047-encode-region (point) (point-max)))
 215 ;;;          ((null method)
 216 ;;;           (if (or (message-options-get
 217 ;;;                    'rfc2047-encode-message-header-encode-any)
 218 ;;;                   (message-options-set
 219 ;;;                    'rfc2047-encode-message-header-encode-any
 220 ;;;                    (y-or-n-p
 221 ;;;                     "Some texts are not encoded. Encode anyway?")))
 222 ;;;               (rfc2047-encode-region (point-min) (point-max))
 223 ;;;             (error "Cannot send unencoded text")))
 224              ((mm-coding-system-p method)
 225               (if (and (featurep 'mule)
 226                        (if (boundp 'default-enable-multibyte-characters)
 227                            default-enable-multibyte-characters))
 228                   (mm-encode-coding-region (point) (point-max) method)))
 229              ;; Hm.
 230              (t)))
 231           (goto-char (point-max)))))))
 232
 233 ;; Fixme: This, and the require below may not be the Right Thing, but
 234 ;; should be safe just before release.  -- fx 2001-02-08
 235 (eval-when-compile (defvar message-posting-charset))
 236
 237 (defun rfc2047-encodable-p ()
 238   "Return non-nil if any characters in current buffer need encoding in headers.
 239 The buffer may be narrowed."
 240   (require 'message)                    ; for message-posting-charset
 241   (let ((charsets
 242          (mm-find-mime-charset-region (point-min) (point-max))))
 243     (goto-char (point-min))
 244     (or (and rfc2047-encode-encoded-words
 245              (prog1
 246                  (search-forward "=?" nil t)
 247                (goto-char (point-min))))
 248         (and charsets
 249              (not (equal charsets (list (car message-posting-charset))))))))
 250
 251 ;; Use this syntax table when parsing into regions that may need
 252 ;; encoding.  Double quotes are string delimiters, backslash is
 253 ;; character quoting, and all other RFC 2822 special characters are
 254 ;; treated as punctuation so we can use forward-sexp/forward-word to
 255 ;; skip to the end of regions appropriately.  Nb. ietf-drums does
 256 ;; things differently.
 257 (defconst rfc2047-syntax-table
 258   ;; (make-char-table 'syntax-table '(2)) only works in Emacs.
 259   (let ((table (make-syntax-table)))
 260     ;; The following is done to work for setting all elements of the table
 261     ;; in Emacs 21 and 22 and XEmacs; it appears to be the cleanest way.
 262     ;; Play safe and don't assume the form of the word syntax entry --
 263     ;; copy it from ?a.
 264     (if (fboundp 'set-char-table-range) ; Emacs
 265         (funcall (intern "set-char-table-range")
 266                  table t (aref (standard-syntax-table) ?a))
 267       (if (fboundp 'put-char-table)
 268           (if (fboundp 'get-char-table) ; warning avoidance
 269               (put-char-table t (get-char-table ?a (standard-syntax-table))
 270                               table))))
 271     (modify-syntax-entry ?\\ "\\" table)
 272     (modify-syntax-entry ?\" "\"" table)
 273     (modify-syntax-entry ?\( "." table)
 274     (modify-syntax-entry ?\) "." table)
 275     (modify-syntax-entry ?\< "." table)
 276     (modify-syntax-entry ?\> "." table)
 277     (modify-syntax-entry ?\[ "." table)
 278     (modify-syntax-entry ?\] "." table)
 279     (modify-syntax-entry ?: "." table)
 280     (modify-syntax-entry ?\; "." table)
 281     (modify-syntax-entry ?, "." table)
 282     (modify-syntax-entry ?@ "." table)
 283     table))
 284
 285 (defun rfc2047-encode-region (b e)
 286   "Encode words in region B to E that need encoding.
 287 By default, the region is treated as containing RFC2822 addresses.
 288 Dynamically bind `rfc2047-encoding-type' to change that."
 289   (save-restriction
 290     (narrow-to-region b e)
 291     (let ((encodable-regexp (if rfc2047-encode-encoded-words
 292                                 "[^\000-\177]+\\|=\\?"
 293                               "[^\000-\177]+"))
 294           start                         ; start of current token
 295           end begin
 296           ;; Whether there's an encoded word before the current token,
 297           ;; either immediately or separated by space.
 298           last-encoded)
 299       (if (eq 'mime rfc2047-encoding-type)
 300           ;; Simple case.  Continuous words in which all those contain
 301           ;; non-ASCII characters are encoded collectively.  Encoding
 302           ;; ASCII words, including `Re:' used in Subject headers, is
 303           ;; avoided for interoperability with non-MIME clients and
 304           ;; for making it easy to find keywords.
 305           (progn
 306             (goto-char (point-min))
 307             (while (progn (skip-chars-forward " \t\n")
 308                           (not (eobp)))
 309               (setq start (point))
 310               (while (and (looking-at "[ \t\n]*\\([^ \t\n]+\\)")
 311                           (progn
 312                             (setq end (match-end 0))
 313                             (re-search-forward encodable-regexp end t)))
 314                 (goto-char end))
 315               (if (> (point) start)
 316                   (rfc2047-encode start (point))
 317                 (goto-char end))))
 318         ;; `address-mime' case -- take care of quoted words, comments.
 319         (with-syntax-table rfc2047-syntax-table
 320           (goto-char (point-min))
 321           (condition-case nil           ; in case of unbalanced quotes
 322               ;; Look for rfc2822-style: sequences of atoms, quoted
 323               ;; strings, specials, whitespace.  (Specials mustn't be
 324               ;; encoded.)
 325               (while (not (eobp))
 326                 ;; Skip whitespace.
 327                 (skip-chars-forward " \t\n")
 328                 (setq start (point))
 329                 (cond
 330                  ((not (char-after)))   ; eob
 331                  ;; else token start
 332                  ((eq ?\" (char-syntax (char-after)))
 333                   ;; Quoted word.
 334                   (forward-sexp)
 335                   (setq end (point))
 336                   ;; Does it need encoding?
 337                   (goto-char start)
 338                   (if (re-search-forward encodable-regexp end 'move)
 339                       ;; It needs encoding.  Strip the quotes first,
 340                       ;; since encoded words can't occur in quotes.
 341                       (progn
 342                         (goto-char end)
 343                         (delete-backward-char 1)
 344                         (goto-char start)
 345                         (delete-char 1)
 346                         (when last-encoded
 347                           ;; There was a preceding quoted word.  We need
 348                           ;; to include any separating whitespace in this
 349                           ;; word to avoid it getting lost.
 350                           (skip-chars-backward " \t")
 351                           ;; A space is needed between the encoded words.
 352                           (insert ? )
 353                           (setq start (point)
 354                                 end (1+ end)))
 355                         ;; Adjust the end position for the deleted quotes.
 356                         (rfc2047-encode start (- end 2))
 357                         (setq last-encoded t)) ; record that it was encoded
 358                     (setq last-encoded  nil)))
 359                  ((eq ?. (char-syntax (char-after)))
 360                   ;; Skip other delimiters, but record that they've
 361                   ;; potentially separated quoted words.
 362                   (forward-char)
 363                   (setq last-encoded nil))
 364                  (t                 ; normal token/whitespace sequence
 365                   ;; Find the end.
 366                   (if (and (prog2
 367                                (skip-chars-backward " \t\n")
 368                                (eq (char-before) ?\()
 369                              (goto-char start))
 370                            ;; Look for the end of parentheses.
 371                            (let ((string (buffer-substring (point)
 372                                                            (point-max)))
 373                                  (default-major-mode 'fundamental-mode))
 374                              ;; Use `standard-syntax-table'.
 375                              (with-temp-buffer
 376                                (insert "(" string)
 377                                (goto-char (point-min))
 378                                (condition-case nil
 379                                    (progn
 380                                      (forward-list 1)
 381                                      (setq end (+ start (point) -3)))
 382                                  (error nil)))))
 383                       ;; Encode text as an unstructured field.
 384                       (let ((rfc2047-encoding-type 'mime))
 385                         (rfc2047-encode-region start end)
 386                         (forward-char))
 387                     ;; Skip one ASCII word, or encode continuous words
 388                     ;; in which all those contain non-ASCII characters.
 389                     (setq end nil)
 390                     (while (not end)
 391                       (when (looking-at "[\000-\177]+")
 392                         (setq begin (point)
 393                               end (match-end 0))
 394                         (if (re-search-forward "[ \t\n]\\|\\Sw" end 'move)
 395                             (progn
 396                               (setq end (match-beginning 0))
 397                               (if rfc2047-encode-encoded-words
 398                                   (progn
 399                                     (goto-char begin)
 400                                     (when (search-forward "=?" end 'move)
 401                                       (goto-char (match-beginning 0))
 402                                       (setq end nil)))
 403                                 (goto-char end)))
 404                           (setq end nil)))
 405                       (unless end
 406                         (setq end t)
 407                         (when (looking-at encodable-regexp)
 408                           (goto-char (match-end 0))
 409                           (while (and (looking-at "[ \t\n]+\\([^ \t\n]+\\)")
 410                                       (setq end (match-end 0))
 411                                       (string-match encodable-regexp
 412                                                     (match-string 1)))
 413                             (goto-char end))
 414                           (when (looking-at "[^ \t\n]+")
 415                             (setq end (match-end 0))
 416                             (if (re-search-forward "\\Sw+" end t)
 417                                 ;; There are special characters better
 418                                 ;; to be encoded so that MTAs may parse
 419                                 ;; them safely.
 420                                 (cond ((= end (point)))
 421                                       ((looking-at encodable-regexp)
 422                                        (setq end nil))
 423                                       (t
 424                                        (goto-char (1- (match-end 0)))
 425                                        (unless (= (point) (match-beginning 0))
 426                                          (insert " "))))
 427                               (goto-char end)
 428                               (skip-chars-forward " \t\n")
 429                               (if (and (looking-at "[^ \t\n]+")
 430                                        (string-match encodable-regexp
 431                                                      (match-string 0)))
 432                                   (setq end nil)
 433                                 (goto-char end)))))))
 434                     (skip-chars-backward " \t\n")
 435                     (setq end (point))
 436                     (goto-char start)
 437                     (if (re-search-forward encodable-regexp end 'move)
 438                         (progn
 439                           (rfc2047-encode start end)
 440                           (setq last-encoded t))
 441                       (setq last-encoded nil))))))
 442             (error
 443              (error "Invalid data for rfc2047 encoding: %s"
 444                     (buffer-substring b e)))))))
 445     (rfc2047-fold-region b (point))))
 446
 447 (defun rfc2047-encode-string (string)
 448   "Encode words in STRING.
 449 By default, the string is treated as containing addresses (see
 450 `rfc2047-encoding-type')."
 451   (with-temp-buffer
 452     (insert string)
 453     (rfc2047-encode-region (point-min) (point-max))
 454     (buffer-string)))
 455
 456 (defun rfc2047-encode-1 (column string cs encoder start space &optional eword)
 457   "Subroutine used by `rfc2047-encode'."
 458   (cond ((string-equal string "")
 459          (or eword ""))
 460         ((>= column 76)
 461          (when (and eword
 462                     (string-match "\n[ \t]+\\'" eword))
 463            ;; Reomove a superfluous empty line.
 464            (setq eword (substring eword 0 (match-beginning 0))))
 465          (rfc2047-encode-1 (length space) string cs encoder start " "
 466                            (concat eword "\n" space)))
 467         (t
 468          (let ((index 0)
 469                (limit (1- (length string)))
 470                (prev "")
 471                next)
 472            (while (and prev
 473                        (<= index limit))
 474              (setq next (concat start
 475                                 (funcall encoder
 476                                          (if cs
 477                                              (mm-encode-coding-string
 478                                               (substring string 0 (1+ index))
 479                                               cs)
 480                                            (substring string 0 (1+ index))))
 481                                 "?="))
 482              (if (<= (+ column (length next)) 76)
 483                  (setq prev next
 484                        index (1+ index))
 485                (setq next prev
 486                      prev nil)))
 487            (setq eword (concat eword next))
 488            (if (> index limit)
 489                eword
 490              (when (string-match "\n[ \t]+\\'" eword)
 491                ;; Reomove a superfluous empty line.
 492                (setq eword (substring eword 0 (match-beginning 0))))
 493              (rfc2047-encode-1 (length space) (substring string index)
 494                                cs encoder start " "
 495                                (concat eword "\n" space)))))))
 496
 497 (defun rfc2047-encode (b e)
 498   "Encode the word(s) in the region B to E.
 499 Point moves to the end of the region."
 500   (let ((mime-charset (or (mm-find-mime-charset-region b e) (list 'us-ascii)))
 501         cs encoding space eword)
 502     (cond ((> (length mime-charset) 1)
 503            (error "Can't rfc2047-encode `%s'"
 504                   (buffer-substring-no-properties b e)))
 505           ((= (length mime-charset) 1)
 506            (setq mime-charset (car mime-charset)
 507                  cs (mm-charset-to-coding-system mime-charset))
 508            (unless (and (mm-multibyte-p)
 509                         (mm-coding-system-p cs))
 510              (setq cs nil))
 511            (save-restriction
 512              (narrow-to-region b e)
 513              (setq encoding
 514                    (or (cdr (assq mime-charset
 515                                   rfc2047-charset-encoding-alist))
 516                        ;; For the charsets that don't have a preferred
 517                        ;; encoding, choose the one that's shorter.
 518                        (if (eq (rfc2047-qp-or-base64) 'base64)
 519                            'B
 520                          'Q)))
 521              (widen)
 522              (goto-char b)
 523              (setq b (point-marker)
 524                    e (set-marker (make-marker) e))
 525              (rfc2047-fold-region (point-at-bol) b)
 526              (unless (= 0 (skip-chars-backward " \t"))
 527                (setq space (buffer-substring-no-properties (point) b)))
 528              (setq eword (rfc2047-encode-1
 529                           (- b (point-at-bol))
 530                           (mm-replace-in-string
 531                            (buffer-substring-no-properties b e)
 532                            "\n\\([ \t]?\\)" "\\1")
 533                           cs
 534                           (or (cdr (assq encoding
 535                                          rfc2047-encode-function-alist))
 536                               'identity)
 537                           (concat "=?" (downcase (symbol-name mime-charset))
 538                                   "?" (upcase (symbol-name encoding)) "?")
 539                           (or space " ")))
 540              (delete-region (if (eq (aref eword 0) ?\n)
 541                                 (point)
 542                               (goto-char b))
 543                             e)
 544              (insert eword)
 545              (set-marker b nil)
 546              (set-marker e nil)
 547              (unless (or (eolp)
 548                          (looking-at "[ \t\n)]"))
 549                (insert " "))))
 550           (t
 551            (goto-char e)))))
 552
 553 (defun rfc2047-fold-field ()
 554   "Fold the current header field."
 555   (save-excursion
 556     (save-restriction
 557       (rfc2047-narrow-to-field)
 558       (rfc2047-fold-region (point-min) (point-max)))))
 559
 560 (defun rfc2047-fold-region (b e)
 561   "Fold long lines in region B to E."
 562   (save-restriction
 563     (narrow-to-region b e)
 564     (goto-char (point-min))
 565     (let ((break nil)
 566           (qword-break nil)
 567           (first t)
 568           (bol (save-restriction
 569                  (widen)
 570                  (point-at-bol))))
 571       (while (not (eobp))
 572         (when (and (or break qword-break)
 573                    (> (- (point) bol) 76))
 574           (goto-char (or break qword-break))
 575           (setq break nil
 576                 qword-break nil)
 577           (skip-chars-backward " \t")
 578           (if (looking-at "[ \t]")
 579               (insert ?\n)
 580             (insert "\n "))
 581           (setq bol (1- (point)))
 582           ;; Don't break before the first non-LWSP characters.
 583           (skip-chars-forward " \t")
 584           (unless (eobp)
 585             (forward-char 1)))
 586         (cond
 587          ((eq (char-after) ?\n)
 588           (forward-char 1)
 589           (setq bol (point)
 590                 break nil
 591                 qword-break nil)
 592           (skip-chars-forward " \t")
 593           (unless (or (eobp) (eq (char-after) ?\n))
 594             (forward-char 1)))
 595          ((eq (char-after) ?\r)
 596           (forward-char 1))
 597          ((memq (char-after) '(?  ?\t))
 598           (skip-chars-forward " \t")
 599           (unless first ;; Don't break just after the header name.
 600             (setq break (point))))
 601          ((not break)
 602           (if (not (looking-at "=\\?[^=]"))
 603               (if (eq (char-after) ?=)
 604                   (forward-char 1)
 605                 (skip-chars-forward "^ \t\n\r="))
 606             ;; Don't break at the start of the field.
 607             (unless (= (point) b)
 608               (setq qword-break (point)))
 609             (skip-chars-forward "^ \t\n\r")))
 610          (t
 611           (skip-chars-forward "^ \t\n\r")))
 612         (setq first nil))
 613       (when (and (or break qword-break)
 614                  (> (- (point) bol) 76))
 615         (goto-char (or break qword-break))
 616         (setq break nil
 617               qword-break nil)
 618           (if (looking-at "[ \t]")
 619               (insert ?\n)
 620             (insert "\n "))
 621         (setq bol (1- (point)))
 622         ;; Don't break before the first non-LWSP characters.
 623         (skip-chars-forward " \t")
 624         (unless (eobp)
 625           (forward-char 1))))))
 626
 627 (defun rfc2047-unfold-field ()
 628   "Fold the current line."
 629   (save-excursion
 630     (save-restriction
 631       (rfc2047-narrow-to-field)
 632       (rfc2047-unfold-region (point-min) (point-max)))))
 633
 634 (defun rfc2047-unfold-region (b e)
 635   "Unfold lines in region B to E."
 636   (save-restriction
 637     (narrow-to-region b e)
 638     (goto-char (point-min))
 639     (let ((bol (save-restriction
 640                  (widen)
 641                  (point-at-bol)))
 642           (eol (point-at-eol)))
 643       (forward-line 1)
 644       (while (not (eobp))
 645         (if (and (looking-at "[ \t]")
 646                  (< (- (point-at-eol) bol) 76))
 647             (delete-region eol (progn
 648                                  (goto-char eol)
 649                                  (skip-chars-forward "\r\n")
 650                                  (point)))
 651           (setq bol (point-at-bol)))
 652         (setq eol (point-at-eol))
 653         (forward-line 1)))))
 654
 655 (defun rfc2047-b-encode-string (string)
 656   "Base64-encode the header contained in STRING."
 657   (base64-encode-string string t))
 658
 659 (defun rfc2047-q-encode-string (string)
 660   "Quoted-printable-encode the header in STRING."
 661   (mm-with-unibyte-buffer
 662     (insert string)
 663     (quoted-printable-encode-region
 664      (point-min) (point-max) nil
 665      ;; = (\075), _ (\137), ? (\077) are used in the encoded word.
 666      ;; Avoid using 8bit characters.
 667      ;; This list excludes `especials' (see the RFC2047 syntax),
 668      ;; meaning that some characters in non-structured fields will
 669      ;; get encoded when they con't need to be.  The following is
 670      ;; what it used to be.
 671      ;;;  ;; Equivalent to "^\000-\007\011\013\015-\037\200-\377=_?"
 672      ;;;  "\010\012\014\040-\074\076\100-\136\140-\177")
 673      "-\b\n\f !#-'*+0-9A-Z\\^`-~\d")
 674     (subst-char-in-region (point-min) (point-max) ?  ?_)
 675     (buffer-string)))
 676
 677 ;;;
 678 ;;; Functions for decoding RFC2047 messages
 679 ;;;
 680
 681 (eval-and-compile
 682   (defconst rfc2047-encoded-word-regexp
 683     "=\\?\\([^][\000-\040()<>@,\;:*\\\"/?.=]+\\)\\(?:\\*[^?]+\\)?\
 684 \\?\\(B\\|Q\\)\\?\\([!->@-~ ]*\\)\\?="))
 685
 686 ;; Fixme: This should decode in place, not cons intermediate strings.
 687 ;; Also check whether it needs to worry about delimiting fields like
 688 ;; encoding.
 689
 690 ;; In fact it's reported that (invalid) encoding of mailboxes in
 691 ;; addr-specs is in use, so delimiting fields might help.  Probably
 692 ;; not decoding a word which isn't properly delimited is good enough
 693 ;; and worthwhile (is it more correct or not?), e.g. something like
 694 ;; `=?iso-8859-1?q?foo?=@'.
 695
 696 (defun rfc2047-decode-region (start end)
 697   "Decode MIME-encoded words in region between START and END."
 698   (interactive "r")
 699   (let ((case-fold-search t)
 700         b e)
 701     (save-excursion
 702       (save-restriction
 703         (narrow-to-region start end)
 704         (goto-char (point-min))
 705         ;; Remove whitespace between encoded words.
 706         (while (re-search-forward
 707                 (eval-when-compile
 708                   (concat "\\(" rfc2047-encoded-word-regexp "\\)"
 709                           "\\(\n?[ \t]\\)+"
 710                           "\\(" rfc2047-encoded-word-regexp "\\)"))
 711                 nil t)
 712           (delete-region (goto-char (match-end 1)) (match-beginning 6)))
 713         ;; Decode the encoded words.
 714         (setq b (goto-char (point-min)))
 715         (while (re-search-forward rfc2047-encoded-word-regexp nil t)
 716           (setq e (match-beginning 0))
 717           (insert (rfc2047-parse-and-decode
 718                    (prog1
 719                        (match-string 0)
 720                      (delete-region (match-beginning 0) (match-end 0)))))
 721           ;; Remove newlines between decoded words, though such things
 722           ;; essentially must not be there.
 723           (save-restriction
 724             (narrow-to-region e (point))
 725             (goto-char e)
 726             (while (re-search-forward "[\n\r]+" nil t)
 727               (replace-match " "))
 728             (goto-char (point-max)))
 729           (when (and (mm-multibyte-p)
 730                      mail-parse-charset
 731                      (not (eq mail-parse-charset 'us-ascii))
 732                      (not (eq mail-parse-charset 'gnus-decoded)))
 733             (mm-decode-coding-region b e mail-parse-charset))
 734           (setq b (point)))
 735         (when (and (mm-multibyte-p)
 736                    mail-parse-charset
 737                    (not (eq mail-parse-charset 'us-ascii))
 738                    (not (eq mail-parse-charset 'gnus-decoded)))
 739           (mm-decode-coding-region b (point-max) mail-parse-charset))))))
 740
 741 (defun rfc2047-decode-string (string)
 742   "Decode the quoted-printable-encoded STRING and return the results."
 743   (let ((m (mm-multibyte-p)))
 744     (if (string-match "=\\?" string)
 745         (with-temp-buffer
 746           ;; Fixme: This logic is wrong, but seems to be required by
 747           ;; Gnus summary buffer generation.  The value of `m' depends
 748           ;; on the current buffer, not global multibyteness or that
 749           ;; of the string.  Also the string returned should always be
 750           ;; multibyte in a multibyte session, i.e. the buffer should
 751           ;; be multibyte before `buffer-string' is called.
 752           (when m
 753             (mm-enable-multibyte))
 754           (insert string)
 755           (inline
 756             (rfc2047-decode-region (point-min) (point-max)))
 757           (buffer-string))
 758       ;; Fixme: As above, `m' here is inappropriate.
 759       (if (and m
 760                mail-parse-charset
 761                (not (eq mail-parse-charset 'us-ascii))
 762                (not (eq mail-parse-charset 'gnus-decoded)))
 763           ;; `decode-coding-string' in Emacs offers a third optional
 764           ;; arg NOCOPY to avoid consing a new string if the decoding
 765           ;; is "trivial".  Unfortunately it currently doesn't
 766           ;; consider anything else than a `nil' coding system
 767           ;; trivial.
 768           ;; `rfc2047-decode-string' is called multiple times for each
 769           ;; article during summary buffer generation, and we really
 770           ;; want to avoid unnecessary consing.  So we bypass
 771           ;; `decode-coding-string' if the string is purely ASCII.
 772           (if (and (fboundp 'detect-coding-string)
 773                    ;; string is purely ASCII
 774                    (eq (detect-coding-string string t) 'undecided))
 775               string
 776             (mm-decode-coding-string string mail-parse-charset))
 777         (mm-string-as-multibyte string)))))
 778
 779 (defun rfc2047-parse-and-decode (word)
 780   "Decode WORD and return it if it is an encoded word.
 781 Return WORD if it is not not an encoded word or if the charset isn't
 782 decodable."
 783   (if (not (string-match rfc2047-encoded-word-regexp word))
 784       word
 785     (or
 786      (condition-case nil
 787          (rfc2047-decode
 788           (match-string 1 word)
 789           (string-to-char (match-string 2 word))
 790           (match-string 3 word))
 791        (error word))
 792      word)))                            ; un-decodable
 793
 794 (defun rfc2047-pad-base64 (string)
 795   "Pad STRING to quartets."
 796   ;; Be more liberal to accept buggy base64 strings. If
 797   ;; base64-decode-string accepts buggy strings, this function could
 798   ;; be aliased to identity.
 799   (if (= 0 (mod (length string) 4))
 800       string
 801     (when (string-match "=+$" string)
 802       (setq string (substring string 0 (match-beginning 0))))
 803     (case (mod (length string) 4)
 804       (0 string)
 805       (1 string) ;; Error, don't pad it.
 806       (2 (concat string "=="))
 807       (3 (concat string "=")))))
 808
 809 (defun rfc2047-decode (charset encoding string)
 810   "Decode STRING from the given MIME CHARSET in the given ENCODING.
 811 Valid ENCODINGs are the characters \"B\" and \"Q\".
 812 If your Emacs implementation can't decode CHARSET, return nil."
 813   (if (stringp charset)
 814       (setq charset (intern (downcase charset))))
 815   (if (or (not charset)
 816           (eq 'gnus-all mail-parse-ignored-charsets)
 817           (memq 'gnus-all mail-parse-ignored-charsets)
 818           (memq charset mail-parse-ignored-charsets))
 819       (setq charset mail-parse-charset))
 820   (let ((cs (mm-charset-to-coding-system charset)))
 821     (if (and (not cs) charset
 822              (listp mail-parse-ignored-charsets)
 823              (memq 'gnus-unknown mail-parse-ignored-charsets))
 824         (setq cs (mm-charset-to-coding-system mail-parse-charset)))
 825     (when cs
 826       (when (eq cs 'ascii)
 827         (setq cs (or mail-parse-charset 'raw-text)))
 828       (mm-decode-coding-string
 829        (cond
 830         ((char-equal ?B encoding)
 831          (base64-decode-string
 832           (rfc2047-pad-base64 string)))
 833         ((char-equal ?Q encoding)
 834          (quoted-printable-decode-string
 835           (mm-subst-char-in-string ?_ ? string t)))
 836         (t (error "Invalid encoding: %c" encoding)))
 837        cs))))
 838
 839 (provide 'rfc2047)
 840
 841 ;;; arch-tag: a07fe3d4-22b5-4c4a-bd89-b1f82d5d36f6
 842 ;;; rfc2047.el ends here