cgit.sxemacs.org Git - gnus/blob - lisp/nnfolder.el

   1 ;;; nnfolder.el --- mail folder access for Gnus
   2 ;; Copyright (C) 1995, 1996, 1997, 1998, 1999, 2000
   3 ;;        Free Software Foundation, Inc.
   4
   5 ;; Author: ShengHuo Zhu <zsh@cs.rochester.edu> (adding NOV)
   6 ;;      Scott Byer <byer@mv.us.adobe.com>
   7 ;;      Lars Magne Ingebrigtsen <larsi@gnus.org>
   8 ;;      Masanobu UMEDA <umerin@flab.flab.fujitsu.junet>
   9 ;; Keywords: mail
  10
  11 ;; This file is part of GNU Emacs.
  12
  13 ;; GNU Emacs is free software; you can redistribute it and/or modify
  14 ;; it under the terms of the GNU General Public License as published by
  15 ;; the Free Software Foundation; either version 2, or (at your option)
  16 ;; any later version.
  17
  18 ;; GNU Emacs is distributed in the hope that it will be useful,
  19 ;; but WITHOUT ANY WARRANTY; without even the implied warranty of
  20 ;; MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.  See the
  21 ;; GNU General Public License for more details.
  22
  23 ;; You should have received a copy of the GNU General Public License
  24 ;; along with GNU Emacs; see the file COPYING.  If not, write to the
  25 ;; Free Software Foundation, Inc., 59 Temple Place - Suite 330,
  26 ;; Boston, MA 02111-1307, USA.
  27
  28 ;;; Commentary:
  29
  30 ;;; Code:
  31
  32 (require 'nnheader)
  33 (require 'message)
  34 (require 'nnmail)
  35 (require 'nnoo)
  36 (eval-when-compile (require 'cl))
  37 (require 'gnus-util)
  38 (require 'gnus-range)
  39
  40 (eval-and-compile
  41   (autoload 'gnus-intersection "gnus-range"))
  42
  43 (nnoo-declare nnfolder)
  44
  45 (defvoo nnfolder-directory (expand-file-name message-directory)
  46   "The name of the nnfolder directory.")
  47
  48 (defvoo nnfolder-nov-directory nil
  49   "The name of the nnfolder NOV directory.
  50 If nil, `nnfolder-directory' is used.")
  51
  52 (defvoo nnfolder-active-file
  53     (nnheader-concat nnfolder-directory "active")
  54   "The name of the active file.")
  55
  56 ;; I renamed this variable to something more in keeping with the general GNU
  57 ;; style. -SLB
  58
  59 (defvoo nnfolder-ignore-active-file nil
  60   "If non-nil, the active file is ignored.
  61 This causes nnfolder to do some extra work in order to determine the
  62 true active ranges of an mbox file.  Note that the active file is
  63 still saved, but its values are not used.  This costs some extra time
  64 when scanning an mbox when opening it.")
  65
  66 (defvoo nnfolder-distrust-mbox nil
  67   "If non-nil, the folder will be distrusted.
  68 This means that nnfolder will not trust the user with respect to
  69 inserting unaccounted for mail in the middle of an mbox file.  This
  70 can greatly slow down scans, which now must scan the entire file for
  71 unmarked messages.  When nil, scans occur forward from the last marked
  72 message, a huge time saver for large mailboxes.")
  73
  74 (defvoo nnfolder-newsgroups-file
  75     (concat (file-name-as-directory nnfolder-directory) "newsgroups")
  76   "Mail newsgroups description file.")
  77
  78 (defvoo nnfolder-get-new-mail t
  79   "If non-nil, nnfolder will check the incoming mail file and split the mail.")
  80
  81 (defvoo nnfolder-prepare-save-mail-hook nil
  82   "Hook run narrowed to an article before saving.")
  83
  84 (defvoo nnfolder-save-buffer-hook nil
  85   "Hook run before saving the nnfolder mbox buffer.")
  86
  87 (defvoo nnfolder-inhibit-expiry nil
  88   "If non-nil, inhibit expiry.")
  89
  90 \f
  91
  92 (defconst nnfolder-version "nnfolder 2.0"
  93   "nnfolder version.")
  94
  95 (defconst nnfolder-article-marker "X-Gnus-Article-Number: "
  96   "String used to demarcate what the article number for a message is.")
  97
  98 (defvoo nnfolder-current-group nil)
  99 (defvoo nnfolder-current-buffer nil)
 100 (defvoo nnfolder-status-string "")
 101 (defvoo nnfolder-group-alist nil)
 102 (defvoo nnfolder-buffer-alist nil)
 103 (defvoo nnfolder-scantime-alist nil)
 104 (defvoo nnfolder-active-timestamp nil)
 105 (defvoo nnfolder-active-file-coding-system mm-text-coding-system)
 106 (defvoo nnfolder-active-file-coding-system-for-write
 107     nnmail-active-file-coding-system)
 108 (defvoo nnfolder-file-coding-system mm-text-coding-system)
 109 (defvoo nnfolder-file-coding-system-for-write nnheader-file-coding-system
 110   "Coding system for save nnfolder file.
 111 If NIL, NNFOLDER-FILE-CODING-SYSTEM is used.")
 112
 113 (defvoo nnfolder-nov-is-evil nil
 114   "If non-nil, Gnus will never generate and use nov databases for mail groups.
 115 Using nov databases will speed up header fetching considerably.
 116 This variable shouldn't be flipped much.  If you have, for some reason,
 117 set this to t, and want to set it to nil again, you should always run
 118 the `nnfolder-generate-active-file' command.  The function will go
 119 through all nnfolder directories and generate nov databases for them
 120 all.  This may very well take some time.")
 121
 122 (defvoo nnfolder-nov-file-suffix ".nov")
 123
 124 (defvoo nnfolder-nov-buffer-alist nil)
 125
 126 (defvar nnfolder-nov-buffer-file-name nil)
 127
 128 \f
 129
 130 ;;; Interface functions
 131
 132 (nnoo-define-basics nnfolder)
 133
 134 (deffoo nnfolder-retrieve-headers (articles &optional group server fetch-old)
 135   (save-excursion
 136     (set-buffer nntp-server-buffer)
 137     (erase-buffer)
 138     (let (article start stop)
 139       (nnfolder-possibly-change-group group server)
 140       (when nnfolder-current-buffer
 141         (set-buffer nnfolder-current-buffer)
 142         (goto-char (point-min))
 143         (if (stringp (car articles))
 144             'headers
 145           (if (nnfolder-retrieve-headers-with-nov articles fetch-old)
 146               'nov
 147             (setq articles (gnus-sorted-intersection
 148                             ;; Is ARTICLES sorted?
 149                             (sort articles '<)
 150                             (nnfolder-existing-articles)))
 151             (while (setq article (pop articles))
 152               (set-buffer nnfolder-current-buffer)
 153               (when (nnfolder-goto-article article)
 154                 (setq start (point))
 155                 (setq stop (if (search-forward "\n\n" nil t)
 156                                (1- (point))
 157                              (point-max)))
 158                 (set-buffer nntp-server-buffer)
 159                 (insert (format "221 %d Article retrieved.\n" article))
 160                 (insert-buffer-substring nnfolder-current-buffer start stop)
 161                 (goto-char (point-max))
 162                 (insert ".\n")))
 163             (set-buffer nntp-server-buffer)
 164             (nnheader-fold-continuation-lines)
 165             'headers))))))
 166
 167 (deffoo nnfolder-open-server (server &optional defs)
 168   (nnoo-change-server 'nnfolder server defs)
 169   (nnmail-activate 'nnfolder t)
 170   (gnus-make-directory nnfolder-directory)
 171   (unless (or gnus-nov-is-evil nnfolder-nov-is-evil)
 172     (and nnfolder-nov-directory
 173          (gnus-make-directory nnfolder-nov-directory)))
 174   (cond
 175    ((not (file-exists-p nnfolder-directory))
 176     (nnfolder-close-server)
 177     (nnheader-report 'nnfolder "Couldn't create directory: %s"
 178                      nnfolder-directory))
 179    ((not (file-directory-p (file-truename nnfolder-directory)))
 180     (nnfolder-close-server)
 181     (nnheader-report 'nnfolder "Not a directory: %s" nnfolder-directory))
 182    (t
 183     (nnmail-activate 'nnfolder)
 184     (nnheader-report 'nnfolder "Opened server %s using directory %s"
 185                      server nnfolder-directory)
 186     t)))
 187
 188 (deffoo nnfolder-request-close ()
 189   (let ((alist nnfolder-buffer-alist))
 190     (while alist
 191       (nnfolder-close-group (caar alist) nil t)
 192       (setq alist (cdr alist))))
 193   (nnoo-close-server 'nnfolder)
 194   (setq nnfolder-buffer-alist nil
 195         nnfolder-group-alist nil))
 196
 197 (deffoo nnfolder-request-article (article &optional group server buffer)
 198   (nnfolder-possibly-change-group group server)
 199   (save-excursion
 200     (set-buffer nnfolder-current-buffer)
 201     (goto-char (point-min))
 202     (when (nnfolder-goto-article article)
 203       (let (start stop)
 204         (setq start (point))
 205         (forward-line 1)
 206         (unless (and (nnmail-search-unix-mail-delim)
 207                      (forward-line -1))
 208           (goto-char (point-max)))
 209         (setq stop (point))
 210         (let ((nntp-server-buffer (or buffer nntp-server-buffer)))
 211           (set-buffer nntp-server-buffer)
 212           (erase-buffer)
 213           (insert-buffer-substring nnfolder-current-buffer start stop)
 214           (goto-char (point-min))
 215           (while (looking-at "From ")
 216             (delete-char 5)
 217             (insert "X-From-Line: ")
 218             (forward-line 1))
 219           (if (numberp article)
 220               (cons nnfolder-current-group article)
 221             (goto-char (point-min))
 222             (cons nnfolder-current-group
 223                   (if (search-forward (concat "\n" nnfolder-article-marker)
 224                                       nil t)
 225                       (string-to-int
 226                        (buffer-substring
 227                         (point) (progn (end-of-line) (point))))
 228                     -1))))))))
 229
 230 (deffoo nnfolder-request-group (group &optional server dont-check)
 231   (nnfolder-possibly-change-group group server t)
 232   (save-excursion
 233     (if (not (assoc group nnfolder-group-alist))
 234         (nnheader-report 'nnfolder "No such group: %s" group)
 235       (if dont-check
 236           (progn
 237             (nnheader-report 'nnfolder "Selected group %s" group)
 238             t)
 239         (let* ((active (assoc group nnfolder-group-alist))
 240                (group (car active))
 241                (range (cadr active)))
 242           (cond
 243            ((null active)
 244             (nnheader-report 'nnfolder "No such group: %s" group))
 245            ((null nnfolder-current-group)
 246             (nnheader-report 'nnfolder "Empty group: %s" group))
 247            (t
 248             (nnheader-report 'nnfolder "Selected group %s" group)
 249             (nnheader-insert "211 %d %d %d %s\n"
 250                              (1+ (- (cdr range) (car range)))
 251                              (car range) (cdr range) group))))))))
 252
 253 (deffoo nnfolder-request-scan (&optional group server)
 254   (nnfolder-possibly-change-group nil server)
 255   (when nnfolder-get-new-mail
 256     (nnfolder-possibly-change-group group server)
 257     (nnmail-get-new-mail
 258      'nnfolder
 259      (lambda ()
 260        (let ((bufs nnfolder-buffer-alist))
 261          (save-excursion
 262            (while bufs
 263              (if (not (gnus-buffer-live-p (nth 1 (car bufs))))
 264                  (setq nnfolder-buffer-alist
 265                        (delq (car bufs) nnfolder-buffer-alist))
 266                (set-buffer (nth 1 (car bufs)))
 267                (nnfolder-save-buffer)
 268                (kill-buffer (current-buffer)))
 269              (setq bufs (cdr bufs))))))
 270      nnfolder-directory
 271      group)))
 272
 273 ;; Don't close the buffer if we're not shutting down the server.  This way,
 274 ;; we can keep the buffer in the group buffer cache, and not have to grovel
 275 ;; over the buffer again unless we add new mail to it or modify it in some
 276 ;; way.
 277
 278 (deffoo nnfolder-close-group (group &optional server force)
 279   ;; Make sure we _had_ the group open.
 280   (when (or (assoc group nnfolder-buffer-alist)
 281             (equal group nnfolder-current-group))
 282     (let ((inf (assoc group nnfolder-buffer-alist)))
 283       (when inf
 284         (when (and nnfolder-current-group
 285                    nnfolder-current-buffer)
 286           (push (list nnfolder-current-group nnfolder-current-buffer)
 287                 nnfolder-buffer-alist))
 288         (setq nnfolder-buffer-alist
 289               (delq inf nnfolder-buffer-alist))
 290         (setq nnfolder-current-buffer (cadr inf)
 291               nnfolder-current-group (car inf))))
 292     (when (and nnfolder-current-buffer
 293                (buffer-name nnfolder-current-buffer))
 294       (save-excursion
 295         (set-buffer nnfolder-current-buffer)
 296         ;; If the buffer was modified, write the file out now.
 297         (nnfolder-save-buffer)
 298         ;; If we're shutting the server down, we need to kill the
 299         ;; buffer and remove it from the open buffer list.  Or, of
 300         ;; course, if we're trying to minimize our space impact.
 301         (kill-buffer (current-buffer))
 302         (setq nnfolder-buffer-alist (delq (assoc group nnfolder-buffer-alist)
 303                                           nnfolder-buffer-alist)))))
 304   (setq nnfolder-current-group nil
 305         nnfolder-current-buffer nil)
 306   t)
 307
 308 (deffoo nnfolder-request-create-group (group &optional server args)
 309   (nnfolder-possibly-change-group nil server)
 310   (nnmail-activate 'nnfolder)
 311   (when group
 312     (unless (assoc group nnfolder-group-alist)
 313       (push (list group (cons 1 0)) nnfolder-group-alist)
 314       (nnfolder-save-active nnfolder-group-alist nnfolder-active-file)
 315       (nnfolder-read-folder group)))
 316   t)
 317
 318 (deffoo nnfolder-request-list (&optional server)
 319   (nnfolder-possibly-change-group nil server)
 320   (save-excursion
 321     (let ((nnmail-file-coding-system nnfolder-active-file-coding-system))
 322       (nnmail-find-file nnfolder-active-file)
 323       (setq nnfolder-group-alist (nnmail-get-active)))
 324     t))
 325
 326 (deffoo nnfolder-request-newgroups (date &optional server)
 327   (nnfolder-possibly-change-group nil server)
 328   (nnfolder-request-list server))
 329
 330 (deffoo nnfolder-request-list-newsgroups (&optional server)
 331   (nnfolder-possibly-change-group nil server)
 332   (save-excursion
 333     (let ((nnmail-file-coding-system nnfolder-file-coding-system))
 334       (nnmail-find-file nnfolder-newsgroups-file))))
 335
 336 ;; Return a list consisting of all article numbers existing in the
 337 ;; current folder.
 338
 339 (defun nnfolder-existing-articles ()
 340   (save-excursion
 341     (when nnfolder-current-buffer
 342       (set-buffer nnfolder-current-buffer)
 343       (goto-char (point-min))
 344       (let ((marker (concat "\n" nnfolder-article-marker))
 345             (number "[0-9]+")
 346             numbers)
 347         (while (and (search-forward marker nil t)
 348                     (re-search-forward number nil t))
 349           (let ((newnum (string-to-number (match-string 0))))
 350             (if (nnmail-within-headers-p)
 351                 (push newnum numbers))))
 352       ;; The article numbers are increasing, so this result is sorted.
 353         (nreverse numbers)))))
 354
 355 (deffoo nnfolder-request-expire-articles
 356     (articles newsgroup &optional server force)
 357   (nnfolder-possibly-change-group newsgroup server)
 358   (let* ((is-old t)
 359          ;; The articles we have deleted so far.
 360          (deleted-articles nil)
 361          ;; The articles that really exist and will
 362          ;; be expired if they are old enough.
 363          (maybe-expirable
 364           (gnus-sorted-intersection articles (nnfolder-existing-articles))))
 365     (nnmail-activate 'nnfolder)
 366
 367     (save-excursion
 368       (set-buffer nnfolder-current-buffer)
 369       ;; Since messages are sorted in arrival order and expired in the
 370       ;; same order, we can stop as soon as we find a message that is
 371       ;; too old.
 372       (while (and maybe-expirable is-old)
 373         (goto-char (point-min))
 374         (when (and (nnfolder-goto-article (car maybe-expirable))
 375                    (search-forward (concat "\n" nnfolder-article-marker)
 376                                    nil t))
 377           (forward-sexp)
 378           (when (setq is-old
 379                       (nnmail-expired-article-p
 380                        newsgroup
 381                        (buffer-substring
 382                         (point) (progn (end-of-line) (point)))
 383                        force nnfolder-inhibit-expiry))
 384             (unless (eq nnmail-expiry-target 'delete)
 385               (with-temp-buffer
 386                 (nnfolder-request-article (car maybe-expirable)
 387                                           newsgroup server (current-buffer))
 388                 (let ((nnml-current-directory nil))
 389                   (nnmail-expiry-target-group
 390                    nnmail-expiry-target newsgroup))))
 391             (nnheader-message 5 "Deleting article %d in %s..."
 392                               (car maybe-expirable) newsgroup)
 393             (nnfolder-delete-mail)
 394             (unless (or gnus-nov-is-evil nnfolder-nov-is-evil)
 395               (nnfolder-nov-delete-article newsgroup (car maybe-expirable)))
 396             ;; Must remember which articles were actually deleted
 397             (push (car maybe-expirable) deleted-articles)))
 398         (setq maybe-expirable (cdr maybe-expirable)))
 399       (unless nnfolder-inhibit-expiry
 400         (nnheader-message 5 "Deleting articles...done"))
 401       (nnfolder-save-buffer)
 402       (nnfolder-adjust-min-active newsgroup)
 403       (nnfolder-save-active nnfolder-group-alist nnfolder-active-file)
 404       (gnus-sorted-complement articles (nreverse deleted-articles)))))
 405
 406 (deffoo nnfolder-request-move-article (article group server
 407                                                accept-form &optional last)
 408   (save-excursion
 409     (let ((buf (get-buffer-create " *nnfolder move*"))
 410           result)
 411       (and
 412        (nnfolder-request-article article group server)
 413        (save-excursion
 414          (set-buffer buf)
 415          (erase-buffer)
 416          (insert-buffer-substring nntp-server-buffer)
 417          (goto-char (point-min))
 418          (while (re-search-forward
 419                  (concat "^" nnfolder-article-marker)
 420                  (save-excursion (and (search-forward "\n\n" nil t) (point)))
 421                  t)
 422            (delete-region (progn (beginning-of-line) (point))
 423                           (progn (forward-line 1) (point))))
 424          (setq result (eval accept-form))
 425          (kill-buffer buf)
 426          result)
 427        (save-excursion
 428          (nnfolder-possibly-change-group group server)
 429          (set-buffer nnfolder-current-buffer)
 430          (goto-char (point-min))
 431          (when (nnfolder-goto-article article)
 432            (nnfolder-delete-mail))
 433          (unless (or gnus-nov-is-evil nnfolder-nov-is-evil)
 434            (nnfolder-nov-delete-article group article))
 435          (when last
 436            (nnfolder-save-buffer)
 437            (nnfolder-adjust-min-active group)
 438            (nnfolder-save-active nnfolder-group-alist nnfolder-active-file))))
 439       result)))
 440
 441 (deffoo nnfolder-request-accept-article (group &optional server last)
 442   (save-excursion
 443     (nnfolder-possibly-change-group group server)
 444     (nnmail-check-syntax)
 445     (let ((buf (current-buffer))
 446           result art-group)
 447       (goto-char (point-min))
 448       (when (looking-at "X-From-Line: ")
 449         (replace-match "From "))
 450       (let ((nnmail-file-coding-system nnfolder-active-file-coding-system))
 451         (with-temp-buffer
 452           (nnmail-find-file nnfolder-active-file)
 453           (setq nnfolder-group-alist (nnmail-parse-active))))
 454       (save-excursion
 455         (goto-char (point-min))
 456         (if (search-forward "\n\n" nil t)
 457             (forward-line -1)
 458           (goto-char (point-max)))
 459         (while (re-search-backward (concat "^" nnfolder-article-marker) nil t)
 460           (delete-region (point) (progn (forward-line 1) (point))))
 461         (when nnmail-cache-accepted-message-ids
 462           (nnmail-cache-insert (nnmail-fetch-field "message-id")))
 463         (setq result (if (stringp group)
 464                          (list (cons group (nnfolder-active-number group)))
 465                        (setq art-group
 466                              (nnmail-article-group 'nnfolder-active-number))))
 467         (if (and (null result)
 468                  (yes-or-no-p "Moved to `junk' group; delete article? "))
 469             (setq result 'junk)
 470           (setq result
 471                 (car (nnfolder-save-mail result)))))
 472       (when last
 473         (save-excursion
 474           (nnfolder-possibly-change-folder (or (caar art-group) group))
 475           (nnfolder-save-buffer)
 476           (when nnmail-cache-accepted-message-ids
 477             (nnmail-cache-close))))
 478       (nnfolder-save-active nnfolder-group-alist nnfolder-active-file)
 479       (unless result
 480         (nnheader-report 'nnfolder "Couldn't store article"))
 481       result)))
 482
 483 (deffoo nnfolder-request-replace-article (article group buffer)
 484   (nnfolder-possibly-change-group group)
 485   (save-excursion
 486     (set-buffer buffer)
 487     (goto-char (point-min))
 488     (let (xfrom)
 489       (while (re-search-forward "^X-From-Line: \\(.*\\)$" nil t)
 490         (setq xfrom (match-string 1))
 491         (gnus-delete-line))
 492       (goto-char (point-min))
 493       (if xfrom
 494           (insert "From " xfrom "\n")
 495         (unless (looking-at "From ")
 496           (insert "From nobody " (current-time-string) "\n"))))
 497     (nnfolder-normalize-buffer)
 498     (set-buffer nnfolder-current-buffer)
 499     (goto-char (point-min))
 500     (if (not (nnfolder-goto-article article))
 501         nil
 502       (nnfolder-delete-mail)
 503       (insert-buffer-substring buffer)
 504       (unless (or gnus-nov-is-evil nnfolder-nov-is-evil)
 505         (save-excursion
 506           (set-buffer buffer)
 507           (let ((headers (nnfolder-parse-head article
 508                                               (point-min) (point-max))))
 509             (with-current-buffer (nnfolder-open-nov group)
 510               (if (nnheader-find-nov-line article)
 511                   (delete-region (point) (progn (forward-line 1) (point))))
 512               (nnheader-insert-nov headers)))))
 513       (nnfolder-save-buffer)
 514       t)))
 515
 516 (deffoo nnfolder-request-delete-group (group &optional force server)
 517   (nnfolder-close-group group server t)
 518   ;; Delete all articles in GROUP.
 519   (if (not force)
 520       ()                                ; Don't delete the articles.
 521     ;; Delete the file that holds the group.
 522     (ignore-errors
 523       (delete-file (nnfolder-group-pathname group))
 524       (delete-file (nnfolder-group-nov-pathname group))))
 525   ;; Remove the group from all structures.
 526   (setq nnfolder-group-alist
 527         (delq (assoc group nnfolder-group-alist) nnfolder-group-alist)
 528         nnfolder-current-group nil
 529         nnfolder-current-buffer nil)
 530   ;; Save the active file.
 531   (nnfolder-save-active nnfolder-group-alist nnfolder-active-file)
 532   t)
 533
 534 (deffoo nnfolder-request-rename-group (group new-name &optional server)
 535   (nnfolder-possibly-change-group group server)
 536   (save-excursion
 537     (set-buffer nnfolder-current-buffer)
 538     (and (file-writable-p buffer-file-name)
 539          (ignore-errors
 540            (let ((new-file (nnfolder-group-pathname new-name)))
 541              (gnus-make-directory (file-name-directory new-file))
 542              (rename-file buffer-file-name new-file)
 543              (setq new-file (nnfolder-group-nov-pathname new-name))
 544              (rename-file (nnfolder-group-nov-pathname group)
 545                           new-file))
 546            t)
 547          ;; That went ok, so we change the internal structures.
 548          (let ((entry (assoc group nnfolder-group-alist)))
 549            (and entry (setcar entry new-name))
 550            (setq nnfolder-current-buffer nil
 551                  nnfolder-current-group nil)
 552            ;; Save the new group alist.
 553            (nnfolder-save-active nnfolder-group-alist nnfolder-active-file)
 554            ;; We kill the buffer instead of renaming it and stuff.
 555            (kill-buffer (current-buffer))
 556            t))))
 557
 558 (deffoo nnfolder-request-regenerate (server)
 559   (nnfolder-possibly-change-group nil server)
 560   (nnfolder-generate-active-file)
 561   t)
 562
 563 \f
 564 ;;; Internal functions.
 565
 566 (defun nnfolder-adjust-min-active (group)
 567   ;; Find the lowest active article in this group.
 568   (let* ((active (cadr (assoc group nnfolder-group-alist)))
 569          (marker (concat "\n" nnfolder-article-marker))
 570          (number "[0-9]+")
 571          (activemin (cdr active)))
 572     (save-excursion
 573       (set-buffer nnfolder-current-buffer)
 574       (goto-char (point-min))
 575       (while (and (search-forward marker nil t)
 576                   (re-search-forward number nil t))
 577         (let ((newnum (string-to-number (match-string 0))))
 578           (if (nnmail-within-headers-p)
 579               (setq activemin (min activemin newnum)))))
 580       (setcar active activemin))))
 581
 582 (defun nnfolder-article-string (article)
 583   (if (numberp article)
 584       (concat "\n" nnfolder-article-marker (int-to-string article) " ")
 585     (concat "\nMessage-ID: " article)))
 586
 587 (defun nnfolder-goto-article (article)
 588   "Place point at the start of the headers of ARTICLE.
 589 ARTICLE can be an article number or a Message-ID.
 590 Returns t if successful, nil otherwise."
 591   (let ((art-string (nnfolder-article-string article))
 592         start found)
 593     ;; It is likely that we are at or before the delimiter line.
 594     ;; We therefore go to the end of the previous line, and start
 595     ;; searching from there.
 596     (beginning-of-line)
 597     (unless (bobp)
 598       (forward-char -1))
 599     (setq start (point))
 600     ;; First search forward.
 601     (while (and (setq found (search-forward art-string nil t))
 602                 (not (nnmail-within-headers-p))))
 603     ;; If unsuccessful, search backward from where we started,
 604     (unless found
 605       (goto-char start)
 606       (while (and (setq found (search-backward art-string nil t))
 607                   (not (nnmail-within-headers-p)))))
 608     (when found
 609       (nnmail-search-unix-mail-delim-backward))))
 610
 611 (defun nnfolder-delete-mail (&optional leave-delim)
 612   "Delete the message that point is in.
 613 If optional argument LEAVE-DELIM is t, then mailbox delimiter is not
 614 deleted.  Point is left where the deleted region was."
 615   (save-restriction
 616     (narrow-to-region
 617      (save-excursion
 618        ;; In case point is at the beginning of the message already.
 619        (forward-line 1)
 620        (nnmail-search-unix-mail-delim-backward)
 621        (if leave-delim (progn (forward-line 1) (point))
 622          (point)))
 623      (progn
 624        (forward-line 1)
 625        (if (nnmail-search-unix-mail-delim)
 626            (point)
 627          (point-max))))
 628     (run-hooks 'nnfolder-delete-mail-hook)
 629     (delete-region (point-min) (point-max))))
 630
 631 (defun nnfolder-possibly-change-group (group &optional server dont-check)
 632   ;; Change servers.
 633   (when (and server
 634              (not (nnfolder-server-opened server)))
 635     (nnfolder-open-server server))
 636   (unless (gnus-buffer-live-p nnfolder-current-buffer)
 637     (setq nnfolder-current-buffer nil
 638           nnfolder-current-group nil))
 639   ;; Change group.
 640   (let ((file-name-coding-system nnmail-pathname-coding-system))
 641     (when (and group
 642                (not (equal group nnfolder-current-group))
 643                (progn
 644                  (nnmail-activate 'nnfolder)
 645                  (and (assoc group nnfolder-group-alist)
 646                       (file-exists-p (nnfolder-group-pathname group)))))
 647       (if dont-check
 648           (setq nnfolder-current-group group
 649                 nnfolder-current-buffer nil)
 650         (let (inf file)
 651           ;; If we have to change groups, see if we don't already have
 652           ;; the folder in memory.  If we do, verify the modtime and
 653           ;; destroy the folder if needed so we can rescan it.
 654           (setq nnfolder-current-buffer
 655                 (nth 1 (assoc group nnfolder-buffer-alist)))
 656
 657           ;; If the buffer is not live, make sure it isn't in the
 658           ;; alist.  If it is live, verify that nobody else has
 659           ;; touched the file since last time.
 660           (when (and nnfolder-current-buffer
 661                      (not (gnus-buffer-live-p nnfolder-current-buffer)))
 662             (setq nnfolder-buffer-alist (delq inf nnfolder-buffer-alist)
 663                   nnfolder-current-buffer nil))
 664
 665           (setq nnfolder-current-group group)
 666
 667           (when (or (not nnfolder-current-buffer)
 668                     (not (verify-visited-file-modtime
 669                           nnfolder-current-buffer)))
 670             (save-excursion
 671               (setq file (nnfolder-group-pathname group))
 672               ;; See whether we need to create the new file.
 673               (unless (file-exists-p file)
 674                 (gnus-make-directory (file-name-directory file))
 675                 (let ((nnmail-file-coding-system
 676                        (or nnfolder-file-coding-system-for-write
 677                            nnfolder-file-coding-system-for-write)))
 678                   (nnmail-write-region 1 1 file t 'nomesg)))
 679               (when (setq nnfolder-current-buffer (nnfolder-read-folder group))
 680                 (set-buffer nnfolder-current-buffer)
 681                 (push (list group nnfolder-current-buffer)
 682                       nnfolder-buffer-alist)))))))))
 683
 684 (defun nnfolder-save-mail (group-art-list)
 685   "Called narrowed to an article."
 686   (let* (save-list group-art)
 687     (goto-char (point-min))
 688     ;; The From line may have been quoted by movemail.
 689     (when (looking-at ">From")
 690       (delete-char 1))
 691     ;; This might come from somewhere else.
 692     (unless (looking-at "From ")
 693       (insert "From nobody " (current-time-string) "\n")
 694       (goto-char (point-min)))
 695     ;; Quote all "From " lines in the article.
 696     (forward-line 1)
 697     (let (case-fold-search)
 698       (while (re-search-forward "^From " nil t)
 699         (beginning-of-line)
 700         (insert "> ")))
 701     (setq save-list group-art-list)
 702     (nnmail-insert-lines)
 703     (nnmail-insert-xref group-art-list)
 704     (run-hooks 'nnmail-prepare-save-mail-hook)
 705     (run-hooks 'nnfolder-prepare-save-mail-hook)
 706
 707     ;; Insert the mail into each of the destination groups.
 708     (while (setq group-art (pop group-art-list))
 709       ;; Kill any previous newsgroup markers.
 710       (goto-char (point-min))
 711       (if (search-forward "\n\n" nil t)
 712           (forward-line -1)
 713         (goto-char (point-max)))
 714       (while (search-backward (concat "\n" nnfolder-article-marker) nil t)
 715         (delete-region (1+ (point)) (progn (forward-line 2) (point))))
 716
 717       ;; Insert the new newsgroup marker.
 718       (nnfolder-insert-newsgroup-line group-art)
 719
 720       (save-excursion
 721         (let ((beg (point-min))
 722               (end (point-max))
 723               (obuf (current-buffer)))
 724           (nnfolder-possibly-change-folder (car group-art))
 725           (let ((buffer-read-only nil))
 726             (nnfolder-normalize-buffer)
 727             (insert-buffer-substring obuf beg end))
 728           (unless (or gnus-nov-is-evil nnfolder-nov-is-evil)
 729             (set-buffer obuf)
 730             (nnfolder-add-nov (car group-art) (cdr group-art)
 731                               (nnfolder-parse-head nil beg end))))))
 732
 733     ;; Did we save it anywhere?
 734     save-list))
 735
 736 (defun nnfolder-normalize-buffer ()
 737   "Make sure there are two newlines at the end of the buffer."
 738   (goto-char (point-max))
 739   (skip-chars-backward "\n")
 740   (delete-region (point) (point-max))
 741   (insert "\n\n"))
 742
 743 (defun nnfolder-insert-newsgroup-line (group-art)
 744   (save-excursion
 745     (goto-char (point-min))
 746     (unless (search-forward "\n\n" nil t)
 747       (goto-char (point-max))
 748       (insert "\n"))
 749     (forward-char -1)
 750     (insert (format (concat nnfolder-article-marker "%d   %s\n")
 751                     (cdr group-art) (current-time-string)))))
 752
 753 (defun nnfolder-active-number (group)
 754   ;; Find the next article number in GROUP.
 755   (let ((active (cadr (assoc group nnfolder-group-alist))))
 756     (if active
 757         (setcdr active (1+ (cdr active)))
 758       ;; This group is new, so we create a new entry for it.
 759       ;; This might be a bit naughty... creating groups on the drop of
 760       ;; a hat, but I don't know...
 761       (push (list group (setq active (cons 1 1)))
 762             nnfolder-group-alist))
 763     (cdr active)))
 764
 765 (defun nnfolder-possibly-change-folder (group)
 766   (let ((inf (assoc group nnfolder-buffer-alist)))
 767     (if (and inf
 768              (gnus-buffer-live-p (cadr inf)))
 769         (set-buffer (cadr inf))
 770       (when inf
 771         (setq nnfolder-buffer-alist (delq inf nnfolder-buffer-alist)))
 772       (when nnfolder-group-alist
 773         (nnfolder-save-active nnfolder-group-alist nnfolder-active-file))
 774       (push (list group (nnfolder-read-folder group))
 775             nnfolder-buffer-alist))))
 776
 777 ;; This method has a problem if you've accidentally let the active
 778 ;; list get out of sync with the files.  This could happen, say, if
 779 ;; you've accidentally gotten new mail with something other than Gnus
 780 ;; (but why would _that_ ever happen? :-).  In that case, we will be
 781 ;; in the middle of processing the file, ready to add new X-Gnus
 782 ;; article number markers, and we'll run across a message with no ID
 783 ;; yet - the active list _may_not_ be ready for us yet.
 784
 785 ;; To handle this, I'm modifying this routine to maintain the maximum
 786 ;; ID seen so far, and when we hit a message with no ID, we will
 787 ;; _manually_ scan the rest of the message looking for any more,
 788 ;; possibly higher IDs.  We'll assume the maximum that we find is the
 789 ;; highest active.  Note that this shouldn't cost us much extra time
 790 ;; at all, but will be a lot less vulnerable to glitches between the
 791 ;; mbox and the active file.
 792
 793 (defun nnfolder-read-folder (group)
 794   (let* ((file (nnfolder-group-pathname group))
 795          (nov  (nnfolder-group-nov-pathname group))
 796          (buffer (set-buffer
 797                   (let ((nnheader-file-coding-system
 798                          nnfolder-file-coding-system))
 799                     (nnheader-find-file-noselect file)))))
 800     (mm-enable-multibyte) ;; Use multibyte buffer for future copying.
 801     (if (equal (cadr (assoc group nnfolder-scantime-alist))
 802                (nth 5 (file-attributes file)))
 803         ;; This looks up-to-date, so we don't do any scanning.
 804         (if (file-exists-p file)
 805             buffer
 806           (push (list group buffer) nnfolder-buffer-alist)
 807           (set-buffer-modified-p t)
 808           (nnfolder-save-buffer))
 809       ;; Parse the damn thing.
 810       (save-excursion
 811         (goto-char (point-min))
 812         ;; Remove any blank lines at the start.
 813         (while (eq (following-char) ?\n)
 814           (delete-char 1))
 815         (nnmail-activate 'nnfolder)
 816         ;; Read in the file.
 817         (let ((delim "^From ")
 818               (marker (concat "\n" nnfolder-article-marker))
 819               (number "[0-9]+")
 820               (active (or (cadr (assoc group nnfolder-group-alist))
 821                           (cons 1 0)))
 822               (scantime (assoc group nnfolder-scantime-alist))
 823               (minid (lsh -1 -1))
 824               maxid start end newscantime
 825               novbuf articles newnum
 826               buffer-read-only)
 827           (buffer-disable-undo)
 828           (setq maxid (cdr active))
 829
 830           (unless (or gnus-nov-is-evil nnfolder-nov-is-evil
 831                       (and (file-exists-p nov)
 832                            (file-newer-than-file-p nov file)))
 833             (unless (file-exists-p nov)
 834               (gnus-make-directory (file-name-directory nov)))
 835             (with-current-buffer
 836                 (setq novbuf (nnfolder-open-nov group))
 837               (goto-char (point-min))
 838               (while (not (eobp))
 839                 (push (read novbuf) articles)
 840                 (forward-line 1))
 841               (setq articles (nreverse articles))))
 842           (goto-char (point-min))
 843
 844           ;; Anytime the active number is 1 or 0, it is suspect.  In
 845           ;; that case, search the file manually to find the active
 846           ;; number.  Or, of course, if we're being paranoid.  (This
 847           ;; would also be the place to build other lists from the
 848           ;; header markers, such as expunge lists, etc., if we ever
 849           ;; desired to abandon the active file entirely for mboxes.)
 850           (when (or nnfolder-ignore-active-file
 851                     novbuf
 852                     (< maxid 2))
 853             (while (and (search-forward marker nil t)
 854                         (looking-at number))
 855               (setq newnum (string-to-number (match-string 0)))
 856               (when (nnmail-within-headers-p)
 857                 (setq maxid (max maxid newnum)
 858                       minid (min minid newnum))
 859                 (when novbuf
 860                   (if (memq newnum articles)
 861                       (setq articles (delq newnum articles))
 862                     (let ((headers (nnfolder-parse-head newnum)))
 863                       (with-current-buffer novbuf
 864                         (nnheader-find-nov-line newnum)
 865                         (nnheader-insert-nov headers)))))))
 866             (when (and novbuf articles)
 867               (with-current-buffer novbuf
 868                 (dolist (article articles)
 869                   (when (nnheader-find-nov-line article)
 870                     (delete-region (point)
 871                                    (progn (forward-line 1) (point)))))))
 872             (setcar active (max 1 (min minid maxid)))
 873             (setcdr active (max maxid (cdr active)))
 874             (goto-char (point-min)))
 875
 876           ;; As long as we trust that the user will only insert
 877           ;; unmarked mail at the end, go to the end and search
 878           ;; backwards for the last marker.  Find the start of that
 879           ;; message, and begin to search for unmarked messages from
 880           ;; there.
 881           (when (not (or nnfolder-distrust-mbox
 882                          (< maxid 2)))
 883             (goto-char (point-max))
 884             (unless (re-search-backward marker nil t)
 885               (goto-char (point-min)))
 886             ;;(when (nnmail-search-unix-mail-delim)
 887             ;;  (goto-char (point-min)))
 888             )
 889
 890           ;; Keep track of the active number on our own, and insert it
 891           ;; back into the active list when we're done.  Also, prime
 892           ;; the pump to cut down on the number of searches we do.
 893           (unless (nnmail-search-unix-mail-delim)
 894             (goto-char (point-max)))
 895           (setq end (point-marker))
 896           (while (not (= end (point-max)))
 897             (setq start (marker-position end))
 898             (goto-char end)
 899            ;; There may be more than one "From " line, so we skip past
 900             ;; them.
 901             (while (looking-at delim)
 902               (forward-line 1))
 903             (set-marker end (if (nnmail-search-unix-mail-delim)
 904                                 (point)
 905                               (point-max)))
 906             (goto-char start)
 907             (when (not (search-forward marker end t))
 908               (narrow-to-region start end)
 909               (nnmail-insert-lines)
 910               (nnfolder-insert-newsgroup-line
 911                (cons nil
 912                      (setq newnum
 913                            (nnfolder-active-number nnfolder-current-group))))
 914               (when novbuf
 915                 (let ((headers (nnfolder-parse-head newnum (point-min)
 916                                                     (point-max))))
 917                   (with-current-buffer novbuf
 918                     (goto-char (point-max))
 919                     (nnheader-insert-nov headers))))
 920               (widen)))
 921
 922           (set-marker end nil)
 923           ;; Make absolutely sure that the active list reflects
 924           ;; reality!
 925           (nnfolder-save-active nnfolder-group-alist nnfolder-active-file)
 926
 927           ;; Set the scantime for this group.
 928           (setq newscantime (visited-file-modtime))
 929           (if scantime
 930               (setcdr scantime (list newscantime))
 931             (push (list nnfolder-current-group newscantime)
 932                   nnfolder-scantime-alist))
 933           ;; Save nov.
 934           (when novbuf
 935             (nnfolder-save-nov))
 936           (current-buffer))))))
 937
 938 ;;;###autoload
 939 (defun nnfolder-generate-active-file ()
 940   "Look for mbox folders in the nnfolder directory and make them into groups.
 941 This command does not work if you use short group names."
 942   (interactive)
 943   (nnmail-activate 'nnfolder)
 944   (unless (or gnus-nov-is-evil nnfolder-nov-is-evil)
 945     (dolist (file (directory-files (or nnfolder-nov-directory
 946                                        nnfolder-directory)
 947                                    t
 948                                    (concat
 949                                     (regexp-quote nnfolder-nov-file-suffix)
 950                                     "$")))
 951       (when (not (message-mail-file-mbox-p file))
 952         (ignore-errors
 953           (delete-file file)))))
 954   (let ((files (directory-files nnfolder-directory))
 955         file)
 956     (while (setq file (pop files))
 957       (when (and (not (backup-file-name-p file))
 958                  (message-mail-file-mbox-p
 959                   (nnheader-concat nnfolder-directory file)))
 960         (let ((oldgroup (assoc file nnfolder-group-alist)))
 961           (if oldgroup
 962               (nnheader-message 5 "Refreshing group %s..." file)
 963             (nnheader-message 5 "Adding group %s..." file))
 964           (if oldgroup
 965               (setq nnfolder-group-alist
 966                     (delq oldgroup (copy-sequence nnfolder-group-alist))))
 967           (push (list file (cons 1 0)) nnfolder-group-alist)
 968           (nnfolder-possibly-change-folder file)
 969           (nnfolder-possibly-change-group file)
 970           (nnfolder-close-group file))))
 971     (nnheader-message 5 "")))
 972
 973 (defun nnfolder-group-pathname (group)
 974   "Make pathname for GROUP."
 975   (setq group
 976         (mm-encode-coding-string group nnmail-pathname-coding-system))
 977   (let ((dir (file-name-as-directory (expand-file-name nnfolder-directory))))
 978     ;; If this file exists, we use it directly.
 979     (if (or nnmail-use-long-file-names
 980             (file-exists-p (concat dir group)))
 981         (concat dir group)
 982       ;; If not, we translate dots into slashes.
 983       (concat dir (nnheader-replace-chars-in-string group ?. ?/)))))
 984
 985 (defun nnfolder-group-nov-pathname (group)
 986   "Make pathname for GROUP NOV."
 987   (let ((nnfolder-directory
 988          (or nnfolder-nov-directory nnfolder-directory)))
 989     (concat (nnfolder-group-pathname group) nnfolder-nov-file-suffix)))
 990
 991 (defun nnfolder-save-buffer ()
 992   "Save the buffer."
 993   (when (buffer-modified-p)
 994     (run-hooks 'nnfolder-save-buffer-hook)
 995     (gnus-make-directory (file-name-directory (buffer-file-name)))
 996     (let ((coding-system-for-write
 997            (or nnfolder-file-coding-system-for-write
 998                nnfolder-file-coding-system)))
 999       (save-buffer)))
1000   (unless (or gnus-nov-is-evil nnfolder-nov-is-evil)
1001     (nnfolder-save-nov)))
1002
1003 (defun nnfolder-save-active (group-alist active-file)
1004   (let ((nnmail-active-file-coding-system
1005          (or nnfolder-active-file-coding-system-for-write
1006              nnfolder-active-file-coding-system)))
1007     (nnmail-save-active group-alist active-file)))
1008
1009 (defun nnfolder-open-nov (group)
1010   (or (cdr (assoc group nnfolder-nov-buffer-alist))
1011       (let ((buffer (get-buffer-create (format " *nnfolder overview %s*" group))))
1012         (save-excursion
1013           (set-buffer buffer)
1014           (set (make-local-variable 'nnfolder-nov-buffer-file-name)
1015                (nnfolder-group-nov-pathname group))
1016           (erase-buffer)
1017           (when (file-exists-p nnfolder-nov-buffer-file-name)
1018             (nnheader-insert-file-contents nnfolder-nov-buffer-file-name)))
1019         (push (cons group buffer) nnfolder-nov-buffer-alist)
1020         buffer)))
1021
1022 (defun nnfolder-save-nov ()
1023   (save-excursion
1024     (while nnfolder-nov-buffer-alist
1025       (when (buffer-name (cdar nnfolder-nov-buffer-alist))
1026         (set-buffer (cdar nnfolder-nov-buffer-alist))
1027         (when (buffer-modified-p)
1028           (gnus-make-directory (file-name-directory
1029                                 nnfolder-nov-buffer-file-name))
1030           (nnmail-write-region 1 (point-max) nnfolder-nov-buffer-file-name
1031                                nil 'nomesg))
1032         (set-buffer-modified-p nil)
1033         (kill-buffer (current-buffer)))
1034       (setq nnfolder-nov-buffer-alist (cdr nnfolder-nov-buffer-alist)))))
1035
1036 (defun nnfolder-nov-delete-article (group article)
1037   (save-excursion
1038     (set-buffer (nnfolder-open-nov group))
1039     (when (nnheader-find-nov-line article)
1040       (delete-region (point) (progn (forward-line 1) (point))))
1041     t))
1042
1043 (defun nnfolder-retrieve-headers-with-nov (articles &optional fetch-old)
1044   (if (or gnus-nov-is-evil nnfolder-nov-is-evil)
1045       nil
1046     (let ((nov (nnfolder-group-nov-pathname nnfolder-current-group)))
1047       (when (file-exists-p nov)
1048         (save-excursion
1049           (set-buffer nntp-server-buffer)
1050           (erase-buffer)
1051           (nnheader-insert-file-contents nov)
1052           (if (and fetch-old
1053                    (not (numberp fetch-old)))
1054               t                         ; Don't remove anything.
1055             (nnheader-nov-delete-outside-range
1056              (if fetch-old (max 1 (- (car articles) fetch-old))
1057                (car articles))
1058              (car (last articles)))
1059             t))))))
1060
1061 (defun nnfolder-parse-head (&optional number b e)
1062   "Parse the head of the current buffer."
1063   (let ((buf (current-buffer))
1064         chars)
1065     (save-excursion
1066       (unless b
1067         (setq b (if (nnmail-search-unix-mail-delim-backward)
1068                     (point) (point-min)))
1069         (forward-line 1)
1070         (setq e (if (nnmail-search-unix-mail-delim)
1071                     (point) (point-max))))
1072       (setq chars (- e b))
1073       (unless (zerop chars)
1074         (goto-char b)
1075         (if (search-forward "\n\n" e t) (setq e (1- (point)))))
1076       (with-temp-buffer
1077         (insert-buffer-substring buf b e)
1078         ;; Fold continuation lines.
1079         (goto-char (point-min))
1080         (while (re-search-forward "\\(\r?\n[ \t]+\\)+" nil t)
1081           (replace-match " " t t))
1082         ;; Remove any tabs; they are too confusing.
1083         (subst-char-in-region (point-min) (point-max) ?\t ? )
1084         (let ((headers (nnheader-parse-head t)))
1085           (mail-header-set-chars headers chars)
1086           (mail-header-set-number headers number)
1087           headers)))))
1088
1089 (defun nnfolder-add-nov (group article headers)
1090   "Add a nov line for the GROUP base."
1091   (save-excursion
1092     (set-buffer (nnfolder-open-nov group))
1093     (goto-char (point-max))
1094     (mail-header-set-number headers article)
1095     (nnheader-insert-nov headers)))
1096
1097 (provide 'nnfolder)
1098
1099 ;;; nnfolder.el ends here