cgit.sxemacs.org Git - gnus/blob - lisp/nnfolder.el

   1 ;;; nnfolder.el --- mail folder access for Gnus
   2 ;; Copyright (C) 1995,96,97 Free Software Foundation, Inc.
   3
   4 ;; Author: Scott Byer <byer@mv.us.adobe.com>
   5 ;;      Lars Magne Ingebrigtsen <larsi@ifi.uio.no>
   6 ;;      Masanobu UMEDA <umerin@flab.flab.fujitsu.junet>
   7 ;; Keywords: mail
   8
   9 ;; This file is part of GNU Emacs.
  10
  11 ;; GNU Emacs is free software; you can redistribute it and/or modify
  12 ;; it under the terms of the GNU General Public License as published by
  13 ;; the Free Software Foundation; either version 2, or (at your option)
  14 ;; any later version.
  15
  16 ;; GNU Emacs is distributed in the hope that it will be useful,
  17 ;; but WITHOUT ANY WARRANTY; without even the implied warranty of
  18 ;; MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.  See the
  19 ;; GNU General Public License for more details.
  20
  21 ;; You should have received a copy of the GNU General Public License
  22 ;; along with GNU Emacs; see the file COPYING.  If not, write to the
  23 ;; Free Software Foundation, Inc., 59 Temple Place - Suite 330,
  24 ;; Boston, MA 02111-1307, USA.
  25
  26 ;;; Commentary:
  27
  28 ;;; Code:
  29
  30 (require 'nnheader)
  31 (require 'message)
  32 (require 'nnmail)
  33 (require 'nnoo)
  34 (require 'cl)
  35 (require 'gnus-util)
  36
  37 (nnoo-declare nnfolder)
  38
  39 (defvoo nnfolder-directory (expand-file-name message-directory)
  40   "The name of the nnfolder directory.")
  41
  42 (defvoo nnfolder-active-file
  43   (nnheader-concat nnfolder-directory "active")
  44   "The name of the active file.")
  45
  46 ;; I renamed this variable to something more in keeping with the general GNU
  47 ;; style. -SLB
  48
  49 (defvoo nnfolder-ignore-active-file nil
  50   "If non-nil, causes nnfolder to do some extra work in order to determine
  51 the true active ranges of an mbox file.  Note that the active file is still
  52 saved, but it's values are not used.  This costs some extra time when
  53 scanning an mbox when opening it.")
  54
  55 (defvoo nnfolder-distrust-mbox nil
  56   "If non-nil, causes nnfolder to not trust the user with respect to
  57 inserting unaccounted for mail in the middle of an mbox file.  This can greatly
  58 slow down scans, which now must scan the entire file for unmarked messages.
  59 When nil, scans occur forward from the last marked message, a huge
  60 time saver for large mailboxes.")
  61
  62 (defvoo nnfolder-newsgroups-file
  63   (concat (file-name-as-directory nnfolder-directory) "newsgroups")
  64   "Mail newsgroups description file.")
  65
  66 (defvoo nnfolder-get-new-mail t
  67   "If non-nil, nnfolder will check the incoming mail file and split the mail.")
  68
  69 (defvoo nnfolder-prepare-save-mail-hook nil
  70   "Hook run narrowed to an article before saving.")
  71
  72 (defvoo nnfolder-save-buffer-hook nil
  73   "Hook run before saving the nnfolder mbox buffer.")
  74
  75 (defvoo nnfolder-inhibit-expiry nil
  76   "If non-nil, inhibit expiry.")
  77
  78 \f
  79
  80 (defconst nnfolder-version "nnfolder 1.0"
  81   "nnfolder version.")
  82
  83 (defconst nnfolder-article-marker "X-Gnus-Article-Number: "
  84   "String used to demarcate what the article number for a message is.")
  85
  86 (defvoo nnfolder-current-group nil)
  87 (defvoo nnfolder-current-buffer nil)
  88 (defvoo nnfolder-status-string "")
  89 (defvoo nnfolder-group-alist nil)
  90 (defvoo nnfolder-buffer-alist nil)
  91 (defvoo nnfolder-scantime-alist nil)
  92
  93 \f
  94
  95 ;;; Interface functions
  96
  97 (nnoo-define-basics nnfolder)
  98
  99 (deffoo nnfolder-retrieve-headers (articles &optional group server fetch-old)
 100   (save-excursion
 101     (set-buffer nntp-server-buffer)
 102     (erase-buffer)
 103     (let (article art-string start stop)
 104       (nnfolder-possibly-change-group group server)
 105       (when nnfolder-current-buffer
 106         (set-buffer nnfolder-current-buffer)
 107         (goto-char (point-min))
 108         (if (stringp (car articles))
 109             'headers
 110           (while articles
 111             (setq article (car articles))
 112             (setq art-string (nnfolder-article-string article))
 113             (set-buffer nnfolder-current-buffer)
 114             (when (or (search-forward art-string nil t)
 115                       ;; Don't search the whole file twice!  Also, articles
 116                       ;; probably have some locality by number, so searching
 117                       ;; backwards will be faster.  Especially if we're at the
 118                       ;; beginning of the buffer :-). -SLB
 119                       (search-backward art-string nil t))
 120               (nnmail-search-unix-mail-delim-backward)
 121               (setq start (point))
 122               (search-forward "\n\n" nil t)
 123               (setq stop (1- (point)))
 124               (set-buffer nntp-server-buffer)
 125               (insert (format "221 %d Article retrieved.\n" article))
 126               (insert-buffer-substring nnfolder-current-buffer start stop)
 127               (goto-char (point-max))
 128               (insert ".\n"))
 129             (setq articles (cdr articles)))
 130
 131           (set-buffer nntp-server-buffer)
 132           (nnheader-fold-continuation-lines)
 133           'headers)))))
 134
 135 (deffoo nnfolder-open-server (server &optional defs)
 136   (nnoo-change-server 'nnfolder server defs)
 137   (when (not (file-exists-p nnfolder-directory))
 138     (gnus-make-directory nnfolder-directory))
 139   (cond
 140    ((not (file-exists-p nnfolder-directory))
 141     (nnfolder-close-server)
 142     (nnheader-report 'nnfolder "Couldn't create directory: %s"
 143                      nnfolder-directory))
 144    ((not (file-directory-p (file-truename nnfolder-directory)))
 145     (nnfolder-close-server)
 146     (nnheader-report 'nnfolder "Not a directory: %s" nnfolder-directory))
 147    (t
 148     (nnheader-report 'nnfolder "Opened server %s using directory %s"
 149                      server nnfolder-directory)
 150     t)))
 151
 152 (deffoo nnfolder-request-close ()
 153   (let ((alist nnfolder-buffer-alist))
 154     (while alist
 155       (nnfolder-close-group (caar alist) nil t)
 156       (setq alist (cdr alist))))
 157   (nnoo-close-server 'nnfolder)
 158   (setq nnfolder-buffer-alist nil
 159         nnfolder-group-alist nil))
 160
 161 (deffoo nnfolder-request-article (article &optional group server buffer)
 162   (nnfolder-possibly-change-group group server)
 163   (save-excursion
 164     (set-buffer nnfolder-current-buffer)
 165     (goto-char (point-min))
 166     (when (search-forward (nnfolder-article-string article) nil t)
 167       (let (start stop)
 168         (nnmail-search-unix-mail-delim-backward)
 169         (setq start (point))
 170         (forward-line 1)
 171         (unless (and (nnmail-search-unix-mail-delim)
 172                      (forward-line -1))
 173           (goto-char (point-max)))
 174         (setq stop (point))
 175         (let ((nntp-server-buffer (or buffer nntp-server-buffer)))
 176           (set-buffer nntp-server-buffer)
 177           (erase-buffer)
 178           (insert-buffer-substring nnfolder-current-buffer start stop)
 179           (goto-char (point-min))
 180           (while (looking-at "From ")
 181             (delete-char 5)
 182             (insert "X-From-Line: ")
 183             (forward-line 1))
 184           (if (numberp article)
 185               (cons nnfolder-current-group article)
 186             (goto-char (point-min))
 187             (search-forward (concat "\n" nnfolder-article-marker))
 188             (cons nnfolder-current-group
 189                   (string-to-int
 190                    (buffer-substring
 191                     (point) (progn (end-of-line) (point)))))))))))
 192
 193 (deffoo nnfolder-request-group (group &optional server dont-check)
 194   (save-excursion
 195     (nnmail-activate 'nnfolder)
 196     (if (not (assoc group nnfolder-group-alist))
 197         (nnheader-report 'nnfolder "No such group: %s" group)
 198       (nnfolder-possibly-change-group group server)
 199       (if dont-check
 200           (progn
 201             (nnheader-report 'nnfolder "Selected group %s" group)
 202             t)
 203         (let* ((active (assoc group nnfolder-group-alist))
 204                (group (car active))
 205                (range (cadr active)))
 206           (cond
 207            ((null active)
 208             (nnheader-report 'nnfolder "No such group: %s" group))
 209            ((null nnfolder-current-group)
 210             (nnheader-report 'nnfolder "Empty group: %s" group))
 211            (t
 212             (nnheader-report 'nnfolder "Selected group %s" group)
 213             (nnheader-insert "211 %d %d %d %s\n"
 214                              (1+ (- (cdr range) (car range)))
 215                              (car range) (cdr range) group))))))))
 216
 217 (deffoo nnfolder-request-scan (&optional group server)
 218   (nnfolder-possibly-change-group group server t)
 219   (nnmail-get-new-mail
 220    'nnfolder
 221    (lambda ()
 222      (let ((bufs nnfolder-buffer-alist))
 223        (save-excursion
 224          (while bufs
 225            (if (not (buffer-name (nth 1 (car bufs))))
 226                (setq nnfolder-buffer-alist
 227                      (delq (car bufs) nnfolder-buffer-alist))
 228              (set-buffer (nth 1 (car bufs)))
 229              (nnfolder-save-buffer)
 230              (kill-buffer (current-buffer)))
 231            (setq bufs (cdr bufs))))))
 232    nnfolder-directory
 233    group))
 234
 235 ;; Don't close the buffer if we're not shutting down the server.  This way,
 236 ;; we can keep the buffer in the group buffer cache, and not have to grovel
 237 ;; over the buffer again unless we add new mail to it or modify it in some
 238 ;; way.
 239
 240 (deffoo nnfolder-close-group (group &optional server force)
 241   ;; Make sure we _had_ the group open.
 242   (when (or (assoc group nnfolder-buffer-alist)
 243             (equal group nnfolder-current-group))
 244     (let ((inf (assoc group nnfolder-buffer-alist)))
 245       (when inf
 246         (when nnfolder-current-group
 247           (push (list nnfolder-current-group nnfolder-current-buffer)
 248                 nnfolder-buffer-alist))
 249         (setq nnfolder-buffer-alist
 250               (delq inf nnfolder-buffer-alist))
 251         (setq nnfolder-current-buffer (cadr inf)
 252               nnfolder-current-group (car inf))))
 253     (when (and nnfolder-current-buffer
 254                (buffer-name nnfolder-current-buffer))
 255       (save-excursion
 256         (set-buffer nnfolder-current-buffer)
 257         ;; If the buffer was modified, write the file out now.
 258         (nnfolder-save-buffer)
 259         ;; If we're shutting the server down, we need to kill the
 260         ;; buffer and remove it from the open buffer list.  Or, of
 261         ;; course, if we're trying to minimize our space impact.
 262         (kill-buffer (current-buffer))
 263         (setq nnfolder-buffer-alist (delq (assoc group nnfolder-buffer-alist)
 264                                           nnfolder-buffer-alist)))))
 265   (setq nnfolder-current-group nil
 266         nnfolder-current-buffer nil)
 267   t)
 268
 269 (deffoo nnfolder-request-create-group (group &optional server args)
 270   (nnfolder-possibly-change-group nil server)
 271   (nnmail-activate 'nnfolder)
 272   (when group
 273     (unless (assoc group nnfolder-group-alist)
 274       (push (list group (cons 1 0)) nnfolder-group-alist)
 275       (nnmail-save-active nnfolder-group-alist nnfolder-active-file)))
 276   t)
 277
 278 (deffoo nnfolder-request-list (&optional server)
 279   (nnfolder-possibly-change-group nil server)
 280   (save-excursion
 281     (nnmail-find-file nnfolder-active-file)
 282     (setq nnfolder-group-alist (nnmail-get-active))
 283     t))
 284
 285 (deffoo nnfolder-request-newgroups (date &optional server)
 286   (nnfolder-possibly-change-group nil server)
 287   (nnfolder-request-list server))
 288
 289 (deffoo nnfolder-request-list-newsgroups (&optional server)
 290   (nnfolder-possibly-change-group nil server)
 291   (save-excursion
 292     (nnmail-find-file nnfolder-newsgroups-file)))
 293
 294 (deffoo nnfolder-request-expire-articles
 295   (articles newsgroup &optional server force)
 296   (nnfolder-possibly-change-group newsgroup server)
 297   (let* ((is-old t)
 298          rest)
 299     (nnmail-activate 'nnfolder)
 300
 301     (save-excursion
 302       (set-buffer nnfolder-current-buffer)
 303       (while (and articles is-old)
 304         (goto-char (point-min))
 305         (when (search-forward (nnfolder-article-string (car articles)) nil t)
 306           (if (setq is-old
 307                     (nnmail-expired-article-p
 308                      newsgroup
 309                      (buffer-substring
 310                       (point) (progn (end-of-line) (point)))
 311                      force nnfolder-inhibit-expiry))
 312               (progn
 313                 (nnheader-message 5 "Deleting article %d..."
 314                                   (car articles) newsgroup)
 315                 (nnfolder-delete-mail))
 316             (push (car articles) rest)))
 317         (setq articles (cdr articles)))
 318       (unless nnfolder-inhibit-expiry
 319         (nnheader-message 5 "Deleting articles...done"))
 320       (nnfolder-save-buffer)
 321       ;; Find the lowest active article in this group.
 322       (let* ((active (cadr (assoc newsgroup nnfolder-group-alist)))
 323              (marker (concat "\n" nnfolder-article-marker))
 324              (number "[0-9]+")
 325              (activemin (cdr active)))
 326         (goto-char (point-min))
 327         (while (and (search-forward marker nil t)
 328                     (re-search-forward number nil t))
 329           (setq activemin (min activemin
 330                                (string-to-number (buffer-substring
 331                                                   (match-beginning 0)
 332                                                   (match-end 0))))))
 333         (setcar active activemin))
 334       (nnmail-save-active nnfolder-group-alist nnfolder-active-file)
 335       (nconc rest articles))))
 336
 337 (deffoo nnfolder-request-move-article
 338   (article group server accept-form &optional last)
 339   (let ((buf (get-buffer-create " *nnfolder move*"))
 340         result)
 341     (and
 342      (nnfolder-request-article article group server)
 343      (save-excursion
 344        (set-buffer buf)
 345        (buffer-disable-undo (current-buffer))
 346        (erase-buffer)
 347        (insert-buffer-substring nntp-server-buffer)
 348        (goto-char (point-min))
 349        (while (re-search-forward
 350                (concat "^" nnfolder-article-marker)
 351                (save-excursion (search-forward "\n\n" nil t) (point)) t)
 352          (delete-region (progn (beginning-of-line) (point))
 353                         (progn (forward-line 1) (point))))
 354        (setq result (eval accept-form))
 355        (kill-buffer buf)
 356        result)
 357      (save-excursion
 358        (nnfolder-possibly-change-group group server)
 359        (set-buffer nnfolder-current-buffer)
 360        (goto-char (point-min))
 361        (when (search-forward (nnfolder-article-string article) nil t)
 362          (nnfolder-delete-mail))
 363        (and last (nnfolder-save-buffer))))
 364     result))
 365
 366 (deffoo nnfolder-request-accept-article (group &optional server last)
 367   (nnfolder-possibly-change-group group server)
 368   (nnmail-check-syntax)
 369   (let ((buf (current-buffer))
 370         result)
 371     (goto-char (point-min))
 372     (when (looking-at "X-From-Line: ")
 373       (replace-match "From "))
 374     (and
 375      (nnfolder-request-list)
 376      (save-excursion
 377        (set-buffer buf)
 378        (goto-char (point-min))
 379        (search-forward "\n\n" nil t)
 380        (forward-line -1)
 381        (while (re-search-backward (concat "^" nnfolder-article-marker) nil t)
 382          (delete-region (point) (progn (forward-line 1) (point))))
 383        (setq result
 384              (car (nnfolder-save-mail
 385                    (if (stringp group)
 386                        (list (cons group (nnfolder-active-number group)))
 387                      (nnmail-article-group 'nnfolder-active-number))))))
 388      (save-excursion
 389        (set-buffer nnfolder-current-buffer)
 390        (and last (nnfolder-save-buffer))))
 391     (nnmail-save-active nnfolder-group-alist nnfolder-active-file)
 392     (unless result
 393       (nnheader-report 'nnfolder "Couldn't store article"))
 394     result))
 395
 396 (deffoo nnfolder-request-replace-article (article group buffer)
 397   (nnfolder-possibly-change-group group)
 398   (save-excursion
 399     (set-buffer nnfolder-current-buffer)
 400     (goto-char (point-min))
 401     (if (not (search-forward (nnfolder-article-string article) nil t))
 402         nil
 403       (nnfolder-delete-mail t t)
 404       (insert-buffer-substring buffer)
 405       (nnfolder-save-buffer)
 406       t)))
 407
 408 (deffoo nnfolder-request-delete-group (group &optional force server)
 409   (nnfolder-close-group group server t)
 410   ;; Delete all articles in GROUP.
 411   (if (not force)
 412       ()                                ; Don't delete the articles.
 413     ;; Delete the file that holds the group.
 414     (ignore-errors
 415       (delete-file (nnfolder-group-pathname group))))
 416   ;; Remove the group from all structures.
 417   (setq nnfolder-group-alist
 418         (delq (assoc group nnfolder-group-alist) nnfolder-group-alist)
 419         nnfolder-current-group nil
 420         nnfolder-current-buffer nil)
 421   ;; Save the active file.
 422   (nnmail-save-active nnfolder-group-alist nnfolder-active-file)
 423   t)
 424
 425 (deffoo nnfolder-request-rename-group (group new-name &optional server)
 426   (nnfolder-possibly-change-group group server)
 427   (save-excursion
 428     (set-buffer nnfolder-current-buffer)
 429     (and (file-writable-p buffer-file-name)
 430          (ignore-errors
 431            (rename-file
 432             buffer-file-name
 433             (nnfolder-group-pathname new-name))
 434            t)
 435          ;; That went ok, so we change the internal structures.
 436          (let ((entry (assoc group nnfolder-group-alist)))
 437            (and entry (setcar entry new-name))
 438            (setq nnfolder-current-buffer nil
 439                  nnfolder-current-group nil)
 440            ;; Save the new group alist.
 441            (nnmail-save-active nnfolder-group-alist nnfolder-active-file)
 442            ;; We kill the buffer instead of renaming it and stuff.
 443            (kill-buffer (current-buffer))
 444            t))))
 445
 446 \f
 447 ;;; Internal functions.
 448
 449 (defun nnfolder-article-string (article)
 450   (if (numberp article)
 451       (concat "\n" nnfolder-article-marker (int-to-string article) " ")
 452     (concat "\nMessage-ID: " article)))
 453
 454 (defun nnfolder-delete-mail (&optional force leave-delim)
 455   "Delete the message that point is in."
 456   (save-excursion
 457     (delete-region
 458      (save-excursion
 459        (nnmail-search-unix-mail-delim-backward)
 460        (if leave-delim (progn (forward-line 1) (point))
 461          (point)))
 462      (progn
 463        (forward-line 1)
 464        (if (nnmail-search-unix-mail-delim)
 465            (if (and (not (bobp)) leave-delim)
 466                (progn (forward-line -2) (point))
 467              (point))
 468          (point-max))))))
 469
 470 ;; When scanning, we're not looking t immediately switch into the group - if
 471 ;; we know our information is up to date, don't even bother reading the file.
 472 (defun nnfolder-possibly-change-group (group &optional server scanning)
 473   (when (and server
 474              (not (nnfolder-server-opened server)))
 475     (nnfolder-open-server server))
 476   (when (and group (or nnfolder-current-buffer
 477                        (not (equal group nnfolder-current-group))))
 478     (gnus-make-directory (directory-file-name nnfolder-directory))
 479     (nnfolder-possibly-activate-groups nil)
 480     (or (assoc group nnfolder-group-alist)
 481         (not (file-exists-p
 482               (nnfolder-group-pathname group)))
 483         (progn
 484           (push (list group (cons 1 0)) nnfolder-group-alist)
 485           (nnmail-save-active nnfolder-group-alist nnfolder-active-file)))
 486     (let (inf file)
 487       (if (and (equal group nnfolder-current-group)
 488                nnfolder-current-buffer
 489                (buffer-name nnfolder-current-buffer))
 490           ()
 491         (setq nnfolder-current-group group)
 492
 493         ;; If we have to change groups, see if we don't already have the mbox
 494         ;; in memory.  If we do, verify the modtime and destroy the mbox if
 495         ;; needed so we can rescan it.
 496         (when (setq inf (assoc group nnfolder-buffer-alist))
 497           (setq nnfolder-current-buffer (nth 1 inf)))
 498
 499         ;; If the buffer is not live, make sure it isn't in the alist.  If it
 500         ;; is live, verify that nobody else has touched the file since last
 501         ;; time.
 502         (when (or (not (and nnfolder-current-buffer
 503                             (buffer-name nnfolder-current-buffer)))
 504                   (not (and (bufferp nnfolder-current-buffer)
 505                             (verify-visited-file-modtime
 506                              nnfolder-current-buffer))))
 507           (when (and nnfolder-current-buffer
 508                      (buffer-name nnfolder-current-buffer)
 509                      (bufferp nnfolder-current-buffer))
 510             (kill-buffer nnfolder-current-buffer))
 511           (setq nnfolder-buffer-alist (delq inf nnfolder-buffer-alist))
 512           (setq inf nil))
 513
 514         (unless inf
 515           (save-excursion
 516             (setq file (nnfolder-group-pathname group))
 517             (unless (file-directory-p (file-truename file))
 518               (unless (file-exists-p file)
 519                 (gnus-make-directory (file-name-directory file))
 520                 (nnmail-write-region 1 1 file t 'nomesg))
 521               (setq nnfolder-current-group group)
 522               (setq nnfolder-current-buffer
 523                     (nnfolder-read-folder file scanning))
 524               (when nnfolder-current-buffer
 525                 (set-buffer nnfolder-current-buffer)
 526                 (push (list group nnfolder-current-buffer)
 527                       nnfolder-buffer-alist)))))))
 528     (setq nnfolder-current-group group)))
 529
 530 (defun nnfolder-save-mail (group-art-list)
 531   "Called narrowed to an article."
 532   (let* (save-list group-art)
 533     (goto-char (point-min))
 534     ;; The From line may have been quoted by movemail.
 535     (when (looking-at (concat ">" message-unix-mail-delimiter))
 536       (delete-char 1))
 537     ;; This might come from somewhere else.
 538     (unless (looking-at message-unix-mail-delimiter)
 539       (insert "From nobody " (current-time-string) "\n")
 540       (goto-char (point-min)))
 541     ;; Quote all "From " lines in the article.
 542     (forward-line 1)
 543     (while (re-search-forward "^From " nil t)
 544       (beginning-of-line)
 545       (insert "> "))
 546     (setq save-list group-art-list)
 547     (nnmail-insert-lines)
 548     (nnmail-insert-xref group-art-list)
 549     (run-hooks 'nnmail-prepare-save-mail-hook)
 550     (run-hooks 'nnfolder-prepare-save-mail-hook)
 551
 552     ;; Insert the mail into each of the destination groups.
 553     (while group-art-list
 554       (setq group-art (car group-art-list)
 555             group-art-list (cdr group-art-list))
 556
 557       ;; Kill the previous newsgroup markers.
 558       (goto-char (point-min))
 559       (search-forward "\n\n" nil t)
 560       (forward-line -1)
 561       (while (search-backward (concat "\n" nnfolder-article-marker) nil t)
 562         (delete-region (1+ (point)) (progn (forward-line 2) (point))))
 563
 564       (nnfolder-possibly-change-group (car group-art))
 565       ;; Insert the new newsgroup marker.
 566       (nnfolder-insert-newsgroup-line group-art)
 567       (unless nnfolder-current-buffer
 568         (nnfolder-close-group (car group-art))
 569         (nnfolder-request-create-group (car group-art))
 570         (nnfolder-possibly-change-group (car group-art)))
 571       (let ((beg (point-min))
 572             (end (point-max))
 573             (obuf (current-buffer)))
 574         (set-buffer nnfolder-current-buffer)
 575         (goto-char (point-max))
 576         (unless (eolp)
 577           (insert "\n"))
 578         (unless (bobp)
 579           (insert "\n"))
 580         (insert-buffer-substring obuf beg end)
 581         (set-buffer obuf)))
 582
 583     ;; Did we save it anywhere?
 584     save-list))
 585
 586 (defun nnfolder-insert-newsgroup-line (group-art)
 587   (save-excursion
 588     (goto-char (point-min))
 589     (when (search-forward "\n\n" nil t)
 590       (forward-char -1)
 591       (insert (format (concat nnfolder-article-marker "%d   %s\n")
 592                       (cdr group-art) (current-time-string))))))
 593
 594 (defun nnfolder-possibly-activate-groups (&optional group)
 595   (save-excursion
 596     ;; If we're looking for the activation of a specific group, find out
 597     ;; its real name and switch to it.
 598     (when group
 599       (nnfolder-possibly-change-group group))
 600     ;; If the group alist isn't active, activate it now.
 601     (nnmail-activate 'nnfolder)))
 602
 603 (defun nnfolder-active-number (group)
 604   ;; Find the next article number in GROUP.
 605   (let ((active (cadr (assoc group nnfolder-group-alist))))
 606     (if active
 607         (setcdr active (1+ (cdr active)))
 608       ;; This group is new, so we create a new entry for it.
 609       ;; This might be a bit naughty... creating groups on the drop of
 610       ;; a hat, but I don't know...
 611       (push (list group (setq active (cons 1 1)))
 612             nnfolder-group-alist))
 613     (cdr active)))
 614
 615
 616 ;; This method has a problem if you've accidentally let the active list get
 617 ;; out of sync with the files.  This could happen, say, if you've
 618 ;; accidentally gotten new mail with something other than Gnus (but why
 619 ;; would _that_ ever happen? :-).  In that case, we will be in the middle of
 620 ;; processing the file, ready to add new X-Gnus article number markers, and
 621 ;; we'll run across a message with no ID yet - the active list _may_not_ be
 622 ;; ready for us yet.
 623
 624 ;; To handle this, I'm modifying this routine to maintain the maximum ID seen
 625 ;; so far, and when we hit a message with no ID, we will _manually_ scan the
 626 ;; rest of the message looking for any more, possibly higher IDs.  We'll
 627 ;; assume the maximum that we find is the highest active.  Note that this
 628 ;; shouldn't cost us much extra time at all, but will be a lot less
 629 ;; vulnerable to glitches between the mbox and the active file.
 630
 631 (defun nnfolder-read-folder (file &optional scanning)
 632   ;; This is an attempt at a serious shortcut - don't even read in the file
 633   ;; if we know we've seen it since the last time it was touched.
 634   (let ((scantime (cadr (assoc nnfolder-current-group
 635                                nnfolder-scantime-alist)))
 636         (modtime (nth 5 (file-attributes file))))
 637     (if (and scanning scantime
 638              (eq (car scantime) (car modtime))
 639              (eq (cdr scantime) (cadr modtime)))
 640         nil
 641       (save-excursion
 642         (nnfolder-possibly-activate-groups nil)
 643         ;; Read in the file.
 644         (set-buffer (setq nnfolder-current-buffer
 645                           (nnheader-find-file-noselect file)))
 646         (buffer-disable-undo (current-buffer))
 647         (setq buffer-read-only nil)
 648         ;; If the file hasn't been touched since the last time we scanned it,
 649         ;; don't bother doing anything with it.
 650         (let ((delim (concat "^" message-unix-mail-delimiter))
 651               (marker (concat "\n" nnfolder-article-marker))
 652               (number "[0-9]+")
 653               (active (or (cadr (assoc nnfolder-current-group
 654                                        nnfolder-group-alist))
 655                           (cons 1 0)))
 656               (scantime (assoc nnfolder-current-group nnfolder-scantime-alist))
 657               (minid (lsh -1 -1))
 658               maxid start end newscantime)
 659
 660           (setq maxid (or (cdr active) 0))
 661           (goto-char (point-min))
 662
 663           ;; Anytime the active number is 1 or 0, it is suspect.  In that
 664           ;; case, search the file manually to find the active number.  Or,
 665           ;; of course, if we're being paranoid.  (This would also be the
 666           ;; place to build other lists from the header markers, such as
 667           ;; expunge lists, etc., if we ever desired to abandon the active
 668           ;; file entirely for mboxes.)
 669           (when (or nnfolder-ignore-active-file
 670                     (< maxid 2))
 671             (while (and (search-forward marker nil t)
 672                         (re-search-forward number nil t))
 673               (let ((newnum (string-to-number (match-string 0))))
 674                 (setq maxid (max maxid newnum))
 675                 (setq minid (min minid newnum))))
 676             (setcar active (max 1 (min minid maxid)))
 677             (setcdr active (max maxid (cdr active)))
 678             (goto-char (point-min)))
 679
 680           ;; As long as we trust that the user will only insert unmarked mail
 681           ;; at the end, go to the end and search backwards for the last
 682           ;; marker.  Find the start of that message, and begin to search for
 683           ;; unmarked messages from there.
 684           (when (not (or nnfolder-distrust-mbox
 685                          (< maxid 2)))
 686             (goto-char (point-max))
 687             (if (not (re-search-backward marker nil t))
 688                 (goto-char (point-min))
 689               (when (not (nnmail-search-unix-mail-delim))
 690                 (goto-char (point-min)))))
 691
 692           ;; Keep track of the active number on our own, and insert it back
 693           ;; into the active list when we're done.  Also, prime the pump to
 694           ;; cut down on the number of searches we do.
 695           (setq end (point-marker))
 696           (set-marker end (or (and (nnmail-search-unix-mail-delim)
 697                                    (point))
 698                               (point-max)))
 699           (while (not (= end (point-max)))
 700             (setq start (marker-position end))
 701             (goto-char end)
 702             ;; There may be more than one "From " line, so we skip past
 703             ;; them.
 704             (while (looking-at delim)
 705               (forward-line 1))
 706             (set-marker end (or (and (nnmail-search-unix-mail-delim)
 707                                      (point))
 708                                 (point-max)))
 709             (goto-char start)
 710             (when (not (search-forward marker end t))
 711               (narrow-to-region start end)
 712               (nnmail-insert-lines)
 713               (nnfolder-insert-newsgroup-line
 714                (cons nil (nnfolder-active-number nnfolder-current-group)))
 715               (widen)))
 716
 717           ;; Make absolutely sure that the active list reflects reality!
 718           (nnmail-save-active nnfolder-group-alist nnfolder-active-file)
 719           ;; Set the scantime for this group.
 720           (setq newscantime (visited-file-modtime))
 721           (if scantime
 722               (setcdr scantime (list newscantime))
 723             (push (list nnfolder-current-group newscantime)
 724                   nnfolder-scantime-alist))
 725           (current-buffer))))))
 726
 727 ;;;###autoload
 728 (defun nnfolder-generate-active-file ()
 729   "Look for mbox folders in the nnfolder directory and make them into groups."
 730   (interactive)
 731   (nnmail-activate 'nnfolder)
 732   (let ((files (directory-files nnfolder-directory))
 733         file)
 734     (while (setq file (pop files))
 735       (when (and (not (backup-file-name-p file))
 736                  (nnheader-mail-file-mbox-p
 737                   (concat nnfolder-directory file)))
 738         (nnheader-message 5 "Adding group %s..." file)
 739         (push (list file (cons 1 0)) nnfolder-group-alist)
 740         (nnfolder-possibly-change-group file)
 741         (nnfolder-close-group file))
 742       (message ""))))
 743
 744 (defun nnfolder-group-pathname (group)
 745   "Make pathname for GROUP."
 746   (let ((dir (file-name-as-directory (expand-file-name nnfolder-directory))))
 747     ;; If this file exists, we use it directly.
 748     (if (or nnmail-use-long-file-names
 749             (file-exists-p (concat dir group)))
 750         (concat dir group)
 751       ;; If not, we translate dots into slashes.
 752       (concat dir (nnheader-replace-chars-in-string group ?. ?/)))))
 753
 754 (defun nnfolder-save-buffer ()
 755   "Save the buffer."
 756   (when (buffer-modified-p)
 757     (run-hooks 'nnfolder-save-buffer-hook)
 758     (save-buffer)))
 759
 760 (provide 'nnfolder)
 761
 762 ;;; nnfolder.el ends here