cgit.sxemacs.org Git - gnus/blob - lisp/nndiary.el

   1 ;;; nndiary.el --- A diary back end for Gnus
   2
   3 ;; Copyright (C) 1999, 2000, 2001, 2002, 2003, 2004,
   4 ;;   2005, 2006, 2007, 2008, 2009 Free Software Foundation, Inc.
   5
   6 ;; Author:        Didier Verna <didier@xemacs.org>
   7 ;; Maintainer:    Didier Verna <didier@xemacs.org>
   8 ;; Created:       Fri Jul 16 18:55:42 1999
   9 ;; Keywords:      calendar mail news
  10
  11 ;; This file is part of GNU Emacs.
  12
  13 ;; GNU Emacs is free software: you can redistribute it and/or modify
  14 ;; it under the terms of the GNU General Public License as published by
  15 ;; the Free Software Foundation, either version 3 of the License, or
  16 ;; (at your option) any later version.
  17
  18 ;; GNU Emacs is distributed in the hope that it will be useful,
  19 ;; but WITHOUT ANY WARRANTY; without even the implied warranty of
  20 ;; MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.  See the
  21 ;; GNU General Public License for more details.
  22
  23 ;; You should have received a copy of the GNU General Public License
  24 ;; along with GNU Emacs.  If not, see <http://www.gnu.org/licenses/>.
  25
  26
  27 ;;; Commentary:
  28
  29 ;; Contents management by FCM version 0.1.
  30
  31 ;; Description:
  32 ;; ===========
  33
  34 ;; nndiary is a mail back end designed to handle mails as diary event
  35 ;; reminders. It is now fully documented in the Gnus manual.
  36
  37
  38 ;; Bugs / Todo:
  39 ;; ===========
  40
  41 ;; * Respooling doesn't work because contrary to the request-scan function,
  42 ;;   Gnus won't allow me to override the split methods when calling the
  43 ;;   respooling back end functions.
  44 ;; * There's a bug in the time zone mechanism with variable TZ locations.
  45 ;; * We could allow a keyword like `ask' in X-Diary-* headers, that would mean
  46 ;;   "ask for value upon reception of the message".
  47 ;; * We could add an optional header X-Diary-Reminders to specify a special
  48 ;;   reminders value for this message. Suggested by Jody Klymak.
  49 ;; * We should check messages validity in other circumstances than just
  50 ;;   moving an article from somewhere else (request-accept). For instance,
  51 ;;   when editing / saving and so on.
  52
  53
  54 ;; Remarks:
  55 ;; =======
  56
  57 ;; * nnoo. NNDiary is very similar to nnml. This makes the idea of using nnoo
  58 ;;   (to derive nndiary from nnml) natural. However, my experience with nnoo
  59 ;;   is that for reasonably complex back ends like this one, noo is a burden
  60 ;;   rather than an help. It's tricky to use, not everything can be inherited,
  61 ;;   what can be inherited and when is not very clear, and you've got to be
  62 ;;   very careful because a little mistake can fuck up your other back ends,
  63 ;;   especially because their variables will be use instead of your real ones.
  64 ;;   Finally, I found it easier to just clone the needed parts of nnml, and
  65 ;;   tracking nnml updates is not a big deal.
  66
  67 ;;   IMHO, nnoo is actually badly designed.  A much simpler, and yet more
  68 ;;   powerful one would be to make *real* functions and variables for a new
  69 ;;   back end based on another. Lisp is a reflexive language so that's a very
  70 ;;   easy thing to do: inspect the function's form, replace occurences of
  71 ;;   <nnfrom> (even in strings) with <nnto>, and you're done.
  72
  73 ;; * nndiary-get-new-mail, nndiary-mail-source and nndiary-split-methods:
  74 ;;   NNDiary has some experimental parts, in the sense Gnus normally uses only
  75 ;;   one mail back ends for mail retreival and splitting. This back end is
  76 ;;   also an attempt to make it behave differently. For Gnus developpers: as
  77 ;;   you can see if you snarf into the code, that was not a very difficult
  78 ;;   thing to do. Something should be done about the respooling breakage
  79 ;;   though.
  80
  81
  82 ;;; Code:
  83
  84 (require 'nnoo)
  85 (require 'nnheader)
  86 (require 'nnmail)
  87 (eval-when-compile (require 'cl))
  88
  89 (require 'gnus-start)
  90 (require 'gnus-sum)
  91
  92 ;; Compatibility Functions  =================================================
  93
  94 (eval-and-compile
  95   (if (fboundp 'signal-error)
  96       (defun nndiary-error (&rest args)
  97         (apply #'signal-error 'nndiary args))
  98     (defun nndiary-error (&rest args)
  99       (apply #'error args))))
 100
 101
 102 ;; Back End behavior customization ===========================================
 103
 104 (defgroup nndiary nil
 105   "The Gnus Diary back end."
 106   :version "22.1"
 107   :group 'gnus-diary)
 108
 109 (defcustom nndiary-mail-sources
 110   `((file :path ,(expand-file-name "~/.nndiary")))
 111   "*NNDiary specific mail sources.
 112 This variable is used by nndiary in place of the standard `mail-sources'
 113 variable when `nndiary-get-new-mail' is set to non-nil.  These sources
 114 must contain diary messages ONLY."
 115   :group 'nndiary
 116   :group 'mail-source
 117   :type 'sexp)
 118
 119 (defcustom nndiary-split-methods '(("diary" ""))
 120   "*NNDiary specific split methods.
 121 This variable is used by nndiary in place of the standard
 122 `nnmail-split-methods' variable when `nndiary-get-new-mail' is set to
 123 non-nil."
 124   :group 'nndiary
 125   :group 'nnmail-split
 126   :type '(choice (repeat :tag "Alist" (group (string :tag "Name") regexp))
 127                  (function-item nnmail-split-fancy)
 128                  (function :tag "Other")))
 129
 130
 131 (defcustom nndiary-reminders '((0 . day))
 132   "*Different times when you want to be reminded of your appointments.
 133 Diary articles will appear again, as if they'd been just received.
 134
 135 Entries look like (3 . day) which means something like \"Please
 136 Hortense, would you be so kind as to remind me of my appointments 3 days
 137 before the date, thank you very much. Anda, hmmm... by the way, are you
 138 doing anything special tonight ?\".
 139
 140 The units of measure are 'minute 'hour 'day 'week 'month and 'year (no,
 141 not 'century, sorry).
 142
 143 NOTE: the units of measure actually express dates, not durations: if you
 144 use 'week, messages will pop up on Sundays at 00:00 (or Mondays if
 145 `nndiary-week-starts-on-monday' is non-nil) and *not* 7 days before the
 146 appointment, if you use 'month, messages will pop up on the first day of
 147 each months, at 00:00 and so on.
 148
 149 If you really want to specify a duration (like 24 hours exactly), you can
 150 use the equivalent in minutes (the smallest unit).  A fuzz of 60 seconds
 151 maximum in the reminder is not that painful, I think.  Although this
 152 scheme might appear somewhat weird at a first glance, it is very powerful.
 153 In order to make this clear, here are some examples:
 154
 155 - '(0 . day): this is the default value of `nndiary-reminders'.  It means
 156   pop up the appointments of the day each morning at 00:00.
 157
 158 - '(1 . day): this means pop up the appointments the day before, at 00:00.
 159
 160 - '(6 . hour): for an appointment at 18:30, this would pop up the
 161   appointment message at 12:00.
 162
 163 - '(360 . minute): for an appointment at 18:30 and 15 seconds, this would
 164   pop up the appointment message at 12:30."
 165   :group 'nndiary
 166   :type '(repeat (cons :format "%v\n"
 167                        (integer :format "%v")
 168                        (choice :format "%[%v(s)%] before...\n"
 169                                :value day
 170                                (const :format "%v" minute)
 171                                (const :format "%v" hour)
 172                                (const :format "%v" day)
 173                                (const :format "%v" week)
 174                                (const :format "%v" month)
 175                                (const :format "%v" year)))))
 176
 177 (defcustom nndiary-week-starts-on-monday nil
 178   "*Whether a week starts on monday (otherwise, sunday)."
 179   :type 'boolean
 180   :group 'nndiary)
 181
 182
 183 (defcustom nndiary-request-create-group-hooks nil
 184   "*Hooks to run after `nndiary-request-create-group' is executed.
 185 The hooks will be called with the full group name as argument."
 186   :group 'nndiary
 187   :type 'hook)
 188
 189 (defcustom nndiary-request-update-info-hooks nil
 190   "*Hooks to run after `nndiary-request-update-info-group' is executed.
 191 The hooks will be called with the full group name as argument."
 192   :group 'nndiary
 193   :type 'hook)
 194
 195 (defcustom nndiary-request-accept-article-hooks nil
 196   "*Hooks to run before accepting an article.
 197 Executed near the beginning of `nndiary-request-accept-article'.
 198 The hooks will be called with the article in the current buffer."
 199   :group 'nndiary
 200   :type 'hook)
 201
 202 (defcustom nndiary-check-directory-twice t
 203   "*If t, check directories twice to avoid NFS failures."
 204   :group 'nndiary
 205   :type 'boolean)
 206
 207
 208 ;; Back End declaration ======================================================
 209
 210 ;; Well, most of this is nnml clonage.
 211
 212 (nnoo-declare nndiary)
 213
 214 (defvoo nndiary-directory (nnheader-concat gnus-directory "diary/")
 215   "Spool directory for the nndiary back end.")
 216
 217 (defvoo nndiary-active-file
 218     (expand-file-name "active" nndiary-directory)
 219   "Active file for the nndiary back end.")
 220
 221 (defvoo nndiary-newsgroups-file
 222     (expand-file-name "newsgroups" nndiary-directory)
 223   "Newsgroups description file for the nndiary back end.")
 224
 225 (defvoo nndiary-get-new-mail nil
 226   "Whether nndiary gets new mail and split it.
 227 Contrary to traditional mail back ends, this variable can be set to t
 228 even if your primary mail back end also retreives mail. In such a case,
 229 NDiary uses its own mail-sources and split-methods.")
 230
 231 (defvoo nndiary-nov-is-evil nil
 232   "If non-nil, Gnus will never use nov databases for nndiary groups.
 233 Using nov databases will speed up header fetching considerably.
 234 This variable shouldn't be flipped much.  If you have, for some reason,
 235 set this to t, and want to set it to nil again, you should always run
 236 the `nndiary-generate-nov-databases' command.  The function will go
 237 through all nnml directories and generate nov databases for them
 238 all.  This may very well take some time.")
 239
 240 (defvoo nndiary-prepare-save-mail-hook nil
 241   "*Hook run narrowed to an article before saving.")
 242
 243 (defvoo nndiary-inhibit-expiry nil
 244   "If non-nil, inhibit expiry.")
 245
 246 \f
 247
 248 (defconst nndiary-version "0.2-b14"
 249   "Current Diary back end version.")
 250
 251 (defun nndiary-version ()
 252   "Current Diary back end version."
 253   (interactive)
 254   (message "NNDiary version %s" nndiary-version))
 255
 256 (defvoo nndiary-nov-file-name ".overview")
 257
 258 (defvoo nndiary-current-directory nil)
 259 (defvoo nndiary-current-group nil)
 260 (defvoo nndiary-status-string "" )
 261 (defvoo nndiary-nov-buffer-alist nil)
 262 (defvoo nndiary-group-alist nil)
 263 (defvoo nndiary-active-timestamp nil)
 264 (defvoo nndiary-article-file-alist nil)
 265
 266 (defvoo nndiary-generate-active-function 'nndiary-generate-active-info)
 267 (defvoo nndiary-nov-buffer-file-name nil)
 268 (defvoo nndiary-file-coding-system nnmail-file-coding-system)
 269
 270 (defconst nndiary-headers
 271   '(("Minute" 0 59)
 272     ("Hour" 0 23)
 273     ("Dom" 1 31)
 274     ("Month" 1 12)
 275     ("Year" 1971)
 276     ("Dow" 0 6)
 277     ("Time-Zone" (("Y" -43200)
 278
 279                   ("X" -39600)
 280
 281                   ("W" -36000)
 282
 283                   ("V" -32400)
 284
 285                   ("U" -28800)
 286                   ("PST" -28800)
 287
 288                   ("T"   -25200)
 289                   ("MST" -25200)
 290                   ("PDT" -25200)
 291
 292                   ("S"   -21600)
 293                   ("CST" -21600)
 294                   ("MDT" -21600)
 295
 296                   ("R"   -18000)
 297                   ("EST" -18000)
 298                   ("CDT" -18000)
 299
 300                   ("Q"   -14400)
 301                   ("AST" -14400)
 302                   ("EDT" -14400)
 303
 304                   ("P"   -10800)
 305                   ("ADT" -10800)
 306
 307                   ("O" -7200)
 308
 309                   ("N" -3600)
 310
 311                   ("Z"   0)
 312                   ("GMT" 0)
 313                   ("UT"  0)
 314                   ("UTC" 0)
 315                   ("WET" 0)
 316
 317                   ("A"    3600)
 318                   ("CET"  3600)
 319                   ("MET"  3600)
 320                   ("MEZ"  3600)
 321                   ("BST"  3600)
 322                   ("WEST" 3600)
 323
 324                   ("B"    7200)
 325                   ("EET"  7200)
 326                   ("CEST" 7200)
 327                   ("MEST" 7200)
 328                   ("MESZ" 7200)
 329
 330                   ("C" 10800)
 331
 332                   ("D" 14400)
 333
 334                   ("E" 18000)
 335
 336                   ("F" 21600)
 337
 338                   ("G" 25200)
 339
 340                   ("H" 28800)
 341
 342                   ("I"   32400)
 343                   ("JST" 32400)
 344
 345                   ("K"   36000)
 346                   ("GST" 36000)
 347
 348                   ("L" 39600)
 349
 350                   ("M"    43200)
 351                   ("NZST" 43200)
 352
 353                   ("NZDT" 46800))))
 354   ;; List of NNDiary headers that specify the time spec. Each header name is
 355   ;; followed by either two integers (specifying a range of possible values
 356   ;; for this header) or one list (specifying all the possible values for this
 357   ;; header). In the latter case, the list does NOT include the unspecifyed
 358   ;; spec (*).
 359   ;; For time zone values, we have symbolic time zone names associated with
 360   ;; the (relative) number of seconds ahead GMT.
 361   )
 362
 363 (defsubst nndiary-schedule ()
 364   (let (head)
 365     (condition-case arg
 366         (mapcar
 367          (lambda (elt)
 368            (setq head (nth 0 elt))
 369            (nndiary-parse-schedule (nth 0 elt) (nth 1 elt) (nth 2 elt)))
 370          nndiary-headers)
 371       (t
 372        (nnheader-report 'nndiary "X-Diary-%s header parse error: %s."
 373                         head (cdr arg))
 374        nil))
 375     ))
 376
 377 ;;; Interface functions =====================================================
 378
 379 (nnoo-define-basics nndiary)
 380
 381 (deffoo nndiary-retrieve-headers (sequence &optional group server fetch-old)
 382   (when (nndiary-possibly-change-directory group server)
 383     (save-excursion
 384       (set-buffer nntp-server-buffer)
 385       (erase-buffer)
 386       (let* ((file nil)
 387              (number (length sequence))
 388              (count 0)
 389              (file-name-coding-system nnmail-pathname-coding-system)
 390              beg article
 391              (nndiary-check-directory-twice
 392               (and nndiary-check-directory-twice
 393                    ;; To speed up, disable it in some case.
 394                    (or (not (numberp nnmail-large-newsgroup))
 395                        (<= number nnmail-large-newsgroup)))))
 396         (if (stringp (car sequence))
 397             'headers
 398           (if (nndiary-retrieve-headers-with-nov sequence fetch-old)
 399               'nov
 400             (while sequence
 401               (setq article (car sequence))
 402               (setq file (nndiary-article-to-file article))
 403               (when (and file
 404                          (file-exists-p file)
 405                          (not (file-directory-p file)))
 406                 (insert (format "221 %d Article retrieved.\n" article))
 407                 (setq beg (point))
 408                 (nnheader-insert-head file)
 409                 (goto-char beg)
 410                 (if (search-forward "\n\n" nil t)
 411                     (forward-char -1)
 412                   (goto-char (point-max))
 413                   (insert "\n\n"))
 414                 (insert ".\n")
 415                 (delete-region (point) (point-max)))
 416               (setq sequence (cdr sequence))
 417               (setq count (1+ count))
 418               (and (numberp nnmail-large-newsgroup)
 419                    (> number nnmail-large-newsgroup)
 420                    (zerop (% count 20))
 421                    (nnheader-message 6 "nndiary: Receiving headers... %d%%"
 422                                      (/ (* count 100) number))))
 423
 424             (and (numberp nnmail-large-newsgroup)
 425                  (> number nnmail-large-newsgroup)
 426                  (nnheader-message 6 "nndiary: Receiving headers...done"))
 427
 428             (nnheader-fold-continuation-lines)
 429             'headers))))))
 430
 431 (deffoo nndiary-open-server (server &optional defs)
 432   (nnoo-change-server 'nndiary server defs)
 433   (when (not (file-exists-p nndiary-directory))
 434     (ignore-errors (make-directory nndiary-directory t)))
 435   (cond
 436    ((not (file-exists-p nndiary-directory))
 437     (nndiary-close-server)
 438     (nnheader-report 'nndiary "Couldn't create directory: %s"
 439                      nndiary-directory))
 440    ((not (file-directory-p (file-truename nndiary-directory)))
 441     (nndiary-close-server)
 442     (nnheader-report 'nndiary "Not a directory: %s" nndiary-directory))
 443    (t
 444     (nnheader-report 'nndiary "Opened server %s using directory %s"
 445                      server nndiary-directory)
 446     t)))
 447
 448 (deffoo nndiary-request-regenerate (server)
 449   (nndiary-possibly-change-directory nil server)
 450   (nndiary-generate-nov-databases server)
 451   t)
 452
 453 (deffoo nndiary-request-article (id &optional group server buffer)
 454   (nndiary-possibly-change-directory group server)
 455   (let* ((nntp-server-buffer (or buffer nntp-server-buffer))
 456          (file-name-coding-system nnmail-pathname-coding-system)
 457          path gpath group-num)
 458     (if (stringp id)
 459         (when (and (setq group-num (nndiary-find-group-number id))
 460                    (cdr
 461                     (assq (cdr group-num)
 462                           (nnheader-article-to-file-alist
 463                            (setq gpath
 464                                  (nnmail-group-pathname
 465                                   (car group-num)
 466                                   nndiary-directory))))))
 467           (setq path (concat gpath (int-to-string (cdr group-num)))))
 468       (setq path (nndiary-article-to-file id)))
 469     (cond
 470      ((not path)
 471       (nnheader-report 'nndiary "No such article: %s" id))
 472      ((not (file-exists-p path))
 473       (nnheader-report 'nndiary "No such file: %s" path))
 474      ((file-directory-p path)
 475       (nnheader-report 'nndiary "File is a directory: %s" path))
 476      ((not (save-excursion (let ((nnmail-file-coding-system
 477                                   nndiary-file-coding-system))
 478                              (nnmail-find-file path))))
 479       (nnheader-report 'nndiary "Couldn't read file: %s" path))
 480      (t
 481       (nnheader-report 'nndiary "Article %s retrieved" id)
 482       ;; We return the article number.
 483       (cons (if group-num (car group-num) group)
 484             (string-to-number (file-name-nondirectory path)))))))
 485
 486 (deffoo nndiary-request-group (group &optional server dont-check)
 487   (let ((file-name-coding-system nnmail-pathname-coding-system))
 488     (cond
 489      ((not (nndiary-possibly-change-directory group server))
 490       (nnheader-report 'nndiary "Invalid group (no such directory)"))
 491      ((not (file-exists-p nndiary-current-directory))
 492       (nnheader-report 'nndiary "Directory %s does not exist"
 493                        nndiary-current-directory))
 494      ((not (file-directory-p nndiary-current-directory))
 495       (nnheader-report 'nndiary "%s is not a directory"
 496                        nndiary-current-directory))
 497      (dont-check
 498       (nnheader-report 'nndiary "Group %s selected" group)
 499       t)
 500      (t
 501       (nnheader-re-read-dir nndiary-current-directory)
 502       (nnmail-activate 'nndiary)
 503       (let ((active (nth 1 (assoc group nndiary-group-alist))))
 504         (if (not active)
 505             (nnheader-report 'nndiary "No such group: %s" group)
 506           (nnheader-report 'nndiary "Selected group %s" group)
 507           (nnheader-insert "211 %d %d %d %s\n"
 508                            (max (1+ (- (cdr active) (car active))) 0)
 509                            (car active) (cdr active) group)))))))
 510
 511 (deffoo nndiary-request-scan (&optional group server)
 512   ;; Use our own mail sources and split methods while Gnus doesn't let us have
 513   ;; multiple back ends for retrieving mail.
 514   (let ((mail-sources nndiary-mail-sources)
 515         (nnmail-split-methods nndiary-split-methods))
 516     (setq nndiary-article-file-alist nil)
 517     (nndiary-possibly-change-directory group server)
 518     (nnmail-get-new-mail 'nndiary 'nndiary-save-nov nndiary-directory group)))
 519
 520 (deffoo nndiary-close-group (group &optional server)
 521   (setq nndiary-article-file-alist nil)
 522   t)
 523
 524 (deffoo nndiary-request-create-group (group &optional server args)
 525   (nndiary-possibly-change-directory nil server)
 526   (nnmail-activate 'nndiary)
 527   (cond
 528    ((assoc group nndiary-group-alist)
 529     t)
 530    ((and (file-exists-p (nnmail-group-pathname group nndiary-directory))
 531          (not (file-directory-p (nnmail-group-pathname
 532                                  group nndiary-directory))))
 533     (nnheader-report 'nndiary "%s is a file"
 534                      (nnmail-group-pathname group nndiary-directory)))
 535    (t
 536     (let (active)
 537       (push (list group (setq active (cons 1 0)))
 538             nndiary-group-alist)
 539       (nndiary-possibly-create-directory group)
 540       (nndiary-possibly-change-directory group server)
 541       (let ((articles (nnheader-directory-articles nndiary-current-directory)))
 542         (when articles
 543           (setcar active (apply 'min articles))
 544           (setcdr active (apply 'max articles))))
 545       (nnmail-save-active nndiary-group-alist nndiary-active-file)
 546       (run-hook-with-args 'nndiary-request-create-group-hooks
 547                           (gnus-group-prefixed-name group
 548                                                     (list "nndiary" server)))
 549       t))
 550    ))
 551
 552 (deffoo nndiary-request-list (&optional server)
 553   (save-excursion
 554     (let ((nnmail-file-coding-system nnmail-active-file-coding-system)
 555           (file-name-coding-system nnmail-pathname-coding-system))
 556       (nnmail-find-file nndiary-active-file))
 557     (setq nndiary-group-alist (nnmail-get-active))
 558     t))
 559
 560 (deffoo nndiary-request-newgroups (date &optional server)
 561   (nndiary-request-list server))
 562
 563 (deffoo nndiary-request-list-newsgroups (&optional server)
 564   (save-excursion
 565     (nnmail-find-file nndiary-newsgroups-file)))
 566
 567 (deffoo nndiary-request-expire-articles (articles group &optional server force)
 568   (nndiary-possibly-change-directory group server)
 569   (let ((active-articles
 570          (nnheader-directory-articles nndiary-current-directory))
 571         article rest number)
 572     (nnmail-activate 'nndiary)
 573     ;; Articles not listed in active-articles are already gone,
 574     ;; so don't try to expire them.
 575     (setq articles (gnus-intersection articles active-articles))
 576     (while articles
 577       (setq article (nndiary-article-to-file (setq number (pop articles))))
 578       (if (and (nndiary-deletable-article-p group number)
 579                ;; Don't use nnmail-expired-article-p. Our notion of expiration
 580                ;; is a bit peculiar ...
 581                (or force (nndiary-expired-article-p article)))
 582           (progn
 583             ;; Allow a special target group.
 584             (unless (eq nnmail-expiry-target 'delete)
 585               (with-temp-buffer
 586                 (nndiary-request-article number group server (current-buffer))
 587                 (let ((nndiary-current-directory nil))
 588                   (nnmail-expiry-target-group nnmail-expiry-target group)))
 589               (nndiary-possibly-change-directory group server))
 590             (nnheader-message 5 "Deleting article %s in %s" number group)
 591             (condition-case ()
 592                 (funcall nnmail-delete-file-function article)
 593               (file-error (push number rest)))
 594             (setq active-articles (delq number active-articles))
 595             (nndiary-nov-delete-article group number))
 596         (push number rest)))
 597     (let ((active (nth 1 (assoc group nndiary-group-alist))))
 598       (when active
 599         (setcar active (or (and active-articles
 600                                 (apply 'min active-articles))
 601                            (1+ (cdr active)))))
 602       (nnmail-save-active nndiary-group-alist nndiary-active-file))
 603     (nndiary-save-nov)
 604     (nconc rest articles)))
 605
 606 (deffoo nndiary-request-move-article
 607     (article group server accept-form &optional last move-is-internal)
 608   (let ((buf (get-buffer-create " *nndiary move*"))
 609         result)
 610     (nndiary-possibly-change-directory group server)
 611     (nndiary-update-file-alist)
 612     (and
 613      (nndiary-deletable-article-p group article)
 614      (nndiary-request-article article group server)
 615      (let (nndiary-current-directory
 616            nndiary-current-group
 617            nndiary-article-file-alist)
 618        (save-excursion
 619          (set-buffer buf)
 620          (insert-buffer-substring nntp-server-buffer)
 621          (setq result (eval accept-form))
 622          (kill-buffer (current-buffer))
 623          result))
 624      (progn
 625        (nndiary-possibly-change-directory group server)
 626        (condition-case ()
 627            (funcall nnmail-delete-file-function
 628                     (nndiary-article-to-file  article))
 629          (file-error nil))
 630        (nndiary-nov-delete-article group article)
 631        (when last
 632          (nndiary-save-nov)
 633          (nnmail-save-active nndiary-group-alist nndiary-active-file))))
 634     result))
 635
 636 (deffoo nndiary-request-accept-article (group &optional server last)
 637   (nndiary-possibly-change-directory group server)
 638   (nnmail-check-syntax)
 639   (run-hooks 'nndiary-request-accept-article-hooks)
 640   (when (nndiary-schedule)
 641     (let (result)
 642       (when nnmail-cache-accepted-message-ids
 643         (nnmail-cache-insert (nnmail-fetch-field "message-id")
 644                              group
 645                              (nnmail-fetch-field "subject")))
 646       (if (stringp group)
 647           (and
 648            (nnmail-activate 'nndiary)
 649            (setq result
 650                  (car (nndiary-save-mail
 651                        (list (cons group (nndiary-active-number group))))))
 652            (progn
 653              (nnmail-save-active nndiary-group-alist nndiary-active-file)
 654              (and last (nndiary-save-nov))))
 655         (and
 656          (nnmail-activate 'nndiary)
 657          (if (and (not (setq result
 658                              (nnmail-article-group 'nndiary-active-number)))
 659                   (yes-or-no-p "Moved to `junk' group; delete article? "))
 660              (setq result 'junk)
 661            (setq result (car (nndiary-save-mail result))))
 662          (when last
 663            (nnmail-save-active nndiary-group-alist nndiary-active-file)
 664            (when nnmail-cache-accepted-message-ids
 665              (nnmail-cache-close))
 666            (nndiary-save-nov))))
 667       result))
 668   )
 669
 670 (deffoo nndiary-request-post (&optional server)
 671   (nnmail-do-request-post 'nndiary-request-accept-article server))
 672
 673 (deffoo nndiary-request-replace-article (article group buffer)
 674   (nndiary-possibly-change-directory group)
 675   (save-excursion
 676     (set-buffer buffer)
 677     (nndiary-possibly-create-directory group)
 678     (let ((chars (nnmail-insert-lines))
 679           (art (concat (int-to-string article) "\t"))
 680           headers)
 681       (when (ignore-errors
 682               (nnmail-write-region
 683                (point-min) (point-max)
 684                (or (nndiary-article-to-file article)
 685                    (expand-file-name (int-to-string article)
 686                                      nndiary-current-directory))
 687                nil (if (nnheader-be-verbose 5) nil 'nomesg))
 688               t)
 689         (setq headers (nndiary-parse-head chars article))
 690         ;; Replace the NOV line in the NOV file.
 691         (save-excursion
 692           (set-buffer (nndiary-open-nov group))
 693           (goto-char (point-min))
 694           (if (or (looking-at art)
 695                   (search-forward (concat "\n" art) nil t))
 696               ;; Delete the old NOV line.
 697               (delete-region (progn (beginning-of-line) (point))
 698                              (progn (forward-line 1) (point)))
 699             ;; The line isn't here, so we have to find out where
 700             ;; we should insert it.  (This situation should never
 701             ;; occur, but one likes to make sure...)
 702             (while (and (looking-at "[0-9]+\t")
 703                         (< (string-to-number
 704                             (buffer-substring
 705                              (match-beginning 0) (match-end 0)))
 706                            article)
 707                         (zerop (forward-line 1)))))
 708           (beginning-of-line)
 709           (nnheader-insert-nov headers)
 710           (nndiary-save-nov)
 711           t)))))
 712
 713 (deffoo nndiary-request-delete-group (group &optional force server)
 714   (nndiary-possibly-change-directory group server)
 715   (when force
 716     ;; Delete all articles in GROUP.
 717     (let ((articles
 718            (directory-files
 719             nndiary-current-directory t
 720             (concat nnheader-numerical-short-files
 721                     "\\|" (regexp-quote nndiary-nov-file-name) "$")))