cgit.sxemacs.org Git - gnus/blob - lisp/nnweb.el

   1 ;;; nnweb.el --- retrieving articles via web search engines
   2 ;; Copyright (C) 1996,97,98 Free Software Foundation, Inc.
   3
   4 ;; Author: Lars Magne Ingebrigtsen <larsi@gnus.org>
   5 ;; Keywords: news
   6
   7 ;; This file is part of GNU Emacs.
   8
   9 ;; GNU Emacs is free software; you can redistribute it and/or modify
  10 ;; it under the terms of the GNU General Public License as published by
  11 ;; the Free Software Foundation; either version 2, or (at your option)
  12 ;; any later version.
  13
  14 ;; GNU Emacs is distributed in the hope that it will be useful,
  15 ;; but WITHOUT ANY WARRANTY; without even the implied warranty of
  16 ;; MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.  See the
  17 ;; GNU General Public License for more details.
  18
  19 ;; You should have received a copy of the GNU General Public License
  20 ;; along with GNU Emacs; see the file COPYING.  If not, write to the
  21 ;; Free Software Foundation, Inc., 59 Temple Place - Suite 330,
  22 ;; Boston, MA 02111-1307, USA.
  23
  24 ;;; Commentary:
  25
  26 ;; Note: You need to have `url' and `w3' installed for this
  27 ;; backend to work.
  28
  29 ;;; Code:
  30
  31 (eval-when-compile (require 'cl))
  32
  33 (require 'nnoo)
  34 (require 'message)
  35 (require 'gnus-util)
  36 (require 'gnus)
  37 (require 'nnmail)
  38 (eval-when-compile
  39   (ignore-errors
  40     (require 'w3)
  41     (require 'url)
  42     (require 'w3-forms)))
  43 ;; Report failure to find w3 at load time if appropriate.
  44 (eval '(progn
  45          (require 'w3)
  46          (require 'url)
  47          (require 'w3-forms)))
  48
  49 (nnoo-declare nnweb)
  50
  51 (defvoo nnweb-directory (nnheader-concat gnus-directory "nnweb/")
  52   "Where nnweb will save its files.")
  53
  54 (defvoo nnweb-type 'dejanews
  55   "What search engine type is being used.
  56 Valid types include `dejanews', `dejanewsold', `reference',
  57 and `altavista'.")
  58
  59 (defvoo nnweb-type-definition
  60   '((dejanews
  61      (article . nnweb-dejanews-wash-article)
  62      (map . nnweb-dejanews-create-mapping)
  63      (search . nnweb-dejanews-search)
  64      (address . "http://x8.dejanews.com/dnquery.xp")
  65      (identifier . nnweb-dejanews-identity))
  66     (dejanewsold
  67      (article . nnweb-dejanews-wash-article)
  68      (map . nnweb-dejanews-create-mapping)
  69      (search . nnweb-dejanewsold-search)
  70      (address . "http://x8.dejanews.com/dnquery.xp")
  71      (identifier . nnweb-dejanews-identity))
  72     (reference
  73      (article . nnweb-reference-wash-article)
  74      (map . nnweb-reference-create-mapping)
  75      (search . nnweb-reference-search)
  76      (address . "http://www.reference.com/cgi-bin/pn/go")
  77      (identifier . identity))
  78     (altavista
  79      (article . nnweb-altavista-wash-article)
  80      (map . nnweb-altavista-create-mapping)
  81      (search . nnweb-altavista-search)
  82      (address . "http://www.altavista.digital.com/cgi-bin/query")
  83      (id . "/cgi-bin/news?id@%s")
  84      (identifier . identity)))
  85   "Type-definition alist.")
  86
  87 (defvoo nnweb-search nil
  88   "Search string to feed to DejaNews.")
  89
  90 (defvoo nnweb-max-hits 999
  91   "Maximum number of hits to display.")
  92
  93 (defvoo nnweb-ephemeral-p nil
  94   "Whether this nnweb server is ephemeral.")
  95
  96 ;;; Internal variables
  97
  98 (defvoo nnweb-articles nil)
  99 (defvoo nnweb-buffer nil)
 100 (defvoo nnweb-group-alist nil)
 101 (defvoo nnweb-group nil)
 102 (defvoo nnweb-hashtb nil)
 103
 104 ;;; Interface functions
 105
 106 (nnoo-define-basics nnweb)
 107
 108 (deffoo nnweb-retrieve-headers (articles &optional group server fetch-old)
 109   (nnweb-possibly-change-server group server)
 110   (save-excursion
 111     (set-buffer nntp-server-buffer)
 112     (erase-buffer)
 113     (let (article header)
 114       (while (setq article (pop articles))
 115         (when (setq header (cadr (assq article nnweb-articles)))
 116           (nnheader-insert-nov header)))
 117       'nov)))
 118
 119 (deffoo nnweb-request-scan (&optional group server)
 120   (nnweb-possibly-change-server group server)
 121   (setq nnweb-hashtb (gnus-make-hashtable 4095))
 122   (funcall (nnweb-definition 'map))
 123   (unless nnweb-ephemeral-p
 124     (nnweb-write-active)
 125     (nnweb-write-overview group)))
 126
 127 (deffoo nnweb-request-group (group &optional server dont-check)
 128   (nnweb-possibly-change-server nil server)
 129   (when (and group
 130              (not (equal group nnweb-group))
 131              (not nnweb-ephemeral-p))
 132     (let ((info (assoc group nnweb-group-alist)))
 133       (setq nnweb-group group)
 134       (setq nnweb-type (nth 2 info))
 135       (setq nnweb-search (nth 3 info))
 136       (unless dont-check
 137         (nnweb-read-overview group))))
 138   (cond
 139    ((not nnweb-articles)
 140     (nnheader-report 'nnweb "No matching articles"))
 141    (t
 142     (let ((active (if nnweb-ephemeral-p
 143                       (cons (caar nnweb-articles)
 144                             (caar (last nnweb-articles)))
 145                     (cadr (assoc group nnweb-group-alist)))))
 146       (nnheader-report 'nnweb "Opened group %s" group)
 147       (nnheader-insert
 148        "211 %d %d %d %s\n" (length nnweb-articles)
 149        (car active) (cdr active) group)))))
 150
 151 (deffoo nnweb-close-group (group &optional server)
 152   (nnweb-possibly-change-server group server)
 153   (when (gnus-buffer-live-p nnweb-buffer)
 154     (save-excursion
 155       (set-buffer nnweb-buffer)
 156       (set-buffer-modified-p nil)
 157       (kill-buffer nnweb-buffer)))
 158   t)
 159
 160 (deffoo nnweb-request-article (article &optional group server buffer)
 161   (nnweb-possibly-change-server group server)
 162   (save-excursion
 163     (set-buffer (or buffer nntp-server-buffer))
 164     (let* ((header (cadr (assq article nnweb-articles)))
 165            (url (and header (mail-header-xref header))))
 166       (when (or (and url
 167                      (nnweb-fetch-url url))
 168                 (and (stringp article)
 169                      (nnweb-definition 'id t)
 170                      (let ((fetch (nnweb-definition 'id))
 171                            art)
 172                        (when (string-match "^<\\(.*\\)>$" article)
 173                          (setq art (match-string 1 article)))
 174                        (and fetch
 175                             art
 176                             (nnweb-fetch-url
 177                              (format fetch article))))))
 178         (unless nnheader-callback-function
 179           (funcall (nnweb-definition 'article))
 180           (nnweb-decode-entities))
 181         (nnheader-report 'nnweb "Fetched article %s" article)
 182         t))))
 183
 184 (deffoo nnweb-close-server (&optional server)
 185   (when (and (nnweb-server-opened server)
 186              (gnus-buffer-live-p nnweb-buffer))
 187     (save-excursion
 188       (set-buffer nnweb-buffer)
 189       (set-buffer-modified-p nil)
 190       (kill-buffer nnweb-buffer)))
 191   (nnoo-close-server 'nnweb server))
 192
 193 (deffoo nnweb-request-list (&optional server)
 194   (nnweb-possibly-change-server nil server)
 195   (save-excursion
 196     (set-buffer nntp-server-buffer)
 197     (nnmail-generate-active nnweb-group-alist)
 198     t))
 199
 200 (deffoo nnweb-request-update-info (group info &optional server)
 201   (nnweb-possibly-change-server group server)
 202   ;;(setcar (cddr info) nil)
 203   )
 204
 205 (deffoo nnweb-asynchronous-p ()
 206   t)
 207
 208 (deffoo nnweb-request-create-group (group &optional server args)
 209   (nnweb-possibly-change-server nil server)
 210   (nnweb-request-delete-group group)
 211   (push `(,group ,(cons 1 0) ,@args) nnweb-group-alist)
 212   (nnweb-write-active)
 213   t)
 214
 215 (deffoo nnweb-request-delete-group (group &optional force server)
 216   (nnweb-possibly-change-server group server)
 217   (gnus-pull group nnweb-group-alist)
 218   (gnus-delete-file (nnweb-overview-file group))
 219   t)
 220
 221 (nnoo-define-skeleton nnweb)
 222
 223 ;;; Internal functions
 224
 225 (defun nnweb-read-overview (group)
 226   "Read the overview of GROUP and build the map."
 227   (when (file-exists-p (nnweb-overview-file group))
 228     (with-temp-buffer
 229       (nnheader-insert-file-contents (nnweb-overview-file group))
 230       (goto-char (point-min))
 231       (let (header)
 232         (while (not (eobp))
 233           (setq header (nnheader-parse-nov))
 234           (forward-line 1)
 235           (push (list (mail-header-number header)
 236                       header (mail-header-xref header))
 237                 nnweb-articles)
 238           (nnweb-set-hashtb header (car nnweb-articles)))))))
 239
 240 (defun nnweb-write-overview (group)
 241   "Write the overview file for GROUP."
 242   (with-temp-file (nnweb-overview-file group)
 243     (let ((articles nnweb-articles))
 244       (while articles
 245         (nnheader-insert-nov (cadr (pop articles)))))))
 246
 247 (defun nnweb-set-hashtb (header data)
 248   (gnus-sethash (nnweb-identifier (mail-header-xref header))
 249                 data nnweb-hashtb))
 250
 251 (defun nnweb-get-hashtb (url)
 252   (gnus-gethash (nnweb-identifier url) nnweb-hashtb))
 253
 254 (defun nnweb-identifier (ident)
 255   (funcall (nnweb-definition 'identifier) ident))
 256
 257 (defun nnweb-overview-file (group)
 258   "Return the name of the overview file of GROUP."
 259   (nnheader-concat nnweb-directory group ".overview"))
 260
 261 (defun nnweb-write-active ()
 262   "Save the active file."
 263   (with-temp-file (nnheader-concat nnweb-directory "active")
 264     (prin1 `(setq nnweb-group-alist ',nnweb-group-alist) (current-buffer))))
 265
 266 (defun nnweb-read-active ()
 267   "Read the active file."
 268   (load (nnheader-concat nnweb-directory "active") t t t))
 269
 270 (defun nnweb-definition (type &optional noerror)
 271   "Return the definition of TYPE."
 272   (let ((def (cdr (assq type (assq nnweb-type nnweb-type-definition)))))
 273     (when (and (not def)
 274                (not noerror))
 275       (error "Undefined definition %s" type))
 276     def))
 277
 278 (defun nnweb-possibly-change-server (&optional group server)
 279   (nnweb-init server)
 280   (when server
 281     (unless (nnweb-server-opened server)
 282       (nnweb-open-server server)))
 283   (unless nnweb-group-alist
 284     (nnweb-read-active))
 285   (when group
 286     (when (and (not nnweb-ephemeral-p)
 287                (not (equal group nnweb-group)))
 288       (nnweb-request-group group nil t))))
 289
 290 (defun nnweb-init (server)
 291   "Initialize buffers and such."
 292   (unless (gnus-buffer-live-p nnweb-buffer)
 293     (setq nnweb-buffer
 294           (save-excursion
 295             (nnheader-set-temp-buffer
 296              (format " *nnweb %s %s %s*" nnweb-type nnweb-search server))))))
 297
 298 (defun nnweb-fetch-url (url)
 299   (save-excursion
 300     (if (not nnheader-callback-function)
 301         (let ((buf (current-buffer)))
 302           (save-excursion
 303             (set-buffer nnweb-buffer)
 304             (erase-buffer)
 305             (url-insert-file-contents url)
 306             (copy-to-buffer buf (point-min) (point-max))
 307             t))
 308       (nnweb-url-retrieve-asynch
 309        url 'nnweb-callback (current-buffer) nnheader-callback-function)
 310       t)))
 311
 312 (defun nnweb-callback (buffer callback)
 313   (when (gnus-buffer-live-p url-working-buffer)
 314     (save-excursion
 315       (set-buffer url-working-buffer)
 316       (funcall (nnweb-definition 'article))
 317       (nnweb-decode-entities)
 318       (set-buffer buffer)
 319       (goto-char (point-max))
 320       (insert-buffer-substring url-working-buffer))
 321     (funcall callback t)
 322     (gnus-kill-buffer url-working-buffer)))
 323
 324 (defun nnweb-url-retrieve-asynch (url callback &rest data)
 325   (let ((url-request-method "GET")
 326         (old-asynch url-be-asynchronous)
 327         (url-request-data nil)
 328         (url-request-extra-headers nil)
 329         (url-working-buffer (generate-new-buffer-name " *nnweb*")))
 330     (setq-default url-be-asynchronous t)
 331     (save-excursion
 332       (set-buffer (get-buffer-create url-working-buffer))
 333       (setq url-current-callback-data data
 334             url-be-asynchronous t
 335             url-current-callback-func callback)
 336       (url-retrieve url))
 337     (setq-default url-be-asynchronous old-asynch)))
 338
 339 (defun nnweb-encode-www-form-urlencoded (pairs)
 340   "Return PAIRS encoded for forms."
 341   (mapconcat
 342    (function
 343     (lambda (data)
 344       (concat (w3-form-encode-xwfu (car data)) "="
 345               (w3-form-encode-xwfu (cdr data)))))
 346    pairs "&"))
 347
 348 (defun nnweb-fetch-form (url pairs)
 349   (let ((url-request-data (nnweb-encode-www-form-urlencoded pairs))
 350         (url-request-method "POST")
 351         (url-request-extra-headers
 352          '(("Content-type" . "application/x-www-form-urlencoded"))))
 353     (url-insert-file-contents url)
 354     (setq buffer-file-name nil))
 355   t)
 356
 357 (defun nnweb-decode-entities ()
 358   (goto-char (point-min))
 359   (while (re-search-forward "&\\([a-z]+\\);" nil t)
 360     (replace-match (char-to-string (or (cdr (assq (intern (match-string 1))
 361                                                   w3-html-entities))
 362                                        ?#))
 363                    t t)))
 364
 365 (defun nnweb-remove-markup ()
 366   (goto-char (point-min))
 367   (while (search-forward "<!--" nil t)
 368     (delete-region (match-beginning 0)
 369                    (or (search-forward "-->" nil t)
 370                        (point-max))))
 371   (goto-char (point-min))
 372   (while (re-search-forward "<[^>]+>" nil t)
 373     (replace-match "" t t)))
 374
 375 ;;;
 376 ;;; DejaNews functions.
 377 ;;;
 378
 379 (defun nnweb-dejanews-create-mapping ()
 380   "Perform the search and create an number-to-url alist."
 381   (save-excursion
 382     (set-buffer nnweb-buffer)
 383     (erase-buffer)
 384     (when (funcall (nnweb-definition 'search) nnweb-search)
 385       (let ((i 0)
 386             (more t)
 387             (case-fold-search t)
 388             (active (or (cadr (assoc nnweb-group nnweb-group-alist))
 389                         (cons 1 0)))
 390             Subject (Score "0") Date Newsgroup Author
 391             map url)
 392         (while more
 393           ;; Go through all the article hits on this page.
 394           (goto-char (point-min))
 395           (nnweb-decode-entities)
 396           (goto-char (point-min))
 397           (while (re-search-forward "^ <P>\n" nil t)
 398             (narrow-to-region
 399              (point)
 400              (cond ((re-search-forward "^ <P>\n" nil t)
 401                     (match-beginning 0))
 402                    ((search-forward "\n\n" nil t)
 403                     (point))
 404                    (t
 405                     (point-max))))
 406             (goto-char (point-min))
 407             (looking-at ".*HREF=\"\\([^\"]+\\)\"\\(.*\\)")
 408             (setq url (match-string 1))
 409             (let ((begin (point)))
 410               (nnweb-remove-markup)
 411               (goto-char begin)
 412               (while (search-forward "\t" nil t)
 413                 (replace-match " "))
 414               (goto-char begin)
 415               (end-of-line)
 416               (setq Subject (buffer-substring begin (point)))
 417               (if (re-search-forward
 418                    "^ Newsgroup: \\(.*\\)\n Posted on \\([0-9/]+\\) by \\(.*\\)$" nil t)
 419                   (setq Newsgroup (match-string 1)
 420                         Date (match-string 2)
 421                         Author (match-string 3))))
 422             (widen)
 423             (incf i)
 424             (unless (nnweb-get-hashtb url)
 425               (push
 426                (list
 427                 (incf (cdr active))
 428                 (make-full-mail-header
 429                  (cdr active) Subject Author Date
 430                  (concat "<" (nnweb-identifier url) "@dejanews>")
 431                  nil 0 (string-to-int Score) url))
 432                map)
 433               (nnweb-set-hashtb (cadar map) (car map))))
 434           ;; See whether there is a "Get next 20 hits" button here.
 435           (if (or (not (re-search-forward
 436                         "HREF=\"\\([^\"]+\\)\"[<>b]+Next result" nil t))
 437                   (>= i nnweb-max-hits))
 438               (setq more nil)
 439             ;; Yup -- fetch it.
 440             (setq more (match-string 1))
 441             (erase-buffer)
 442             (url-insert-file-contents more)))
 443         ;; Return the articles in the right order.
 444         (setq nnweb-articles
 445               (sort (nconc nnweb-articles map) 'car-less-than-car))))))
 446
 447 (defun nnweb-dejanews-wash-article ()
 448   (let ((case-fold-search t))
 449     (goto-char (point-min))
 450     (re-search-forward "<PRE>" nil t)
 451     (delete-region (point-min) (point))
 452     (re-search-forward "</PRE>" nil t)
 453     (delete-region (point) (point-max))
 454     (nnweb-remove-markup)
 455     (goto-char (point-min))
 456     (while (and (looking-at " *$")
 457                 (not (eobp)))
 458       (gnus-delete-line))
 459     (while (looking-at "\\(^[^ ]+:\\) *")
 460       (replace-match "\\1 " t)
 461       (forward-line 1))
 462     (when (re-search-forward "\n\n+" nil t)
 463       (replace-match "\n" t t))
 464     (goto-char (point-min))
 465     (when (search-forward "[More Headers]" nil t)
 466       (replace-match "" t t))))
 467
 468 (defun nnweb-dejanews-search (search)
 469   (nnweb-fetch-form
 470    (nnweb-definition 'address)
 471    `(("query" . ,search)
 472      ("defaultOp" . "AND")
 473      ("svcclass" . "dncurrent")
 474      ("maxhits" . "100")
 475      ("format" . "verbose2")
 476      ("threaded" . "0")
 477      ("showsort" . "date")
 478      ("agesign" . "1")
 479      ("ageweight" . "1")))
 480   t)
 481
 482 (defun nnweb-dejanewsold-search (search)
 483   (nnweb-fetch-form
 484    (nnweb-definition 'address)
 485    `(("query" . ,search)
 486      ("defaultOp" . "AND")
 487      ("svcclass" . "dnold")
 488      ("maxhits" . "100")
 489      ("format" . "verbose2")
 490      ("threaded" . "0")
 491      ("showsort" . "date")
 492      ("agesign" . "1")
 493      ("ageweight" . "1")))
 494   t)
 495
 496 (defun nnweb-dejanews-identity (url)
 497   "Return an unique identifier based on URL."
 498   (if (string-match "recnum=\\([0-9]+\\)" url)
 499       (match-string 1 url)
 500     url))
 501
 502 ;;;
 503 ;;; InReference
 504 ;;;
 505
 506 (defun nnweb-reference-create-mapping ()
 507   "Perform the search and create an number-to-url alist."
 508   (save-excursion
 509     (set-buffer nnweb-buffer)
 510     (erase-buffer)
 511     (when (funcall (nnweb-definition 'search) nnweb-search)
 512       (let ((i 0)
 513             (more t)
 514             (case-fold-search t)
 515             (active (or (cadr (assoc nnweb-group nnweb-group-alist))
 516                         (cons 1 0)))
 517             Subject Score Date Newsgroups From Message-ID
 518             map url)
 519         (while more
 520           ;; Go through all the article hits on this page.
 521           (goto-char (point-min))
 522           (search-forward "</pre><hr>" nil t)
 523           (delete-region (point-min) (point))
 524                                         ;(nnweb-decode-entities)
 525           (goto-char (point-min))
 526           (while (re-search-forward "^ +[0-9]+\\." nil t)
 527             (narrow-to-region
 528              (point)
 529              (if (re-search-forward "^$" nil t)
 530                  (match-beginning 0)
 531                (point-max)))
 532             (goto-char (point-min))
 533             (when (looking-at ".*href=\"\\([^\"]+\\)\"")
 534               (setq url (match-string 1)))
 535             (nnweb-remove-markup)
 536             (goto-char (point-min))
 537             (while (search-forward "\t" nil t)
 538               (replace-match " "))
 539             (goto-char (point-min))
 540             (while (re-search-forward "^\\([^:]+\\): \\(.*\\)$" nil t)
 541               (set (intern (match-string 1)) (match-string 2)))
 542             (widen)
 543             (search-forward "</pre>" nil t)
 544             (incf i)
 545             (unless (nnweb-get-hashtb url)
 546               (push
 547                (list
 548                 (incf (cdr active))
 549                 (make-full-mail-header
 550                  (cdr active) (concat  "(" Newsgroups ") " Subject) From Date
 551                  Message-ID
 552                  nil 0 (string-to-int Score) url))
 553                map)
 554               (nnweb-set-hashtb (cadar map) (car map))))
 555           (setq more nil))
 556         ;; Return the articles in the right order.
 557         (setq nnweb-articles
 558               (sort (nconc nnweb-articles map) 'car-less-than-car))))))
 559
 560 (defun nnweb-reference-wash-article ()
 561   (let ((case-fold-search t))
 562     (goto-char (point-min))
 563     (re-search-forward "^</center><hr>" nil t)
 564     (delete-region (point-min) (point))
 565     (search-forward "<pre>" nil t)
 566     (forward-line -1)
 567     (let ((body (point-marker)))
 568       (search-forward "</pre>" nil t)
 569       (delete-region (point) (point-max))
 570       (nnweb-remove-markup)
 571       (goto-char (point-min))
 572       (while (looking-at " *$")
 573         (gnus-delete-line))
 574       (narrow-to-region (point-min) body)
 575       (while (and (re-search-forward "^$" nil t)
 576                   (not (eobp)))
 577         (gnus-delete-line))
 578       (goto-char (point-min))
 579       (while (looking-at "\\(^[^ ]+:\\) *")
 580         (replace-match "\\1 " t)
 581         (forward-line 1))
 582       (goto-char (point-min))
 583       (when (re-search-forward "^References:" nil t)
 584         (narrow-to-region
 585          (point) (if (re-search-forward "^$\\|^[^:]+:" nil t)
 586                      (match-beginning 0)
 587                    (point-max)))
 588         (goto-char (point-min))
 589         (while (not (eobp))
 590           (unless (looking-at "References")
 591             (insert "\t")
 592             (forward-line 1)))
 593         (goto-char (point-min))
 594         (while (search-forward "," nil t)
 595           (replace-match " " t t)))
 596       (widen)
 597       (set-marker body nil))))
 598
 599 (defun nnweb-reference-search (search)
 600   (url-insert-file-contents
 601    (concat
 602     (nnweb-definition 'address)
 603     "?"
 604     (nnweb-encode-www-form-urlencoded
 605      `(("search" . "advanced")
 606        ("querytext" . ,search)
 607        ("subj" . "")
 608        ("name" . "")
 609        ("login" . "")
 610        ("host" . "")
 611        ("organization" . "")
 612        ("groups" . "")
 613        ("keywords" . "")
 614        ("choice" . "Search")
 615        ("startmonth" . "Jul")
 616        ("startday" . "25")
 617        ("startyear" . "1996")
 618        ("endmonth" . "Aug")
 619        ("endday" . "24")
 620        ("endyear" . "1996")
 621        ("mode" . "Quick")
 622        ("verbosity" . "Verbose")
 623        ("ranking" . "Relevance")
 624        ("first" . "1")
 625        ("last" . "25")
 626        ("score" . "50")))))
 627   (setq buffer-file-name nil)
 628   t)
 629
 630 ;;;
 631 ;;; Alta Vista
 632 ;;;
 633
 634 (defun nnweb-altavista-create-mapping ()
 635   "Perform the search and create an number-to-url alist."
 636   (save-excursion
 637     (set-buffer nnweb-buffer)
 638     (erase-buffer)
 639     (let ((part 0))
 640       (when (funcall (nnweb-definition 'search) nnweb-search part)
 641         (let ((i 0)
 642               (more t)
 643               (case-fold-search t)
 644               (active (or (cadr (assoc nnweb-group nnweb-group-alist))
 645                           (cons 1 0)))
 646               subject date from id group
 647               map url)
 648           (while more
 649             ;; Go through all the article hits on this page.
 650             (goto-char (point-min))
 651             (search-forward "<dt>" nil t)
 652             (delete-region (point-min) (match-beginning 0))
 653             (goto-char (point-min))
 654             (while (search-forward "<dt>" nil t)
 655               (replace-match "\n<blubb>"))
 656             (nnweb-decode-entities)
 657             (goto-char (point-min))
 658             (while (re-search-forward "<blubb>.*href=\"\\([^\"]+\\)\"><strong>\\([^>]*\\)</strong></a><dd>\\([^-]+\\)- <b>\\([^<]+\\)<.*href=\"news:\\([^\"]+\\)\">.*\">\\(.+\\)</a><P>"
 659                                       nil t)
 660               (setq url (match-string 1)
 661                     subject (match-string 2)
 662                     date (match-string 3)
 663                     group (match-string 4)
 664                     id (concat "<" (match-string 5) ">")
 665                     from (match-string 6))
 666               (incf i)
 667               (unless (nnweb-get-hashtb url)
 668                 (push
 669                  (list
 670                   (incf (cdr active))
 671                   (make-full-mail-header
 672                    (cdr active) (concat  "(" group ") " subject) from date
 673                    id nil 0 0 url))
 674                  map)
 675                 (nnweb-set-hashtb (cadar map) (car map))))
 676             ;; See if we want more.
 677             (when (or (not nnweb-articles)
 678                       (>= i nnweb-max-hits)
 679                       (not (funcall (nnweb-definition 'search)
 680                                     nnweb-search (incf part))))
 681               (setq more nil)))
 682           ;; Return the articles in the right order.
 683           (setq nnweb-articles
 684                 (sort (nconc nnweb-articles map) 'car-less-than-car)))))))
 685
 686 (defun nnweb-altavista-wash-article ()
 687   (goto-char (point-min))
 688   (let ((case-fold-search t))
 689     (when (re-search-forward "^<strong>" nil t)
 690       (delete-region (point-min) (match-beginning 0)))
 691     (goto-char (point-min))
 692     (while (looking-at "<strong>\\([^ ]+\\) +</strong> +\\(.*\\)$")
 693       (replace-match "\\1: \\2" t)
 694       (forward-line 1))
 695     (when (re-search-backward "^References:" nil t)
 696       (narrow-to-region (point) (progn (forward-line 1) (point)))
 697       (goto-char (point-min))
 698       (while (re-search-forward "<A.*\\?id@\\([^\"]+\\)\">[0-9]+</A>" nil t)
 699         (replace-match "&lt;\\1&gt; " t)))
 700     (widen)
 701     (nnweb-remove-markup)))
 702
 703 (defun nnweb-altavista-search (search &optional part)
 704   (url-insert-file-contents
 705    (concat
 706     (nnweb-definition 'address)
 707     "?"
 708     (nnweb-encode-www-form-urlencoded
 709      `(("pg" . "aq")
 710        ("what" . "news")
 711        ,@(when part `(("stq" . ,(int-to-string (* part 30)))))
 712        ("fmt" . "d")
 713        ("q" . ,search)
 714        ("r" . "")
 715        ("d0" . "")
 716        ("d1" . "")))))
 717   (setq buffer-file-name nil)
 718   t)
 719
 720 (provide 'nnweb)
 721
 722 ;;; nnweb.el ends here