cgit.sxemacs.org Git - gnus/blob - lisp/nnimap.el

   1 ;;; nnimap.el --- IMAP interface for Gnus
   2
   3 ;; Copyright (C) 2010-2012 Free Software Foundation, Inc.
   4
   5 ;; Author: Lars Magne Ingebrigtsen <larsi@gnus.org>
   6 ;;         Simon Josefsson <simon@josefsson.org>
   7
   8 ;; This file is part of GNU Emacs.
   9
  10 ;; GNU Emacs is free software: you can redistribute it and/or modify
  11 ;; it under the terms of the GNU General Public License as published by
  12 ;; the Free Software Foundation, either version 3 of the License, or
  13 ;; (at your option) any later version.
  14
  15 ;; GNU Emacs is distributed in the hope that it will be useful,
  16 ;; but WITHOUT ANY WARRANTY; without even the implied warranty of
  17 ;; MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.  See the
  18 ;; GNU General Public License for more details.
  19
  20 ;; You should have received a copy of the GNU General Public License
  21 ;; along with GNU Emacs.  If not, see <http://www.gnu.org/licenses/>.
  22
  23 ;;; Commentary:
  24
  25 ;; nnimap interfaces Gnus with IMAP servers.
  26
  27 ;;; Code:
  28
  29 ;; For Emacs <22.2 and XEmacs.
  30 (eval-and-compile
  31   (unless (fboundp 'declare-function) (defmacro declare-function (&rest r))))
  32
  33 (eval-and-compile
  34   (require 'nnheader)
  35   ;; In Emacs 24, `open-protocol-stream' is an autoloaded alias for
  36   ;; `make-network-stream'.
  37   (unless (fboundp 'open-protocol-stream)
  38     (require 'proto-stream)))
  39
  40 (eval-when-compile
  41   (require 'cl))
  42
  43 (require 'nnheader)
  44 (require 'gnus-util)
  45 (require 'gnus)
  46 (require 'nnoo)
  47 (require 'netrc)
  48 (require 'utf7)
  49 (require 'tls)
  50 (require 'parse-time)
  51 (require 'nnmail)
  52
  53 (autoload 'auth-source-forget+ "auth-source")
  54 (autoload 'auth-source-search "auth-source")
  55
  56 (nnoo-declare nnimap)
  57
  58 (defvoo nnimap-address nil
  59   "The address of the IMAP server.")
  60
  61 (defvoo nnimap-user nil
  62   "Username to use for authentication to the IMAP server.")
  63
  64 (defvoo nnimap-server-port nil
  65   "The IMAP port used.
  66 If nnimap-stream is `ssl', this will default to `imaps'.  If not,
  67 it will default to `imap'.")
  68
  69 (defvoo nnimap-stream 'undecided
  70   "How nnimap talks to the IMAP server.
  71 The value should be either `undecided', `ssl' or `tls',
  72 `network', `starttls', `plain', or `shell'.
  73
  74 If the value is `undecided', nnimap tries `ssl' first, then falls
  75 back on `network'.")
  76
  77 (defvoo nnimap-shell-program (if (boundp 'imap-shell-program)
  78                                  (if (listp imap-shell-program)
  79                                      (car imap-shell-program)
  80                                    imap-shell-program)
  81                                "ssh %s imapd"))
  82
  83 (defvoo nnimap-inbox nil
  84   "The mail box where incoming mail arrives and should be split out of.
  85 This can be a string or a list of strings
  86 For example, \"INBOX\" or (\"INBOX\" \"SENT\").")
  87
  88 (defvoo nnimap-split-methods nil
  89   "How mail is split.
  90 Uses the same syntax as `nnmail-split-methods'.")
  91
  92 (defvoo nnimap-split-fancy nil
  93   "Uses the same syntax as `nnmail-split-fancy'.")
  94
  95 (defvoo nnimap-unsplittable-articles '(%Deleted %Seen)
  96   "Articles with the flags in the list will not be considered when splitting.")
  97
  98 (make-obsolete-variable 'nnimap-split-rule "see `nnimap-split-methods'"
  99                         "Emacs 24.1")
 100
 101 (defvoo nnimap-authenticator nil
 102   "How nnimap authenticate itself to the server.
 103 Possible choices are nil (use default methods) or `anonymous'.")
 104
 105 (defvoo nnimap-expunge t
 106   "If non-nil, expunge articles after deleting them.
 107 This is always done if the server supports UID EXPUNGE, but it's
 108 not done by default on servers that doesn't support that command.")
 109
 110 (defvoo nnimap-streaming t
 111   "If non-nil, try to use streaming commands with IMAP servers.
 112 Switching this off will make nnimap slower, but it helps with
 113 some servers.")
 114
 115 (defvoo nnimap-connection-alist nil)
 116
 117 (defvoo nnimap-current-infos nil)
 118
 119 (defvoo nnimap-fetch-partial-articles nil
 120   "If non-nil, Gnus will fetch partial articles.
 121 If t, Gnus will fetch only the first part.  If a string, it
 122 will fetch all parts that have types that match that string.  A
 123 likely value would be \"text/\" to automatically fetch all
 124 textual parts.")
 125
 126 (defgroup nnimap nil
 127   "IMAP for Gnus."
 128   :group 'gnus)
 129
 130 (defcustom nnimap-request-articles-find-limit nil
 131   "Limit the number of articles to look for after moving an article."
 132   :type 'integer
 133   :version "24.3"
 134   :group 'nnimap)
 135
 136 (defvar nnimap-process nil)
 137
 138 (defvar nnimap-status-string "")
 139
 140 (defvar nnimap-split-download-body-default nil
 141   "Internal variable with default value for `nnimap-split-download-body'.")
 142
 143 (defvar nnimap-keepalive-timer nil)
 144 (defvar nnimap-process-buffers nil)
 145
 146 (defstruct nnimap
 147   group process commands capabilities select-result newlinep server
 148   last-command-time greeting examined stream-type initial-resync)
 149
 150 (defvar nnimap-object nil)
 151
 152 (defvar nnimap-mark-alist
 153   '((read "\\Seen" %Seen)
 154     (tick "\\Flagged" %Flagged)
 155     (reply "\\Answered" %Answered)
 156     (expire "gnus-expire")
 157     (dormant "gnus-dormant")
 158     (score "gnus-score")
 159     (save "gnus-save")
 160     (download "gnus-download")
 161     (forward "gnus-forward")))
 162
 163 (defvar nnimap-quirks
 164   '(("QRESYNC" "Zimbra" "QRESYNC ")))
 165
 166 (defvar nnimap-inhibit-logging nil)
 167
 168 (defun nnimap-buffer ()
 169   (nnimap-find-process-buffer nntp-server-buffer))
 170
 171 (defun nnimap-header-parameters ()
 172   (format "(UID RFC822.SIZE BODYSTRUCTURE %s)"
 173           (format
 174            (if (nnimap-ver4-p)
 175                "BODY.PEEK[HEADER.FIELDS %s]"
 176              "RFC822.HEADER.LINES %s")
 177            (append '(Subject From Date Message-Id
 178                              References In-Reply-To Xref)
 179                    nnmail-extra-headers))))
 180
 181 (deffoo nnimap-retrieve-headers (articles &optional group server fetch-old)
 182   (when group
 183     (setq group (nnimap-decode-gnus-group group)))
 184   (with-current-buffer nntp-server-buffer
 185     (erase-buffer)
 186     (when (nnimap-change-group group server)
 187       (with-current-buffer (nnimap-buffer)
 188         (erase-buffer)
 189         (nnimap-wait-for-response
 190          (nnimap-send-command
 191           "UID FETCH %s %s"
 192           (nnimap-article-ranges (gnus-compress-sequence articles))
 193           (nnimap-header-parameters))
 194          t)
 195         (nnimap-transform-headers)
 196         (nnheader-remove-cr-followed-by-lf))
 197       (insert-buffer-substring
 198        (nnimap-find-process-buffer (current-buffer))))
 199     'headers))
 200
 201 (defun nnimap-transform-headers ()
 202   (goto-char (point-min))
 203   (let (article lines size string)
 204     (block nil
 205       (while (not (eobp))
 206         (while (not (looking-at "\\* [0-9]+ FETCH"))
 207           (delete-region (point) (progn (forward-line 1) (point)))
 208           (when (eobp)
 209             (return)))
 210         (goto-char (match-end 0))
 211         ;; Unfold quoted {number} strings.
 212         (while (re-search-forward
 213                 "[^]][ (]{\\([0-9]+\\)}\r?\n"
 214                 (save-excursion
 215                   ;; Start of the header section.
 216                   (or (re-search-forward "] {[0-9]+}\r?\n" nil t)
 217                       ;; Start of the next FETCH.
 218                       (re-search-forward "\\* [0-9]+ FETCH" nil t)
 219                       (point-max)))
 220                 t)
 221           (setq size (string-to-number (match-string 1)))
 222           (delete-region (+ (match-beginning 0) 2) (point))
 223           (setq string (buffer-substring (point) (+ (point) size)))
 224           (delete-region (point) (+ (point) size))
 225           (insert (format "%S" (mm-subst-char-in-string ?\n ?\s string))))
 226         (beginning-of-line)
 227         (setq article
 228               (and (re-search-forward "UID \\([0-9]+\\)" (line-end-position)
 229                                       t)
 230                    (match-string 1)))
 231         (setq lines nil)
 232         (setq size
 233               (and (re-search-forward "RFC822.SIZE \\([0-9]+\\)"
 234                                       (line-end-position)
 235                                       t)
 236                    (match-string 1)))
 237         (beginning-of-line)
 238         (when (search-forward "BODYSTRUCTURE" (line-end-position) t)
 239           (let ((structure (ignore-errors
 240                              (read (current-buffer)))))
 241             (while (and (consp structure)
 242                         (not (atom (car structure))))
 243               (setq structure (car structure)))
 244             (setq lines (if (and
 245                              (stringp (car structure))
 246                              (equal (upcase (nth 0 structure)) "MESSAGE")
 247                              (equal (upcase (nth 1 structure)) "RFC822"))
 248                             (nth 9 structure)
 249                           (nth 7 structure)))))
 250         (delete-region (line-beginning-position) (line-end-position))
 251         (insert (format "211 %s Article retrieved." article))
 252         (forward-line 1)
 253         (when size
 254           (insert (format "Chars: %s\n" size)))
 255         (when lines
 256           (insert (format "Lines: %s\n" lines)))
 257         (unless (re-search-forward "^\r$" nil t)
 258           (goto-char (point-max)))
 259         (delete-region (line-beginning-position) (line-end-position))
 260         (insert ".")
 261         (forward-line 1)))))
 262
 263 (defun nnimap-unfold-quoted-lines ()
 264   ;; Unfold quoted {number} strings.
 265   (let (size string)
 266     (while (re-search-forward " {\\([0-9]+\\)}\r?\n" nil t)
 267       (setq size (string-to-number (match-string 1)))
 268       (delete-region (1+ (match-beginning 0)) (point))
 269       (setq string (buffer-substring (point) (+ (point) size)))
 270       (delete-region (point) (+ (point) size))
 271       (insert (format "%S" string)))))
 272
 273 (defun nnimap-get-length ()
 274   (and (re-search-forward "{\\([0-9]+\\)}" (line-end-position) t)
 275        (string-to-number (match-string 1))))
 276
 277 (defun nnimap-article-ranges (ranges)
 278   (let (result)
 279     (cond
 280      ((numberp ranges)
 281       (number-to-string ranges))
 282      ((numberp (cdr ranges))
 283       (format "%d:%d" (car ranges) (cdr ranges)))
 284      (t
 285       (dolist (elem ranges)
 286         (push
 287          (if (consp elem)
 288              (format "%d:%d" (car elem) (cdr elem))
 289            (number-to-string elem))
 290          result))
 291       (mapconcat #'identity (nreverse result) ",")))))
 292
 293 (deffoo nnimap-open-server (server &optional defs no-reconnect)
 294   (if (nnimap-server-opened server)
 295       t
 296     (unless (assq 'nnimap-address defs)
 297       (setq defs (append defs (list (list 'nnimap-address server)))))
 298     (nnoo-change-server 'nnimap server defs)
 299     (if no-reconnect
 300         (nnimap-find-connection nntp-server-buffer)
 301       (or (nnimap-find-connection nntp-server-buffer)
 302           (nnimap-open-connection nntp-server-buffer)))))
 303
 304 (defun nnimap-make-process-buffer (buffer)
 305   (with-current-buffer
 306       (generate-new-buffer (format " *nnimap %s %s %s*"
 307                                    nnimap-address nnimap-server-port
 308                                    (gnus-buffer-exists-p buffer)))
 309     (mm-disable-multibyte)
 310     (buffer-disable-undo)
 311     (gnus-add-buffer)
 312     (set (make-local-variable 'after-change-functions) nil)
 313     (set (make-local-variable 'nnimap-object)
 314          (make-nnimap :server (nnoo-current-server 'nnimap)
 315                       :initial-resync 0))
 316     (push (list buffer (current-buffer)) nnimap-connection-alist)
 317     (push (current-buffer) nnimap-process-buffers)
 318     (current-buffer)))
 319
 320 (defun nnimap-credentials (address ports user)
 321   (let* ((auth-source-creation-prompts
 322           '((user  . "IMAP user at %h: ")
 323             (secret . "IMAP password for %u@%h: ")))
 324          (found (nth 0 (auth-source-search :max 1
 325                                            :host address
 326                                            :port ports
 327                                            :user user
 328                                            :require '(:user :secret)
 329                                            :create t))))
 330     (if found
 331         (list (plist-get found :user)
 332               (let ((secret (plist-get found :secret)))
 333                 (if (functionp secret)
 334                     (funcall secret)
 335                   secret))
 336               (plist-get found :save-function))
 337       nil)))
 338
 339 (defun nnimap-keepalive ()
 340   (let ((now (current-time)))
 341     (dolist (buffer nnimap-process-buffers)
 342       (when (buffer-name buffer)
 343         (with-current-buffer buffer
 344           (when (and nnimap-object
 345                      (nnimap-last-command-time nnimap-object)
 346                      (> (gnus-float-time
 347                          (time-subtract
 348                           now
 349                           (nnimap-last-command-time nnimap-object)))
 350                         ;; More than five minutes since the last command.
 351                         (* 5 60)))
 352             (nnimap-send-command "NOOP")))))))
 353
 354 (defun nnimap-open-connection (buffer)
 355   ;; Be backwards-compatible -- the earlier value of nnimap-stream was
 356   ;; `ssl' when nnimap-server-port was nil.  Sort of.
 357   (when (and nnimap-server-port
 358              (eq nnimap-stream 'undecided))
 359     (setq nnimap-stream 'ssl))
 360   (let ((stream
 361          (if (eq nnimap-stream 'undecided)
 362              (loop for type in '(ssl network)
 363                    for stream = (let ((nnimap-stream type))
 364                                   (nnimap-open-connection-1 buffer))
 365                    while (eq stream 'no-connect)
 366                    finally (return stream))
 367            (nnimap-open-connection-1 buffer))))
 368     (if (eq stream 'no-connect)
 369         nil
 370       stream)))
 371
 372 (defun nnimap-map-port (port)
 373   (if (equal port "imaps")
 374       "993"
 375     port))
 376
 377 (defun nnimap-open-connection-1 (buffer)
 378   (unless nnimap-keepalive-timer
 379     (setq nnimap-keepalive-timer (run-at-time (* 60 15) (* 60 15)
 380                                               'nnimap-keepalive)))
 381   (with-current-buffer (nnimap-make-process-buffer buffer)
 382     (let* ((coding-system-for-read 'binary)
 383            (coding-system-for-write 'binary)
 384            (ports
 385             (cond
 386              ((memq nnimap-stream '(network plain starttls))
 387               (nnheader-message 7 "Opening connection to %s..."
 388                                 nnimap-address)
 389               '("imap" "143"))
 390              ((eq nnimap-stream 'shell)
 391               (nnheader-message 7 "Opening connection to %s via shell..."
 392                                 nnimap-address)
 393               '("imap"))
 394              ((memq nnimap-stream '(ssl tls))
 395               (nnheader-message 7 "Opening connection to %s via tls..."
 396                                 nnimap-address)
 397               '("imaps" "imap" "993" "143"))
 398              (t
 399               (error "Unknown stream type: %s" nnimap-stream))))
 400            login-result credentials)
 401       (when nnimap-server-port
 402         (push nnimap-server-port ports))
 403       (let* ((stream-list
 404               (open-protocol-stream
 405                "*nnimap*" (current-buffer) nnimap-address
 406                (nnimap-map-port (car ports))
 407                :type nnimap-stream
 408                :return-list t
 409                :shell-command nnimap-shell-program
 410                :capability-command "1 CAPABILITY\r\n"
 411                :end-of-command "\r\n"
 412                :success " OK "
 413                :starttls-function
 414                (lambda (capabilities)
 415                  (when (gnus-string-match-p "STARTTLS" capabilities)
 416                    "1 STARTTLS\r\n"))))
 417              (stream (car stream-list))
 418              (props (cdr stream-list))
 419              (greeting (plist-get props :greeting))
 420              (capabilities (plist-get props :capabilities))
 421              (stream-type (plist-get props :type)))
 422         (when (and stream (not (memq (process-status stream) '(open run))))
 423           (setq stream nil))
 424
 425         (when (and (fboundp 'set-network-process-option) ;; Not in XEmacs.
 426                    (fboundp 'process-type) ;; Emacs 22 doesn't provide it.
 427                    (eq (process-type stream) 'network))
 428           ;; Use TCP-keepalive so that connections that pass through a NAT
 429           ;; router don't hang when left idle.
 430           (set-network-process-option stream :keepalive t))
 431
 432         (setf (nnimap-process nnimap-object) stream)
 433         (setf (nnimap-stream-type nnimap-object) stream-type)
 434         (if (not stream)
 435             (progn
 436               (nnheader-report 'nnimap "Unable to contact %s:%s via %s"
 437                                nnimap-address (car ports) nnimap-stream)
 438               'no-connect)
 439           (gnus-set-process-query-on-exit-flag stream nil)
 440           (if (not (gnus-string-match-p "[*.] \\(OK\\|PREAUTH\\)" greeting))
 441               (nnheader-report 'nnimap "%s" greeting)
 442             ;; Store the greeting (for debugging purposes).
 443             (setf (nnimap-greeting nnimap-object) greeting)
 444             (setf (nnimap-capabilities nnimap-object)
 445                   (mapcar #'upcase
 446                           (split-string capabilities)))
 447             (unless (gnus-string-match-p "[*.] PREAUTH" greeting)
 448               (if (not (setq credentials
 449                              (if (eq nnimap-authenticator 'anonymous)
 450                                  (list "anonymous"
 451                                        (message-make-address))
 452                                ;; Look for the credentials based on
 453                                ;; the virtual server name and the address
 454                                (nnimap-credentials
 455                                 (gnus-delete-duplicates
 456                                  (list
 457                                   nnimap-address
 458                                   (nnoo-current-server 'nnimap)))
 459                                 ports
 460                                 nnimap-user))))
 461                   (setq nnimap-object nil)
 462                 (let ((nnimap-inhibit-logging t))
 463                   (setq login-result
 464                         (nnimap-login (car credentials) (cadr credentials))))
 465                 (if (car login-result)
 466                     (progn
 467                       ;; Save the credentials if a save function exists
 468                       ;; (such a function will only be passed if a new
 469                       ;; token was created).
 470                       (when (functionp (nth 2 credentials))
 471                         (funcall (nth 2 credentials)))
 472                       ;; See if CAPABILITY is set as part of login
 473                       ;; response.
 474                       (dolist (response (cddr login-result))
 475                         (when (string= "CAPABILITY" (upcase (car response)))
 476                           (setf (nnimap-capabilities nnimap-object)
 477                                 (mapcar #'upcase (cdr response))))))
 478                   ;; If the login failed, then forget the credentials
 479                   ;; that are now possibly cached.
 480                   (dolist (host (list (nnoo-current-server 'nnimap)
 481                                       nnimap-address))
 482                     (dolist (port ports)
 483                       (auth-source-forget+ :host host :port port)))
 484                   (delete-process (nnimap-process nnimap-object))
 485                   (setq nnimap-object nil))))
 486             (when nnimap-object
 487               (when (nnimap-capability "QRESYNC")
 488                 (nnimap-command "ENABLE QRESYNC"))
 489               (nnheader-message 7 "Opening connection to %s...done"
 490                                 nnimap-address)
 491               (nnimap-process nnimap-object))))))))
 492
 493 (autoload 'rfc2104-hash "rfc2104")
 494
 495 (defun nnimap-login (user password)
 496   (cond
 497    ;; Prefer plain LOGIN if it's enabled (since it requires fewer
 498    ;; round trips than CRAM-MD5, and it's less likely to be buggy),
 499    ;; and we're using an encrypted connection.
 500    ((and (not (nnimap-capability "LOGINDISABLED"))
 501          (eq (nnimap-stream-type nnimap-object) 'tls))
 502     (nnimap-command "LOGIN %S %S" user password))
 503    ((nnimap-capability "AUTH=CRAM-MD5")
 504     (erase-buffer)
 505     (let ((sequence (nnimap-send-command "AUTHENTICATE CRAM-MD5"))
 506           (challenge (nnimap-wait-for-line "^\\+\\(.*\\)\n")))
 507       (process-send-string
 508        (get-buffer-process (current-buffer))
 509        (concat
 510         (base64-encode-string
 511          (concat user " "
 512                  (rfc2104-hash 'md5 64 16 password
 513                                (base64-decode-string challenge))))
 514         "\r\n"))
 515       (nnimap-wait-for-response sequence)))
 516    ((not (nnimap-capability "LOGINDISABLED"))
 517     (nnimap-command "LOGIN %S %S" user password))
 518    ((nnimap-capability "AUTH=PLAIN")
 519     (nnimap-command
 520      "AUTHENTICATE PLAIN %s"
 521      (base64-encode-string
 522       (format "\000%s\000%s"
 523               (nnimap-quote-specials user)
 524               (nnimap-quote-specials password)))))))
 525
 526 (defun nnimap-quote-specials (string)
 527   (with-temp-buffer
 528     (insert string)
 529     (goto-char (point-min))
 530     (while (re-search-forward "[\\\"]" nil t)
 531       (forward-char -1)
 532       (insert "\\")
 533       (forward-char 1))
 534     (buffer-string)))
 535
 536 (defun nnimap-find-parameter (parameter elems)
 537   (let (result)
 538     (dolist (elem elems)
 539       (cond
 540        ((equal (car elem) parameter)
 541         (setq result (cdr elem)))
 542        ((and (equal (car elem) "OK")
 543              (consp (cadr elem))
 544              (equal (caadr elem) parameter))
 545         (setq result (cdr (cadr elem))))))
 546     result))
 547
 548 (deffoo nnimap-close-server (&optional server)
 549   (when (nnoo-change-server 'nnimap server nil)
 550     (ignore-errors
 551       (delete-process (get-buffer-process (nnimap-buffer))))
 552     (nnoo-close-server 'nnimap server)
 553     t))
 554
 555 (deffoo nnimap-request-close ()
 556   t)
 557
 558 (deffoo nnimap-server-opened (&optional server)
 559   (and (nnoo-current-server-p 'nnimap server)
 560        nntp-server-buffer
 561        (gnus-buffer-live-p nntp-server-buffer)
 562        (nnimap-find-connection nntp-server-buffer)))
 563
 564 (deffoo nnimap-status-message (&optional server)
 565   nnimap-status-string)
 566
 567 (deffoo nnimap-request-article (article &optional group server to-buffer)
 568   (when group
 569     (setq group (nnimap-decode-gnus-group group)))
 570   (with-current-buffer nntp-server-buffer
 571     (let ((result (nnimap-change-group group server))
 572           parts structure)
 573       (when (stringp article)
 574         (setq article (nnimap-find-article-by-message-id group server article)))
 575       (when (and result
 576                  article)
 577         (erase-buffer)
 578         (with-current-buffer (nnimap-buffer)
 579           (erase-buffer)
 580           (when nnimap-fetch-partial-articles
 581             (nnimap-command "UID FETCH %d (BODYSTRUCTURE)" article)
 582             (goto-char (point-min))
 583             (when (re-search-forward "FETCH.*BODYSTRUCTURE" nil t)
 584               (setq structure (ignore-errors
 585                                 (let ((start (point)))
 586                                   (forward-sexp 1)
 587                                   (downcase-region start (point))
 588                                   (goto-char start)
 589                                   (read (current-buffer))))
 590                     parts (nnimap-find-wanted-parts structure))))
 591           (when (if parts
 592                     (nnimap-get-partial-article article parts structure)
 593                   (nnimap-get-whole-article article))
 594             (let ((buffer (current-buffer)))
 595               (with-current-buffer (or to-buffer nntp-server-buffer)
 596                 (nnheader-insert-buffer-substring buffer)
 597                 (nnheader-ms-strip-cr)))
 598             (cons group article)))))))
 599
 600 (deffoo nnimap-request-head (article &optional group server to-buffer)
 601   (when group
 602     (setq group (nnimap-decode-gnus-group group)))
 603   (when (nnimap-change-group group server)
 604     (with-current-buffer (nnimap-buffer)
 605       (when (stringp article)
 606         (setq article (nnimap-find-article-by-message-id group server article)))
 607       (if (null article)
 608           nil
 609         (nnimap-get-whole-article
 610          article (format "UID FETCH %%d %s"
 611                          (nnimap-header-parameters)))
 612         (let ((buffer (current-buffer)))
 613           (with-current-buffer (or to-buffer nntp-server-buffer)
 614             (erase-buffer)
 615             (insert-buffer-substring buffer)
 616             (nnheader-ms-strip-cr)
 617             (cons group article)))))))
 618
 619 (defun nnimap-get-whole-article (article &optional command)
 620   (let ((result
 621          (nnimap-command
 622           (or command
 623               (if (nnimap-ver4-p)
 624                   "UID FETCH %d BODY.PEEK[]"
 625                 "UID FETCH %d RFC822.PEEK"))
 626           article)))
 627     ;; Check that we really got an article.
 628     (goto-char (point-min))
 629     (unless (re-search-forward "\\* [0-9]+ FETCH" nil t)
 630       (setq result nil))
 631     (when result
 632       ;; Remove any data that may have arrived before the FETCH data.
 633       (beginning-of-line)
 634       (unless (bobp)
 635         (delete-region (point-min) (point)))
 636       (let ((bytes (nnimap-get-length)))
 637         (delete-region (line-beginning-position)
 638                        (progn (forward-line 1) (point)))
 639         (goto-char (+ (point) bytes))
 640         (delete-region (point) (point-max)))
 641       t)))
 642
 643 (defun nnimap-capability (capability)
 644   (member capability (nnimap-capabilities nnimap-object)))
 645
 646 (defun nnimap-ver4-p ()
 647   (nnimap-capability "IMAP4REV1"))
 648
 649 (defun nnimap-get-partial-article (article parts structure)
 650   (let ((result
 651          (nnimap-command
 652           "UID FETCH %d (%s %s)"
 653           article
 654           (if (nnimap-ver4-p)
 655               "BODY.PEEK[HEADER]"
 656             "RFC822.HEADER")
 657           (if (nnimap-ver4-p)
 658               (mapconcat (lambda (part)
 659                            (format "BODY.PEEK[%s]" part))
 660                          parts " ")
 661             (mapconcat (lambda (part)
 662                          (format "RFC822.PEEK[%s]" part))
 663                        parts " ")))))
 664     (when result
 665       (nnimap-convert-partial-article structure))))
 666
 667 (defun nnimap-convert-partial-article (structure)
 668   ;; First just skip past the headers.
 669   (goto-char (point-min))
 670   (let ((bytes (nnimap-get-length))
 671         id parts)
 672     ;; Delete "FETCH" line.
 673     (delete-region (line-beginning-position)
 674                    (progn (forward-line 1) (point)))
 675     (goto-char (+ (point) bytes))
 676     ;; Collect all the body parts.
 677     (while (looking-at ".*BODY\\[\\([.0-9]+\\)\\]")
 678       (setq id (match-string 1)
 679             bytes (or (nnimap-get-length) 0))
 680       (beginning-of-line)
 681       (delete-region (point) (progn (forward-line 1) (point)))
 682       (push (list id (buffer-substring (point) (+ (point) bytes)))
 683             parts)
 684       (delete-region (point) (+ (point) bytes)))
 685     ;; Delete trailing junk.
 686     (delete-region (point) (point-max))
 687     ;; Now insert all the parts again where they fit in the structure.
 688     (nnimap-insert-partial-structure structure parts)
 689     t))
 690
 691 (defun nnimap-insert-partial-structure (structure parts &optional subp)
 692   (let (type boundary)
 693     (let ((bstruc structure))
 694       (while (consp (car bstruc))
 695         (pop bstruc))
 696       (setq type (car bstruc))
 697       (setq bstruc (car (cdr bstruc)))
 698       (let ((has-boundary (member "boundary" bstruc)))
 699         (when has-boundary
 700           (setq boundary (cadr has-boundary)))))
 701     (when subp
 702       (insert (format "Content-type: multipart/%s; boundary=%S\n\n"
 703                       (downcase type) boundary)))
 704     (while (not (stringp (car structure)))
 705       (insert "\n--" boundary "\n")
 706       (if (consp (caar structure))
 707           (nnimap-insert-partial-structure (pop structure) parts t)
 708         (let ((bit (pop structure)))
 709           (insert (format "Content-type: %s/%s"
 710                           (downcase (nth 0 bit))
 711                           (downcase (nth 1 bit))))
 712           (if (member-ignore-case "CHARSET" (nth 2 bit))
 713               (insert (format
 714                        "; charset=%S\n"
 715                        (cadr (member-ignore-case "CHARSET" (nth 2 bit)))))
 716             (insert "\n"))
 717           (insert (format "Content-transfer-encoding: %s\n"
 718                           (nth 5 bit)))
 719           (insert "\n")
 720           (when (assoc (nth 9 bit) parts)
 721             (insert (cadr (assoc (nth 9 bit) parts)))))))
 722     (insert "\n--" boundary "--\n")))
 723
 724 (defun nnimap-find-wanted-parts (structure)
 725   (message-flatten-list (nnimap-find-wanted-parts-1 structure "")))
 726
 727 (defun nnimap-find-wanted-parts-1 (structure prefix)
 728   (let ((num 1)
 729         parts)
 730     (while (consp (car structure))
 731       (let ((sub (pop structure)))
 732         (if (consp (car sub))
 733             (push (nnimap-find-wanted-parts-1
 734                    sub (if (string= prefix "")
 735                            (number-to-string num)
 736                          (format "%s.%s" prefix num)))
 737                   parts)
 738           (let ((type (format "%s/%s" (nth 0 sub) (nth 1 sub)))
 739                 (id (if (string= prefix "")
 740                         (number-to-string num)
 741                       (format "%s.%s" prefix num))))
 742             (setcar (nthcdr 9 sub) id)
 743             (when (if (eq nnimap-fetch-partial-articles t)
 744                       (equal id "1")
 745                     (string-match nnimap-fetch-partial-articles type))
 746               (push id parts))))
 747         (incf num)))
 748     (nreverse parts)))
 749
 750 (defun nnimap-decode-gnus-group (group)
 751   (decode-coding-string group 'utf-8))
 752
 753 (deffoo nnimap-request-group (group &optional server dont-check info)
 754   (setq group (nnimap-decode-gnus-group group))
 755   (let ((result (nnimap-change-group
 756                  ;; Don't SELECT the group if we're going to select it
 757                  ;; later, anyway.
 758                  (if (and (not dont-check)
 759                           (assoc group nnimap-current-infos))
 760                      nil
 761                    group)
 762                  server))
 763         articles active marks high low)
 764     (with-current-buffer nntp-server-buffer
 765       (when result
 766         (if (and dont-check
 767                  (setq active (nth 2 (assoc group nnimap-current-infos))))
 768             (insert (format "211 %d %d %d %S\n"
 769                             (- (cdr active) (car active))
 770                             (car active)
 771                             (cdr active)
 772                             group))
 773           (with-current-buffer (nnimap-buffer)
 774             (erase-buffer)
 775             (let ((group-sequence
 776                    (nnimap-send-command "SELECT %S" (utf7-encode group t)))
 777                   (flag-sequence
 778                    (nnimap-send-command "UID FETCH 1:* FLAGS")))
 779               (setf (nnimap-group nnimap-object) group)
 780               (nnimap-wait-for-response flag-sequence)
 781               (setq marks
 782                     (nnimap-flags-to-marks
 783                      (nnimap-parse-flags
 784                       (list (list group-sequence flag-sequence
 785                                   1 group "SELECT")))))
 786               (when (and info
 787                          marks)
 788                 (nnimap-update-infos marks (list info))
 789                 (nnimap-store-info info (gnus-active (gnus-info-group info))))
 790               (goto-char (point-max))
 791               (let ((uidnext (nth 5 (car marks))))
 792                 (setq high (or (if uidnext
 793                                    (1- uidnext)
 794                                  (nth 3 (car marks)))
 795                                0)
 796                       low (or (nth 4 (car marks)) uidnext 1)))))
 797           (erase-buffer)
 798           (insert
 799            (format
 800             "211 %d %d %d %S\n" (1+ (- high low)) low high group)))
 801         t))))
 802
 803 (deffoo nnimap-request-create-group (group &optional server args)
 804   (setq group (nnimap-decode-gnus-group group))
 805   (when (nnimap-change-group nil server)
 806     (with-current-buffer (nnimap-buffer)
 807       (car (nnimap-command "CREATE %S" (utf7-encode group t))))))
 808
 809 (deffoo nnimap-request-delete-group (group &optional force server)
 810   (setq group (nnimap-decode-gnus-group group))
 811   (when (nnimap-change-group nil server)
 812     (with-current-buffer (nnimap-buffer)
 813       (car (nnimap-command "DELETE %S" (utf7-encode group t))))))
 814
 815 (deffoo nnimap-request-rename-group (group new-name &optional server)
 816   (setq group (nnimap-decode-gnus-group group))
 817   (when (nnimap-change-group nil server)
 818     (with-current-buffer (nnimap-buffer)
 819       (nnimap-unselect-group)
 820       (car (nnimap-command "RENAME %S %S"
 821                            (utf7-encode group t) (utf7-encode new-name t))))))
 822
 823 (defun nnimap-unselect-group ()
 824   ;; Make sure we don't have this group open read/write by asking
 825   ;; to examine a mailbox that doesn't exist.  This seems to be
 826   ;; the only way that allows us to reliably go back to unselected
 827   ;; state on Courier.
 828   (nnimap-command "EXAMINE DOES.NOT.EXIST"))
 829
 830 (deffoo nnimap-request-expunge-group (group &optional server)
 831   (setq group (nnimap-decode-gnus-group group))
 832   (when (nnimap-change-group group server)
 833     (with-current-buffer (nnimap-buffer)
 834       (car (nnimap-command "EXPUNGE")))))
 835
 836 (defun nnimap-get-flags (spec)
 837   (let ((articles nil)
 838         elems end)
 839     (with-current-buffer (nnimap-buffer)
 840       (erase-buffer)
 841       (nnimap-wait-for-response (nnimap-send-command
 842                                  "UID FETCH %s FLAGS" spec))
 843       (setq end (point))
 844       (subst-char-in-region (point-min) (point-max)
 845                             ?\\ ?% t)
 846       (goto-char (point-min))
 847       (while (search-forward " FETCH " end t)
 848         (setq elems (read (current-buffer)))
 849         (push (cons (cadr (memq 'UID elems))
 850                     (cadr (memq 'FLAGS elems)))
 851               articles)))
 852     (nreverse articles)))
 853
 854 (deffoo nnimap-close-group (group &optional server)
 855   t)
 856
 857 (deffoo nnimap-request-move-article (article group server accept-form
 858                                              &optional last internal-move-group)
 859   (setq group (nnimap-decode-gnus-group group))
 860   (with-temp-buffer
 861     (mm-disable-multibyte)
 862     (when (funcall (if internal-move-group
 863                        'nnimap-request-head
 864                      'nnimap-request-article)
 865                    article group server (current-buffer))
 866       ;; If the move is internal (on the same server), just do it the easy
 867       ;; way.
 868       (let ((message-id (message-field-value "message-id")))
 869         (if internal-move-group
 870             (let ((result
 871                    (with-current-buffer (nnimap-buffer)
 872                      (nnimap-command "UID COPY %d %S"
 873                                      article
 874                                      (utf7-encode internal-move-group t)))))
 875               (when (car result)
 876                 (nnimap-delete-article article)
 877                 (cons internal-move-group
 878                       (or (nnimap-find-uid-response "COPYUID" (cadr result))
 879                           (nnimap-find-article-by-message-id
 880                            internal-move-group server message-id
 881                            nnimap-request-articles-find-limit)))))
 882           ;; Move the article to a different method.
 883           (let ((result (eval accept-form)))
 884             (when result
 885               (nnimap-change-group group server)
 886               (nnimap-delete-article article)
 887               result)))))))
 888
 889 (deffoo nnimap-request-expire-articles (articles group &optional server force)
 890   (setq group (nnimap-decode-gnus-group group))
 891   (cond
 892    ((null articles)
 893     nil)
 894    ((not (nnimap-change-group group server))
 895     articles)
 896    ((and force
 897          (eq nnmail-expiry-target 'delete))
 898     (unless (nnimap-delete-article (gnus-compress-sequence articles))
 899       (nnheader-message 7 "Article marked for deletion, but not expunged."))
 900     nil)
 901    (t
 902     (let ((deletable-articles
 903            (if (or force
 904                    (eq nnmail-expiry-wait 'immediate))
 905                articles
 906              (gnus-sorted-intersection
 907               articles
 908               (nnimap-find-expired-articles group)))))
 909       (if (null deletable-articles)
 910           articles
 911         (if (eq nnmail-expiry-target 'delete)
 912             (nnimap-delete-article (gnus-compress-sequence deletable-articles))
 913           (setq deletable-articles
 914                 (nnimap-process-expiry-targets
 915                  deletable-articles group server)))
 916         ;; Return the articles we didn't delete.
 917         (gnus-sorted-complement articles deletable-articles))))))
 918
 919 (defun nnimap-process-expiry-targets (articles group server)
 920   (let ((deleted-articles nil))
 921     (cond
 922      ;; shortcut further processing if we're going to delete the articles
 923      ((eq nnmail-expiry-target 'delete)
 924       (setq deleted-articles articles)
 925       t)
 926      ;; or just move them to another folder on the same IMAP server
 927      ((and (not (functionp nnmail-expiry-target))
 928            (gnus-server-equal (gnus-group-method nnmail-expiry-target)
 929                               (gnus-server-to-method
 930                                (format "nnimap:%s" server))))
 931       (and (nnimap-change-group group server)
 932            (with-current-buffer (nnimap-buffer)
 933              (nnheader-message 7 "Expiring articles from %s: %s" group articles)
 934              (nnimap-command
 935               "UID COPY %s %S"
 936               (nnimap-article-ranges (gnus-compress-sequence articles))
 937               (utf7-encode (gnus-group-real-name nnmail-expiry-target) t))
 938              (setq deleted-articles articles)))
 939       t)
 940      (t
 941       (dolist (article articles)
 942         (let ((target nnmail-expiry-target))
 943           (with-temp-buffer
 944             (mm-disable-multibyte)
 945             (when (nnimap-request-article article group server (current-buffer))
 946               (when (functionp target)
 947                 (setq target (funcall target group)))
 948               (if (and target
 949                        (not (eq target 'delete)))
 950                   (if (or (gnus-request-group target t)
 951                           (gnus-request-create-group target))
 952                       (progn
 953                         (nnmail-expiry-target-group target group)
 954                         (nnheader-message 7 "Expiring article %s:%d to %s"
 955                                           group article target))
 956                     (setq target nil))
 957                 (nnheader-message 7 "Expiring article %s:%d" group article))
 958               (when target
 959                 (push article deleted-articles))))))))
 960     ;; Change back to the current group again.
 961     (nnimap-change-group group server)
 962     (setq deleted-articles (nreverse deleted-articles))
 963     (nnimap-delete-article (gnus-compress-sequence deleted-articles))
 964     deleted-articles))
 965
 966 (defun nnimap-find-expired-articles (group)
 967   (let ((cutoff (nnmail-expired-article-p group nil nil)))
 968     (with-current-buffer (nnimap-buffer)
 969       (let ((result
 970              (nnimap-command
 971               "UID SEARCH SENTBEFORE %s"
 972               (format-time-string
 973                (format "%%d-%s-%%Y"
 974                        (upcase
 975                         (car (rassoc (nth 4 (decode-time cutoff))
 976                                      parse-time-months))))
 977                cutoff))))
 978         (and (car result)
 979              (delete 0 (mapcar #'string-to-number
 980                                (cdr (assoc "SEARCH" (cdr result))))))))))
 981
 982
 983 (defun nnimap-find-article-by-message-id (group server message-id &optional limit)
 984   "Search for message with MESSAGE-ID in GROUP from SERVER.
 985 If LIMIT, first try to limit the search to the N last articles."
 986   (with-current-buffer (nnimap-buffer)
 987     (erase-buffer)
 988     (let* ((change-group-result (nnimap-change-group group server nil t))
 989            (number-of-article
 990             (and (listp change-group-result)
 991                  (catch 'found
 992                    (dolist (result (cdr change-group-result))
 993                      (when (equal "EXISTS" (cadr result))
 994                        (throw 'found (car result)))))))
 995            (sequence
 996             (nnimap-send-command "UID SEARCH%s HEADER Message-Id %S"
 997                                  (if (and limit number-of-article)
 998                                      ;; The -1 is because IMAP message
 999                                      ;; numbers are one-based rather than
1000                                      ;; zero-based.
1001                                      (format " %s:*" (- (string-to-number number-of-article) limit -1))
1002                                    "")
1003                                  message-id)))
1004       (when (nnimap-wait-for-response sequence)
1005         (let ((article (car (last (cdr (assoc "SEARCH" (nnimap-parse-response)))))))
1006           (if article
1007               (string-to-number article)
1008             (when (and limit number-of-article)
1009               (nnimap-find-article-by-message-id group server message-id))))))))
1010
1011 (defun nnimap-delete-article (articles)
1012   (with-current-buffer (nnimap-buffer)
1013     (nnimap-command "UID STORE %s +FLAGS.SILENT (\\Deleted)"
1014                     (nnimap-article-ranges articles))
1015     (cond
1016      ((nnimap-capability "UIDPLUS")
1017       (nnimap-command "UID EXPUNGE %s"
1018                       (nnimap-article-ranges articles))
1019       t)
1020      (nnimap-expunge
1021       (nnimap-command "EXPUNGE")
1022       t)
1023      (t (gnus-message 7 (concat "nnimap: nnimap-expunge is not set and the "
1024                                 "server doesn't support UIDPLUS, so we won't "
1025                                 "delete this article now"))))))
1026
1027 (deffoo nnimap-request-scan (&optional group server)
1028   (when group
1029     (setq group (nnimap-decode-gnus-group group)))
1030   (when (and (nnimap-change-group nil server)
1031              nnimap-inbox
1032              nnimap-split-methods)
1033     (nnheader-message 7 "nnimap %s splitting mail..." server)
1034     (if (listp nnimap-inbox)
1035        (dolist (nnimap-inbox nnimap-inbox)
1036          (nnimap-split-incoming-mail))
1037       (nnimap-split-incoming-mail))
1038     (nnheader-message 7 "nnimap %s splitting mail...done" server)))
1039
1040 (defun nnimap-marks-to-flags (marks)
1041   (let (flags flag)
1042     (dolist (mark marks)
1043       (when (setq flag (cadr (assq mark nnimap-mark-alist)))
1044         (push flag flags)))
1045     flags))
1046
1047 (deffoo nnimap-request-update-group-status (group status &optional server)
1048   (setq group (nnimap-decode-gnus-group group))
1049   (when (nnimap-change-group nil server)
1050     (let ((command (assoc
1051                     status
1052                     '((subscribe "SUBSCRIBE")
1053                       (unsubscribe "UNSUBSCRIBE")))))
1054       (when command
1055         (with-current-buffer (nnimap-buffer)
1056           (nnimap-command "%s %S" (cadr command) (utf7-encode group t)))))))
1057
1058 (deffoo nnimap-request-set-mark (group actions &optional server)
1059   (setq group (nnimap-decode-gnus-group group))
1060   (when (nnimap-change-group group server)
1061     (let (sequence)
1062       (with-current-buffer (nnimap-buffer)
1063         (erase-buffer)
1064         ;; Just send all the STORE commands without waiting for
1065         ;; response.  If they're successful, they're successful.
1066         (dolist (action actions)
1067           (destructuring-bind (range action marks) action
1068             (let ((flags (nnimap-marks-to-flags marks)))
1069               (when flags
1070                 (setq sequence (nnimap-send-command
1071                                 "UID STORE %s %sFLAGS.SILENT (%s)"
1072                                 (nnimap-article-ranges range)
1073                                 (cond
1074                                  ((eq action 'del) "-")
1075                                  ((eq action 'add) "+")
1076                                  ((eq action 'set) ""))
1077                                 (mapconcat #'identity flags " ")))))))
1078         ;; Wait for the last command to complete to avoid later
1079         ;; synchronization problems with the stream.
1080         (when sequence
1081           (nnimap-wait-for-response sequence))))))
1082
1083 (deffoo nnimap-request-accept-article (group &optional server last)
1084   (setq group (nnimap-decode-gnus-group group))
1085   (when (nnimap-change-group nil server)
1086     (nnmail-check-syntax)
1087     (let ((message-id (message-field-value "message-id"))
1088           sequence message)
1089       (nnimap-add-cr)
1090       (setq message (buffer-substring-no-properties (point-min) (point-max)))
1091       (with-current-buffer (nnimap-buffer)
1092         (when (setq message (or (nnimap-process-quirk "OK Gimap " 'append message)
1093                                 message))
1094           ;; If we have this group open read-only, then unselect it
1095           ;; before appending to it.
1096           (when (equal (nnimap-examined nnimap-object) group)
1097             (nnimap-unselect-group))
1098           (erase-buffer)
1099           (setq sequence (nnimap-send-command
1100                           "APPEND %S {%d}" (utf7-encode group t)
1101                           (length message)))
1102           (unless nnimap-streaming
1103             (nnimap-wait-for-connection "^[+]"))
1104           (process-send-string (get-buffer-process (current-buffer)) message)
1105           (process-send-string (get-buffer-process (current-buffer))
1106                                (if (nnimap-newlinep nnimap-object)
1107                                    "\n"
1108                                  "\r\n"))
1109           (let ((result (nnimap-get-response sequence)))
1110             (if (not (nnimap-ok-p result))
1111                 (progn
1112                   (nnheader-report 'nnimap "%s" result)
1113                   nil)
1114               (cons group
1115                     (or (nnimap-find-uid-response "APPENDUID" (car result))
1116                         (nnimap-find-article-by-message-id
1117                          group server message-id
1118                          nnimap-request-articles-find-limit))))))))))
1119
1120 (defun nnimap-process-quirk (greeting-match type data)
1121   (when (and (nnimap-greeting nnimap-object)
1122              (string-match greeting-match (nnimap-greeting nnimap-object))
1123              (eq type 'append)
1124              (string-match "\000" data))
1125     (let ((choice (gnus-multiple-choice
1126                    "Message contains NUL characters.  Delete, continue, abort? "
1127                    '((?d "Delete NUL characters")
1128                      (?c "Try to APPEND the message as is")
1129                      (?a "Abort")))))
1130       (cond
1131        ((eq choice ?a)
1132         (nnheader-report 'nnimap "Aborted APPEND due to NUL characters"))
1133        ((eq choice ?c)
1134         data)
1135        (t
1136         (with-temp-buffer
1137           (insert data)
1138           (goto-char (point-min))
1139           (while (search-forward "\000" nil t)
1140             (replace-match "" t t))
1141           (buffer-string)))))))
1142
1143 (defun nnimap-ok-p (value)
1144   (and (consp value)
1145        (consp (car value))
1146        (equal (caar value) "OK")))
1147
1148 (defun nnimap-find-uid-response (name list)
1149   (let ((result (car (last (nnimap-find-response-element name list)))))
1150     (and result
1151          (string-to-number result))))
1152
1153 (defun nnimap-find-response-element (name list)
1154   (let (result)
1155     (dolist (elem list)
1156       (when (and (consp elem)
1157                  (equal name (car elem)))
1158         (setq result elem)))
1159     result))
1160
1161 (deffoo nnimap-request-replace-article (article group buffer)
1162   (setq group (nnimap-decode-gnus-group group))
1163   (let (group-art)
1164     (when (and (nnimap-change-group group)
1165                ;; Put the article into the group.
1166                (with-current-buffer buffer
1167                  (setq group-art
1168                        (nnimap-request-accept-article group nil t))))
1169       (nnimap-delete-article (list article))
1170       ;; Return the new article number.
1171       (cdr group-art))))
1172
1173 (defun nnimap-add-cr ()
1174   (goto-char (point-min))
1175   (while (re-search-forward "\r?\n" nil t)
1176     (replace-match "\r\n" t t)))
1177
1178 (defun nnimap-get-groups ()
1179   (erase-buffer)
1180   (let ((sequence (nnimap-send-command "LIST \"\" \"*\""))
1181         groups)
1182     (nnimap-wait-for-response sequence)
1183     (subst-char-in-region (point-min) (point-max)
1184                           ?\\ ?% t)
1185     (goto-char (point-min))
1186     (nnimap-unfold-quoted-lines)
1187     (goto-char (point-min))
1188     (while (search-forward "* LIST " nil t)
1189       (let ((flags (read (current-buffer)))
1190             (separator (read (current-buffer)))
1191             (group (read (current-buffer))))
1192         (unless (member '%NoSelect flags)
1193           (push (utf7-decode (if (stringp group)
1194                                  group
1195                                (format "%s" group)) t)
1196                 groups))))
1197     (nreverse groups)))
1198
1199 (defun nnimap-get-responses (sequences)
1200   (let (responses)
1201     (dolist (sequence sequences)
1202       (goto-char (point-min))
1203       (when (re-search-forward (format "^%d " sequence) nil t)
1204         (push (list sequence (nnimap-parse-response))
1205               responses)))
1206     responses))
1207
1208 (deffoo nnimap-request-list (&optional server)
1209   (when (nnimap-change-group nil server)
1210     (with-current-buffer nntp-server-buffer
1211       (erase-buffer)
1212       (let ((groups
1213              (with-current-buffer (nnimap-buffer)
1214                (nnimap-get-groups)))
1215             sequences responses)
1216         (when groups
1217           (with-current-buffer (nnimap-buffer)
1218             (setf (nnimap-group nnimap-object) nil)
1219             (dolist (group groups)
1220               (setf (nnimap-examined nnimap-object) group)
1221               (push (list (nnimap-send-command "EXAMINE %S"
1222                                                (utf7-encode group t))
1223                           group)
1224                     sequences))
1225             (nnimap-wait-for-response (caar sequences))
1226             (setq responses
1227                   (nnimap-get-responses (mapcar #'car sequences))))
1228           (dolist (response responses)
1229             (let* ((sequence (car response))
1230                    (response (cadr response))
1231                    (group (cadr (assoc sequence sequences)))
1232                    (egroup (encode-coding-string group 'utf-8)))
1233               (when (and group
1234                          (equal (caar response) "OK"))
1235                 (let ((uidnext (nnimap-find-parameter "UIDNEXT" response))
1236                       highest exists)
1237                   (dolist (elem response)
1238                     (when (equal (cadr elem) "EXISTS")
1239                       (setq exists (string-to-number (car elem)))))
1240                   (when uidnext
1241                     (setq highest (1- (string-to-number (car uidnext)))))
1242                   (cond
1243                    ((null highest)
1244                     (insert (format "%S 0 1 y\n" egroup)))
1245                    ((zerop exists)
1246                     ;; Empty group.
1247                     (insert (format "%S %d %d y\n" egroup
1248                                     highest (1+ highest))))
1249                    (t
1250                     ;; Return the widest possible range.
1251                     (insert (format "%S %d 1 y\n" egroup
1252                                     (or highest exists)))))))))
1253           t)))))
1254
1255 (deffoo nnimap-request-newgroups (date &optional server)
1256   (when (nnimap-change-group nil server)
1257     (with-current-buffer nntp-server-buffer
1258       (erase-buffer)
1259       (dolist (group (with-current-buffer (nnimap-buffer)
1260                        (nnimap-get-groups)))
1261         (unless (assoc group nnimap-current-infos)
1262           ;; Insert dummy numbers here -- they don't matter.
1263           (insert (format "%S 0 1 y\n" (encode-coding-string group 'utf-8)))))
1264       t)))
1265
1266 (deffoo nnimap-retrieve-group-data-early (server infos)
1267   (when (and (nnimap-change-group nil server)
1268              infos)
1269     (with-current-buffer (nnimap-buffer)
1270       (erase-buffer)
1271       (setf (nnimap-group nnimap-object) nil)
1272       (setf (nnimap-initial-resync nnimap-object) 0)
1273       (let ((qresyncp (nnimap-capability "QRESYNC"))
1274             params groups sequences active uidvalidity modseq group
1275             unexist)
1276         ;; Go through the infos and gather the data needed to know
1277         ;; what and how to request the data.
1278         (dolist (info infos)
1279           (setq params (gnus-info-params info)
1280                 group (nnimap-decode-gnus-group
1281                        (gnus-group-real-name (gnus-info-group info)))
1282                 active (cdr (assq 'active params))
1283                 unexist (assq 'unexist (gnus-info-marks info))
1284                 uidvalidity (cdr (assq 'uidvalidity params))
1285                 modseq (cdr (assq 'modseq params)))
1286           (setf (nnimap-examined nnimap-object) group)
1287           (if (and qresyncp
1288                    uidvalidity
1289                    active
1290                    modseq
1291                    unexist)
1292               (push
1293                (list (nnimap-send-command "EXAMINE %S (%s (%s %s))"
1294                                           (utf7-encode group t)
1295                                           (nnimap-quirk "QRESYNC")
1296                                           uidvalidity modseq)
1297                      'qresync
1298                      nil group 'qresync)
1299                sequences)
1300             (let ((command
1301                    (if uidvalidity
1302                        "EXAMINE"
1303                      ;; If we don't have a UIDVALIDITY, then this is
1304                      ;; the first time we've seen the group, so we
1305                      ;; have to do a SELECT (which is slower than an
1306                      ;; examine), but will tell us whether the group
1307                      ;; is read-only or not.
1308                      "SELECT"))
1309                   start)
1310               (if (and active uidvalidity unexist)
1311                   ;; Fetch the last 100 flags.
1312                   (setq start (max 1 (- (cdr active) 100)))
1313                 (incf (nnimap-initial-resync nnimap-object))
1314                 (setq start 1))
1315               (push (list (nnimap-send-command "%s %S" command
1316                                                (utf7-encode group t))
1317                           (nnimap-send-command "UID FETCH %d:* FLAGS" start)
1318                           start group command)
1319                     sequences))))
1320         sequences))))
1321
1322 (defun nnimap-quirk (command)
1323   (let ((quirk (assoc command nnimap-quirks)))
1324     ;; If this server is of a type that matches a quirk, then return
1325     ;; the "quirked" command instead of the proper one.
1326     (if (or (null quirk)
1327             (not (string-match (nth 1 quirk) (nnimap-greeting nnimap-object))))
1328         command
1329       (nth 2 quirk))))
1330
1331 (deffoo nnimap-finish-retrieve-group-infos (server infos sequences)
1332   (when (and sequences
1333              (nnimap-change-group nil server t)
1334              ;; Check that the process is still alive.
1335              (get-buffer-process (nnimap-buffer))
1336              (memq (process-status (get-buffer-process (nnimap-buffer)))
1337                    '(open run)))
1338     (with-current-buffer (nnimap-buffer)
1339       ;; Wait for the final data to trickle in.
1340       (when (nnimap-wait-for-response (if (eq (cadar sequences) 'qresync)
1341                                           (caar sequences)
1342                                         (cadar sequences))
1343                                       t)
1344         ;; Now we should have most of the data we need, no matter
1345         ;; whether we're QRESYNCING, fetching all the flags from
1346         ;; scratch, or just fetching the last 100 flags per group.
1347         (nnimap-update-infos (nnimap-flags-to-marks
1348                               (nnimap-parse-flags
1349                                (nreverse sequences)))
1350                              infos)
1351         ;; Finally, just return something resembling an active file in
1352         ;; the nntp buffer, so that the agent can save the info, too.
1353         (with-current-buffer nntp-server-buffer
1354           (erase-buffer)
1355           (dolist (info infos)
1356             (let* ((group (gnus-info-group info))
1357                    (active (gnus-active group)))
1358               (when active
1359                 (insert (format "%S %d %d y\n"
1360                                 (decode-coding-string
1361                                  (gnus-group-real-name group) 'utf-8)
1362                                 (cdr active)
1363                                 (car active)))))))))))
1364
1365 (defun nnimap-update-infos (flags infos)
1366   (dolist (info infos)
1367     (let* ((group (nnimap-decode-gnus-group
1368                    (gnus-group-real-name (gnus-info-group info))))
1369            (marks (cdr (assoc group flags))))
1370       (when marks
1371         (nnimap-update-info info marks)))))
1372
1373 (defun nnimap-update-info (info marks)
1374   (destructuring-bind (existing flags high low uidnext start-article
1375                                 permanent-flags uidvalidity
1376                                 vanished highestmodseq) marks
1377     (cond
1378      ;; Ignore groups with no UIDNEXT/marks.  This happens for
1379      ;; completely empty groups.
1380      ((and (not existing)
1381            (not uidnext))
1382       (let ((active (cdr (assq 'active (gnus-info-params info)))))
1383         (when active
1384           (gnus-set-active (gnus-info-group info) active))))
1385      ;; We have a mismatch between the old and new UIDVALIDITY
1386      ;; identifiers, so we have to re-request the group info (the next
1387      ;; time).  This virtually never happens.
1388      ((let ((old-uidvalidity
1389              (cdr (assq 'uidvalidity (gnus-info-params info)))))
1390         (and old-uidvalidity
1391              (not (equal old-uidvalidity uidvalidity))
1392              (or (not start-article)
1393                  (> start-article 1))))
1394       (gnus-group-remove-parameter info 'uidvalidity)
1395       (gnus-group-remove-parameter info 'modseq))
1396      ;; We have the data needed to update.
1397      (t
1398       (let* ((group (gnus-info-group info))
1399              (completep (and start-article
1400                              (= start-article 1)))
1401              (active (or (gnus-active group)
1402                          (cdr (assq 'active (gnus-info-params info))))))
1403         (when uidnext
1404           (setq high (1- uidnext)))
1405         ;; First set the active ranges based on high/low.
1406         (if (or completep
1407                 (not (gnus-active group)))
1408             (gnus-set-active group
1409                              (cond
1410                               (active
1411                                (cons (min (or low (car active))
1412                                           (car active))
1413                                      (max (or high (cdr active))
1414                                           (cdr active))))
1415                               ((and low high)
1416                                (cons low high))
1417                               (uidnext
1418                                ;; No articles in this group.
1419                                (cons uidnext (1- uidnext)))
1420                               (start-article
1421                                (cons start-article (1- start-article)))
1422                               (t
1423                                ;; No articles and no uidnext.
1424                                nil)))
1425           (gnus-set-active group
1426                            (cons (car active)
1427                                  (or high (1- uidnext)))))
1428         ;; See whether this is a read-only group.
1429         (unless (eq permanent-flags 'not-scanned)
1430           (gnus-group-set-parameter
1431            info 'permanent-flags
1432            (and (or (memq '%* permanent-flags)
1433                     (memq '%Seen permanent-flags))
1434                 permanent-flags)))
1435         ;; Update marks and read articles if this isn't a
1436         ;; read-only IMAP group.
1437         (when (setq permanent-flags
1438                     (cdr (assq 'permanent-flags (gnus-info-params info))))
1439           (if (and highestmodseq
1440                    (not start-article))
1441               ;; We've gotten the data by QRESYNCing.
1442               (nnimap-update-qresync-info
1443                info existing (nnimap-imap-ranges-to-gnus-ranges vanished) flags)
1444             ;; Do normal non-QRESYNC flag updates.
1445             ;; Update the list of read articles.
1446             (let* ((unread
1447                     (gnus-compress-sequence
1448                      (gnus-set-difference
1449                       (gnus-set-difference
1450                        existing
1451                        (cdr (assoc '%Seen flags)))
1452                       (cdr (assoc '%Flagged flags)))))
1453                    (read (gnus-range-difference
1454                           (cons start-article high) unread)))
1455               (when (> start-article 1)
1456                 (setq read
1457                       (gnus-range-nconcat
1458                        (if (> start-article 1)
1459                            (gnus-sorted-range-intersection
1460                             (cons 1 (1- start-article))
1461                             (gnus-info-read info))
1462                          (gnus-info-read info))
1463                        read)))
1464               (when (or (not (listp permanent-flags))
1465                         (memq '%Seen permanent-flags))
1466                 (gnus-info-set-read info read))
1467               ;; Update the marks.
1468               (setq marks (gnus-info-marks info))
1469               (dolist (type (cdr nnimap-mark-alist))
1470                 (when (or (not (listp permanent-flags))
1471                           (memq (car (assoc (caddr type) flags))
1472                                 permanent-flags)
1473                           (memq '%* permanent-flags))
1474                   (let ((old-marks (assoc (car type) marks))
1475                         (new-marks
1476                          (gnus-compress-sequence
1477                           (cdr (or (assoc (caddr type) flags) ; %Flagged
1478                                    (assoc (intern (cadr type) obarray) flags)
1479                                    (assoc (cadr type) flags)))))) ; "\Flagged"
1480                     (setq marks (delq old-marks marks))
1481                     (pop old-marks)
1482                     (when (and old-marks
1483                                (> start-article 1))
1484                       (setq old-marks (gnus-range-difference
1485                                        old-marks
1486                                        (cons start-article high)))
1487                       (setq new-marks (gnus-range-nconcat old-marks new-marks)))
1488                     (when new-marks
1489                       (push (cons (car type) new-marks) marks)))))
1490               ;; Keep track of non-existing articles.
1491               (let* ((old-unexists (assq 'unexist marks))
1492                      (active (gnus-active group))
1493                      (unexists
1494                       (if completep
1495                           (gnus-range-difference
1496                            active
1497                            (gnus-compress-sequence existing))
1498                         (gnus-add-to-range
1499                          (cdr old-unexists)
1500                          (gnus-list-range-difference
1501                           existing (gnus-active group))))))
1502                 (when (> (car active) 1)
1503                   (setq unexists (gnus-range-add
1504                                   (cons 1 (1- (car active)))
1505                                   unexists)))
1506                 (if old-unexists
1507                     (setcdr old-unexists unexists)
1508                   (push (cons 'unexist unexists) marks)))
1509               (gnus-info-set-marks info marks t))))
1510         ;; Tell Gnus whether there are any \Recent messages in any of
1511         ;; the groups.
1512         (let ((recent (cdr (assoc '%Recent flags))))
1513           (when (and active
1514                      recent
1515                      (> (car (last recent)) (cdr active)))
1516             (push (list (cons (gnus-group-real-name group) 0))
1517                   nnmail-split-history)))
1518         ;; Note the active level for the next run-through.
1519         (gnus-group-set-parameter info 'active (gnus-active group))
1520         (gnus-group-set-parameter info 'uidvalidity uidvalidity)
1521         (gnus-group-set-parameter info 'modseq highestmodseq)
1522         (nnimap-store-info info (gnus-active group)))))))
1523
1524 (defun nnimap-update-qresync-info (info existing vanished flags)
1525   ;; Add all the vanished articles to the list of read articles.
1526   (gnus-info-set-read
1527    info
1528    (gnus-add-to-range
1529     (gnus-add-to-range
1530      (gnus-range-add (gnus-info-read info)
1531                      vanished)
1532      (cdr (assq '%Flagged flags)))
1533     (cdr (assq '%Seen flags))))
1534   (let ((marks (gnus-info-marks info)))
1535     (dolist (type (cdr nnimap-mark-alist))
1536       (let ((ticks (assoc (car type) marks))
1537             (new-marks
1538              (cdr (or (assoc (caddr type) flags) ; %Flagged
1539                       (assoc (intern (cadr type) obarray) flags)
1540                       (assoc (cadr type) flags))))) ; "\Flagged"
1541         (setq marks (delq ticks marks))
1542         (pop ticks)
1543         ;; Add the new marks we got.
1544         (setq ticks (gnus-add-to-range ticks new-marks))
1545         ;; Remove the marks from messages that don't have them.
1546         (setq ticks (gnus-remove-from-range
1547                      ticks
1548                      (gnus-compress-sequence
1549                       (gnus-sorted-complement existing new-marks))))
1550         (when ticks
1551           (push (cons (car type) ticks) marks)))
1552       (gnus-info-set-marks info marks t))
1553     ;; Add vanished to the list of unexisting articles.
1554     (when vanished
1555       (let* ((old-unexists (assq 'unexist marks))
1556              (unexists (gnus-range-add (cdr old-unexists) vanished)))
1557         (if old-unexists
1558             (setcdr old-unexists unexists)
1559           (push (cons 'unexist unexists) marks)))
1560       (gnus-info-set-marks info marks t))))
1561
1562 (defun nnimap-imap-ranges-to-gnus-ranges (irange)
1563   (if (zerop (length irange))
1564       nil
1565     (let ((result nil))
1566       (dolist (elem (split-string irange ","))
1567         (push
1568          (if (string-match ":" elem)
1569              (let ((numbers (split-string elem ":")))
1570                (cons (string-to-number (car numbers))
1571                      (string-to-number (cadr numbers))))
1572            (string-to-number elem))
1573          result))
1574       (nreverse result))))
1575
1576 (defun nnimap-store-info (info active)
1577   (let* ((group (gnus-group-real-name (gnus-info-group info)))
1578          (entry (assoc group nnimap-current-infos)))
1579     (if entry
1580         (setcdr entry (list info active))
1581       (push (list group info active) nnimap-current-infos))))
1582
1583 (defun nnimap-flags-to-marks (groups)
1584   (let (data group totalp uidnext articles start-article mark permanent-flags
1585              uidvalidity vanished highestmodseq)
1586     (dolist (elem groups)
1587       (setq group (car elem)
1588             uidnext (nth 1 elem)
1589             start-article (nth 2 elem)
1590             permanent-flags (nth 3 elem)
1591             uidvalidity (nth 4 elem)
1592             vanished (nth 5 elem)
1593             highestmodseq (nth 6 elem)
1594             articles (nthcdr 7 elem))
1595       (let ((high (caar articles))
1596             marks low existing)
1597         (dolist (article articles)
1598           (setq low (car article))
1599           (push (car article) existing)
1600           (dolist (flag (cdr article))
1601             (setq mark (assoc flag marks))
1602             (if (not mark)
1603                 (push (list flag (car article)) marks)
1604               (setcdr mark (cons (car article) (cdr mark))))))
1605         (push (list group existing marks high low uidnext start-article
1606                     permanent-flags uidvalidity vanished highestmodseq)
1607               data)))
1608     data))
1609
1610 (defun nnimap-parse-flags (sequences)
1611   (goto-char (point-min))
1612   ;; Change \Delete etc to %Delete, so that the Emacs Lisp reader can
1613   ;; read it.
1614   (subst-char-in-region (point-min) (point-max)
1615                         ?\\ ?% t)
1616   ;; Remove any MODSEQ entries in the buffer, because they may contain
1617   ;; numbers that are too large for 32-bit Emacsen.
1618   (while (re-search-forward " MODSEQ ([0-9]+)" nil t)
1619     (replace-match "" t t))
1620   (goto-char (point-min))
1621   (let (start end articles groups uidnext elems permanent-flags
1622               uidvalidity vanished highestmodseq)
1623     (dolist (elem sequences)
1624       (destructuring-bind (group-sequence flag-sequence totalp group command)
1625           elem
1626         (setq start (point))
1627         (when (and
1628                ;; The EXAMINE was successful.
1629                (search-forward (format "\n%d OK " group-sequence) nil t)
1630                (progn
1631                  (forward-line 1)
1632                  (setq end (point))
1633                  (goto-char start)
1634                  (setq permanent-flags
1635                        (if (equal command "SELECT")
1636                            (and (search-forward "PERMANENTFLAGS "
1637                                                 (or end (point-min)) t)
1638                                 (read (current-buffer)))
1639                          'not-scanned))
1640                  (goto-char start)
1641                  (setq uidnext
1642                        (and (search-forward "UIDNEXT "
1643                                             (or end (point-min)) t)
1644                             (read (current-buffer))))
1645                  (goto-char start)
1646                  (setq uidvalidity
1647                        (and (re-search-forward "UIDVALIDITY \\([0-9]+\\)"
1648                                                (or end (point-min)) t)
1649                             ;; Store UIDVALIDITY as a string, as it's
1650                             ;; too big for 32-bit Emacsen, usually.
1651                             (match-string 1)))
1652                  (goto-char start)
1653                  (setq vanished
1654                        (and (eq flag-sequence 'qresync)
1655                             (re-search-forward "^\\* VANISHED .*? \\([0-9:,]+\\)"
1656                                                (or end (point-min)) t)
1657                             (match-string 1)))
1658                  (goto-char start)
1659                  (setq highestmodseq
1660                        (and (re-search-forward "HIGHESTMODSEQ \\([0-9]+\\)"
1661                                             (or end (point-min)) t)
1662                             (match-string 1)))
1663                  (goto-char end)
1664                  (forward-line -1))
1665                ;; The UID FETCH FLAGS was successful.
1666                (or (eq flag-sequence 'qresync)
1667                    (search-forward (format "\n%d OK " flag-sequence) nil t)))
1668           (if (eq flag-sequence 'qresync)
1669               (progn
1670                 (goto-char start)
1671                 (setq start end))
1672             (setq start (point))
1673             (goto-char end))
1674           (while (re-search-forward "^\\* [0-9]+ FETCH " start t)
1675             (let ((p (point)))
1676               (setq elems (read (current-buffer)))
1677               (push (cons (cadr (memq 'UID elems))
1678                           (cadr (memq 'FLAGS elems)))
1679                     articles)))
1680           (push (nconc (list group uidnext totalp permanent-flags uidvalidity
1681                              vanished highestmodseq)
1682                        articles)
1683                 groups)
1684           (if (eq flag-sequence 'qresync)
1685               (goto-char end)
1686             (setq end (point)))
1687           (setq articles nil))))
1688     groups))
1689
1690 (defun nnimap-find-process-buffer (buffer)
1691   (cadr (assoc buffer nnimap-connection-alist)))
1692
1693 (deffoo nnimap-request-post (&optional server)
1694   (setq nnimap-status-string "Read-only server")
1695   nil)
1696
1697 (defvar gnus-refer-thread-use-nnir) ;; gnus-sum.el
1698 (declare-function gnus-fetch-headers "gnus-sum"
1699                   (articles &optional limit force-new dependencies))
1700
1701 (autoload 'nnir-search-thread "nnir")
1702
1703 (deffoo nnimap-request-thread (header &optional group server)
1704   (when group
1705     (setq group (nnimap-decode-gnus-group group)))
1706   (if gnus-refer-thread-use-nnir
1707       (nnir-search-thread header)
1708     (when (nnimap-change-group group server)
1709       (let* ((cmd (nnimap-make-thread-query header))
1710              (result (with-current-buffer (nnimap-buffer)
1711                        (nnimap-command  "UID SEARCH %s" cmd))))
1712         (when result
1713           (gnus-fetch-headers
1714            (and (car result)
1715                 (delete 0 (mapcar #'string-to-number
1716                                   (cdr (assoc "SEARCH" (cdr result))))))
1717            nil t))))))
1718
1719 (defun nnimap-change-group (group &optional server no-reconnect read-only)
1720   "Change group to GROUP if non-nil.
1721 If SERVER is set, check that server is connected, otherwise retry
1722 to reconnect, unless NO-RECONNECT is set to t.  Return nil if
1723 unsuccessful in connecting.
1724 If GROUP is nil, return t.
1725 If READ-ONLY is set, send EXAMINE rather than SELECT to the server.
1726 Return the server's response to the SELECT or EXAMINE command.
1727 "
1728   (let ((open-result t))
1729     (when (and server
1730                (not (nnimap-server-opened server)))
1731       (setq open-result (nnimap-open-server server nil no-reconnect)))
1732     (cond
1733      ((not open-result)
1734       nil)
1735      ((not group)
1736       t)
1737      (t
1738       (with-current-buffer (nnimap-buffer)
1739         (let ((result (nnimap-command "%s %S"
1740                                       (if read-only
1741                                           "EXAMINE"
1742                                         "SELECT")
1743                                       (utf7-encode group t))))
1744           (when (car result)
1745             (setf (nnimap-group nnimap-object) group
1746                   (nnimap-select-result nnimap-object) result)
1747             result)))))))
1748
1749 (defun nnimap-find-connection (buffer)
1750   "Find the connection delivering to BUFFER."
1751   (let ((entry (assoc buffer nnimap-connection-alist)))
1752     (when entry
1753       (if (and (buffer-name (cadr entry))
1754                (get-buffer-process (cadr entry))
1755                (memq (process-status (get-buffer-process (cadr entry)))
1756                      '(open run)))
1757           (get-buffer-process (cadr entry))
1758         (setq nnimap-connection-alist (delq entry nnimap-connection-alist))
1759         nil))))
1760
1761 (defvar nnimap-sequence 0)
1762
1763 (defun nnimap-send-command (&rest args)
1764   (setf (nnimap-last-command-time nnimap-object) (current-time))
1765   (process-send-string
1766    (get-buffer-process (current-buffer))
1767    (nnimap-log-command
1768     (format "%d %s%s\n"
1769             (incf nnimap-sequence)
1770             (apply #'format args)
1771             (if (nnimap-newlinep nnimap-object)
1772                 ""
1773               "\r"))))
1774   ;; Some servers apparently can't have many outstanding
1775   ;; commands, so throttle them.
1776   (unless nnimap-streaming
1777     (nnimap-wait-for-response nnimap-sequence))
1778   nnimap-sequence)
1779
1780 (defvar nnimap-record-commands nil
1781   "If non-nil, log commands to the \"*imap log*\" buffer.")
1782
1783 (defun nnimap-log-buffer ()
1784   (let ((name "*imap log*"))
1785     (or (get-buffer name)
1786         (with-current-buffer (get-buffer-create name)
1787           (when (boundp 'window-point-insertion-type)
1788             (make-local-variable 'window-point-insertion-type)
1789             (setq window-point-insertion-type t))
1790           (current-buffer)))))
1791
1792 (defun nnimap-log-command (command)
1793   (when nnimap-record-commands
1794     (with-current-buffer (nnimap-log-buffer)
1795       (goto-char (point-max))
1796       (insert (format-time-string "%H:%M:%S")
1797               " [" nnimap-address "] "
1798               (if nnimap-inhibit-logging
1799                   "(inhibited)\n"
1800                 command))))
1801   command)
1802
1803 (defun nnimap-command (&rest args)
1804   (erase-buffer)
1805   (let* ((sequence (apply #'nnimap-send-command args))
1806          (response (nnimap-get-response sequence)))
1807     (if (equal (caar response) "OK")
1808         (cons t response)
1809       (nnheader-report 'nnimap "%s"
1810                        (mapconcat (lambda (a)
1811                                     (format "%s" a))
1812                                   (car response) " "))
1813       nil)))
1814
1815 (defun nnimap-get-response (sequence)
1816   (nnimap-wait-for-response sequence)
1817   (nnimap-parse-response))
1818
1819 (defun nnimap-wait-for-connection (&optional regexp)
1820   (nnimap-wait-for-line (or regexp "^[*.] .*\n") "[*.] \\([A-Z0-9]+\\)"))
1821
1822 (defun nnimap-wait-for-line (regexp &optional response-regexp)
1823   (let ((process (get-buffer-process (current-buffer))))
1824     (goto-char (point-min))
1825     (while (and (memq (process-status process)
1826                       '(open run))
1827                 (not (re-search-forward regexp nil t)))
1828       (nnheader-accept-process-output process)
1829       (goto-char (point-min)))
1830     (forward-line -1)
1831     (and (looking-at (or response-regexp regexp))
1832          (match-string 1))))
1833
1834 (defun nnimap-wait-for-response (sequence &optional messagep)
1835   (let ((process (get-buffer-process (current-buffer)))
1836         openp)
1837     (condition-case nil
1838         (progn
1839           (goto-char (point-max))
1840           (while (and (setq openp (memq (process-status process)
1841                                         '(open run)))
1842                       (progn
1843                         ;; Skip past any "*" lines that the server has
1844                         ;; output.
1845                         (while (and (not (bobp))
1846                                     (progn
1847                                       (forward-line -1)
1848                                       (looking-at "\\*"))))
1849                         (not (looking-at (format "%d .*\n" sequence)))))
1850             (when messagep
1851               (nnheader-message-maybe
1852                7 "nnimap read %dk from %s%s" (/ (buffer-size) 1000)
1853                nnimap-address
1854                (if (not (zerop (nnimap-initial-resync nnimap-object)))
1855                    (format " (initial sync of %d group%s; please wait)"
1856                            (nnimap-initial-resync nnimap-object)
1857                            (if (= (nnimap-initial-resync nnimap-object) 1)
1858                                ""
1859                              "s"))
1860                  "")))
1861             (nnheader-accept-process-output process)
1862             (goto-char (point-max)))
1863           (setf (nnimap-initial-resync nnimap-object) 0)
1864           openp)
1865       (quit
1866        (when debug-on-quit
1867          (debug "Quit"))
1868        ;; The user hit C-g while we were waiting: kill the process, in case
1869        ;; it's a gnutls-cli process that's stuck (tends to happen a lot behind
1870        ;; NAT routers).
1871        (delete-process process)
1872        nil))))
1873
1874 (defun nnimap-parse-response ()
1875   (let ((lines (split-string (nnimap-last-response-string) "\r\n" t))
1876         result)
1877     (dolist (line lines)
1878       (push (cdr (nnimap-parse-line line)) result))
1879     ;; Return the OK/error code first, and then all the "continuation
1880     ;; lines" afterwards.
1881     (cons (pop result)
1882           (nreverse result))))
1883
1884 ;; Parse an IMAP response line lightly.  They look like
1885 ;; "* OK [UIDVALIDITY 1164213559] UIDs valid", typically, so parse
1886 ;; the lines into a list of strings and lists of string.
1887 (defun nnimap-parse-line (line)
1888   (let (char result)
1889     (with-temp-buffer
1890       (mm-disable-multibyte)
1891       (insert line)
1892       (goto-char (point-min))
1893       (while (not (eobp))
1894         (if (eql (setq char (following-char)) ? )
1895             (forward-char 1)
1896           (push
1897            (cond
1898             ((eql char ?\[)
1899              (split-string
1900               (buffer-substring
1901                (1+ (point))
1902                (if (search-forward "]" (line-end-position) 'move)
1903                    (1- (point))
1904                  (point)))))
1905             ((eql char ?\()
1906              (split-string
1907               (buffer-substring
1908                (1+ (point))
1909                (if (search-forward ")" (line-end-position) 'move)
1910                    (1- (point))
1911                  (point)))))
1912             ((eql char ?\")
1913              (forward-char 1)
1914              (buffer-substring
1915               (point)
1916               (1- (or (search-forward "\"" (line-end-position) 'move)
1917                       (point)))))
1918             (t
1919              (buffer-substring (point) (if (search-forward " " nil t)
1920                                            (1- (point))
1921                                          (goto-char (point-max))))))
1922            result)))
1923       (nreverse result))))
1924
1925 (defun nnimap-last-response-string ()
1926   (save-excursion
1927     (forward-line 1)
1928     (let ((end (point)))
1929       (forward-line -1)
1930       (when (not (bobp))
1931         (forward-line -1)
1932         (while (and (not (bobp))
1933                     (eql (following-char) ?*))
1934           (forward-line -1))
1935         (unless (eql (following-char) ?*)
1936           (forward-line 1)))
1937       (buffer-substring (point) end))))
1938
1939 (defvar nnimap-incoming-split-list nil)
1940
1941 (defun nnimap-fetch-inbox (articles)
1942   (erase-buffer)
1943   (nnimap-wait-for-response
1944    (nnimap-send-command
1945     "UID FETCH %s %s"
1946     (nnimap-article-ranges articles)
1947     (format "(UID %s%s)"
1948             (format
1949              (if (nnimap-ver4-p)
1950                  "BODY.PEEK"
1951                "RFC822.PEEK"))
1952             (cond
1953              (nnimap-split-download-body-default
1954               "[]")
1955              ((nnimap-ver4-p)
1956               "[HEADER]")
1957              (t
1958               "[1]"))))
1959    t))
1960
1961 (defun nnimap-split-incoming-mail ()
1962   (with-current-buffer (nnimap-buffer)
1963     (let ((nnimap-incoming-split-list nil)
1964           (nnmail-split-methods
1965            (cond
1966             ((eq nnimap-split-methods 'default)
1967              nnmail-split-methods)
1968             (nnimap-split-methods
1969              nnimap-split-methods)
1970             (nnimap-split-fancy
1971              'nnmail-split-fancy)))
1972           (nnmail-split-fancy (or nnimap-split-fancy
1973                                   nnmail-split-fancy))
1974           (nnmail-inhibit-default-split-group t)
1975           (groups (nnimap-get-groups))
1976           new-articles)
1977       (erase-buffer)
1978       (nnimap-command "SELECT %S" nnimap-inbox)
1979       (setf (nnimap-group nnimap-object) nnimap-inbox)
1980       (setq new-articles (nnimap-new-articles (nnimap-get-flags "1:*")))
1981       (when new-articles
1982         (nnimap-fetch-inbox new-articles)
1983         (nnimap-transform-split-mail)
1984         (nnheader-ms-strip-cr)
1985         (nnmail-cache-open)
1986         (nnmail-split-incoming (current-buffer)
1987                                #'nnimap-save-mail-spec
1988                                nil nil
1989                                #'nnimap-dummy-active-number
1990                                #'nnimap-save-mail-spec)
1991         (when nnimap-incoming-split-list
1992           (let ((specs (nnimap-make-split-specs nnimap-incoming-split-list))
1993                 sequences junk-articles)
1994             ;; Create any groups that doesn't already exist on the
1995             ;; server first.
1996             (dolist (spec specs)
1997               (when (and (not (member (car spec) groups))
1998                          (not (eq (car spec) 'junk)))
1999                 (nnimap-command "CREATE %S" (utf7-encode (car spec) t))))
2000             ;; Then copy over all the messages.
2001             (erase-buffer)
2002             (dolist (spec specs)
2003               (let ((group (car spec))
2004                     (ranges (cdr spec)))
2005                 (if (eq group 'junk)
2006                     (setq junk-articles ranges)
2007                   (push (list (nnimap-send-command
2008                                "UID COPY %s %S"
2009                                (nnimap-article-ranges ranges)
2010                                (utf7-encode group t))
2011                               ranges)
2012                         sequences))))
2013             ;; Wait for the last COPY response...
2014             (when sequences
2015               (nnimap-wait-for-response (caar sequences))
2016               ;; And then mark the successful copy actions as deleted,
2017               ;; and possibly expunge them.
2018               (nnimap-mark-and-expunge-incoming
2019                (nnimap-parse-copied-articles sequences)))
2020             (nnimap-mark-and-expunge-incoming junk-articles)))))))
2021
2022 (defun nnimap-mark-and-expunge-incoming (range)
2023   (when range
2024     (setq range (nnimap-article-ranges range))
2025     (erase-buffer)
2026     (let ((sequence
2027            (nnimap-send-command
2028             "UID STORE %s +FLAGS.SILENT (\\Deleted)" range)))
2029       (cond
2030        ;; If the server supports it, we now delete the message we have
2031        ;; just copied over.
2032        ((nnimap-capability "UIDPLUS")
2033         (setq sequence (nnimap-send-command "UID EXPUNGE %s" range)))
2034        ;; If it doesn't support UID EXPUNGE, then we only expunge if the
2035        ;; user has configured it.
2036        (nnimap-expunge
2037         (setq sequence (nnimap-send-command "EXPUNGE"))))
2038       (nnimap-wait-for-response sequence))))
2039
2040 (defun nnimap-parse-copied-articles (sequences)
2041   (let (sequence copied range)
2042     (goto-char (point-min))
2043     (while (re-search-forward "^\\([0-9]+\\) OK\\b" nil t)
2044       (setq sequence (string-to-number (match-string 1)))
2045       (when (setq range (cadr (assq sequence sequences)))
2046         (push (gnus-uncompress-range range) copied)))
2047     (gnus-compress-sequence (sort (apply #'nconc copied) #'<))))
2048
2049 (defun nnimap-new-articles (flags)
2050   (let (new)
2051     (dolist (elem flags)
2052       (unless (gnus-list-memq-of-list nnimap-unsplittable-articles
2053                                       (cdr elem))
2054         (push (car elem) new)))
2055     (gnus-compress-sequence (nreverse new))))
2056
2057 (defun nnimap-make-split-specs (list)
2058   (let ((specs nil)
2059         entry)
2060     (dolist (elem list)
2061       (destructuring-bind (article spec) elem
2062         (dolist (group (delete nil (mapcar #'car spec)))
2063           (unless (setq entry (assoc group specs))
2064             (push (setq entry (list group)) specs))
2065           (setcdr entry (cons article (cdr entry))))))
2066     (dolist (entry specs)
2067       (setcdr entry (gnus-compress-sequence (sort (cdr entry) #'<))))
2068     specs))
2069
2070 (defun nnimap-transform-split-mail ()
2071   (goto-char (point-min))
2072   (let (article bytes)
2073     (block nil
2074       (while (not (eobp))
2075         (while (not (looking-at "\\* [0-9]+ FETCH.+UID \\([0-9]+\\)"))
2076           (delete-region (point) (progn (forward-line 1) (point)))
2077           (when (eobp)
2078             (return)))
2079         (setq article (match-string 1)
2080               bytes (nnimap-get-length))
2081         (delete-region (line-beginning-position) (line-end-position))
2082         ;; Insert MMDF separator, and a way to remember what this
2083         ;; article UID is.
2084         (insert (format "\^A\^A\^A\^A\n\nX-nnimap-article: %s" article))
2085         (forward-char (1+ bytes))
2086         (setq bytes (nnimap-get-length))
2087         (delete-region (line-beginning-position) (line-end-position))
2088         ;; There's a body; skip past that.
2089         (when bytes
2090           (forward-char (1+ bytes))
2091           (delete-region (line-beginning-position) (line-end-position)))))))
2092
2093 (defun nnimap-dummy-active-number (group &optional server)
2094   1)
2095
2096 (defun nnimap-save-mail-spec (group-art &optional server full-nov)
2097   (let (article)
2098     (goto-char (point-min))
2099     (if (not (re-search-forward "X-nnimap-article: \\([0-9]+\\)" nil t))
2100         (error "Invalid nnimap mail")
2101       (setq article (string-to-number (match-string 1))))
2102     (push (list article
2103                 (if (eq group-art 'junk)
2104                     (list (cons 'junk 1))
2105                   group-art))
2106           nnimap-incoming-split-list)))
2107
2108 (defun nnimap-make-thread-query (header)
2109   (let* ((id  (mail-header-id header))
2110          (refs (split-string
2111                 (or (mail-header-references header)
2112                     "")))
2113          (value
2114           (format
2115            "(OR HEADER REFERENCES %S HEADER Message-Id %S)"
2116            id id)))
2117     (dolist (refid refs value)
2118       (setq value (format
2119                    "(OR (OR HEADER Message-Id %S HEADER REFERENCES %S) %s)"
2120                    refid refid value)))))
2121
2122
2123 (provide 'nnimap)
2124
2125 ;;; nnimap.el ends here