cgit.sxemacs.org Git - gnus/blob - lisp/nnrss.el

   1 ;;; nnrss.el --- interfacing with RSS
   2 ;; Copyright (C) 2001, 2002, 2003, 2004  Free Software Foundation, Inc.
   3
   4 ;; Author: Shenghuo Zhu <zsh@cs.rochester.edu>
   5 ;; Keywords: RSS
   6
   7 ;; This file is part of GNU Emacs.
   8
   9 ;; GNU Emacs is free software; you can redistribute it and/or modify
  10 ;; it under the terms of the GNU General Public License as published
  11 ;; by the Free Software Foundation; either version 2, or (at your
  12 ;; option) any later version.
  13
  14 ;; GNU Emacs is distributed in the hope that it will be useful, but
  15 ;; WITHOUT ANY WARRANTY; without even the implied warranty of
  16 ;; MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.  See the GNU
  17 ;; General Public License for more details.
  18
  19 ;; You should have received a copy of the GNU General Public License
  20 ;; along with GNU Emacs; see the file COPYING.  If not, write to the
  21 ;; Free Software Foundation, Inc., 59 Temple Place - Suite 330,
  22 ;; Boston, MA 02111-1307, USA.
  23
  24 ;;; Commentary:
  25
  26 ;;; Code:
  27
  28 (eval-when-compile (require 'cl))
  29
  30 (require 'gnus)
  31 (require 'nnoo)
  32 (require 'nnmail)
  33 (require 'message)
  34 (require 'mm-util)
  35 (require 'gnus-util)
  36 (require 'time-date)
  37 (require 'rfc2231)
  38 (require 'mm-url)
  39 (eval-when-compile
  40   (ignore-errors
  41     (require 'xml)))
  42 (eval '(require 'xml))
  43
  44 (nnoo-declare nnrss)
  45
  46 (defvoo nnrss-directory (nnheader-concat gnus-directory "rss/")
  47   "Where nnrss will save its files.")
  48
  49 ;; (group max rss-url)
  50 (defvoo nnrss-server-data nil)
  51
  52 ;; (num timestamp url subject author date extra)
  53 (defvoo nnrss-group-data nil)
  54 (defvoo nnrss-group-max 0)
  55 (defvoo nnrss-group-min 1)
  56 (defvoo nnrss-group nil)
  57 (defvoo nnrss-group-hashtb (make-hash-table :test 'equal))
  58 (defvoo nnrss-status-string "")
  59
  60 (defconst nnrss-version "nnrss 1.0")
  61
  62 (defvar nnrss-group-alist '()
  63   "List of RSS addresses.")
  64
  65 (defvar nnrss-use-local nil)
  66
  67 (defvar nnrss-description-field 'X-Gnus-Description
  68   "Field name used for DESCRIPTION.
  69 To use the description in headers, put this name into `nnmail-extra-headers'.")
  70
  71 (defvar nnrss-url-field 'X-Gnus-Url
  72   "Field name used for URL.
  73 To use the description in headers, put this name into `nnmail-extra-headers'.")
  74
  75 (defvar nnrss-content-function nil
  76   "A function which is called in `nnrss-request-article'.
  77 The arguments are (ENTRY GROUP ARTICLE).
  78 ENTRY is the record of the current headline.  GROUP is the group name.
  79 ARTICLE is the article number of the current headline.")
  80
  81 (nnoo-define-basics nnrss)
  82
  83 ;;; Interface functions
  84
  85 (deffoo nnrss-retrieve-headers (articles &optional group server fetch-old)
  86   (nnrss-possibly-change-group group server)
  87   (let (e)
  88     (save-excursion
  89       (set-buffer nntp-server-buffer)
  90       (erase-buffer)
  91       (dolist (article articles)
  92         (if (setq e (assq article nnrss-group-data))
  93             (insert (number-to-string (car e)) "\t" ;; number
  94                     (if (nth 3 e)
  95                         (nnrss-format-string (nth 3 e)) "")
  96                     "\t" ;; subject
  97                     (if (nth 4 e)
  98                         (nnrss-format-string (nth 4 e))
  99                       "(nobody)")
 100                     "\t" ;;from
 101                     (or (nth 5 e) "")
 102                     "\t" ;; date
 103                     (format "<%d@%s.nnrss>" (car e) group)
 104                     "\t" ;; id
 105                     "\t" ;; refs
 106                     "-1" "\t" ;; chars
 107                     "-1" "\t" ;; lines
 108                     "" "\t" ;; Xref
 109                     (if (and (nth 6 e)
 110                              (memq nnrss-description-field
 111                                    nnmail-extra-headers))
 112                         (concat (symbol-name nnrss-description-field)
 113                                 ": "
 114                                 (nnrss-format-string (nth 6 e))
 115                                 "\t")
 116                       "")
 117                     (if (and (nth 2 e)
 118                              (memq nnrss-url-field
 119                                    nnmail-extra-headers))
 120                         (concat (symbol-name nnrss-url-field)
 121                                 ": "
 122                                 (nnrss-format-string (nth 2 e))
 123                                 "\t")
 124                       "")
 125                     "\n")))))
 126   'nov)
 127
 128 (deffoo nnrss-request-group (group &optional server dont-check)
 129   (nnrss-possibly-change-group group server)
 130   (if dont-check
 131       t
 132     (nnrss-check-group group server)
 133     (nnheader-report 'nnrss "Opened group %s" group)
 134     (nnheader-insert
 135      "211 %d %d %d %s\n" nnrss-group-max nnrss-group-min nnrss-group-max
 136      (prin1-to-string group)
 137      t)))
 138
 139 (deffoo nnrss-close-group (group &optional server)
 140   t)
 141
 142 (deffoo nnrss-request-article (article &optional group server buffer)
 143   (nnrss-possibly-change-group group server)
 144   (let ((e (assq article nnrss-group-data))
 145         (boundary "=-=-=-=-=-=-=-=-=-")
 146         (nntp-server-buffer (or buffer nntp-server-buffer))
 147         post err)
 148     (when e
 149       (catch 'error
 150         (with-current-buffer nntp-server-buffer
 151           (erase-buffer)
 152           (goto-char (point-min))
 153           (insert "Mime-Version: 1.0\nContent-Type: multipart/alternative; boundary=\"" boundary "\"\n")
 154           (if group
 155               (insert "Newsgroups: " group "\n"))
 156           (if (nth 3 e)
 157               (insert "Subject: " (nnrss-format-string (nth 3 e)) "\n"))
 158           (if (nth 4 e)
 159               (insert "From: " (nnrss-format-string (nth 4 e)) "\n"))
 160           (if (nth 5 e)
 161               (insert "Date: " (nnrss-format-string (nth 5 e)) "\n"))
 162           (insert "Message-ID: " (format "<%d@%s.nnrss>" (car e) group) "\n")
 163           (insert "\n")
 164           (let ((text (if (nth 6 e)
 165                           (nnrss-string-as-multibyte (nth 6 e))))
 166                 (link (if (nth 2 e)
 167                           (nth 2 e))))
 168             (insert "\n\n--" boundary "\nContent-Type: text/plain\n\n")
 169             (let ((point (point)))
 170               (when text
 171                 (insert text)
 172                 (goto-char point)
 173                 (while (search-forward "\n" nil t)
 174                   (replace-match " "))
 175                 (goto-char (point-max))
 176                 (insert "\n\n"))
 177               (when link
 178                 (insert link)))
 179             (insert "\n\n--" boundary "\nContent-Type: text/html\n\n")
 180             (let ((point (point)))
 181               (when text
 182                 (insert "<html><head></head><body>\n" text "\n</body></html>")
 183                 (goto-char point)
 184                 (while (search-forward "\n" nil t)
 185                   (replace-match " "))
 186                 (goto-char (point-max))
 187                 (insert "\n\n"))
 188               (when link
 189                 (insert "<p><a href=\"" link "\">link</a></p>\n"))))
 190           (when nnrss-content-function
 191             (funcall nnrss-content-function e group article)))))
 192     (cond
 193      (err
 194       (nnheader-report 'nnrss err))
 195      ((not e)
 196       (nnheader-report 'nnrss "no such id: %d" article))
 197      (t
 198       (nnheader-report 'nnrss "article %s retrieved" (car e))
 199       ;; we return the article number.
 200       (cons nnrss-group (car e))))))
 201
 202 (deffoo nnrss-request-list (&optional server)
 203   (nnrss-possibly-change-group nil server)
 204   (nnrss-generate-active)
 205   t)
 206
 207 (deffoo nnrss-open-server (server &optional defs connectionless)
 208   (nnrss-read-server-data server)
 209   (nnoo-change-server 'nnrss server defs)
 210   t)
 211
 212 (deffoo nnrss-request-expire-articles
 213     (articles group &optional server force)
 214   (nnrss-possibly-change-group group server)
 215   (let (e days not-expirable changed)
 216     (dolist (art articles)
 217       (if (and (setq e (assq art nnrss-group-data))
 218                (nnmail-expired-article-p
 219                 group
 220                 (if (listp (setq days (nth 1 e))) days
 221                   (days-to-time (- days (time-to-days '(0 0)))))
 222                 force))
 223           (setq nnrss-group-data (delq e nnrss-group-data)
 224                 changed t)
 225         (push art not-expirable)))
 226     (if changed
 227         (nnrss-save-group-data group server))
 228     not-expirable))
 229
 230 (deffoo nnrss-request-delete-group (group &optional force server)
 231   (nnrss-possibly-change-group group server)
 232   (setq nnrss-server-data
 233         (delq (assoc group nnrss-server-data) nnrss-server-data))
 234   (nnrss-save-server-data server)
 235   (ignore-errors
 236     (delete-file (nnrss-make-filename group server)))
 237   t)
 238
 239 (deffoo nnrss-request-list-newsgroups (&optional server)
 240   (nnrss-possibly-change-group nil server)
 241   (save-excursion
 242     (set-buffer nntp-server-buffer)
 243     (erase-buffer)
 244     (dolist (elem nnrss-group-alist)
 245       (if (third elem)
 246           (insert (car elem) "\t" (third elem) "\n"))))
 247   t)
 248
 249 (nnoo-define-skeleton nnrss)
 250
 251 ;;; Internal functions
 252 (eval-when-compile (defun xml-rpc-method-call (&rest args)))
 253 (defun nnrss-fetch (url &optional local)
 254   "Fetch URL and put it in a the expected Lisp structure."
 255   (with-temp-buffer
 256     ;;some CVS versions of url.el need this to close the connection quickly
 257     (let (xmlform htmlform)
 258       ;; bit o' work necessary for w3 pre-cvs and post-cvs
 259       (if local
 260           (let ((coding-system-for-read 'binary))
 261             (insert-file-contents url))
 262         (mm-url-insert url))
 263
 264       ;; Because xml-parse-region can't deal with anything that isn't
 265       ;; xml and w3-parse-buffer can't deal with some xml, we have to
 266       ;; parse with xml-parse-region first and, if that fails, parse
 267       ;; with w3-parse-buffer.  Yuck.  Eventually, someone should find out
 268       ;; why w3-parse-buffer fails to parse some well-formed xml and
 269       ;; fix it.
 270
 271       (condition-case err
 272           (setq xmlform (xml-parse-region (point-min) (point-max)))
 273         (error (if (fboundp 'w3-parse-buffer)
 274                    (setq htmlform (caddar (w3-parse-buffer
 275                                            (current-buffer))))
 276                  (message "nnrss: Not valid XML and w3 parse not available (%s)"
 277                           url))))
 278       (if htmlform
 279           htmlform
 280         xmlform))))
 281
 282 (defun nnrss-possibly-change-group (&optional group server)
 283   (when (and server
 284              (not (nnrss-server-opened server)))
 285     (nnrss-open-server server))
 286   (when (and group (not (equal group nnrss-group)))
 287     (nnrss-read-group-data group server)
 288     (setq nnrss-group group)))
 289
 290 (defvar nnrss-extra-categories '(nnrss-snarf-moreover-categories))
 291
 292 (defun nnrss-generate-active ()
 293   (when (y-or-n-p "Fetch extra categories? ")
 294     (mapc 'funcall nnrss-extra-categories))
 295   (save-excursion
 296     (set-buffer nntp-server-buffer)
 297     (erase-buffer)
 298     (dolist (elem nnrss-group-alist)
 299       (insert (prin1-to-string (car elem)) " 0 1 y\n"))
 300     (dolist (elem nnrss-server-data)
 301       (unless (assoc (car elem) nnrss-group-alist)
 302         (insert (prin1-to-string (car elem)) " 0 1 y\n")))))
 303
 304 ;;; data functions
 305
 306 (defun nnrss-read-server-data (server)
 307   (setq nnrss-server-data nil)
 308   (let ((file (nnrss-make-filename "nnrss" server)))
 309     (when (file-exists-p file)
 310       (let ((coding-system-for-read 'binary))
 311         (load file nil nil t)))))
 312
 313 (defun nnrss-save-server-data (server)
 314   (gnus-make-directory nnrss-directory)
 315   (let ((coding-system-for-write 'binary))
 316     (with-temp-file (nnrss-make-filename "nnrss" server)
 317       (gnus-prin1 `(setq nnrss-group-alist ',nnrss-group-alist))
 318       (gnus-prin1 `(setq nnrss-server-data ',nnrss-server-data)))))
 319
 320 (defun nnrss-read-group-data (group server)
 321   (setq nnrss-group-data nil)
 322   (if (hash-table-p nnrss-group-hashtb)
 323       (clrhash nnrss-group-hashtb)
 324     (setq nnrss-group-hashtb (make-hash-table :test 'equal)))
 325   (let ((pair (assoc group nnrss-server-data)))
 326     (setq nnrss-group-max (or (cadr pair) 0))
 327     (setq nnrss-group-min (+ nnrss-group-max 1)))
 328   (let ((file (nnrss-make-filename group server)))
 329     (when (file-exists-p file)
 330       (let ((coding-system-for-read 'binary))
 331         (load file nil t t))
 332       (dolist (e nnrss-group-data)
 333         (puthash (or (nth 2 e) (nth 6 e)) t nnrss-group-hashtb)
 334         (when (and (car e) (> nnrss-group-min (car e)))
 335           (setq nnrss-group-min (car e)))
 336         (when (and (car e) (< nnrss-group-max (car e)))
 337           (setq nnrss-group-max (car e)))))))
 338
 339 (defun nnrss-save-group-data (group server)
 340   (gnus-make-directory nnrss-directory)
 341   (let ((coding-system-for-write 'binary))
 342     (with-temp-file (nnrss-make-filename group server)
 343       (gnus-prin1 `(setq nnrss-group-data ',nnrss-group-data)))))
 344
 345 (defun nnrss-make-filename (name server)
 346   (expand-file-name
 347    (nnrss-translate-file-chars
 348     (concat name
 349             (and server
 350                  (not (equal server ""))
 351                  "-")
 352             server
 353             ".el"))
 354    nnrss-directory))
 355
 356 (gnus-add-shutdown 'nnrss-close 'gnus)
 357
 358 (defun nnrss-close ()
 359   "Clear internal nnrss variables."
 360   (setq nnrss-group-data nil
 361         nnrss-server-data nil
 362         nnrss-group-hashtb nil
 363         nnrss-group-alist nil))
 364
 365 ;;; URL interface
 366
 367 (defun nnrss-no-cache (url)
 368   "")
 369
 370 (defun nnrss-insert-w3 (url)
 371   (mm-with-unibyte-current-buffer
 372     (mm-url-insert url)))
 373
 374 (defun nnrss-decode-entities-unibyte-string (string)
 375   (if string
 376       (mm-with-unibyte-buffer
 377         (insert string)
 378         (mm-url-decode-entities-nbsp)
 379         (buffer-string))))
 380
 381 (defalias 'nnrss-insert 'nnrss-insert-w3)
 382
 383 (if (featurep 'xemacs)
 384     (defalias 'nnrss-string-as-multibyte 'identity)
 385   (defalias 'nnrss-string-as-multibyte 'string-as-multibyte))
 386
 387 ;;; Snarf functions
 388
 389 (defun nnrss-check-group (group server)
 390   (let (file xml subject url extra changed author
 391              date rss-ns rdf-ns content-ns dc-ns)
 392     (if (and nnrss-use-local
 393              (file-exists-p (setq file (expand-file-name
 394                                         (nnrss-translate-file-chars
 395                                          (concat group ".xml"))
 396                                         nnrss-directory))))
 397         (setq xml (nnrss-fetch file t))
 398       (setq url (or (nth 2 (assoc group nnrss-server-data))
 399                     (second (assoc group nnrss-group-alist))))
 400       (unless url
 401         (setq url
 402              (cdr
 403               (assoc 'href
 404                      (nnrss-discover-feed
 405                       (read-string
 406                        (format "URL to search for %s: " group) "http://")))))
 407         (let ((pair (assoc group nnrss-server-data)))
 408           (if pair
 409               (setcdr (cdr pair) (list url))
 410             (push (list group nnrss-group-max url) nnrss-server-data)))
 411         (setq changed t))
 412       (setq xml (nnrss-fetch url)))
 413     ;; See
 414     ;; http://feeds.archive.org/validator/docs/howto/declare_namespaces.html
 415     ;; for more RSS namespaces.
 416     (setq dc-ns (nnrss-get-namespace-prefix xml "http://purl.org/dc/elements/1.1/")
 417           rdf-ns (nnrss-get-namespace-prefix xml "http://www.w3.org/1999/02/22-rdf-syntax-ns#")
 418           rss-ns (nnrss-get-namespace-prefix xml "http://purl.org/rss/1.0/")
 419           content-ns (nnrss-get-namespace-prefix xml "http://purl.org/rss/1.0/modules/content/"))
 420     (dolist (item (nreverse (nnrss-find-el (intern (concat rss-ns "item")) xml)))
 421       (when (and (listp item)
 422                  (string= (concat rss-ns "item") (car item))
 423                  (if (setq url (nnrss-decode-entities-unibyte-string
 424                                 (nnrss-node-text rss-ns 'link (cddr item))))
 425                      (not (gethash url nnrss-group-hashtb))
 426                    (setq extra (or (nnrss-node-text content-ns 'encoded item)
 427                                    (nnrss-node-text rss-ns 'description item)))
 428                    (not (gethash extra nnrss-group-hashtb))))
 429         (setq subject (nnrss-node-text rss-ns 'title item))
 430         (setq extra (or extra
 431                         (nnrss-node-text content-ns 'encoded item)
 432                         (nnrss-node-text rss-ns 'description item)))
 433         (setq author (or (nnrss-node-text rss-ns 'author item)
 434                          (nnrss-node-text dc-ns 'creator item)
 435                          (nnrss-node-text dc-ns 'contributor item)))
 436         (setq date (or (nnrss-node-text dc-ns 'date item)
 437                        (nnrss-node-text rss-ns 'pubDate item)
 438                        (message-make-date)))
 439         (push
 440          (list
 441           (incf nnrss-group-max)
 442           (current-time)
 443           url
 444           (and subject (nnrss-decode-entities-unibyte-string subject))
 445           (and author (nnrss-decode-entities-unibyte-string author))
 446           date
 447           (and extra (nnrss-decode-entities-unibyte-string extra)))
 448          nnrss-group-data)
 449         (puthash (or url extra) t nnrss-group-hashtb)
 450         (setq changed t))
 451         (setq extra nil))
 452     (when changed
 453       (nnrss-save-group-data group server)
 454       (let ((pair (assoc group nnrss-server-data)))
 455         (if pair
 456             (setcar (cdr pair) nnrss-group-max)
 457           (push (list group nnrss-group-max) nnrss-server-data)))
 458       (nnrss-save-server-data server))))
 459
 460 (defun nnrss-opml-import (opml-file)
 461   "OPML subscriptions import.
 462 Read the file and attempt to subscribe to each Feed in the file."
 463   (interactive "fImport file: ")
 464   (mapcar
 465    (lambda (node) (gnus-group-make-rss-group
 466                    (cdr (assq 'xmlUrl (cadr node)))))
 467    (nnrss-find-el 'outline
 468                   (progn
 469                     (find-file opml-file)
 470                     (xml-parse-region (point-min)
 471                                       (point-max))))))
 472
 473 (defun nnrss-opml-export ()
 474   "OPML subscription export.
 475 Export subscriptions to a buffer in OPML Format."
 476   (interactive)
 477   (with-current-buffer (get-buffer-create "*OPML Export*")
 478     (mm-set-buffer-file-coding-system 'utf-8)
 479     (insert (concat
 480              "<?xml version=\"1.0\" encoding=\"utf-8\"?>\n"
 481              "<!-- OPML generated by Emacs Gnus' nnrss.el -->\n"
 482              "<opml version=\"1.1\">\n"
 483              "  <head>\n"
 484              "    <title>mySubscriptions</title>\n"
 485              "    <dateCreated>" (format-time-string "%a, %d %b %Y %T %z")
 486              "</dateCreated>\n"
 487              "    <ownerEmail>" user-mail-address "</ownerEmail>\n"
 488              "    <ownerName>" (user-full-name) "</ownerName>\n"
 489              "  </head>\n"
 490              "  <body>\n"))
 491     (mapc (lambda (sub)
 492             (insert (concat
 493                      "    <outline text=\"" (car sub) "\" xmlUrl=\""
 494                      (cadr sub) "\"/>\n")))
 495           nnrss-group-alist)
 496     (insert (concat
 497              "  </body>\n"
 498            "</opml>\n")))
 499   (pop-to-buffer "*OPML Export*")
 500   (when (fboundp 'sgml-mode)
 501     (sgml-mode)))
 502
 503 (defun nnrss-generate-download-script ()
 504   "Generate a download script in the current buffer.
 505 It is useful when `(setq nnrss-use-local t)'."
 506   (interactive)
 507   (insert "#!/bin/sh\n")
 508   (insert "WGET=wget\n")
 509   (insert "RSSDIR='" (expand-file-name nnrss-directory) "'\n")
 510   (dolist (elem nnrss-server-data)
 511     (let ((url (or (nth 2 elem)
 512                    (second (assoc (car elem) nnrss-group-alist)))))
 513       (insert "$WGET -q -O \"$RSSDIR\"/'"
 514               (nnrss-translate-file-chars (concat (car elem) ".xml"))
 515               "' '" url "'\n"))))
 516
 517 (defun nnrss-translate-file-chars (name)
 518   (let ((nnheader-file-name-translation-alist
 519          (append nnheader-file-name-translation-alist '((?' . ?_)))))
 520     (nnheader-translate-file-chars name)))
 521
 522 (defvar nnrss-moreover-url
 523   "http://w.moreover.com/categories/category_list_rss.html"
 524   "The url of moreover.com categories.")
 525
 526 (defun nnrss-snarf-moreover-categories ()
 527   "Snarf RSS links from moreover.com."
 528   (interactive)
 529   (let (category name url changed)
 530     (with-temp-buffer
 531       (nnrss-insert nnrss-moreover-url)
 532       (goto-char (point-min))
 533       (while (re-search-forward
 534               "<a name=\"\\([^\"]+\\)\">\\|<a href=\"\\(http://[^\"]*moreover\\.com[^\"]+page\\?c=\\([^\"&]+\\)&o=rss\\)" nil t)
 535         (if (match-string 1)
 536             (setq category (match-string 1))
 537           (setq url (match-string 2)
 538                 name (mm-url-decode-entities-string
 539                       (rfc2231-decode-encoded-string
 540                        (match-string 3))))
 541           (if category
 542               (setq name (concat category "." name)))
 543           (unless (assoc name nnrss-server-data)
 544             (setq changed t)
 545             (push (list name 0 url) nnrss-server-data)))))
 546     (if changed
 547         (nnrss-save-server-data ""))))
 548
 549 (defun nnrss-format-string (string)
 550   (gnus-replace-in-string (nnrss-string-as-multibyte string) " *\n *" " "))
 551
 552 (defun nnrss-node-text (namespace local-name element)
 553   (let* ((node (assq (intern (concat namespace (symbol-name local-name)))
 554                      element))
 555          (text (if (and node (listp node))
 556                    (nnrss-node-just-text node)
 557                  node))
 558          (cleaned-text (if text (gnus-replace-in-string
 559                                  text "^[\000-\037\177]+\\|^ +\\| +$" ""))))
 560     (if (string-equal "" cleaned-text)
 561         nil
 562       cleaned-text)))
 563
 564 (defun nnrss-node-just-text (node)
 565   (if (and node (listp node))
 566       (mapconcat 'nnrss-node-just-text (cddr node) " ")
 567     node))
 568
 569 (defun nnrss-find-el (tag data &optional found-list)
 570   "Find the all matching elements in the data.
 571 Careful with this on large documents!"
 572   (when (listp data)
 573     (mapc (lambda (bit)
 574             (when (car-safe bit)
 575               (when (equal tag (car bit))
 576                 (setq found-list
 577                       (append found-list
 578                               (list bit))))
 579               (if (and (listp (car-safe (caddr bit)))
 580                        (not (stringp (caddr bit))))
 581                   (setq found-list
 582                         (append found-list
 583                                 (nnrss-find-el
 584                                  tag (caddr bit))))
 585                 (setq found-list
 586                       (append found-list
 587                               (nnrss-find-el
 588                                tag (cddr bit)))))))
 589           data))
 590   found-list)
 591
 592 (defun nnrss-rsslink-p (el)
 593   "Test if the element we are handed is an RSS autodiscovery link."
 594   (and (eq (car-safe el) 'link)
 595        (string-equal (cdr (assoc 'rel (cadr el))) "alternate")
 596        (or (string-equal (cdr (assoc 'type (cadr el)))
 597                          "application/rss+xml")
 598            (string-equal (cdr (assoc 'type (cadr el))) "text/xml"))))
 599
 600 (defun nnrss-get-rsslinks (data)
 601   "Extract the <link> elements that are links to RSS from the parsed data."
 602   (delq nil (mapcar
 603              (lambda (el)
 604                (if (nnrss-rsslink-p el) el))
 605              (nnrss-find-el 'link data))))
 606
 607 (defun nnrss-extract-hrefs (data)
 608   "Recursively extract hrefs from a page's source.
 609 DATA should be the output of `xml-parse-region' or
 610 `w3-parse-buffer'."
 611   (mapcar (lambda (ahref)
 612             (cdr (assoc 'href (cadr ahref))))
 613           (nnrss-find-el 'a data)))
 614
 615 (defmacro nnrss-match-macro (base-uri item
 616                                            onsite-list offsite-list)
 617   `(cond ((or (string-match (concat "^" ,base-uri) ,item)
 618                (not (string-match "://" ,item)))
 619            (setq ,onsite-list (append ,onsite-list (list ,item))))
 620           (t (setq ,offsite-list (append ,offsite-list (list ,item))))))
 621
 622 (defun nnrss-order-hrefs (base-uri hrefs)
 623   "Given a list of hrefs, sort them using the following priorities:
 624   1. links ending in .rss
 625   2. links ending in .rdf
 626   3. links ending in .xml
 627   4. links containing the above
 628   5. offsite links
 629
 630 BASE-URI is used to determine the location of the links and
 631 whether they are `offsite' or `onsite'."
 632   (let (rss-onsite-end  rdf-onsite-end  xml-onsite-end
 633         rss-onsite-in   rdf-onsite-in   xml-onsite-in
 634         rss-offsite-end rdf-offsite-end xml-offsite-end
 635         rss-offsite-in rdf-offsite-in xml-offsite-in)
 636     (mapc (lambda (href)
 637             (if (not (null href))
 638                 (cond ((string-match "\\.rss$" href)
 639                        (nnrss-match-macro
 640                         base-uri href rss-onsite-end rss-offsite-end))
 641                       ((string-match "\\.rdf$" href)
 642                        (nnrss-match-macro
 643                         base-uri href rdf-onsite-end rdf-offsite-end))
 644                       ((string-match "\\.xml$" href)
 645                        (nnrss-match-macro
 646                         base-uri href xml-onsite-end xml-offsite-end))
 647                       ((string-match "rss" href)
 648                        (nnrss-match-macro
 649                         base-uri href rss-onsite-in rss-offsite-in))
 650                       ((string-match "rdf" href)
 651                        (nnrss-match-macro
 652                         base-uri href rdf-onsite-in rdf-offsite-in))
 653                       ((string-match "xml" href)
 654                        (nnrss-match-macro
 655                         base-uri href xml-onsite-in xml-offsite-in)))))
 656           hrefs)
 657     (append
 658      rss-onsite-end  rdf-onsite-end  xml-onsite-end
 659      rss-onsite-in   rdf-onsite-in   xml-onsite-in
 660      rss-offsite-end rdf-offsite-end xml-offsite-end
 661      rss-offsite-in rdf-offsite-in xml-offsite-in)))
 662
 663 (defun nnrss-discover-feed (url)
 664   "Given a page, find an RSS feed using Mark Pilgrim's
 665 `ultra-liberal rss locator' (http://diveintomark.org/2002/08/15.html)."
 666
 667   (let ((parsed-page (nnrss-fetch url)))
 668
 669 ;;    1. if this url is the rss, use it.
 670     (if (nnrss-rss-p parsed-page)
 671         (let ((rss-ns (nnrss-get-namespace-prefix parsed-page "http://purl.org/rss/1.0/")))
 672           (nnrss-rss-title-description rss-ns parsed-page url))
 673
 674 ;;    2. look for the <link rel="alternate"
 675 ;;    type="application/rss+xml" and use that if it is there.
 676       (let ((links (nnrss-get-rsslinks parsed-page)))
 677         (if links
 678             (let* ((xml (nnrss-fetch
 679                          (cdr (assoc 'href (cadar links)))))
 680                    (rss-ns (nnrss-get-namespace-prefix xml "http://purl.org/rss/1.0/")))
 681               (nnrss-rss-title-description rss-ns xml (cdr (assoc 'href (cadar links)))))
 682
 683 ;;    3. look for links on the site in the following order:
 684 ;;       - onsite links ending in .rss, .rdf, or .xml
 685 ;;       - onsite links containing any of the above
 686 ;;       - offsite links ending in .rss, .rdf, or .xml
 687 ;;       - offsite links containing any of the above
 688           (let* ((base-uri (progn (string-match ".*://[^/]+/?" url)
 689                                   (match-string 0 url)))
 690                  (hrefs (nnrss-order-hrefs
 691                          base-uri (nnrss-extract-hrefs parsed-page)))
 692                  (rss-link nil))
 693           (while (and (eq rss-link nil) (not (eq hrefs nil)))
 694             (let ((href-data (nnrss-fetch (car hrefs))))
 695               (if (nnrss-rss-p href-data)
 696                   (let* ((rss-ns (nnrss-get-namespace-prefix href-data "http://purl.org/rss/1.0/")))
 697                     (setq rss-link (nnrss-rss-title-description
 698                                     rss-ns href-data (car hrefs))))
 699                 (setq hrefs (cdr hrefs)))))
 700           (if rss-link rss-link
 701
 702 ;;    4. check syndic8
 703             (nnrss-find-rss-via-syndic8 url))))))))
 704
 705 (defun nnrss-find-rss-via-syndic8 (url)
 706   "Query syndic8 for the rss feeds it has for URL."
 707   (if (not (locate-library "xml-rpc"))
 708       (progn
 709         (message "XML-RPC is not available... not checking Syndic8.")
 710         nil)
 711     (require 'xml-rpc)
 712     (let ((feedid (xml-rpc-method-call
 713                    "http://www.syndic8.com/xmlrpc.php"
 714                    'syndic8.FindSites
 715                    url)))
 716       (when feedid
 717         (let* ((feedinfo (xml-rpc-method-call
 718                           "http://www.syndic8.com/xmlrpc.php"
 719                           'syndic8.GetFeedInfo
 720                           feedid))
 721                (urllist
 722                 (delq nil
 723                       (mapcar
 724                        (lambda (listinfo)
 725                          (if (string-equal
 726                               (cdr (assoc "status" listinfo))
 727                               "Syndicated")
 728                              (cons
 729                               (cdr (assoc "sitename" listinfo))
 730                               (list
 731                                (cons 'title
 732                                      (cdr (assoc
 733                                            "sitename" listinfo)))
 734                                (cons 'href
 735                                      (cdr (assoc
 736                                            "dataurl" listinfo)))))))
 737                        feedinfo))))
 738           (if (not (> (length urllist) 1))
 739               (cdar urllist)
 740             (let ((completion-ignore-case t)
 741                   (selection
 742                    (mapcar (lambda (listinfo)
 743                              (cons (cdr (assoc "sitename" listinfo))
 744                                    (string-to-int
 745                                     (cdr (assoc "feedid" listinfo)))))
 746                            feedinfo)))
 747               (cdr (assoc
 748                     (completing-read
 749                      "Multiple feeds found.  Select one: "
 750                      selection nil t) urllist)))))))))
 751
 752 (defun nnrss-rss-p (data)
 753   "Test if DATA is an RSS feed.
 754 Simply ensures that the first element is rss or rdf."
 755   (or (eq (caar data) 'rss)
 756       (eq (caar data) 'rdf:RDF)))
 757
 758 (defun nnrss-rss-title-description (rss-namespace data url)
 759   "Return the title of an RSS feed."
 760   (if (nnrss-rss-p data)
 761       (let ((description (intern (concat rss-namespace "description")))
 762             (title (intern (concat rss-namespace "title")))
 763             (channel (nnrss-find-el (intern (concat rss-namespace "channel"))
 764                                     data)))
 765         (list
 766          (cons 'description (caddr (nth 0 (nnrss-find-el description channel))))
 767          (cons 'title (caddr (nth 0 (nnrss-find-el title channel))))
 768          (cons 'href url)))))
 769
 770 (defun nnrss-get-namespace-prefix (el uri)
 771   "Given EL (containing a parsed element) and URI (containing a string
 772 that gives the URI for which you want to retrieve the namespace
 773 prefix), return the prefix."
 774   (let* ((prefix (car (rassoc uri (cadar el))))
 775          (nslist (if prefix
 776                      (split-string (symbol-name prefix) ":")))
 777          (ns (cond ((eq (length nslist) 1) ; no prefix given
 778                     "")
 779                    ((eq (length nslist) 2) ; extract prefix
 780                     (cadr nslist)))))
 781     (if (and ns (not (string= ns "")))
 782         (concat ns ":")
 783       ns)))
 784
 785 (provide 'nnrss)
 786
 787
 788 ;;; nnrss.el ends here
 789
 790 ;;; arch-tag: 12910c07-0cdf-44fb-8d2c-416ded64c267