cgit.sxemacs.org Git - gnus/blob - lisp/nnmbox.el

   1 ;;; nnmbox.el --- mail mbox access for Gnus
   2 ;; Copyright (C) 1995,96,97 Free Software Foundation, Inc.
   3
   4 ;; Author: Lars Magne Ingebrigtsen <larsi@ifi.uio.no>
   5 ;;      Masanobu UMEDA <umerin@flab.flab.fujitsu.junet>
   6 ;; Keywords: news, mail
   7
   8 ;; This file is part of GNU Emacs.
   9
  10 ;; GNU Emacs is free software; you can redistribute it and/or modify
  11 ;; it under the terms of the GNU General Public License as published by
  12 ;; the Free Software Foundation; either version 2, or (at your option)
  13 ;; any later version.
  14
  15 ;; GNU Emacs is distributed in the hope that it will be useful,
  16 ;; but WITHOUT ANY WARRANTY; without even the implied warranty of
  17 ;; MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.  See the
  18 ;; GNU General Public License for more details.
  19
  20 ;; You should have received a copy of the GNU General Public License
  21 ;; along with GNU Emacs; see the file COPYING.  If not, write to the
  22 ;; Free Software Foundation, Inc., 59 Temple Place - Suite 330,
  23 ;; Boston, MA 02111-1307, USA.
  24
  25 ;;; Commentary:
  26
  27 ;; For an overview of what the interface functions do, please see the
  28 ;; Gnus sources.
  29
  30 ;;; Code:
  31
  32 (require 'nnheader)
  33 (require 'message)
  34 (require 'nnmail)
  35 (require 'nnoo)
  36 (eval-when-compile (require 'cl))
  37
  38 (nnoo-declare nnmbox)
  39
  40 (defvoo nnmbox-mbox-file (expand-file-name "~/mbox")
  41   "The name of the mail box file in the user's home directory.")
  42
  43 (defvoo nnmbox-active-file (expand-file-name "~/.mbox-active")
  44   "The name of the active file for the mail box.")
  45
  46 (defvoo nnmbox-get-new-mail t
  47   "If non-nil, nnmbox will check the incoming mail file and split the mail.")
  48
  49 (defvoo nnmbox-prepare-save-mail-hook nil
  50   "Hook run narrowed to an article before saving.")
  51
  52 \f
  53
  54 (defconst nnmbox-version "nnmbox 1.0"
  55   "nnmbox version.")
  56
  57 (defvoo nnmbox-current-group nil
  58   "Current nnmbox news group directory.")
  59
  60 (defconst nnmbox-mbox-buffer nil)
  61
  62 (defvoo nnmbox-status-string "")
  63
  64 (defvoo nnmbox-group-alist nil)
  65 (defvoo nnmbox-active-timestamp nil)
  66
  67 \f
  68
  69 ;;; Interface functions
  70
  71 (nnoo-define-basics nnmbox)
  72
  73 (deffoo nnmbox-retrieve-headers (sequence &optional newsgroup server fetch-old)
  74   (save-excursion
  75     (set-buffer nntp-server-buffer)
  76     (erase-buffer)
  77     (let ((number (length sequence))
  78           (count 0)
  79           article art-string start stop)
  80       (nnmbox-possibly-change-newsgroup newsgroup server)
  81       (while sequence
  82         (setq article (car sequence))
  83         (setq art-string (nnmbox-article-string article))
  84         (set-buffer nnmbox-mbox-buffer)
  85         (when (or (search-forward art-string nil t)
  86                   (progn (goto-char (point-min))
  87                          (search-forward art-string nil t)))
  88           (setq start
  89                 (save-excursion
  90                   (re-search-backward
  91                    (concat "^" message-unix-mail-delimiter) nil t)
  92                   (point)))
  93           (search-forward "\n\n" nil t)
  94           (setq stop (1- (point)))
  95           (set-buffer nntp-server-buffer)
  96           (insert (format "221 %d Article retrieved.\n" article))
  97           (insert-buffer-substring nnmbox-mbox-buffer start stop)
  98           (goto-char (point-max))
  99           (insert ".\n"))
 100         (setq sequence (cdr sequence))
 101         (setq count (1+ count))
 102         (and (numberp nnmail-large-newsgroup)
 103              (> number nnmail-large-newsgroup)
 104              (zerop (% count 20))
 105              (nnheader-message 5 "nnmbox: Receiving headers... %d%%"
 106                                (/ (* count 100) number))))
 107
 108       (and (numberp nnmail-large-newsgroup)
 109            (> number nnmail-large-newsgroup)
 110            (nnheader-message 5 "nnmbox: Receiving headers...done"))
 111
 112       (set-buffer nntp-server-buffer)
 113       (nnheader-fold-continuation-lines)
 114       'headers)))
 115
 116 (deffoo nnmbox-open-server (server &optional defs)
 117   (nnoo-change-server 'nnmbox server defs)
 118   (nnmbox-create-mbox)
 119   (cond
 120    ((not (file-exists-p nnmbox-mbox-file))
 121     (nnmbox-close-server)
 122     (nnheader-report 'nnmbox "No such file: %s" nnmbox-mbox-file))
 123    ((file-directory-p nnmbox-mbox-file)
 124     (nnmbox-close-server)
 125     (nnheader-report 'nnmbox "Not a regular file: %s" nnmbox-mbox-file))
 126    (t
 127     (nnheader-report 'nnmbox "Opened server %s using mbox %s" server
 128                      nnmbox-mbox-file)
 129     t)))
 130
 131 (deffoo nnmbox-close-server (&optional server)
 132   (when (and nnmbox-mbox-buffer
 133              (buffer-name nnmbox-mbox-buffer))
 134     (kill-buffer nnmbox-mbox-buffer))
 135   (nnoo-close-server 'nnmbox server)
 136   t)
 137
 138 (deffoo nnmbox-server-opened (&optional server)
 139   (and (nnoo-current-server-p 'nnmbox server)
 140        nnmbox-mbox-buffer
 141        (buffer-name nnmbox-mbox-buffer)
 142        nntp-server-buffer
 143        (buffer-name nntp-server-buffer)))
 144
 145 (deffoo nnmbox-request-article (article &optional newsgroup server buffer)
 146   (nnmbox-possibly-change-newsgroup newsgroup server)
 147   (save-excursion
 148     (set-buffer nnmbox-mbox-buffer)
 149     (goto-char (point-min))
 150     (when (search-forward (nnmbox-article-string article) nil t)
 151       (let (start stop)
 152         (re-search-backward (concat "^" message-unix-mail-delimiter) nil t)
 153         (setq start (point))
 154         (forward-line 1)
 155         (or (and (re-search-forward
 156                   (concat "^" message-unix-mail-delimiter) nil t)
 157                  (forward-line -1))
 158             (goto-char (point-max)))
 159         (setq stop (point))
 160         (let ((nntp-server-buffer (or buffer nntp-server-buffer)))
 161           (set-buffer nntp-server-buffer)
 162           (erase-buffer)
 163           (insert-buffer-substring nnmbox-mbox-buffer start stop)
 164           (goto-char (point-min))
 165           (while (looking-at "From ")
 166             (delete-char 5)
 167             (insert "X-From-Line: ")
 168             (forward-line 1))
 169           (if (numberp article)
 170               (cons nnmbox-current-group article)
 171             (nnmbox-article-group-number)))))))
 172
 173 (deffoo nnmbox-request-group (group &optional server dont-check)
 174   (let ((active (cadr (assoc group nnmbox-group-alist))))
 175     (cond
 176      ((or (null active)
 177           (null (nnmbox-possibly-change-newsgroup group server)))
 178       (nnheader-report 'nnmbox "No such group: %s" group))
 179      (dont-check
 180       (nnheader-report 'nnmbox "Selected group %s" group)
 181       (nnheader-insert ""))
 182      (t
 183       (nnheader-report 'nnmbox "Selected group %s" group)
 184       (nnheader-insert "211 %d %d %d %s\n"
 185                        (1+ (- (cdr active) (car active)))
 186                        (car active) (cdr active) group)))))
 187
 188 (deffoo nnmbox-request-scan (&optional group server)
 189   (nnmbox-possibly-change-newsgroup group server)
 190   (nnmbox-read-mbox)
 191   (nnmail-get-new-mail
 192    'nnmbox
 193    (lambda ()
 194      (save-excursion
 195        (set-buffer nnmbox-mbox-buffer)
 196        (save-buffer)))
 197    (file-name-directory nnmbox-mbox-file)
 198    group
 199    (lambda ()
 200      (save-excursion
 201        (let ((in-buf (current-buffer)))
 202          (set-buffer nnmbox-mbox-buffer)
 203          (goto-char (point-max))
 204          (insert-buffer-substring in-buf)))
 205      (nnmail-save-active nnmbox-group-alist nnmbox-active-file))))
 206
 207 (deffoo nnmbox-close-group (group &optional server)
 208   t)
 209
 210 (deffoo nnmbox-request-list (&optional server)
 211   (save-excursion
 212     (nnmail-find-file nnmbox-active-file)
 213     (setq nnmbox-group-alist (nnmail-get-active))
 214     t))
 215
 216 (deffoo nnmbox-request-newgroups (date &optional server)
 217   (nnmbox-request-list server))
 218
 219 (deffoo nnmbox-request-list-newsgroups (&optional server)
 220   (nnheader-report 'nnmbox "LIST NEWSGROUPS is not implemented."))
 221
 222 (deffoo nnmbox-request-expire-articles
 223   (articles newsgroup &optional server force)
 224   (nnmbox-possibly-change-newsgroup newsgroup server)
 225   (let* ((is-old t)
 226          rest)
 227     (nnmail-activate 'nnmbox)
 228
 229     (save-excursion
 230       (set-buffer nnmbox-mbox-buffer)
 231       (while (and articles is-old)
 232         (goto-char (point-min))
 233         (when (search-forward (nnmbox-article-string (car articles)) nil t)
 234           (if (setq is-old
 235                     (nnmail-expired-article-p
 236                      newsgroup
 237                      (buffer-substring
 238                       (point) (progn (end-of-line) (point))) force))
 239               (progn
 240                 (nnheader-message 5 "Deleting article %d in %s..."
 241                                   (car articles) newsgroup)
 242                 (nnmbox-delete-mail))
 243             (push (car articles) rest)))
 244         (setq articles (cdr articles)))
 245       (save-buffer)
 246       ;; Find the lowest active article in this group.
 247       (let ((active (nth 1 (assoc newsgroup nnmbox-group-alist))))
 248         (goto-char (point-min))
 249         (while (and (not (search-forward
 250                           (nnmbox-article-string (car active)) nil t))
 251                     (<= (car active) (cdr active)))
 252           (setcar active (1+ (car active)))
 253           (goto-char (point-min))))
 254       (nnmail-save-active nnmbox-group-alist nnmbox-active-file)
 255       (nconc rest articles))))
 256
 257 (deffoo nnmbox-request-move-article
 258   (article group server accept-form &optional last)
 259   (let ((buf (get-buffer-create " *nnmbox move*"))
 260         result)
 261     (and
 262      (nnmbox-request-article article group server)
 263      (save-excursion
 264        (set-buffer buf)
 265        (buffer-disable-undo (current-buffer))
 266        (erase-buffer)
 267        (insert-buffer-substring nntp-server-buffer)
 268        (goto-char (point-min))
 269        (while (re-search-forward
 270                "^X-Gnus-Newsgroup:"
 271                (save-excursion (search-forward "\n\n" nil t) (point)) t)
 272          (delete-region (progn (beginning-of-line) (point))
 273                         (progn (forward-line 1) (point))))
 274        (setq result (eval accept-form))
 275        (kill-buffer buf)
 276        result)
 277      (save-excursion
 278        (nnmbox-possibly-change-newsgroup group server)
 279        (set-buffer nnmbox-mbox-buffer)
 280        (goto-char (point-min))
 281        (when (search-forward (nnmbox-article-string article) nil t)
 282          (nnmbox-delete-mail))
 283        (and last (save-buffer))))
 284     result))
 285
 286 (deffoo nnmbox-request-accept-article (group &optional server last)
 287   (nnmbox-possibly-change-newsgroup group server)
 288   (nnmail-check-syntax)
 289   (let ((buf (current-buffer))
 290         result)
 291     (goto-char (point-min))
 292     ;; The From line may have been quoted by movemail.
 293     (when (looking-at (concat ">" message-unix-mail-delimiter))
 294       (delete-char 1))
 295     (if (looking-at "X-From-Line: ")
 296         (replace-match "From ")
 297       (insert "From nobody " (current-time-string) "\n"))
 298     (and
 299      (nnmail-activate 'nnmbox)
 300      (progn
 301        (set-buffer buf)
 302        (goto-char (point-min))
 303        (search-forward "\n\n" nil t)
 304        (forward-line -1)
 305        (while (re-search-backward "^X-Gnus-Newsgroup: " nil t)
 306          (delete-region (point) (progn (forward-line 1) (point))))
 307        (when nnmail-cache-accepted-message-ids
 308          (nnmail-cache-insert (nnmail-fetch-field "message-id")))
 309        (setq result (if (stringp group)
 310                         (list (cons group (nnmbox-active-number group)))
 311                       (nnmail-article-group 'nnmbox-active-number)))
 312        (if (null result)
 313            (setq result 'junk)
 314          (setq result (car (nnmbox-save-mail result)))))
 315      (save-excursion
 316        (set-buffer nnmbox-mbox-buffer)
 317        (goto-char (point-max))
 318        (insert-buffer-substring buf)
 319        (when last
 320          (when nnmail-cache-accepted-message-ids
 321            (nnmail-cache-close))
 322          (nnmail-save-active nnmbox-group-alist nnmbox-active-file)
 323          (save-buffer))))
 324     result))
 325
 326 (deffoo nnmbox-request-replace-article (article group buffer)
 327   (nnmbox-possibly-change-newsgroup group)
 328   (save-excursion
 329     (set-buffer nnmbox-mbox-buffer)
 330     (goto-char (point-min))
 331     (if (not (search-forward (nnmbox-article-string article) nil t))
 332         nil
 333       (nnmbox-delete-mail t t)
 334       (insert-buffer-substring buffer)
 335       (save-buffer)
 336       t)))
 337
 338 (deffoo nnmbox-request-delete-group (group &optional force server)
 339   (nnmbox-possibly-change-newsgroup group server)
 340   ;; Delete all articles in GROUP.
 341   (if (not force)
 342       ()                                ; Don't delete the articles.
 343     (save-excursion
 344       (set-buffer nnmbox-mbox-buffer)
 345       (goto-char (point-min))
 346       ;; Delete all articles in this group.
 347       (let ((ident (concat "\nX-Gnus-Newsgroup: " nnmbox-current-group ":"))
 348             found)
 349         (while (search-forward ident nil t)
 350           (setq found t)
 351           (nnmbox-delete-mail))
 352         (when found
 353           (save-buffer)))))
 354   ;; Remove the group from all structures.
 355   (setq nnmbox-group-alist
 356         (delq (assoc group nnmbox-group-alist) nnmbox-group-alist)
 357         nnmbox-current-group nil)
 358   ;; Save the active file.
 359   (nnmail-save-active nnmbox-group-alist nnmbox-active-file)
 360   t)
 361
 362 (deffoo nnmbox-request-rename-group (group new-name &optional server)
 363   (nnmbox-possibly-change-newsgroup group server)
 364   (save-excursion
 365     (set-buffer nnmbox-mbox-buffer)
 366     (goto-char (point-min))
 367     (let ((ident (concat "\nX-Gnus-Newsgroup: " nnmbox-current-group ":"))
 368           (new-ident (concat "\nX-Gnus-Newsgroup: " new-name ":"))
 369           found)
 370       (while (search-forward ident nil t)
 371         (replace-match new-ident t t)
 372         (setq found t))
 373       (when found
 374         (save-buffer))))
 375   (let ((entry (assoc group nnmbox-group-alist)))
 376     (when entry
 377       (setcar entry new-name))
 378     (setq nnmbox-current-group nil)
 379     ;; Save the new group alist.
 380     (nnmail-save-active nnmbox-group-alist nnmbox-active-file)
 381     t))
 382
 383 \f
 384 ;;; Internal functions.
 385
 386 ;; If FORCE, delete article no matter how many X-Gnus-Newsgroup
 387 ;; headers there are.  If LEAVE-DELIM, don't delete the Unix mbox
 388 ;; delimiter line.
 389 (defun nnmbox-delete-mail (&optional force leave-delim)
 390   ;; Delete the current X-Gnus-Newsgroup line.
 391   (or force
 392       (delete-region
 393        (progn (beginning-of-line) (point))
 394        (progn (forward-line 1) (point))))
 395   ;; Beginning of the article.
 396   (save-excursion
 397     (save-restriction
 398       (narrow-to-region
 399        (save-excursion
 400          (re-search-backward (concat "^" message-unix-mail-delimiter) nil t)
 401          (if leave-delim (progn (forward-line 1) (point))
 402            (match-beginning 0)))
 403        (progn
 404          (forward-line 1)
 405          (or (and (re-search-forward (concat "^" message-unix-mail-delimiter)
 406                                      nil t)
 407                   (if (and (not (bobp)) leave-delim)
 408                       (progn (forward-line -2) (point))
 409                     (match-beginning 0)))
 410              (point-max))))
 411       (goto-char (point-min))
 412       ;; Only delete the article if no other groups owns it as well.
 413       (when (or force (not (re-search-forward "^X-Gnus-Newsgroup: " nil t)))
 414         (delete-region (point-min) (point-max))))))
 415
 416 (defun nnmbox-possibly-change-newsgroup (newsgroup &optional server)
 417   (when (and server
 418              (not (nnmbox-server-opened server)))
 419     (nnmbox-open-server server))
 420   (when (or (not nnmbox-mbox-buffer)
 421             (not (buffer-name nnmbox-mbox-buffer)))
 422     (save-excursion
 423       (set-buffer (setq nnmbox-mbox-buffer
 424                         (nnheader-find-file-noselect
 425                          nnmbox-mbox-file nil 'raw)))
 426       (buffer-disable-undo (current-buffer))))
 427   (when (not nnmbox-group-alist)
 428     (nnmail-activate 'nnmbox))
 429   (if newsgroup
 430       (when (assoc newsgroup nnmbox-group-alist)
 431         (setq nnmbox-current-group newsgroup))
 432     t))
 433
 434 (defun nnmbox-article-string (article)
 435   (if (numberp article)
 436       (concat "\nX-Gnus-Newsgroup: " nnmbox-current-group ":"
 437               (int-to-string article) " ")
 438     (concat "\nMessage-ID: " article)))
 439
 440 (defun nnmbox-article-group-number ()
 441   (save-excursion
 442     (goto-char (point-min))
 443     (when (re-search-forward "^X-Gnus-Newsgroup: +\\([^:]+\\):\\([0-9]+\\) "
 444                              nil t)
 445       (cons (buffer-substring (match-beginning 1) (match-end 1))
 446             (string-to-int
 447              (buffer-substring (match-beginning 2) (match-end 2)))))))
 448
 449 (defun nnmbox-save-mail (group-art)
 450   "Called narrowed to an article."
 451   (let ((delim (concat "^" message-unix-mail-delimiter)))
 452     (goto-char (point-min))
 453     ;; This might come from somewhere else.
 454     (unless (looking-at delim)
 455       (insert "From nobody " (current-time-string) "\n")
 456       (goto-char (point-min)))
 457     ;; Quote all "From " lines in the article.
 458     (forward-line 1)
 459     (while (re-search-forward delim nil t)
 460       (beginning-of-line)
 461       (insert "> "))
 462     (nnmail-insert-lines)
 463     (nnmail-insert-xref group-art)
 464     (nnmbox-insert-newsgroup-line group-art)
 465     (run-hooks 'nnmail-prepare-save-mail-hook)
 466     (run-hooks 'nnmbox-prepare-save-mail-hook)
 467     group-art))
 468
 469 (defun nnmbox-insert-newsgroup-line (group-art)
 470   (save-excursion
 471     (goto-char (point-min))
 472     (when (search-forward "\n\n" nil t)
 473       (forward-char -1)
 474       (while group-art
 475         (insert (format "X-Gnus-Newsgroup: %s:%d   %s\n"
 476                         (caar group-art) (cdar group-art)
 477                         (current-time-string)))
 478         (setq group-art (cdr group-art))))
 479     t))
 480
 481 (defun nnmbox-active-number (group)
 482   ;; Find the next article number in GROUP.
 483   (let ((active (cadr (assoc group nnmbox-group-alist))))
 484     (if active
 485         (setcdr active (1+ (cdr active)))
 486       ;; This group is new, so we create a new entry for it.
 487       ;; This might be a bit naughty... creating groups on the drop of
 488       ;; a hat, but I don't know...
 489       (push (list group (setq active (cons 1 1)))
 490             nnmbox-group-alist))
 491     (cdr active)))
 492
 493 (defun nnmbox-create-mbox ()
 494   (when (not (file-exists-p nnmbox-mbox-file))
 495     (nnmail-write-region 1 1 nnmbox-mbox-file t 'nomesg)))
 496
 497 (defun nnmbox-read-mbox ()
 498   (nnmail-activate 'nnmbox)
 499   (nnmbox-create-mbox)
 500   (if (and nnmbox-mbox-buffer
 501            (buffer-name nnmbox-mbox-buffer)
 502            (save-excursion
 503              (set-buffer nnmbox-mbox-buffer)
 504              (= (buffer-size) (nnheader-file-size nnmbox-mbox-file))))
 505       ()
 506     (save-excursion
 507       (let ((delim (concat "^" message-unix-mail-delimiter))
 508             (alist nnmbox-group-alist)
 509             start end number)
 510         (set-buffer (setq nnmbox-mbox-buffer
 511                           (nnheader-find-file-noselect
 512                            nnmbox-mbox-file nil 'raw)))
 513         (buffer-disable-undo (current-buffer))
 514
 515         ;; Go through the group alist and compare against
 516         ;; the mbox file.
 517         (while alist
 518           (goto-char (point-max))
 519           (when (and (re-search-backward
 520                       (format "^X-Gnus-Newsgroup: %s:\\([0-9]+\\) "
 521                               (caar alist)) nil t)
 522                      (>= (setq number
 523                                (string-to-number
 524                                 (buffer-substring
 525                                  (match-beginning 1) (match-end 1))))
 526                          (cdadar alist)))
 527             (setcdr (cadar alist) (1+ number)))
 528           (setq alist (cdr alist)))
 529
 530         (goto-char (point-min))
 531         (while (re-search-forward delim nil t)
 532           (setq start (match-beginning 0))
 533           (when (not (search-forward "\nX-Gnus-Newsgroup: "
 534                                      (save-excursion
 535                                        (setq end
 536                                              (or
 537                                               (and
 538                                                (re-search-forward delim nil t)
 539                                                (match-beginning 0))
 540                                               (point-max))))
 541                                      t))
 542             (save-excursion
 543               (save-restriction
 544                 (narrow-to-region start end)
 545                 (nnmbox-save-mail
 546                  (nnmail-article-group 'nnmbox-active-number)))))
 547           (goto-char end))))))
 548
 549 (provide 'nnmbox)
 550
 551 ;;; nnmbox.el ends here