cgit.sxemacs.org Git - gnus/blob - lisp/nnbabyl.el

   1 ;;; nnbabyl.el --- rmail mbox access for Gnus
   2 ;; Copyright (C) 1995 Free Software Foundation, Inc.
   3
   4 ;; Author: Lars Magne Ingebrigtsen <larsi@ifi.uio.no>
   5 ;;      Masanobu UMEDA <umerin@flab.flab.fujitsu.junet>
   6 ;; Keywords: news, mail
   7
   8 ;; This file is part of GNU Emacs.
   9
  10 ;; GNU Emacs is free software; you can redistribute it and/or modify
  11 ;; it under the terms of the GNU General Public License as published by
  12 ;; the Free Software Foundation; either version 2, or (at your option)
  13 ;; any later version.
  14
  15 ;; GNU Emacs is distributed in the hope that it will be useful,
  16 ;; but WITHOUT ANY WARRANTY; without even the implied warranty of
  17 ;; MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.  See the
  18 ;; GNU General Public License for more details.
  19
  20 ;; You should have received a copy of the GNU General Public License
  21 ;; along with GNU Emacs; see the file COPYING.  If not, write to
  22 ;; the Free Software Foundation, 675 Mass Ave, Cambridge, MA 02139, USA.
  23
  24 ;;; Commentary:
  25
  26 ;; For an overview of what the interface functions do, please see the
  27 ;; Gnus sources.
  28
  29 ;;; Code:
  30
  31 (require 'nnheader)
  32 (require 'rmail)
  33 (require 'nnmail)
  34
  35 (defvar nnbabyl-mbox-file (expand-file-name "~/RMAIL")
  36   "The name of the rmail box file in the users home directory.")
  37
  38 (defvar nnbabyl-active-file (expand-file-name "~/.rmail-active")
  39   "The name of the active file for the rmail box.")
  40
  41 (defvar nnbabyl-get-new-mail t
  42   "If non-nil, nnbabyl will check the incoming mail file and split the mail.")
  43
  44 (defvar nnbabyl-prepare-save-mail-hook nil
  45   "Hook run narrowed to an article before saving.")
  46
  47 \f
  48
  49 (defvar nnbabyl-mail-delimiter "\^_")
  50
  51 (defconst nnbabyl-version "nnbabyl 1.0"
  52   "nnbabyl version.")
  53
  54 (defvar nnbabyl-mbox-buffer nil)
  55 (defvar nnbabyl-current-group nil)
  56 (defvar nnbabyl-status-string "")
  57 (defvar nnbabyl-group-alist nil)
  58 (defvar nnbabyl-active-timestamp nil)
  59
  60 \f
  61
  62 (defvar nnbabyl-current-server nil)
  63 (defvar nnbabyl-server-alist nil)
  64 (defvar nnbabyl-server-variables
  65   (list
  66    (list 'nnbabyl-mbox-file nnbabyl-mbox-file)
  67    (list 'nnbabyl-active-file nnbabyl-active-file)
  68    (list 'nnbabyl-get-new-mail nnbabyl-get-new-mail)
  69    '(nnbabyl-current-group nil)
  70    '(nnbabyl-status-string "")
  71    '(nnbabyl-group-alist nil)))
  72
  73 \f
  74
  75 ;;; Interface functions
  76
  77 (defun nnbabyl-retrieve-headers (sequence &optional newsgroup server)
  78   (save-excursion
  79     (set-buffer nntp-server-buffer)
  80     (erase-buffer)
  81     (let ((number (length sequence))
  82           (count 0)
  83           article art-string start stop)
  84       (nnbabyl-possibly-change-newsgroup newsgroup)
  85       (if (stringp (car sequence))
  86           'headers
  87         (while sequence
  88           (setq article (car sequence))
  89           (setq art-string (nnbabyl-article-string article))
  90           (set-buffer nnbabyl-mbox-buffer)
  91           (if (or (search-forward art-string nil t)
  92                   (search-backward art-string nil t))
  93               (progn
  94                 (re-search-backward (concat "^" nnbabyl-mail-delimiter) nil t)
  95                 (while (and (not (looking-at ".+:"))
  96                             (zerop (forward-line 1))))
  97                 (setq start (point))
  98                 (search-forward "\n\n" nil t)
  99                 (setq stop (1- (point)))
 100                 (set-buffer nntp-server-buffer)
 101                 (insert "221 " (int-to-string article) " Article retrieved.\n")
 102                 (insert-buffer-substring nnbabyl-mbox-buffer start stop)
 103                 (goto-char (point-max))
 104                 (insert ".\n")))
 105           (setq sequence (cdr sequence))
 106           (setq count (1+ count))
 107           (and (numberp nnmail-large-newsgroup)
 108                (> number nnmail-large-newsgroup)
 109                (zerop (% count 20))
 110                gnus-verbose-backends
 111                (message "nnbabyl: Receiving headers... %d%%"
 112                         (/ (* count 100) number))))
 113
 114         (and (numberp nnmail-large-newsgroup)
 115              (> number nnmail-large-newsgroup)
 116              gnus-verbose-backends
 117              (message "nnbabyl: Receiving headers...done"))
 118
 119         ;; Fold continuation lines.
 120         (set-buffer nntp-server-buffer)
 121         (goto-char (point-min))
 122         (while (re-search-forward "\\(\r?\n[ \t]+\\)+" nil t)
 123           (replace-match " " t t))
 124         'headers))))
 125
 126 (defun nnbabyl-open-server (server &optional defs)
 127   (nnheader-init-server-buffer)
 128   (if (equal server nnbabyl-current-server)
 129       t
 130     (if nnbabyl-current-server
 131         (setq nnbabyl-server-alist
 132               (cons (list nnbabyl-current-server
 133                           (nnheader-save-variables nnbabyl-server-variables))
 134                     nnbabyl-server-alist)))
 135     (let ((state (assoc server nnbabyl-server-alist)))
 136       (if state
 137           (progn
 138             (nnheader-restore-variables (nth 1 state))
 139             (setq nnbabyl-server-alist (delq state nnbabyl-server-alist)))
 140         (nnheader-set-init-variables nnbabyl-server-variables defs)))
 141     (setq nnbabyl-current-server server)))
 142
 143 (defun nnbabyl-close-server (&optional server)
 144   t)
 145
 146 (defun nnbabyl-server-opened (&optional server)
 147   (and (equal server nnbabyl-current-server)
 148        nnbabyl-mbox-buffer
 149        (buffer-name nnbabyl-mbox-buffer)
 150        nntp-server-buffer
 151        (buffer-name nntp-server-buffer)))
 152
 153 (defun nnbabyl-status-message (&optional server)
 154   nnbabyl-status-string)
 155
 156 (defun nnbabyl-request-article (article &optional newsgroup server buffer)
 157   (nnbabyl-possibly-change-newsgroup newsgroup)
 158   (if (stringp article)
 159       nil
 160     (save-excursion
 161       (set-buffer nnbabyl-mbox-buffer)
 162       (goto-char (point-min))
 163       (if (search-forward (nnbabyl-article-string article) nil t)
 164           (let (start stop)
 165             (re-search-backward (concat "^" nnbabyl-mail-delimiter) nil t)
 166             (while (and (not (looking-at ".+:"))
 167                         (zerop (forward-line 1))))
 168             (setq start (point))
 169             (or (and (re-search-forward
 170                       (concat "^" nnbabyl-mail-delimiter) nil t)
 171                      (forward-line -1))
 172                 (goto-char (point-max)))
 173             (setq stop (point))
 174             (let ((nntp-server-buffer (or buffer nntp-server-buffer)))
 175               (set-buffer nntp-server-buffer)
 176               (erase-buffer)
 177               (insert-buffer-substring nnbabyl-mbox-buffer start stop)
 178               (goto-char (point-min))
 179               (if (search-forward "\n*** EOOH ***" nil t)
 180                   (progn
 181                     (delete-region (progn (beginning-of-line) (point))
 182                                    (or (search-forward "\n\n" nil t)
 183                                        (point)))))
 184               t))))))
 185
 186 (defun nnbabyl-request-group (group &optional server dont-check)
 187   (save-excursion
 188     (if (nnbabyl-possibly-change-newsgroup group)
 189         (if dont-check
 190             t
 191           (nnbabyl-get-new-mail group)
 192           (save-excursion
 193             (set-buffer nntp-server-buffer)
 194             (erase-buffer)
 195             (let ((active (assoc group nnbabyl-group-alist)))
 196               (insert (format "211 %d %d %d %s\n"
 197                               (1+ (- (cdr (car (cdr active)))
 198                                      (car (car (cdr active)))))
 199                               (car (car (cdr active)))
 200                               (cdr (car (cdr active)))
 201                               (car active))))
 202             t)))))
 203
 204 (defun nnbabyl-close-group (group &optional server)
 205   t)
 206
 207 (defun nnbabyl-request-create-group (group &optional server)
 208   (nnmail-activate 'nnbabyl)
 209   (or (assoc group nnbabyl-group-alist)
 210       (let (active)
 211         (setq nnbabyl-group-alist (cons (list group (setq active (cons 1 0)))
 212                                         nnbabyl-group-alist))
 213         (nnmail-save-active nnbabyl-group-alist nnbabyl-active-file)))
 214   t)
 215
 216 (defun nnbabyl-request-list (&optional server)
 217   (if server (nnbabyl-get-new-mail))
 218   (save-excursion
 219     (or (nnmail-find-file nnbabyl-active-file)
 220         (progn
 221           (setq nnbabyl-group-alist (nnmail-get-active))
 222           (nnmail-save-active nnbabyl-group-alist nnbabyl-active-file)
 223           (nnmail-find-file nnbabyl-active-file)))))
 224
 225 (defun nnbabyl-request-newgroups (date &optional server)
 226   (nnbabyl-request-list server))
 227
 228 (defun nnbabyl-request-list-newsgroups (&optional server)
 229   (setq nnbabyl-status-string "nnbabyl: LIST NEWSGROUPS is not implemented.")
 230   nil)
 231
 232 (defun nnbabyl-request-post (&optional server)
 233   (mail-send-and-exit nil))
 234
 235 (defalias 'nnbabyl-request-post-buffer 'nnmail-request-post-buffer)
 236
 237 (defun nnbabyl-request-expire-articles
 238   (articles newsgroup &optional server force)
 239   (nnbabyl-possibly-change-newsgroup newsgroup)
 240   (let* ((days (or (and nnmail-expiry-wait-function
 241                         (funcall nnmail-expiry-wait-function newsgroup))
 242                    nnmail-expiry-wait))
 243          (is-old t)
 244          rest)
 245     (nnmail-activate 'nnbabyl)
 246
 247     (save-excursion
 248       (set-buffer nnbabyl-mbox-buffer)
 249       (set-text-properties (point-min) (point-max) nil)
 250       (while (and articles is-old)
 251         (goto-char (point-min))
 252         (if (search-forward (nnbabyl-article-string (car articles)) nil t)
 253             (if (or force
 254                     (setq is-old
 255                           (> (nnmail-days-between
 256                               (current-time-string)
 257                               (buffer-substring
 258                                (point) (progn (end-of-line) (point))))
 259                              days)))
 260                 (progn
 261                   (and gnus-verbose-backends
 262                        (message "Deleting article %s..." (car articles)))
 263                   (nnbabyl-delete-mail))
 264               (setq rest (cons (car articles) rest))))
 265         (setq articles (cdr articles)))
 266       (save-buffer)
 267       ;; Find the lowest active article in this group.
 268       (let ((active (nth 1 (assoc newsgroup nnbabyl-group-alist))))
 269         (goto-char (point-min))
 270         (while (and (not (search-forward
 271                           (nnbabyl-article-string (car active)) nil t))
 272                     (<= (car active) (cdr active)))
 273           (setcar active (1+ (car active)))
 274           (goto-char (point-min))))
 275       (nnmail-save-active nnbabyl-group-alist nnbabyl-active-file)
 276       (nconc rest articles))))
 277
 278 (defun nnbabyl-request-move-article
 279   (article group server accept-form &optional last)
 280   (nnbabyl-possibly-change-newsgroup group)
 281   (let ((buf (get-buffer-create " *nnbabyl move*"))
 282         result)
 283     (and
 284      (nnbabyl-request-article article group server)
 285      (save-excursion
 286        (set-buffer buf)
 287        (insert-buffer-substring nntp-server-buffer)
 288        (goto-char (point-min))
 289        (if (re-search-forward
 290             "^X-Gnus-Newsgroup:"
 291             (save-excursion (search-forward "\n\n" nil t) (point)) t)
 292            (delete-region (progn (beginning-of-line) (point))
 293                           (progn (forward-line 1) (point))))
 294        (setq result (eval accept-form))
 295        (kill-buffer (current-buffer))
 296        result)
 297      (save-excursion
 298        (set-buffer nnbabyl-mbox-buffer)
 299        (goto-char (point-min))
 300        (if (search-forward (nnbabyl-article-string article) nil t)
 301            (nnbabyl-delete-mail))
 302        (and last (save-buffer))))
 303     result))
 304
 305 (defun nnbabyl-request-accept-article (group &optional last)
 306   (let ((buf (current-buffer))
 307         result beg)
 308     (and
 309      (nnmail-activate 'nnbabyl)
 310      (save-excursion
 311        (goto-char (point-min))
 312        (search-forward "\n\n" nil t)
 313        (forward-line -1)
 314        (save-excursion
 315          (while (re-search-backward "^X-Gnus-Newsgroup: " beg t)
 316            (delete-region (point) (progn (forward-line 1) (point)))))
 317        (let ((nnmail-split-methods
 318               (if (stringp group) (list (list group ""))
 319                 nnmail-split-methods)))
 320          (setq result (car (nnbabyl-save-mail))))
 321        (set-buffer nnbabyl-mbox-buffer)
 322        (goto-char (point-max))
 323        (search-backward "\n\^_")
 324        (goto-char (match-end 0))
 325        (insert-buffer buf)
 326        (and last (progn
 327                    (save-buffer)
 328                    (nnmail-save-active
 329                     nnbabyl-group-alist nnbabyl-active-file)))
 330        result))))
 331
 332 (defun nnbabyl-request-replace-article (article group buffer)
 333   (nnbabyl-possibly-change-newsgroup group)
 334   (save-excursion
 335     (set-buffer nnbabyl-mbox-buffer)
 336     (goto-char (point-min))
 337     (if (not (search-forward (nnbabyl-article-string article) nil t))
 338         nil
 339       (nnbabyl-delete-mail t t)
 340       (insert-buffer-substring buffer)
 341       (save-buffer)
 342       t)))
 343
 344 \f
 345 ;;; Low-Level Interface
 346
 347 ;; If FORCE, delete article no matter how many X-Gnus-Newsgroup
 348 ;; headers there are. If LEAVE-DELIM, don't delete the Unix mbox
 349 ;; delimeter line.
 350 (defun nnbabyl-delete-mail (&optional force leave-delim)
 351   ;; Delete the current X-Gnus-Newsgroup line.
 352   (or force
 353       (delete-region
 354        (progn (beginning-of-line) (point))
 355        (progn (forward-line 1) (point))))
 356   ;; Beginning of the article.
 357   (save-excursion
 358     (save-restriction
 359       (widen)
 360       (narrow-to-region
 361        (save-excursion
 362          (re-search-backward (concat "^" nnbabyl-mail-delimiter) nil t)
 363          (if leave-delim (progn (forward-line 1) (point))
 364            (match-beginning 0)))
 365        (progn
 366          (forward-line 1)
 367          (or (and (re-search-forward (concat "^" nnbabyl-mail-delimiter)
 368                                      nil t)
 369                   (if (and (not (bobp)) leave-delim)
 370                       (progn (forward-line -2) (point))
 371                     (match-beginning 0)))
 372              (point-max))))
 373       (goto-char (point-min))
 374       ;; Only delete the article if no other groups owns it as well.
 375       (if (or force (not (re-search-forward "^X-Gnus-Newsgroup: " nil t)))
 376           (delete-region (point-min) (point-max))))))
 377
 378 (defun nnbabyl-possibly-change-newsgroup (newsgroup)
 379   (if (or (not nnbabyl-mbox-buffer)
 380           (not (buffer-name nnbabyl-mbox-buffer)))
 381       (save-excursion (nnbabyl-read-mbox)))
 382   (or nnbabyl-group-alist
 383       (nnmail-activate 'nnbabyl))
 384   (if newsgroup
 385       (if (assoc newsgroup nnbabyl-group-alist)
 386           (setq nnbabyl-current-group newsgroup)
 387         (setq nnbabyl-status-string "No such group in file")
 388         nil)))
 389
 390 (defun nnbabyl-article-string (article)
 391   (concat "\nX-Gnus-Newsgroup: " nnbabyl-current-group ":"
 392           (int-to-string article) " "))
 393
 394 (defun nnbabyl-insert-lines ()
 395   "Insert how many lines and chars there are in the body of the mail."
 396   (let (lines chars)
 397     (save-excursion
 398       (goto-char (point-min))
 399       (if (search-forward "\n\n" nil t)
 400           (progn
 401             ;; There may be an EOOH line here...
 402             (if (looking-at "\\*\\*\\* EOOH \\*\\*\\*")
 403                 (search-forward "\n\n" nil t))
 404             (setq chars (- (point-max) (point)))
 405             (setq lines (- (count-lines (point) (point-max)) 1))
 406             ;; Move back to the end of the headers.
 407             (goto-char (point-min))
 408             (search-forward "\n\n" nil t)
 409             (forward-char -1)
 410             (save-excursion
 411               (if (re-search-backward "^Lines: " nil t)
 412                   (delete-region (point) (progn (forward-line 1) (point)))))
 413             (insert (format "Lines: %d\n" lines))
 414             chars)))))
 415
 416 (defun nnbabyl-save-mail ()
 417   ;; Called narrowed to an article.
 418   (let ((group-art (nreverse (nnmail-article-group 'nnbabyl-active-number))))
 419     (nnbabyl-insert-lines)
 420     (nnmail-insert-xref group-art)
 421     (nnbabyl-insert-newsgroup-line group-art)
 422     (run-hooks 'nnbabyl-prepare-save-mail-hook)
 423     group-art))
 424
 425 (defun nnbabyl-insert-newsgroup-line (group-art)
 426   (save-excursion
 427     (goto-char (point-min))
 428     (while (looking-at "From ")
 429       (replace-match "Mail-from: From " t t)
 430       (forward-line 1))
 431     ;; If there is a C-l at the beginning of the narrowed region, this
 432     ;; isn't really a "save", but rather a "scan".
 433     (goto-char (point-min))
 434     (or (looking-at "\^L")
 435         (save-excursion
 436           (insert "\^L\n0, unseen,,\n*** EOOH ***\n")
 437           (goto-char (point-max))
 438           (insert "\^_\n")))
 439     (if (search-forward "\n\n" nil t)
 440         (progn
 441           (forward-char -1)
 442           (while group-art
 443             (insert (format "X-Gnus-Newsgroup: %s:%d   %s\n"
 444                             (car (car group-art)) (cdr (car group-art))
 445                             (current-time-string)))
 446             (setq group-art (cdr group-art)))))
 447     t))
 448
 449 (defun nnbabyl-active-number (group)
 450   ;; Find the next article number in GROUP.
 451   (let ((active (car (cdr (assoc group nnbabyl-group-alist)))))
 452     (if active
 453         (setcdr active (1+ (cdr active)))
 454       ;; This group is new, so we create a new entry for it.
 455       ;; This might be a bit naughty... creating groups on the drop of
 456       ;; a hat, but I don't know...
 457       (setq nnbabyl-group-alist (cons (list group (setq active (cons 1 1)))
 458                                       nnbabyl-group-alist)))
 459     (cdr active)))
 460
 461 (defun nnbabyl-read-mbox ()
 462   (nnmail-activate 'nnbabyl)
 463   (or (file-exists-p nnbabyl-mbox-file)
 464       (save-excursion
 465         (set-buffer (setq nnbabyl-mbox-buffer
 466                           (create-file-buffer nnbabyl-mbox-file)))
 467         (setq buffer-file-name nnbabyl-mbox-file)
 468         (insert "BABYL OPTIONS:\n\n\^_")
 469         (write-region (point-min) (point-max) nnbabyl-mbox-file t 'nomesg)))
 470
 471   (if (and nnbabyl-mbox-buffer
 472            (buffer-name nnbabyl-mbox-buffer)
 473            (save-excursion
 474              (set-buffer nnbabyl-mbox-buffer)
 475              (= (buffer-size) (nth 7 (file-attributes nnbabyl-mbox-file)))))
 476       ()
 477     (save-excursion
 478       (let ((delim (concat "^" nnbabyl-mail-delimiter))
 479             start end)
 480         (set-buffer (setq nnbabyl-mbox-buffer
 481                           (nnheader-find-file-noselect
 482                            nnbabyl-mbox-file nil 'raw)))
 483         (buffer-disable-undo (current-buffer))
 484         (widen)
 485         (setq buffer-read-only nil)
 486         (fundamental-mode)
 487
 488         (goto-char (point-min))
 489         (re-search-forward delim nil t)
 490         (setq start (match-end 0))
 491         (while (re-search-forward delim nil t)
 492           (setq end (match-end 0))
 493           (or (search-backward "\nX-Gnus-Newsgroup: " start t)
 494               (progn
 495                 (goto-char end)
 496                 (save-excursion
 497                   (save-restriction
 498                     (goto-char start)
 499                     (narrow-to-region start end)
 500                     (nnbabyl-save-mail)
 501                     (setq end (point-max))))))
 502           (goto-char (setq start end)))
 503         (and (buffer-modified-p (current-buffer)) (save-buffer))
 504         (nnmail-save-active nnbabyl-group-alist nnbabyl-active-file)))))
 505
 506 (defun nnbabyl-remove-incoming-delims ()
 507   (goto-char (point-min))
 508   (while (search-forward "\^_" nil t)
 509     (replace-match "?" t t)))
 510
 511 (defun nnbabyl-get-new-mail (&optional group)
 512   "Read new incoming mail."
 513   (let* ((spools (nnmail-get-spool-files group))
 514          (group-in group)
 515          incoming incomings)
 516     (nnbabyl-read-mbox)
 517     (if (or (not nnbabyl-get-new-mail) (not nnmail-spool-file))
 518         ()
 519       ;; We go through all the existing spool files and split the
 520       ;; mail from each.
 521       (while spools
 522         (and
 523          (file-exists-p (car spools))
 524          (> (nth 7 (file-attributes (car spools))) 0)
 525          (progn
 526            (and gnus-verbose-backends
 527                 (message "nnbabyl: Reading incoming mail..."))
 528            (if (not (setq incoming
 529                           (nnmail-move-inbox
 530                            (car spools)
 531                            (concat nnbabyl-mbox-file "-Incoming"))))
 532                ()
 533              (setq incomings (cons incoming incomings))
 534              (save-excursion
 535                (setq group (nnmail-get-split-group (car spools) group-in))
 536                (let* ((nnmail-prepare-incoming-hook
 537                        (cons 'nnbabyl-remove-incoming-delims
 538                              nnmail-prepare-incoming-hook))
 539                       in-buf)
 540                  (setq in-buf (nnmail-split-incoming
 541                                incoming 'nnbabyl-save-mail t group))
 542                  (set-buffer in-buf)
 543                  (goto-char (point-min))
 544                  (while (search-forward "\n\^_\n" nil t)
 545                    (delete-char -1))
 546                  (set-buffer nnbabyl-mbox-buffer)
 547                  (goto-char (point-max))
 548                  (search-backward "\n\^_" nil t)
 549                  (goto-char (match-end 0))
 550                  (insert-buffer-substring in-buf)
 551                  (kill-buffer in-buf))))))
 552         (setq spools (cdr spools)))
 553       ;; If we did indeed read any incoming spools, we save all info.
 554       (and (buffer-modified-p nnbabyl-mbox-buffer)
 555            (save-excursion
 556              (nnmail-save-active nnbabyl-group-alist nnbabyl-active-file)
 557              (set-buffer nnbabyl-mbox-buffer)
 558              (save-buffer)))
 559       (if incomings (run-hooks 'nnmail-read-incoming-hook))
 560       (while incomings
 561         (setq incoming (car incomings))
 562         (and nnmail-delete-incoming
 563              (file-exists-p incoming)
 564              (file-writable-p incoming)
 565              (delete-file incoming))
 566         (setq incomings (cdr incomings))))))
 567
 568 (provide 'nnbabyl)
 569
 570 ;;; nnbabyl.el ends here