cgit.sxemacs.org Git - gnus/blob - lisp/nnmh.el

   1 ;;; nnmh.el --- mhspool access for Gnus
   2 ;; Copyright (C) 1995 Free Software Foundation, Inc.
   3
   4 ;; Author: Lars Magne Ingebrigtsen <larsi@ifi.uio.no>
   5 ;;      Masanobu UMEDA <umerin@flab.flab.fujitsu.junet>
   6 ;; Keywords: news, mail
   7
   8 ;; This file is part of GNU Emacs.
   9
  10 ;; GNU Emacs is free software; you can redistribute it and/or modify
  11 ;; it under the terms of the GNU General Public License as published by
  12 ;; the Free Software Foundation; either version 2, or (at your option)
  13 ;; any later version.
  14
  15 ;; GNU Emacs is distributed in the hope that it will be useful,
  16 ;; but WITHOUT ANY WARRANTY; without even the implied warranty of
  17 ;; MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.  See the
  18 ;; GNU General Public License for more details.
  19
  20 ;; You should have received a copy of the GNU General Public License
  21 ;; along with GNU Emacs; see the file COPYING.  If not, write to
  22 ;; the Free Software Foundation, 675 Mass Ave, Cambridge, MA 02139, USA.
  23
  24 ;;; Commentary:
  25
  26 ;; Based on nnspool.el by Masanobu UMEDA <umerin@flab.flab.fujitsu.junet>.
  27 ;; For an overview of what the interface functions do, please see the
  28 ;; Gnus sources.
  29
  30 ;;; Code:
  31
  32 (require 'nnheader)
  33 (require 'rmail)
  34 (require 'nnmail)
  35 (require 'gnus)
  36
  37 (defvar nnmh-directory "~/Mail/"
  38   "*Mail spool directory.")
  39
  40 (defvar nnmh-get-new-mail t
  41   "*If non-nil, nnmh will check the incoming mail file and split the mail.")
  42
  43 (defvar nnmh-prepare-save-mail-hook nil
  44   "*Hook run narrowed to an article before saving.")
  45
  46 (defvar nnmh-be-safe nil
  47   "*If non-nil, nnmh will check all articles to make sure whether they are new or not.")
  48
  49 \f
  50
  51 (defconst nnmh-version "nnmh 0.1"
  52   "nnmh version.")
  53
  54 (defvar nnmh-current-directory nil
  55   "Current news group directory.")
  56
  57 (defvar nnmh-status-string "")
  58 (defvar nnmh-group-alist nil)
  59
  60 \f
  61
  62 (defvar nnmh-current-server nil)
  63 (defvar nnmh-server-alist nil)
  64 (defvar nnmh-server-variables
  65   (list
  66    (list 'nnmh-directory nnmh-directory)
  67    (list 'nnmh-get-new-mail nnmh-get-new-mail)
  68    '(nnmh-current-directory nil)
  69    '(nnmh-status-string "")
  70    '(nnmh-group-alist)))
  71
  72 \f
  73
  74 ;;; Interface functions.
  75
  76 (defun nnmh-retrieve-headers (sequence &optional newsgroup server)
  77   (save-excursion
  78     (set-buffer nntp-server-buffer)
  79     (erase-buffer)
  80     (let* ((file nil)
  81            (number (length sequence))
  82            (large (and (numberp nnmail-large-newsgroup)
  83                        (> number nnmail-large-newsgroup)))
  84            (count 0)
  85            beg article)
  86       (nnmh-possibly-change-directory newsgroup)
  87       (if (stringp (car sequence))
  88           'headers
  89         (while sequence
  90           (setq article (car sequence))
  91           (setq file
  92                 (concat nnmh-current-directory (int-to-string article)))
  93           (if (and (file-exists-p file)
  94                    (not (file-directory-p file)))
  95               (progn
  96                 (insert (format "221 %d Article retrieved.\n" article))
  97                 (setq beg (point))
  98                 (nnheader-insert-head file)
  99                 (goto-char beg)
 100                 (if (search-forward "\n\n" nil t)
 101                     (forward-char -1)
 102                   (goto-char (point-max))
 103                   (insert "\n\n"))
 104                 (insert ".\n")
 105                 (delete-region (point) (point-max))))
 106           (setq sequence (cdr sequence))
 107           (setq count (1+ count))
 108
 109           (and large
 110                (zerop (% count 20))
 111                (message "nnmh: Receiving headers... %d%%"
 112                         (/ (* count 100) number))))
 113
 114         (and large (message "nnmh: Receiving headers...done"))
 115
 116         ;; Fold continuation lines.
 117         (goto-char (point-min))
 118         (while (re-search-forward "\\(\r?\n[ \t]+\\)+" nil t)
 119           (replace-match " " t t))
 120         'headers))))
 121
 122 (defun nnmh-open-server (server &optional defs)
 123   (nnheader-init-server-buffer)
 124   (if (equal server nnmh-current-server)
 125       t
 126     (if nnmh-current-server
 127         (setq nnmh-server-alist
 128               (cons (list nnmh-current-server
 129                           (nnheader-save-variables nnmh-server-variables))
 130                     nnmh-server-alist)))
 131     (let ((state (assoc server nnmh-server-alist)))
 132       (if state
 133           (progn
 134             (nnheader-restore-variables (nth 1 state))
 135             (setq nnmh-server-alist (delq state nnmh-server-alist)))
 136         (nnheader-set-init-variables nnmh-server-variables defs)))
 137     (setq nnmh-current-server server)))
 138
 139 (defun nnmh-close-server (&optional server)
 140   t)
 141
 142 (defun nnmh-server-opened (&optional server)
 143   (and (equal server nnmh-current-server)
 144        nntp-server-buffer
 145        (buffer-name nntp-server-buffer)))
 146
 147 (defun nnmh-status-message (&optional server)
 148   nnmh-status-string)
 149
 150 (defun nnmh-request-article (id &optional newsgroup server buffer)
 151   (nnmh-possibly-change-directory newsgroup)
 152   (let ((file (if (stringp id)
 153                   nil
 154                 (concat nnmh-current-directory (int-to-string id))))
 155         (nntp-server-buffer (or buffer nntp-server-buffer)))
 156     (and (stringp file)
 157          (file-exists-p file)
 158          (not (file-directory-p file))
 159          (save-excursion (nnmail-find-file file)))))
 160
 161 (defun nnmh-request-group (group &optional server dont-check)
 162   (and nnmh-get-new-mail (or dont-check (nnmh-get-new-mail group)))
 163   (let ((pathname (nnmh-article-pathname group nnmh-directory))
 164         dir)
 165     (if (file-directory-p pathname)
 166         (progn
 167           (setq nnmh-current-directory pathname)
 168           (and nnmh-get-new-mail
 169                nnmh-be-safe
 170                (nnmh-update-gnus-unreads group))
 171           (or dont-check
 172               (progn
 173                 (setq dir
 174                       (sort
 175                        (mapcar
 176                         (function
 177                          (lambda (name)
 178                            (string-to-int name)))
 179                         (directory-files pathname nil "^[0-9]+$" t))
 180                        '<))
 181                 (save-excursion
 182                   (set-buffer nntp-server-buffer)
 183                   (erase-buffer)
 184                   (if dir
 185                       (insert (format "211 %d %d %d %s\n" (length dir)
 186                                       (car dir)
 187                                       (progn (while (cdr dir)
 188                                                (setq dir (cdr dir)))
 189                                              (car dir))
 190                                       group))
 191                     (insert (format "211 0 1 0 %s\n" group))))))
 192           t))))
 193
 194 (defun nnmh-request-list (&optional server dir)
 195   (or dir
 196       (save-excursion
 197         (set-buffer nntp-server-buffer)
 198         (erase-buffer)
 199         (setq dir (file-name-as-directory nnmh-directory))))
 200   (setq dir (expand-file-name dir))
 201   ;; Recurse down all directories.
 202   (let ((dirs (and (file-readable-p dir)
 203                    (> (nth 1 (file-attributes (file-chase-links dir))) 2)
 204                    (directory-files dir t nil t))))
 205     (while dirs
 206       (if (and (not (string-match "/\\.\\.?$" (car dirs)))
 207                (file-directory-p (car dirs))
 208                (file-readable-p (car dirs)))
 209           (nnmh-request-list nil (car dirs)))
 210       (setq dirs (cdr dirs))))
 211   ;; For each directory, generate an active file line.
 212   (if (not (string= (expand-file-name nnmh-directory) dir))
 213       (let ((files (mapcar
 214                     (lambda (name) (string-to-int name))
 215                     (directory-files dir nil "^[0-9]+$" t))))
 216         (if (null files)
 217             ()
 218           (save-excursion
 219             (set-buffer nntp-server-buffer)
 220             (goto-char (point-max))
 221             (insert
 222              (format
 223               "%s %d %d y\n"
 224               (progn
 225                 (string-match (file-name-as-directory
 226                                (expand-file-name nnmh-directory)) dir)
 227                 (nnmail-replace-chars-in-string
 228                  (substring dir (match-end 0)) ?/ ?.))
 229               (apply (function max) files)
 230               (apply (function min) files)))))))
 231   (setq nnmh-group-alist (nnmail-get-active))
 232   (and server nnmh-get-new-mail (nnmh-get-new-mail))
 233   t)
 234
 235 (defun nnmh-request-newgroups (date &optional server)
 236   (nnmh-request-list server))
 237
 238 (defun nnmh-request-post (&optional server)
 239   (mail-send-and-exit nil))
 240
 241 (defalias 'nnmh-request-post-buffer 'nnmail-request-post-buffer)
 242
 243 (defun nnmh-request-expire-articles (articles newsgroup &optional server force)
 244   (nnmh-possibly-change-directory newsgroup)
 245   (let* ((days (or (and nnmail-expiry-wait-function
 246                         (funcall nnmail-expiry-wait-function newsgroup))
 247                    nnmail-expiry-wait))
 248          (active-articles
 249           (mapcar
 250            (function
 251             (lambda (name)
 252               (string-to-int name)))
 253            (directory-files nnmh-current-directory nil "^[0-9]+$" t)))
 254          (max-article (and active-articles (apply 'max active-articles)))
 255          (is-old t)
 256          article rest mod-time)
 257     (while (and articles is-old)
 258       (setq article (concat nnmh-current-directory
 259                             (int-to-string (car articles))))
 260       (if (setq mod-time (nth 5 (file-attributes article)))
 261           (if (and (or (not nnmail-keep-last-article)
 262                        (not max-article)
 263                        (not (= (car articles) max-article)))
 264                    (not (equal mod-time '(0 0)))
 265                    (or force
 266                        (setq is-old
 267                              (> (nnmail-days-between
 268                                  (current-time-string)
 269                                  (current-time-string mod-time))
 270                                 days))))
 271               (progn
 272                 (and gnus-verbose-backends (message "Deleting %s..." article))
 273                 (condition-case ()
 274                     (delete-file article)
 275                   (file-error
 276                    (setq rest (cons (car articles) rest)))))
 277             (setq rest (cons (car articles) rest))))
 278       (setq articles (cdr articles)))
 279     (message "")
 280     (nconc rest articles)))
 281
 282 (defun nnmh-close-group (group &optional server)
 283   t)
 284
 285 (defun nnmh-request-move-article
 286   (article group server accept-form &optional last)
 287   (let ((buf (get-buffer-create " *nnmh move*"))
 288         result)
 289     (and
 290      (nnmh-request-article article group server)
 291      (save-excursion
 292        (set-buffer buf)
 293        (insert-buffer-substring nntp-server-buffer)
 294        (setq result (eval accept-form))
 295        (kill-buffer (current-buffer))
 296        result)
 297      (condition-case ()
 298          (delete-file (concat nnmh-current-directory
 299                               (int-to-string article)))
 300        (file-error nil)))
 301  result))
 302
 303 (defun nnmh-request-accept-article (group &optional last)
 304   (if (stringp group)
 305       (and
 306        (nnmh-request-list)
 307        (setq nnmh-group-alist (nnmail-get-active))
 308        ;; We trick the choosing function into believing that only one
 309        ;; group is availiable.
 310        (let ((nnmail-split-methods (list (list group ""))))
 311          (car (nnmh-save-mail))))
 312     (and
 313      (nnmh-request-list)
 314      (setq nnmh-group-alist (nnmail-get-active))
 315      (car (nnmh-save-mail)))))
 316
 317 (defun nnmh-request-replace-article (article group buffer)
 318   (nnmh-possibly-change-directory group)
 319   (save-excursion
 320     (set-buffer buffer)
 321     (nnmh-possibly-create-directory group)
 322     (condition-case ()
 323         (progn
 324           (write-region (point-min) (point-max)
 325                         (concat nnmh-current-directory (int-to-string article))
 326                         nil (if gnus-verbose-backends nil 'nomesg))
 327           t)
 328       (error nil))))
 329
 330 \f
 331 ;;; Internal functions.
 332
 333 (defun nnmh-possibly-change-directory (newsgroup)
 334   (if newsgroup
 335       (let ((pathname (nnmh-article-pathname newsgroup nnmh-directory)))
 336         (if (file-directory-p pathname)
 337             (setq nnmh-current-directory pathname)
 338           (error "No such newsgroup: %s" newsgroup)))))
 339
 340 (defun nnmh-possibly-create-directory (group)
 341   (let (dir dirs)
 342     (setq dir (nnmail-article-pathname group nnmh-directory))
 343     (while (not (file-directory-p dir))
 344       (setq dirs (cons dir dirs))
 345       (setq dir (file-name-directory (directory-file-name dir))))
 346     (while dirs
 347       (if (make-directory (directory-file-name (car dirs)))
 348           (error "Could not create directory %s" (car dirs)))
 349       (and gnus-verbose-backends
 350            (message "Creating mail directory %s" (car dirs)))
 351       (setq dirs (cdr dirs)))))
 352
 353 (defun nnmh-save-mail ()
 354   "Called narrowed to an article."
 355   (let ((group-art (nreverse (nnmail-article-group 'nnmh-active-number))))
 356     (nnmail-insert-lines)
 357     (nnmail-insert-xref group-art)
 358     (run-hooks 'nnmh-prepare-save-mail-hook)
 359     (goto-char (point-min))
 360     (while (looking-at "From ")
 361       (replace-match "X-From-Line: ")
 362       (forward-line 1))
 363     ;; We save the article in all the newsgroups it belongs in.
 364     (let ((ga group-art)
 365           first)
 366       (while ga
 367         (nnmh-possibly-create-directory (car (car ga)))
 368         (let ((file (concat (nnmh-article-pathname
 369                              (car (car ga)) nnmh-directory)
 370                             (int-to-string (cdr (car ga))))))
 371           (if first
 372               ;; It was already saved, so we just make a hard link.
 373               (add-name-to-file first file t)
 374             ;; Save the article.
 375             (write-region (point-min) (point-max) file nil nil)
 376             (setq first file)))
 377         (setq ga (cdr ga))))
 378     group-art))
 379
 380 (defun nnmh-active-number (group)
 381   "Compute the next article number in GROUP."
 382   (let ((active (car (cdr (assoc group nnmh-group-alist)))))
 383     (setcdr active (1+ (cdr active)))
 384     (while (file-exists-p
 385             (concat (nnmh-article-pathname group nnmh-directory)
 386                     (int-to-string (cdr active))))
 387       (setcdr active (1+ (cdr active))))
 388     (cdr active)))
 389
 390 (defun nnmh-article-pathname (group mail-dir)
 391   "Make pathname for GROUP."
 392   (let ((mail-dir (file-name-as-directory (expand-file-name mail-dir))))
 393     (if (file-directory-p (concat mail-dir group))
 394         (concat mail-dir group "/")
 395       (concat mail-dir (nnmail-replace-chars-in-string group ?. ?/) "/"))))
 396
 397 (defun nnmh-get-new-mail (&optional group)
 398   "Read new incoming mail."
 399   (let* ((spools (nnmail-get-spool-files group))
 400          (group-in group)
 401          incoming incomings)
 402     (if (or (not nnmh-get-new-mail) (not nnmail-spool-file))
 403         ()
 404       ;; We first activate all the groups.
 405       (or nnmh-group-alist
 406           (nnmh-request-list))
 407       ;; The we go through all the existing spool files and split the
 408       ;; mail from each.
 409       (while spools
 410         (and
 411          (file-exists-p (car spools))
 412          (> (nth 7 (file-attributes (car spools))) 0)
 413          (progn
 414            (and gnus-verbose-backends
 415                 (message "nnmh: Reading incoming mail..."))
 416            (setq incoming
 417                  (nnmail-move-inbox
 418                   (car spools) (concat (file-name-as-directory nnmh-directory)
 419                                        "Incoming")))
 420            (setq incomings (cons incoming incomings))
 421            (setq group (nnmail-get-split-group (car spools) group-in))
 422            (nnmail-split-incoming incoming 'nnmh-save-mail nil group)))
 423         (setq spools (cdr spools)))
 424       ;; If we did indeed read any incoming spools, we save all info.
 425       (if incoming
 426           (message "nnmh: Reading incoming mail...done"))
 427       (while incomings
 428         (and nnmail-delete-incoming
 429              (file-writable-p incoming)
 430              (delete-file incoming))
 431         (setq incomings (cdr incomings))))))
 432
 433
 434 (defun nnmh-update-gnus-unreads (group)
 435   ;; Go through the .nnmh-articles file and compare with the actual
 436   ;; articles in this folder. The articles that are "new" will be
 437   ;; marked as unread by Gnus.
 438   (let* ((dir nnmh-current-directory)
 439          (files (sort (mapcar (function (lambda (name) (string-to-int name)))
 440                               (directory-files nnmh-current-directory
 441                                                nil "^[0-9]+$" t)) '<))
 442          (nnmh-file (concat dir ".nnmh-articles"))
 443          new articles)
 444     ;; Load the .nnmh-articles file.
 445     (if (file-exists-p nnmh-file)
 446         (setq articles
 447               (let (nnmh-newsgroup-articles)
 448                 (condition-case nil (load nnmh-file nil t t) (error nil))
 449                 nnmh-newsgroup-articles)))
 450     ;; Add all new articles to the `new' list.
 451     (let ((art files))
 452       (while art
 453         (if (not (assq (car art) articles)) (setq new (cons (car art) new)))
 454         (setq art (cdr art))))
 455     ;; Remove all deleted articles.
 456     (let ((art articles))
 457       (while art
 458         (if (not (memq (car (car art)) files))
 459             (setq articles (delq (car art) articles)))
 460         (setq art (cdr art))))
 461     ;; Check whether the highest-numbered articles really are the ones
 462     ;; that Gnus thinks they are by looking at the time-stamps.
 463     (let ((art articles))
 464       (while (and art
 465                   (not (equal
 466                         (nth 5 (file-attributes
 467                                 (concat dir (int-to-string (car (car art))))))
 468                         (cdr (car art)))))
 469         (setq articles (delq (car art) articles))
 470         (setq new (cons (car (car art)) new))
 471         (setq art (cdr art))))
 472     ;; Go through all the new articles and add them, and their
 473     ;; time-stamps to the list.
 474     (let ((n new))
 475       (while n
 476         (setq articles
 477               (cons (cons
 478                      (car n)
 479                      (nth 5 (file-attributes
 480                              (concat dir (int-to-string (car n))))))
 481                     articles))
 482         (setq n (cdr n))))
 483     ;; Make Gnus mark all new articles as unread.
 484     (or (zerop (length new))
 485         (gnus-make-articles-unread
 486          (gnus-group-prefixed-name group (list 'nnmh ""))
 487          (setq new (sort new '<))))
 488     ;; Sort the article list with highest numbers first.
 489     (setq articles (sort articles (lambda (art1 art2)
 490                                     (> (car art1) (car art2)))))
 491     ;; Finally write this list back to the .nnmh-articles file.
 492     (save-excursion
 493       (set-buffer (get-buffer-create "*nnmh out*"))
 494       (insert ";; Gnus article active file for " group "\n\n")
 495       (insert "(setq nnmh-newsgroup-articles '")
 496       (insert (prin1-to-string articles) ")\n")
 497       (write-region (point-min) (point-max) nnmh-file nil 'nomesg)
 498       (kill-buffer (current-buffer)))))
 499
 500 (provide 'nnmh)
 501
 502 ;;; nnmh.el ends here