cgit.sxemacs.org Git - gnus/blob - lisp/nnrss.el

   1 ;;; nnrss.el --- interfacing with RSS
   2 ;; Copyright (C) 2001, 2002, 2003, 2004  Free Software Foundation, Inc.
   3
   4 ;; Author: Shenghuo Zhu <zsh@cs.rochester.edu>
   5 ;; Keywords: RSS
   6
   7 ;; This file is part of GNU Emacs.
   8
   9 ;; GNU Emacs is free software; you can redistribute it and/or modify
  10 ;; it under the terms of the GNU General Public License as published
  11 ;; by the Free Software Foundation; either version 2, or (at your
  12 ;; option) any later version.
  13
  14 ;; GNU Emacs is distributed in the hope that it will be useful, but
  15 ;; WITHOUT ANY WARRANTY; without even the implied warranty of
  16 ;; MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.  See the GNU
  17 ;; General Public License for more details.
  18
  19 ;; You should have received a copy of the GNU General Public License
  20 ;; along with GNU Emacs; see the file COPYING.  If not, write to the
  21 ;; Free Software Foundation, Inc., 59 Temple Place - Suite 330,
  22 ;; Boston, MA 02111-1307, USA.
  23
  24 ;;; Commentary:
  25
  26 ;;; Code:
  27
  28 (eval-when-compile (require 'cl))
  29
  30 (require 'gnus)
  31 (require 'nnoo)
  32 (require 'nnmail)
  33 (require 'message)
  34 (require 'mm-util)
  35 (require 'gnus-util)
  36 (require 'time-date)
  37 (require 'rfc2231)
  38 (require 'mm-url)
  39 (eval-when-compile
  40   (ignore-errors
  41     (require 'xml)))
  42 (eval '(require 'xml))
  43
  44 (nnoo-declare nnrss)
  45
  46 (defvoo nnrss-directory (nnheader-concat gnus-directory "rss/")
  47   "Where nnrss will save its files.")
  48
  49 ;; (group max rss-url)
  50 (defvoo nnrss-server-data nil)
  51
  52 ;; (num timestamp url subject author date extra)
  53 (defvoo nnrss-group-data nil)
  54 (defvoo nnrss-group-max 0)
  55 (defvoo nnrss-group-min 1)
  56 (defvoo nnrss-group nil)
  57 (defvoo nnrss-group-hashtb (make-hash-table :test 'equal))
  58 (defvoo nnrss-status-string "")
  59
  60 (defconst nnrss-version "nnrss 1.0")
  61
  62 (defvar nnrss-group-alist '()
  63   "List of RSS addresses.")
  64
  65 (defvar nnrss-use-local nil)
  66
  67 (defvar nnrss-description-field 'X-Gnus-Description
  68   "Field name used for DESCRIPTION.
  69 To use the description in headers, put this name into `nnmail-extra-headers'.")
  70
  71 (defvar nnrss-url-field 'X-Gnus-Url
  72   "Field name used for URL.
  73 To use the description in headers, put this name into `nnmail-extra-headers'.")
  74
  75 (defvar nnrss-content-function nil
  76   "A function which is called in `nnrss-request-article'.
  77 The arguments are (ENTRY GROUP ARTICLE).
  78 ENTRY is the record of the current headline.  GROUP is the group name.
  79 ARTICLE is the article number of the current headline.")
  80
  81 (nnoo-define-basics nnrss)
  82
  83 ;;; Interface functions
  84
  85 (deffoo nnrss-retrieve-headers (articles &optional group server fetch-old)
  86   (nnrss-possibly-change-group group server)
  87   (let (e)
  88     (save-excursion
  89       (set-buffer nntp-server-buffer)
  90       (erase-buffer)
  91       (dolist (article articles)
  92         (if (setq e (assq article nnrss-group-data))
  93             (insert (number-to-string (car e)) "\t" ;; number
  94                     (if (nth 3 e)
  95                         (nnrss-format-string (nth 3 e)) "")
  96                     "\t" ;; subject
  97                     (if (nth 4 e)
  98                         (nnrss-format-string (nth 4 e))
  99                       "(nobody)")
 100                     "\t" ;;from
 101                     (or (nth 5 e) "")
 102                     "\t" ;; date
 103                     (format "<%d@%s.nnrss>" (car e) group)
 104                     "\t" ;; id
 105                     "\t" ;; refs
 106                     "-1" "\t" ;; chars
 107                     "-1" "\t" ;; lines
 108                     "" "\t" ;; Xref
 109                     (if (and (nth 6 e)
 110                              (memq nnrss-description-field
 111                                    nnmail-extra-headers))
 112                         (concat (symbol-name nnrss-description-field)
 113                                 ": "
 114                                 (nnrss-format-string (nth 6 e))
 115                                 "\t")
 116                       "")
 117                     (if (and (nth 2 e)
 118                              (memq nnrss-url-field
 119                                    nnmail-extra-headers))
 120                         (concat (symbol-name nnrss-url-field)
 121                                 ": "
 122                                 (nnrss-format-string (nth 2 e))
 123                                 "\t")
 124                       "")
 125                     "\n")))))
 126   'nov)
 127
 128 (deffoo nnrss-request-group (group &optional server dont-check)
 129   (nnrss-possibly-change-group group server)
 130   (if dont-check
 131       t
 132     (nnrss-check-group group server)
 133     (nnheader-report 'nnrss "Opened group %s" group)
 134     (nnheader-insert
 135      "211 %d %d %d %s\n" nnrss-group-max nnrss-group-min nnrss-group-max
 136      (prin1-to-string group)
 137      t)))
 138
 139 (deffoo nnrss-close-group (group &optional server)
 140   t)
 141
 142 (deffoo nnrss-request-article (article &optional group server buffer)
 143   (nnrss-possibly-change-group group server)
 144   (let ((e (assq article nnrss-group-data))
 145         (boundary "=-=-=-=-=-=-=-=-=-")
 146         (nntp-server-buffer (or buffer nntp-server-buffer))
 147         post err)
 148     (when e
 149       (catch 'error
 150         (with-current-buffer nntp-server-buffer
 151           (erase-buffer)
 152           (goto-char (point-min))
 153           (insert "Mime-Version: 1.0\nContent-Type: multipart/alternative; boundary=\"" boundary "\"\n")
 154           (if group
 155               (insert "Newsgroups: " group "\n"))
 156           (if (nth 3 e)
 157               (insert "Subject: " (nnrss-format-string (nth 3 e)) "\n"))
 158           (if (nth 4 e)
 159               (insert "From: " (nnrss-format-string (nth 4 e)) "\n"))
 160           (if (nth 5 e)
 161               (insert "Date: " (nnrss-format-string (nth 5 e)) "\n"))
 162           (insert "Message-ID: " (format "<%d@%s.nnrss>" (car e) group) "\n")
 163           (insert "\n")
 164           (let ((text (if (nth 6 e)
 165                           (nnrss-string-as-multibyte (nth 6 e))))
 166                 (link (if (nth 2 e)
 167                           (nth 2 e))))
 168             (insert "\n\n--" boundary "\nContent-Type: text/plain\n\n")
 169             (let ((point (point)))
 170               (when text
 171                 (insert text)
 172                 (goto-char point)
 173                 (while (re-search-forward "\n" nil t)
 174                   (replace-match " "))
 175                 (goto-char (point-max))
 176                 (insert "\n\n"))
 177               (when link
 178                 (insert link)))
 179             (insert "\n\n--" boundary "\nContent-Type: text/html\n\n")
 180             (let ((point (point)))
 181               (when text
 182                 (insert "<html><head></head><body>\n" text "\n</body></html>")
 183                 (goto-char point)
 184                 (while (re-search-forward "\n" nil t)
 185                   (replace-match " "))
 186                 (goto-char (point-max))
 187                 (insert "\n\n"))
 188               (when link
 189                 (insert "<p><a href=\"" link "\">link</a></p>\n"))))
 190           (when nnrss-content-function
 191             (funcall nnrss-content-function e group article)))))
 192     (cond
 193      (err
 194       (nnheader-report 'nnrss err))
 195      ((not e)
 196       (nnheader-report 'nnrss "no such id: %d" article))
 197      (t
 198       (nnheader-report 'nnrss "article %s retrieved" (car e))
 199       ;; we return the article number.
 200       (cons nnrss-group (car e))))))
 201
 202 (deffoo nnrss-request-list (&optional server)
 203   (nnrss-possibly-change-group nil server)
 204   (nnrss-generate-active)
 205   t)
 206
 207 (deffoo nnrss-open-server (server &optional defs connectionless)
 208   (nnrss-read-server-data server)
 209   (nnoo-change-server 'nnrss server defs)
 210   t)
 211
 212 (deffoo nnrss-request-expire-articles
 213     (articles group &optional server force)
 214   (nnrss-possibly-change-group group server)
 215   (let (e days not-expirable changed)
 216     (dolist (art articles)
 217       (if (and (setq e (assq art nnrss-group-data))
 218                (nnmail-expired-article-p
 219                 group
 220                 (if (listp (setq days (nth 1 e))) days
 221                   (days-to-time (- days (time-to-days '(0 0)))))
 222                 force))
 223           (setq nnrss-group-data (delq e nnrss-group-data)
 224                 changed t)
 225         (push art not-expirable)))
 226     (if changed
 227         (nnrss-save-group-data group server))
 228     not-expirable))
 229
 230 (deffoo nnrss-request-delete-group (group &optional force server)
 231   (nnrss-possibly-change-group group server)
 232   (setq nnrss-server-data
 233         (delq (assoc group nnrss-server-data) nnrss-server-data))
 234   (nnrss-save-server-data server)
 235   (ignore-errors
 236     (delete-file (nnrss-make-filename group server)))
 237   t)
 238
 239 (deffoo nnrss-request-list-newsgroups (&optional server)
 240   (nnrss-possibly-change-group nil server)
 241   (save-excursion
 242     (set-buffer nntp-server-buffer)
 243     (erase-buffer)
 244     (dolist (elem nnrss-group-alist)
 245       (if (third elem)
 246           (insert (car elem) "\t" (third elem) "\n"))))
 247   t)
 248
 249 (nnoo-define-skeleton nnrss)
 250
 251 ;;; Internal functions
 252 (eval-when-compile (defun xml-rpc-method-call (&rest args)))
 253 (defun nnrss-fetch (url &optional local)
 254   "Fetch URL and put it in a the expected Lisp structure."
 255   (with-temp-buffer
 256   ;some CVS versions of url.el need this to close the connection quickly
 257     (let* (xmlform htmlform)
 258       ;; bit o' work necessary for w3 pre-cvs and post-cvs
 259       (if local
 260           (let ((coding-system-for-read 'binary))
 261             (insert-file-contents url))
 262         (mm-url-insert url))
 263
 264 ;; Because xml-parse-region can't deal with anything that isn't
 265 ;; xml and w3-parse-buffer can't deal with some xml, we have to
 266 ;; parse with xml-parse-region first and, if that fails, parse
 267 ;; with w3-parse-buffer.  Yuck.  Eventually, someone should find out
 268 ;; why w3-parse-buffer fails to parse some well-formed xml and
 269 ;; fix it.
 270
 271     (condition-case err
 272         (setq xmlform (xml-parse-region (point-min) (point-max)))
 273       (error (if (fboundp 'w3-parse-buffer)
 274                  (setq htmlform (caddar (w3-parse-buffer
 275                                          (current-buffer))))
 276                (message "nnrss: Not valid XML and w3 parse not available (%s)"
 277                         url))))
 278     (if htmlform
 279         htmlform
 280       xmlform))))
 281
 282 (defun nnrss-possibly-change-group (&optional group server)
 283   (when (and server
 284              (not (nnrss-server-opened server)))
 285     (nnrss-open-server server))
 286   (when (and group (not (equal group nnrss-group)))
 287     (nnrss-read-group-data group server)
 288     (setq nnrss-group group)))
 289
 290 (defvar nnrss-extra-categories '(nnrss-snarf-moreover-categories))
 291
 292 (defun nnrss-generate-active ()
 293   (if (y-or-n-p "Fetch extra categories? ")
 294       (dolist (func nnrss-extra-categories)
 295         (funcall func)))
 296   (save-excursion
 297     (set-buffer nntp-server-buffer)
 298     (erase-buffer)
 299     (dolist (elem nnrss-group-alist)
 300       (insert (prin1-to-string (car elem)) " 0 1 y\n"))
 301     (dolist (elem nnrss-server-data)
 302       (unless (assoc (car elem) nnrss-group-alist)
 303         (insert (prin1-to-string (car elem)) " 0 1 y\n")))))
 304
 305 ;;; data functions
 306
 307 (defun nnrss-read-server-data (server)
 308   (setq nnrss-server-data nil)
 309   (let ((file (nnrss-make-filename "nnrss" server)))
 310     (when (file-exists-p file)
 311       (let ((coding-system-for-read 'binary))
 312         (load file nil nil t)))))
 313
 314 (defun nnrss-save-server-data (server)
 315   (gnus-make-directory nnrss-directory)
 316   (let ((coding-system-for-write 'binary))
 317     (with-temp-file (nnrss-make-filename "nnrss" server)
 318       (gnus-prin1 `(setq nnrss-group-alist ',nnrss-group-alist))
 319       (gnus-prin1 `(setq nnrss-server-data ',nnrss-server-data)))))
 320
 321 (defun nnrss-read-group-data (group server)
 322   (setq nnrss-group-data nil)
 323   (if (hash-table-p nnrss-group-hashtb)
 324       (clrhash nnrss-group-hashtb)
 325     (setq nnrss-group-hashtb (make-hash-table :test 'equal)))
 326   (let ((pair (assoc group nnrss-server-data)))
 327     (setq nnrss-group-max (or (cadr pair) 0))
 328     (setq nnrss-group-min (+ nnrss-group-max 1)))
 329   (let ((file (nnrss-make-filename group server)))
 330     (when (file-exists-p file)
 331       (let ((coding-system-for-read 'binary))
 332         (load file nil t t))
 333       (dolist (e nnrss-group-data)
 334         (puthash (or (nth 2 e) (nth 3 e)) t nnrss-group-hashtb)
 335         (when (and (car e) (> nnrss-group-min (car e)))
 336           (setq nnrss-group-min (car e)))
 337         (when (and (car e) (< nnrss-group-max (car e)))
 338           (setq nnrss-group-max (car e)))))))
 339
 340 (defun nnrss-save-group-data (group server)
 341   (gnus-make-directory nnrss-directory)
 342   (let ((coding-system-for-write 'binary))
 343     (with-temp-file (nnrss-make-filename group server)
 344       (gnus-prin1 `(setq nnrss-group-data ',nnrss-group-data)))))
 345
 346 (defun nnrss-make-filename (name server)
 347   (expand-file-name
 348    (nnrss-translate-file-chars
 349     (concat name
 350             (and server
 351                  (not (equal server ""))
 352                  "-")
 353             server
 354             ".el"))
 355    nnrss-directory))
 356
 357 (gnus-add-shutdown 'nnrss-close 'gnus)
 358
 359 (defun nnrss-close ()
 360   "Clear internal nnrss variables."
 361   (setq nnrss-group-data nil
 362         nnrss-server-data nil
 363         nnrss-group-hashtb nil
 364         nnrss-group-alist nil))
 365
 366 ;;; URL interface
 367
 368 (defun nnrss-no-cache (url)
 369   "")
 370
 371 (defun nnrss-insert-w3 (url)
 372   (mm-with-unibyte-current-buffer
 373     (mm-url-insert url)))
 374
 375 (defun nnrss-decode-entities-unibyte-string (string)
 376   (if string
 377       (mm-with-unibyte-buffer
 378         (insert string)
 379         (mm-url-decode-entities-nbsp)
 380         (buffer-string))))
 381
 382 (defalias 'nnrss-insert 'nnrss-insert-w3)
 383
 384 (if (featurep 'xemacs)
 385     (defalias 'nnrss-string-as-multibyte 'identity)
 386   (defalias 'nnrss-string-as-multibyte 'string-as-multibyte))
 387
 388 ;;; Snarf functions
 389
 390 (defun nnrss-check-group (group server)
 391   (let (file xml subject url extra changed author
 392              date rss-ns rdf-ns content-ns dc-ns)
 393     (if (and nnrss-use-local
 394              (file-exists-p (setq file (expand-file-name
 395                                         (nnrss-translate-file-chars
 396                                          (concat group ".xml"))
 397                                         nnrss-directory))))
 398         (setq xml (nnrss-fetch file t))
 399       (setq url (or (nth 2 (assoc group nnrss-server-data))
 400                     (second (assoc group nnrss-group-alist))))
 401       (unless url
 402         (setq url
 403              (cdr
 404               (assoc 'href
 405                      (nnrss-discover-feed
 406                       (read-string
 407                        (format "URL to search for %s: " group) "http://")))))
 408         (let ((pair (assoc group nnrss-server-data)))
 409           (if pair
 410               (setcdr (cdr pair) (list url))
 411             (push (list group nnrss-group-max url) nnrss-server-data)))
 412         (setq changed t))
 413       (setq xml (nnrss-fetch url)))
 414     ;; See
 415     ;; http://feeds.archive.org/validator/docs/howto/declare_namespaces.html
 416     ;; for more RSS namespaces.
 417     (setq dc-ns (nnrss-get-namespace-prefix xml "http://purl.org/dc/elements/1.1/")
 418           rdf-ns (nnrss-get-namespace-prefix xml "http://www.w3.org/1999/02/22-rdf-syntax-ns#")
 419           rss-ns (nnrss-get-namespace-prefix xml "http://purl.org/rss/1.0/")
 420           content-ns (nnrss-get-namespace-prefix xml "http://purl.org/rss/1.0/modules/content/"))
 421     (dolist (item (nreverse (nnrss-find-el (intern (concat rss-ns "item")) xml)))
 422       (when (and (listp item)
 423                  (string= (concat rss-ns "item") (car item))
 424                  (if (setq url (nnrss-decode-entities-unibyte-string
 425                                 (nnrss-node-text rss-ns 'link (cddr item))))
 426                      (not (gethash url nnrss-group-hashtb))
 427                    (setq subject (nnrss-node-text rss-ns 'title item))
 428                    (not (gethash subject nnrss-group-hashtb))))
 429         (setq subject (or subject (nnrss-node-text rss-ns 'title item)))
 430         (setq extra (or (nnrss-node-text content-ns 'encoded item)
 431                         (nnrss-node-text rss-ns 'description item)))
 432         (setq author (or (nnrss-node-text rss-ns 'author item)
 433                          (nnrss-node-text dc-ns 'creator item)
 434                          (nnrss-node-text dc-ns 'contributor item)))
 435         (setq date (or (nnrss-node-text dc-ns 'date item)
 436                        (nnrss-node-text rss-ns 'pubDate item)
 437                        (message-make-date)))
 438         (push
 439          (list
 440           (incf nnrss-group-max)
 441           (current-time)
 442           url
 443           (and subject (nnrss-decode-entities-unibyte-string subject))
 444           (and author (nnrss-decode-entities-unibyte-string author))
 445           date
 446           (and extra (nnrss-decode-entities-unibyte-string extra)))
 447          nnrss-group-data)
 448         (puthash (or url subject) t nnrss-group-hashtb)
 449         (setq changed t))
 450         (setq subject nil))
 451     (when changed
 452       (nnrss-save-group-data group server)
 453       (let ((pair (assoc group nnrss-server-data)))
 454         (if pair
 455             (setcar (cdr pair) nnrss-group-max)
 456           (push (list group nnrss-group-max) nnrss-server-data)))
 457       (nnrss-save-server-data server))))
 458
 459 (defun nnrss-opml-import (opml-file)
 460   "OPML subscriptions import.
 461 Read the file and attempt to subscribe to each Feed in the file."
 462   (interactive "fImport file: ")
 463   (mapcar
 464    (lambda (node) (gnus-group-make-rss-group
 465                    (cdr (assq 'xmlUrl (cadr node)))))
 466    (nnrss-find-el 'outline
 467                   (progn
 468                     (find-file opml-file)
 469                     (xml-parse-region (point-min)
 470                                       (point-max))))))
 471
 472 (defun nnrss-opml-export ()
 473   "OPML subscription export.
 474 Export subscriptions to a buffer in OPML Format."
 475   (interactive)
 476   (with-current-buffer (get-buffer-create "*OPML Export*")
 477     (mm-set-buffer-file-coding-system 'utf-8)
 478     (insert (concat
 479              "<?xml version=\"1.0\" encoding=\"utf-8\"?>\n"
 480              "<!-- OPML generated by Emacs Gnus' nnrss.el -->\n"
 481              "<opml version=\"1.1\">\n"
 482              "  <head>\n"
 483              "    <title>mySubscriptions</title>\n"
 484              "    <dateCreated>" (format-time-string "%a, %d %b %Y %T %z")
 485              "</dateCreated>\n"
 486              "    <ownerEmail>" user-mail-address "</ownerEmail>\n"
 487              "    <ownerName>" (user-full-name) "</ownerName>\n"
 488              "  </head>\n"
 489              "  <body>\n"))
 490     (mapc (lambda (sub)
 491             (insert (concat
 492                      "    <outline text=\"" (car sub) "\" xmlUrl=\""
 493                      (cadr sub) "\"/>\n")))
 494           nnrss-group-alist)
 495     (insert (concat
 496              "  </body>\n"
 497            "</opml>\n")))
 498   (pop-to-buffer "*OPML Export*")
 499   (when (fboundp 'sgml-mode)
 500     (sgml-mode)))
 501
 502 (defun nnrss-generate-download-script ()
 503   "Generate a download script in the current buffer.
 504 It is useful when `(setq nnrss-use-local t)'."
 505   (interactive)
 506   (insert "#!/bin/sh\n")
 507   (insert "WGET=wget\n")
 508   (insert "RSSDIR='" (expand-file-name nnrss-directory) "'\n")
 509   (dolist (elem nnrss-server-data)
 510     (let ((url (or (nth 2 elem)
 511                    (second (assoc (car elem) nnrss-group-alist)))))
 512       (insert "$WGET -q -O \"$RSSDIR\"/'"
 513               (nnrss-translate-file-chars (concat (car elem) ".xml"))
 514               "' '" url "'\n"))))
 515
 516 (defun nnrss-translate-file-chars (name)
 517   (let ((nnheader-file-name-translation-alist
 518          (append nnheader-file-name-translation-alist '((?' . ?_)))))
 519     (nnheader-translate-file-chars name)))
 520
 521 (defvar nnrss-moreover-url
 522   "http://w.moreover.com/categories/category_list_rss.html"
 523   "The url of moreover.com categories.")
 524
 525 (defun nnrss-snarf-moreover-categories ()
 526   "Snarf RSS links from moreover.com."
 527   (interactive)
 528   (let (category name url changed)
 529     (with-temp-buffer
 530       (nnrss-insert nnrss-moreover-url)
 531       (goto-char (point-min))
 532       (while (re-search-forward
 533               "<a name=\"\\([^\"]+\\)\">\\|<a href=\"\\(http://[^\"]*moreover\\.com[^\"]+page\\?c=\\([^\"&]+\\)&o=rss\\)" nil t)
 534         (if (match-string 1)
 535             (setq category (match-string 1))
 536           (setq url (match-string 2)
 537                 name (mm-url-decode-entities-string
 538                       (rfc2231-decode-encoded-string
 539                        (match-string 3))))
 540           (if category
 541               (setq name (concat category "." name)))
 542           (unless (assoc name nnrss-server-data)
 543             (setq changed t)
 544             (push (list name 0 url) nnrss-server-data)))))
 545     (if changed
 546         (nnrss-save-server-data ""))))
 547
 548 (defun nnrss-format-string (string)
 549   (gnus-replace-in-string (nnrss-string-as-multibyte string) " *\n *" " "))
 550
 551 (defun nnrss-node-text (namespace local-name element)
 552   (let* ((node (assq (intern (concat namespace (symbol-name local-name)))
 553                      element))
 554          (text (if (and node (listp node))
 555                    (nnrss-node-just-text node)
 556                  node))
 557          (cleaned-text (if text (gnus-replace-in-string
 558                                  text "^[\000-\037\177]+\\|^ +\\| +$" ""))))
 559     (if (string-equal "" cleaned-text)
 560         nil
 561       cleaned-text)))
 562
 563 (defun nnrss-node-just-text (node)
 564   (if (and node (listp node))
 565       (mapconcat 'nnrss-node-just-text (cddr node) " ")
 566     node))
 567
 568 (defun nnrss-find-el (tag data &optional found-list)
 569   "Find the all matching elements in the data.
 570 Careful with this on large documents!"
 571   (when (listp data)
 572     (mapc (lambda (bit)
 573             (when (car-safe bit)
 574               (when (equal tag (car bit))
 575                 (setq found-list
 576                       (append found-list
 577                               (list bit))))
 578               (if (and (listp (car-safe (caddr bit)))
 579                        (not (stringp (caddr bit))))
 580                   (setq found-list
 581                         (append found-list
 582                                 (nnrss-find-el
 583                                  tag (caddr bit))))
 584                 (setq found-list
 585                       (append found-list
 586                               (nnrss-find-el
 587                                tag (cddr bit)))))))
 588           data))
 589   found-list)
 590
 591 (defun nnrss-rsslink-p (el)
 592   "Test if the element we are handed is an RSS autodiscovery link."
 593   (and (eq (car-safe el) 'link)
 594        (string-equal (cdr (assoc 'rel (cadr el))) "alternate")
 595        (or (string-equal (cdr (assoc 'type (cadr el)))
 596                          "application/rss+xml")
 597            (string-equal (cdr (assoc 'type (cadr el))) "text/xml"))))
 598
 599 (defun nnrss-get-rsslinks (data)
 600   "Extract the <link> elements that are links to RSS from the parsed data."
 601   (delq nil (mapcar
 602              (lambda (el)
 603                (if (nnrss-rsslink-p el) el))
 604              (nnrss-find-el 'link data))))
 605
 606 (defun nnrss-extract-hrefs (data)
 607   "Recursively extract hrefs from a page's source.
 608 DATA should be the output of `xml-parse-region' or
 609 `w3-parse-buffer'."
 610   (mapcar (lambda (ahref)
 611             (cdr (assoc 'href (cadr ahref))))
 612           (nnrss-find-el 'a data)))
 613
 614 (defmacro nnrss-match-macro (base-uri item
 615                                            onsite-list offsite-list)
 616   `(cond ((or (string-match (concat "^" ,base-uri) ,item)
 617                (not (string-match "://" ,item)))
 618            (setq ,onsite-list (append ,onsite-list (list ,item))))
 619           (t (setq ,offsite-list (append ,offsite-list (list ,item))))))
 620
 621 (defun nnrss-order-hrefs (base-uri hrefs)
 622   "Given a list of hrefs, sort them using the following priorities:
 623   1. links ending in .rss
 624   2. links ending in .rdf
 625   3. links ending in .xml
 626   4. links containing the above
 627   5. offsite links
 628
 629 BASE-URI is used to determine the location of the links and
 630 whether they are `offsite' or `onsite'."
 631   (let (rss-onsite-end  rdf-onsite-end  xml-onsite-end
 632         rss-onsite-in   rdf-onsite-in   xml-onsite-in
 633         rss-offsite-end rdf-offsite-end xml-offsite-end
 634         rss-offsite-in rdf-offsite-in xml-offsite-in)
 635     (mapc (lambda (href)
 636             (if (not (null href))
 637                 (cond ((string-match "\\.rss$" href)
 638                        (nnrss-match-macro
 639                         base-uri href rss-onsite-end rss-offsite-end))
 640                       ((string-match "\\.rdf$" href)
 641                        (nnrss-match-macro
 642                         base-uri href rdf-onsite-end rdf-offsite-end))
 643                       ((string-match "\\.xml$" href)
 644                        (nnrss-match-macro
 645                         base-uri href xml-onsite-end xml-offsite-end))
 646                       ((string-match "rss" href)
 647                        (nnrss-match-macro
 648                         base-uri href rss-onsite-in rss-offsite-in))
 649                       ((string-match "rdf" href)
 650                        (nnrss-match-macro
 651                         base-uri href rdf-onsite-in rdf-offsite-in))
 652                       ((string-match "xml" href)
 653                        (nnrss-match-macro
 654                         base-uri href xml-onsite-in xml-offsite-in)))))
 655           hrefs)
 656     (append
 657      rss-onsite-end  rdf-onsite-end  xml-onsite-end
 658      rss-onsite-in   rdf-onsite-in   xml-onsite-in
 659      rss-offsite-end rdf-offsite-end xml-offsite-end
 660      rss-offsite-in rdf-offsite-in xml-offsite-in)))
 661
 662 (defun nnrss-discover-feed (url)
 663   "Given a page, find an RSS feed using Mark Pilgrim's
 664 `ultra-liberal rss locator' (http://diveintomark.org/2002/08/15.html)."
 665
 666   (let ((parsed-page (nnrss-fetch url)))
 667
 668 ;;    1. if this url is the rss, use it.
 669     (if (nnrss-rss-p parsed-page)
 670         (let ((rss-ns (nnrss-get-namespace-prefix parsed-page "http://purl.org/rss/1.0/")))
 671           (nnrss-rss-title-description rss-ns parsed-page url))
 672
 673 ;;    2. look for the <link rel="alternate"
 674 ;;    type="application/rss+xml" and use that if it is there.
 675       (let ((links (nnrss-get-rsslinks parsed-page)))
 676         (if links
 677             (let* ((xml (nnrss-fetch
 678                          (cdr (assoc 'href (cadar links)))))
 679                    (rss-ns (nnrss-get-namespace-prefix xml "http://purl.org/rss/1.0/")))
 680               (nnrss-rss-title-description rss-ns xml (cdr (assoc 'href (cadar links)))))
 681
 682 ;;    3. look for links on the site in the following order:
 683 ;;       - onsite links ending in .rss, .rdf, or .xml
 684 ;;       - onsite links containing any of the above
 685 ;;       - offsite links ending in .rss, .rdf, or .xml
 686 ;;       - offsite links containing any of the above
 687           (let* ((base-uri (progn (string-match ".*://[^/]+/?" url)
 688                                   (match-string 0 url)))
 689                  (hrefs (nnrss-order-hrefs
 690                          base-uri (nnrss-extract-hrefs parsed-page)))
 691                  (rss-link nil))
 692           (while (and (eq rss-link nil) (not (eq hrefs nil)))
 693             (let ((href-data (nnrss-fetch (car hrefs))))
 694               (if (nnrss-rss-p href-data)
 695                   (let* ((rss-ns (nnrss-get-namespace-prefix href-data "http://purl.org/rss/1.0/")))
 696                     (setq rss-link (nnrss-rss-title-description
 697                                     rss-ns href-data (car hrefs))))
 698                 (setq hrefs (cdr hrefs)))))
 699           (if rss-link rss-link
 700
 701 ;;    4. check syndic8
 702             (nnrss-find-rss-via-syndic8 url))))))))
 703
 704 (defun nnrss-find-rss-via-syndic8 (url)
 705   "Query syndic8 for the rss feeds it has for URL."
 706   (if (not (locate-library "xml-rpc"))
 707       (progn
 708         (message "XML-RPC is not available... not checking Syndic8.")
 709         nil)
 710     (require 'xml-rpc)
 711     (let ((feedid (xml-rpc-method-call
 712                    "http://www.syndic8.com/xmlrpc.php"
 713                    'syndic8.FindSites
 714                    url)))
 715       (when feedid
 716         (let* ((feedinfo (xml-rpc-method-call
 717                           "http://www.syndic8.com/xmlrpc.php"
 718                           'syndic8.GetFeedInfo
 719                           feedid))
 720                (urllist
 721                 (delq nil
 722                       (mapcar
 723                        (lambda (listinfo)
 724                          (if (string-equal
 725                               (cdr (assoc "status" listinfo))
 726                               "Syndicated")
 727                              (cons
 728                               (cdr (assoc "sitename" listinfo))
 729                               (list
 730                                (cons 'title
 731                                      (cdr (assoc
 732                                            "sitename" listinfo)))
 733                                (cons 'href
 734                                      (cdr (assoc
 735                                            "dataurl" listinfo)))))))
 736                        feedinfo))))
 737           (if (not (> (length urllist) 1))
 738               (cdar urllist)
 739             (let ((completion-ignore-case t)
 740                   (selection
 741                    (mapcar (lambda (listinfo)
 742                              (cons (cdr (assoc "sitename" listinfo))
 743                                    (string-to-int
 744                                     (cdr (assoc "feedid" listinfo)))))
 745                            feedinfo)))
 746               (cdr (assoc
 747                     (completing-read
 748                      "Multiple feeds found.  Select one: "
 749                      selection nil t) urllist)))))))))
 750
 751 (defun nnrss-rss-p (data)
 752   "Test if DATA is an RSS feed.
 753 Simply ensures that the first element is rss or rdf."
 754   (or (eq (caar data) 'rss)
 755       (eq (caar data) 'rdf:RDF)))
 756
 757 (defun nnrss-rss-title-description (rss-namespace data url)
 758   "Return the title of an RSS feed."
 759   (if (nnrss-rss-p data)
 760       (let ((description (intern (concat rss-namespace "description")))
 761             (title (intern (concat rss-namespace "title")))
 762             (channel (nnrss-find-el (intern (concat rss-namespace "channel"))
 763                                     data)))
 764         (list
 765          (cons 'description (caddr (nth 0 (nnrss-find-el description channel))))
 766          (cons 'title (caddr (nth 0 (nnrss-find-el title channel))))
 767          (cons 'href url)))))
 768
 769 (defun nnrss-get-namespace-prefix (el uri)
 770   "Given EL (containing a parsed element) and URI (containing a string
 771 that gives the URI for which you want to retrieve the namespace
 772 prefix), return the prefix."
 773   (let* ((prefix (car (rassoc uri (cadar el))))
 774          (nslist (if prefix
 775                      (split-string (symbol-name prefix) ":")))
 776          (ns (cond ((eq (length nslist) 1) ; no prefix given
 777                     "")
 778                    ((eq (length nslist) 2) ; extract prefix
 779                     (cadr nslist)))))
 780     (if (and ns (not (string= ns "")))
 781         (concat ns ":")
 782       ns)))
 783
 784 (provide 'nnrss)
 785
 786
 787 ;;; nnrss.el ends here
 788