cgit.sxemacs.org Git - gnus/blob - lisp/rfc2047.el

   1 ;;; rfc2047.el --- functions for encoding and decoding rfc2047 messages
   2
   3 ;; Copyright (C) 1998, 1999, 2000, 2002, 2003, 2004
   4 ;;        Free Software Foundation, Inc.
   5
   6 ;; Author: Lars Magne Ingebrigtsen <larsi@gnus.org>
   7 ;;      MORIOKA Tomohiko <morioka@jaist.ac.jp>
   8 ;; This file is part of GNU Emacs.
   9
  10 ;; GNU Emacs is free software; you can redistribute it and/or modify
  11 ;; it under the terms of the GNU General Public License as published by
  12 ;; the Free Software Foundation; either version 2, or (at your option)
  13 ;; any later version.
  14
  15 ;; GNU Emacs is distributed in the hope that it will be useful,
  16 ;; but WITHOUT ANY WARRANTY; without even the implied warranty of
  17 ;; MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.  See the
  18 ;; GNU General Public License for more details.
  19
  20 ;; You should have received a copy of the GNU General Public License
  21 ;; along with GNU Emacs; see the file COPYING.  If not, write to the
  22 ;; Free Software Foundation, Inc., 59 Temple Place - Suite 330,
  23 ;; Boston, MA 02111-1307, USA.
  24
  25 ;;; Commentary:
  26
  27 ;; RFC 2047 is "MIME (Multipurpose Internet Mail Extensions) Part
  28 ;; Three:  Message Header Extensions for Non-ASCII Text".
  29
  30 ;;; Code:
  31
  32 (eval-when-compile
  33   (require 'cl)
  34   (defvar message-posting-charset))
  35
  36 (require 'qp)
  37 (require 'mm-util)
  38 ;; Fixme: Avoid this (used for mail-parse-charset) mm dependence on gnus.
  39 (require 'mail-prsvr)
  40 (require 'base64)
  41 (autoload 'mm-body-7-or-8 "mm-bodies")
  42
  43 (defvar rfc2047-header-encoding-alist
  44   '(("Newsgroups" . nil)
  45     ("Followup-To" . nil)
  46     ("Message-ID" . nil)
  47     ("\\(Resent-\\)?\\(From\\|Cc\\|To\\|Bcc\\|Reply-To\\|Sender\
  48 \\|Mail-Followup-To\\|Mail-Copies-To\\|Approved\\)" . address-mime)
  49     (t . mime))
  50   "*Header/encoding method alist.
  51 The list is traversed sequentially.  The keys can either be
  52 header regexps or t.
  53
  54 The values can be:
  55
  56 1) nil, in which case no encoding is done;
  57 2) `mime', in which case the header will be encoded according to RFC2047;
  58 3) `address-mime', like `mime', but takes account of the rules for address
  59    fields (where quoted strings and comments must be treated separately);
  60 4) a charset, in which case it will be encoded as that charset;
  61 5) `default', in which case the field will be encoded as the rest
  62    of the article.")
  63
  64 (defvar rfc2047-charset-encoding-alist
  65   '((us-ascii . nil)
  66     (iso-8859-1 . Q)
  67     (iso-8859-2 . Q)
  68     (iso-8859-3 . Q)
  69     (iso-8859-4 . Q)
  70     (iso-8859-5 . B)
  71     (koi8-r . B)
  72     (iso-8859-7 . B)
  73     (iso-8859-8 . B)
  74     (iso-8859-9 . Q)
  75     (iso-8859-14 . Q)
  76     (iso-8859-15 . Q)
  77     (iso-2022-jp . B)
  78     (iso-2022-kr . B)
  79     (gb2312 . B)
  80     (big5 . B)
  81     (cn-big5 . B)
  82     (cn-gb . B)
  83     (cn-gb-2312 . B)
  84     (euc-kr . B)
  85     (iso-2022-jp-2 . B)
  86     (iso-2022-int-1 . B)
  87     (viscii . Q))
  88   "Alist of MIME charsets to RFC2047 encodings.
  89 Valid encodings are nil, `Q' and `B'.  These indicate binary (no) encoding,
  90 quoted-printable and base64 respectively.")
  91
  92 (defvar rfc2047-encode-function-alist
  93   '((Q . rfc2047-q-encode-string)
  94     (B . rfc2047-b-encode-string)
  95     (nil . identity))
  96   "Alist of RFC2047 encodings to encoding functions.")
  97
  98 (defvar rfc2047-encode-encoded-words t
  99   "Whether encoded words should be encoded again.")
 100
 101 ;;;
 102 ;;; Functions for encoding RFC2047 messages
 103 ;;;
 104
 105 (defun rfc2047-qp-or-base64 ()
 106   "Return the type with which to encode the buffer.
 107 This is either `base64' or `quoted-printable'."
 108   (save-excursion
 109     (let ((limit (min (point-max) (+ 2000 (point-min))))
 110           (n8bit 0))
 111       (goto-char (point-min))
 112       (skip-chars-forward "\x20-\x7f\r\n\t" limit)
 113       (while (< (point) limit)
 114         (incf n8bit)
 115         (forward-char 1)
 116         (skip-chars-forward "\x20-\x7f\r\n\t" limit))
 117       (if (or (< (* 6 n8bit) (- limit (point-min)))
 118               ;; Don't base64, say, a short line with a single
 119               ;; non-ASCII char when splitting parts by charset.
 120               (= n8bit 1))
 121           'quoted-printable
 122         'base64))))
 123
 124 (defun rfc2047-narrow-to-field ()
 125   "Narrow the buffer to the header on the current line."
 126   (beginning-of-line)
 127   (narrow-to-region
 128    (point)
 129    (progn
 130      (forward-line 1)
 131      (if (re-search-forward "^[^ \n\t]" nil t)
 132          (point-at-bol)
 133        (point-max))))
 134   (goto-char (point-min)))
 135
 136 (defun rfc2047-field-value ()
 137   "Return the value of the field at point."
 138   (save-excursion
 139     (save-restriction
 140       (rfc2047-narrow-to-field)
 141       (re-search-forward ":[ \t\n]*" nil t)
 142       (buffer-substring-no-properties (point) (point-max)))))
 143
 144 (defvar rfc2047-encoding-type 'address-mime
 145   "The type of encoding done by `rfc2047-encode-region'.
 146 This should be dynamically bound around calls to
 147 `rfc2047-encode-region' to either `mime' or `address-mime'.  See
 148 `rfc2047-header-encoding-alist', for definitions.")
 149
 150 (defun rfc2047-encode-message-header ()
 151   "Encode the message header according to `rfc2047-header-encoding-alist'.
 152 Should be called narrowed to the head of the message."
 153   (interactive "*")
 154   (save-excursion
 155     (goto-char (point-min))
 156     (let (alist elem method)
 157       (while (not (eobp))
 158         (save-restriction
 159           (rfc2047-narrow-to-field)
 160           (if (not (rfc2047-encodable-p))
 161               (prog1
 162                   (if (and (eq (mm-body-7-or-8) '8bit)
 163                            (mm-multibyte-p)
 164                            (mm-coding-system-p
 165                             (car message-posting-charset)))
 166                       ;; 8 bit must be decoded.
 167                       (mm-encode-coding-region
 168                        (point-min) (point-max)
 169                        (mm-charset-to-coding-system
 170                         (car message-posting-charset))))
 171                 ;; No encoding necessary, but folding is nice
 172                 (when nil
 173                   (rfc2047-fold-region
 174                    (save-excursion
 175                      (goto-char (point-min))
 176                      (skip-chars-forward "^:")
 177                      (when (looking-at ": ")
 178                        (forward-char 2))
 179                      (point))
 180                    (point-max))))
 181             ;; We found something that may perhaps be encoded.
 182             (setq method nil
 183                   alist rfc2047-header-encoding-alist)
 184             (while (setq elem (pop alist))
 185               (when (or (and (stringp (car elem))
 186                              (looking-at (car elem)))
 187                         (eq (car elem) t))
 188                 (setq alist nil
 189                       method (cdr elem))))
 190             (re-search-forward "^[^:]+: *" nil t)
 191             (cond
 192              ((eq method 'address-mime)
 193               (rfc2047-encode-region (point) (point-max)))
 194              ((eq method 'mime)
 195               (let ((rfc2047-encoding-type 'mime))
 196                 (rfc2047-encode-region (point) (point-max))))
 197              ((eq method 'default)
 198               (if (and (featurep 'mule)
 199                        (if (boundp 'default-enable-multibyte-characters)
 200                            default-enable-multibyte-characters)
 201                        mail-parse-charset)
 202                   (mm-encode-coding-region (point) (point-max)
 203                                            mail-parse-charset)))
 204              ;; We get this when CC'ing messsages to newsgroups with
 205              ;; 8-bit names.  The group name mail copy just got
 206              ;; unconditionally encoded.  Previously, it would ask
 207              ;; whether to encode, which was quite confusing for the
 208              ;; user.  If the new behaviour is wrong, tell me. I have
 209              ;; left the old code commented out below.
 210              ;; -- Per Abrahamsen <abraham@dina.kvl.dk> Date: 2001-10-07.
 211              ;; Modified by Dave Love, with the commented-out code changed
 212              ;; in accordance with changes elsewhere.
 213              ((null method)
 214               (rfc2047-encode-region (point) (point-max)))
 215 ;;;          ((null method)
 216 ;;;           (if (or (message-options-get
 217 ;;;                    'rfc2047-encode-message-header-encode-any)
 218 ;;;                   (message-options-set
 219 ;;;                    'rfc2047-encode-message-header-encode-any
 220 ;;;                    (y-or-n-p
 221 ;;;                     "Some texts are not encoded. Encode anyway?")))
 222 ;;;               (rfc2047-encode-region (point-min) (point-max))
 223 ;;;             (error "Cannot send unencoded text")))
 224              ((mm-coding-system-p method)
 225               (if (and (featurep 'mule)
 226                        (if (boundp 'default-enable-multibyte-characters)
 227                            default-enable-multibyte-characters))
 228                   (mm-encode-coding-region (point) (point-max) method)))
 229              ;; Hm.
 230              (t)))
 231           (goto-char (point-max)))))))
 232
 233 ;; Fixme: This, and the require below may not be the Right Thing, but
 234 ;; should be safe just before release.  -- fx 2001-02-08
 235 (eval-when-compile (defvar message-posting-charset))
 236
 237 (defun rfc2047-encodable-p ()
 238   "Return non-nil if any characters in current buffer need encoding in headers.
 239 The buffer may be narrowed."
 240   (require 'message)                    ; for message-posting-charset
 241   (let ((charsets
 242          (mm-find-mime-charset-region (point-min) (point-max))))
 243     (goto-char (point-min))
 244     (or (and rfc2047-encode-encoded-words
 245              (prog1
 246                  (search-forward "=?" nil t)
 247                (goto-char (point-min))))
 248         (and charsets
 249              (not (equal charsets (list (car message-posting-charset))))))))
 250
 251 ;; Use this syntax table when parsing into regions that may need
 252 ;; encoding.  Double quotes are string delimiters, backslash is
 253 ;; character quoting, and all other RFC 2822 special characters are
 254 ;; treated as punctuation so we can use forward-sexp/forward-word to
 255 ;; skip to the end of regions appropriately.  Nb. ietf-drums does
 256 ;; things differently.
 257 (defconst rfc2047-syntax-table
 258   ;; (make-char-table 'syntax-table '(2)) only works in Emacs.
 259   (let ((table (make-syntax-table)))
 260     ;; The following is done to work for setting all elements of the table
 261     ;; in Emacs 21 and 22 and XEmacs; it appears to be the cleanest way.
 262     ;; Play safe and don't assume the form of the word syntax entry --
 263     ;; copy it from ?a.
 264     (if (fboundp 'set-char-table-range) ; Emacs
 265         (funcall (intern "set-char-table-range")
 266                  table t (aref (standard-syntax-table) ?a))
 267       (if (fboundp 'put-char-table)
 268           (if (fboundp 'get-char-table) ; warning avoidance
 269               (put-char-table t (get-char-table ?a (standard-syntax-table))
 270                               table))))
 271     (modify-syntax-entry ?\\ "\\" table)
 272     (modify-syntax-entry ?\" "\"" table)
 273     (modify-syntax-entry ?\( "(" table)
 274     (modify-syntax-entry ?\) ")" table)
 275     (modify-syntax-entry ?\< "." table)
 276     (modify-syntax-entry ?\> "." table)
 277     (modify-syntax-entry ?\[ "." table)
 278     (modify-syntax-entry ?\] "." table)
 279     (modify-syntax-entry ?: "." table)
 280     (modify-syntax-entry ?\; "." table)
 281     (modify-syntax-entry ?, "." table)
 282     (modify-syntax-entry ?@ "." table)
 283     table))
 284
 285 (defun rfc2047-encode-region (b e)
 286   "Encode words in region B to E that need encoding.
 287 By default, the region is treated as containing RFC2822 addresses.
 288 Dynamically bind `rfc2047-encoding-type' to change that."
 289   (save-restriction
 290     (narrow-to-region b e)
 291     (let ((encodable-regexp (if rfc2047-encode-encoded-words
 292                                 "[^\000-\177]+\\|=\\?"
 293                               "[^\000-\177]+"))
 294           start                         ; start of current token
 295           end begin csyntax
 296           ;; Whether there's an encoded word before the current token,
 297           ;; either immediately or separated by space.
 298           last-encoded
 299           (orig-text (buffer-substring-no-properties b e)))
 300       (if (eq 'mime rfc2047-encoding-type)
 301           ;; Simple case.  Continuous words in which all those contain
 302           ;; non-ASCII characters are encoded collectively.  Encoding
 303           ;; ASCII words, including `Re:' used in Subject headers, is
 304           ;; avoided for interoperability with non-MIME clients and
 305           ;; for making it easy to find keywords.
 306           (progn
 307             (goto-char (point-min))
 308             (while (progn (skip-chars-forward " \t\n")
 309                           (not (eobp)))
 310               (setq start (point))
 311               (while (and (looking-at "[ \t\n]*\\([^ \t\n]+\\)")
 312                           (progn
 313                             (setq end (match-end 0))
 314                             (re-search-forward encodable-regexp end t)))
 315                 (goto-char end))
 316               (if (> (point) start)
 317                   (rfc2047-encode start (point))
 318                 (goto-char end))))
 319         ;; `address-mime' case -- take care of quoted words, comments.
 320         (with-syntax-table rfc2047-syntax-table
 321           (goto-char (point-min))
 322           (condition-case nil           ; in case of unbalanced quotes
 323               ;; Look for rfc2822-style: sequences of atoms, quoted
 324               ;; strings, specials, whitespace.  (Specials mustn't be
 325               ;; encoded.)
 326               (while (not (eobp))
 327                 ;; Skip whitespace.
 328                 (skip-chars-forward " \t\n")
 329                 (setq start (point))
 330                 (cond
 331                  ((not (char-after)))   ; eob
 332                  ;; else token start
 333                  ((eq ?\" (setq csyntax (char-syntax (char-after))))
 334                   ;; Quoted word.
 335                   (forward-sexp)
 336                   (setq end (point))
 337                   ;; Does it need encoding?
 338                   (goto-char start)
 339                   (if (re-search-forward encodable-regexp end 'move)
 340                       ;; It needs encoding.  Strip the quotes first,
 341                       ;; since encoded words can't occur in quotes.
 342                       (progn
 343                         (goto-char end)
 344                         (delete-backward-char 1)
 345                         (goto-char start)
 346                         (delete-char 1)
 347                         (when last-encoded
 348                           ;; There was a preceding quoted word.  We need
 349                           ;; to include any separating whitespace in this
 350                           ;; word to avoid it getting lost.
 351                           (skip-chars-backward " \t")
 352                           ;; A space is needed between the encoded words.
 353                           (insert ? )
 354                           (setq start (point)
 355                                 end (1+ end)))
 356                         ;; Adjust the end position for the deleted quotes.
 357                         (rfc2047-encode start (- end 2))
 358                         (setq last-encoded t)) ; record that it was encoded
 359                     (setq last-encoded  nil)))
 360                  ((eq ?. csyntax)
 361                   ;; Skip other delimiters, but record that they've
 362                   ;; potentially separated quoted words.
 363                   (forward-char)
 364                   (setq last-encoded nil))
 365                  ((eq ?\) csyntax)
 366                   (error "Unbalanced parentheses"))
 367                  ((eq ?\( csyntax)
 368                   ;; Look for the end of parentheses.
 369                   (forward-list)
 370                   ;; Encode text as an unstructured field.
 371                   (let ((rfc2047-encoding-type 'mime))
 372                     (rfc2047-encode-region (1+ start) (1- (point)))
 373                     (forward-char)))
 374                  (t                 ; normal token/whitespace sequence
 375                   ;; Find the end.
 376                   ;; Skip one ASCII word, or encode continuous words
 377                   ;; in which all those contain non-ASCII characters.
 378                   (setq end nil)
 379                   (while (not end)
 380                     (when (looking-at "[\000-\177]+")
 381                       (setq begin (point)
 382                             end (match-end 0))
 383                       (when (progn
 384                               (while (and (or (re-search-forward
 385                                                "[ \t\n]\\|\\Sw" end 'move)
 386                                               (setq end nil))
 387                                           (eq ?\\ (char-syntax (char-before))))
 388                                 ;; Skip backslash-quoted characters.
 389                                 (forward-char))
 390                               end)
 391                         (setq end (match-beginning 0))
 392                         (if rfc2047-encode-encoded-words
 393                             (progn
 394                               (goto-char begin)
 395                               (when (search-forward "=?" end 'move)
 396                                 (goto-char (match-beginning 0))
 397                                 (setq end nil)))
 398                           (goto-char end))))
 399                     (unless end
 400                       (setq end t)
 401                       (when (looking-at encodable-regexp)
 402                         (goto-char (match-end 0))
 403                         (while (and (looking-at "[ \t\n]+\\([^ \t\n]+\\)")
 404                                     (setq end (match-end 0))
 405                                     (string-match encodable-regexp
 406                                                   (match-string 1)))
 407                           (goto-char end))
 408                         (when (looking-at "[^ \t\n]+")
 409                           (setq end (match-end 0))
 410                           (if (re-search-forward "\\Sw+" end t)
 411                               ;; There are special characters better
 412                               ;; to be encoded so that MTAs may parse
 413                               ;; them safely.
 414                               (cond ((= end (point)))
 415                                     ((looking-at encodable-regexp)
 416                                      (setq end nil))
 417                                     (t
 418                                      (goto-char (1- (match-end 0)))
 419                                      (unless (= (point) (match-beginning 0))
 420                                        (insert " "))))
 421                             (goto-char end)
 422                             (skip-chars-forward " \t\n")
 423                             (if (and (looking-at "[^ \t\n]+")
 424                                      (string-match encodable-regexp
 425                                                    (match-string 0)))
 426                                 (setq end nil)
 427                               (goto-char end)))))))
 428                   (skip-chars-backward " \t\n")
 429                   (setq end (point))
 430                   (goto-char start)
 431                   (if (re-search-forward encodable-regexp end 'move)
 432                       (progn
 433                         (rfc2047-encode start end)
 434                         (setq last-encoded t))
 435                     (setq last-encoded nil)))))
 436             (error
 437              (error "Invalid data for rfc2047 encoding: %s"
 438                     (mm-replace-in-string orig-text "[ \t\n]+" " ")))))))
 439     (rfc2047-fold-region b (point))
 440     (goto-char (point-max))))
 441
 442 (defun rfc2047-encode-string (string)
 443   "Encode words in STRING.
 444 By default, the string is treated as containing addresses (see
 445 `rfc2047-encoding-type')."
 446   (mm-with-multibyte-buffer
 447     (insert string)
 448     (rfc2047-encode-region (point-min) (point-max))
 449     (buffer-string)))
 450
 451 (defun rfc2047-encode-1 (column string cs encoder start space &optional eword)
 452   "Subroutine used by `rfc2047-encode'."
 453   (cond ((string-equal string "")
 454          (or eword ""))
 455         ((>= column 76)
 456          (when (and eword
 457                     (string-match "\n[ \t]+\\'" eword))
 458            ;; Reomove a superfluous empty line.
 459            (setq eword (substring eword 0 (match-beginning 0))))
 460          (rfc2047-encode-1 (length space) string cs encoder start " "
 461                            (concat eword "\n" space)))
 462         (t
 463          (let ((index 0)
 464                (limit (1- (length string)))
 465                (prev "")
 466                next)
 467            (while (and prev
 468                        (<= index limit))
 469              (setq next (concat start
 470                                 (funcall encoder
 471                                          (if cs
 472                                              (mm-encode-coding-string
 473                                               (substring string 0 (1+ index))
 474                                               cs)
 475                                            (substring string 0 (1+ index))))
 476                                 "?="))
 477              (if (<= (+ column (length next)) 76)
 478                  (setq prev next
 479                        index (1+ index))
 480                (setq next prev
 481                      prev nil)))
 482            (setq eword (concat eword next))
 483            (if (> index limit)
 484                eword
 485              (when (string-match "\n[ \t]+\\'" eword)
 486                ;; Reomove a superfluous empty line.
 487                (setq eword (substring eword 0 (match-beginning 0))))
 488              (rfc2047-encode-1 (length space) (substring string index)
 489                                cs encoder start " "
 490                                (concat eword "\n" space)))))))
 491
 492 (defun rfc2047-encode (b e)
 493   "Encode the word(s) in the region B to E.
 494 Point moves to the end of the region."
 495   (let ((mime-charset (or (mm-find-mime-charset-region b e) (list 'us-ascii)))
 496         cs encoding space eword)
 497     (cond ((> (length mime-charset) 1)
 498            (error "Can't rfc2047-encode `%s'"
 499                   (buffer-substring-no-properties b e)))
 500           ((= (length mime-charset) 1)
 501            (setq mime-charset (car mime-charset)
 502                  cs (mm-charset-to-coding-system mime-charset))
 503            (unless (and (mm-multibyte-p)
 504                         (mm-coding-system-p cs))
 505              (setq cs nil))
 506            (save-restriction
 507              (narrow-to-region b e)
 508              (setq encoding
 509                    (or (cdr (assq mime-charset
 510                                   rfc2047-charset-encoding-alist))
 511                        ;; For the charsets that don't have a preferred
 512                        ;; encoding, choose the one that's shorter.
 513                        (if (eq (rfc2047-qp-or-base64) 'base64)
 514                            'B
 515                          'Q)))
 516              (widen)
 517              (goto-char b)
 518              (setq b (point-marker)
 519                    e (set-marker (make-marker) e))
 520              (rfc2047-fold-region (point-at-bol) b)
 521              (unless (= 0 (skip-chars-backward " \t"))
 522                (setq space (buffer-substring-no-properties (point) b)))
 523              (setq eword (rfc2047-encode-1
 524                           (- b (point-at-bol))
 525                           (mm-replace-in-string
 526                            (buffer-substring-no-properties b e)
 527                            "\n\\([ \t]?\\)" "\\1")
 528                           cs
 529                           (or (cdr (assq encoding
 530                                          rfc2047-encode-function-alist))
 531                               'identity)
 532                           (concat "=?" (downcase (symbol-name mime-charset))
 533                                   "?" (upcase (symbol-name encoding)) "?")
 534                           (or space " ")))
 535              (delete-region (if (eq (aref eword 0) ?\n)
 536                                 (point)
 537                               (goto-char b))
 538                             e)
 539              (insert eword)
 540              (set-marker b nil)
 541              (set-marker e nil)
 542              (unless (or (eolp)
 543                          (looking-at "[ \t\n)]"))
 544                (insert " "))))
 545           (t
 546            (goto-char e)))))
 547
 548 (defun rfc2047-fold-field ()
 549   "Fold the current header field."
 550   (save-excursion
 551     (save-restriction
 552       (rfc2047-narrow-to-field)
 553       (rfc2047-fold-region (point-min) (point-max)))))
 554
 555 (defun rfc2047-fold-region (b e)
 556   "Fold long lines in region B to E."
 557   (save-restriction
 558     (narrow-to-region b e)
 559     (goto-char (point-min))
 560     (let ((break nil)
 561           (qword-break nil)
 562           (first t)
 563           (bol (save-restriction
 564                  (widen)
 565                  (point-at-bol))))
 566       (while (not (eobp))
 567         (when (and (or break qword-break)
 568                    (> (- (point) bol) 76))
 569           (goto-char (or break qword-break))
 570           (setq break nil
 571                 qword-break nil)
 572           (skip-chars-backward " \t")
 573           (if (looking-at "[ \t]")
 574               (insert ?\n)
 575             (insert "\n "))
 576           (setq bol (1- (point)))
 577           ;; Don't break before the first non-LWSP characters.
 578           (skip-chars-forward " \t")
 579           (unless (eobp)
 580             (forward-char 1)))
 581         (cond
 582          ((eq (char-after) ?\n)
 583           (forward-char 1)
 584           (setq bol (point)
 585                 break nil
 586                 qword-break nil)
 587           (skip-chars-forward " \t")
 588           (unless (or (eobp) (eq (char-after) ?\n))
 589             (forward-char 1)))
 590          ((eq (char-after) ?\r)
 591           (forward-char 1))
 592          ((memq (char-after) '(?  ?\t))
 593           (skip-chars-forward " \t")
 594           (unless first ;; Don't break just after the header name.
 595             (setq break (point))))
 596          ((not break)
 597           (if (not (looking-at "=\\?[^=]"))
 598               (if (eq (char-after) ?=)
 599                   (forward-char 1)
 600                 (skip-chars-forward "^ \t\n\r="))
 601             ;; Don't break at the start of the field.
 602             (unless (= (point) b)
 603               (setq qword-break (point)))
 604             (skip-chars-forward "^ \t\n\r")))
 605          (t
 606           (skip-chars-forward "^ \t\n\r")))
 607         (setq first nil))
 608       (when (and (or break qword-break)
 609                  (> (- (point) bol) 76))
 610         (goto-char (or break qword-break))
 611         (setq break nil
 612               qword-break nil)
 613           (if (looking-at "[ \t]")
 614               (insert ?\n)
 615             (insert "\n "))
 616         (setq bol (1- (point)))
 617         ;; Don't break before the first non-LWSP characters.
 618         (skip-chars-forward " \t")
 619         (unless (eobp)
 620           (forward-char 1))))))
 621
 622 (defun rfc2047-unfold-field ()
 623   "Fold the current line."
 624   (save-excursion
 625     (save-restriction
 626       (rfc2047-narrow-to-field)
 627       (rfc2047-unfold-region (point-min) (point-max)))))
 628
 629 (defun rfc2047-unfold-region (b e)
 630   "Unfold lines in region B to E."
 631   (save-restriction
 632     (narrow-to-region b e)
 633     (goto-char (point-min))
 634     (let ((bol (save-restriction
 635                  (widen)
 636                  (point-at-bol)))
 637           (eol (point-at-eol)))
 638       (forward-line 1)
 639       (while (not (eobp))
 640         (if (and (looking-at "[ \t]")
 641                  (< (- (point-at-eol) bol) 76))
 642             (delete-region eol (progn
 643                                  (goto-char eol)
 644                                  (skip-chars-forward "\r\n")
 645                                  (point)))
 646           (setq bol (point-at-bol)))
 647         (setq eol (point-at-eol))
 648         (forward-line 1)))))
 649
 650 (defun rfc2047-b-encode-string (string)
 651   "Base64-encode the header contained in STRING."
 652   (base64-encode-string string t))
 653
 654 (defun rfc2047-q-encode-string (string)
 655   "Quoted-printable-encode the header in STRING."
 656   (mm-with-unibyte-buffer
 657     (insert string)
 658     (quoted-printable-encode-region
 659      (point-min) (point-max) nil
 660      ;; = (\075), _ (\137), ? (\077) are used in the encoded word.
 661      ;; Avoid using 8bit characters.
 662      ;; This list excludes `especials' (see the RFC2047 syntax),
 663      ;; meaning that some characters in non-structured fields will
 664      ;; get encoded when they con't need to be.  The following is
 665      ;; what it used to be.
 666      ;;;  ;; Equivalent to "^\000-\007\011\013\015-\037\200-\377=_?"
 667      ;;;  "\010\012\014\040-\074\076\100-\136\140-\177")
 668      "-\b\n\f !#-'*+0-9A-Z\\^`-~\d")
 669     (subst-char-in-region (point-min) (point-max) ?  ?_)
 670     (buffer-string)))
 671
 672 ;;;
 673 ;;; Functions for decoding RFC2047 messages
 674 ;;;
 675
 676 (eval-and-compile
 677   (defconst rfc2047-encoded-word-regexp
 678     "=\\?\\([^][\000-\040()<>@,\;:*\\\"/?.=]+\\)\\(?:\\*[^?]+\\)?\
 679 \\?\\(B\\|Q\\)\\?\\([!->@-~ ]*\\)\\?="))
 680
 681 ;; Fixme: This should decode in place, not cons intermediate strings.
 682 ;; Also check whether it needs to worry about delimiting fields like
 683 ;; encoding.
 684
 685 ;; In fact it's reported that (invalid) encoding of mailboxes in
 686 ;; addr-specs is in use, so delimiting fields might help.  Probably
 687 ;; not decoding a word which isn't properly delimited is good enough
 688 ;; and worthwhile (is it more correct or not?), e.g. something like
 689 ;; `=?iso-8859-1?q?foo?=@'.
 690
 691 (defun rfc2047-decode-region (start end)
 692   "Decode MIME-encoded words in region between START and END."
 693   (interactive "r")
 694   (let ((case-fold-search t)
 695         b e)
 696     (save-excursion
 697       (save-restriction
 698         (narrow-to-region start end)
 699         (goto-char (point-min))
 700         ;; Remove whitespace between encoded words.
 701         (while (re-search-forward
 702                 (eval-when-compile
 703                   (concat "\\(" rfc2047-encoded-word-regexp "\\)"
 704                           "\\(\n?[ \t]\\)+"
 705                           "\\(" rfc2047-encoded-word-regexp "\\)"))
 706                 nil t)
 707           (delete-region (goto-char (match-end 1)) (match-beginning 6)))
 708         ;; Decode the encoded words.
 709         (setq b (goto-char (point-min)))
 710         (while (re-search-forward rfc2047-encoded-word-regexp nil t)
 711           (setq e (match-beginning 0))
 712           (insert (rfc2047-parse-and-decode
 713                    (prog1
 714                        (match-string 0)
 715                      (delete-region (match-beginning 0) (match-end 0)))))
 716           ;; Remove newlines between decoded words, though such things
 717           ;; essentially must not be there.
 718           (save-restriction
 719             (narrow-to-region e (point))
 720             (goto-char e)
 721             (while (re-search-forward "[\n\r]+" nil t)
 722               (replace-match " "))
 723             (goto-char (point-max)))
 724           (when (and (mm-multibyte-p)
 725                      mail-parse-charset
 726                      (not (eq mail-parse-charset 'us-ascii))
 727                      (not (eq mail-parse-charset 'gnus-decoded)))
 728             (mm-decode-coding-region b e mail-parse-charset))
 729           (setq b (point)))
 730         (when (and (mm-multibyte-p)
 731                    mail-parse-charset
 732                    (not (eq mail-parse-charset 'us-ascii))
 733                    (not (eq mail-parse-charset 'gnus-decoded)))
 734           (mm-decode-coding-region b (point-max) mail-parse-charset))))))
 735
 736 (defun rfc2047-decode-string (string)
 737   "Decode the quoted-printable-encoded STRING and return the results."
 738   (let ((m (mm-multibyte-p)))
 739     (if (string-match "=\\?" string)
 740         (with-temp-buffer
 741           ;; Fixme: This logic is wrong, but seems to be required by
 742           ;; Gnus summary buffer generation.  The value of `m' depends
 743           ;; on the current buffer, not global multibyteness or that
 744           ;; of the string.  Also the string returned should always be
 745           ;; multibyte in a multibyte session, i.e. the buffer should
 746           ;; be multibyte before `buffer-string' is called.
 747           (when m
 748             (mm-enable-multibyte))
 749           (insert string)
 750           (inline
 751             (rfc2047-decode-region (point-min) (point-max)))
 752           (buffer-string))
 753       ;; Fixme: As above, `m' here is inappropriate.
 754       (if (and m
 755                mail-parse-charset
 756                (not (eq mail-parse-charset 'us-ascii))
 757                (not (eq mail-parse-charset 'gnus-decoded)))
 758           ;; `decode-coding-string' in Emacs offers a third optional
 759           ;; arg NOCOPY to avoid consing a new string if the decoding
 760           ;; is "trivial".  Unfortunately it currently doesn't
 761           ;; consider anything else than a `nil' coding system
 762           ;; trivial.
 763           ;; `rfc2047-decode-string' is called multiple times for each
 764           ;; article during summary buffer generation, and we really
 765           ;; want to avoid unnecessary consing.  So we bypass
 766           ;; `decode-coding-string' if the string is purely ASCII.
 767           (if (and (fboundp 'detect-coding-string)
 768                    ;; string is purely ASCII
 769                    (eq (detect-coding-string string t) 'undecided))
 770               string
 771             (mm-decode-coding-string string mail-parse-charset))
 772         (mm-string-as-multibyte string)))))
 773
 774 (defun rfc2047-parse-and-decode (word)
 775   "Decode WORD and return it if it is an encoded word.
 776 Return WORD if it is not not an encoded word or if the charset isn't
 777 decodable."
 778   (if (not (string-match rfc2047-encoded-word-regexp word))
 779       word
 780     (or
 781      (condition-case nil
 782          (rfc2047-decode
 783           (match-string 1 word)
 784           (string-to-char (match-string 2 word))
 785           (match-string 3 word))
 786        (error word))
 787      word)))                            ; un-decodable
 788
 789 (defun rfc2047-pad-base64 (string)
 790   "Pad STRING to quartets."
 791   ;; Be more liberal to accept buggy base64 strings. If
 792   ;; base64-decode-string accepts buggy strings, this function could
 793   ;; be aliased to identity.
 794   (if (= 0 (mod (length string) 4))
 795       string
 796     (when (string-match "=+$" string)
 797       (setq string (substring string 0 (match-beginning 0))))
 798     (case (mod (length string) 4)
 799       (0 string)
 800       (1 string) ;; Error, don't pad it.
 801       (2 (concat string "=="))
 802       (3 (concat string "=")))))
 803
 804 (defun rfc2047-decode (charset encoding string)
 805   "Decode STRING from the given MIME CHARSET in the given ENCODING.
 806 Valid ENCODINGs are the characters \"B\" and \"Q\".
 807 If your Emacs implementation can't decode CHARSET, return nil."
 808   (if (stringp charset)
 809       (setq charset (intern (downcase charset))))
 810   (if (or (not charset)
 811           (eq 'gnus-all mail-parse-ignored-charsets)
 812           (memq 'gnus-all mail-parse-ignored-charsets)
 813           (memq charset mail-parse-ignored-charsets))
 814       (setq charset mail-parse-charset))
 815   (let ((cs (mm-charset-to-coding-system charset)))
 816     (if (and (not cs) charset
 817              (listp mail-parse-ignored-charsets)
 818              (memq 'gnus-unknown mail-parse-ignored-charsets))
 819         (setq cs (mm-charset-to-coding-system mail-parse-charset)))
 820     (when cs
 821       (when (eq cs 'ascii)
 822         (setq cs (or mail-parse-charset 'raw-text)))
 823       (mm-decode-coding-string
 824        (cond
 825         ((char-equal ?B encoding)
 826          (base64-decode-string
 827           (rfc2047-pad-base64 string)))
 828         ((char-equal ?Q encoding)
 829          (quoted-printable-decode-string
 830           (mm-subst-char-in-string ?_ ? string t)))
 831         (t (error "Invalid encoding: %c" encoding)))
 832        cs))))
 833
 834 (provide 'rfc2047)
 835
 836 ;;; arch-tag: a07fe3d4-22b5-4c4a-bd89-b1f82d5d36f6
 837 ;;; rfc2047.el ends here