cgit.sxemacs.org Git - gnus/blob - lisp/nnfolder.el

   1 ;;; nnfolder.el --- mail folder access for Gnus
   2 ;; Copyright (C) 1995,96 Free Software Foundation, Inc.
   3
   4 ;; Author: Scott Byer <byer@mv.us.adobe.com>
   5 ;;      Lars Magne Ingebrigtsen <larsi@ifi.uio.no>
   6 ;;      Masanobu UMEDA <umerin@flab.flab.fujitsu.junet>
   7 ;; Keywords: mail
   8
   9 ;; This file is part of GNU Emacs.
  10
  11 ;; GNU Emacs is free software; you can redistribute it and/or modify
  12 ;; it under the terms of the GNU General Public License as published by
  13 ;; the Free Software Foundation; either version 2, or (at your option)
  14 ;; any later version.
  15
  16 ;; GNU Emacs is distributed in the hope that it will be useful,
  17 ;; but WITHOUT ANY WARRANTY; without even the implied warranty of
  18 ;; MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.  See the
  19 ;; GNU General Public License for more details.
  20
  21 ;; You should have received a copy of the GNU General Public License
  22 ;; along with GNU Emacs; see the file COPYING.  If not, write to the
  23 ;; Free Software Foundation, Inc., 59 Temple Place - Suite 330,
  24 ;; Boston, MA 02111-1307, USA.
  25
  26 ;;; Commentary:
  27
  28 ;; For an overview of what the interface functions do, please see the
  29 ;; Gnus sources.
  30
  31 ;; Various enhancements by byer@mv.us.adobe.com (Scott Byer).
  32
  33 ;;; Code:
  34
  35 (require 'nnheader)
  36 (require 'message)
  37 (require 'nnmail)
  38 (require 'nnoo)
  39 (eval-when-compile (require 'cl))
  40
  41 (nnoo-declare nnfolder)
  42
  43 (defvoo nnfolder-directory (expand-file-name message-directory)
  44   "The name of the nnfolder directory.")
  45
  46 (defvoo nnfolder-active-file
  47   (nnheader-concat nnfolder-directory "active")
  48   "The name of the active file.")
  49
  50 ;; I renamed this variable to something more in keeping with the general GNU
  51 ;; style. -SLB
  52
  53 (defvoo nnfolder-ignore-active-file nil
  54   "If non-nil, causes nnfolder to do some extra work in order to determine
  55 the true active ranges of an mbox file.  Note that the active file is still
  56 saved, but it's values are not used.  This costs some extra time when
  57 scanning an mbox when opening it.")
  58
  59 (defvoo nnfolder-distrust-mbox nil
  60   "If non-nil, causes nnfolder to not trust the user with respect to
  61 inserting unaccounted for mail in the middle of an mbox file.  This can greatly
  62 slow down scans, which now must scan the entire file for unmarked messages.
  63 When nil, scans occur forward from the last marked message, a huge
  64 time saver for large mailboxes.")
  65
  66 (defvoo nnfolder-newsgroups-file
  67   (concat (file-name-as-directory nnfolder-directory) "newsgroups")
  68   "Mail newsgroups description file.")
  69
  70 (defvoo nnfolder-get-new-mail t
  71   "If non-nil, nnfolder will check the incoming mail file and split the mail.")
  72
  73 (defvoo nnfolder-prepare-save-mail-hook nil
  74   "Hook run narrowed to an article before saving.")
  75
  76 (defvoo nnfolder-save-buffer-hook nil
  77   "Hook run before saving the nnfolder mbox buffer.")
  78
  79 (defvoo nnfolder-inhibit-expiry nil
  80   "If non-nil, inhibit expiry.")
  81
  82 \f
  83
  84 (defconst nnfolder-version "nnfolder 1.0"
  85   "nnfolder version.")
  86
  87 (defconst nnfolder-article-marker "X-Gnus-Article-Number: "
  88   "String used to demarcate what the article number for a message is.")
  89
  90 (defvoo nnfolder-current-group nil)
  91 (defvoo nnfolder-current-buffer nil)
  92 (defvoo nnfolder-status-string "")
  93 (defvoo nnfolder-group-alist nil)
  94 (defvoo nnfolder-buffer-alist nil)
  95 (defvoo nnfolder-scantime-alist nil)
  96
  97 \f
  98
  99 ;;; Interface functions
 100
 101 (nnoo-define-basics nnfolder)
 102
 103 (deffoo nnfolder-retrieve-headers (articles &optional group server fetch-old)
 104   (save-excursion
 105     (set-buffer nntp-server-buffer)
 106     (erase-buffer)
 107     (let ((delim-string (concat "^" message-unix-mail-delimiter))
 108           article art-string start stop)
 109       (nnfolder-possibly-change-group group server)
 110       (when nnfolder-current-buffer
 111         (set-buffer nnfolder-current-buffer)
 112         (goto-char (point-min))
 113         (if (stringp (car articles))
 114             'headers
 115           (while articles
 116             (setq article (car articles))
 117             (setq art-string (nnfolder-article-string article))
 118             (set-buffer nnfolder-current-buffer)
 119             (when (or (search-forward art-string nil t)
 120                       ;; Don't search the whole file twice!  Also, articles
 121                       ;; probably have some locality by number, so searching
 122                       ;; backwards will be faster.  Especially if we're at the
 123                       ;; beginning of the buffer :-). -SLB
 124                       (search-backward art-string nil t))
 125               (setq start (or (re-search-backward delim-string nil t)
 126                               (point)))
 127               (search-forward "\n\n" nil t)
 128               (setq stop (1- (point)))
 129               (set-buffer nntp-server-buffer)
 130               (insert (format "221 %d Article retrieved.\n" article))
 131               (insert-buffer-substring nnfolder-current-buffer start stop)
 132               (goto-char (point-max))
 133               (insert ".\n"))
 134             (setq articles (cdr articles)))
 135
 136           (set-buffer nntp-server-buffer)
 137           (nnheader-fold-continuation-lines)
 138           'headers)))))
 139
 140 (deffoo nnfolder-open-server (server &optional defs)
 141   (nnoo-change-server 'nnfolder server defs)
 142   (when (not (file-exists-p nnfolder-directory))
 143     (condition-case ()
 144         (gnus-make-directory nnfolder-directory)
 145       (error t)))
 146   (cond
 147    ((not (file-exists-p nnfolder-directory))
 148     (nnfolder-close-server)
 149     (nnheader-report 'nnfolder "Couldn't create directory: %s"
 150                      nnfolder-directory))
 151    ((not (file-directory-p (file-truename nnfolder-directory)))
 152     (nnfolder-close-server)
 153     (nnheader-report 'nnfolder "Not a directory: %s" nnfolder-directory))
 154    (t
 155     (nnheader-report 'nnfolder "Opened server %s using directory %s"
 156                      server nnfolder-directory)
 157     t)))
 158
 159 (deffoo nnfolder-request-close ()
 160   (let ((alist nnfolder-buffer-alist))
 161     (while alist
 162       (nnfolder-close-group (caar alist) nil t)
 163       (setq alist (cdr alist))))
 164   (nnoo-close-server 'nnfolder)
 165   (setq nnfolder-buffer-alist nil
 166         nnfolder-group-alist nil))
 167
 168 (deffoo nnfolder-request-article (article &optional group server buffer)
 169   (nnfolder-possibly-change-group group server)
 170   (save-excursion
 171     (set-buffer nnfolder-current-buffer)
 172     (goto-char (point-min))
 173     (when (search-forward (nnfolder-article-string article) nil t)
 174       (let (start stop)
 175         (re-search-backward (concat "^" message-unix-mail-delimiter) nil t)
 176         (setq start (point))
 177         (forward-line 1)
 178         (unless (and (re-search-forward
 179                       (concat "^" message-unix-mail-delimiter) nil t)
 180                      (forward-line -1))
 181           (goto-char (point-max)))
 182         (setq stop (point))
 183         (let ((nntp-server-buffer (or buffer nntp-server-buffer)))
 184           (set-buffer nntp-server-buffer)
 185           (erase-buffer)
 186           (insert-buffer-substring nnfolder-current-buffer start stop)
 187           (goto-char (point-min))
 188           (while (looking-at "From ")
 189             (delete-char 5)
 190             (insert "X-From-Line: ")
 191             (forward-line 1))
 192           (if (numberp article)
 193               (cons nnfolder-current-group article)
 194             (goto-char (point-min))
 195             (search-forward (concat "\n" nnfolder-article-marker))
 196             (cons nnfolder-current-group
 197                   (string-to-int
 198                    (buffer-substring
 199                     (point) (progn (end-of-line) (point)))))))))))
 200
 201 (deffoo nnfolder-request-group (group &optional server dont-check)
 202   (save-excursion
 203     (nnmail-activate 'nnfolder)
 204     (if (not (assoc group nnfolder-group-alist))
 205         (nnheader-report 'nnfolder "No such group: %s" group)
 206       (nnfolder-possibly-change-group group server)
 207       (if dont-check
 208           (progn
 209             (nnheader-report 'nnfolder "Selected group %s" group)
 210             t)
 211         (let* ((active (assoc group nnfolder-group-alist))
 212                (group (car active))
 213                (range (cadr active)))
 214           (cond
 215            ((null active)
 216             (nnheader-report 'nnfolder "No such group: %s" group))
 217            ((null nnfolder-current-group)
 218             (nnheader-report 'nnfolder "Empty group: %s" group))
 219            (t
 220             (nnheader-report 'nnfolder "Selected group %s" group)
 221             (nnheader-insert "211 %d %d %d %s\n"
 222                              (1+ (- (cdr range) (car range)))
 223                              (car range) (cdr range) group))))))))
 224
 225 (deffoo nnfolder-request-scan (&optional group server)
 226   (nnfolder-possibly-change-group group server t)
 227   (nnmail-get-new-mail
 228    'nnfolder
 229    (lambda ()
 230      (let ((bufs nnfolder-buffer-alist))
 231        (save-excursion
 232          (while bufs
 233            (if (not (buffer-name (nth 1 (car bufs))))
 234                (setq nnfolder-buffer-alist
 235                      (delq (car bufs) nnfolder-buffer-alist))
 236              (set-buffer (nth 1 (car bufs)))
 237              (nnfolder-save-buffer)
 238              (kill-buffer (current-buffer)))
 239            (setq bufs (cdr bufs))))))
 240    nnfolder-directory
 241    group))
 242
 243 ;; Don't close the buffer if we're not shutting down the server.  This way,
 244 ;; we can keep the buffer in the group buffer cache, and not have to grovel
 245 ;; over the buffer again unless we add new mail to it or modify it in some
 246 ;; way.
 247
 248 (deffoo nnfolder-close-group (group &optional server force)
 249   ;; Make sure we _had_ the group open.
 250   (when (or (assoc group nnfolder-buffer-alist)
 251             (equal group nnfolder-current-group))
 252     (let ((inf (assoc group nnfolder-buffer-alist)))
 253       (when inf
 254         (when nnfolder-current-group
 255           (push (list nnfolder-current-group nnfolder-current-buffer)
 256                 nnfolder-buffer-alist))
 257         (setq nnfolder-buffer-alist
 258               (delq inf nnfolder-buffer-alist))
 259         (setq nnfolder-current-buffer (cadr inf)
 260               nnfolder-current-group (car inf))))
 261     (when (and nnfolder-current-buffer
 262                (buffer-name nnfolder-current-buffer))
 263       (save-excursion
 264         (set-buffer nnfolder-current-buffer)
 265         ;; If the buffer was modified, write the file out now.
 266         (nnfolder-save-buffer)
 267         ;; If we're shutting the server down, we need to kill the
 268         ;; buffer and remove it from the open buffer list.  Or, of
 269         ;; course, if we're trying to minimize our space impact.
 270         (kill-buffer (current-buffer))
 271         (setq nnfolder-buffer-alist (delq (assoc group nnfolder-buffer-alist)
 272                                           nnfolder-buffer-alist)))))
 273   (setq nnfolder-current-group nil
 274         nnfolder-current-buffer nil)
 275   t)
 276
 277 (deffoo nnfolder-request-create-group (group &optional server args)
 278   (nnfolder-possibly-change-group nil server)
 279   (nnmail-activate 'nnfolder)
 280   (when group
 281     (unless (assoc group nnfolder-group-alist)
 282       (push (list group (cons 1 0)) nnfolder-group-alist)
 283       (nnmail-save-active nnfolder-group-alist nnfolder-active-file)))
 284   t)
 285
 286 (deffoo nnfolder-request-list (&optional server)
 287   (nnfolder-possibly-change-group nil server)
 288   (save-excursion
 289     (nnmail-find-file nnfolder-active-file)
 290     (setq nnfolder-group-alist (nnmail-get-active))))
 291
 292 (deffoo nnfolder-request-newgroups (date &optional server)
 293   (nnfolder-possibly-change-group nil server)
 294   (nnfolder-request-list server))
 295
 296 (deffoo nnfolder-request-list-newsgroups (&optional server)
 297   (nnfolder-possibly-change-group nil server)
 298   (save-excursion
 299     (nnmail-find-file nnfolder-newsgroups-file)))
 300
 301 (deffoo nnfolder-request-expire-articles
 302   (articles newsgroup &optional server force)
 303   (nnfolder-possibly-change-group newsgroup server)
 304   (let* ((is-old t)
 305          rest)
 306     (nnmail-activate 'nnfolder)
 307
 308     (save-excursion
 309       (set-buffer nnfolder-current-buffer)
 310       (while (and articles is-old)
 311         (goto-char (point-min))
 312         (when (search-forward (nnfolder-article-string (car articles)) nil t)
 313           (if (setq is-old
 314                     (nnmail-expired-article-p
 315                      newsgroup
 316                      (buffer-substring
 317                       (point) (progn (end-of-line) (point)))
 318                      force nnfolder-inhibit-expiry))
 319               (progn
 320                 (nnheader-message 5 "Deleting article %d..."
 321                                   (car articles) newsgroup)
 322                 (nnfolder-delete-mail))
 323             (push (car articles) rest)))
 324         (setq articles (cdr articles)))
 325       (nnfolder-save-buffer)
 326       ;; Find the lowest active article in this group.
 327       (let* ((active (cadr (assoc newsgroup nnfolder-group-alist)))
 328              (marker (concat "\n" nnfolder-article-marker))
 329              (number "[0-9]+")
 330              (activemin (cdr active)))
 331         (goto-char (point-min))
 332         (while (and (search-forward marker nil t)
 333                     (re-search-forward number nil t))
 334           (setq activemin (min activemin
 335                                (string-to-number (buffer-substring
 336                                                   (match-beginning 0)
 337                                                   (match-end 0))))))
 338         (setcar active activemin))
 339       (nnmail-save-active nnfolder-group-alist nnfolder-active-file)
 340       (nconc rest articles))))
 341
 342 (deffoo nnfolder-request-move-article
 343   (article group server accept-form &optional last)
 344   (let ((buf (get-buffer-create " *nnfolder move*"))
 345         result)
 346     (and
 347      (nnfolder-request-article article group server)
 348      (save-excursion
 349        (set-buffer buf)
 350        (buffer-disable-undo (current-buffer))
 351        (erase-buffer)
 352        (insert-buffer-substring nntp-server-buffer)
 353        (goto-char (point-min))
 354        (while (re-search-forward
 355                (concat "^" nnfolder-article-marker)
 356                (save-excursion (search-forward "\n\n" nil t) (point)) t)
 357          (delete-region (progn (beginning-of-line) (point))
 358                         (progn (forward-line 1) (point))))
 359        (setq result (eval accept-form))
 360        (kill-buffer buf)
 361        result)
 362      (save-excursion
 363        (nnfolder-possibly-change-group group server)
 364        (set-buffer nnfolder-current-buffer)
 365        (goto-char (point-min))
 366        (when (search-forward (nnfolder-article-string article) nil t)
 367          (nnfolder-delete-mail))
 368        (and last (nnfolder-save-buffer))))
 369     result))
 370
 371 (deffoo nnfolder-request-accept-article (group &optional server last)
 372   (nnfolder-possibly-change-group group server)
 373   (nnmail-check-syntax)
 374   (when (stringp group)
 375     (nnfolder-possibly-change-group group))
 376   (let ((buf (current-buffer))
 377         result)
 378     (goto-char (point-min))
 379     (when (looking-at "X-From-Line: ")
 380       (replace-match "From "))
 381     (and
 382      (nnfolder-request-list)
 383      (save-excursion
 384        (set-buffer buf)
 385        (goto-char (point-min))
 386        (search-forward "\n\n" nil t)
 387        (forward-line -1)
 388        (while (re-search-backward (concat "^" nnfolder-article-marker) nil t)
 389          (delete-region (point) (progn (forward-line 1) (point))))
 390        (setq result
 391              (car (nnfolder-save-mail
 392                    (if (stringp group)
 393                        (list (cons group (nnfolder-active-number group)))
 394                      (nnmail-article-group 'nnfolder-active-number))))))
 395      (save-excursion
 396        (set-buffer nnfolder-current-buffer)
 397        (and last (nnfolder-save-buffer))))
 398     (nnmail-save-active nnfolder-group-alist nnfolder-active-file)
 399     (unless result
 400       (nnheader-report 'nnfolder "Couldn't store article"))
 401     result))
 402
 403 (deffoo nnfolder-request-replace-article (article group buffer)
 404   (nnfolder-possibly-change-group group)
 405   (save-excursion
 406     (set-buffer nnfolder-current-buffer)
 407     (goto-char (point-min))
 408     (if (not (search-forward (nnfolder-article-string article) nil t))
 409         nil
 410       (nnfolder-delete-mail t t)
 411       (insert-buffer-substring buffer)
 412       (nnfolder-save-buffer)
 413       t)))
 414
 415 (deffoo nnfolder-request-delete-group (group &optional force server)
 416   (nnfolder-close-group group server t)
 417   ;; Delete all articles in GROUP.
 418   (if (not force)
 419       ()                                ; Don't delete the articles.
 420     ;; Delete the file that holds the group.
 421     (condition-case nil
 422         (delete-file (nnfolder-group-pathname group))
 423       (error nil)))
 424   ;; Remove the group from all structures.
 425   (setq nnfolder-group-alist
 426         (delq (assoc group nnfolder-group-alist) nnfolder-group-alist)
 427         nnfolder-current-group nil
 428         nnfolder-current-buffer nil)
 429   ;; Save the active file.
 430   (nnmail-save-active nnfolder-group-alist nnfolder-active-file)
 431   t)
 432
 433 (deffoo nnfolder-request-rename-group (group new-name &optional server)
 434   (nnfolder-possibly-change-group group server)
 435   (save-excursion
 436     (set-buffer nnfolder-current-buffer)
 437     (and (file-writable-p buffer-file-name)
 438          (condition-case ()
 439              (progn
 440                (rename-file
 441                 buffer-file-name
 442                 (nnfolder-group-pathname new-name))
 443                t)
 444            (error nil))
 445          ;; That went ok, so we change the internal structures.
 446          (let ((entry (assoc group nnfolder-group-alist)))
 447            (and entry (setcar entry new-name))
 448            (setq nnfolder-current-buffer nil
 449                  nnfolder-current-group nil)
 450            ;; Save the new group alist.
 451            (nnmail-save-active nnfolder-group-alist nnfolder-active-file)
 452            ;; We kill the buffer instead of renaming it and stuff.
 453            (kill-buffer (current-buffer))
 454            t))))
 455
 456 \f
 457 ;;; Internal functions.
 458
 459 (defun nnfolder-article-string (article)
 460   (if (numberp article)
 461       (concat "\n" nnfolder-article-marker (int-to-string article) " ")
 462     (concat "\nMessage-ID: " article)))
 463
 464 (defun nnfolder-delete-mail (&optional force leave-delim)
 465   "Delete the message that point is in."
 466   (save-excursion
 467     (delete-region
 468      (save-excursion
 469        (re-search-backward (concat "^" message-unix-mail-delimiter) nil t)
 470        (if leave-delim (progn (forward-line 1) (point))
 471          (match-beginning 0)))
 472      (progn
 473        (forward-line 1)
 474        (if (re-search-forward (concat "^" message-unix-mail-delimiter) nil t)
 475            (if (and (not (bobp)) leave-delim)
 476                (progn (forward-line -2) (point))
 477              (match-beginning 0))
 478          (point-max))))))
 479
 480 ;; When scanning, we're not looking t immediately switch into the group - if
 481 ;; we know our information is up to date, don't even bother reading the file.
 482 (defun nnfolder-possibly-change-group (group &optional server scanning)
 483   (when (and server
 484              (not (nnfolder-server-opened server)))
 485     (nnfolder-open-server server))
 486   (when (and group (or nnfolder-current-buffer
 487                        (not (equal group nnfolder-current-group))))
 488     (gnus-make-directory (directory-file-name nnfolder-directory))
 489     (nnfolder-possibly-activate-groups nil)
 490     (or (assoc group nnfolder-group-alist)
 491         (not (file-exists-p
 492               (nnfolder-group-pathname group)))
 493         (progn
 494           (push (list group (cons 1 0)) nnfolder-group-alist)
 495           (nnmail-save-active nnfolder-group-alist nnfolder-active-file)))
 496     (let (inf file)
 497       (if (and (equal group nnfolder-current-group)
 498                nnfolder-current-buffer
 499                (buffer-name nnfolder-current-buffer))
 500           ()
 501         (setq nnfolder-current-group group)
 502
 503         ;; If we have to change groups, see if we don't already have the mbox
 504         ;; in memory.  If we do, verify the modtime and destroy the mbox if
 505         ;; needed so we can rescan it.
 506         (when (setq inf (assoc group nnfolder-buffer-alist))
 507           (setq nnfolder-current-buffer (nth 1 inf)))
 508
 509         ;; If the buffer is not live, make sure it isn't in the alist.  If it
 510         ;; is live, verify that nobody else has touched the file since last
 511         ;; time.
 512         (when (or (not (and nnfolder-current-buffer
 513                             (buffer-name nnfolder-current-buffer)))
 514                   (not (and (bufferp nnfolder-current-buffer)
 515                             (verify-visited-file-modtime
 516                              nnfolder-current-buffer))))
 517           (when (and nnfolder-current-buffer
 518                      (buffer-name nnfolder-current-buffer)
 519                      (bufferp nnfolder-current-buffer))
 520             (kill-buffer nnfolder-current-buffer))
 521           (setq nnfolder-buffer-alist (delq inf nnfolder-buffer-alist))
 522           (setq inf nil))
 523
 524         (unless inf
 525           (save-excursion
 526             (setq file (nnfolder-group-pathname group))
 527             (unless (file-directory-p (file-truename file))
 528               (unless (file-exists-p file)
 529                 (gnus-make-directory (file-name-directory file))
 530                 (nnmail-write-region 1 1 file t 'nomesg))
 531               (setq nnfolder-current-buffer
 532                     (nnfolder-read-folder file scanning))
 533               (when nnfolder-current-buffer
 534                 (set-buffer nnfolder-current-buffer)
 535                 (push (list group nnfolder-current-buffer)
 536                       nnfolder-buffer-alist)))))))
 537     (setq nnfolder-current-group group)))
 538
 539 (defun nnfolder-save-mail (group-art-list)
 540   "Called narrowed to an article."
 541   (let* ((delim (concat "^" message-unix-mail-delimiter))
 542          save-list group-art)
 543     (goto-char (point-min))
 544     ;; The From line may have been quoted by movemail.
 545     (when (looking-at (concat ">" message-unix-mail-delimiter))
 546       (delete-char 1))
 547     ;; This might come from somewhere else.
 548     (unless (looking-at delim)
 549       (insert "From nobody " (current-time-string) "\n")
 550       (goto-char (point-min)))
 551     ;; Quote all "From " lines in the article.
 552     (forward-line 1)
 553     (while (re-search-forward delim nil t)
 554       (beginning-of-line)
 555       (insert "> "))
 556     (setq save-list group-art-list)
 557     (nnmail-insert-lines)
 558     (nnmail-insert-xref group-art-list)
 559     (run-hooks 'nnmail-prepare-save-mail-hook)
 560     (run-hooks 'nnfolder-prepare-save-mail-hook)
 561
 562     ;; Insert the mail into each of the destination groups.
 563     (while group-art-list
 564       (setq group-art (car group-art-list)
 565             group-art-list (cdr group-art-list))
 566
 567       ;; Kill the previous newsgroup markers.
 568       (goto-char (point-min))
 569       (search-forward "\n\n" nil t)
 570       (forward-line -1)
 571       (while (search-backward (concat "\n" nnfolder-article-marker) nil t)
 572         (delete-region (1+ (point)) (progn (forward-line 2) (point))))
 573
 574       (nnfolder-possibly-change-group (car group-art))
 575       ;; Insert the new newsgroup marker.
 576       (nnfolder-insert-newsgroup-line group-art)
 577       (unless nnfolder-current-buffer
 578         (nnfolder-close-group (car group-art))
 579         (nnfolder-request-create-group (car group-art))
 580         (nnfolder-possibly-change-group (car group-art)))
 581       (let ((beg (point-min))
 582             (end (point-max))
 583             (obuf (current-buffer)))
 584         (set-buffer nnfolder-current-buffer)
 585         (goto-char (point-max))
 586         (unless (eolp)
 587           (insert "\n"))
 588         (insert "\n")
 589         (insert-buffer-substring obuf beg end)
 590         (set-buffer obuf)))
 591
 592     ;; Did we save it anywhere?
 593     save-list))
 594
 595 (defun nnfolder-insert-newsgroup-line (group-art)
 596   (save-excursion
 597     (goto-char (point-min))
 598     (when (search-forward "\n\n" nil t)
 599       (forward-char -1)
 600       (insert (format (concat nnfolder-article-marker "%d   %s\n")
 601                       (cdr group-art) (current-time-string))))))
 602
 603 (defun nnfolder-possibly-activate-groups (&optional group)
 604   (save-excursion
 605     ;; If we're looking for the activation of a specific group, find out
 606     ;; its real name and switch to it.
 607     (when group
 608       (nnfolder-possibly-change-group group))
 609     ;; If the group alist isn't active, activate it now.
 610     (nnmail-activate 'nnfolder)))
 611
 612 (defun nnfolder-active-number (group)
 613   (when group
 614     (save-excursion
 615       ;; Find the next article number in GROUP.
 616       (prog1
 617           (let ((active (cadr (assoc group nnfolder-group-alist))))
 618             (if active
 619                 (setcdr active (1+ (cdr active)))
 620               ;; This group is new, so we create a new entry for it.
 621               ;; This might be a bit naughty... creating groups on the drop of
 622               ;; a hat, but I don't know...
 623               (push (list group (setq active (cons 1 1)))
 624                     nnfolder-group-alist))
 625             (cdr active))
 626         (nnmail-save-active nnfolder-group-alist nnfolder-active-file)
 627         (nnfolder-possibly-activate-groups group)))))
 628
 629
 630 ;; This method has a problem if you've accidentally let the active list get
 631 ;; out of sync with the files.  This could happen, say, if you've
 632 ;; accidentally gotten new mail with something other than Gnus (but why
 633 ;; would _that_ ever happen? :-).  In that case, we will be in the middle of
 634 ;; processing the file, ready to add new X-Gnus article number markers, and
 635 ;; we'll run across a message with no ID yet - the active list _may_not_ be
 636 ;; ready for us yet.
 637
 638 ;; To handle this, I'm modifying this routine to maintain the maximum ID seen
 639 ;; so far, and when we hit a message with no ID, we will _manually_ scan the
 640 ;; rest of the message looking for any more, possibly higher IDs.  We'll
 641 ;; assume the maximum that we find is the highest active.  Note that this
 642 ;; shouldn't cost us much extra time at all, but will be a lot less
 643 ;; vulnerable to glitches between the mbox and the active file.
 644
 645 (defun nnfolder-read-folder (file &optional scanning)
 646   ;; This is an attempt at a serious shortcut - don't even read in the file
 647   ;; if we know we've seen it since the last time it was touched.
 648   (let ((scantime (cadr (assoc nnfolder-current-group
 649                                nnfolder-scantime-alist)))
 650         (modtime (nth 5 (or (file-attributes file) '(nil nil nil nil nil)))))
 651     (if (and scanning scantime
 652              (eq (car scantime) (car modtime))
 653              (eq (cdr scantime) (cadr modtime)))
 654         nil
 655       (save-excursion
 656         (nnfolder-possibly-activate-groups nil)
 657         ;; Read in the file.
 658         (set-buffer (setq nnfolder-current-buffer
 659                           (nnheader-find-file-noselect file nil 'raw)))
 660         (buffer-disable-undo (current-buffer))
 661         ;; If the file hasn't been touched since the last time we scanned it,
 662         ;; don't bother doing anything with it.
 663         (let ((delim (concat "^" message-unix-mail-delimiter))
 664               (marker (concat "\n" nnfolder-article-marker))
 665               (number "[0-9]+")
 666               (active (or (cadr (assoc nnfolder-current-group
 667                                        nnfolder-group-alist))
 668                           (cons 1 0)))
 669               (scantime (assoc nnfolder-current-group nnfolder-scantime-alist))
 670               (minid (lsh -1 -1))
 671               maxid start end newscantime)
 672
 673           (setq maxid (or (cdr active) 0))
 674           (goto-char (point-min))
 675
 676           ;; Anytime the active number is 1 or 0, it is suspect.  In that
 677           ;; case, search the file manually to find the active number.  Or,
 678           ;; of course, if we're being paranoid.  (This would also be the
 679           ;; place to build other lists from the header markers, such as
 680           ;; expunge lists, etc., if we ever desired to abandon the active
 681           ;; file entirely for mboxes.)
 682           (when (or nnfolder-ignore-active-file
 683                     (< maxid 2))
 684             (while (and (search-forward marker nil t)
 685                         (re-search-forward number nil t))
 686               (let ((newnum (string-to-number (match-string 0))))
 687                 (setq maxid (max maxid newnum))
 688                 (setq minid (min minid newnum))))
 689             (setcar active (max 1 (min minid maxid)))
 690             (setcdr active (max maxid (cdr active)))
 691             (goto-char (point-min)))
 692
 693           ;; As long as we trust that the user will only insert unmarked mail
 694           ;; at the end, go to the end and search backwards for the last
 695           ;; marker.  Find the start of that message, and begin to search for
 696           ;; unmarked messages from there.
 697           (when (not (or nnfolder-distrust-mbox
 698                          (< maxid 2)))
 699             (goto-char (point-max))
 700             (if (not (re-search-backward marker nil t))
 701                 (goto-char (point-min))
 702               (when (not (re-search-backward delim nil t))
 703                 (goto-char (point-min)))))
 704
 705           ;; Keep track of the active number on our own, and insert it back
 706           ;; into the active list when we're done.  Also, prime the pump to
 707           ;; cut down on the number of searches we do.
 708           (setq end (point-marker))
 709           (set-marker end (or (and (re-search-forward delim nil t)
 710                                    (match-beginning 0))
 711                               (point-max)))
 712           (while (not (= end (point-max)))
 713             (setq start (marker-position end))
 714             (goto-char end)
 715             ;; There may be more than one "From " line, so we skip past
 716             ;; them.
 717             (while (looking-at delim)
 718               (forward-line 1))
 719             (set-marker end (or (and (re-search-forward delim nil t)
 720                                      (match-beginning 0))
 721                                 (point-max)))
 722             (goto-char start)
 723             (when (not (search-forward marker end t))
 724               (narrow-to-region start end)
 725               (nnmail-insert-lines)
 726               (nnfolder-insert-newsgroup-line
 727                (cons nil (nnfolder-active-number nnfolder-current-group)))
 728               (widen)))
 729
 730           ;; Make absolutely sure that the active list reflects reality!
 731           (nnmail-save-active nnfolder-group-alist nnfolder-active-file)
 732           ;; Set the scantime for this group.
 733           (setq newscantime (visited-file-modtime))
 734           (if scantime
 735               (setcdr scantime (list newscantime))
 736             (push (list nnfolder-current-group newscantime)
 737                   nnfolder-scantime-alist))
 738           (current-buffer))))))
 739
 740 ;;;###autoload
 741 (defun nnfolder-generate-active-file ()
 742   "Look for mbox folders in the nnfolder directory and make them into groups."
 743   (interactive)
 744   (nnmail-activate 'nnfolder)
 745   (let ((files (directory-files nnfolder-directory))
 746         file)
 747     (while (setq file (pop files))
 748       (when (and (not (backup-file-name-p file))
 749                  (nnheader-mail-file-mbox-p
 750                   (concat nnfolder-directory file)))
 751         (nnheader-message 5 "Adding group %s..." file)
 752         (push (list file (cons 1 0)) nnfolder-group-alist)
 753         (nnfolder-possibly-change-group file)
 754         (nnfolder-close-group file))
 755       (message ""))))
 756
 757 (defun nnfolder-group-pathname (group)
 758   "Make pathname for GROUP."
 759   (let ((dir (file-name-as-directory (expand-file-name nnfolder-directory))))
 760     ;; If this file exists, we use it directly.
 761     (if (or nnmail-use-long-file-names
 762             (file-exists-p (concat dir group)))
 763         (concat dir group)
 764       ;; If not, we translate dots into slashes.
 765       (concat dir (nnheader-replace-chars-in-string group ?. ?/)))))
 766
 767 (defun nnfolder-save-buffer ()
 768   "Save the buffer."
 769   (when (buffer-modified-p)
 770     (run-hooks 'nnfolder-save-buffer-hook)
 771     (save-buffer)))
 772
 773 (provide 'nnfolder)
 774
 775 ;;; nnfolder.el ends here