cgit.sxemacs.org Git - gnus/blob - lisp/nnmh.el

   1 ;;; nnmh.el --- mhspool access for Gnus
   2 ;; Copyright (C) 1995,96 Free Software Foundation, Inc.
   3
   4 ;; Author: Lars Magne Ingebrigtsen <larsi@ifi.uio.no>
   5 ;;      Masanobu UMEDA <umerin@flab.flab.fujitsu.junet>
   6 ;; Keywords: news, mail
   7
   8 ;; This file is part of GNU Emacs.
   9
  10 ;; GNU Emacs is free software; you can redistribute it and/or modify
  11 ;; it under the terms of the GNU General Public License as published by
  12 ;; the Free Software Foundation; either version 2, or (at your option)
  13 ;; any later version.
  14
  15 ;; GNU Emacs is distributed in the hope that it will be useful,
  16 ;; but WITHOUT ANY WARRANTY; without even the implied warranty of
  17 ;; MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.  See the
  18 ;; GNU General Public License for more details.
  19
  20 ;; You should have received a copy of the GNU General Public License
  21 ;; along with GNU Emacs; see the file COPYING.  If not, write to the
  22 ;; Free Software Foundation, Inc., 59 Temple Place - Suite 330,
  23 ;; Boston, MA 02111-1307, USA.
  24
  25 ;;; Commentary:
  26
  27 ;; Based on nnspool.el by Masanobu UMEDA <umerin@flab.flab.fujitsu.junet>.
  28 ;; For an overview of what the interface functions do, please see the
  29 ;; Gnus sources.
  30
  31 ;;; Code:
  32
  33 (require 'nnheader)
  34 (require 'nnmail)
  35 (require 'gnus)
  36 (require 'nnoo)
  37 (eval-and-compile (require 'cl))
  38
  39 (nnoo-declare nnmh)
  40
  41 (defvoo nnmh-directory message-directory
  42   "*Mail spool directory.")
  43
  44 (defvoo nnmh-get-new-mail t
  45   "*If non-nil, nnmh will check the incoming mail file and split the mail.")
  46
  47 (defvoo nnmh-prepare-save-mail-hook nil
  48   "*Hook run narrowed to an article before saving.")
  49
  50 (defvoo nnmh-be-safe nil
  51   "*If non-nil, nnmh will check all articles to make sure whether they are new or not.")
  52
  53 \f
  54
  55 (defconst nnmh-version "nnmh 1.0"
  56   "nnmh version.")
  57
  58 (defvoo nnmh-current-directory nil
  59   "Current news group directory.")
  60
  61 (defvoo nnmh-status-string "")
  62 (defvoo nnmh-group-alist nil)
  63
  64 \f
  65
  66 ;;; Interface functions.
  67
  68 (nnoo-define-basics nnmh)
  69
  70 (deffoo nnmh-retrieve-headers (articles &optional newsgroup server fetch-old)
  71   (save-excursion
  72     (set-buffer nntp-server-buffer)
  73     (erase-buffer)
  74     (let* ((file nil)
  75            (number (length articles))
  76            (large (and (numberp nnmail-large-newsgroup)
  77                        (> number nnmail-large-newsgroup)))
  78            (count 0)
  79            beg article)
  80       (nnmh-possibly-change-directory newsgroup server)
  81       ;; We don't support fetching by Message-ID.
  82       (if (stringp (car articles))
  83           'headers
  84         (while articles
  85           (when (and (file-exists-p
  86                       (setq file (concat (file-name-as-directory
  87                                           nnmh-current-directory)
  88                                          (int-to-string
  89                                           (setq article (pop articles))))))
  90                      (not (file-directory-p file)))
  91             (insert (format "221 %d Article retrieved.\n" article))
  92             (setq beg (point))
  93             (nnheader-insert-head file)
  94             (goto-char beg)
  95             (if (search-forward "\n\n" nil t)
  96                 (forward-char -1)
  97               (goto-char (point-max))
  98               (insert "\n\n"))
  99             (insert ".\n")
 100             (delete-region (point) (point-max)))
 101           (setq count (1+ count))
 102
 103           (and large
 104                (zerop (% count 20))
 105                (message "nnmh: Receiving headers... %d%%"
 106                         (/ (* count 100) number))))
 107
 108         (and large (message "nnmh: Receiving headers...done"))
 109
 110         (nnheader-fold-continuation-lines)
 111         'headers))))
 112
 113 (deffoo nnmh-open-server (server &optional defs)
 114   (nnoo-change-server 'nnmh server defs)
 115   (when (not (file-exists-p nnmh-directory))
 116     (condition-case ()
 117         (make-directory nnmh-directory t)
 118       (error t)))
 119   (cond
 120    ((not (file-exists-p nnmh-directory))
 121     (nnmh-close-server)
 122     (nnheader-report 'nnmh "Couldn't create directory: %s" nnmh-directory))
 123    ((not (file-directory-p (file-truename nnmh-directory)))
 124     (nnmh-close-server)
 125     (nnheader-report 'nnmh "Not a directory: %s" nnmh-directory))
 126    (t
 127     (nnheader-report 'nnmh "Opened server %s using directory %s"
 128                      server nnmh-directory)
 129     t)))
 130
 131 (deffoo nnmh-request-article (id &optional newsgroup server buffer)
 132   (nnmh-possibly-change-directory newsgroup server)
 133   (let ((file (if (stringp id)
 134                   nil
 135                 (concat nnmh-current-directory (int-to-string id))))
 136         (nntp-server-buffer (or buffer nntp-server-buffer)))
 137     (and (stringp file)
 138          (file-exists-p file)
 139          (not (file-directory-p file))
 140          (save-excursion (nnmail-find-file file))
 141          (string-to-int (file-name-nondirectory file)))))
 142
 143 (deffoo nnmh-request-group (group &optional server dont-check)
 144   (let ((pathname (nnmail-group-pathname group nnmh-directory))
 145         dir)
 146     (cond
 147      ((not (file-directory-p pathname))
 148       (nnheader-report
 149        'nnmh "Can't select group (no such directory): %s" group))
 150      (t
 151       (setq nnmh-current-directory pathname)
 152       (and nnmh-get-new-mail
 153            nnmh-be-safe
 154            (nnmh-update-gnus-unreads group))
 155       (cond
 156        (dont-check
 157         (nnheader-report 'nnmh "Selected group %s" group)
 158         t)
 159        (t
 160         (setq dir
 161               (sort
 162                (mapcar (lambda (name) (string-to-int name))
 163                        (directory-files pathname nil "^[0-9]+$" t))
 164                '<))
 165           (cond
 166            (dir
 167             (nnheader-report 'nnmh "Selected group %s" group)
 168             (nnheader-insert
 169              "211 %d %d %d %s\n" (length dir) (car dir)
 170              (progn (while (cdr dir) (setq dir (cdr dir))) (car dir))
 171              group))
 172            (t
 173             (nnheader-report 'nnmh "Empty group %s" group)
 174             (nnheader-insert (format "211 0 1 0 %s\n" group))))))))))
 175
 176 (deffoo nnmh-request-scan (&optional group server)
 177   (nnmail-get-new-mail 'nnmh nil nnmh-directory group))
 178
 179 (deffoo nnmh-request-list (&optional server dir)
 180   (nnheader-insert "")
 181   (let ((nnmh-toplev
 182          (or dir (file-truename (file-name-as-directory nnmh-directory)))))
 183     (nnmh-request-list-1 nnmh-toplev))
 184   (setq nnmh-group-alist (nnmail-get-active))
 185   t)
 186
 187 (defvar nnmh-toplev)
 188 (defun nnmh-request-list-1 (dir)
 189   (setq dir (expand-file-name dir))
 190   ;; Recurse down all directories.
 191   (let ((dirs (and (file-readable-p dir)
 192                    (> (nth 1 (file-attributes (file-chase-links dir))) 2)
 193                    (directory-files dir t nil t)))
 194         dir)
 195     ;; Recurse down directories.
 196     (while (setq dir (pop dirs))
 197       (when (and (not (member (file-name-nondirectory dir) '("." "..")))
 198                  (file-directory-p dir)
 199                  (file-readable-p dir))
 200         (nnmh-request-list-1 dir))))
 201   ;; For each directory, generate an active file line.
 202   (unless (string= (expand-file-name nnmh-toplev) dir)
 203     (let ((files (mapcar
 204                   (lambda (name) (string-to-int name))
 205                   (directory-files dir nil "^[0-9]+$" t))))
 206       (when files
 207         (save-excursion
 208           (set-buffer nntp-server-buffer)
 209           (goto-char (point-max))
 210           (insert
 211            (format
 212             "%s %d %d y\n"
 213             (progn
 214               (string-match
 215                (file-truename (file-name-as-directory
 216                                (expand-file-name nnmh-toplev))) dir)
 217               (nnheader-replace-chars-in-string
 218                (substring dir (match-end 0)) ?/ ?.))
 219             (apply (function max) files)
 220             (apply (function min) files)))))))
 221   t)
 222
 223 (deffoo nnmh-request-newgroups (date &optional server)
 224   (nnmh-request-list server))
 225
 226 (deffoo nnmh-request-expire-articles (articles newsgroup &optional server force)
 227   (nnmh-possibly-change-directory newsgroup server)
 228   (let* ((active-articles
 229           (mapcar
 230            (function
 231             (lambda (name)
 232               (string-to-int name)))
 233            (directory-files nnmh-current-directory nil "^[0-9]+$" t)))
 234          (is-old t)
 235          article rest mod-time)
 236     (nnmail-activate 'nnmh)
 237
 238     (while (and articles is-old)
 239       (setq article (concat nnmh-current-directory
 240                             (int-to-string (car articles))))
 241       (if (setq mod-time (nth 5 (file-attributes article)))
 242           (if (and (nnmh-deletable-article-p newsgroup (car articles))
 243                    (setq is-old
 244                          (nnmail-expired-article-p newsgroup mod-time force)))
 245               (progn
 246                 (nnheader-message 5 "Deleting article %s in %s..."
 247                                   article newsgroup)
 248                 (condition-case ()
 249                     (funcall nnmail-delete-file-function article)
 250                   (file-error
 251                    (setq rest (cons (car articles) rest)))))
 252             (setq rest (cons (car articles) rest))))
 253       (setq articles (cdr articles)))
 254     (message "")
 255     (nconc rest articles)))
 256
 257 (deffoo nnmh-close-group (group &optional server)
 258   t)
 259
 260 (deffoo nnmh-request-move-article
 261   (article group server accept-form &optional last)
 262   (let ((buf (get-buffer-create " *nnmh move*"))
 263         result)
 264     (and
 265      (nnmh-deletable-article-p group article)
 266      (nnmh-request-article article group server)
 267      (save-excursion
 268        (set-buffer buf)
 269        (insert-buffer-substring nntp-server-buffer)
 270        (setq result (eval accept-form))
 271        (kill-buffer (current-buffer))
 272        result)
 273      (condition-case ()
 274          (funcall nnmail-delete-file-function
 275                   (concat nnmh-current-directory (int-to-string article)))
 276        (file-error nil)))
 277     result))
 278
 279 (deffoo nnmh-request-accept-article (group &optional server last noinsert)
 280   (nnmh-possibly-change-directory group server)
 281   (nnmail-check-syntax)
 282   (if (stringp group)
 283       (and
 284        (nnmail-activate 'nnmh)
 285        ;; We trick the choosing function into believing that only one
 286        ;; group is available.
 287        (let ((nnmail-split-methods (list (list group ""))))
 288          (car (nnmh-save-mail noinsert))))
 289     (and
 290      (nnmail-activate 'nnmh)
 291      (car (nnmh-save-mail noinsert)))))
 292
 293 (deffoo nnmh-request-replace-article (article group buffer)
 294   (nnmh-possibly-change-directory group)
 295   (save-excursion
 296     (set-buffer buffer)
 297     (nnmh-possibly-create-directory group)
 298     (condition-case ()
 299         (progn
 300           (write-region (point-min) (point-max)
 301                         (concat nnmh-current-directory (int-to-string article))
 302                         nil (if (nnheader-be-verbose 5) nil 'nomesg))
 303           t)
 304       (error nil))))
 305
 306 (deffoo nnmh-request-create-group (group &optional server)
 307   (nnmail-activate 'nnmh)
 308   (or (assoc group nnmh-group-alist)
 309       (let (active)
 310         (setq nnmh-group-alist (cons (list group (setq active (cons 1 0)))
 311                                      nnmh-group-alist))
 312         (nnmh-possibly-create-directory group)
 313         (nnmh-possibly-change-directory group server)
 314         (let ((articles (mapcar
 315                          (lambda (file)
 316                            (string-to-int file))
 317                          (directory-files
 318                           nnmh-current-directory nil "^[0-9]+$"))))
 319           (and articles
 320                (progn
 321                  (setcar active (apply 'min articles))
 322                  (setcdr active (apply 'max articles)))))))
 323   t)
 324
 325 (deffoo nnmh-request-delete-group (group &optional force server)
 326   (nnmh-possibly-change-directory group server)
 327   ;; Delete all articles in GROUP.
 328   (if (not force)
 329       ()                                ; Don't delete the articles.
 330     (let ((articles (directory-files nnmh-current-directory t "^[0-9]+$")))
 331       (while articles
 332         (and (file-writable-p (car articles))
 333              (progn
 334                (nnheader-message 5 "Deleting article %s in %s..."
 335                                  (car articles) group)
 336                (funcall nnmail-delete-file-function (car articles))))
 337         (setq articles (cdr articles))))
 338     ;; Try to delete the directory itself.
 339     (condition-case ()
 340         (delete-directory nnmh-current-directory)
 341       (error nil)))
 342   ;; Remove the group from all structures.
 343   (setq nnmh-group-alist
 344         (delq (assoc group nnmh-group-alist) nnmh-group-alist)
 345         nnmh-current-directory nil)
 346   t)
 347
 348 (deffoo nnmh-request-rename-group (group new-name &optional server)
 349   (nnmh-possibly-change-directory group server)
 350   ;; Rename directory.
 351   (and (file-writable-p nnmh-current-directory)
 352        (condition-case ()
 353            (progn
 354              (rename-file
 355               (directory-file-name nnmh-current-directory)
 356               (directory-file-name
 357                (nnmail-group-pathname new-name nnmh-directory)))
 358              t)
 359          (error nil))
 360        ;; That went ok, so we change the internal structures.
 361        (let ((entry (assoc group nnmh-group-alist)))
 362          (and entry (setcar entry new-name))
 363          (setq nnmh-current-directory nil)
 364          t)))
 365
 366 \f
 367 ;;; Internal functions.
 368
 369 (defun nnmh-possibly-change-directory (newsgroup &optional server)
 370   (when (and server
 371              (not (nnmh-server-opened server)))
 372     (nnmh-open-server server))
 373   (if newsgroup
 374       (let ((pathname (nnmail-group-pathname newsgroup nnmh-directory)))
 375         (if (file-directory-p pathname)
 376             (setq nnmh-current-directory pathname)
 377           (error "No such newsgroup: %s" newsgroup)))))
 378
 379 (defun nnmh-possibly-create-directory (group)
 380   (let (dir dirs)
 381     (setq dir (nnmail-group-pathname group nnmh-directory))
 382     (while (not (file-directory-p dir))
 383       (setq dirs (cons dir dirs))
 384       (setq dir (file-name-directory (directory-file-name dir))))
 385     (while dirs
 386       (if (make-directory (directory-file-name (car dirs)))
 387           (error "Could not create directory %s" (car dirs)))
 388       (nnheader-message 5 "Creating mail directory %s" (car dirs))
 389       (setq dirs (cdr dirs)))))
 390
 391 (defun nnmh-save-mail (&optional noinsert)
 392   "Called narrowed to an article."
 393   (let ((group-art (nreverse (nnmail-article-group 'nnmh-active-number))))
 394     (unless noinsert
 395       (nnmail-insert-lines)
 396       (nnmail-insert-xref group-art))
 397     (run-hooks 'nnmail-prepare-save-mail-hook)
 398     (run-hooks 'nnmh-prepare-save-mail-hook)
 399     (goto-char (point-min))
 400     (while (looking-at "From ")
 401       (replace-match "X-From-Line: ")
 402       (forward-line 1))
 403     ;; We save the article in all the newsgroups it belongs in.
 404     (let ((ga group-art)
 405           first)
 406       (while ga
 407         (nnmh-possibly-create-directory (caar ga))
 408         (let ((file (concat (nnmail-group-pathname
 409                              (caar ga) nnmh-directory)
 410                             (int-to-string (cdar ga)))))
 411           (if first
 412               ;; It was already saved, so we just make a hard link.
 413               (funcall nnmail-crosspost-link-function first file t)
 414             ;; Save the article.
 415             (write-region (point-min) (point-max) file nil nil)
 416             (setq first file)))
 417         (setq ga (cdr ga))))
 418     group-art))
 419
 420 (defun nnmh-active-number (group)
 421   "Compute the next article number in GROUP."
 422   (let ((active (cadr (assoc group nnmh-group-alist))))
 423     ;; The group wasn't known to nnmh, so we just create an active
 424     ;; entry for it.
 425     (or active
 426         (progn
 427           (setq active (cons 1 0))
 428           (setq nnmh-group-alist (cons (list group active) nnmh-group-alist))))
 429     (setcdr active (1+ (cdr active)))
 430     (while (file-exists-p
 431             (concat (nnmail-group-pathname group nnmh-directory)
 432                     (int-to-string (cdr active))))
 433       (setcdr active (1+ (cdr active))))
 434     (cdr active)))
 435
 436 (defun nnmh-update-gnus-unreads (group)
 437   ;; Go through the .nnmh-articles file and compare with the actual
 438   ;; articles in this folder. The articles that are "new" will be
 439   ;; marked as unread by Gnus.
 440   (let* ((dir nnmh-current-directory)
 441          (files (sort (mapcar (function (lambda (name) (string-to-int name)))
 442                               (directory-files nnmh-current-directory
 443                                                nil "^[0-9]+$" t)) '<))
 444          (nnmh-file (concat dir ".nnmh-articles"))
 445          new articles)
 446     ;; Load the .nnmh-articles file.
 447     (if (file-exists-p nnmh-file)
 448         (setq articles
 449               (let (nnmh-newsgroup-articles)
 450                 (condition-case nil (load nnmh-file nil t t) (error nil))
 451                 nnmh-newsgroup-articles)))
 452     ;; Add all new articles to the `new' list.
 453     (let ((art files))
 454       (while art
 455         (if (not (assq (car art) articles)) (setq new (cons (car art) new)))
 456         (setq art (cdr art))))
 457     ;; Remove all deleted articles.
 458     (let ((art articles))
 459       (while art
 460         (if (not (memq (caar art) files))
 461             (setq articles (delq (car art) articles)))
 462         (setq art (cdr art))))
 463     ;; Check whether the highest-numbered articles really are the ones
 464     ;; that Gnus thinks they are by looking at the time-stamps.
 465     (let ((art articles))
 466       (while (and art
 467                   (not (equal
 468                         (nth 5 (file-attributes
 469                                 (concat dir (int-to-string (caar art)))))
 470                         (cdar art))))
 471         (setq articles (delq (car art) articles))
 472         (setq new (cons (caar art) new))
 473         (setq art (cdr art))))
 474     ;; Go through all the new articles and add them, and their
 475     ;; time-stamps to the list.
 476     (let ((n new))
 477       (while n
 478         (setq articles
 479               (cons (cons
 480                      (car n)
 481                      (nth 5 (file-attributes
 482                              (concat dir (int-to-string (car n))))))
 483                     articles))
 484         (setq n (cdr n))))
 485     ;; Make Gnus mark all new articles as unread.
 486     (or (zerop (length new))
 487         (gnus-make-articles-unread
 488          (gnus-group-prefixed-name group (list 'nnmh ""))
 489          (setq new (sort new '<))))
 490     ;; Sort the article list with highest numbers first.
 491     (setq articles (sort articles (lambda (art1 art2)
 492                                     (> (car art1) (car art2)))))
 493     ;; Finally write this list back to the .nnmh-articles file.
 494     (save-excursion
 495       (set-buffer (get-buffer-create "*nnmh out*"))
 496       (insert ";; Gnus article active file for " group "\n\n")
 497       (insert "(setq nnmh-newsgroup-articles '")
 498       (insert (prin1-to-string articles) ")\n")
 499       (write-region (point-min) (point-max) nnmh-file nil 'nomesg)
 500       (kill-buffer (current-buffer)))))
 501
 502 (defun nnmh-deletable-article-p (group article)
 503   "Say whether ARTICLE in GROUP can be deleted."
 504   (let ((path (concat nnmh-current-directory (int-to-string article))))
 505     (and (file-writable-p path)
 506          (or (not nnmail-keep-last-article)
 507              (not (eq (cdr (nth 1 (assoc group nnmh-group-alist)))
 508                       article))))))
 509
 510 (provide 'nnmh)
 511
 512 ;;; nnmh.el ends here