cgit.sxemacs.org Git - gnus/blob - lisp/nnmbox.el

   1 ;;; nnmbox.el --- mail mbox access for Gnus
   2 ;; Copyright (C) 1995 Free Software Foundation, Inc.
   3
   4 ;; Author: Lars Magne Ingebrigtsen <larsi@ifi.uio.no>
   5 ;;      Masanobu UMEDA <umerin@flab.flab.fujitsu.junet>
   6 ;; Keywords: news, mail
   7
   8 ;; This file is part of GNU Emacs.
   9
  10 ;; GNU Emacs is free software; you can redistribute it and/or modify
  11 ;; it under the terms of the GNU General Public License as published by
  12 ;; the Free Software Foundation; either version 2, or (at your option)
  13 ;; any later version.
  14
  15 ;; GNU Emacs is distributed in the hope that it will be useful,
  16 ;; but WITHOUT ANY WARRANTY; without even the implied warranty of
  17 ;; MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.  See the
  18 ;; GNU General Public License for more details.
  19
  20 ;; You should have received a copy of the GNU General Public License
  21 ;; along with GNU Emacs; see the file COPYING.  If not, write to
  22 ;; the Free Software Foundation, 675 Mass Ave, Cambridge, MA 02139, USA.
  23
  24 ;;; Commentary:
  25
  26 ;; For an overview of what the interface functions do, please see the
  27 ;; Gnus sources.
  28
  29 ;;; Code:
  30
  31 (require 'nnheader)
  32 (require 'rmail)
  33 (require 'nnmail)
  34
  35 (defvar nnmbox-mbox-file (expand-file-name "~/mbox")
  36   "The name of the mail box file in the user's home directory.")
  37
  38 (defvar nnmbox-active-file (expand-file-name "~/.mbox-active")
  39   "The name of the active file for the mail box.")
  40
  41 (defvar nnmbox-get-new-mail t
  42   "If non-nil, nnmbox will check the incoming mail file and split the mail.")
  43
  44 (defvar nnmbox-prepare-save-mail-hook nil
  45   "Hook run narrowed to an article before saving.")
  46
  47 \f
  48
  49 (defconst nnmbox-version "nnmbox 0.1"
  50   "nnmbox version.")
  51
  52 (defvar nnmbox-current-group nil
  53   "Current nnmbox news group directory.")
  54
  55 (defconst nnmbox-mbox-buffer nil)
  56
  57 (defvar nnmbox-status-string "")
  58
  59 (defvar nnmbox-group-alist nil)
  60
  61 \f
  62
  63 (defvar nnmbox-current-server nil)
  64 (defvar nnmbox-server-alist nil)
  65 (defvar nnmbox-server-variables
  66   (list
  67    (list 'nnmbox-mbox-file nnmbox-mbox-file)
  68    (list 'nnmbox-active-file nnmbox-active-file)
  69    (list 'nnmbox-get-new-mail nnmbox-get-new-mail)
  70    '(nnmbox-current-group nil)
  71    '(nnmbox-status-string "")
  72    '(nnmbox-group-alist nil)))
  73
  74 \f
  75
  76 ;;; Interface functions
  77
  78 (defun nnmbox-retrieve-headers (sequence &optional newsgroup server)
  79   (save-excursion
  80     (set-buffer nntp-server-buffer)
  81     (erase-buffer)
  82     (let ((number (length sequence))
  83           (count 0)
  84           article art-string start stop)
  85       (nnmbox-possibly-change-newsgroup newsgroup)
  86       (if (stringp (car sequence))
  87           'headers
  88         (while sequence
  89           (setq article (car sequence))
  90           (setq art-string (nnmbox-article-string article))
  91           (set-buffer nnmbox-mbox-buffer)
  92           (if (or (search-forward art-string nil t)
  93                   (progn (goto-char (point-min))
  94                          (search-forward art-string nil t)))
  95               (progn
  96                 (setq start
  97                       (save-excursion
  98                         (re-search-backward
  99                          (concat "^" rmail-unix-mail-delimiter) nil t)
 100                         (point)))
 101                 (search-forward "\n\n" nil t)
 102                 (setq stop (1- (point)))
 103                 (set-buffer nntp-server-buffer)
 104                 (insert (format "221 %d Article retrieved.\n" article))
 105                 (insert-buffer-substring nnmbox-mbox-buffer start stop)
 106                 (goto-char (point-max))
 107                 (insert ".\n")))
 108           (setq sequence (cdr sequence))
 109           (setq count (1+ count))
 110           (and (numberp nnmail-large-newsgroup)
 111                (> number nnmail-large-newsgroup)
 112                (zerop (% count 20))
 113                gnus-verbose-backends
 114                (message "nnmbox: Receiving headers... %d%%"
 115                         (/ (* count 100) number))))
 116
 117         (and (numberp nnmail-large-newsgroup)
 118              (> number nnmail-large-newsgroup)
 119              gnus-verbose-backends
 120              (message "nnmbox: Receiving headers...done"))
 121
 122         ;; Fold continuation lines.
 123         (set-buffer nntp-server-buffer)
 124         (goto-char (point-min))
 125         (while (re-search-forward "\\(\r?\n[ \t]+\\)+" nil t)
 126           (replace-match " " t t))
 127         'headers))))
 128
 129 (defun nnmbox-open-server (server &optional defs)
 130   (nnheader-init-server-buffer)
 131   (if (equal server nnmbox-current-server)
 132       t
 133     (if nnmbox-current-server
 134         (setq nnmbox-server-alist
 135               (cons (list nnmbox-current-server
 136                           (nnheader-save-variables nnmbox-server-variables))
 137                     nnmbox-server-alist)))
 138     (let ((state (assoc server nnmbox-server-alist)))
 139       (if state
 140           (progn
 141             (nnheader-restore-variables (nth 1 state))
 142             (setq nnmbox-server-alist (delq state nnmbox-server-alist)))
 143         (nnheader-set-init-variables nnmbox-server-variables defs)))
 144     (setq nnmbox-current-server server)))
 145
 146 (defun nnmbox-close-server (&optional server)
 147   t)
 148
 149 (defun nnmbox-server-opened (&optional server)
 150   (and (equal server nnmbox-current-server)
 151        nnmbox-mbox-buffer
 152        (buffer-name nnmbox-mbox-buffer)
 153        nntp-server-buffer
 154        (buffer-name nntp-server-buffer)))
 155
 156 (defun nnmbox-status-message (&optional server)
 157   nnmbox-status-string)
 158
 159 (defun nnmbox-request-article (article &optional newsgroup server buffer)
 160   (nnmbox-possibly-change-newsgroup newsgroup)
 161   (if (stringp article)
 162       nil
 163     (save-excursion
 164       (set-buffer nnmbox-mbox-buffer)
 165       (goto-char (point-min))
 166       (if (search-forward (nnmbox-article-string article) nil t)
 167           (let (start stop)
 168             (re-search-backward (concat "^" rmail-unix-mail-delimiter) nil t)
 169             (setq start (point))
 170             (forward-line 1)
 171             (or (and (re-search-forward
 172                       (concat "^" rmail-unix-mail-delimiter) nil t)
 173                      (forward-line -1))
 174                 (goto-char (point-max)))
 175             (setq stop (point))
 176             (let ((nntp-server-buffer (or buffer nntp-server-buffer)))
 177               (set-buffer nntp-server-buffer)
 178               (erase-buffer)
 179               (insert-buffer-substring nnmbox-mbox-buffer start stop)
 180               (goto-char (point-min))
 181               (while (looking-at "From ")
 182                 (delete-char 5)
 183                 (insert "X-From-Line: ")
 184                 (forward-line 1))
 185               t))))))
 186
 187 (defun nnmbox-request-group (group &optional server dont-check)
 188   (save-excursion
 189     (if (nnmbox-possibly-change-newsgroup group)
 190         (if dont-check
 191             t
 192           (nnmbox-get-new-mail group)
 193           (save-excursion
 194             (set-buffer nntp-server-buffer)
 195             (erase-buffer)
 196             (let ((active (assoc group nnmbox-group-alist)))
 197               (insert (format "211 %d %d %d %s\n"
 198                               (1+ (- (cdr (car (cdr active)))
 199                                      (car (car (cdr active)))))
 200                               (car (car (cdr active)))
 201                               (cdr (car (cdr active)))
 202                               (car active))))
 203             t)))))
 204
 205 (defun nnmbox-close-group (group &optional server)
 206   t)
 207
 208 (defun nnmbox-request-list (&optional server)
 209   (if server (nnmbox-get-new-mail))
 210   (save-excursion
 211     (or (nnmail-find-file nnmbox-active-file)
 212         (progn
 213           (setq nnmbox-group-alist (nnmail-get-active))
 214           (nnmail-save-active nnmbox-group-alist nnmbox-active-file)
 215           (nnmail-find-file nnmbox-active-file)))))
 216
 217 (defun nnmbox-request-newgroups (date &optional server)
 218   (nnmbox-request-list server))
 219
 220 (defun nnmbox-request-list-newsgroups (&optional server)
 221   (setq nnmbox-status-string "nnmbox: LIST NEWSGROUPS is not implemented.")
 222   nil)
 223
 224 (defun nnmbox-request-post (&optional server)
 225   (mail-send-and-exit nil))
 226
 227 (defalias 'nnmbox-request-post-buffer 'nnmail-request-post-buffer)
 228
 229 (defun nnmbox-request-expire-articles
 230   (articles newsgroup &optional server force)
 231   (nnmbox-possibly-change-newsgroup newsgroup)
 232   (let* ((days (or (and nnmail-expiry-wait-function
 233                         (funcall nnmail-expiry-wait-function newsgroup))
 234                    nnmail-expiry-wait))
 235          (is-old t)
 236          rest)
 237     (save-excursion
 238       (set-buffer nnmbox-mbox-buffer)
 239       (while articles
 240         (goto-char (point-min))
 241         (if (search-forward (nnmbox-article-string (car articles)) nil t)
 242             (if (or force
 243                     (setq is-old
 244                           (> (nnmail-days-between
 245                               (current-time-string)
 246                               (buffer-substring
 247                                (point) (progn (end-of-line) (point))))
 248                              days)))
 249                 (progn
 250                   (and gnus-verbose-backends
 251                        (message "Deleting: %s" (car articles)))
 252                   (nnmbox-delete-mail))
 253               (setq rest (cons (car articles) rest))))
 254         (setq articles (cdr articles)))
 255       (save-buffer)
 256       ;; Find the lowest active article in this group.
 257       (let ((active (nth 1 (assoc newsgroup nnmbox-group-alist))))
 258         (goto-char (point-min))
 259         (while (and (not (search-forward
 260                           (nnmbox-article-string (car active)) nil t))
 261                     (<= (car active) (cdr active)))
 262           (setcar active (1+ (car active)))
 263           (goto-char (point-min))))
 264       (nnmail-save-active nnmbox-group-alist nnmbox-active-file)
 265       (nconc rest articles))))
 266
 267 (defun nnmbox-request-move-article
 268   (article group server accept-form &optional last)
 269   (nnmbox-possibly-change-newsgroup group)
 270   (let ((buf (get-buffer-create " *nnmbox move*"))
 271         result)
 272     (and
 273      (nnmbox-request-article article group server)
 274      (save-excursion
 275        (set-buffer buf)
 276        (buffer-disable-undo (current-buffer))
 277        (erase-buffer)
 278        (insert-buffer-substring nntp-server-buffer)
 279        (goto-char (point-min))
 280        (while (re-search-forward
 281                "^X-Gnus-Newsgroup:"
 282                (save-excursion (search-forward "\n\n" nil t) (point)) t)
 283          (delete-region (progn (beginning-of-line) (point))
 284                         (progn (forward-line 1) (point))))
 285        (setq result (eval accept-form))
 286        (kill-buffer buf)
 287        result)
 288      (save-excursion
 289        (set-buffer nnmbox-mbox-buffer)
 290        (goto-char (point-min))
 291        (if (search-forward (nnmbox-article-string article) nil t)
 292            (nnmbox-delete-mail))
 293        (and last (save-buffer))))
 294     result))
 295
 296 (defun nnmbox-request-accept-article (group &optional last)
 297   (let ((buf (current-buffer))
 298         result)
 299     (goto-char (point-min))
 300     (if (looking-at "X-From-Line: ")
 301         (replace-match "From ")
 302       (insert "From nobody " (current-time-string) "\n"))
 303     (and
 304      (nnmbox-request-list)
 305      (setq nnmbox-group-alist (nnmail-get-active))
 306      (progn
 307        (set-buffer buf)
 308        (goto-char (point-min))
 309        (search-forward "\n\n" nil t)
 310        (forward-line -1)
 311        (while (re-search-backward "^X-Gnus-Newsgroup: " nil t)
 312          (delete-region (point) (progn (forward-line 1) (point))))
 313        (setq result (nnmbox-save-mail (and (stringp group) group))))
 314      (save-excursion
 315        (set-buffer nnmbox-mbox-buffer)
 316        (insert-buffer-substring buf)
 317        (and last (save-buffer))
 318        result)
 319      (nnmail-save-active nnmbox-group-alist nnmbox-active-file))
 320     (car result)))
 321
 322 (defun nnmbox-request-replace-article (article group buffer)
 323   (nnmbox-possibly-change-newsgroup group)
 324   (save-excursion
 325     (set-buffer nnmbox-mbox-buffer)
 326     (goto-char (point-min))
 327     (if (not (search-forward (nnmbox-article-string article) nil t))
 328         nil
 329       (nnmbox-delete-mail t t)
 330       (insert-buffer-substring buffer)
 331       (save-buffer)
 332       t)))
 333
 334 \f
 335 ;;; Internal functions.
 336
 337 ;; If FORCE, delete article no matter how many X-Gnus-Newsgroup
 338 ;; headers there are. If LEAVE-DELIM, don't delete the Unix mbox
 339 ;; delimeter line.
 340 (defun nnmbox-delete-mail (&optional force leave-delim)
 341   ;; Delete the current X-Gnus-Newsgroup line.
 342   (or force
 343       (delete-region
 344        (progn (beginning-of-line) (point))
 345        (progn (forward-line 1) (point))))
 346   ;; Beginning of the article.
 347   (save-excursion
 348     (save-restriction
 349       (narrow-to-region
 350        (save-excursion
 351          (re-search-backward (concat "^" rmail-unix-mail-delimiter) nil t)
 352          (if leave-delim (progn (forward-line 1) (point))
 353            (match-beginning 0)))
 354        (progn
 355          (forward-line 1)
 356          (or (and (re-search-forward (concat "^" rmail-unix-mail-delimiter)
 357                                      nil t)
 358                   (if (and (not (bobp)) leave-delim)
 359                       (progn (forward-line -2) (point))
 360                     (match-beginning 0)))
 361              (point-max))))
 362       (goto-char (point-min))
 363       ;; Only delete the article if no other groups owns it as well.
 364       (if (or force (not (re-search-forward "^X-Gnus-Newsgroup: " nil t)))
 365           (delete-region (point-min) (point-max))))))
 366
 367 (defun nnmbox-possibly-change-newsgroup (newsgroup)
 368   (if (or (not nnmbox-mbox-buffer)
 369           (not (buffer-name nnmbox-mbox-buffer)))
 370       (save-excursion
 371         (set-buffer (setq nnmbox-mbox-buffer
 372                           (find-file-noselect nnmbox-mbox-file)))
 373         (buffer-disable-undo (current-buffer))))
 374   (if (not nnmbox-group-alist)
 375       (progn
 376         (nnmbox-request-list)
 377         (setq nnmbox-group-alist (nnmail-get-active))))
 378   (if newsgroup
 379       (if (assoc newsgroup nnmbox-group-alist)
 380           (setq nnmbox-current-group newsgroup))))
 381
 382 (defun nnmbox-article-string (article)
 383   (concat "\nX-Gnus-Newsgroup: " nnmbox-current-group ":"
 384           (int-to-string article) " "))
 385
 386 (defun nnmbox-save-mail (&optional group)
 387   "Called narrowed to an article."
 388   (let* ((nnmail-split-methods
 389           (if group (list (list group "")) nnmail-split-methods))
 390          (group-art (nreverse (nnmail-article-group 'nnmbox-active-number))))
 391     (nnmail-insert-lines)
 392     (nnmail-insert-xref group-art)
 393     (nnmbox-insert-newsgroup-line group-art)
 394     (run-hooks 'nnml-prepare-save-mail-hook)
 395     group-art))
 396
 397 (defun nnmbox-insert-newsgroup-line (group-art)
 398   (save-excursion
 399     (goto-char (point-min))
 400     (if (search-forward "\n\n" nil t)
 401         (progn
 402           (forward-char -1)
 403           (while group-art
 404             (insert (format "X-Gnus-Newsgroup: %s:%d   %s\n"
 405                             (car (car group-art)) (cdr (car group-art))
 406                             (current-time-string)))
 407             (setq group-art (cdr group-art)))))
 408     t))
 409
 410 (defun nnmbox-active-number (group)
 411   "Find the next article number in GROUP."
 412   (let ((active (car (cdr (assoc group nnmbox-group-alist)))))
 413     (setcdr active (1+ (cdr active)))
 414     (cdr active)))
 415
 416 (defun nnmbox-read-mbox ()
 417   (nnmbox-request-list)
 418   (setq nnmbox-group-alist (nnmail-get-active))
 419   (if (not (file-exists-p nnmbox-mbox-file))
 420       (write-region 1 1 nnmbox-mbox-file t 'nomesg))
 421   (if (and nnmbox-mbox-buffer
 422            (buffer-name nnmbox-mbox-buffer)
 423            (save-excursion
 424              (set-buffer nnmbox-mbox-buffer)
 425              (= (buffer-size) (nth 7 (file-attributes nnmbox-mbox-file)))))
 426       ()
 427     (save-excursion
 428       (let ((delim (concat "^" rmail-unix-mail-delimiter))
 429             start end)
 430         (set-buffer (setq nnmbox-mbox-buffer
 431                           (find-file-noselect nnmbox-mbox-file)))
 432         (buffer-disable-undo (current-buffer))
 433         (goto-char (point-min))
 434         (while (re-search-forward delim nil t)
 435           (setq start (match-beginning 0))
 436           (if (not (search-forward "\nX-Gnus-Newsgroup: "
 437                                    (save-excursion
 438                                      (setq end
 439                                            (or
 440                                             (and
 441                                              (re-search-forward delim nil t)
 442                                              (match-beginning 0))
 443                                             (point-max))))
 444                                    t))
 445               (save-excursion
 446                 (save-restriction
 447                   (narrow-to-region start end)
 448                   (nnmbox-save-mail))))
 449           (goto-char end))))))
 450
 451 (defun nnmbox-get-new-mail (&optional group)
 452   "Read new incoming mail."
 453   (let* ((spools (nnmail-get-spool-files group))
 454          (group-in group)
 455          incoming incomings)
 456     (nnmbox-read-mbox)
 457     (if (or (not nnmbox-get-new-mail) (not nnmail-spool-file))
 458         ()
 459       ;; We go through all the existing spool files and split the
 460       ;; mail from each.
 461       (while spools
 462         (and
 463          (file-exists-p (car spools))
 464          (> (nth 7 (file-attributes (car spools))) 0)
 465          (progn
 466            (and gnus-verbose-backends
 467                 (message "nnmbox: Reading incoming mail..."))
 468            (setq incoming
 469                  (nnmail-move-inbox
 470                   (car spools) (concat nnmbox-mbox-file "-Incoming")))
 471            (save-excursion
 472              (setq group (nnmail-get-split-group (car spools) group-in))
 473              (let ((in-buf (nnmail-split-incoming
 474                             incoming 'nnmbox-save-mail t group)))
 475                (set-buffer nnmbox-mbox-buffer)
 476                (goto-char (point-max))
 477                (insert-buffer-substring in-buf)
 478                (kill-buffer in-buf)))))
 479         (setq spools (cdr spools)))
 480       ;; If we did indeed read any incoming spools, we save all info.
 481       (and (buffer-modified-p nnmbox-mbox-buffer)
 482            (save-excursion
 483              (nnmail-save-active nnmbox-group-alist nnmbox-active-file)
 484              (set-buffer nnmbox-mbox-buffer)
 485              (save-buffer)))
 486       (if incomings (run-hooks 'nnmail-read-incoming-hook))
 487       (while incomings
 488         (and nnmail-delete-incoming
 489              (file-writable-p incoming)
 490              (delete-file incoming))
 491         (setq incomings (cdr incomings))))))
 492
 493
 494 (provide 'nnmbox)
 495
 496 ;;; nnmbox.el ends here