cgit.sxemacs.org Git - gnus/blob - lisp/nntp.el

   1 ;;; Copyright (C) 1987,88,89,90,92,93,94,95,96 Free Software Foundation, Inc.
   2
   3 ;; Author: Lars Magne Ingebrigtsen <larsi@ifi.uio.no>
   4 ;; Keywords: news
   5
   6 ;; This file is part of GNU Emacs.
   7
   8 ;; GNU Emacs is free software; you can redistribute it and/or modify
   9 ;; it under the terms of the GNU General Public License as published by
  10 ;; the Free Software Foundation; either version 2, or (at your option)
  11 ;; any later version.
  12
  13 ;; GNU Emacs is distributed in the hope that it will be useful,
  14 ;; but WITHOUT ANY WARRANTY; without even the implied warranty of
  15 ;; MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.  See the
  16 ;; GNU General Public License for more details.
  17
  18 ;; You should have received a copy of the GNU General Public License
  19 ;; along with GNU Emacs; see the file COPYING.  If not, write to
  20 ;; the Free Software Foundation, 675 Mass Ave, Cambridge, MA 02139, USA.
  21
  22 ;;; Commentary:
  23
  24 ;;; Code:
  25
  26 (require 'nnheader)
  27 (require 'nnoo)
  28 (require 'gnus-util)
  29
  30 (nnoo-declare nntp)
  31
  32 (eval-and-compile
  33   (unless (fboundp 'open-network-stream)
  34     (require 'tcp)))
  35
  36 (eval-when-compile (require 'cl))
  37
  38 (defvoo nntp-address nil
  39   "Address of the physical nntp server.")
  40
  41 (defvoo nntp-port-number "nntp"
  42   "Port number on the physical nntp server.")
  43
  44 (defvoo nntp-server-opened-hook '(nntp-send-mode-reader)
  45   "*Hook used for sending commands to the server at startup.
  46 The default value is `nntp-send-mode-reader', which makes an innd
  47 server spawn an nnrpd server.  Another useful function to put in this
  48 hook might be `nntp-send-authinfo', which will prompt for a password
  49 to allow posting from the server.  Note that this is only necessary to
  50 do on servers that use strict access control.")
  51
  52 (defvoo nntp-authinfo-function 'nntp-send-authinfo
  53   "Function used to send AUTHINFO to the server.")
  54
  55 (defvoo nntp-server-action-alist
  56   '(("nntpd 1\\.5\\.11t"
  57      (remove-hook 'nntp-server-opened-hook 'nntp-send-mode-reader))
  58     ("NNRP server Netscape"
  59      (setq nntp-server-list-active-group nil)))
  60   "Alist of regexps to match on server types and actions to be taken.
  61 For instance, if you want Gnus to beep every time you connect
  62 to innd, you could say something like:
  63
  64 \(setq nntp-server-action-alist
  65        '((\"innd\" (ding))))
  66
  67 You probably don't want to do that, though.")
  68
  69 (defvoo nntp-open-connection-function 'nntp-open-network-stream
  70   "*Function used for connecting to a remote system.
  71 It will be called with the buffer to output in.
  72
  73 Two pre-made functions are `nntp-open-network-stream', which is the
  74 default, and simply connects to some port or other on the remote
  75 system (see nntp-port-number).  The other are `nntp-open-rlogin', which
  76 does an rlogin on the remote system, and then does a telnet to the
  77 NNTP server available there (see nntp-rlogin-parameters) and `nntp-open-telnet' which
  78 telnets to a remote system, logs in and does the same")
  79
  80 (defvoo nntp-rlogin-parameters '("telnet" "-8" "${NNTPSERVER:=news}" "nntp")
  81   "*Parameters to `nntp-open-login'.
  82 That function may be used as `nntp-open-server-function'.  In that
  83 case, this list will be used as the parameter list given to rsh.")
  84
  85 (defvoo nntp-rlogin-user-name nil
  86   "*User name on remote system when using the rlogin connect method.")
  87
  88 (defvoo nntp-telnet-parameters '("exec" "telnet" "-8" "${NNTPSERVER:=news}" "nntp")
  89   "*Parameters to `nntp-open-telnet'.
  90 That function may be used as `nntp-open-server-function'.  In that
  91 case, this list will be executed as a command after logging in
  92 via telnet.")
  93
  94 (defvoo nntp-telnet-user-name nil
  95   "User name to log in via telnet with.")
  96
  97 (defvoo nntp-telnet-passwd nil
  98   "Password to use to log in via telnet with.")
  99
 100 (defvoo nntp-end-of-line "\r\n"
 101   "String to use on the end of lines when talking to the NNTP server.
 102 This is \"\\r\\n\" by default, but should be \"\\n\" when
 103 using rlogin or telnet to communicate with the server.")
 104
 105 (defvoo nntp-large-newsgroup 50
 106   "*The number of the articles which indicates a large newsgroup.
 107 If the number of the articles is greater than the value, verbose
 108 messages will be shown to indicate the current status.")
 109
 110 (defvoo nntp-maximum-request 400
 111   "*The maximum number of the requests sent to the NNTP server at one time.
 112 If Emacs hangs up while retrieving headers, set the variable to a
 113 lower value.")
 114
 115 (defvoo nntp-nov-is-evil nil
 116   "*If non-nil, nntp will never attempt to use XOVER when talking to the server.")
 117
 118 (defvoo nntp-xover-commands '("XOVER" "XOVERVIEW")
 119   "*List of strings that are used as commands to fetch NOV lines from a server.
 120 The strings are tried in turn until a positive response is gotten.  If
 121 none of the commands are successful, nntp will just grab headers one
 122 by one.")
 123
 124 (defvoo nntp-nov-gap 20
 125   "*Maximum allowed gap between two articles.
 126 If the gap between two consecutive articles is bigger than this
 127 variable, split the XOVER request into two requests.")
 128
 129 (defvoo nntp-connection-timeout nil
 130   "*Number of seconds to wait before an nntp connection times out.
 131 If this variable is nil, which is the default, no timers are set.")
 132
 133 (defvoo nntp-prepare-server-hook nil
 134   "*Hook run before a server is opened.
 135 If can be used to set up a server remotely, for instance.  Say you
 136 have an account at the machine \"other.machine\".  This machine has
 137 access to an NNTP server that you can't access locally.  You could
 138 then use this hook to rsh to the remote machine and start a proxy NNTP
 139 server there that you can connect to.  See also `nntp-open-connection-function'")
 140
 141 (defvoo nntp-warn-about-losing-connection t
 142   "*If non-nil, beep when a server closes connection.")
 143
 144 \f
 145
 146 ;;; Internal variables.
 147
 148 (defvar nntp-process-wait-for nil)
 149 (defvar nntp-process-to-buffer nil)
 150 (defvar nntp-process-callback nil)
 151 (defvar nntp-process-decode nil)
 152 (defvar nntp-process-start-point nil)
 153 (defvar nntp-inside-change-function nil)
 154
 155 (defvar nntp-connection-list nil)
 156
 157 (defvoo nntp-server-type nil)
 158 (defvoo nntp-connection-alist nil)
 159 (defvoo nntp-status-string "")
 160 (defconst nntp-version "nntp 5.0")
 161 (defvoo nntp-inhibit-erase nil)
 162
 163 (defvoo nntp-server-xover 'try)
 164 (defvoo nntp-server-list-active-group 'try)
 165
 166 (eval-and-compile
 167   (autoload 'nnmail-read-passwd "nnmail"))
 168
 169 \f
 170
 171 ;;; Interface functions.
 172
 173 (nnoo-define-basics nntp)
 174
 175 (deffoo nntp-retrieve-headers (articles &optional group server fetch-old)
 176   "Retrieve the headers of ARTICLES."
 177   (nntp-possibly-change-group group server)
 178   (save-excursion
 179     (set-buffer (nntp-find-connection-buffer nntp-server-buffer))
 180     (erase-buffer)
 181     (if (and (not gnus-nov-is-evil)
 182              (not nntp-nov-is-evil)
 183              (nntp-retrieve-headers-with-xover articles fetch-old))
 184         ;; We successfully retrieved the headers via XOVER.
 185         'nov
 186       ;; XOVER didn't work, so we do it the hard, slow and inefficient
 187       ;; way.
 188       (let ((number (length articles))
 189             (count 0)
 190             (received 0)
 191             (last-point (point-min))
 192             (buf (nntp-find-connection-buffer nntp-server-buffer))
 193             (nntp-inhibit-erase t))
 194         ;; Send HEAD command.
 195         (while articles
 196           (nntp-send-command
 197            nil
 198            "HEAD" (if (numberp (car articles))
 199                       (int-to-string (car articles))
 200                     ;; `articles' is either a list of article numbers
 201                     ;; or a list of article IDs.
 202                     (car articles)))
 203           (setq articles (cdr articles)
 204                 count (1+ count))
 205           ;; Every 400 header requests we have to read the stream in
 206           ;; order to avoid deadlocks.
 207           (when (or (null articles)     ;All requests have been sent.
 208                     (zerop (% count nntp-maximum-request)))
 209             (nntp-accept-response)
 210             (while (progn
 211                      (progn
 212                        (set-buffer buf)
 213                        (goto-char last-point))
 214                      ;; Count replies.
 215                      (while (re-search-forward "^[0-9]" nil t)
 216                        (incf received))
 217                      (setq last-point (point))
 218                      (< received count))
 219               ;; If number of headers is greater than 100, give
 220               ;;  informative messages.
 221               (and (numberp nntp-large-newsgroup)
 222                    (> number nntp-large-newsgroup)
 223                    (zerop (% received 20))
 224                    (message "NNTP: Receiving headers... %d%%"
 225                             (/ (* received 100) number)))
 226               (nntp-accept-response))))
 227         ;; Wait for text of last command.
 228         (goto-char (point-max))
 229         (re-search-backward "^[0-9]" nil t)
 230         (when (looking-at "^[23]")
 231           (while (progn
 232                    (goto-char (- (point-max) 3))
 233                    (not (looking-at "^\\.\r?\n")))
 234             (nntp-accept-response)))
 235         (and (numberp nntp-large-newsgroup)
 236              (> number nntp-large-newsgroup)
 237              (message "NNTP: Receiving headers...done"))
 238
 239         ;; Now all of replies are received.  Fold continuation lines.
 240         (nnheader-fold-continuation-lines)
 241         ;; Remove all "\r"'s.
 242         (goto-char (point-min))
 243         (while (search-forward "\r" nil t)
 244           (replace-match "" t t))
 245         (copy-to-buffer nntp-server-buffer (point-min) (point-max))
 246         'headers))))
 247
 248 (deffoo nntp-retrieve-groups (groups &optional server)
 249   "Retrieve group info on GROUPS."
 250   (nntp-possibly-change-group nil server)
 251   (save-excursion
 252     (set-buffer (nntp-find-connection-buffer nntp-server-buffer))
 253     ;; The first time this is run, this variable is `try'.  So we
 254     ;; try.
 255     (when (eq nntp-server-list-active-group 'try)
 256       (nntp-try-list-active (car groups)))
 257     (erase-buffer)
 258     (let ((count 0)
 259           (received 0)
 260           (last-point (point-min))
 261           (nntp-inhibit-erase t)
 262           (command (if nntp-server-list-active-group "LIST ACTIVE" "GROUP")))
 263       (while groups
 264         ;; Send the command to the server.
 265         (nntp-send-command nil command (pop groups))
 266         (incf count)
 267         ;; Every 400 requests we have to read the stream in
 268         ;; order to avoid deadlocks.
 269         (when (or (null groups)         ;All requests have been sent.
 270                   (zerop (% count nntp-maximum-request)))
 271           (nntp-accept-response)
 272           (while (progn
 273                    (goto-char last-point)
 274                    ;; Count replies.
 275                    (while (re-search-forward "^[0-9]" nil t)
 276                      (incf received))
 277                    (setq last-point (point))
 278                    (< received count))
 279             (nntp-accept-response))))
 280
 281       ;; Wait for the reply from the final command.
 282       (goto-char (point-max))
 283       (re-search-backward "^[0-9]" nil t)
 284       (when (looking-at "^[23]")
 285         (while (progn
 286                  (goto-char (point-max))
 287                  (if (not nntp-server-list-active-group)
 288                      (not (re-search-backward "\r?\n" (- (point) 3) t))
 289                    (not (re-search-backward "^\\.\r?\n" (- (point) 4) t))))
 290           (nntp-accept-response)))
 291
 292       ;; Now all replies are received.  We remove CRs.
 293       (goto-char (point-min))
 294       (while (search-forward "\r" nil t)
 295         (replace-match "" t t))
 296
 297       (if (not nntp-server-list-active-group)
 298           (progn
 299             (copy-to-buffer nntp-server-buffer (point-min) (point-max))
 300             'group)
 301         ;; We have read active entries, so we just delete the
 302         ;; superfluous gunk.
 303         (goto-char (point-min))
 304         (while (re-search-forward "^[.2-5]" nil t)
 305           (delete-region (match-beginning 0)
 306                          (progn (forward-line 1) (point))))
 307         (copy-to-buffer nntp-server-buffer (point-min) (point-max))
 308         'active))))
 309
 310 (defun nntp-try-list-active (group)
 311   (nntp-list-active-group group)
 312   (save-excursion
 313     (set-buffer nntp-server-buffer)
 314     (goto-char (point-min))
 315     (cond ((looking-at "5[0-9]+")
 316            (setq nntp-server-list-active-group nil))
 317           (t
 318            (setq nntp-server-list-active-group t)))))
 319
 320 (deffoo nntp-list-active-group (group &optional server)
 321   "Return the active info on GROUP (which can be a regexp."
 322   (nntp-possibly-change-group nil server)
 323   (nntp-send-command "^.*\r?\n" "LIST ACTIVE" group))
 324
 325 (deffoo nntp-request-article (article &optional group server buffer command)
 326   (nntp-possibly-change-group group server)
 327   (when (nntp-send-command-and-decode
 328          "\r?\n\\.\r?\n" "ARTICLE"
 329          (if (numberp article) (int-to-string article) article))
 330     (when (and buffer
 331                (not (equal buffer nntp-server-buffer)))
 332       (save-excursion
 333         (set-buffer nntp-server-buffer)
 334         (copy-to-buffer buffer (point-min) (point-max))
 335         (nntp-find-group-and-number)))
 336     (nntp-find-group-and-number)))
 337
 338 (deffoo nntp-request-head (article &optional group server)
 339   (nntp-possibly-change-group group server)
 340   (when (nntp-send-command-and-decode
 341          "\r\n\\.\r\n" "HEAD"
 342          (if (numberp article) (int-to-string article) article))
 343     (nntp-find-group-and-number)))
 344
 345 (deffoo nntp-request-body (article &optional group server)
 346   (nntp-possibly-change-group group server)
 347   (nntp-send-command-and-decode
 348    "\r?\n\\.\r?\n" "BODY"
 349    (if (numberp article) (int-to-string article) article)))
 350
 351 (deffoo nntp-request-group (group &optional server dont-check)
 352   (nntp-possibly-change-group nil server)
 353   (when (nntp-send-command "^2.*\n" "GROUP" group)
 354     (let ((entry (nntp-find-connection-entry nntp-server-buffer)))
 355       (setcar (cddr entry) group))))
 356
 357 (deffoo nntp-close-group (group &optional server)
 358   t)
 359
 360 (deffoo nntp-server-opened (&optional server)
 361   "Say whether a connection to SERVER has been opened."
 362   (and (nnoo-current-server-p 'nntp server)
 363        nntp-server-buffer
 364        (gnus-buffer-live-p nntp-server-buffer)
 365        (nntp-find-connection nntp-server-buffer)))
 366
 367 (deffoo nntp-open-server (server &optional defs connectionless)
 368   (nnheader-init-server-buffer)
 369   (if (nntp-server-opened server)
 370       t
 371     (when (or (stringp (car defs))
 372               (numberp (car defs)))
 373       (setq defs (cons (list 'nntp-port-number (car defs)) (cdr defs))))
 374     (unless (assq 'nntp-address defs)
 375       (setq defs (append defs (list (list 'nntp-address server)))))
 376     (nnoo-change-server 'nntp server defs)
 377     (unless connectionless
 378       (or (nntp-find-connection nntp-server-buffer)
 379           (nntp-open-connection nntp-server-buffer)))))
 380
 381 (deffoo nntp-close-server (&optional server)
 382   (nntp-possibly-change-group nil server t)
 383   (let (process)
 384     (while (setq process (car (pop nntp-connection-alist)))
 385       (when (memq (process-status process) '(open run))
 386         (set-process-sentinel process nil)
 387         (nntp-send-string process "QUIT"))
 388       (when (buffer-name (process-buffer process))
 389         (kill-buffer (process-buffer process))))
 390     (nnoo-close-server 'nntp)))
 391
 392 (deffoo nntp-request-close ()
 393   (let (process)
 394     (while (setq process (pop nntp-connection-list))
 395       (when (memq (process-status process) '(open run))
 396         (set-process-sentinel process nil)
 397         (nntp-send-string process "QUIT"))
 398       (when (buffer-name (process-buffer process))
 399         (kill-buffer (process-buffer process))))))
 400
 401 (deffoo nntp-request-list (&optional server)
 402   (nntp-possibly-change-group nil server)
 403   (nntp-send-command-and-decode "\r?\n\\.\r?\n" "LIST"))
 404
 405 (deffoo nntp-request-list-newsgroups (&optional server)
 406   (nntp-possibly-change-group nil server)
 407   (nntp-send-command "\r?\n\\.\r?\n" "LIST NEWSGROUPS"))
 408
 409 (deffoo nntp-request-newgroups (date &optional server)
 410   (nntp-possibly-change-group nil server)
 411   (save-excursion
 412     (set-buffer nntp-server-buffer)
 413     (let* ((date (timezone-parse-date date))
 414            (time-string
 415             (format "%s%02d%02d %s%s%s"
 416                     (substring (aref date 0) 2) (string-to-int (aref date 1))
 417                     (string-to-int (aref date 2)) (substring (aref date 3) 0 2)
 418                     (substring
 419                      (aref date 3) 3 5) (substring (aref date 3) 6 8))))
 420       (prog1
 421           (nntp-send-command "^\\.\r?\n" "NEWGROUPS" time-string)
 422         (nntp-decode-text)))))
 423
 424 (deffoo nntp-request-post (&optional server)
 425   (nntp-possibly-change-group nil server)
 426   (when (nntp-send-command "^[23].*\r?\n" "POST")
 427     (nntp-send-buffer "^[23].*\n")))
 428
 429 (deffoo nntp-request-type (group article)
 430   'news)
 431
 432 (deffoo nntp-asynchronous-p ()
 433   t)
 434
 435 ;;; Hooky functions.
 436
 437 (defun nntp-send-mode-reader ()
 438   "Send the MODE READER command to the nntp server.
 439 This function is supposed to be called from `nntp-server-opened-hook'.
 440 It will make innd servers spawn an nnrpd process to allow actual article
 441 reading."
 442   (nntp-send-command "^.*\r?\n" "MODE READER"))
 443
 444 (defun nntp-send-nosy-authinfo ()
 445   "Send the AUTHINFO to the nntp server.
 446 This function is supposed to be called from `nntp-server-opened-hook'.
 447 It will prompt for a password."
 448   (nntp-send-command
 449    "^.*\r?\n" "AUTHINFO USER"
 450    (read-string "NNTP (%s) user name: " nntp-address))
 451   (nntp-send-command
 452    "^.*\r?\n" "AUTHINFO PASS"
 453    (nnmail-read-passwd "NNTP (%s) password: " nntp-address)))
 454
 455 (defun nntp-send-authinfo ()
 456   "Send the AUTHINFO to the nntp server.
 457 This function is supposed to be called from `nntp-server-opened-hook'.
 458 It will prompt for a password."
 459   (nntp-send-command "^.*\r?\n" "AUTHINFO USER" (user-login-name))
 460   (nntp-send-command
 461    "^.*\r?\n" "AUTHINFO PASS"
 462    (read-string "NNTP (%s) password: " nntp-address)))
 463
 464 (defun nntp-send-authinfo-from-file ()
 465   "Send the AUTHINFO to the nntp server.
 466 This function is supposed to be called from `nntp-server-opened-hook'.
 467 It will prompt for a password."
 468   (when (file-exists-p "~/.nntp-authinfo")
 469     (save-excursion
 470       (set-buffer (get-buffer-create " *authinfo*"))
 471       (buffer-disable-undo (current-buffer))
 472       (erase-buffer)
 473       (insert-file-contents "~/.nntp-authinfo")
 474       (goto-char (point-min))
 475       (nntp-send-command "^.*\r?\n" "AUTHINFO USER" (user-login-name))
 476       (nntp-send-command
 477        "^.*\r?\n" "AUTHINFO PASS"
 478        (buffer-substring (point) (progn (end-of-line) (point))))
 479       (kill-buffer (current-buffer)))))
 480
 481 ;;; Internal functions.
 482
 483 (defun nntp-send-command (wait-for &rest strings)
 484   "Send STRINGS to server and wait until WAIT-FOR returns."
 485   (unless nnheader-callback-function
 486     (save-excursion
 487       (set-buffer nntp-server-buffer)
 488       (erase-buffer)))
 489   (nntp-retrieve-data
 490    (mapconcat 'identity strings " ")
 491    nntp-address nntp-port-number nntp-server-buffer
 492    wait-for nnheader-callback-function))
 493
 494 (defun nntp-send-command-nodelete (wait-for &rest strings)
 495   "Send STRINGS to server and wait until WAIT-FOR returns."
 496   (nntp-retrieve-data
 497    (mapconcat 'identity strings " ")
 498    nntp-address nntp-port-number nntp-server-buffer
 499    wait-for nnheader-callback-function))
 500
 501 (defun nntp-send-command-and-decode (wait-for &rest strings)
 502   "Send STRINGS to server and wait until WAIT-FOR returns."
 503   (unless nnheader-callback-function
 504     (save-excursion
 505       (set-buffer nntp-server-buffer)
 506       (erase-buffer)))
 507   (nntp-retrieve-data
 508    (mapconcat 'identity strings " ")
 509    nntp-address nntp-port-number nntp-server-buffer
 510    wait-for nnheader-callback-function t))
 511
 512 (defun nntp-send-buffer (wait-for)
 513   "Send the current buffer to server and wait until WAIT-FOR returns."
 514   (unless nnheader-callback-function
 515     (save-excursion
 516       (set-buffer (nntp-find-connection-buffer nntp-server-buffer))
 517       (erase-buffer)))
 518   (nntp-encode-text)
 519   (process-send-region (nntp-find-connection nntp-server-buffer)
 520                        (point-min) (point-max))
 521   (nntp-retrieve-data
 522    nil nntp-address nntp-port-number nntp-server-buffer
 523    wait-for nnheader-callback-function))
 524
 525 (defun nntp-find-connection (buffer)
 526   "Find the connection delivering to BUFFER."
 527   (let ((alist nntp-connection-alist)
 528         (buffer (if (stringp buffer) (get-buffer buffer) buffer))
 529         process entry)
 530     (while (setq entry (pop alist))
 531       (when (eq buffer (cadr entry))
 532         (setq process (car entry)
 533               alist nil)))
 534     (when process
 535       (if (memq (process-status process) '(open run))
 536           process
 537         (when (buffer-name (process-buffer process))
 538           (kill-buffer (process-buffer process)))
 539         (setq nntp-connection-alist (delq entry nntp-connection-alist))
 540         nil))))
 541
 542 (defun nntp-find-connection-entry (buffer)
 543   "Return the entry for the connection to BUFFER."
 544   (assq (nntp-find-connection buffer) nntp-connection-alist))
 545
 546 (defun nntp-find-connection-buffer (buffer)
 547   "Return the process connection buffer tied to BUFFER."
 548   (let ((process (nntp-find-connection buffer)))
 549     (when process
 550       (process-buffer process))))
 551
 552 (defun nntp-make-process-buffer (buffer)
 553   "Create a new, fresh buffer usable for nntp process connections."
 554   (save-excursion
 555     (set-buffer
 556      (generate-new-buffer
 557       (format " *server %s %s %s*"
 558               nntp-address nntp-port-number
 559               (buffer-name (get-buffer buffer)))))
 560     (buffer-disable-undo (current-buffer))
 561     (set (make-local-variable 'after-change-functions) nil)
 562     (set (make-local-variable 'nntp-process-wait-for) nil)
 563     (set (make-local-variable 'nntp-process-callback) nil)
 564     (set (make-local-variable 'nntp-process-to-buffer) nil)
 565     (set (make-local-variable 'nntp-process-start-point) nil)
 566     (set (make-local-variable 'nntp-process-decode) nil)
 567     (current-buffer)))
 568
 569 (defun nntp-open-connection (buffer)
 570   "Open a connection to PORT on ADDRESS delivering output to BUFFER."
 571   (run-hooks 'nntp-prepare-server-hook)
 572   (let* ((pbuffer (nntp-make-process-buffer buffer))
 573          (process
 574           (condition-case ()
 575               (funcall
 576                nntp-open-connection-function pbuffer)
 577             (error nil))))
 578     (when process
 579       (process-kill-without-query process)
 580       (nntp-wait-for process "^.*\n" buffer)
 581       (if (memq (process-status process) '(open run))
 582           (prog1
 583               (caar (push (list process buffer nil)
 584                           nntp-connection-alist))
 585             (push process nntp-connection-list)
 586             (save-excursion
 587               (set-buffer nntp-server-buffer)
 588               (nntp-read-server-type)
 589               (run-hooks 'nntp-server-opened-hook)
 590               (set-buffer pbuffer)
 591               (erase-buffer)))
 592         (when (buffer-name (process-buffer process))
 593           (kill-buffer (process-buffer process)))
 594         nil))))
 595
 596 (defun nntp-open-network-stream (buffer)
 597   (open-network-stream "nntpd" buffer nntp-address nntp-port-number))
 598
 599 (defun nntp-read-server-type ()
 600   "Find out what the name of the server we have connected to is."
 601   ;; Wait for the status string to arrive.
 602   (setq nntp-server-type (buffer-string))
 603   (let ((alist nntp-server-action-alist)
 604         (case-fold-search t)
 605         entry)
 606     ;; Run server-specific commands.
 607     (while alist
 608       (setq entry (pop alist))
 609       (when (string-match (car entry) nntp-server-type)
 610         (if (and (listp (cadr entry))
 611                  (not (eq 'lambda (caadr entry))))
 612             (eval (cadr entry))
 613           (funcall (cadr entry)))))))
 614
 615 (defun nntp-after-change-function-callback (beg end len)
 616   (when nntp-process-callback
 617     (save-match-data
 618       (if (and (= beg (point-min))
 619                (memq (char-after beg) '(?4 ?5)))
 620           ;; Report back error messages.
 621           (save-excursion
 622             (goto-char beg)
 623             (if (looking-at "480")
 624                 (funcall nntp-authinfo-function)
 625               (nntp-snarf-error-message)
 626               (funcall nntp-process-callback nil)))
 627         (goto-char end)
 628         (when (and (> (point) nntp-process-start-point)
 629                    (re-search-backward nntp-process-wait-for
 630                                        nntp-process-start-point t))
 631           (when (buffer-name (get-buffer nntp-process-to-buffer))
 632             (let ((cur (current-buffer))
 633                   (start nntp-process-start-point))
 634               (save-excursion
 635                 (set-buffer (get-buffer nntp-process-to-buffer))
 636                 (goto-char (point-max))
 637                 (let ((b (point)))
 638                   (insert-buffer-substring cur start)
 639                   (narrow-to-region b (point-max))
 640                   (nntp-decode-text)
 641                   (widen)))))
 642           (goto-char end)
 643           (let ((callback nntp-process-callback)
 644                 (nntp-inside-change-function t))
 645             (setq nntp-process-callback nil)
 646             (save-excursion
 647               (funcall callback (buffer-name
 648                                  (get-buffer nntp-process-to-buffer))))))))))
 649
 650 (defun nntp-retrieve-data (command address port buffer
 651                                    &optional wait-for callback decode)
 652   "Use COMMAND to retrieve data into BUFFER from PORT on ADDRESS."
 653   (let ((process (or (nntp-find-connection buffer)
 654                      (nntp-open-connection buffer))))
 655     (if (not process)
 656         (nnheader-report 'nntp "Couldn't open connection to %s" address)
 657       (unless (or nntp-inhibit-erase nnheader-callback-function)
 658         (save-excursion
 659           (set-buffer (process-buffer process))
 660           (erase-buffer)))
 661       (when command
 662         (nntp-send-string process command))
 663       (cond
 664        ((eq callback 'ignore)
 665         t)
 666        ((and callback wait-for)
 667         (save-excursion
 668           (set-buffer (process-buffer process))
 669           (unless nntp-inside-change-function
 670             (erase-buffer))
 671           (setq nntp-process-decode decode
 672                 nntp-process-to-buffer buffer
 673                 nntp-process-wait-for wait-for
 674                 nntp-process-callback callback
 675                 nntp-process-start-point (point-max)
 676                 after-change-functions
 677                 (list 'nntp-after-change-function-callback)))
 678         t)
 679        (wait-for
 680         (nntp-wait-for process wait-for buffer decode))
 681        (t t)))))
 682
 683 (defun nntp-send-string (process string)
 684   "Send STRING to PROCESS."
 685   (process-send-string process (concat string nntp-end-of-line)))
 686
 687 (defun nntp-wait-for (process wait-for buffer &optional decode)
 688   "Wait for WAIT-FOR to arrive from PROCESS."
 689   (save-excursion
 690     (set-buffer (process-buffer process))
 691     (goto-char (point-min))
 692     (while (or (not (memq (following-char) '(?2 ?3 ?4 ?5)))
 693                (looking-at "480"))
 694       (when (looking-at "480")
 695         (erase-buffer)
 696         (funcall nntp-authinfo-function))
 697       (nntp-accept-process-output process)
 698       (goto-char (point-min)))
 699     (prog1
 700         (if (looking-at "[45]")
 701             (progn
 702               (nntp-snarf-error-message)
 703               nil)
 704           (goto-char (point-max))
 705           (while (not (re-search-backward wait-for nil t))
 706             (nntp-accept-process-output process)
 707             (goto-char (point-max)))
 708           (nntp-decode-text (not decode))
 709           (save-excursion
 710             (set-buffer buffer)
 711             (goto-char (point-max))
 712             (insert-buffer-substring (process-buffer process))
 713             t))
 714       (erase-buffer))))
 715
 716 (defun nntp-snarf-error-message ()
 717   "Save the error message in the current buffer."
 718   (setq nntp-status-string (buffer-string)))
 719
 720 (defun nntp-accept-process-output (process)
 721   "Wait for output from PROCESS and message some dots."
 722   (save-excursion
 723     (set-buffer (or (nntp-find-connection-buffer nntp-server-buffer)
 724                     nntp-server-buffer))
 725     (let ((len (/ (point-max) 10000)))
 726       (unless (zerop len)
 727         (message "nntp reading%s" (make-string len ?.))))
 728     (accept-process-output process 1)))
 729
 730 (defun nntp-accept-response ()
 731   "Wait for output from the process that outputs to BUFFER."
 732   (nntp-accept-process-output (nntp-find-connection nntp-server-buffer)))
 733
 734 (defun nntp-possibly-change-group (group server &optional connectionless)
 735   (when server
 736     (or (nntp-server-opened server)
 737         (nntp-open-server server nil connectionless)))
 738
 739   (unless connectionless
 740     (or (nntp-find-connection nntp-server-buffer)
 741         (nntp-open-connection nntp-server-buffer)))
 742
 743   (when group
 744     (let ((entry (nntp-find-connection-entry nntp-server-buffer)))
 745       (when (not (equal group (caddr entry)))
 746         (nntp-request-group group)
 747         (erase-buffer)))))
 748
 749 (defun nntp-decode-text (&optional cr-only)
 750   "Decode the text in the current buffer."
 751   (goto-char (point-min))
 752   ;; Remove \R's.
 753   (while (search-forward "\r" nil t)
 754     (delete-char -1))
 755   (unless cr-only
 756     ;; Remove trailing ".\n" end-of-transfer marker.
 757     (goto-char (point-max))
 758     (forward-line -1)
 759     (when (looking-at ".\n")
 760       (delete-char 2))
 761     ;; Delete status line.
 762     (goto-char (point-min))
 763     (delete-region (point) (progn (forward-line 1) (point)))
 764     ;; Remove "." -> ".." encoding.
 765     (while (search-forward "\n.." nil t)
 766       (delete-char -1))))
 767
 768 (defun nntp-encode-text ()
 769   "Encode the text in the current buffer."
 770   (save-excursion
 771     ;; Replace "." at beginning of line with "..".
 772     (goto-char (point-min))
 773     (while (re-search-forward "^\\." nil t)
 774       (insert "."))
 775     (goto-char (point-max))
 776     ;; Insert newline at the end of the buffer.
 777     (unless (bolp)
 778       (insert "\n"))
 779     ;; Insert `.' at end of buffer (end of text mark).
 780     (goto-char (point-max))
 781     (insert "." nntp-end-of-line)))
 782
 783 (defun nntp-retrieve-headers-with-xover (articles &optional fetch-old)
 784   (set-buffer nntp-server-buffer)
 785   (erase-buffer)
 786   (cond
 787
 788    ;; This server does not talk NOV.
 789    ((not nntp-server-xover)
 790     nil)
 791
 792    ;; We don't care about gaps.
 793    ((or (not nntp-nov-gap)
 794         fetch-old)
 795     (nntp-send-xover-command
 796      (if fetch-old
 797          (if (numberp fetch-old)
 798              (max 1 (- (car articles) fetch-old))
 799            1)
 800        (car articles))
 801      (car (last articles)) 'wait)
 802
 803     (goto-char (point-min))
 804     (when (looking-at "[1-5][0-9][0-9] ")
 805       (delete-region (point) (progn (forward-line 1) (point))))
 806     (while (search-forward "\r" nil t)
 807       (replace-match "" t t))
 808     (goto-char (point-max))
 809     (forward-line -1)
 810     (when (looking-at "\\.")
 811       (delete-region (point) (progn (forward-line 1) (point)))))
 812
 813    ;; We do it the hard way.  For each gap, an XOVER command is sent
 814    ;; to the server.  We do not wait for a reply from the server, we
 815    ;; just send them off as fast as we can.  That means that we have
 816    ;; to count the number of responses we get back to find out when we
 817    ;; have gotten all we asked for.
 818    ((numberp nntp-nov-gap)
 819     (let ((count 0)
 820           (received 0)
 821           (last-point (point-min))
 822           (buf nntp-server-buffer)
 823           ;;(process-buffer (nntp-find-connection (current-buffer))))
 824           first)
 825       ;; We have to check `nntp-server-xover'.  If it gets set to nil,
 826       ;; that means that the server does not understand XOVER, but we
 827       ;; won't know that until we try.
 828       (while (and nntp-server-xover articles)
 829         (setq first (car articles))
 830         ;; Search forward until we find a gap, or until we run out of
 831         ;; articles.
 832         (while (and (cdr articles)
 833                     (< (- (nth 1 articles) (car articles)) nntp-nov-gap))
 834           (setq articles (cdr articles)))
 835
 836         (when (nntp-send-xover-command first (car articles))
 837           (setq articles (cdr articles)
 838                 count (1+ count))
 839
 840           ;; Every 400 requests we have to read the stream in
 841           ;; order to avoid deadlocks.
 842           (when (or (null articles)     ;All requests have been sent.
 843                     (zerop (% count nntp-maximum-request)))
 844             (accept-process-output)
 845             ;; On some Emacs versions the preceding function has
 846             ;; a tendency to change the buffer.  Perhaps.  It's
 847             ;; quite difficult to reproduce, because it only
 848             ;; seems to happen once in a blue moon.
 849             (set-buffer buf)
 850             (while (progn
 851                      (goto-char last-point)
 852                      ;; Count replies.
 853                      (while (re-search-forward "^[0-9][0-9][0-9] " nil t)
 854                        (setq received (1+ received)))
 855                      (setq last-point (point))
 856                      (< received count))
 857               (accept-process-output)
 858               (set-buffer buf)))))
 859
 860       (when nntp-server-xover
 861         ;; Wait for the reply from the final command.
 862         (goto-char (point-max))
 863         (re-search-backward "^[0-9][0-9][0-9] " nil t)
 864         (when (looking-at "^[23]")
 865           (while (progn
 866                    (goto-char (point-max))
 867                    (forward-line -1)
 868                    (not (looking-at "^\\.\r?\n")))
 869             (nntp-accept-response)))
 870
 871         ;; We remove any "." lines and status lines.
 872         (goto-char (point-min))
 873         (while (search-forward "\r" nil t)
 874           (delete-char -1))
 875         (goto-char (point-min))
 876         (delete-matching-lines "^\\.$\\|^[1-5][0-9][0-9] ")
 877         ;;(copy-to-buffer nntp-server-buffer (point-min) (point-max))
 878         t))))
 879
 880   nntp-server-xover)
 881
 882 (defun nntp-send-xover-command (beg end &optional wait-for-reply)
 883   "Send the XOVER command to the server."
 884   (let ((range (format "%d-%d" beg end))
 885         (nntp-inhibit-erase t))
 886     (if (stringp nntp-server-xover)
 887         ;; If `nntp-server-xover' is a string, then we just send this
 888         ;; command.
 889         (if wait-for-reply
 890             (nntp-send-command-nodelete "\r?\n\\.\r?\n" nntp-server-xover range)
 891           ;; We do not wait for the reply.
 892           (nntp-send-command-nodelete "\r?\n\\.\r?\n" nntp-server-xover range))
 893       (let ((commands nntp-xover-commands))
 894         ;; `nntp-xover-commands' is a list of possible XOVER commands.
 895         ;; We try them all until we get at positive response.
 896         (while (and commands (eq nntp-server-xover 'try))
 897           (nntp-send-command-nodelete "\r?\n\\.\r?\n" (car commands) range)
 898           (save-excursion
 899             (set-buffer nntp-server-buffer)
 900             (goto-char (point-min))
 901             (and (looking-at "[23]")    ; No error message.
 902                  ;; We also have to look at the lines.  Some buggy
 903                  ;; servers give back simple lines with just the
 904                  ;; article number.  How... helpful.
 905                  (progn
 906                    (forward-line 1)
 907                    (looking-at "[0-9]+\t...")) ; More text after number.
 908                  (setq nntp-server-xover (car commands))))
 909           (setq commands (cdr commands)))
 910         ;; If none of the commands worked, we disable XOVER.
 911         (when (eq nntp-server-xover 'try)
 912           (save-excursion
 913             (set-buffer nntp-server-buffer)
 914             (erase-buffer)
 915             (setq nntp-server-xover nil)))
 916         nntp-server-xover))))
 917
 918 ;;; Alternative connection methods.
 919
 920 (defun nntp-wait-for-string (regexp)
 921   "Wait until string arrives in the buffer."
 922   (let ((buf (current-buffer)))
 923     (goto-char (point-min))
 924     (while (not (re-search-forward regexp nil t))
 925       (accept-process-output (nntp-find-connection nntp-server-buffer))
 926       (set-buffer buf)
 927       (goto-char (point-min)))))
 928
 929 (defun nntp-open-telnet (buffer)
 930   (save-excursion
 931     (set-buffer buffer)
 932     (erase-buffer)
 933     (let ((proc (start-process
 934                  "nntpd" buffer "telnet" "-8"))
 935           (case-fold-search t))
 936       (when (memq (process-status proc) '(open run))
 937         (process-send-string proc "set escape \^X\n")
 938         (process-send-string proc (concat "open " nntp-address "\n"))
 939         (nntp-wait-for-string "^\r*.?login:")
 940         (process-send-string
 941          proc (concat
 942                (or nntp-telnet-user-name
 943                    (setq nntp-telnet-user-name (read-string "login: ")))
 944                "\n"))
 945         (nntp-wait-for-string "^\r*.?password:")
 946         (process-send-string
 947          proc (concat
 948                (or nntp-telnet-passwd
 949                    (setq nntp-telnet-passwd
 950                          (nnmail-read-passwd "Password: ")))
 951                "\n"))
 952         (erase-buffer)
 953         (nntp-wait-for-string "bash\\|\$ *\r?$\\|> *\r?")
 954         (process-send-string
 955          proc (concat (mapconcat 'identity nntp-telnet-parameters " ") "\n"))
 956         (nntp-wait-for-string "^\r*200")
 957         (beginning-of-line)
 958         (delete-region (point-min) (point))
 959         (process-send-string proc "\^]")
 960         (nntp-wait-for-string "^telnet")
 961         (process-send-string proc "mode character\n")
 962         (accept-process-output proc 1)
 963         (sit-for 1)
 964         (goto-char (point-min))
 965         (forward-line 1)
 966         (delete-region (point) (point-max)))
 967       proc)))
 968
 969 (defun nntp-open-rlogin (buffer)
 970   "Open a connection to SERVER using rsh."
 971   (let ((proc (if nntp-rlogin-user-name
 972                   (start-process
 973                    "nntpd" buffer "rsh"
 974                    nntp-address "-l" nntp-rlogin-user-name
 975                    (mapconcat 'identity
 976                               nntp-rlogin-parameters " "))
 977                 (start-process
 978                  "nntpd" buffer "rsh" nntp-address
 979                  (mapconcat 'identity
 980                             nntp-rlogin-parameters " ")))))
 981     (set-buffer buffer)
 982     (nntp-wait-for-string "^\r*200")
 983     (beginning-of-line)
 984     (delete-region (point-min) (point))
 985     proc)
 986   )
 987
 988 (defun nntp-find-group-and-number ()
 989   (save-excursion
 990     (save-restriction
 991       (set-buffer nntp-server-buffer)
 992       (narrow-to-region (goto-char (point-min))
 993                         (or (search-forward "\n\n" nil t) (point-max)))
 994       (goto-char (point-min))
 995       ;; We first find the number by looking at the status line.
 996       (let ((number (and (looking-at "2[0-9][0-9] +\\([0-9]+\\) ")
 997                          (string-to-int
 998                           (buffer-substring (match-beginning 1)
 999                                             (match-end 1)))))
1000             group newsgroups xref)
1001         (and number (zerop number) (setq number nil))
1002         ;; Then we find the group name.
1003         (setq group
1004               (cond
1005                ;; If there is only one group in the Newsgroups header,
1006                ;; then it seems quite likely that this article comes
1007                ;; from that group, I'd say.
1008                ((and (setq newsgroups (mail-fetch-field "newsgroups"))
1009                      (not (string-match "," newsgroups)))
1010                 newsgroups)
1011                ;; If there is more than one group in the Newsgroups
1012                ;; header, then the Xref header should be filled out.
1013                ;; We hazard a guess that the group that has this
1014                ;; article number in the Xref header is the one we are
1015                ;; looking for.  This might very well be wrong if this
1016                ;; article happens to have the same number in several
1017                ;; groups, but that's life.
1018                ((and (setq xref (mail-fetch-field "xref"))
1019                      number
1020                      (string-match (format "\\([^ :]+\\):%d" number) xref))
1021                 (substring xref (match-beginning 1) (match-end 1)))
1022                (t "")))
1023         (when (string-match "\r" group)
1024           (setq group (substring group 0 (match-beginning 0))))
1025         (cons group number)))))
1026
1027 (provide 'nntp)
1028
1029 ;;; nntp.el ends here