cgit.sxemacs.org Git - gnus/blob - lisp/nndraft.el

   1 ;;; nndraft.el --- draft article access for Gnus
   2 ;; Copyright (C) 1995, 1996, 1997, 1998, 1999, 2000
   3 ;;        Free Software Foundation, Inc.
   4
   5 ;; Author: Lars Magne Ingebrigtsen <larsi@gnus.org>
   6 ;; Keywords: news
   7
   8 ;; This file is part of GNU Emacs.
   9
  10 ;; GNU Emacs is free software; you can redistribute it and/or modify
  11 ;; it under the terms of the GNU General Public License as published by
  12 ;; the Free Software Foundation; either version 2, or (at your option)
  13 ;; any later version.
  14
  15 ;; GNU Emacs is distributed in the hope that it will be useful,
  16 ;; but WITHOUT ANY WARRANTY; without even the implied warranty of
  17 ;; MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.  See the
  18 ;; GNU General Public License for more details.
  19
  20 ;; You should have received a copy of the GNU General Public License
  21 ;; along with GNU Emacs; see the file COPYING.  If not, write to the
  22 ;; Free Software Foundation, Inc., 59 Temple Place - Suite 330,
  23 ;; Boston, MA 02111-1307, USA.
  24
  25 ;;; Commentary:
  26
  27 ;;; Code:
  28
  29 (require 'nnheader)
  30 (require 'nnmail)
  31 (require 'gnus-start)
  32 (require 'nnmh)
  33 (require 'nnoo)
  34 (require 'mm-util)
  35 (eval-when-compile (require 'cl))
  36
  37 (nnoo-declare nndraft
  38   nnmh)
  39
  40 (defvoo nndraft-directory (nnheader-concat gnus-directory "drafts/")
  41   "Where nndraft will store its files."
  42   nnmh-directory)
  43
  44 \f
  45
  46 (defvoo nndraft-current-group "" nil nnmh-current-group)
  47 (defvoo nndraft-get-new-mail nil nil nnmh-get-new-mail)
  48 (defvoo nndraft-current-directory nil nil nnmh-current-directory)
  49
  50 (defconst nndraft-version "nndraft 1.0")
  51 (defvoo nndraft-status-string "" nil nnmh-status-string)
  52
  53 \f
  54
  55 ;;; Interface functions.
  56
  57 (nnoo-define-basics nndraft)
  58
  59 (deffoo nndraft-open-server (server &optional defs)
  60   (nnoo-change-server 'nndraft server defs)
  61   (cond
  62    ((not (file-exists-p nndraft-directory))
  63     (nndraft-close-server)
  64     (nnheader-report 'nndraft "No such file or directory: %s"
  65                      nndraft-directory))
  66    ((not (file-directory-p (file-truename nndraft-directory)))
  67     (nndraft-close-server)
  68     (nnheader-report 'nndraft "Not a directory: %s" nndraft-directory))
  69    (t
  70     (nnheader-report 'nndraft "Opened server %s using directory %s"
  71                      server nndraft-directory)
  72     t)))
  73
  74 (deffoo nndraft-retrieve-headers (articles &optional group server fetch-old)
  75   (nndraft-possibly-change-group group)
  76   (save-excursion
  77     (set-buffer nntp-server-buffer)
  78     (erase-buffer)
  79     (let* (article)
  80       ;; We don't support fetching by Message-ID.
  81       (if (stringp (car articles))
  82           'headers
  83         (while articles
  84           (narrow-to-region (point) (point))
  85           (when (nndraft-request-article
  86                  (setq article (pop articles)) group server (current-buffer))
  87             (goto-char (point-min))
  88             (if (search-forward "\n\n" nil t)
  89                 (forward-line -1)
  90               (goto-char (point-max)))
  91             (delete-region (point) (point-max))
  92             (goto-char (point-min))
  93             (insert (format "221 %d Article retrieved.\n" article))
  94             (widen)
  95             (goto-char (point-max))
  96             (insert ".\n")))
  97
  98         (nnheader-fold-continuation-lines)
  99         'headers))))
 100
 101 (deffoo nndraft-request-article (id &optional group server buffer)
 102   (nndraft-possibly-change-group group)
 103   (when (numberp id)
 104     ;; We get the newest file of the auto-saved file and the
 105     ;; "real" file.
 106     (let* ((file (nndraft-article-filename id))
 107            (auto (nndraft-auto-save-file-name file))
 108            (newest (if (file-newer-than-file-p file auto) file auto))
 109            (nntp-server-buffer (or buffer nntp-server-buffer)))
 110       (when (and (file-exists-p newest)
 111                  (let ((nnmail-file-coding-system
 112                         (if (file-newer-than-file-p file auto)
 113                             (if (equal group "drafts")
 114                                 message-draft-coding-system
 115                               mm-text-coding-system)
 116                           mm-auto-save-coding-system)))
 117                    (nnmail-find-file newest)))
 118         (save-excursion
 119           (set-buffer nntp-server-buffer)
 120           (goto-char (point-min))
 121           ;; If there's a mail header separator in this file,
 122           ;; we remove it.
 123           (when (re-search-forward
 124                  (concat "^" mail-header-separator "$") nil t)
 125             (replace-match "" t t)))
 126         t))))
 127
 128 (deffoo nndraft-request-restore-buffer (article &optional group server)
 129   "Request a new buffer that is restored to the state of ARTICLE."
 130   (nndraft-possibly-change-group group)
 131   (when (nndraft-request-article article group server (current-buffer))
 132     (message-remove-header "xref")
 133     (message-remove-header "lines")
 134     ;; Articles in nndraft:queue are considered as sent messages.  The
 135     ;; Date field should be the time when they are sent.
 136     ;;(message-remove-header "date")
 137     t))
 138
 139 (deffoo nndraft-request-update-info (group info &optional server)
 140   (nndraft-possibly-change-group group)
 141   (gnus-info-set-read
 142    info
 143    (gnus-update-read-articles (gnus-group-prefixed-name group '(nndraft ""))
 144                               (nndraft-articles) t))
 145   (let ((marks (nth 3 info)))
 146     (when marks
 147       ;; Nix out all marks except the `unsend'-able article marks.
 148       (setcar (nthcdr 3 info)
 149               (if (assq 'unsend marks)
 150                   (list (assq 'unsend marks))
 151                 nil))))
 152   t)
 153
 154 (deffoo nndraft-request-associate-buffer (group)
 155   "Associate the current buffer with some article in the draft group."
 156   (nndraft-open-server "")
 157   (nndraft-request-group group)
 158   (nndraft-possibly-change-group group)
 159   (let ((gnus-verbose-backends nil)
 160         (buf (current-buffer))
 161         article file)
 162     (with-temp-buffer
 163       (insert-buffer-substring buf)
 164       (setq article (nndraft-request-accept-article
 165                      group (nnoo-current-server 'nndraft) t 'noinsert)
 166             file (nndraft-article-filename article)))
 167     (setq buffer-file-name (expand-file-name file)
 168           buffer-auto-save-file-name (make-auto-save-file-name))
 169     (clear-visited-file-modtime)
 170     article))
 171
 172 (deffoo nndraft-request-group (group &optional server dont-check)
 173   (nndraft-possibly-change-group group)
 174   (unless dont-check
 175     (let* ((pathname (nnmail-group-pathname group nndraft-directory))
 176            (file-name-coding-system nnmail-pathname-coding-system)
 177            dir file)
 178       (nnheader-re-read-dir pathname)
 179       (setq dir (mapcar (lambda (name) (string-to-int (substring name 1)))
 180                         (directory-files pathname nil "^#[0-9]+#$" t)))
 181       (dolist (n dir)
 182         (unless (file-exists-p
 183                  (setq file (expand-file-name (int-to-string n) pathname)))
 184           (rename-file (let ((buffer-file-name file))
 185                          (make-auto-save-file-name)) file)))))
 186   (nnoo-parent-function 'nndraft
 187                         'nnmh-request-group
 188                         (list group server dont-check)))
 189
 190 (deffoo nndraft-request-expire-articles (articles group &optional server force)
 191   (nndraft-possibly-change-group group)
 192   (let* ((nnmh-allow-delete-final t)
 193          (res (nnoo-parent-function 'nndraft
 194                                     'nnmh-request-expire-articles
 195                                     (list articles group server force)))
 196          article)
 197     ;; Delete all the "state" files of articles that have been expired.
 198     (while articles
 199       (unless (memq (setq article (pop articles)) res)
 200         (let ((auto (nndraft-auto-save-file-name
 201                      (nndraft-article-filename article))))
 202           (when (file-exists-p auto)
 203             (funcall nnmail-delete-file-function auto)))
 204         (dolist (backup
 205                  (let ((kept-new-versions 1)
 206                        (kept-old-versions 0))
 207                    (find-backup-file-name
 208                     (nndraft-article-filename article))))
 209           (when (file-exists-p backup)
 210             (funcall nnmail-delete-file-function backup)))))
 211     res))
 212
 213 (deffoo nndraft-request-accept-article (group &optional server last noinsert)
 214   (nndraft-possibly-change-group group)
 215   (let ((gnus-verbose-backends nil))
 216     (nnoo-parent-function 'nndraft 'nnmh-request-accept-article
 217                           (list group server last noinsert))))
 218
 219 (deffoo nndraft-request-replace-article (article group buffer)
 220   (nndraft-possibly-change-group group)
 221   (let ((nnmail-file-coding-system
 222          (if (equal group "drafts")
 223              mm-auto-save-coding-system
 224            mm-text-coding-system)))
 225     (nnoo-parent-function 'nndraft 'nnmh-request-replace-article
 226                           (list article group buffer))))
 227
 228 (deffoo nndraft-request-create-group (group &optional server args)
 229   (nndraft-possibly-change-group group)
 230   (if (file-exists-p nndraft-current-directory)
 231       (if (file-directory-p nndraft-current-directory)
 232           t
 233         nil)
 234     (condition-case ()
 235         (progn
 236           (gnus-make-directory nndraft-current-directory)
 237           t)
 238       (file-error nil))))
 239
 240 \f
 241 ;;; Low-Level Interface
 242
 243 (defun nndraft-possibly-change-group (group)
 244   (when (and group
 245              (not (equal group nndraft-current-group)))
 246     (nndraft-open-server "")
 247     (setq nndraft-current-group group)
 248     (setq nndraft-current-directory
 249           (nnheader-concat nndraft-directory group))))
 250
 251 (defun nndraft-article-filename (article &rest args)
 252   (apply 'concat
 253          (file-name-as-directory nndraft-current-directory)
 254          (int-to-string article)
 255          args))
 256
 257 (defun nndraft-auto-save-file-name (file)
 258   (save-excursion
 259     (prog1
 260         (progn
 261           (set-buffer (get-buffer-create " *draft tmp*"))
 262           (setq buffer-file-name file)
 263           (make-auto-save-file-name))
 264       (kill-buffer (current-buffer)))))
 265
 266 (defun nndraft-articles ()
 267   "Return the list of messages in the group."
 268   (gnus-make-directory nndraft-current-directory)
 269   (sort
 270    (mapcar 'string-to-int
 271            (directory-files nndraft-current-directory nil "\\`[0-9]+\\'" t))
 272    '<))
 273
 274 (nnoo-import nndraft
 275   (nnmh
 276    nnmh-retrieve-headers
 277    nnmh-request-group
 278    nnmh-close-group
 279    nnmh-request-list
 280    nnmh-request-newsgroups
 281    nnmh-request-move-article))
 282
 283 (provide 'nndraft)
 284
 285 ;;; nndraft.el ends here