cgit.sxemacs.org Git - gnus/blob - lisp/nnimap.el

   1 ;;; nnimap.el --- IMAP interface for Gnus
   2
   3 ;; Copyright (C) 2010 Free Software Foundation, Inc.
   4
   5 ;; Author: Lars Magne Ingebrigtsen <larsi@gnus.org>
   6 ;;         Simon Josefsson <simon@josefsson.org>
   7
   8 ;; This file is part of GNU Emacs.
   9
  10 ;; GNU Emacs is free software: you can redistribute it and/or modify
  11 ;; it under the terms of the GNU General Public License as published by
  12 ;; the Free Software Foundation, either version 3 of the License, or
  13 ;; (at your option) any later version.
  14
  15 ;; GNU Emacs is distributed in the hope that it will be useful,
  16 ;; but WITHOUT ANY WARRANTY; without even the implied warranty of
  17 ;; MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.  See the
  18 ;; GNU General Public License for more details.
  19
  20 ;; You should have received a copy of the GNU General Public License
  21 ;; along with GNU Emacs.  If not, see <http://www.gnu.org/licenses/>.
  22
  23 ;;; Commentary:
  24
  25 ;; nnimap interfaces Gnus with IMAP servers.
  26
  27 ;;; Code:
  28
  29 (eval-and-compile
  30   (require 'nnheader))
  31
  32 (eval-when-compile
  33   (require 'cl))
  34
  35 (require 'nnheader)
  36 (require 'gnus-util)
  37 (require 'gnus)
  38 (require 'nnoo)
  39 (require 'netrc)
  40 (require 'utf7)
  41 (require 'tls)
  42 (require 'parse-time)
  43
  44 (autoload 'auth-source-forget-user-or-password "auth-source")
  45 (autoload 'auth-source-user-or-password "auth-source")
  46
  47 (nnoo-declare nnimap)
  48
  49 (defvoo nnimap-address nil
  50   "The address of the IMAP server.")
  51
  52 (defvoo nnimap-server-port nil
  53   "The IMAP port used.
  54 If nnimap-stream is `ssl', this will default to `imaps'.  If not,
  55 it will default to `imap'.")
  56
  57 (defvoo nnimap-stream 'ssl
  58   "How nnimap will talk to the IMAP server.
  59 Values are `ssl', `network', `starttls' or `shell'.")
  60
  61 (defvoo nnimap-shell-program (if (boundp 'imap-shell-program)
  62                                  (if (listp imap-shell-program)
  63                                      (car imap-shell-program)
  64                                    imap-shell-program)
  65                                "ssh %s imapd"))
  66
  67 (defvoo nnimap-inbox nil
  68   "The mail box where incoming mail arrives and should be split out of.")
  69
  70 (defvoo nnimap-split-methods nil
  71   "How mail is split.
  72 Uses the same syntax as nnmail-split-methods")
  73
  74 (defvoo nnimap-split-fancy nil
  75   "Uses the same syntax as nnmail-split-fancy.")
  76
  77 (make-obsolete-variable 'nnimap-split-rule "see `nnimap-split-methods'"
  78                         "Emacs 24.1")
  79
  80 (defvoo nnimap-authenticator nil
  81   "How nnimap authenticate itself to the server.
  82 Possible choices are nil (use default methods) or `anonymous'.")
  83
  84 (defvoo nnimap-expunge t
  85   "If non-nil, expunge articles after deleting them.
  86 This is always done if the server supports UID EXPUNGE, but it's
  87 not done by default on servers that doesn't support that command.")
  88
  89 (defvoo nnimap-streaming t
  90   "If non-nil, try to use streaming commands with IMAP servers.
  91 Switching this off will make nnimap slower, but it helps with
  92 some servers.")
  93
  94 (defvoo nnimap-connection-alist nil)
  95
  96 (defvoo nnimap-current-infos nil)
  97
  98 (defvoo nnimap-fetch-partial-articles nil
  99   "If non-nil, Gnus will fetch partial articles.
 100 If t, nnimap will fetch only the first part.  If a string, it
 101 will fetch all parts that have types that match that string.  A
 102 likely value would be \"text/\" to automatically fetch all
 103 textual parts.")
 104
 105 (defvar nnimap-process nil)
 106
 107 (defvar nnimap-status-string "")
 108
 109 (defvar nnimap-split-download-body-default nil
 110   "Internal variable with default value for `nnimap-split-download-body'.")
 111
 112 (defvar nnimap-keepalive-timer nil)
 113 (defvar nnimap-process-buffers nil)
 114
 115 (defstruct nnimap
 116   group process commands capabilities select-result newlinep server
 117   last-command-time greeting)
 118
 119 (defvar nnimap-object nil)
 120
 121 (defvar nnimap-mark-alist
 122   '((read "\\Seen" %Seen)
 123     (tick "\\Flagged" %Flagged)
 124     (reply "\\Answered" %Answered)
 125     (expire "gnus-expire")
 126     (dormant "gnus-dormant")
 127     (score "gnus-score")
 128     (save "gnus-save")
 129     (download "gnus-download")
 130     (forward "gnus-forward")))
 131
 132 (defun nnimap-buffer ()
 133   (nnimap-find-process-buffer nntp-server-buffer))
 134
 135 (deffoo nnimap-retrieve-headers (articles &optional group server fetch-old)
 136   (with-current-buffer nntp-server-buffer
 137     (erase-buffer)
 138     (when (nnimap-possibly-change-group group server)
 139       (with-current-buffer (nnimap-buffer)
 140         (erase-buffer)
 141         (nnimap-wait-for-response
 142          (nnimap-send-command
 143           "UID FETCH %s %s"
 144           (nnimap-article-ranges (gnus-compress-sequence articles))
 145           (format "(UID RFC822.SIZE BODYSTRUCTURE %s)"
 146                   (format
 147                    (if (nnimap-ver4-p)
 148                        "BODY.PEEK[HEADER.FIELDS %s]"
 149                      "RFC822.HEADER.LINES %s")
 150                    (append '(Subject From Date Message-Id
 151                                      References In-Reply-To Xref)
 152                            nnmail-extra-headers))))
 153          t)
 154         (nnimap-transform-headers))
 155       (insert-buffer-substring
 156        (nnimap-find-process-buffer (current-buffer))))
 157     'headers))
 158
 159 (defun nnimap-transform-headers ()
 160   (goto-char (point-min))
 161   (let (article bytes lines size string)
 162     (block nil
 163       (while (not (eobp))
 164         (while (not (looking-at "^\\* [0-9]+ FETCH.*UID \\([0-9]+\\)"))
 165           (delete-region (point) (progn (forward-line 1) (point)))
 166           (when (eobp)
 167             (return)))
 168         (setq article (match-string 1))
 169         ;; Unfold quoted {number} strings.
 170         (while (re-search-forward "[^]] {\\([0-9]+\\)}\r\n"
 171                                   (1+ (line-end-position)) t)
 172           (setq size (string-to-number (match-string 1)))
 173           (delete-region (+ (match-beginning 0) 2) (point))
 174           (setq string (delete-region (point) (+ (point) size)))
 175           (insert (format "%S" string)))
 176         (setq bytes (nnimap-get-length)
 177               lines nil)
 178         (beginning-of-line)
 179         (setq size
 180               (and (re-search-forward "RFC822.SIZE \\([0-9]+\\)"
 181                                       (line-end-position)
 182                                       t)
 183                    (match-string 1)))
 184         (beginning-of-line)
 185         (when (search-forward "BODYSTRUCTURE" (line-end-position) t)
 186           (let ((structure (ignore-errors
 187                              (read (current-buffer)))))
 188             (while (and (consp structure)
 189                         (not (stringp (car structure))))
 190               (setq structure (car structure)))
 191             (setq lines (nth 7 structure))))
 192         (delete-region (line-beginning-position) (line-end-position))
 193         (insert (format "211 %s Article retrieved." article))
 194         (forward-line 1)
 195         (when size
 196           (insert (format "Chars: %s\n" size)))
 197         (when lines
 198           (insert (format "Lines: %s\n" lines)))
 199         (re-search-forward "^\r$")
 200         (delete-region (line-beginning-position) (line-end-position))
 201         (insert ".")
 202         (forward-line 1)))))
 203
 204 (defun nnimap-get-length ()
 205   (and (re-search-forward "{\\([0-9]+\\)}" (line-end-position) t)
 206        (string-to-number (match-string 1))))
 207
 208 (defun nnimap-article-ranges (ranges)
 209   (let (result)
 210     (cond
 211      ((numberp ranges)
 212       (number-to-string ranges))
 213      ((numberp (cdr ranges))
 214       (format "%d:%d" (car ranges) (cdr ranges)))
 215      (t
 216       (dolist (elem ranges)
 217         (push
 218          (if (consp elem)
 219              (format "%d:%d" (car elem) (cdr elem))
 220            (number-to-string elem))
 221          result))
 222       (mapconcat #'identity (nreverse result) ",")))))
 223
 224 (deffoo nnimap-open-server (server &optional defs)
 225   (if (nnimap-server-opened server)
 226       t
 227     (unless (assq 'nnimap-address defs)
 228       (setq defs (append defs (list (list 'nnimap-address server)))))
 229     (nnoo-change-server 'nnimap server defs)
 230     (or (nnimap-find-connection nntp-server-buffer)
 231         (nnimap-open-connection nntp-server-buffer))))
 232
 233 (defun nnimap-make-process-buffer (buffer)
 234   (with-current-buffer
 235       (generate-new-buffer (format "*nnimap %s %s %s*"
 236                                    nnimap-address nnimap-server-port
 237                                    (gnus-buffer-exists-p buffer)))
 238     (mm-disable-multibyte)
 239     (buffer-disable-undo)
 240     (gnus-add-buffer)
 241     (set (make-local-variable 'after-change-functions) nil)
 242     (set (make-local-variable 'nnimap-object)
 243          (make-nnimap :server (nnoo-current-server 'nnimap)))
 244     (push (list buffer (current-buffer)) nnimap-connection-alist)
 245     (push (current-buffer) nnimap-process-buffers)
 246     (current-buffer)))
 247
 248 (defun nnimap-open-shell-stream (name buffer host port)
 249   (let ((process-connection-type nil))
 250     (start-process name buffer shell-file-name
 251                    shell-command-switch
 252                    (format-spec
 253                     nnimap-shell-program
 254                     (format-spec-make
 255                      ?s host
 256                      ?p port)))))
 257
 258 (defun nnimap-credentials (address ports &optional inhibit-create)
 259   (let (port credentials)
 260     ;; Request the credentials from all ports, but only query on the
 261     ;; last port if all the previous ones have failed.
 262     (while (and (null credentials)
 263                 (setq port (pop ports)))
 264       (setq credentials
 265             (auth-source-user-or-password
 266              '("login" "password") address port nil
 267              (if inhibit-create
 268                  nil
 269                (null ports)))))
 270     credentials))
 271
 272 (defun nnimap-keepalive ()
 273   (let ((now (current-time)))
 274     (dolist (buffer nnimap-process-buffers)
 275       (when (buffer-name buffer)
 276         (with-current-buffer buffer
 277           (when (and nnimap-object
 278                      (nnimap-last-command-time nnimap-object)
 279                      (> (time-to-seconds
 280                          (time-subtract
 281                           now
 282                           (nnimap-last-command-time nnimap-object)))
 283                         ;; More than five minutes since the last command.
 284                         (* 5 60)))
 285             (nnimap-send-command "NOOP")))))))
 286
 287 (defun nnimap-open-connection (buffer)
 288   (unless nnimap-keepalive-timer
 289     (setq nnimap-keepalive-timer (run-at-time (* 60 15) (* 60 15)
 290                                               'nnimap-keepalive)))
 291   (block nil
 292     (with-current-buffer (nnimap-make-process-buffer buffer)
 293       (let* ((coding-system-for-read 'binary)
 294              (coding-system-for-write 'binary)
 295              (port nil)
 296              (ports
 297               (cond
 298                ((eq nnimap-stream 'network)
 299                 (open-network-stream
 300                  "*nnimap*" (current-buffer) nnimap-address
 301                  (setq port
 302                        (or nnimap-server-port
 303                            (if (netrc-find-service-number "imap")
 304                                "imap"
 305                              "143"))))
 306                 '("143" "imap"))
 307                ((eq nnimap-stream 'shell)
 308                 (nnimap-open-shell-stream
 309                  "*nnimap*" (current-buffer) nnimap-address
 310                  (setq port (or nnimap-server-port "imap")))
 311                 '("imap"))
 312                ((eq nnimap-stream 'starttls)
 313                 (let ((tls-program (nnimap-extend-tls-programs)))
 314                   (open-tls-stream
 315                    "*nnimap*" (current-buffer) nnimap-address
 316                    (setq port (or nnimap-server-port "imap"))
 317                    'starttls))
 318                 '("imap"))
 319                ((memq nnimap-stream '(ssl tls))
 320                 (funcall (if (and nil
 321                                   (fboundp 'open-gnutls-stream))
 322                              'open-gnutls-stream
 323                            'open-tls-stream)
 324                          "*nnimap*" (current-buffer) nnimap-address
 325                          (setq port
 326                                (or nnimap-server-port
 327                                    (if (netrc-find-service-number "imaps")
 328                                        "imaps"
 329                                      "993"))))
 330                 '("143" "993" "imap" "imaps"))
 331                (t
 332                 (error "Unknown stream type: %s" nnimap-stream))))
 333              connection-result login-result credentials)
 334         (setf (nnimap-process nnimap-object)
 335               (get-buffer-process (current-buffer)))
 336         (if (not (and (nnimap-process nnimap-object)
 337                       (memq (process-status (nnimap-process nnimap-object))
 338                             '(open run))))
 339             (nnheader-report 'nnimap "Unable to contact %s:%s via %s"
 340                              nnimap-address port nnimap-stream)
 341           (gnus-set-process-query-on-exit-flag (nnimap-process nnimap-object) nil)
 342           (if (not (setq connection-result (nnimap-wait-for-connection)))
 343               (nnheader-report 'nnimap
 344                                "%s" (buffer-substring
 345                                      (point) (line-end-position)))
 346             ;; Store the greeting (for debugging purposes).
 347             (setf (nnimap-greeting nnimap-object)
 348                   (buffer-substring (line-beginning-position)
 349                                     (line-end-position)))
 350             ;; Store the capabilities.
 351             (setf (nnimap-capabilities nnimap-object)
 352                   (mapcar
 353                    #'upcase
 354                    (nnimap-find-parameter
 355                     "CAPABILITY" (cdr (nnimap-command "CAPABILITY")))))
 356             (when nnimap-server-port
 357               (push (format "%s" nnimap-server-port) ports))
 358             ;; If this is a STARTTLS-capable server, then sever the
 359             ;; connection and start a STARTTLS connection instead.
 360             (when (and (eq nnimap-stream 'network)
 361                        (member "STARTTLS" (nnimap-capabilities nnimap-object)))
 362               (let ((nnimap-stream 'starttls))
 363                 (let ((tls-process
 364                        (nnimap-open-connection buffer)))
 365                   ;; If the STARTTLS connection was successful, we
 366                   ;; kill our first non-encrypted connection.  If it
 367                   ;; wasn't successful, we just use our unencrypted
 368                   ;; connection.
 369                   (when (memq (process-status tls-process) '(open run))
 370                     (delete-process (nnimap-process nnimap-object))
 371                     (kill-buffer (current-buffer))
 372                     (return tls-process)))))
 373             (unless (equal connection-result "PREAUTH")
 374               (if (not (setq credentials
 375                              (if (eq nnimap-authenticator 'anonymous)
 376                                  (list "anonymous"
 377                                        (message-make-address))
 378                                (or
 379                                 ;; First look for the credentials based
 380                                 ;; on the virtual server name.
 381                                 (nnimap-credentials
 382                                  (nnoo-current-server 'nnimap) ports t)
 383                                 ;; Then look them up based on the
 384                                 ;; physical address.
 385                                 (nnimap-credentials nnimap-address ports)))))
 386                   (setq nnimap-object nil)
 387                 (setq login-result (nnimap-command "LOGIN %S %S"
 388                                                    (car credentials)
 389                                                    (cadr credentials)))
 390                 (unless (car login-result)
 391                   ;; If the login failed, then forget the credentials
 392                   ;; that are now possibly cached.
 393                   (dolist (host (list (nnoo-current-server 'nnimap)
 394                                       nnimap-address))
 395                     (dolist (port ports)
 396                       (dolist (element '("login" "password"))
 397                         (auth-source-forget-user-or-password
 398                          element host port))))
 399                   (delete-process (nnimap-process nnimap-object))
 400                   (setq nnimap-object nil))))
 401             (when nnimap-object
 402               (when (member "QRESYNC" (nnimap-capabilities nnimap-object))
 403                 (nnimap-command "ENABLE QRESYNC"))
 404               (nnimap-process nnimap-object))))))))
 405
 406 (defun nnimap-extend-tls-programs ()
 407   (let ((programs tls-program)
 408         result)
 409     (unless (consp programs)
 410       (setq programs (list programs)))
 411     (dolist (program programs)
 412       (when (assoc (car (split-string program)) tls-starttls-switches)
 413         (push (if (not (string-match "%s" program))
 414                   (concat program " " "%s")
 415                 program)
 416               result)))
 417     (nreverse result)))
 418
 419 (defun nnimap-find-parameter (parameter elems)
 420   (let (result)
 421     (dolist (elem elems)
 422       (cond
 423        ((equal (car elem) parameter)
 424         (setq result (cdr elem)))
 425        ((and (equal (car elem) "OK")
 426              (consp (cadr elem))
 427              (equal (caadr elem) parameter))
 428         (setq result (cdr (cadr elem))))))
 429     result))
 430
 431 (deffoo nnimap-close-server (&optional server)
 432   (when (nnoo-change-server 'nnimap server nil)
 433     (ignore-errors
 434       (delete-process (get-buffer-process (nnimap-buffer))))
 435     t))
 436
 437 (deffoo nnimap-request-close ()
 438   t)
 439
 440 (deffoo nnimap-server-opened (&optional server)
 441   (and (nnoo-current-server-p 'nnimap server)
 442        nntp-server-buffer
 443        (gnus-buffer-live-p nntp-server-buffer)
 444        (nnimap-find-connection nntp-server-buffer)))
 445
 446 (deffoo nnimap-status-message (&optional server)
 447   nnimap-status-string)
 448
 449 (deffoo nnimap-request-article (article &optional group server to-buffer)
 450   (with-current-buffer nntp-server-buffer
 451     (let ((result (nnimap-possibly-change-group group server))
 452           parts structure)
 453       (when (stringp article)
 454         (setq article (nnimap-find-article-by-message-id group article)))
 455       (when (and result
 456                  article)
 457         (erase-buffer)
 458         (with-current-buffer (nnimap-buffer)
 459           (erase-buffer)
 460           (when nnimap-fetch-partial-articles
 461             (nnimap-command "UID FETCH %d (BODYSTRUCTURE)" article)
 462             (goto-char (point-min))
 463             (when (re-search-forward "FETCH.*BODYSTRUCTURE" nil t)
 464               (setq structure (ignore-errors
 465                                 (let ((start (point)))
 466                                   (forward-sexp 1)
 467                                   (downcase-region start (point))
 468                                   (goto-char (point))
 469                                   (read (current-buffer))))
 470                     parts (nnimap-find-wanted-parts structure))))
 471           (when (if parts
 472                     (nnimap-get-partial-article article parts structure)
 473                   (nnimap-get-whole-article article))
 474             (let ((buffer (current-buffer)))
 475               (with-current-buffer (or to-buffer nntp-server-buffer)
 476                 (erase-buffer)
 477                 (insert-buffer-substring buffer)
 478                 (nnheader-ms-strip-cr)
 479                 (cons group article)))))))))
 480
 481 (defun nnimap-get-whole-article (article)
 482   (let ((result
 483          (nnimap-command
 484           (if (nnimap-ver4-p)
 485               "UID FETCH %d BODY.PEEK[]"
 486             "UID FETCH %d RFC822.PEEK")
 487           article)))
 488     ;; Check that we really got an article.
 489     (goto-char (point-min))
 490     (unless (re-search-forward "\\* [0-9]+ FETCH" nil t)
 491       (setq result nil))
 492     (when result
 493       ;; Remove any data that may have arrived before the FETCH data.
 494       (beginning-of-line)
 495       (unless (bobp)
 496         (delete-region (point-min) (point)))
 497       (let ((bytes (nnimap-get-length)))
 498         (delete-region (line-beginning-position)
 499                        (progn (forward-line 1) (point)))
 500         (goto-char (+ (point) bytes))
 501         (delete-region (point) (point-max)))
 502       t)))
 503
 504 (defun nnimap-ver4-p ()
 505   (member "IMAP4REV1" (nnimap-capabilities nnimap-object)))
 506
 507 (defun nnimap-get-partial-article (article parts structure)
 508   (let ((result
 509          (nnimap-command
 510           "UID FETCH %d (%s %s)"
 511           article
 512           (if (nnimap-ver4-p)
 513               "BODY.PEEK[HEADER]"
 514             "RFC822.HEADER")
 515           (if (nnimap-ver4-p)
 516               (mapconcat (lambda (part)
 517                            (format "BODY.PEEK[%s]" part))
 518                          parts " ")
 519             (mapconcat (lambda (part)
 520                          (format "RFC822.PEEK[%s]" part))
 521                        parts " ")))))
 522     (when result
 523       (nnimap-convert-partial-article structure))))
 524
 525 (defun nnimap-convert-partial-article (structure)
 526   ;; First just skip past the headers.
 527   (goto-char (point-min))
 528   (let ((bytes (nnimap-get-length))
 529         id parts)
 530     ;; Delete "FETCH" line.
 531     (delete-region (line-beginning-position)
 532                    (progn (forward-line 1) (point)))
 533     (goto-char (+ (point) bytes))
 534     ;; Collect all the body parts.
 535     (while (looking-at ".*BODY\\[\\([.0-9]+\\)\\]")
 536       (setq id (match-string 1)
 537             bytes (nnimap-get-length))
 538       (beginning-of-line)
 539       (delete-region (point) (progn (forward-line 1) (point)))
 540       (push (list id (buffer-substring (point) (+ (point) bytes)))
 541             parts)
 542       (delete-region (point) (+ (point) bytes)))
 543     ;; Delete trailing junk.
 544     (delete-region (point) (point-max))
 545     ;; Now insert all the parts again where they fit in the structure.
 546     (nnimap-insert-partial-structure structure parts)
 547     t))
 548
 549 (defun nnimap-insert-partial-structure (structure parts &optional subp)
 550   (let (type boundary)
 551     (let ((bstruc structure))
 552       (while (consp (car bstruc))
 553         (pop bstruc))
 554       (setq type (car bstruc))
 555       (setq bstruc (car (cdr bstruc)))
 556       (when (and (stringp (car bstruc))
 557                  (string= (downcase (car bstruc)) "boundary"))
 558         (setq boundary (cadr bstruc))))
 559     (when subp
 560       (insert (format "Content-type: multipart/%s; boundary=%S\n\n"
 561                       (downcase type) boundary)))
 562     (while (not (stringp (car structure)))
 563       (insert "\n--" boundary "\n")
 564       (if (consp (caar structure))
 565           (nnimap-insert-partial-structure (pop structure) parts t)
 566         (let ((bit (pop structure)))
 567           (insert (format  "Content-type: %s/%s"
 568                            (downcase (nth 0 bit))
 569                            (downcase (nth 1 bit))))
 570           (if (member "CHARSET" (nth 2 bit))
 571               (insert (format
 572                        "; charset=%S\n" (cadr (member "CHARSET" (nth 2 bit)))))
 573             (insert "\n"))
 574           (insert (format "Content-transfer-encoding: %s\n"
 575                           (nth 5 bit)))
 576           (insert "\n")
 577           (when (assoc (nth 9 bit) parts)
 578             (insert (cadr (assoc (nth 9 bit) parts)))))))
 579     (insert "\n--" boundary "--\n")))
 580
 581 (defun nnimap-find-wanted-parts (structure)
 582   (message-flatten-list (nnimap-find-wanted-parts-1 structure "")))
 583
 584 (defun nnimap-find-wanted-parts-1 (structure prefix)
 585   (let ((num 1)
 586         parts)
 587     (while (consp (car structure))
 588       (let ((sub (pop structure)))
 589         (if (consp (car sub))
 590             (push (nnimap-find-wanted-parts-1
 591                    sub (if (string= prefix "")
 592                            (number-to-string num)
 593                          (format "%s.%s" prefix num)))
 594                   parts)
 595           (let ((type (format "%s/%s" (nth 0 sub) (nth 1 sub)))
 596                 (id (if (string= prefix "")
 597                         (number-to-string num)
 598                       (format "%s.%s" prefix num))))
 599             (setcar (nthcdr 9 sub) id)
 600             (when (if (eq nnimap-fetch-partial-articles t)
 601                       (equal id "1")
 602                     (string-match nnimap-fetch-partial-articles type))
 603               (push id parts))))
 604         (incf num)))
 605     (nreverse parts)))
 606
 607 (deffoo nnimap-request-group (group &optional server dont-check info)
 608   (let ((result (nnimap-possibly-change-group group server))
 609         articles active marks high low)
 610     (with-current-buffer nntp-server-buffer
 611       (when result
 612         (if (and dont-check
 613                  (setq active (nth 2 (assoc group nnimap-current-infos))))
 614             (insert (format "211 %d %d %d %S\n"
 615                             (- (cdr active) (car active))
 616                             (car active)
 617                             (cdr active)
 618                             group))
 619           (with-current-buffer (nnimap-buffer)
 620             (erase-buffer)
 621             (let ((group-sequence
 622                    (nnimap-send-command "SELECT %S" (utf7-encode group t)))
 623                   (flag-sequence
 624                    (nnimap-send-command "UID FETCH 1:* FLAGS")))
 625               (nnimap-wait-for-response flag-sequence)
 626               (setq marks
 627                     (nnimap-flags-to-marks
 628                      (nnimap-parse-flags
 629                       (list (list group-sequence flag-sequence 1 group)))))
 630               (when info
 631                 (nnimap-update-infos marks (list info)))
 632               (goto-char (point-max))
 633               (let ((uidnext (nth 5 (car marks))))
 634                 (setq high (or (if uidnext
 635                                    (1- uidnext)
 636                                  (nth 3 (car marks)))
 637                                0)
 638                       low (or (nth 4 (car marks)) uidnext 1)))))
 639           (erase-buffer)
 640           (insert
 641            (format
 642             "211 %d %d %d %S\n" (1+ (- high low)) low high group)))
 643         t))))
 644
 645 (deffoo nnimap-request-create-group (group &optional server args)
 646   (when (nnimap-possibly-change-group nil server)
 647     (with-current-buffer (nnimap-buffer)
 648       (car (nnimap-command "CREATE %S" (utf7-encode group t))))))
 649
 650 (deffoo nnimap-request-delete-group (group &optional force server)
 651   (when (nnimap-possibly-change-group nil server)
 652     (with-current-buffer (nnimap-buffer)
 653       (car (nnimap-command "DELETE %S" (utf7-encode group t))))))
 654
 655 (deffoo nnimap-request-rename-group (group new-name &optional server)
 656   (when (nnimap-possibly-change-group nil server)
 657     (with-current-buffer (nnimap-buffer)
 658       (car (nnimap-command "RENAME %S %S" (utf7-encode group t) (utf7-encode new-name t))))))
 659
 660 (deffoo nnimap-request-expunge-group (group &optional server)
 661   (when (nnimap-possibly-change-group group server)
 662     (with-current-buffer (nnimap-buffer)
 663       (car (nnimap-command "EXPUNGE")))))
 664
 665 (defun nnimap-get-flags (spec)
 666   (let ((articles nil)
 667         elems)
 668     (with-current-buffer (nnimap-buffer)
 669       (erase-buffer)
 670       (nnimap-wait-for-response (nnimap-send-command
 671                                  "UID FETCH %s FLAGS" spec))
 672       (goto-char (point-min))
 673       (while (re-search-forward "^\\* [0-9]+ FETCH (\\(.*\\))" nil t)
 674         (setq elems (nnimap-parse-line (match-string 1)))
 675         (push (cons (string-to-number (cadr (member "UID" elems)))
 676                     (cadr (member "FLAGS" elems)))
 677               articles)))
 678     (nreverse articles)))
 679
 680 (deffoo nnimap-close-group (group &optional server)
 681   t)
 682
 683 (deffoo nnimap-request-move-article (article group server accept-form
 684                                              &optional last internal-move-group)
 685   (with-temp-buffer
 686     (when (nnimap-request-article article group server (current-buffer))
 687       ;; If the move is internal (on the same server), just do it the easy
 688       ;; way.
 689       (let ((message-id (message-field-value "message-id")))
 690         (if internal-move-group
 691             (let ((result
 692                    (with-current-buffer (nnimap-buffer)
 693                      (nnimap-command "UID COPY %d %S"
 694                                      article
 695                                      (utf7-encode internal-move-group t)))))
 696               (when (car result)
 697                 (nnimap-delete-article article)
 698                 (cons internal-move-group
 699                       (nnimap-find-article-by-message-id
 700                        internal-move-group message-id))))
 701           ;; Move the article to a different method.
 702           (let ((result (eval accept-form)))
 703             (when result
 704               (nnimap-delete-article article)
 705               result)))))))
 706
 707 (deffoo nnimap-request-expire-articles (articles group &optional server force)
 708   (cond
 709    ((null articles)
 710     nil)
 711    ((not (nnimap-possibly-change-group group server))
 712     articles)
 713    ((and force
 714          (eq nnmail-expiry-target 'delete))
 715     (unless (nnimap-delete-article (gnus-compress-sequence articles))
 716       (message "Article marked for deletion, but not expunged."))
 717     nil)
 718    (t
 719     (let ((deletable-articles
 720            (if (or force
 721                    (eq nnmail-expiry-wait 'immediate))
 722                articles
 723              (gnus-sorted-intersection
 724               articles
 725               (nnimap-find-expired-articles group)))))
 726       (if (null deletable-articles)
 727           articles
 728         (if (eq nnmail-expiry-target 'delete)
 729             (nnimap-delete-article (gnus-compress-sequence deletable-articles))
 730           (setq deletable-articles
 731                 (nnimap-process-expiry-targets
 732                  deletable-articles group server)))
 733         ;; Return the articles we didn't delete.
 734         (gnus-sorted-complement articles deletable-articles))))))
 735
 736 (defun nnimap-process-expiry-targets (articles group server)
 737   (let ((deleted-articles nil))
 738     (dolist (article articles)
 739       (let ((target nnmail-expiry-target))
 740         (with-temp-buffer
 741           (when (nnimap-request-article article group server (current-buffer))
 742             (message "Expiring article %s:%d" group article)
 743             (when (functionp target)
 744               (setq target (funcall target group)))
 745             (when (and target
 746                        (not (eq target 'delete)))
 747               (if (or (gnus-request-group target t)
 748                       (gnus-request-create-group target))
 749                   (nnmail-expiry-target-group target group)
 750                 (setq target nil)))
 751             (when target
 752               (push article deleted-articles))))))
 753     ;; Change back to the current group again.
 754     (nnimap-possibly-change-group group server)
 755     (setq deleted-articles (nreverse deleted-articles))
 756     (nnimap-delete-article (gnus-compress-sequence deleted-articles))
 757     deleted-articles))
 758
 759 (defun nnimap-find-expired-articles (group)
 760   (let ((cutoff (nnmail-expired-article-p group nil nil)))
 761     (with-current-buffer (nnimap-buffer)
 762       (let ((result
 763              (nnimap-command
 764               "UID SEARCH SENTBEFORE %s"
 765               (format-time-string
 766                (format "%%d-%s-%%Y"
 767                        (upcase
 768                         (car (rassoc (nth 4 (decode-time cutoff))
 769                                      parse-time-months))))
 770                cutoff))))
 771         (and (car result)
 772              (delete 0 (mapcar #'string-to-number
 773                                (cdr (assoc "SEARCH" (cdr result))))))))))
 774
 775
 776 (defun nnimap-find-article-by-message-id (group message-id)
 777   (with-current-buffer (nnimap-buffer)
 778     (erase-buffer)
 779     (setf (nnimap-group nnimap-object) nil)
 780     (nnimap-send-command "EXAMINE %S" (utf7-encode group t))
 781     (let ((sequence
 782            (nnimap-send-command "UID SEARCH HEADER Message-Id %S" message-id))
 783           article result)
 784       (setq result (nnimap-wait-for-response sequence))
 785       (when (and result
 786                  (car (setq result (nnimap-parse-response))))
 787         ;; Select the last instance of the message in the group.
 788         (and (setq article
 789                    (car (last (assoc "SEARCH" (cdr result)))))
 790              (string-to-number article))))))
 791
 792 (defun nnimap-delete-article (articles)
 793   (with-current-buffer (nnimap-buffer)
 794     (nnimap-command "UID STORE %s +FLAGS.SILENT (\\Deleted)"
 795                     (nnimap-article-ranges articles))
 796     (cond
 797      ((member "UIDPLUS" (nnimap-capabilities nnimap-object))
 798       (nnimap-command "UID EXPUNGE %s"
 799                       (nnimap-article-ranges articles))
 800       t)
 801      (nnimap-expunge
 802       (nnimap-command "EXPUNGE")
 803       t)
 804      (t (gnus-message 7 (concat "nnimap: nnimap-expunge is not set and the "
 805                                 "server doesn't support UIDPLUS, so we won't "
 806                                 "delete this article now"))))))
 807
 808 (deffoo nnimap-request-scan (&optional group server)
 809   (when (and (nnimap-possibly-change-group nil server)
 810              nnimap-inbox
 811              nnimap-split-methods)
 812     (message "nnimap %s splitting mail..." server)
 813     (nnimap-split-incoming-mail)))
 814
 815 (defun nnimap-marks-to-flags (marks)
 816   (let (flags flag)
 817     (dolist (mark marks)
 818       (when (setq flag (cadr (assq mark nnimap-mark-alist)))
 819         (push flag flags)))
 820     flags))
 821
 822 (deffoo nnimap-request-set-mark (group actions &optional server)
 823   (when (nnimap-possibly-change-group group server)
 824     (let (sequence)
 825       (with-current-buffer (nnimap-buffer)
 826         (erase-buffer)
 827         ;; Just send all the STORE commands without waiting for
 828         ;; response.  If they're successful, they're successful.
 829         (dolist (action actions)
 830           (destructuring-bind (range action marks) action
 831             (let ((flags (nnimap-marks-to-flags marks)))
 832               (when flags
 833                 (setq sequence (nnimap-send-command
 834                                 "UID STORE %s %sFLAGS.SILENT (%s)"
 835                                 (nnimap-article-ranges range)
 836                                 (if (eq action 'del)
 837                                     "-"
 838                                   "+")
 839                                 (mapconcat #'identity flags " ")))))))
 840         ;; Wait for the last command to complete to avoid later
 841         ;; syncronisation problems with the stream.
 842         (when sequence
 843           (nnimap-wait-for-response sequence))))))
 844
 845 (deffoo nnimap-request-accept-article (group &optional server last)
 846   (when (nnimap-possibly-change-group nil server)
 847     (nnmail-check-syntax)
 848     (let ((message-id (message-field-value "message-id"))
 849           sequence message)
 850       (nnimap-add-cr)
 851       (setq message (buffer-string))
 852       (with-current-buffer (nnimap-buffer)
 853         (setq sequence (nnimap-send-command
 854                         "APPEND %S {%d}" (utf7-encode group t)
 855                         (length message)))
 856         (process-send-string (get-buffer-process (current-buffer)) message)
 857         (process-send-string (get-buffer-process (current-buffer))
 858                              (if (nnimap-newlinep nnimap-object)
 859                                  "\n"
 860                                "\r\n"))
 861         (let ((result (nnimap-get-response sequence)))
 862           (if (not (car result))
 863               (progn
 864                 (message "%s" (nnheader-get-report-string 'nnimap))
 865                 nil)
 866             (cons group
 867                   (nnimap-find-article-by-message-id group message-id))))))))
 868
 869 (defun nnimap-add-cr ()
 870   (goto-char (point-min))
 871   (while (re-search-forward "\r?\n" nil t)
 872     (replace-match "\r\n" t t)))
 873
 874 (defun nnimap-get-groups ()
 875   (let ((result (nnimap-command "LIST \"\" \"*\""))
 876         groups)
 877     (when (car result)
 878       (dolist (line (cdr result))
 879         (when (and (equal (car line) "LIST")
 880                    (not (and (caadr line)
 881                              (string-match "noselect" (caadr line)))))
 882           (push (car (last line)) groups)))
 883       (nreverse groups))))
 884
 885 (deffoo nnimap-request-list (&optional server)
 886   (nnimap-possibly-change-group nil server)
 887   (with-current-buffer nntp-server-buffer
 888     (erase-buffer)
 889     (let ((groups
 890            (with-current-buffer (nnimap-buffer)
 891              (nnimap-get-groups)))
 892           sequences responses)
 893       (when groups
 894         (with-current-buffer (nnimap-buffer)
 895           (setf (nnimap-group nnimap-object) nil)
 896           (dolist (group groups)
 897             (push (list (nnimap-send-command "EXAMINE %S" (utf7-encode group t))
 898                         group)
 899                   sequences))
 900           (nnimap-wait-for-response (caar sequences))
 901           (setq responses
 902                 (nnimap-get-responses (mapcar #'car sequences))))
 903         (dolist (response responses)
 904           (let* ((sequence (car response))
 905                  (response (cadr response))
 906                  (group (cadr (assoc sequence sequences))))
 907             (when (and group
 908                        (equal (caar response) "OK"))
 909               (let ((uidnext (nnimap-find-parameter "UIDNEXT" response))
 910                     highest exists)
 911                 (dolist (elem response)
 912                   (when (equal (cadr elem) "EXISTS")
 913                     (setq exists (string-to-number (car elem)))))
 914                 (when uidnext
 915                   (setq highest (1- (string-to-number (car uidnext)))))
 916                 (cond
 917                  ((null highest)
 918                   (insert (format "%S 0 1 y\n" (utf7-decode group t))))
 919                  ((zerop exists)
 920                   ;; Empty group.
 921                   (insert (format "%S %d %d y\n"
 922                                   (utf7-decode group t) highest (1+ highest))))
 923                  (t
 924                   ;; Return the widest possible range.
 925                   (insert (format "%S %d 1 y\n" (utf7-decode group t)
 926                                   (or highest exists)))))))))
 927         t))))
 928
 929 (deffoo nnimap-request-newgroups (date &optional server)
 930   (nnimap-possibly-change-group nil server)
 931   (with-current-buffer nntp-server-buffer
 932     (erase-buffer)
 933     (dolist (group (with-current-buffer (nnimap-buffer)
 934                      (nnimap-get-groups)))
 935       (unless (assoc group nnimap-current-infos)
 936         ;; Insert dummy numbers here -- they don't matter.
 937         (insert (format "%S 0 1 y\n" group))))
 938     t))
 939
 940 (deffoo nnimap-retrieve-group-data-early (server infos)
 941   (when (nnimap-possibly-change-group nil server)
 942     (with-current-buffer (nnimap-buffer)
 943       ;; QRESYNC handling isn't implemented.
 944       (let ((qresyncp (member "notQRESYNC" (nnimap-capabilities nnimap-object)))
 945             marks groups sequences)
 946         ;; Go through the infos and gather the data needed to know
 947         ;; what and how to request the data.
 948         (dolist (info infos)
 949           (setq marks (gnus-info-marks info))
 950           (push (list (gnus-group-real-name (gnus-info-group info))
 951                       (cdr (assq 'active marks))
 952                       (cdr (assq 'uid marks)))
 953                 groups))
 954         ;; Then request the data.
 955         (erase-buffer)
 956         (setf (nnimap-group nnimap-object) nil)
 957         (dolist (elem groups)
 958           (if (and qresyncp
 959                    (nth 2 elem))
 960               (push
 961                (list 'qresync
 962                      (nnimap-send-command "EXAMINE %S (QRESYNC (%s %s))"
 963                                           (car elem)
 964                                           (car (nth 2 elem))
 965                                           (cdr (nth 2 elem)))
 966                      nil
 967                      (car elem))
 968                sequences)
 969             (let ((start
 970                    (if (nth 1 elem)
 971                        ;; Fetch the last 100 flags.
 972                        (max 1 (- (cdr (nth 1 elem)) 100))
 973                      1)))
 974               (push (list (nnimap-send-command "EXAMINE %S" (car elem))
 975                           (nnimap-send-command "UID FETCH %d:* FLAGS" start)
 976                           start
 977                           (car elem))
 978                     sequences)))
 979           ;; Some servers apparently can't have many outstanding
 980           ;; commands, so throttle them.
 981           (when (and (not nnimap-streaming)
 982                      (car sequences))
 983             (nnimap-wait-for-response (caar sequences))))
 984         sequences))))
 985
 986 (deffoo nnimap-finish-retrieve-group-infos (server infos sequences)
 987   (when (and sequences
 988              (nnimap-possibly-change-group nil server))
 989     (with-current-buffer (nnimap-buffer)
 990       ;; Wait for the final data to trickle in.
 991       (when (nnimap-wait-for-response (cadar sequences) t)
 992         ;; Now we should have all the data we need, no matter whether
 993         ;; we're QRESYNCING, fetching all the flags from scratch, or
 994         ;; just fetching the last 100 flags per group.
 995         (nnimap-update-infos (nnimap-flags-to-marks
 996                               (nnimap-parse-flags
 997                                (nreverse sequences)))
 998                              infos)
 999         ;; Finally, just return something resembling an active file in
1000         ;; the nntp buffer, so that the agent can save the info, too.
1001         (with-current-buffer nntp-server-buffer
1002           (erase-buffer)
1003           (dolist (info infos)
1004             (let* ((group (gnus-info-group info))
1005                    (active (gnus-active group)))
1006               (when active
1007                 (insert (format "%S %d %d y\n"
1008                                 (gnus-group-real-name group)
1009                                 (cdr active)
1010                                 (car active)))))))))))
1011
1012 (defun nnimap-update-infos (flags infos)
1013   (dolist (info infos)
1014     (let ((group (gnus-group-real-name (gnus-info-group info))))
1015       (nnimap-update-info info (cdr (assoc group flags))))))
1016
1017 (defun nnimap-update-info (info marks)
1018   (when (and marks
1019              ;; Ignore groups with no UIDNEXT values.
1020              (nth 4 marks))
1021     (destructuring-bind (existing flags high low uidnext start-article
1022                                   permanent-flags) marks
1023       (let ((group (gnus-info-group info))
1024             (completep (and start-article
1025                             (= start-article 1))))
1026         (when uidnext
1027           (setq high (1- uidnext)))
1028         ;; First set the active ranges based on high/low.
1029         (if (or completep
1030                 (not (gnus-active group)))
1031             (gnus-set-active group
1032                              (cond
1033                               ((and low high)
1034                                (cons low high))
1035                               (uidnext
1036                                ;; No articles in this group.
1037                                (cons uidnext (1- uidnext)))
1038                               (start-article
1039                                (cons start-article (1- start-article)))
1040                               (t
1041                                ;; No articles and no uidnext.
1042                                nil)))
1043           (gnus-set-active
1044            group
1045            (cons (car (gnus-active group))
1046                  (or high (1- uidnext)))))
1047         ;; Then update the list of read articles.
1048         (let* ((unread
1049                 (gnus-compress-sequence
1050                  (gnus-set-difference
1051                   (gnus-set-difference
1052                    existing
1053                    (cdr (assoc '%Seen flags)))
1054                   (cdr (assoc '%Flagged flags)))))
1055                (read (gnus-range-difference
1056                       (cons start-article high) unread)))
1057           (when (> start-article 1)
1058             (setq read
1059                   (gnus-range-nconcat
1060                    (if (> start-article 1)
1061                        (gnus-sorted-range-intersection
1062                         (cons 1 (1- start-article))
1063                         (gnus-info-read info))
1064                      (gnus-info-read info))
1065                    read)))
1066           (gnus-info-set-read info read)
1067           ;; Update the marks.
1068           (setq marks (gnus-info-marks info))
1069           ;; Note the active level for the next run-through.
1070           (let ((active (assq 'active marks)))
1071             (if active
1072                 (setcdr active (gnus-active group))
1073               (push (cons 'active (gnus-active group)) marks)))
1074           (dolist (type (cdr nnimap-mark-alist))
1075             (let ((old-marks (assoc (car type) marks))
1076                   (new-marks
1077                    (gnus-compress-sequence
1078                     (cdr (or (assoc (caddr type) flags)     ; %Flagged
1079                              (assoc (intern (cadr type) obarray) flags)
1080                              (assoc (cadr type) flags)))))) ; "\Flagged"
1081               (setq marks (delq old-marks marks))
1082               (pop old-marks)
1083               (when (and old-marks
1084                          (> start-article 1))
1085                 (setq old-marks (gnus-range-difference
1086                                  old-marks
1087                                  (cons start-article high)))
1088                 (setq new-marks (gnus-range-nconcat old-marks new-marks)))
1089               (when new-marks
1090                 (push (cons (car type) new-marks) marks)))
1091             (gnus-info-set-marks info marks t)
1092             (nnimap-store-info info (gnus-active group))))))))
1093
1094 (defun nnimap-store-info (info active)
1095   (let* ((group (gnus-group-real-name (gnus-info-group info)))
1096          (entry (assoc group nnimap-current-infos)))
1097     (if entry
1098         (setcdr entry (list info active))
1099       (push (list group info active) nnimap-current-infos))))
1100
1101 (defun nnimap-flags-to-marks (groups)
1102   (let (data group totalp uidnext articles start-article mark permanent-flags)
1103     (dolist (elem groups)
1104       (setq group (car elem)
1105             uidnext (nth 1 elem)
1106             start-article (nth 2 elem)
1107             permanent-flags (nth 3 elem)
1108             articles (nthcdr 4 elem))
1109       (let ((high (caar articles))
1110             marks low existing)
1111         (dolist (article articles)
1112           (setq low (car article))
1113           (push (car article) existing)
1114           (dolist (flag (cdr article))
1115             (setq mark (assoc flag marks))
1116             (if (not mark)
1117                 (push (list flag (car article)) marks)
1118               (setcdr mark (cons (car article) (cdr mark))))))
1119         (push (list group existing marks high low uidnext start-article
1120                     permanent-flags)
1121               data)))
1122     data))
1123
1124 (defun nnimap-parse-flags (sequences)
1125   (goto-char (point-min))
1126   ;; Change \Delete etc to %Delete, so that the reader can read it.
1127   (subst-char-in-region (point-min) (point-max)
1128                         ?\\ ?% t)
1129   (let (start end articles groups uidnext elems permanent-flags)
1130     (dolist (elem sequences)
1131       (destructuring-bind (group-sequence flag-sequence totalp group) elem
1132         (setq start (point))
1133         ;; The EXAMINE was successful.
1134         (when (and (search-forward (format "\n%d OK " group-sequence) nil t)
1135                    (progn
1136                      (forward-line 1)
1137                      (setq end (point))
1138                      (goto-char start)
1139                      (setq permanent-flags
1140                            (and (search-forward "PERMANENTFLAGS "
1141                                                  (or end (point-min)) t)
1142                                 (read (current-buffer))))
1143                      (goto-char start)
1144                      (setq uidnext
1145                            (and (search-forward "UIDNEXT "
1146                                                  (or end (point-min)) t)
1147                                 (read (current-buffer))))
1148                      (goto-char end)
1149                      (forward-line -1))
1150                    ;; The UID FETCH FLAGS was successful.
1151                    (search-forward (format "\n%d OK " flag-sequence) nil t))
1152           (setq start (point))
1153           (goto-char end)
1154           (while (search-forward " FETCH " start t)
1155             (setq elems (read (current-buffer)))
1156             (push (cons (cadr (memq 'UID elems))
1157                         (cadr (memq 'FLAGS elems)))
1158                   articles))
1159           (push (nconc (list group uidnext totalp permanent-flags) articles)
1160                 groups)
1161           (setq articles nil))))
1162     groups))
1163
1164 (defun nnimap-find-process-buffer (buffer)
1165   (cadr (assoc buffer nnimap-connection-alist)))
1166
1167 (deffoo nnimap-request-post (&optional server)
1168   (setq nnimap-status-string "Read-only server")
1169   nil)
1170
1171 (defun nnimap-possibly-change-group (group server)
1172   (let ((open-result t))
1173     (when (and server
1174                (not (nnimap-server-opened server)))
1175       (setq open-result (nnimap-open-server server)))
1176     (cond
1177      ((not open-result)
1178       nil)
1179      ((not group)
1180       t)
1181      (t
1182       (with-current-buffer (nnimap-buffer)
1183         (if (equal group (nnimap-group nnimap-object))
1184             t
1185           (let ((result (nnimap-command "SELECT %S" (utf7-encode group t))))
1186             (when (car result)
1187               (setf (nnimap-group nnimap-object) group
1188                     (nnimap-select-result nnimap-object) result)
1189               result))))))))
1190
1191 (defun nnimap-find-connection (buffer)
1192   "Find the connection delivering to BUFFER."
1193   (let ((entry (assoc buffer nnimap-connection-alist)))
1194     (when entry
1195       (if (and (buffer-name (cadr entry))
1196                (get-buffer-process (cadr entry))
1197                (memq (process-status (get-buffer-process (cadr entry)))
1198                      '(open run)))
1199           (get-buffer-process (cadr entry))
1200         (setq nnimap-connection-alist (delq entry nnimap-connection-alist))
1201         nil))))
1202
1203 (defvar nnimap-sequence 0)
1204
1205 (defun nnimap-send-command (&rest args)
1206   (process-send-string
1207    (get-buffer-process (current-buffer))
1208    (nnimap-log-command
1209     (format "%d %s%s\n"
1210             (incf nnimap-sequence)
1211             (apply #'format args)
1212             (if (nnimap-newlinep nnimap-object)
1213                 ""
1214               "\r"))))
1215   nnimap-sequence)
1216
1217 (defun nnimap-log-command (command)
1218   (with-current-buffer (get-buffer-create "*imap log*")
1219     (goto-char (point-max))
1220     (insert (format-time-string "%H:%M:%S") " " command))
1221   command)
1222
1223 (defun nnimap-command (&rest args)
1224   (erase-buffer)
1225   (setf (nnimap-last-command-time nnimap-object) (current-time))
1226   (let* ((sequence (apply #'nnimap-send-command args))
1227          (response (nnimap-get-response sequence)))
1228     (if (equal (caar response) "OK")
1229         (cons t response)
1230       (nnheader-report 'nnimap "%s"
1231                        (mapconcat (lambda (a)
1232                                     (format "%s" a))
1233                                   (car response) " "))
1234       nil)))
1235
1236 (defun nnimap-get-response (sequence)
1237   (nnimap-wait-for-response sequence)
1238   (nnimap-parse-response))
1239
1240 (defun nnimap-wait-for-connection ()
1241   (let ((process (get-buffer-process (current-buffer))))
1242     (goto-char (point-min))
1243     (while (and (memq (process-status process)
1244                       '(open run))
1245                 (not (re-search-forward "^[*.] .*\n" nil t)))
1246       (nnheader-accept-process-output process)
1247       (goto-char (point-min)))
1248     (forward-line -1)
1249     (and (looking-at "[*.] \\([A-Z0-9]+\\)")
1250          (match-string 1))))
1251
1252 (defun nnimap-wait-for-response (sequence &optional messagep)
1253   (let ((process (get-buffer-process (current-buffer)))
1254         openp)
1255     (goto-char (point-max))
1256     (while (and (setq openp (memq (process-status process)
1257                                   '(open run)))
1258                 (not (re-search-backward
1259                       (format "^%d .*\n" sequence)
1260                       (if nnimap-streaming
1261                           (max (point-min) (- (point) 500))
1262                         (point-min))
1263                       t)))
1264       (when messagep
1265         (message "nnimap read %dk" (/ (buffer-size) 1000)))
1266       (nnheader-accept-process-output process)
1267       (goto-char (point-max)))
1268     openp))
1269
1270 (defun nnimap-parse-response ()
1271   (let ((lines (split-string (nnimap-last-response-string) "\r\n" t))
1272         result)
1273     (dolist (line lines)
1274       (push (cdr (nnimap-parse-line line)) result))
1275     ;; Return the OK/error code first, and then all the "continuation
1276     ;; lines" afterwards.
1277     (cons (pop result)
1278           (nreverse result))))
1279
1280 ;; Parse an IMAP response line lightly.  They look like
1281 ;; "* OK [UIDVALIDITY 1164213559] UIDs valid", typically, so parse
1282 ;; the lines into a list of strings and lists of string.
1283 (defun nnimap-parse-line (line)
1284   (let (char result)
1285     (with-temp-buffer
1286       (insert line)
1287       (goto-char (point-min))
1288       (while (not (eobp))
1289         (if (eql (setq char (following-char)) ? )
1290             (forward-char 1)
1291           (push
1292            (cond
1293             ((eql char ?\[)
1294              (split-string (buffer-substring
1295                             (1+ (point))
1296                             (1- (search-forward "]" (line-end-position) 'move)))))
1297             ((eql char ?\()
1298              (split-string (buffer-substring
1299                             (1+ (point))
1300                             (1- (search-forward ")" (line-end-position) 'move)))))
1301             ((eql char ?\")
1302              (forward-char 1)
1303              (buffer-substring
1304               (point)
1305               (1- (or (search-forward "\"" (line-end-position) 'move)
1306                       (point)))))
1307             (t
1308              (buffer-substring (point) (if (search-forward " " nil t)
1309                                            (1- (point))
1310                                          (goto-char (point-max))))))
1311            result)))
1312       (nreverse result))))
1313
1314 (defun nnimap-last-response-string ()
1315   (save-excursion
1316     (forward-line 1)
1317     (let ((end (point)))
1318       (forward-line -1)
1319       (when (not (bobp))
1320         (forward-line -1)
1321         (while (and (not (bobp))
1322                     (eql (following-char) ?*))
1323           (forward-line -1))
1324         (unless (eql (following-char) ?*)
1325           (forward-line 1)))
1326       (buffer-substring (point) end))))
1327
1328 (defun nnimap-get-responses (sequences)
1329   (let (responses)
1330     (dolist (sequence sequences)
1331       (goto-char (point-min))
1332       (when (re-search-forward (format "^%d " sequence) nil t)
1333         (push (list sequence (nnimap-parse-response))
1334               responses)))
1335     responses))
1336
1337 (defvar nnimap-incoming-split-list nil)
1338
1339 (defun nnimap-fetch-inbox (articles)
1340   (erase-buffer)
1341   (nnimap-wait-for-response
1342    (nnimap-send-command
1343     "UID FETCH %s %s"
1344     (nnimap-article-ranges articles)
1345     (format "(UID %s%s)"
1346             (format
1347              (if (nnimap-ver4-p)
1348                  "BODY.PEEK[HEADER] BODY.PEEK"
1349                "RFC822.PEEK"))
1350             (if nnimap-split-download-body-default
1351                 "[]"
1352               "[1]")))
1353    t))
1354
1355 (defun nnimap-split-incoming-mail ()
1356   (with-current-buffer (nnimap-buffer)
1357     (let ((nnimap-incoming-split-list nil)
1358           (nnmail-split-methods (if (eq nnimap-split-methods 'default)
1359                                     nnmail-split-methods
1360                                   nnimap-split-methods))
1361           (nnmail-split-fancy (or nnimap-split-fancy
1362                                   nnmail-split-fancy))
1363           (nnmail-inhibit-default-split-group t)
1364           (groups (nnimap-get-groups))
1365           new-articles)
1366       (erase-buffer)
1367       (nnimap-command "SELECT %S" nnimap-inbox)
1368       (setq new-articles (nnimap-new-articles (nnimap-get-flags "1:*")))
1369       (when new-articles
1370         (nnimap-fetch-inbox new-articles)
1371         (nnimap-transform-split-mail)
1372         (nnheader-ms-strip-cr)
1373         (nnmail-cache-open)
1374         (nnmail-split-incoming (current-buffer)
1375                                #'nnimap-save-mail-spec
1376                                nil nil
1377                                #'nnimap-dummy-active-number
1378                                #'nnimap-save-mail-spec)
1379         (when nnimap-incoming-split-list
1380           (let ((specs (nnimap-make-split-specs nnimap-incoming-split-list))
1381                 sequences junk-articles)
1382             ;; Create any groups that doesn't already exist on the
1383             ;; server first.
1384             (dolist (spec specs)
1385               (when (and (not (member (car spec) groups))
1386                          (not (eq (car spec) 'junk)))
1387                 (nnimap-command "CREATE %S" (utf7-encode (car spec) t))))
1388             ;; Then copy over all the messages.
1389             (erase-buffer)
1390             (dolist (spec specs)
1391               (let ((group (car spec))
1392                     (ranges (cdr spec)))
1393                 (if (eq group 'junk)
1394                     (setq junk-articles ranges)
1395                   (push (list (nnimap-send-command
1396                                "UID COPY %s %S"
1397                                (nnimap-article-ranges ranges)
1398                                (utf7-encode group t))
1399                               ranges)
1400                         sequences))))
1401             ;; Wait for the last COPY response...
1402             (when sequences
1403               (nnimap-wait-for-response (caar sequences))
1404               ;; And then mark the successful copy actions as deleted,
1405               ;; and possibly expunge them.
1406               (nnimap-mark-and-expunge-incoming
1407                (nnimap-parse-copied-articles sequences)))
1408             (nnimap-mark-and-expunge-incoming junk-articles)))))))
1409
1410 (defun nnimap-mark-and-expunge-incoming (range)
1411   (when range
1412     (setq range (nnimap-article-ranges range))
1413     (erase-buffer)
1414     (let ((sequence
1415            (nnimap-send-command
1416             "UID STORE %s +FLAGS.SILENT (\\Deleted)" range)))
1417       (cond
1418        ;; If the server supports it, we now delete the message we have
1419        ;; just copied over.
1420        ((member "UIDPLUS" (nnimap-capabilities nnimap-object))
1421         (setq sequence (nnimap-send-command "UID EXPUNGE %s" range)))
1422        ;; If it doesn't support UID EXPUNGE, then we only expunge if the
1423        ;; user has configured it.
1424        (nnimap-expunge
1425         (setq sequence (nnimap-send-command "EXPUNGE"))))
1426       (nnimap-wait-for-response sequence))))
1427
1428 (defun nnimap-parse-copied-articles (sequences)
1429   (let (sequence copied range)
1430     (goto-char (point-min))
1431     (while (re-search-forward "^\\([0-9]+\\) OK " nil t)
1432       (setq sequence (string-to-number (match-string 1)))
1433       (when (setq range (cadr (assq sequence sequences)))
1434         (push (gnus-uncompress-range range) copied)))
1435     (gnus-compress-sequence (sort (apply #'nconc copied) #'<))))
1436
1437 (defun nnimap-new-articles (flags)
1438   (let (new)
1439     (dolist (elem flags)
1440       (when (or (null (cdr elem))
1441                 (and (not (memq '%Deleted (cdr elem)))
1442                      (not (memq '%Seen (cdr elem)))))
1443         (push (car elem) new)))
1444     (gnus-compress-sequence (nreverse new))))
1445
1446 (defun nnimap-make-split-specs (list)
1447   (let ((specs nil)
1448         entry)
1449     (dolist (elem list)
1450       (destructuring-bind (article spec) elem
1451         (dolist (group (delete nil (mapcar #'car spec)))
1452           (unless (setq entry (assoc group specs))
1453             (push (setq entry (list group)) specs))
1454           (setcdr entry (cons article (cdr entry))))))
1455     (dolist (entry specs)
1456       (setcdr entry (gnus-compress-sequence (sort (cdr entry) #'<))))
1457     specs))
1458
1459 (defun nnimap-transform-split-mail ()
1460   (goto-char (point-min))
1461   (let (article bytes)
1462     (block nil
1463       (while (not (eobp))
1464         (while (not (looking-at "^\\* [0-9]+ FETCH.*UID \\([0-9]+\\)"))
1465           (delete-region (point) (progn (forward-line 1) (point)))
1466           (when (eobp)
1467             (return)))
1468         (setq article (match-string 1)
1469               bytes (nnimap-get-length))
1470         (delete-region (line-beginning-position) (line-end-position))
1471         ;; Insert MMDF separator, and a way to remember what this
1472         ;; article UID is.
1473         (insert (format "\^A\^A\^A\^A\n\nX-nnimap-article: %s" article))
1474         (forward-char (1+ bytes))
1475         (setq bytes (nnimap-get-length))
1476         (delete-region (line-beginning-position) (line-end-position))
1477         (forward-char (1+ bytes))
1478         (delete-region (line-beginning-position) (line-end-position))))))
1479
1480 (defun nnimap-dummy-active-number (group &optional server)
1481   1)
1482
1483 (defun nnimap-save-mail-spec (group-art &optional server full-nov)
1484   (let (article)
1485     (goto-char (point-min))
1486     (if (not (re-search-forward "X-nnimap-article: \\([0-9]+\\)" nil t))
1487         (error "Invalid nnimap mail")
1488       (setq article (string-to-number (match-string 1))))
1489     (push (list article
1490                 (if (eq group-art 'junk)
1491                     (list (cons 'junk 1))
1492                   group-art))
1493           nnimap-incoming-split-list)))
1494
1495 (provide 'nnimap)
1496
1497 ;;; nnimap.el ends here