cgit.sxemacs.org Git - gnus/blob - lisp/nnimap.el

   1 ;;; nnimap.el --- IMAP interface for Gnus
   2
   3 ;; Copyright (C) 2010-2012 Free Software Foundation, Inc.
   4
   5 ;; Author: Lars Magne Ingebrigtsen <larsi@gnus.org>
   6 ;;         Simon Josefsson <simon@josefsson.org>
   7
   8 ;; This file is part of GNU Emacs.
   9
  10 ;; GNU Emacs is free software: you can redistribute it and/or modify
  11 ;; it under the terms of the GNU General Public License as published by
  12 ;; the Free Software Foundation, either version 3 of the License, or
  13 ;; (at your option) any later version.
  14
  15 ;; GNU Emacs is distributed in the hope that it will be useful,
  16 ;; but WITHOUT ANY WARRANTY; without even the implied warranty of
  17 ;; MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.  See the
  18 ;; GNU General Public License for more details.
  19
  20 ;; You should have received a copy of the GNU General Public License
  21 ;; along with GNU Emacs.  If not, see <http://www.gnu.org/licenses/>.
  22
  23 ;;; Commentary:
  24
  25 ;; nnimap interfaces Gnus with IMAP servers.
  26
  27 ;;; Code:
  28
  29 ;; For Emacs <22.2 and XEmacs.
  30 (eval-and-compile
  31   (unless (fboundp 'declare-function) (defmacro declare-function (&rest r))))
  32
  33 (eval-and-compile
  34   (require 'nnheader)
  35   ;; In Emacs 24, `open-protocol-stream' is an autoloaded alias for
  36   ;; `make-network-stream'.
  37   (unless (fboundp 'open-protocol-stream)
  38     (require 'proto-stream)))
  39
  40 (eval-when-compile
  41   (require 'cl))
  42
  43 (require 'nnheader)
  44 (require 'gnus-util)
  45 (require 'gnus)
  46 (require 'nnoo)
  47 (require 'netrc)
  48 (require 'utf7)
  49 (require 'tls)
  50 (require 'parse-time)
  51 (require 'nnmail)
  52
  53 (autoload 'auth-source-forget+ "auth-source")
  54 (autoload 'auth-source-search "auth-source")
  55
  56 (nnoo-declare nnimap)
  57
  58 (defvoo nnimap-address nil
  59   "The address of the IMAP server.")
  60
  61 (defvoo nnimap-user nil
  62   "Username to use for authentication to the IMAP server.")
  63
  64 (defvoo nnimap-server-port nil
  65   "The IMAP port used.
  66 If nnimap-stream is `ssl', this will default to `imaps'.  If not,
  67 it will default to `imap'.")
  68
  69 (defvoo nnimap-stream 'undecided
  70   "How nnimap talks to the IMAP server.
  71 The value should be either `undecided', `ssl' or `tls',
  72 `network', `starttls', `plain', or `shell'.
  73
  74 If the value is `undecided', nnimap tries `ssl' first, then falls
  75 back on `network'.")
  76
  77 (defvoo nnimap-shell-program (if (boundp 'imap-shell-program)
  78                                  (if (listp imap-shell-program)
  79                                      (car imap-shell-program)
  80                                    imap-shell-program)
  81                                "ssh %s imapd"))
  82
  83 (defvoo nnimap-inbox nil
  84   "The mail box where incoming mail arrives and should be split out of.
  85 This can be a string or a list of strings
  86 For example, \"INBOX\" or (\"INBOX\" \"SENT\").")
  87
  88 (defvoo nnimap-split-methods nil
  89   "How mail is split.
  90 Uses the same syntax as `nnmail-split-methods'.")
  91
  92 (defvoo nnimap-split-fancy nil
  93   "Uses the same syntax as `nnmail-split-fancy'.")
  94
  95 (defvoo nnimap-unsplittable-articles '(%Deleted %Seen)
  96   "Articles with the flags in the list will not be considered when splitting.")
  97
  98 (make-obsolete-variable 'nnimap-split-rule "see `nnimap-split-methods'"
  99                         "Emacs 24.1")
 100
 101 (defvoo nnimap-authenticator nil
 102   "How nnimap authenticate itself to the server.
 103 Possible choices are nil (use default methods) or `anonymous'.")
 104
 105 (defvoo nnimap-expunge t
 106   "If non-nil, expunge articles after deleting them.
 107 This is always done if the server supports UID EXPUNGE, but it's
 108 not done by default on servers that doesn't support that command.")
 109
 110 (defvoo nnimap-streaming t
 111   "If non-nil, try to use streaming commands with IMAP servers.
 112 Switching this off will make nnimap slower, but it helps with
 113 some servers.")
 114
 115 (defvoo nnimap-connection-alist nil)
 116
 117 (defvoo nnimap-current-infos nil)
 118
 119 (defvoo nnimap-fetch-partial-articles nil
 120   "If non-nil, Gnus will fetch partial articles.
 121 If t, Gnus will fetch only the first part.  If a string, it
 122 will fetch all parts that have types that match that string.  A
 123 likely value would be \"text/\" to automatically fetch all
 124 textual parts.")
 125
 126 (defgroup nnimap nil
 127   "IMAP for Gnus."
 128   :group 'gnus)
 129
 130 (defcustom nnimap-request-articles-find-limit nil
 131   "Limit the number of articles to look for after moving an article."
 132   :type 'integer
 133   :version "24.3"
 134   :group 'nnimap)
 135
 136 (defvar nnimap-process nil)
 137
 138 (defvar nnimap-status-string "")
 139
 140 (defvar nnimap-split-download-body-default nil
 141   "Internal variable with default value for `nnimap-split-download-body'.")
 142
 143 (defvar nnimap-keepalive-timer nil)
 144 (defvar nnimap-process-buffers nil)
 145
 146 (defstruct nnimap
 147   group process commands capabilities select-result newlinep server
 148   last-command-time greeting examined stream-type initial-resync)
 149
 150 (defvar nnimap-object nil)
 151
 152 (defvar nnimap-mark-alist
 153   '((read "\\Seen" %Seen)
 154     (tick "\\Flagged" %Flagged)
 155     (reply "\\Answered" %Answered)
 156     (expire "gnus-expire")
 157     (dormant "gnus-dormant")
 158     (score "gnus-score")
 159     (save "gnus-save")
 160     (download "gnus-download")
 161     (forward "gnus-forward")))
 162
 163 (defvar nnimap-quirks
 164   '(("QRESYNC" "Zimbra" "QRESYNC ")))
 165
 166 (defvar nnimap-inhibit-logging nil)
 167
 168 (defun nnimap-buffer ()
 169   (nnimap-find-process-buffer nntp-server-buffer))
 170
 171 (defun nnimap-header-parameters ()
 172   (format "(UID RFC822.SIZE BODYSTRUCTURE %s)"
 173           (format
 174            (if (nnimap-ver4-p)
 175                "BODY.PEEK[HEADER.FIELDS %s]"
 176              "RFC822.HEADER.LINES %s")
 177            (append '(Subject From Date Message-Id
 178                              References In-Reply-To Xref)
 179                    nnmail-extra-headers))))
 180
 181 (deffoo nnimap-retrieve-headers (articles &optional group server fetch-old)
 182   (when group
 183     (setq group (nnimap-decode-gnus-group group)))
 184   (with-current-buffer nntp-server-buffer
 185     (erase-buffer)
 186     (when (nnimap-change-group group server)
 187       (with-current-buffer (nnimap-buffer)
 188         (erase-buffer)
 189         (nnimap-wait-for-response
 190          (nnimap-send-command
 191           "UID FETCH %s %s"
 192           (nnimap-article-ranges (gnus-compress-sequence articles))
 193           (nnimap-header-parameters))
 194          t)
 195         (nnimap-transform-headers)
 196         (nnheader-remove-cr-followed-by-lf))
 197       (insert-buffer-substring
 198        (nnimap-find-process-buffer (current-buffer))))
 199     'headers))
 200
 201 (defun nnimap-transform-headers ()
 202   (goto-char (point-min))
 203   (let (article lines size string)
 204     (block nil
 205       (while (not (eobp))
 206         (while (not (looking-at "\\* [0-9]+ FETCH"))
 207           (delete-region (point) (progn (forward-line 1) (point)))
 208           (when (eobp)
 209             (return)))
 210         (goto-char (match-end 0))
 211         ;; Unfold quoted {number} strings.
 212         (while (re-search-forward
 213                 "[^]][ (]{\\([0-9]+\\)}\r?\n"
 214                 (save-excursion
 215                   ;; Start of the header section.
 216                   (or (re-search-forward "] {[0-9]+}\r?\n" nil t)
 217                       ;; Start of the next FETCH.
 218                       (re-search-forward "\\* [0-9]+ FETCH" nil t)
 219                       (point-max)))
 220                 t)
 221           (setq size (string-to-number (match-string 1)))
 222           (delete-region (+ (match-beginning 0) 2) (point))
 223           (setq string (buffer-substring (point) (+ (point) size)))
 224           (delete-region (point) (+ (point) size))
 225           (insert (format "%S" (mm-subst-char-in-string ?\n ?\s string))))
 226         (beginning-of-line)
 227         (setq article
 228               (and (re-search-forward "UID \\([0-9]+\\)" (line-end-position)
 229                                       t)
 230                    (match-string 1)))
 231         (setq lines nil)
 232         (setq size
 233               (and (re-search-forward "RFC822.SIZE \\([0-9]+\\)"
 234                                       (line-end-position)
 235                                       t)
 236                    (match-string 1)))
 237         (beginning-of-line)
 238         (when (search-forward "BODYSTRUCTURE" (line-end-position) t)
 239           (let ((structure (ignore-errors
 240                              (read (current-buffer)))))
 241             (while (and (consp structure)
 242                         (not (atom (car structure))))
 243               (setq structure (car structure)))
 244             (setq lines (if (and
 245                              (stringp (car structure))
 246                              (equal (upcase (nth 0 structure)) "MESSAGE")
 247                              (equal (upcase (nth 1 structure)) "RFC822"))
 248                             (nth 9 structure)
 249                           (nth 7 structure)))))
 250         (delete-region (line-beginning-position) (line-end-position))
 251         (insert (format "211 %s Article retrieved." article))
 252         (forward-line 1)
 253         (when size
 254           (insert (format "Chars: %s\n" size)))
 255         (when lines
 256           (insert (format "Lines: %s\n" lines)))
 257         (unless (re-search-forward "^\r$" nil t)
 258           (goto-char (point-max)))
 259         (delete-region (line-beginning-position) (line-end-position))
 260         (insert ".")
 261         (forward-line 1)))))
 262
 263 (defun nnimap-unfold-quoted-lines ()
 264   ;; Unfold quoted {number} strings.
 265   (let (size string)
 266     (while (re-search-forward " {\\([0-9]+\\)}\r?\n" nil t)
 267       (setq size (string-to-number (match-string 1)))
 268       (delete-region (1+ (match-beginning 0)) (point))
 269       (setq string (buffer-substring (point) (+ (point) size)))
 270       (delete-region (point) (+ (point) size))
 271       (insert (format "%S" string)))))
 272
 273 (defun nnimap-get-length ()
 274   (and (re-search-forward "{\\([0-9]+\\)}" (line-end-position) t)
 275        (string-to-number (match-string 1))))
 276
 277 (defun nnimap-article-ranges (ranges)
 278   (let (result)
 279     (cond
 280      ((numberp ranges)
 281       (number-to-string ranges))
 282      ((numberp (cdr ranges))
 283       (format "%d:%d" (car ranges) (cdr ranges)))
 284      (t
 285       (dolist (elem ranges)
 286         (push
 287          (if (consp elem)
 288              (format "%d:%d" (car elem) (cdr elem))
 289            (number-to-string elem))
 290          result))
 291       (mapconcat #'identity (nreverse result) ",")))))
 292
 293 (deffoo nnimap-open-server (server &optional defs no-reconnect)
 294   (if (nnimap-server-opened server)
 295       t
 296     (unless (assq 'nnimap-address defs)
 297       (setq defs (append defs (list (list 'nnimap-address server)))))
 298     (nnoo-change-server 'nnimap server defs)
 299     (if no-reconnect
 300         (nnimap-find-connection nntp-server-buffer)
 301       (or (nnimap-find-connection nntp-server-buffer)
 302           (nnimap-open-connection nntp-server-buffer)))))
 303
 304 (defun nnimap-make-process-buffer (buffer)
 305   (with-current-buffer
 306       (generate-new-buffer (format " *nnimap %s %s %s*"
 307                                    nnimap-address nnimap-server-port
 308                                    (gnus-buffer-exists-p buffer)))
 309     (mm-disable-multibyte)
 310     (buffer-disable-undo)
 311     (gnus-add-buffer)
 312     (set (make-local-variable 'after-change-functions) nil)
 313     (set (make-local-variable 'nnimap-object)
 314          (make-nnimap :server (nnoo-current-server 'nnimap)
 315                       :initial-resync 0))
 316     (push (list buffer (current-buffer)) nnimap-connection-alist)
 317     (push (current-buffer) nnimap-process-buffers)
 318     (current-buffer)))
 319
 320 (defun nnimap-credentials (address ports user)
 321   (let* ((auth-source-creation-prompts
 322           '((user  . "IMAP user at %h: ")
 323             (secret . "IMAP password for %u@%h: ")))
 324          (found (nth 0 (auth-source-search :max 1
 325                                            :host address
 326                                            :port ports
 327                                            :user user
 328                                            :require '(:user :secret)
 329                                            :create t))))
 330     (if found
 331         (list (plist-get found :user)
 332               (let ((secret (plist-get found :secret)))
 333                 (if (functionp secret)
 334                     (funcall secret)
 335                   secret))
 336               (plist-get found :save-function))
 337       nil)))
 338
 339 (defun nnimap-keepalive ()
 340   (let ((now (current-time)))
 341     (dolist (buffer nnimap-process-buffers)
 342       (when (buffer-name buffer)
 343         (with-current-buffer buffer
 344           (when (and nnimap-object
 345                      (nnimap-last-command-time nnimap-object)
 346                      (> (gnus-float-time
 347                          (time-subtract
 348                           now
 349                           (nnimap-last-command-time nnimap-object)))
 350                         ;; More than five minutes since the last command.
 351                         (* 5 60)))
 352             (nnimap-send-command "NOOP")))))))
 353
 354 (defun nnimap-open-connection (buffer)
 355   ;; Be backwards-compatible -- the earlier value of nnimap-stream was
 356   ;; `ssl' when nnimap-server-port was nil.  Sort of.
 357   (when (and nnimap-server-port
 358              (eq nnimap-stream 'undecided))
 359     (setq nnimap-stream 'ssl))
 360   (let ((stream
 361          (if (eq nnimap-stream 'undecided)
 362              (loop for type in '(ssl network)
 363                    for stream = (let ((nnimap-stream type))
 364                                   (nnimap-open-connection-1 buffer))
 365                    while (eq stream 'no-connect)
 366                    finally (return stream))
 367            (nnimap-open-connection-1 buffer))))
 368     (if (eq stream 'no-connect)
 369         nil
 370       stream)))
 371
 372 (defun nnimap-map-port (port)
 373   (if (equal port "imaps")
 374       "993"
 375     port))
 376
 377 (defun nnimap-open-connection-1 (buffer)
 378   (unless nnimap-keepalive-timer
 379     (setq nnimap-keepalive-timer (run-at-time (* 60 15) (* 60 15)
 380                                               'nnimap-keepalive)))
 381   (with-current-buffer (nnimap-make-process-buffer buffer)
 382     (let* ((coding-system-for-read 'binary)
 383            (coding-system-for-write 'binary)
 384            (ports
 385             (cond
 386              ((memq nnimap-stream '(network plain starttls))
 387               (nnheader-message 7 "Opening connection to %s..."
 388                                 nnimap-address)
 389               '("imap" "143"))
 390              ((eq nnimap-stream 'shell)
 391               (nnheader-message 7 "Opening connection to %s via shell..."
 392                                 nnimap-address)
 393               '("imap"))
 394              ((memq nnimap-stream '(ssl tls))
 395               (nnheader-message 7 "Opening connection to %s via tls..."
 396                                 nnimap-address)
 397               '("imaps" "imap" "993" "143"))
 398              (t
 399               (error "Unknown stream type: %s" nnimap-stream))))
 400            login-result credentials)
 401       (when nnimap-server-port
 402         (push nnimap-server-port ports))
 403       (let* ((stream-list
 404               (open-protocol-stream
 405                "*nnimap*" (current-buffer) nnimap-address
 406                (nnimap-map-port (car ports))
 407                :type nnimap-stream
 408                :return-list t
 409                :shell-command nnimap-shell-program
 410                :capability-command "1 CAPABILITY\r\n"
 411                :end-of-command "\r\n"
 412                :success " OK "
 413                :starttls-function
 414                (lambda (capabilities)
 415                  (when (gnus-string-match-p "STARTTLS" capabilities)
 416                    "1 STARTTLS\r\n"))))
 417              (stream (car stream-list))
 418              (props (cdr stream-list))
 419              (greeting (plist-get props :greeting))
 420              (capabilities (plist-get props :capabilities))
 421              (stream-type (plist-get props :type)))
 422         (when (and stream (not (memq (process-status stream) '(open run))))
 423           (setq stream nil))
 424
 425         (when (and (fboundp 'set-network-process-option) ;; Not in XEmacs.
 426                    (fboundp 'process-type) ;; Emacs 22 doesn't provide it.
 427                    (eq (process-type stream) 'network))
 428           ;; Use TCP-keepalive so that connections that pass through a NAT
 429           ;; router don't hang when left idle.
 430           (set-network-process-option stream :keepalive t))
 431
 432         (setf (nnimap-process nnimap-object) stream)
 433         (setf (nnimap-stream-type nnimap-object) stream-type)
 434         (if (not stream)
 435             (progn
 436               (nnheader-report 'nnimap "Unable to contact %s:%s via %s"
 437                                nnimap-address (car ports) nnimap-stream)
 438               'no-connect)
 439           (gnus-set-process-query-on-exit-flag stream nil)
 440           (if (not (gnus-string-match-p "[*.] \\(OK\\|PREAUTH\\)" greeting))
 441               (nnheader-report 'nnimap "%s" greeting)
 442             ;; Store the greeting (for debugging purposes).
 443             (setf (nnimap-greeting nnimap-object) greeting)
 444             (setf (nnimap-capabilities nnimap-object)
 445                   (mapcar #'upcase
 446                           (split-string capabilities)))
 447             (unless (gnus-string-match-p "[*.] PREAUTH" greeting)
 448               (if (not (setq credentials
 449                              (if (eq nnimap-authenticator 'anonymous)
 450                                  (list "anonymous"
 451                                        (message-make-address))
 452                                ;; Look for the credentials based on
 453                                ;; the virtual server name and the address
 454                                (nnimap-credentials
 455                                 (gnus-delete-duplicates
 456                                  (list
 457                                   nnimap-address
 458                                   (nnoo-current-server 'nnimap)))
 459                                 ports
 460                                 nnimap-user))))
 461                   (setq nnimap-object nil)
 462                 (let ((nnimap-inhibit-logging t))
 463                   (setq login-result
 464                         (nnimap-login (car credentials) (cadr credentials))))
 465                 (if (car login-result)
 466                     (progn
 467                       ;; Save the credentials if a save function exists
 468                       ;; (such a function will only be passed if a new
 469                       ;; token was created).
 470                       (when (functionp (nth 2 credentials))
 471                         (funcall (nth 2 credentials)))
 472                       ;; See if CAPABILITY is set as part of login
 473                       ;; response.
 474                       (dolist (response (cddr login-result))
 475                         (when (string= "CAPABILITY" (upcase (car response)))
 476                           (setf (nnimap-capabilities nnimap-object)
 477                                 (mapcar #'upcase (cdr response))))))
 478                   ;; If the login failed, then forget the credentials
 479                   ;; that are now possibly cached.
 480                   (dolist (host (list (nnoo-current-server 'nnimap)
 481                                       nnimap-address))
 482                     (dolist (port ports)
 483                       (auth-source-forget+ :host host :port port)))
 484                   (delete-process (nnimap-process nnimap-object))
 485                   (setq nnimap-object nil))))
 486             (when nnimap-object
 487               (when (nnimap-capability "QRESYNC")
 488                 (nnimap-command "ENABLE QRESYNC"))
 489               (nnheader-message 7 "Opening connection to %s...done"
 490                                 nnimap-address)
 491               (nnimap-process nnimap-object))))))))
 492
 493 (autoload 'rfc2104-hash "rfc2104")
 494
 495 (defun nnimap-login (user password)
 496   (cond
 497    ;; Prefer plain LOGIN if it's enabled (since it requires fewer
 498    ;; round trips than CRAM-MD5, and it's less likely to be buggy),
 499    ;; and we're using an encrypted connection.
 500    ((and (not (nnimap-capability "LOGINDISABLED"))
 501          (eq (nnimap-stream-type nnimap-object) 'tls))
 502     (nnimap-command "LOGIN %S %S" user password))
 503    ((nnimap-capability "AUTH=CRAM-MD5")
 504     (erase-buffer)
 505     (let ((sequence (nnimap-send-command "AUTHENTICATE CRAM-MD5"))
 506           (challenge (nnimap-wait-for-line "^\\+\\(.*\\)\n")))
 507       (process-send-string
 508        (get-buffer-process (current-buffer))
 509        (concat
 510         (base64-encode-string
 511          (concat user " "
 512                  (rfc2104-hash 'md5 64 16 password
 513                                (base64-decode-string challenge))))
 514         "\r\n"))
 515       (nnimap-wait-for-response sequence)))
 516    ((not (nnimap-capability "LOGINDISABLED"))
 517     (nnimap-command "LOGIN %S %S" user password))
 518    ((nnimap-capability "AUTH=PLAIN")
 519     (nnimap-command
 520      "AUTHENTICATE PLAIN %s"
 521      (base64-encode-string
 522       (format "\000%s\000%s"
 523               (nnimap-quote-specials user)
 524               (nnimap-quote-specials password)))))))
 525
 526 (defun nnimap-quote-specials (string)
 527   (with-temp-buffer
 528     (insert string)
 529     (goto-char (point-min))
 530     (while (re-search-forward "[\\\"]" nil t)
 531       (forward-char -1)
 532       (insert "\\")
 533       (forward-char 1))
 534     (buffer-string)))
 535
 536 (defun nnimap-find-parameter (parameter elems)
 537   (let (result)
 538     (dolist (elem elems)
 539       (cond
 540        ((equal (car elem) parameter)
 541         (setq result (cdr elem)))
 542        ((and (equal (car elem) "OK")
 543              (consp (cadr elem))
 544              (equal (caadr elem) parameter))
 545         (setq result (cdr (cadr elem))))))
 546     result))
 547
 548 (deffoo nnimap-close-server (&optional server)
 549   (when (nnoo-change-server 'nnimap server nil)
 550     (ignore-errors
 551       (delete-process (get-buffer-process (nnimap-buffer))))
 552     (nnoo-close-server 'nnimap server)
 553     t))
 554
 555 (deffoo nnimap-request-close ()
 556   t)
 557
 558 (deffoo nnimap-server-opened (&optional server)
 559   (and (nnoo-current-server-p 'nnimap server)
 560        nntp-server-buffer
 561        (gnus-buffer-live-p nntp-server-buffer)
 562        (nnimap-find-connection nntp-server-buffer)))
 563
 564 (deffoo nnimap-status-message (&optional server)
 565   nnimap-status-string)
 566
 567 (deffoo nnimap-request-article (article &optional group server to-buffer)
 568   (when group
 569     (setq group (nnimap-decode-gnus-group group)))
 570   (with-current-buffer nntp-server-buffer
 571     (let ((result (nnimap-change-group group server))
 572           parts structure)
 573       (when (stringp article)
 574         (setq article (nnimap-find-article-by-message-id group server article)))
 575       (when (and result
 576                  article)
 577         (erase-buffer)
 578         (with-current-buffer (nnimap-buffer)
 579           (erase-buffer)
 580           (when nnimap-fetch-partial-articles
 581             (nnimap-command "UID FETCH %d (BODYSTRUCTURE)" article)
 582             (goto-char (point-min))
 583             (when (re-search-forward "FETCH.*BODYSTRUCTURE" nil t)
 584               (setq structure (ignore-errors
 585                                 (let ((start (point)))
 586                                   (forward-sexp 1)
 587                                   (downcase-region start (point))
 588                                   (goto-char start)
 589                                   (read (current-buffer))))
 590                     parts (nnimap-find-wanted-parts structure))))
 591           (when (if parts
 592                     (nnimap-get-partial-article article parts structure)
 593                   (nnimap-get-whole-article article))
 594             (let ((buffer (current-buffer)))
 595               (with-current-buffer (or to-buffer nntp-server-buffer)
 596                 (nnheader-insert-buffer-substring buffer)
 597                 (nnheader-ms-strip-cr)))
 598             (cons group article)))))))
 599
 600 (deffoo nnimap-request-head (article &optional group server to-buffer)
 601   (when group
 602     (setq group (nnimap-decode-gnus-group group)))
 603   (when (nnimap-change-group group server)
 604     (with-current-buffer (nnimap-buffer)
 605       (when (stringp article)
 606         (setq article (nnimap-find-article-by-message-id group server article)))
 607       (if (null article)
 608           nil
 609         (nnimap-get-whole-article
 610          article (format "UID FETCH %%d %s"
 611                          (nnimap-header-parameters)))
 612         (let ((buffer (current-buffer)))
 613           (with-current-buffer (or to-buffer nntp-server-buffer)
 614             (erase-buffer)
 615             (insert-buffer-substring buffer)
 616             (nnheader-ms-strip-cr)
 617             (cons group article)))))))
 618
 619 (defun nnimap-get-whole-article (article &optional command)
 620   (let ((result
 621          (nnimap-command
 622           (or command
 623               (if (nnimap-ver4-p)
 624                   "UID FETCH %d BODY.PEEK[]"
 625                 "UID FETCH %d RFC822.PEEK"))
 626           article)))
 627     ;; Check that we really got an article.
 628     (goto-char (point-min))
 629     (unless (re-search-forward "\\* [0-9]+ FETCH" nil t)
 630       (setq result nil))
 631     (when result
 632       ;; Remove any data that may have arrived before the FETCH data.
 633       (beginning-of-line)
 634       (unless (bobp)
 635         (delete-region (point-min) (point)))
 636       (let ((bytes (nnimap-get-length)))
 637         (delete-region (line-beginning-position)
 638                        (progn (forward-line 1) (point)))
 639         (goto-char (+ (point) bytes))
 640         (delete-region (point) (point-max)))
 641       t)))
 642
 643 (defun nnimap-capability (capability)
 644   (member capability (nnimap-capabilities nnimap-object)))
 645
 646 (defun nnimap-ver4-p ()
 647   (nnimap-capability "IMAP4REV1"))
 648
 649 (defun nnimap-get-partial-article (article parts structure)
 650   (let ((result
 651          (nnimap-command
 652           "UID FETCH %d (%s %s)"
 653           article
 654           (if (nnimap-ver4-p)
 655               "BODY.PEEK[HEADER]"
 656             "RFC822.HEADER")
 657           (if (nnimap-ver4-p)
 658               (mapconcat (lambda (part)
 659                            (format "BODY.PEEK[%s]" part))
 660                          parts " ")
 661             (mapconcat (lambda (part)
 662                          (format "RFC822.PEEK[%s]" part))
 663                        parts " ")))))
 664     (when result
 665       (nnimap-convert-partial-article structure))))
 666
 667 (defun nnimap-convert-partial-article (structure)
 668   ;; First just skip past the headers.
 669   (goto-char (point-min))
 670   (let ((bytes (nnimap-get-length))
 671         id parts)
 672     ;; Delete "FETCH" line.
 673     (delete-region (line-beginning-position)
 674                    (progn (forward-line 1) (point)))
 675     (goto-char (+ (point) bytes))
 676     ;; Collect all the body parts.
 677     (while (looking-at ".*BODY\\[\\([.0-9]+\\)\\]")
 678       (setq id (match-string 1)
 679             bytes (or (nnimap-get-length) 0))
 680       (beginning-of-line)
 681       (delete-region (point) (progn (forward-line 1) (point)))
 682       (push (list id (buffer-substring (point) (+ (point) bytes)))
 683             parts)
 684       (delete-region (point) (+ (point) bytes)))
 685     ;; Delete trailing junk.
 686     (delete-region (point) (point-max))
 687     ;; Now insert all the parts again where they fit in the structure.
 688     (nnimap-insert-partial-structure structure parts)
 689     t))
 690
 691 (defun nnimap-insert-partial-structure (structure parts &optional subp)
 692   (let (type boundary)
 693     (let ((bstruc structure))
 694       (while (consp (car bstruc))
 695         (pop bstruc))
 696       (setq type (car bstruc))
 697       (setq bstruc (car (cdr bstruc)))
 698       (let ((has-boundary (member "boundary" bstruc)))
 699         (when has-boundary
 700           (setq boundary (cadr has-boundary)))))
 701     (when subp
 702       (insert (format "Content-type: multipart/%s; boundary=%S\n\n"
 703                       (downcase type) boundary)))
 704     (while (not (stringp (car structure)))
 705       (insert "\n--" boundary "\n")
 706       (if (consp (caar structure))
 707           (nnimap-insert-partial-structure (pop structure) parts t)
 708         (let ((bit (pop structure)))
 709           (insert (format "Content-type: %s/%s"
 710                           (downcase (nth 0 bit))
 711                           (downcase (nth 1 bit))))
 712           (if (member-ignore-case "CHARSET" (nth 2 bit))
 713               (insert (format
 714                        "; charset=%S\n"
 715                        (cadr (member-ignore-case "CHARSET" (nth 2 bit)))))
 716             (insert "\n"))
 717           (insert (format "Content-transfer-encoding: %s\n"
 718                           (nth 5 bit)))
 719           (insert "\n")
 720           (when (assoc (nth 9 bit) parts)
 721             (insert (cadr (assoc (nth 9 bit) parts)))))))
 722     (insert "\n--" boundary "--\n")))
 723
 724 (defun nnimap-find-wanted-parts (structure)
 725   (message-flatten-list (nnimap-find-wanted-parts-1 structure "")))
 726
 727 (defun nnimap-find-wanted-parts-1 (structure prefix)
 728   (let ((num 1)
 729         parts)
 730     (while (consp (car structure))
 731       (let ((sub (pop structure)))
 732         (if (consp (car sub))
 733             (push (nnimap-find-wanted-parts-1
 734                    sub (if (string= prefix "")
 735                            (number-to-string num)
 736                          (format "%s.%s" prefix num)))
 737                   parts)
 738           (let ((type (format "%s/%s" (nth 0 sub) (nth 1 sub)))
 739                 (id (if (string= prefix "")
 740                         (number-to-string num)
 741                       (format "%s.%s" prefix num))))
 742             (setcar (nthcdr 9 sub) id)
 743             (when (if (eq nnimap-fetch-partial-articles t)
 744                       (equal id "1")
 745                     (string-match nnimap-fetch-partial-articles type))
 746               (push id parts))))
 747         (incf num)))
 748     (nreverse parts)))
 749
 750 (defun nnimap-decode-gnus-group (group)
 751   (decode-coding-string group 'utf-8))
 752
 753 (deffoo nnimap-request-group (group &optional server dont-check info)
 754   (setq group (nnimap-decode-gnus-group group))
 755   (let ((result (nnimap-change-group
 756                  ;; Don't SELECT the group if we're going to select it
 757                  ;; later, anyway.
 758                  (if (and (not dont-check)
 759                           (assoc group nnimap-current-infos))
 760                      nil
 761                    group)
 762                  server))
 763         articles active marks high low)
 764     (with-current-buffer nntp-server-buffer
 765       (when result
 766         (if (and dont-check
 767                  (setq active (nth 2 (assoc group nnimap-current-infos))))
 768             (insert (format "211 %d %d %d %S\n"
 769                             (- (cdr active) (car active))
 770                             (car active)
 771                             (cdr active)
 772                             group))
 773           (with-current-buffer (nnimap-buffer)
 774             (erase-buffer)
 775             (let ((group-sequence
 776                    (nnimap-send-command "SELECT %S" (utf7-encode group t)))
 777                   (flag-sequence
 778                    (nnimap-send-command "UID FETCH 1:* FLAGS")))
 779               (setf (nnimap-group nnimap-object) group)
 780               (nnimap-wait-for-response flag-sequence)
 781               (setq marks
 782                     (nnimap-flags-to-marks
 783                      (nnimap-parse-flags
 784                       (list (list group-sequence flag-sequence
 785                                   1 group "SELECT")))))
 786               (when (and info
 787                          marks)
 788                 (nnimap-update-infos marks (list info))
 789                 (nnimap-store-info info (gnus-active (gnus-info-group info))))
 790               (goto-char (point-max))
 791               (let ((uidnext (nth 5 (car marks))))
 792                 (setq high (or (if uidnext
 793                                    (1- uidnext)
 794                                  (nth 3 (car marks)))
 795                                0)
 796                       low (or (nth 4 (car marks)) uidnext 1)))))
 797           (erase-buffer)
 798           (insert
 799            (format
 800             "211 %d %d %d %S\n" (1+ (- high low)) low high group)))
 801         t))))
 802
 803 (deffoo nnimap-request-create-group (group &optional server args)
 804   (setq group (nnimap-decode-gnus-group group))
 805   (when (nnimap-change-group nil server)
 806     (with-current-buffer (nnimap-buffer)
 807       (car (nnimap-command "CREATE %S" (utf7-encode group t))))))
 808
 809 (deffoo nnimap-request-delete-group (group &optional force server)
 810   (setq group (nnimap-decode-gnus-group group))
 811   (when (nnimap-change-group nil server)
 812     (with-current-buffer (nnimap-buffer)
 813       (car (nnimap-command "DELETE %S" (utf7-encode group t))))))
 814
 815 (deffoo nnimap-request-rename-group (group new-name &optional server)
 816   (setq group (nnimap-decode-gnus-group group))
 817   (when (nnimap-change-group nil server)
 818     (with-current-buffer (nnimap-buffer)
 819       (nnimap-unselect-group)
 820       (car (nnimap-command "RENAME %S %S"
 821                            (utf7-encode group t) (utf7-encode new-name t))))))
 822
 823 (defun nnimap-unselect-group ()
 824   ;; Make sure we don't have this group open read/write by asking
 825   ;; to examine a mailbox that doesn't exist.  This seems to be
 826   ;; the only way that allows us to reliably go back to unselected
 827   ;; state on Courier.
 828   (nnimap-command "EXAMINE DOES.NOT.EXIST"))
 829
 830 (deffoo nnimap-request-expunge-group (group &optional server)
 831   (setq group (nnimap-decode-gnus-group group))
 832   (when (nnimap-change-group group server)
 833     (with-current-buffer (nnimap-buffer)
 834       (car (nnimap-command "EXPUNGE")))))
 835
 836 (defun nnimap-get-flags (spec)
 837   (let ((articles nil)
 838         elems end)
 839     (with-current-buffer (nnimap-buffer)
 840       (erase-buffer)
 841       (nnimap-wait-for-response (nnimap-send-command
 842                                  "UID FETCH %s FLAGS" spec))
 843       (setq end (point))
 844       (subst-char-in-region (point-min) (point-max)
 845                             ?\\ ?% t)
 846       (goto-char (point-min))
 847       (while (search-forward " FETCH " end t)
 848         (setq elems (read (current-buffer)))
 849         (push (cons (cadr (memq 'UID elems))
 850                     (cadr (memq 'FLAGS elems)))
 851               articles)))
 852     (nreverse articles)))
 853
 854 (deffoo nnimap-close-group (group &optional server)
 855   t)
 856
 857 (deffoo nnimap-request-move-article (article group server accept-form
 858                                              &optional last internal-move-group)
 859   (setq group (nnimap-decode-gnus-group group))
 860   (with-temp-buffer
 861     (mm-disable-multibyte)
 862     (when (funcall (if internal-move-group
 863                        'nnimap-request-head
 864                      'nnimap-request-article)
 865                    article group server (current-buffer))
 866       ;; If the move is internal (on the same server), just do it the easy
 867       ;; way.
 868       (let ((message-id (message-field-value "message-id")))
 869         (if internal-move-group
 870             (let ((result
 871                    (with-current-buffer (nnimap-buffer)
 872                      (nnimap-command "UID COPY %d %S"
 873                                      article
 874                                      (utf7-encode internal-move-group t)))))
 875               (when (car result)
 876                 (nnimap-delete-article article)
 877                 (cons internal-move-group
 878                       (or (nnimap-find-uid-response "COPYUID" (cadr result))
 879                           (nnimap-find-article-by-message-id
 880                            internal-move-group server message-id
 881                            nnimap-request-articles-find-limit)))))
 882           ;; Move the article to a different method.
 883           (let ((result (eval accept-form)))
 884             (when result
 885               (nnimap-change-group group server)
 886               (nnimap-delete-article article)
 887               result)))))))
 888
 889 (deffoo nnimap-request-expire-articles (articles group &optional server force)
 890   (setq group (nnimap-decode-gnus-group group))
 891   (cond
 892    ((null articles)
 893     nil)
 894    ((not (nnimap-change-group group server))
 895     articles)
 896    ((and force
 897          (eq nnmail-expiry-target 'delete))
 898     (unless (nnimap-delete-article (gnus-compress-sequence articles))
 899       (nnheader-message 7 "Article marked for deletion, but not expunged."))
 900     nil)
 901    (t
 902     (let ((deletable-articles
 903            (if (or force
 904                    (eq nnmail-expiry-wait 'immediate))
 905                articles
 906              (gnus-sorted-intersection
 907               articles
 908               (nnimap-find-expired-articles group)))))
 909       (if (null deletable-articles)
 910           articles
 911         (if (eq nnmail-expiry-target 'delete)
 912             (nnimap-delete-article (gnus-compress-sequence deletable-articles))
 913           (setq deletable-articles
 914                 (nnimap-process-expiry-targets
 915                  deletable-articles group server)))
 916         ;; Return the articles we didn't delete.
 917         (gnus-sorted-complement articles deletable-articles))))))
 918
 919 (defun nnimap-process-expiry-targets (articles group server)
 920   (let ((deleted-articles nil))
 921     (cond
 922      ;; shortcut further processing if we're going to delete the articles
 923      ((eq nnmail-expiry-target 'delete)
 924       (setq deleted-articles articles)
 925       t)
 926      ;; or just move them to another folder on the same IMAP server
 927      ((and (not (functionp nnmail-expiry-target))
 928            (gnus-server-equal (gnus-group-method nnmail-expiry-target)
 929                               (gnus-server-to-method
 930                                (format "nnimap:%s" server))))
 931       (and (nnimap-change-group group server)
 932            (with-current-buffer (nnimap-buffer)
 933              (nnheader-message 7 "Expiring articles from %s: %s" group articles)
 934              (nnimap-command
 935               "UID COPY %s %S"
 936               (nnimap-article-ranges (gnus-compress-sequence articles))
 937               (utf7-encode (gnus-group-real-name nnmail-expiry-target) t))
 938              (setq deleted-articles articles)))
 939       t)
 940      (t
 941       (dolist (article articles)
 942         (let ((target nnmail-expiry-target))
 943           (with-temp-buffer
 944             (mm-disable-multibyte)
 945             (when (nnimap-request-article article group server (current-buffer))
 946               (when (functionp target)
 947                 (setq target (funcall target group)))
 948               (if (and target
 949                        (not (eq target 'delete)))
 950                   (if (or (gnus-request-group target t)
 951                           (gnus-request-create-group target))
 952                       (progn
 953                         (nnmail-expiry-target-group target group)
 954                         (nnheader-message 7 "Expiring article %s:%d to %s"
 955                                           group article target))
 956                     (setq target nil))
 957                 (nnheader-message 7 "Expiring article %s:%d" group article))
 958               (when target
 959                 (push article deleted-articles))))))))
 960     ;; Change back to the current group again.
 961     (nnimap-change-group group server)
 962     (setq deleted-articles (nreverse deleted-articles))
 963     (nnimap-delete-article (gnus-compress-sequence deleted-articles))
 964     deleted-articles))
 965
 966 (defun nnimap-find-expired-articles (group)
 967   (let ((cutoff (nnmail-expired-article-p group nil nil)))
 968     (with-current-buffer (nnimap-buffer)
 969       (let ((result
 970              (nnimap-command
 971               "UID SEARCH SENTBEFORE %s"
 972               (format-time-string
 973                (format "%%d-%s-%%Y"
 974                        (upcase
 975                         (car (rassoc (nth 4 (decode-time cutoff))
 976                                      parse-time-months))))
 977                cutoff))))
 978         (and (car result)
 979              (delete 0 (mapcar #'string-to-number
 980                                (cdr (assoc "SEARCH" (cdr result))))))))))
 981
 982
 983 (defun nnimap-find-article-by-message-id (group server message-id &optional limit)
 984   "Search for message with MESSAGE-ID in GROUP from SERVER.
 985 If LIMIT, first try to limit the search to the N last articles."
 986   (with-current-buffer (nnimap-buffer)
 987     (erase-buffer)
 988     (let* ((change-group-result (nnimap-change-group group server nil t))
 989            (number-of-article
 990             (and (listp change-group-result)
 991                  (catch 'found
 992                    (dolist (result (cdr change-group-result))
 993                      (when (equal "EXISTS" (cadr result))
 994                        (throw 'found (car result)))))))
 995            (sequence
 996             (nnimap-send-command "UID SEARCH%s HEADER Message-Id %S"
 997                                  (if (and limit number-of-article)
 998                                      ;; The -1 is because IMAP message
 999                                      ;; numbers are one-based rather than
1000                                      ;; zero-based.
1001                                      (format " %s:*" (- (string-to-number number-of-article) limit -1))
1002                                    "")
1003                                  message-id)))
1004       (when (nnimap-wait-for-response sequence)
1005         (let ((article (car (last (cdr (assoc "SEARCH" (nnimap-parse-response)))))))
1006           (if article
1007               (string-to-number article)
1008             (when (and limit number-of-article)
1009               (nnimap-find-article-by-message-id group server message-id))))))))
1010
1011 (defun nnimap-delete-article (articles)
1012   (with-current-buffer (nnimap-buffer)
1013     (nnimap-command "UID STORE %s +FLAGS.SILENT (\\Deleted)"
1014                     (nnimap-article-ranges articles))
1015     (cond
1016      ((nnimap-capability "UIDPLUS")
1017       (nnimap-command "UID EXPUNGE %s"
1018                       (nnimap-article-ranges articles))
1019       t)
1020      (nnimap-expunge
1021       (nnimap-command "EXPUNGE")
1022       t)
1023      (t (gnus-message 7 (concat "nnimap: nnimap-expunge is not set and the "
1024                                 "server doesn't support UIDPLUS, so we won't "
1025                                 "delete this article now"))))))
1026
1027 (deffoo nnimap-request-scan (&optional group server)
1028   (when group
1029     (setq group (nnimap-decode-gnus-group group)))
1030   (when (and (nnimap-change-group nil server)
1031              nnimap-inbox
1032              nnimap-split-methods)
1033     (nnheader-message 7 "nnimap %s splitting mail..." server)
1034     (if (listp nnimap-inbox)
1035        (dolist (nnimap-inbox nnimap-inbox)
1036          (nnimap-split-incoming-mail))
1037       (nnimap-split-incoming-mail))
1038     (nnheader-message 7 "nnimap %s splitting mail...done" server)))
1039
1040 (defun nnimap-marks-to-flags (marks)
1041   (let (flags flag)
1042     (dolist (mark marks)
1043       (when (setq flag (cadr (assq mark nnimap-mark-alist)))
1044         (push flag flags)))
1045     flags))
1046
1047 (deffoo nnimap-request-update-group-status (group status &optional server)
1048   (setq group (nnimap-decode-gnus-group group))
1049   (when (nnimap-change-group nil server)
1050     (let ((command (assoc
1051                     status
1052                     '((subscribe "SUBSCRIBE")
1053                       (unsubscribe "UNSUBSCRIBE")))))
1054       (when command
1055         (with-current-buffer (nnimap-buffer)
1056           (nnimap-command "%s %S" (cadr command) (utf7-encode group t)))))))
1057
1058 (deffoo nnimap-request-set-mark (group actions &optional server)
1059   (setq group (nnimap-decode-gnus-group group))
1060   (when (nnimap-change-group group server)
1061     (let (sequence)
1062       (with-current-buffer (nnimap-buffer)
1063         (erase-buffer)
1064         ;; Just send all the STORE commands without waiting for
1065         ;; response.  If they're successful, they're successful.
1066         (dolist (action actions)
1067           (destructuring-bind (range action marks) action
1068             (let ((flags (nnimap-marks-to-flags marks)))
1069               (when flags
1070                 (setq sequence (nnimap-send-command
1071                                 "UID STORE %s %sFLAGS.SILENT (%s)"
1072                                 (nnimap-article-ranges range)
1073                                 (cond
1074                                  ((eq action 'del) "-")
1075                                  ((eq action 'add) "+")
1076                                  ((eq action 'set) ""))
1077                                 (mapconcat #'identity flags " ")))))))
1078         ;; Wait for the last command to complete to avoid later
1079         ;; synchronization problems with the stream.
1080         (when sequence
1081           (nnimap-wait-for-response sequence))))))
1082
1083 (deffoo nnimap-request-accept-article (group &optional server last)
1084   (setq group (nnimap-decode-gnus-group group))
1085   (when (nnimap-change-group nil server)
1086     (nnmail-check-syntax)
1087     (let ((message-id (message-field-value "message-id"))
1088           sequence message)
1089       (nnimap-add-cr)
1090       (setq message (buffer-substring-no-properties (point-min) (point-max)))
1091       (with-current-buffer (nnimap-buffer)
1092         (when (setq message (or (nnimap-process-quirk "OK Gimap " 'append message)
1093                                 message))
1094           ;; If we have this group open read-only, then unselect it
1095           ;; before appending to it.
1096           (when (equal (nnimap-examined nnimap-object) group)
1097             (nnimap-unselect-group))
1098           (erase-buffer)
1099           (setq sequence (nnimap-send-command
1100                           "APPEND %S {%d}" (utf7-encode group t)
1101                           (length message)))
1102           (unless nnimap-streaming
1103             (nnimap-wait-for-connection "^[+]"))
1104           (process-send-string (get-buffer-process (current-buffer)) message)
1105           (process-send-string (get-buffer-process (current-buffer))
1106                                (if (nnimap-newlinep nnimap-object)
1107                                    "\n"
1108                                  "\r\n"))
1109           (let ((result (nnimap-get-response sequence)))
1110             (if (not (nnimap-ok-p result))
1111                 (progn
1112                   (nnheader-report 'nnimap "%s" result)
1113                   nil)
1114               (cons group
1115                     (or (nnimap-find-uid-response "APPENDUID" (car result))
1116                         (nnimap-find-article-by-message-id
1117                          group server message-id
1118                          nnimap-request-articles-find-limit))))))))))
1119
1120 (defun nnimap-process-quirk (greeting-match type data)
1121   (when (and (nnimap-greeting nnimap-object)
1122              (string-match greeting-match (nnimap-greeting nnimap-object))
1123              (eq type 'append)
1124              (string-match "\000" data))
1125     (let ((choice (gnus-multiple-choice
1126                    "Message contains NUL characters.  Delete, continue, abort? "
1127                    '((?d "Delete NUL characters")
1128                      (?c "Try to APPEND the message as is")
1129                      (?a "Abort")))))
1130       (cond
1131        ((eq choice ?a)
1132         (nnheader-report 'nnimap "Aborted APPEND due to NUL characters"))
1133        ((eq choice ?c)
1134         data)
1135        (t
1136         (with-temp-buffer
1137           (insert data)
1138           (goto-char (point-min))
1139           (while (search-forward "\000" nil t)
1140             (replace-match "" t t))
1141           (buffer-string)))))))
1142
1143 (defun nnimap-ok-p (value)
1144   (and (consp value)
1145        (consp (car value))
1146        (equal (caar value) "OK")))
1147
1148 (defun nnimap-find-uid-response (name list)
1149   (let ((result (car (last (nnimap-find-response-element name list)))))
1150     (and result
1151          (string-to-number result))))
1152
1153 (defun nnimap-find-response-element (name list)
1154   (let (result)
1155     (dolist (elem list)
1156       (when (and (consp elem)
1157                  (equal name (car elem)))
1158         (setq result elem)))
1159     result))
1160
1161 (deffoo nnimap-request-replace-article (article group buffer)
1162   (setq group (nnimap-decode-gnus-group group))
1163   (let (group-art)
1164     (when (and (nnimap-change-group group)
1165                ;; Put the article into the group.
1166                (with-current-buffer buffer
1167                  (setq group-art
1168                        (nnimap-request-accept-article group nil t))))
1169       (nnimap-delete-article (list article))
1170       ;; Return the new article number.
1171       (cdr group-art))))
1172
1173 (defun nnimap-add-cr ()
1174   (goto-char (point-min))
1175   (while (re-search-forward "\r?\n" nil t)
1176     (replace-match "\r\n" t t)))
1177
1178 (defun nnimap-get-groups ()
1179   (erase-buffer)
1180   (let ((sequence (nnimap-send-command "LIST \"\" \"*\""))
1181         groups)
1182     (nnimap-wait-for-response sequence)
1183     (subst-char-in-region (point-min) (point-max)
1184                           ?\\ ?% t)
1185     (goto-char (point-min))
1186     (nnimap-unfold-quoted-lines)
1187     (goto-char (point-min))
1188     (while (search-forward "* LIST " nil t)
1189       (let ((flags (read (current-buffer)))
1190             (separator (read (current-buffer)))
1191             (group (read (current-buffer))))
1192         (unless (member '%NoSelect flags)
1193           (push (utf7-decode (if (stringp group)
1194                                  group
1195                                (format "%s" group)) t)
1196                 groups))))
1197     (nreverse groups)))
1198
1199 (deffoo nnimap-request-list (&optional server)
1200   (when (nnimap-change-group nil server)
1201     (with-current-buffer nntp-server-buffer
1202       (erase-buffer)
1203       (let ((groups
1204              (with-current-buffer (nnimap-buffer)
1205                (nnimap-get-groups)))
1206             sequences responses)
1207         (when groups
1208           (with-current-buffer (nnimap-buffer)
1209             (setf (nnimap-group nnimap-object) nil)
1210             (dolist (group groups)
1211               (setf (nnimap-examined nnimap-object) group)
1212               (push (list (nnimap-send-command "EXAMINE %S"
1213                                                (utf7-encode group t))
1214                           group)
1215                     sequences))
1216             (nnimap-wait-for-response (caar sequences))
1217             (setq responses
1218                   (nnimap-get-responses (mapcar #'car sequences))))
1219           (dolist (response responses)
1220             (let* ((sequence (car response))
1221                    (response (cadr response))
1222                    (group (cadr (assoc sequence sequences)))
1223                    (egroup (encode-coding-string group 'utf-8)))
1224               (when (and group
1225                          (equal (caar response) "OK"))
1226                 (let ((uidnext (nnimap-find-parameter "UIDNEXT" response))
1227                       highest exists)
1228                   (dolist (elem response)
1229                     (when (equal (cadr elem) "EXISTS")
1230                       (setq exists (string-to-number (car elem)))))
1231                   (when uidnext
1232                     (setq highest (1- (string-to-number (car uidnext)))))
1233                   (cond
1234                    ((null highest)
1235                     (insert (format "%S 0 1 y\n" egroup)))
1236                    ((zerop exists)
1237                     ;; Empty group.
1238                     (insert (format "%S %d %d y\n" egroup
1239                                     highest (1+ highest))))
1240                    (t
1241                     ;; Return the widest possible range.
1242                     (insert (format "%S %d 1 y\n" egroup
1243                                     (or highest exists)))))))))
1244           t)))))
1245
1246 (deffoo nnimap-request-newgroups (date &optional server)
1247   (when (nnimap-change-group nil server)
1248     (with-current-buffer nntp-server-buffer
1249       (erase-buffer)
1250       (dolist (group (with-current-buffer (nnimap-buffer)
1251                        (nnimap-get-groups)))
1252         (unless (assoc group nnimap-current-infos)
1253           ;; Insert dummy numbers here -- they don't matter.
1254           (insert (format "%S 0 1 y\n" (encode-coding-string group 'utf-8)))))
1255       t)))
1256
1257 (deffoo nnimap-retrieve-group-data-early (server infos)
1258   (when (and (nnimap-change-group nil server)
1259              infos)
1260     (with-current-buffer (nnimap-buffer)
1261       (erase-buffer)
1262       (setf (nnimap-group nnimap-object) nil)
1263       (setf (nnimap-initial-resync nnimap-object) 0)
1264       (let ((qresyncp (nnimap-capability "QRESYNC"))
1265             params groups sequences active uidvalidity modseq group
1266             unexist)
1267         ;; Go through the infos and gather the data needed to know
1268         ;; what and how to request the data.
1269         (dolist (info infos)
1270           (setq params (gnus-info-params info)
1271                 group (nnimap-decode-gnus-group
1272                        (gnus-group-real-name (gnus-info-group info)))
1273                 active (cdr (assq 'active params))
1274                 unexist (assq 'unexist (gnus-info-marks info))
1275                 uidvalidity (cdr (assq 'uidvalidity params))
1276                 modseq (cdr (assq 'modseq params)))
1277           (setf (nnimap-examined nnimap-object) group)
1278           (if (and qresyncp
1279                    uidvalidity
1280                    active
1281                    modseq
1282                    unexist)
1283               (push
1284                (list (nnimap-send-command "EXAMINE %S (%s (%s %s))"
1285                                           (utf7-encode group t)
1286                                           (nnimap-quirk "QRESYNC")
1287                                           uidvalidity modseq)
1288                      'qresync
1289                      nil group 'qresync)
1290                sequences)
1291             (let ((command
1292                    (if uidvalidity
1293                        "EXAMINE"
1294                      ;; If we don't have a UIDVALIDITY, then this is
1295                      ;; the first time we've seen the group, so we
1296                      ;; have to do a SELECT (which is slower than an
1297                      ;; examine), but will tell us whether the group
1298                      ;; is read-only or not.
1299                      "SELECT"))
1300                   start)
1301               (if (and active uidvalidity unexist)
1302                   ;; Fetch the last 100 flags.
1303                   (setq start (max 1 (- (cdr active) 100)))
1304                 (incf (nnimap-initial-resync nnimap-object))
1305                 (setq start 1))
1306               (push (list (nnimap-send-command "%s %S" command
1307                                                (utf7-encode group t))
1308                           (nnimap-send-command "UID FETCH %d:* FLAGS" start)
1309                           start group command)
1310                     sequences))))
1311         sequences))))
1312
1313 (defun nnimap-quirk (command)
1314   (let ((quirk (assoc command nnimap-quirks)))
1315     ;; If this server is of a type that matches a quirk, then return
1316     ;; the "quirked" command instead of the proper one.
1317     (if (or (null quirk)
1318             (not (string-match (nth 1 quirk) (nnimap-greeting nnimap-object))))
1319         command
1320       (nth 2 quirk))))
1321
1322 (deffoo nnimap-finish-retrieve-group-infos (server infos sequences)
1323   (when (and sequences
1324              (nnimap-change-group nil server t)
1325              ;; Check that the process is still alive.
1326              (get-buffer-process (nnimap-buffer))
1327              (memq (process-status (get-buffer-process (nnimap-buffer)))
1328                    '(open run)))
1329     (with-current-buffer (nnimap-buffer)
1330       ;; Wait for the final data to trickle in.
1331       (when (nnimap-wait-for-response (if (eq (cadar sequences) 'qresync)
1332                                           (caar sequences)
1333                                         (cadar sequences))
1334                                       t)
1335         ;; Now we should have most of the data we need, no matter
1336         ;; whether we're QRESYNCING, fetching all the flags from
1337         ;; scratch, or just fetching the last 100 flags per group.
1338         (nnimap-update-infos (nnimap-flags-to-marks
1339                               (nnimap-parse-flags
1340                                (nreverse sequences)))
1341                              infos)
1342         ;; Finally, just return something resembling an active file in
1343         ;; the nntp buffer, so that the agent can save the info, too.
1344         (with-current-buffer nntp-server-buffer
1345           (erase-buffer)
1346           (dolist (info infos)
1347             (let* ((group (gnus-info-group info))
1348                    (active (gnus-active group)))
1349               (when active
1350                 (insert (format "%S %d %d y\n"
1351                                 (decode-coding-string
1352                                  (gnus-group-real-name group) 'utf-8)
1353                                 (cdr active)
1354                                 (car active)))))))))))
1355
1356 (defun nnimap-update-infos (flags infos)
1357   (dolist (info infos)
1358     (let* ((group (nnimap-decode-gnus-group
1359                    (gnus-group-real-name (gnus-info-group info))))
1360            (marks (cdr (assoc group flags))))
1361       (when marks
1362         (nnimap-update-info info marks)))))
1363
1364 (defun nnimap-update-info (info marks)
1365   (destructuring-bind (existing flags high low uidnext start-article
1366                                 permanent-flags uidvalidity
1367                                 vanished highestmodseq) marks
1368     (cond
1369      ;; Ignore groups with no UIDNEXT/marks.  This happens for
1370      ;; completely empty groups.
1371      ((and (not existing)
1372            (not uidnext))
1373       (let ((active (cdr (assq 'active (gnus-info-params info)))))
1374         (when active
1375           (gnus-set-active (gnus-info-group info) active))))
1376      ;; We have a mismatch between the old and new UIDVALIDITY
1377      ;; identifiers, so we have to re-request the group info (the next
1378      ;; time).  This virtually never happens.
1379      ((let ((old-uidvalidity
1380              (cdr (assq 'uidvalidity (gnus-info-params info)))))
1381         (and old-uidvalidity
1382              (not (equal old-uidvalidity uidvalidity))
1383              (or (not start-article)
1384                  (> start-article 1))))
1385       (gnus-group-remove-parameter info 'uidvalidity)
1386       (gnus-group-remove-parameter info 'modseq))
1387      ;; We have the data needed to update.
1388      (t
1389       (let* ((group (gnus-info-group info))
1390              (completep (and start-article
1391                              (= start-article 1)))
1392              (active (or (gnus-active group)
1393                          (cdr (assq 'active (gnus-info-params info))))))
1394         (when uidnext
1395           (setq high (1- uidnext)))
1396         ;; First set the active ranges based on high/low.
1397         (if (or completep
1398                 (not (gnus-active group)))
1399             (gnus-set-active group
1400                              (cond
1401                               (active
1402                                (cons (min (or low (car active))
1403                                           (car active))
1404                                      (max (or high (cdr active))
1405                                           (cdr active))))
1406                               ((and low high)
1407                                (cons low high))
1408                               (uidnext
1409                                ;; No articles in this group.
1410                                (cons uidnext (1- uidnext)))
1411                               (start-article
1412                                (cons start-article (1- start-article)))
1413                               (t
1414                                ;; No articles and no uidnext.
1415                                nil)))
1416           (gnus-set-active group
1417                            (cons (car active)
1418                                  (or high (1- uidnext)))))
1419         ;; See whether this is a read-only group.
1420         (unless (eq permanent-flags 'not-scanned)
1421           (gnus-group-set-parameter
1422            info 'permanent-flags
1423            (and (or (memq '%* permanent-flags)
1424                     (memq '%Seen permanent-flags))
1425                 permanent-flags)))
1426         ;; Update marks and read articles if this isn't a
1427         ;; read-only IMAP group.
1428         (when (setq permanent-flags
1429                     (cdr (assq 'permanent-flags (gnus-info-params info))))
1430           (if (and highestmodseq
1431                    (not start-article))
1432               ;; We've gotten the data by QRESYNCing.
1433               (nnimap-update-qresync-info
1434                info existing (nnimap-imap-ranges-to-gnus-ranges vanished) flags)
1435             ;; Do normal non-QRESYNC flag updates.
1436             ;; Update the list of read articles.
1437             (let* ((unread
1438                     (gnus-compress-sequence
1439                      (gnus-set-difference
1440                       (gnus-set-difference
1441                        existing
1442                        (cdr (assoc '%Seen flags)))
1443                       (cdr (assoc '%Flagged flags)))))
1444                    (read (gnus-range-difference
1445                           (cons start-article high) unread)))
1446               (when (> start-article 1)
1447                 (setq read
1448                       (gnus-range-nconcat
1449                        (if (> start-article 1)
1450                            (gnus-sorted-range-intersection
1451                             (cons 1 (1- start-article))
1452                             (gnus-info-read info))
1453                          (gnus-info-read info))
1454                        read)))
1455               (when (or (not (listp permanent-flags))
1456                         (memq '%Seen permanent-flags))
1457                 (gnus-info-set-read info read))
1458               ;; Update the marks.
1459               (setq marks (gnus-info-marks info))
1460               (dolist (type (cdr nnimap-mark-alist))
1461                 (when (or (not (listp permanent-flags))
1462                           (memq (car (assoc (caddr type) flags))
1463                                 permanent-flags)
1464                           (memq '%* permanent-flags))
1465                   (let ((old-marks (assoc (car type) marks))
1466                         (new-marks
1467                          (gnus-compress-sequence
1468                           (cdr (or (assoc (caddr type) flags) ; %Flagged
1469                                    (assoc (intern (cadr type) obarray) flags)
1470                                    (assoc (cadr type) flags)))))) ; "\Flagged"
1471                     (setq marks (delq old-marks marks))
1472                     (pop old-marks)
1473                     (when (and old-marks
1474                                (> start-article 1))
1475                       (setq old-marks (gnus-range-difference
1476                                        old-marks
1477                                        (cons start-article high)))
1478                       (setq new-marks (gnus-range-nconcat old-marks new-marks)))
1479                     (when new-marks
1480                       (push (cons (car type) new-marks) marks)))))
1481               ;; Keep track of non-existing articles.
1482               (let* ((old-unexists (assq 'unexist marks))
1483                      (active (gnus-active group))
1484                      (unexists
1485                       (if completep
1486                           (gnus-range-difference
1487                            active
1488                            (gnus-compress-sequence existing))
1489                         (gnus-add-to-range
1490                          (cdr old-unexists)
1491                          (gnus-list-range-difference
1492                           existing (gnus-active group))))))
1493                 (when (> (car active) 1)
1494                   (setq unexists (gnus-range-add
1495                                   (cons 1 (1- (car active)))
1496                                   unexists)))
1497                 (if old-unexists
1498                     (setcdr old-unexists unexists)
1499                   (push (cons 'unexist unexists) marks)))
1500               (gnus-info-set-marks info marks t))))
1501         ;; Tell Gnus whether there are any \Recent messages in any of
1502         ;; the groups.
1503         (let ((recent (cdr (assoc '%Recent flags))))
1504           (when (and active
1505                      recent
1506                      (> (car (last recent)) (cdr active)))
1507             (push (list (cons (gnus-group-real-name group) 0))
1508                   nnmail-split-history)))
1509         ;; Note the active level for the next run-through.
1510         (gnus-group-set-parameter info 'active (gnus-active group))
1511         (gnus-group-set-parameter info 'uidvalidity uidvalidity)
1512         (gnus-group-set-parameter info 'modseq highestmodseq)
1513         (nnimap-store-info info (gnus-active group)))))))
1514
1515 (defun nnimap-update-qresync-info (info existing vanished flags)
1516   ;; Add all the vanished articles to the list of read articles.
1517   (gnus-info-set-read
1518    info
1519    (gnus-add-to-range
1520     (gnus-add-to-range
1521      (gnus-range-add (gnus-info-read info)
1522                      vanished)
1523      (cdr (assq '%Flagged flags)))
1524     (cdr (assq '%Seen flags))))
1525   (let ((marks (gnus-info-marks info)))
1526     (dolist (type (cdr nnimap-mark-alist))
1527       (let ((ticks (assoc (car type) marks))
1528             (new-marks
1529              (cdr (or (assoc (caddr type) flags) ; %Flagged
1530                       (assoc (intern (cadr type) obarray) flags)
1531                       (assoc (cadr type) flags))))) ; "\Flagged"
1532         (setq marks (delq ticks marks))
1533         (pop ticks)
1534         ;; Add the new marks we got.
1535         (setq ticks (gnus-add-to-range ticks new-marks))
1536         ;; Remove the marks from messages that don't have them.
1537         (setq ticks (gnus-remove-from-range
1538                      ticks
1539                      (gnus-compress-sequence
1540                       (gnus-sorted-complement existing new-marks))))
1541         (when ticks
1542           (push (cons (car type) ticks) marks)))
1543       (gnus-info-set-marks info marks t))
1544     ;; Add vanished to the list of unexisting articles.
1545     (when vanished
1546       (let* ((old-unexists (assq 'unexist marks))
1547              (unexists (gnus-range-add (cdr old-unexists) vanished)))
1548         (if old-unexists
1549             (setcdr old-unexists unexists)
1550           (push (cons 'unexist unexists) marks)))
1551       (gnus-info-set-marks info marks t))))
1552
1553 (defun nnimap-imap-ranges-to-gnus-ranges (irange)
1554   (if (zerop (length irange))
1555       nil
1556     (let ((result nil))
1557       (dolist (elem (split-string irange ","))
1558         (push
1559          (if (string-match ":" elem)
1560              (let ((numbers (split-string elem ":")))
1561                (cons (string-to-number (car numbers))
1562                      (string-to-number (cadr numbers))))
1563            (string-to-number elem))
1564          result))
1565       (nreverse result))))
1566
1567 (defun nnimap-store-info (info active)
1568   (let* ((group (gnus-group-real-name (gnus-info-group info)))
1569          (entry (assoc group nnimap-current-infos)))
1570     (if entry
1571         (setcdr entry (list info active))
1572       (push (list group info active) nnimap-current-infos))))
1573
1574 (defun nnimap-flags-to-marks (groups)
1575   (let (data group totalp uidnext articles start-article mark permanent-flags
1576              uidvalidity vanished highestmodseq)
1577     (dolist (elem groups)
1578       (setq group (car elem)
1579             uidnext (nth 1 elem)
1580             start-article (nth 2 elem)
1581             permanent-flags (nth 3 elem)
1582             uidvalidity (nth 4 elem)
1583             vanished (nth 5 elem)
1584             highestmodseq (nth 6 elem)
1585             articles (nthcdr 7 elem))
1586       (let ((high (caar articles))
1587             marks low existing)
1588         (dolist (article articles)
1589           (setq low (car article))
1590           (push (car article) existing)
1591           (dolist (flag (cdr article))
1592             (setq mark (assoc flag marks))
1593             (if (not mark)
1594                 (push (list flag (car article)) marks)
1595               (setcdr mark (cons (car article) (cdr mark))))))
1596         (push (list group existing marks high low uidnext start-article
1597                     permanent-flags uidvalidity vanished highestmodseq)
1598               data)))
1599     data))
1600
1601 (defun nnimap-parse-flags (sequences)
1602   (goto-char (point-min))
1603   ;; Change \Delete etc to %Delete, so that the Emacs Lisp reader can
1604   ;; read it.
1605   (subst-char-in-region (point-min) (point-max)
1606                         ?\\ ?% t)
1607   ;; Remove any MODSEQ entries in the buffer, because they may contain
1608   ;; numbers that are too large for 32-bit Emacsen.
1609   (while (re-search-forward " MODSEQ ([0-9]+)" nil t)
1610     (replace-match "" t t))
1611   (goto-char (point-min))
1612   (let (start end articles groups uidnext elems permanent-flags
1613               uidvalidity vanished highestmodseq)
1614     (dolist (elem sequences)
1615       (destructuring-bind (group-sequence flag-sequence totalp group command)
1616           elem
1617         (setq start (point))
1618         (when (and
1619                ;; The EXAMINE was successful.
1620                (search-forward (format "\n%d OK " group-sequence) nil t)
1621                (progn
1622                  (forward-line 1)
1623                  (setq end (point))
1624                  (goto-char start)
1625                  (setq permanent-flags
1626                        (if (equal command "SELECT")
1627                            (and (search-forward "PERMANENTFLAGS "
1628                                                 (or end (point-min)) t)
1629                                 (read (current-buffer)))
1630                          'not-scanned))
1631                  (goto-char start)
1632                  (setq uidnext
1633                        (and (search-forward "UIDNEXT "
1634                                             (or end (point-min)) t)
1635                             (read (current-buffer))))
1636                  (goto-char start)
1637                  (setq uidvalidity
1638                        (and (re-search-forward "UIDVALIDITY \\([0-9]+\\)"
1639                                                (or end (point-min)) t)
1640                             ;; Store UIDVALIDITY as a string, as it's
1641                             ;; too big for 32-bit Emacsen, usually.
1642                             (match-string 1)))
1643                  (goto-char start)
1644                  (setq vanished
1645                        (and (eq flag-sequence 'qresync)
1646                             (re-search-forward "^\\* VANISHED .*? \\([0-9:,]+\\)"
1647                                                (or end (point-min)) t)
1648                             (match-string 1)))
1649                  (goto-char start)
1650                  (setq highestmodseq
1651                        (and (re-search-forward "HIGHESTMODSEQ \\([0-9]+\\)"
1652                                             (or end (point-min)) t)
1653                             (match-string 1)))
1654                  (goto-char end)
1655                  (forward-line -1))
1656                ;; The UID FETCH FLAGS was successful.
1657                (or (eq flag-sequence 'qresync)
1658                    (search-forward (format "\n%d OK " flag-sequence) nil t)))
1659           (if (eq flag-sequence 'qresync)
1660               (progn
1661                 (goto-char start)
1662                 (setq start end))
1663             (setq start (point))
1664             (goto-char end))
1665           (while (re-search-forward "^\\* [0-9]+ FETCH " start t)
1666             (let ((p (point)))
1667               (setq elems (read (current-buffer)))
1668               (push (cons (cadr (memq 'UID elems))
1669                           (cadr (memq 'FLAGS elems)))
1670                     articles)))
1671           (push (nconc (list group uidnext totalp permanent-flags uidvalidity
1672                              vanished highestmodseq)
1673                        articles)
1674                 groups)
1675           (if (eq flag-sequence 'qresync)
1676               (goto-char end)
1677             (setq end (point)))
1678           (setq articles nil))))
1679     groups))
1680
1681 (defun nnimap-find-process-buffer (buffer)
1682   (cadr (assoc buffer nnimap-connection-alist)))
1683
1684 (deffoo nnimap-request-post (&optional server)
1685   (setq nnimap-status-string "Read-only server")
1686   nil)
1687
1688 (defvar gnus-refer-thread-use-nnir) ;; gnus-sum.el
1689 (declare-function gnus-fetch-headers "gnus-sum"
1690                   (articles &optional limit force-new dependencies))
1691
1692 (autoload 'nnir-search-thread "nnir")
1693
1694 (deffoo nnimap-request-thread (header &optional group server)
1695   (when group
1696     (setq group (nnimap-decode-gnus-group group)))
1697   (if gnus-refer-thread-use-nnir
1698       (nnir-search-thread header)
1699     (when (nnimap-change-group group server)
1700       (let* ((cmd (nnimap-make-thread-query header))
1701              (result (with-current-buffer (nnimap-buffer)
1702                        (nnimap-command  "UID SEARCH %s" cmd))))
1703         (when result
1704           (gnus-fetch-headers
1705            (and (car result)
1706                 (delete 0 (mapcar #'string-to-number
1707                                   (cdr (assoc "SEARCH" (cdr result))))))
1708            nil t))))))
1709
1710 (defun nnimap-change-group (group &optional server no-reconnect read-only)
1711   "Change group to GROUP if non-nil.
1712 If SERVER is set, check that server is connected, otherwise retry
1713 to reconnect, unless NO-RECONNECT is set to t.  Return nil if
1714 unsuccessful in connecting.
1715 If GROUP is nil, return t.
1716 If READ-ONLY is set, send EXAMINE rather than SELECT to the server.
1717 Return the server's response to the SELECT or EXAMINE command.
1718 "
1719   (let ((open-result t))
1720     (when (and server
1721                (not (nnimap-server-opened server)))
1722       (setq open-result (nnimap-open-server server nil no-reconnect)))
1723     (cond
1724      ((not open-result)
1725       nil)
1726      ((not group)
1727       t)
1728      (t
1729       (with-current-buffer (nnimap-buffer)
1730         (let ((result (nnimap-command "%s %S"
1731                                       (if read-only
1732                                           "EXAMINE"
1733                                         "SELECT")
1734                                       (utf7-encode group t))))
1735           (when (car result)
1736             (setf (nnimap-group nnimap-object) group
1737                   (nnimap-select-result nnimap-object) result)
1738             result)))))))
1739
1740 (defun nnimap-find-connection (buffer)
1741   "Find the connection delivering to BUFFER."
1742   (let ((entry (assoc buffer nnimap-connection-alist)))
1743     (when entry
1744       (if (and (buffer-name (cadr entry))
1745                (get-buffer-process (cadr entry))
1746                (memq (process-status (get-buffer-process (cadr entry)))
1747                      '(open run)))
1748           (get-buffer-process (cadr entry))
1749         (setq nnimap-connection-alist (delq entry nnimap-connection-alist))
1750         nil))))
1751
1752 (defvar nnimap-sequence 0)
1753
1754 (defun nnimap-send-command (&rest args)
1755   (setf (nnimap-last-command-time nnimap-object) (current-time))
1756   (process-send-string
1757    (get-buffer-process (current-buffer))
1758    (nnimap-log-command
1759     (format "%d %s%s\n"
1760             (incf nnimap-sequence)
1761             (apply #'format args)
1762             (if (nnimap-newlinep nnimap-object)
1763                 ""
1764               "\r"))))
1765   ;; Some servers apparently can't have many outstanding
1766   ;; commands, so throttle them.
1767   (unless nnimap-streaming
1768     (nnimap-wait-for-response nnimap-sequence))
1769   nnimap-sequence)
1770
1771 (defvar nnimap-record-commands nil
1772   "If non-nil, log commands to the \"*imap log*\" buffer.")
1773
1774 (defun nnimap-log-buffer ()
1775   (let ((name "*imap log*"))
1776     (or (get-buffer name)
1777         (with-current-buffer (get-buffer-create name)
1778           (when (boundp 'window-point-insertion-type)
1779             (make-local-variable 'window-point-insertion-type)
1780             (setq window-point-insertion-type t))
1781           (current-buffer)))))
1782
1783 (defun nnimap-log-command (command)
1784   (when nnimap-record-commands
1785     (with-current-buffer (nnimap-log-buffer)
1786       (goto-char (point-max))
1787       (insert (format-time-string "%H:%M:%S")
1788               " [" nnimap-address "] "
1789               (if nnimap-inhibit-logging
1790                   "(inhibited)\n"
1791                 command))))
1792   command)
1793
1794 (defun nnimap-command (&rest args)
1795   (erase-buffer)
1796   (let* ((sequence (apply #'nnimap-send-command args))
1797          (response (nnimap-get-response sequence)))
1798     (if (equal (caar response) "OK")
1799         (cons t response)
1800       (nnheader-report 'nnimap "%s"
1801                        (mapconcat (lambda (a)
1802                                     (format "%s" a))
1803                                   (car response) " "))
1804       nil)))
1805
1806 (defun nnimap-get-response (sequence)
1807   (nnimap-wait-for-response sequence)
1808   (nnimap-parse-response))
1809
1810 (defun nnimap-wait-for-connection (&optional regexp)
1811   (nnimap-wait-for-line (or regexp "^[*.] .*\n") "[*.] \\([A-Z0-9]+\\)"))
1812
1813 (defun nnimap-wait-for-line (regexp &optional response-regexp)
1814   (let ((process (get-buffer-process (current-buffer))))
1815     (goto-char (point-min))
1816     (while (and (memq (process-status process)
1817                       '(open run))
1818                 (not (re-search-forward regexp nil t)))
1819       (nnheader-accept-process-output process)
1820       (goto-char (point-min)))
1821     (forward-line -1)
1822     (and (looking-at (or response-regexp regexp))
1823          (match-string 1))))
1824
1825 (defun nnimap-wait-for-response (sequence &optional messagep)
1826   (let ((process (get-buffer-process (current-buffer)))
1827         openp)
1828     (condition-case nil
1829         (progn
1830           (goto-char (point-max))
1831           (while (and (setq openp (memq (process-status process)
1832                                         '(open run)))
1833                       (progn
1834                         ;; Skip past any "*" lines that the server has
1835                         ;; output.
1836                         (while (and (not (bobp))
1837                                     (progn
1838                                       (forward-line -1)
1839                                       (looking-at "\\*"))))
1840                         (not (looking-at (format "%d .*\n" sequence)))))
1841             (when messagep
1842               (nnheader-message-maybe
1843                7 "nnimap read %dk from %s%s" (/ (buffer-size) 1000)
1844                nnimap-address
1845                (if (not (zerop (nnimap-initial-resync nnimap-object)))
1846                    (format " (initial sync of %d group%s; please wait)"
1847                            (nnimap-initial-resync nnimap-object)
1848                            (if (= (nnimap-initial-resync nnimap-object) 1)
1849                                ""
1850                              "s"))
1851                  "")))
1852             (nnheader-accept-process-output process)
1853             (goto-char (point-max)))
1854           (setf (nnimap-initial-resync nnimap-object) 0)
1855           openp)
1856       (quit
1857        (when debug-on-quit
1858          (debug "Quit"))
1859        ;; The user hit C-g while we were waiting: kill the process, in case
1860        ;; it's a gnutls-cli process that's stuck (tends to happen a lot behind
1861        ;; NAT routers).
1862        (delete-process process)
1863        nil))))
1864
1865 (defun nnimap-parse-response ()
1866   (let ((lines (split-string (nnimap-last-response-string) "\r\n" t))
1867         result)
1868     (dolist (line lines)
1869       (push (cdr (nnimap-parse-line line)) result))
1870     ;; Return the OK/error code first, and then all the "continuation
1871     ;; lines" afterwards.
1872     (cons (pop result)
1873           (nreverse result))))
1874
1875 ;; Parse an IMAP response line lightly.  They look like
1876 ;; "* OK [UIDVALIDITY 1164213559] UIDs valid", typically, so parse
1877 ;; the lines into a list of strings and lists of string.
1878 (defun nnimap-parse-line (line)
1879   (let (char result)
1880     (with-temp-buffer
1881       (mm-disable-multibyte)
1882       (insert line)
1883       (goto-char (point-min))
1884       (while (not (eobp))
1885         (if (eql (setq char (following-char)) ? )
1886             (forward-char 1)
1887           (push
1888            (cond
1889             ((eql char ?\[)
1890              (split-string
1891               (buffer-substring
1892                (1+ (point))
1893                (if (search-forward "]" (line-end-position) 'move)
1894                    (1- (point))
1895                  (point)))))
1896             ((eql char ?\()
1897              (split-string
1898               (buffer-substring
1899                (1+ (point))
1900                (if (search-forward ")" (line-end-position) 'move)
1901                    (1- (point))
1902                  (point)))))
1903             ((eql char ?\")
1904              (forward-char 1)
1905              (buffer-substring
1906               (point)
1907               (1- (or (search-forward "\"" (line-end-position) 'move)
1908                       (point)))))
1909             (t
1910              (buffer-substring (point) (if (search-forward " " nil t)
1911                                            (1- (point))
1912                                          (goto-char (point-max))))))
1913            result)))
1914       (nreverse result))))
1915
1916 (defun nnimap-last-response-string ()
1917   (save-excursion
1918     (forward-line 1)
1919     (let ((end (point)))
1920       (forward-line -1)
1921       (when (not (bobp))
1922         (forward-line -1)
1923         (while (and (not (bobp))
1924                     (eql (following-char) ?*))
1925           (forward-line -1))
1926         (unless (eql (following-char) ?*)
1927           (forward-line 1)))
1928       (buffer-substring (point) end))))
1929
1930 (defvar nnimap-incoming-split-list nil)
1931
1932 (defun nnimap-fetch-inbox (articles)
1933   (erase-buffer)
1934   (nnimap-wait-for-response
1935    (nnimap-send-command
1936     "UID FETCH %s %s"
1937     (nnimap-article-ranges articles)
1938     (format "(UID %s%s)"
1939             (format
1940              (if (nnimap-ver4-p)
1941                  "BODY.PEEK"
1942                "RFC822.PEEK"))
1943             (cond
1944              (nnimap-split-download-body-default
1945               "[]")
1946              ((nnimap-ver4-p)
1947               "[HEADER]")
1948              (t
1949               "[1]"))))
1950    t))
1951
1952 (defun nnimap-split-incoming-mail ()
1953   (with-current-buffer (nnimap-buffer)
1954     (let ((nnimap-incoming-split-list nil)
1955           (nnmail-split-methods
1956            (cond
1957             ((eq nnimap-split-methods 'default)
1958              nnmail-split-methods)
1959             (nnimap-split-methods
1960              nnimap-split-methods)
1961             (nnimap-split-fancy
1962              'nnmail-split-fancy)))
1963           (nnmail-split-fancy (or nnimap-split-fancy
1964                                   nnmail-split-fancy))
1965           (nnmail-inhibit-default-split-group t)
1966           (groups (nnimap-get-groups))
1967           new-articles)
1968       (erase-buffer)
1969       (nnimap-command "SELECT %S" nnimap-inbox)
1970       (setf (nnimap-group nnimap-object) nnimap-inbox)
1971       (setq new-articles (nnimap-new-articles (nnimap-get-flags "1:*")))
1972       (when new-articles
1973         (nnimap-fetch-inbox new-articles)
1974         (nnimap-transform-split-mail)
1975         (nnheader-ms-strip-cr)
1976         (nnmail-cache-open)
1977         (nnmail-split-incoming (current-buffer)
1978                                #'nnimap-save-mail-spec
1979                                nil nil
1980                                #'nnimap-dummy-active-number
1981                                #'nnimap-save-mail-spec)
1982         (when nnimap-incoming-split-list
1983           (let ((specs (nnimap-make-split-specs nnimap-incoming-split-list))
1984                 sequences junk-articles)
1985             ;; Create any groups that doesn't already exist on the
1986             ;; server first.
1987             (dolist (spec specs)
1988               (when (and (not (member (car spec) groups))
1989                          (not (eq (car spec) 'junk)))
1990                 (nnimap-command "CREATE %S" (utf7-encode (car spec) t))))
1991             ;; Then copy over all the messages.
1992             (erase-buffer)
1993             (dolist (spec specs)
1994               (let ((group (car spec))
1995                     (ranges (cdr spec)))
1996                 (if (eq group 'junk)
1997                     (setq junk-articles ranges)
1998                   (push (list (nnimap-send-command
1999                                "UID COPY %s %S"
2000                                (nnimap-article-ranges ranges)
2001                                (utf7-encode group t))
2002                               ranges)
2003                         sequences))))
2004             ;; Wait for the last COPY response...
2005             (when sequences
2006               (nnimap-wait-for-response (caar sequences))
2007               ;; And then mark the successful copy actions as deleted,
2008               ;; and possibly expunge them.
2009               (nnimap-mark-and-expunge-incoming
2010                (nnimap-parse-copied-articles sequences)))
2011             (nnimap-mark-and-expunge-incoming junk-articles)))))))
2012
2013 (defun nnimap-mark-and-expunge-incoming (range)
2014   (when range
2015     (setq range (nnimap-article-ranges range))
2016     (erase-buffer)
2017     (let ((sequence
2018            (nnimap-send-command
2019             "UID STORE %s +FLAGS.SILENT (\\Deleted)" range)))
2020       (cond
2021        ;; If the server supports it, we now delete the message we have
2022        ;; just copied over.
2023        ((nnimap-capability "UIDPLUS")
2024         (setq sequence (nnimap-send-command "UID EXPUNGE %s" range)))
2025        ;; If it doesn't support UID EXPUNGE, then we only expunge if the
2026        ;; user has configured it.
2027        (nnimap-expunge
2028         (setq sequence (nnimap-send-command "EXPUNGE"))))
2029       (nnimap-wait-for-response sequence))))
2030
2031 (defun nnimap-parse-copied-articles (sequences)
2032   (let (sequence copied range)
2033     (goto-char (point-min))
2034     (while (re-search-forward "^\\([0-9]+\\) OK\\b" nil t)
2035       (setq sequence (string-to-number (match-string 1)))
2036       (when (setq range (cadr (assq sequence sequences)))
2037         (push (gnus-uncompress-range range) copied)))
2038     (gnus-compress-sequence (sort (apply #'nconc copied) #'<))))
2039
2040 (defun nnimap-new-articles (flags)
2041   (let (new)
2042     (dolist (elem flags)
2043       (unless (gnus-list-memq-of-list nnimap-unsplittable-articles
2044                                       (cdr elem))
2045         (push (car elem) new)))
2046     (gnus-compress-sequence (nreverse new))))
2047
2048 (defun nnimap-make-split-specs (list)
2049   (let ((specs nil)
2050         entry)
2051     (dolist (elem list)
2052       (destructuring-bind (article spec) elem
2053         (dolist (group (delete nil (mapcar #'car spec)))
2054           (unless (setq entry (assoc group specs))
2055             (push (setq entry (list group)) specs))
2056           (setcdr entry (cons article (cdr entry))))))
2057     (dolist (entry specs)
2058       (setcdr entry (gnus-compress-sequence (sort (cdr entry) #'<))))
2059     specs))
2060
2061 (defun nnimap-transform-split-mail ()
2062   (goto-char (point-min))
2063   (let (article bytes)
2064     (block nil
2065       (while (not (eobp))
2066         (while (not (looking-at "\\* [0-9]+ FETCH.+UID \\([0-9]+\\)"))
2067           (delete-region (point) (progn (forward-line 1) (point)))
2068           (when (eobp)
2069             (return)))
2070         (setq article (match-string 1)
2071               bytes (nnimap-get-length))
2072         (delete-region (line-beginning-position) (line-end-position))
2073         ;; Insert MMDF separator, and a way to remember what this
2074         ;; article UID is.
2075         (insert (format "\^A\^A\^A\^A\n\nX-nnimap-article: %s" article))
2076         (forward-char (1+ bytes))
2077         (setq bytes (nnimap-get-length))
2078         (delete-region (line-beginning-position) (line-end-position))
2079         ;; There's a body; skip past that.
2080         (when bytes
2081           (forward-char (1+ bytes))
2082           (delete-region (line-beginning-position) (line-end-position)))))))
2083
2084 (defun nnimap-dummy-active-number (group &optional server)
2085   1)
2086
2087 (defun nnimap-save-mail-spec (group-art &optional server full-nov)
2088   (let (article)
2089     (goto-char (point-min))
2090     (if (not (re-search-forward "X-nnimap-article: \\([0-9]+\\)" nil t))
2091         (error "Invalid nnimap mail")
2092       (setq article (string-to-number (match-string 1))))
2093     (push (list article
2094                 (if (eq group-art 'junk)
2095                     (list (cons 'junk 1))
2096                   group-art))
2097           nnimap-incoming-split-list)))
2098
2099 (defun nnimap-make-thread-query (header)
2100   (let* ((id  (mail-header-id header))
2101          (refs (split-string
2102                 (or (mail-header-references header)
2103                     "")))
2104          (value
2105           (format
2106            "(OR HEADER REFERENCES %S HEADER Message-Id %S)"
2107            id id)))
2108     (dolist (refid refs value)
2109       (setq value (format
2110                    "(OR (OR HEADER Message-Id %S HEADER REFERENCES %S) %s)"
2111                    refid refid value)))))
2112
2113
2114 (provide 'nnimap)
2115
2116 ;;; nnimap.el ends here