cgit.sxemacs.org Git - gnus/blob - lisp/nnvirtual.el

   1 ;;; nnvirtual.el --- virtual newsgroups access for Gnus
   2
   3 ;; Copyright (C) 1994, 1995, 1996, 1997, 1998, 1999, 2000, 2001, 2002,
   4 ;;   2003, 2004, 2005, 2006, 2007, 2008, 2009, 2010 Free Software Foundation, Inc.
   5
   6 ;; Author: David Moore <dmoore@ucsd.edu>
   7 ;;      Lars Magne Ingebrigtsen <larsi@gnus.org>
   8 ;;      Masanobu UMEDA <umerin@flab.flab.fujitsu.junet>
   9 ;; Keywords: news
  10
  11 ;; This file is part of GNU Emacs.
  12
  13 ;; GNU Emacs is free software: you can redistribute it and/or modify
  14 ;; it under the terms of the GNU General Public License as published by
  15 ;; the Free Software Foundation, either version 3 of the License, or
  16 ;; (at your option) any later version.
  17
  18 ;; GNU Emacs is distributed in the hope that it will be useful,
  19 ;; but WITHOUT ANY WARRANTY; without even the implied warranty of
  20 ;; MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.  See the
  21 ;; GNU General Public License for more details.
  22
  23 ;; You should have received a copy of the GNU General Public License
  24 ;; along with GNU Emacs.  If not, see <http://www.gnu.org/licenses/>.
  25
  26 ;;; Commentary:
  27
  28 ;; The other access methods (nntp, nnspool, etc) are general news
  29 ;; access methods.  This module relies on Gnus and can not be used
  30 ;; separately.
  31
  32 ;;; Code:
  33
  34 (require 'nntp)
  35 (require 'nnheader)
  36 (require 'gnus)
  37 (require 'nnoo)
  38 (require 'gnus-util)
  39 (require 'gnus-start)
  40 (require 'gnus-sum)
  41 (require 'gnus-msg)
  42 (eval-when-compile (require 'cl))
  43
  44 (nnoo-declare nnvirtual)
  45
  46 (defvoo nnvirtual-always-rescan t
  47   "If non-nil, always scan groups for unread articles when entering a group.
  48 If this variable is nil and you read articles in a component group
  49 after the virtual group has been activated, the read articles from the
  50 component group will show up when you enter the virtual group.")
  51
  52 (defvoo nnvirtual-component-regexp nil
  53   "Regexp to match component groups.")
  54
  55 (defvoo nnvirtual-component-groups nil
  56   "Component group in this nnvirtual group.")
  57
  58 \f
  59
  60 (defconst nnvirtual-version "nnvirtual 1.1")
  61
  62 (defvoo nnvirtual-current-group nil)
  63
  64 (defvoo nnvirtual-mapping-table nil
  65   "Table of rules on how to map between component group and article number to virtual article number.")
  66
  67 (defvoo nnvirtual-mapping-offsets nil
  68   "Table indexed by component group to an offset to be applied to article numbers in that group.")
  69
  70 (defvoo nnvirtual-mapping-len 0
  71   "Number of articles in this virtual group.")
  72
  73 (defvoo nnvirtual-mapping-reads nil
  74   "Compressed sequence of read articles on the virtual group as computed from the unread status of individual component groups.")
  75
  76 (defvoo nnvirtual-mapping-marks nil
  77   "Compressed marks alist for the virtual group as computed from the marks of individual component groups.")
  78
  79 (defvoo nnvirtual-info-installed nil
  80   "T if we have already installed the group info for this group, and shouldn't blast over it again.")
  81
  82 (defvoo nnvirtual-status-string "")
  83
  84 (autoload 'gnus-cache-articles-in-group "gnus-cache")
  85
  86 \f
  87
  88 ;;; Interface functions.
  89
  90 (nnoo-define-basics nnvirtual)
  91
  92
  93 (deffoo nnvirtual-retrieve-headers (articles &optional newsgroup
  94                                              server fetch-old)
  95   (when (nnvirtual-possibly-change-server server)
  96     (save-excursion
  97       (set-buffer nntp-server-buffer)
  98       (erase-buffer)
  99       (if (stringp (car articles))
 100           'headers
 101         (let ((vbuf (nnheader-set-temp-buffer
 102                      (get-buffer-create " *virtual headers*")))
 103               (carticles (nnvirtual-partition-sequence articles))
 104               (system-name (system-name))
 105               cgroup carticle article result prefix)
 106           (while carticles
 107             (setq cgroup (caar carticles))
 108             (setq articles (cdar carticles))
 109             (pop carticles)
 110             (when (and articles
 111                        (gnus-check-server
 112                         (gnus-find-method-for-group cgroup) t)
 113                        (gnus-request-group cgroup t)
 114                        (setq prefix (gnus-group-real-prefix cgroup))
 115                        ;; FIX FIX FIX we want to check the cache!
 116                        ;; This is probably evil if people have set
 117                        ;; gnus-use-cache to nil themselves, but I
 118                        ;; have no way of finding the true value of it.
 119                        (let ((gnus-use-cache t))
 120                          (setq result (gnus-retrieve-headers
 121                                        articles cgroup nil))))
 122               (set-buffer nntp-server-buffer)
 123               ;; If we got HEAD headers, we convert them into NOV
 124               ;; headers.  This is slow, inefficient and, come to think
 125               ;; of it, downright evil.  So sue me.  I couldn't be
 126               ;; bothered to write a header parse routine that could
 127               ;; parse a mixed HEAD/NOV buffer.
 128               (when (eq result 'headers)
 129                 (nnvirtual-convert-headers))
 130               (goto-char (point-min))
 131               (while (not (eobp))
 132                 (delete-region (point)
 133                                (progn
 134                                  (setq carticle (read nntp-server-buffer))
 135                                  (point)))
 136
 137                 ;; We remove this article from the articles list, if
 138                 ;; anything is left in the articles list after going through
 139                 ;; the entire buffer, then those articles have been
 140                 ;; expired or canceled, so we appropriately update the
 141                 ;; component group below.  They should be coming up
 142                 ;; generally in order, so this shouldn't be slow.
 143                 (setq articles (delq carticle articles))
 144
 145                 (setq article (nnvirtual-reverse-map-article cgroup carticle))
 146                 (if (null article)
 147                     ;; This line has no reverse mapping, that means it
 148                     ;; was an extra article reference returned by nntp.
 149                     (progn
 150                       (beginning-of-line)
 151                       (delete-region (point) (progn (forward-line 1) (point))))
 152                   ;; Otherwise insert the virtual article number,
 153                   ;; and clean up the xrefs.
 154                   (princ article nntp-server-buffer)
 155                   (nnvirtual-update-xref-header cgroup carticle
 156                                                 prefix system-name)
 157                   (forward-line 1))
 158                 )
 159
 160               (set-buffer vbuf)
 161               (goto-char (point-max))
 162               (insert-buffer-substring nntp-server-buffer))
 163             ;; Anything left in articles is expired or canceled.
 164             ;; Could be smart and not tell it about articles already known?
 165             (when articles
 166               (gnus-group-make-articles-read cgroup articles))
 167             )
 168
 169           ;; The headers are ready for reading, so they are inserted into
 170           ;; the nntp-server-buffer, which is where Gnus expects to find
 171           ;; them.
 172           (prog1
 173               (save-excursion
 174                 (set-buffer nntp-server-buffer)
 175                 (erase-buffer)
 176                 (insert-buffer-substring vbuf)
 177                 ;; FIX FIX FIX, we should be able to sort faster than
 178                 ;; this if needed, since each cgroup is sorted, we just
 179                 ;; need to merge
 180                 (sort-numeric-fields 1 (point-min) (point-max))
 181                 'nov)
 182             (kill-buffer vbuf)))))))
 183
 184
 185 (defvoo nnvirtual-last-accessed-component-group nil)
 186
 187 (deffoo nnvirtual-request-article (article &optional group server buffer)
 188   (when (nnvirtual-possibly-change-server server)
 189     (if (stringp article)
 190         ;; This is a fetch by Message-ID.
 191         (cond
 192          ((not nnvirtual-last-accessed-component-group)
 193           (nnheader-report
 194            'nnvirtual "Don't know what server to request from"))
 195          (t
 196           (save-excursion
 197             (when buffer
 198               (set-buffer buffer))
 199             (let* ((gnus-override-method nil)
 200                    (method (gnus-find-method-for-group
 201                             nnvirtual-last-accessed-component-group)))
 202               (funcall (gnus-get-function method 'request-article)
 203                        article nil (nth 1 method) buffer)))))
 204       ;; This is a fetch by number.
 205       (let* ((amap (nnvirtual-map-article article))
 206              (cgroup (car amap)))
 207         (cond
 208          ((not amap)
 209           (nnheader-report 'nnvirtual "No such article: %s" article))
 210          ((not (gnus-check-group cgroup))
 211           (nnheader-report
 212            'nnvirtual "Can't open server where %s exists" cgroup))
 213          ((not (gnus-request-group cgroup t))
 214           (nnheader-report 'nnvirtual "Can't open component group %s" cgroup))
 215          (t
 216           (setq nnvirtual-last-accessed-component-group cgroup)
 217           (if buffer
 218               (save-excursion
 219                 (set-buffer buffer)
 220                 ;; We bind this here to avoid double decoding.
 221                 (let ((gnus-article-decode-hook nil))
 222                   (gnus-request-article-this-buffer (cdr amap) cgroup)))
 223             (gnus-request-article (cdr amap) cgroup))))))))
 224
 225
 226 (deffoo nnvirtual-open-server (server &optional defs)
 227   (unless (assq 'nnvirtual-component-regexp defs)
 228     (push `(nnvirtual-component-regexp ,server)
 229           defs))
 230   (nnoo-change-server 'nnvirtual server defs)
 231   (if nnvirtual-component-groups
 232       t
 233     (setq nnvirtual-mapping-table nil
 234           nnvirtual-mapping-offsets nil
 235           nnvirtual-mapping-len 0
 236           nnvirtual-mapping-reads nil
 237           nnvirtual-mapping-marks nil
 238           nnvirtual-info-installed nil)
 239     (when nnvirtual-component-regexp
 240       ;; Go through the newsrc alist and find all component groups.
 241       (let ((newsrc (cdr gnus-newsrc-alist))
 242             group)
 243         (while (setq group (car (pop newsrc)))
 244           (when (string-match nnvirtual-component-regexp group) ; Match
 245             ;; Add this group to the list of component groups.
 246             (setq nnvirtual-component-groups
 247                   (cons group (delete group nnvirtual-component-groups)))))))
 248     (if (not nnvirtual-component-groups)
 249         (nnheader-report 'nnvirtual "No component groups: %s" server)
 250       t)))
 251
 252
 253 (deffoo nnvirtual-request-group (group &optional server dont-check)
 254   (nnvirtual-possibly-change-server server)
 255   (setq nnvirtual-component-groups
 256         (delete (nnvirtual-current-group) nnvirtual-component-groups))
 257   (cond
 258    ((null nnvirtual-component-groups)
 259     (setq nnvirtual-current-group nil)
 260     (nnheader-report 'nnvirtual "No component groups in %s" group))
 261    (t
 262     (setq nnvirtual-current-group group)
 263     (when (or (not dont-check)
 264               nnvirtual-always-rescan)
 265       (nnvirtual-create-mapping)
 266       (when nnvirtual-always-rescan
 267         (nnvirtual-request-update-info
 268          (nnvirtual-current-group)
 269          (gnus-get-info (nnvirtual-current-group)))))
 270     (nnheader-insert "211 %d 1 %d %s\n"
 271                      nnvirtual-mapping-len nnvirtual-mapping-len group))))
 272
 273
 274 (deffoo nnvirtual-request-type (group &optional article)
 275   (if (not article)
 276       'unknown
 277     (if (numberp article)
 278         (let ((mart (nnvirtual-map-article article)))
 279           (if mart
 280               (gnus-request-type (car mart) (cdr mart))))
 281       (gnus-request-type
 282        nnvirtual-last-accessed-component-group nil))))
 283
 284 (deffoo nnvirtual-request-update-mark (group article mark)
 285   (let* ((nart (nnvirtual-map-article article))
 286          (cgroup (car nart)))
 287     (when (and nart
 288                (memq mark gnus-auto-expirable-marks)
 289                ;; The component group might be a virtual group.
 290                (= mark (gnus-request-update-mark cgroup (cdr nart) mark))
 291                (gnus-group-auto-expirable-p cgroup))
 292       (setq mark gnus-expirable-mark)))
 293   mark)
 294
 295
 296 (deffoo nnvirtual-close-group (group &optional server)
 297   (when (and (nnvirtual-possibly-change-server server)
 298              (not (gnus-ephemeral-group-p (nnvirtual-current-group))))
 299     (nnvirtual-update-read-and-marked t t))
 300   t)
 301
 302
 303 (deffoo nnvirtual-request-newgroups (date &optional server)
 304   (nnheader-report 'nnvirtual "NEWGROUPS is not supported."))
 305
 306
 307 (deffoo nnvirtual-request-list-newsgroups (&optional server)
 308   (nnheader-report 'nnvirtual "LIST NEWSGROUPS is not implemented."))
 309
 310
 311 (deffoo nnvirtual-request-update-info (group info &optional server)
 312   (when (and (nnvirtual-possibly-change-server server)
 313              (not nnvirtual-info-installed))
 314     ;; Install the precomputed lists atomically, so the virtual group
 315     ;; is not left in a half-way state in case of C-g.
 316     (gnus-atomic-progn
 317       (setcar (cddr info) nnvirtual-mapping-reads)
 318       (if (nthcdr 3 info)
 319           (setcar (nthcdr 3 info) nnvirtual-mapping-marks)
 320         (when nnvirtual-mapping-marks
 321           (setcdr (nthcdr 2 info) (list nnvirtual-mapping-marks))))
 322       (setq nnvirtual-info-installed t))
 323     t))
 324
 325
 326 (deffoo nnvirtual-catchup-group (group &optional server all)
 327   (when (and (nnvirtual-possibly-change-server server)
 328              (not (gnus-ephemeral-group-p (nnvirtual-current-group))))
 329     ;; copy over existing marks first, in case they set anything
 330     (nnvirtual-update-read-and-marked nil nil)
 331     ;; do a catchup on all component groups
 332     (let ((gnus-group-marked (copy-sequence nnvirtual-component-groups))
 333           (gnus-expert-user t))
 334       ;; Make sure all groups are activated.
 335       (mapc
 336        (lambda (g)
 337          (when (not (numberp (gnus-group-unread g)))
 338            (gnus-activate-group g)))
 339        nnvirtual-component-groups)
 340       (save-excursion
 341         (set-buffer gnus-group-buffer)
 342         (gnus-group-catchup-current nil all)))))
 343
 344
 345 (deffoo nnvirtual-find-group-art (group article)
 346   "Return the real group and article for virtual GROUP and ARTICLE."
 347   (nnvirtual-map-article article))
 348
 349
 350 (deffoo nnvirtual-request-post (&optional server)
 351   (if (not gnus-message-group-art)
 352       (nnheader-report 'nnvirtual "Can't post to an nnvirtual group")
 353     (let ((group (car (nnvirtual-find-group-art
 354                        (car gnus-message-group-art)
 355                        (cdr gnus-message-group-art)))))
 356       (gnus-request-post (gnus-find-method-for-group group)))))
 357
 358
 359 (deffoo nnvirtual-request-expire-articles (articles group
 360                                                     &optional server force)
 361   (nnvirtual-possibly-change-server server)
 362   (setq nnvirtual-component-groups
 363         (delete (nnvirtual-current-group) nnvirtual-component-groups))
 364   (let (unexpired)
 365     (dolist (group nnvirtual-component-groups)
 366       (setq unexpired (nconc unexpired
 367                              (mapcar
 368                               #'(lambda (article)
 369                                   (nnvirtual-reverse-map-article
 370                                    group article))
 371                               (gnus-uncompress-range
 372                                (gnus-group-expire-articles-1 group))))))
 373     (sort (delq nil unexpired) '<)))
 374
 375 \f
 376 ;;; Internal functions.
 377
 378 (defun nnvirtual-convert-headers ()
 379   "Convert HEAD headers into NOV headers."
 380   (with-current-buffer nntp-server-buffer
 381     (let* ((dependencies (make-vector 100 0))
 382            (headers (gnus-get-newsgroup-headers dependencies)))
 383       (erase-buffer)
 384       (mapc 'nnheader-insert-nov headers))))
 385
 386
 387 (defun nnvirtual-update-xref-header (group article prefix system-name)
 388   "Edit current NOV header in current buffer to have an xref to the component group, and also server prefix any existing xref lines."
 389   ;; Move to beginning of Xref field, creating a slot if needed.
 390   (beginning-of-line)
 391   (looking-at
 392    "[^\t]*\t[^\t]*\t[^\t]*\t[^\t]*\t[^\t]*\t[^\t]*\t[^\t]*\t")
 393   (goto-char (match-end 0))
 394   (unless (search-forward "\t" (point-at-eol) 'move)
 395     (insert "\t"))
 396
 397   ;; Remove any spaces at the beginning of the Xref field.
 398   (while (eq (char-after (1- (point))) ? )
 399     (forward-char -1)
 400     (delete-char 1))
 401
 402   (insert "Xref: " system-name " " group ":")
 403   (princ article (current-buffer))
 404   (insert " ")
 405
 406   ;; If there were existing xref lines, clean them up to have the correct
 407   ;; component server prefix.
 408   (save-restriction
 409     (narrow-to-region (point)
 410                       (or (search-forward "\t" (point-at-eol) t)
 411                           (point-at-eol)))
 412     (goto-char (point-min))
 413     (when (re-search-forward "Xref: *[^\n:0-9 ]+ *" nil t)
 414       (replace-match "" t t))
 415     (goto-char (point-min))
 416     (when (re-search-forward
 417            (concat (regexp-quote (gnus-group-real-name group)) ":[0-9]+")
 418            nil t)
 419       (replace-match "" t t))
 420     (unless (eobp)
 421       (insert " ")
 422       (when (not (string= "" prefix))
 423         (while (re-search-forward "[^ ]+:[0-9]+" nil t)
 424           (save-excursion
 425             (goto-char (match-beginning 0))
 426             (insert prefix))))))
 427
 428   ;; Ensure a trailing \t.
 429   (end-of-line)
 430   (or (eq (char-after (1- (point))) ?\t)
 431       (insert ?\t)))
 432
 433
 434 (defun nnvirtual-possibly-change-server (server)
 435   (or (not server)
 436       (nnoo-current-server-p 'nnvirtual server)
 437       (nnvirtual-open-server server)))
 438
 439
 440 (defun nnvirtual-update-read-and-marked (read-p update-p)
 441   "Copy marks from the virtual group to the component groups.
 442 If READ-P is not nil, update the (un)read status of the components.
 443 If UPDATE-P is not nil, call gnus-group-update-group on the components."
 444   (when nnvirtual-current-group
 445     (let ((unreads (and read-p
 446                         (nnvirtual-partition-sequence
 447                          (gnus-list-of-unread-articles
 448                           (nnvirtual-current-group)))))
 449           (type-marks
 450            (delq nil
 451                  (mapcar (lambda (ml)
 452                            (if (eq (car ml) 'score)
 453                                nil
 454                              (cons (car ml)
 455                                    (nnvirtual-partition-sequence (cdr ml)))))
 456                          (gnus-info-marks (gnus-get-info
 457                                            (nnvirtual-current-group))))))
 458           type groups info)
 459
 460       ;; Ok, atomically move all of the (un)read info, clear any old
 461       ;; marks, and move all of the current marks.  This way if someone
 462       ;; hits C-g, you won't leave the component groups in a half-way state.
 463       (progn
 464         ;; move (un)read
 465         ;; bind for workaround guns-update-read-articles
 466         (let ((gnus-newsgroup-active nil))
 467           (dolist (entry unreads)
 468             (gnus-update-read-articles (car entry) (cdr entry))))
 469
 470         ;; clear all existing marks on the component groups
 471         (dolist (group nnvirtual-component-groups)
 472           (when (and (setq info (gnus-get-info group))
 473                      (gnus-info-marks info))
 474             (gnus-info-set-marks
 475              info
 476              (if (assq 'score (gnus-info-marks info))
 477                  (list (assq 'score (gnus-info-marks info)))
 478                nil))))
 479
 480         ;; Ok, currently type-marks is an assq list with keys of a mark type,
 481         ;; with data of an assq list with keys of component group names
 482         ;; and the articles which correspond to that key/group pair.
 483         (dolist (mark type-marks)
 484           (setq type (car mark))
 485           (setq groups (cdr mark))
 486           (dolist (carticles groups)
 487             (gnus-add-marked-articles (car carticles) type (cdr carticles)
 488                                       nil t))))
 489
 490       ;; possibly update the display, it is really slow
 491       (when update-p
 492         (dolist (group nnvirtual-component-groups)
 493           (gnus-group-update-group group t))))))
 494
 495
 496 (defun nnvirtual-current-group ()
 497   "Return the prefixed name of the current nnvirtual group."
 498   (concat "nnvirtual:" nnvirtual-current-group))
 499
 500
 501
 502 ;;; This is currently O(kn^2) to merge n lists of length k.
 503 ;;; You could do it in O(knlogn), but we have a small n, and the
 504 ;;; overhead of the other approach is probably greater.
 505 (defun nnvirtual-merge-sorted-lists (&rest lists)
 506   "Merge many sorted lists of numbers."
 507   (if (null (cdr lists))
 508       (car lists)
 509     (sort (apply 'nconc lists) '<)))
 510
 511
 512 ;;; We map between virtual articles and real articles in a manner
 513 ;;; which keeps the size of the virtual active list the same as the
 514 ;;; sum of the component active lists.
 515
 516 ;;; To achieve fair mixing of the groups, the last article in each of
 517 ;;; N component groups will be in the last N articles in the virtual
 518 ;;; group.
 519
 520 ;;; If you have 3 components A, B and C, with articles 1-8, 1-5, and
 521 ;;; 6-7 respectively, then the virtual article numbers look like:
 522 ;;;
 523 ;;;  1  2  3  4  5  6  7  8  9  10 11 12 13 14 15
 524 ;;;  A1 A2 A3 A4 B1 A5 B2 A6 B3 A7 B4 C6 A8 B5 C7
 525
 526 ;;; To compute these mappings we generate a couple tables and then
 527 ;;; do some fast operations on them.  Tables for the example above:
 528 ;;;
 529 ;;; Offsets - [(A 0) (B -3) (C -1)]
 530 ;;;
 531 ;;;               a  b  c  d  e
 532 ;;; Mapping - ([  3  0  1  3  0 ]
 533 ;;;            [  6  3  2  9  3 ]
 534 ;;;            [  8  6  3 15  9 ])
 535 ;;;
 536 ;;; (note column 'e' is different in real algorithm, which is slightly
 537 ;;;  different than described here, but this gives you the methodology.)
 538 ;;;
 539 ;;; The basic idea is this, when going from component->virtual, apply
 540 ;;; the appropriate offset to the article number.  Then search the first
 541 ;;; column of the table for a row where 'a' is less than or equal to the
 542 ;;; modified number.  You can see that only group A can therefore go to
 543 ;;; the first row, groups A and B to the second, and all to the last.
 544 ;;; The third column of the table is telling us the number of groups
 545 ;;; which might be able to reach that row (it might increase by more than
 546 ;;; 1 if several groups have the same size).
 547 ;;; Then column 'b' provides an additional offset you apply when you have
 548 ;;; found the correct row.  You then multiply by 'c' and add on the groups
 549 ;;; _position_ in the offset table.  The basic idea here is that on
 550 ;;; any given row we are going to map back and forth using X'=X*c+Y and
 551 ;;; X=(X'/c), Y=(X' mod c).  Then once you've done this transformation,
 552 ;;; you apply a final offset from column 'e' to give the virtual article.
 553 ;;;
 554 ;;; Going the other direction, you instead search on column 'd' instead
 555 ;;; of 'a', and apply everything in reverse order.
 556
 557 ;;; Convert component -> virtual:
 558 ;;; set num = num - Offset(group)
 559 ;;; find first row in Mapping where num <= 'a'
 560 ;;; num = (num-'b')*c + Position(group) + 'e'
 561
 562 ;;; Convert virtual -> component:
 563 ;;; find first row in Mapping where num <= 'd'
 564 ;;; num = num - 'e'
 565 ;;; group_pos = num mod 'c'
 566 ;;; num = (num / 'c') + 'b' + Offset(group_pos)
 567
 568 ;;; Easy no? :)
 569 ;;;
 570 ;;; Well actually, you need to keep column e offset smaller by the 'c'
 571 ;;; column for that line, and always add 1 more when going from
 572 ;;; component -> virtual.  Otherwise you run into a problem with
 573 ;;; unique reverse mapping.
 574
 575 (defun nnvirtual-map-article (article)
 576   "Return a cons of the component group and article corresponding to the given virtual ARTICLE."
 577   (let ((table nnvirtual-mapping-table)
 578         entry group-pos)
 579     (while (and table
 580                 (> article (aref (car table) 3)))
 581       (setq table (cdr table)))
 582     (when (and table
 583                (> article 0))
 584       (setq entry (car table))
 585       (setq article (- article (aref entry 4) 1))
 586       (setq group-pos (mod article (aref entry 2)))
 587       (cons (car (aref nnvirtual-mapping-offsets group-pos))
 588             (+ (/ article (aref entry 2))
 589                (aref entry 1)
 590                (cdr (aref nnvirtual-mapping-offsets group-pos)))
 591             ))
 592     ))
 593
 594
 595
 596 (defun nnvirtual-reverse-map-article (group article)
 597   "Return the virtual article number corresponding to the given component GROUP and ARTICLE."
 598   (when (numberp article)
 599     (let ((table nnvirtual-mapping-table)
 600           (group-pos 0)
 601           entry)
 602       (while (not (string= group (car (aref nnvirtual-mapping-offsets
 603                                             group-pos))))
 604         (setq group-pos (1+ group-pos)))
 605       (setq article (- article (cdr (aref nnvirtual-mapping-offsets
 606                                           group-pos))))
 607       (while (and table
 608                   (> article (aref (car table) 0)))
 609         (setq table (cdr table)))
 610       (setq entry (car table))
 611       (when (and entry
 612                  (> article 0)
 613                  (< group-pos (aref entry 2))) ; article not out of range below
 614         (+ (aref entry 4)
 615            group-pos
 616            (* (- article (aref entry 1))
 617               (aref entry 2))
 618            1))
 619       )))
 620
 621
 622 (defsubst nnvirtual-reverse-map-sequence (group articles)
 623   "Return list of virtual article numbers for all ARTICLES in GROUP.
 624 The ARTICLES should be sorted, and can be a compressed sequence.
 625 If any of the article numbers has no corresponding virtual article,
 626 then it is left out of the result."
 627   (when (numberp (cdr-safe articles))
 628     (setq articles (list articles)))
 629   (let (result a i j new-a)
 630     (while (setq a (pop articles))
 631       (if (atom a)
 632           (setq i a
 633                 j a)
 634         (setq i (car a)
 635               j (cdr a)))
 636       (while (<= i j)
 637         ;; If this is slow, you can optimize by moving article checking
 638         ;; into here.  You don't have to recompute the group-pos,
 639         ;; nor scan the table every time.
 640         (when (setq new-a (nnvirtual-reverse-map-article group i))
 641           (push new-a result))
 642         (setq i (1+ i))))
 643     (nreverse result)))
 644
 645
 646 (defun nnvirtual-partition-sequence (articles)
 647   "Return an association list of component article numbers.
 648 These are indexed by elements of nnvirtual-component-groups, based on
 649 the sequence ARTICLES of virtual article numbers.  ARTICLES should be
 650 sorted, and can be a compressed sequence.  If any of the article
 651 numbers has no corresponding component article, then it is left out of
 652 the result."
 653   (when (numberp (cdr-safe articles))
 654     (setq articles (list articles)))
 655   (let ((carticles (mapcar 'list nnvirtual-component-groups))
 656         a i j article entry)
 657     (while (setq a (pop articles))
 658       (if (atom a)
 659           (setq i a
 660                 j a)
 661         (setq i (car a)
 662               j (cdr a)))
 663       (while (<= i j)
 664         (when (setq article (nnvirtual-map-article i))
 665           (setq entry (assoc (car article) carticles))
 666           (setcdr entry (cons (cdr article) (cdr entry))))
 667         (setq i (1+ i))))
 668     (mapc (lambda (x) (setcdr x (nreverse (cdr x))))
 669           carticles)
 670     carticles))
 671
 672
 673 (defun nnvirtual-create-mapping ()
 674   "Build the tables necessary to map between component (group, article) to virtual article.
 675 Generate the set of read messages and marks for the virtual group
 676 based on the marks on the component groups."
 677   (let ((cnt 0)
 678         (tot 0)
 679         (M 0)
 680         (i 0)
 681         actives all-unreads all-marks
 682         active min max size unreads marks
 683         next-M next-tot
 684         reads beg)
 685     ;; Ok, we loop over all component groups and collect a lot of
 686     ;; information:
 687     ;; Into actives we place (g size max), where size is max-min+1.
 688     ;; Into all-unreads we put (g unreads).
 689     ;; Into all-marks we put (g marks).
 690     ;; We also increment cnt and tot here, and compute M (max of sizes).
 691     (mapc (lambda (g)
 692             (setq active (gnus-activate-group g)
 693                   min (car active)
 694                   max (cdr active))
 695             (when (and active (>= max min) (not (zerop max)))
 696               ;; store active information
 697               (push (list g (- max min -1) max) actives)
 698               ;; collect unread/mark info for later
 699               (setq unreads (gnus-list-of-unread-articles g))
 700               (setq marks (gnus-info-marks (gnus-get-info g)))
 701               (when gnus-use-cache
 702                 (push (cons 'cache
 703                             (gnus-cache-articles-in-group g))
 704                       marks))
 705               (push (cons g unreads) all-unreads)
 706               (push (cons g marks) all-marks)
 707               ;; count groups, total #articles, and max size
 708               (setq size (- max min -1))
 709               (setq cnt (1+ cnt)
 710                     tot (+ tot size)
 711                     M (max M size))))
 712           nnvirtual-component-groups)
 713
 714     ;; Number of articles in the virtual group.
 715     (setq nnvirtual-mapping-len tot)
 716
 717
 718     ;; We want the actives list sorted by size, to build the tables.
 719     (setq actives (sort actives (lambda (g1 g2) (< (nth 1 g1) (nth 1 g2)))))
 720
 721     ;; Build the offset table.  Largest sized groups are at the front.
 722     (setq nnvirtual-mapping-offsets
 723           (vconcat
 724            (nreverse
 725             (mapcar (lambda (entry)
 726                       (cons (nth 0 entry)
 727                             (- (nth 2 entry) M)))
 728                     actives))))
 729
 730     ;; Build the mapping table.
 731     (setq nnvirtual-mapping-table nil)
 732     (setq actives (mapcar (lambda (entry) (nth 1 entry)) actives))
 733     (while actives
 734       (setq size (car actives))
 735       (setq next-M (- M size))
 736       (setq next-tot (- tot (* cnt size)))
 737       ;; make current row in table
 738       (push (vector M next-M cnt tot (- next-tot cnt))
 739             nnvirtual-mapping-table)
 740       ;; update M and tot
 741       (setq M next-M)
 742       (setq tot next-tot)
 743       ;; subtract the current size from all entries.
 744       (setq actives (mapcar (lambda (x) (- x size)) actives))
 745       ;; remove anything that went to 0.
 746       (while (and actives
 747                   (= (car actives) 0))
 748         (pop actives)
 749         (setq cnt (- cnt 1))))
 750
 751
 752     ;; Now that the mapping tables are generated, we can convert
 753     ;; and combine the separate component unreads and marks lists
 754     ;; into single lists of virtual article numbers.
 755     (setq unreads (apply 'nnvirtual-merge-sorted-lists
 756                          (mapcar (lambda (x)
 757                                    (nnvirtual-reverse-map-sequence
 758                                     (car x) (cdr x)))
 759                                  all-unreads)))
 760     (setq marks (mapcar
 761                  (lambda (type)
 762                    (cons (cdr type)
 763                          (gnus-compress-sequence
 764                           (apply
 765                            'nnvirtual-merge-sorted-lists
 766                            (mapcar (lambda (x)
 767                                      (nnvirtual-reverse-map-sequence
 768                                       (car x)
 769                                       (cdr (assq (cdr type) (cdr x)))))
 770                                    all-marks)))))
 771                  gnus-article-mark-lists))
 772
 773     ;; Remove any empty marks lists, and store.
 774     (setq nnvirtual-mapping-marks nil)
 775     (dolist (mark marks)
 776       (when (cdr mark)
 777         (push mark nnvirtual-mapping-marks)))
 778
 779     ;; We need to convert the unreads to reads.  We compress the
 780     ;; sequence as we go, otherwise it could be huge.
 781     (while (and (<= (incf i) nnvirtual-mapping-len)
 782                 unreads)
 783       (if (= i (car unreads))
 784           (setq unreads (cdr unreads))
 785         ;; try to get a range.
 786         (setq beg i)
 787         (while (and (<= (incf i) nnvirtual-mapping-len)
 788                     (not (= i (car unreads)))))
 789         (setq i (- i 1))
 790         (if (= i beg)
 791             (push i reads)
 792           (push (cons beg i) reads))
 793         ))
 794     (when (<= i nnvirtual-mapping-len)
 795       (if (= i nnvirtual-mapping-len)
 796           (push i reads)
 797         (push (cons i nnvirtual-mapping-len) reads)))
 798
 799     ;; Store the reads list for later use.
 800     (setq nnvirtual-mapping-reads (nreverse reads))
 801
 802     ;; Throw flag to show we changed the info.
 803     (setq nnvirtual-info-installed nil)
 804     ))
 805
 806 (provide 'nnvirtual)
 807
 808 ;;; nnvirtual.el ends here