cgit.sxemacs.org Git - gnus/blob - lisp/nnbabyl.el

   1 ;;; nnbabyl.el --- rmail mbox access for Gnus
   2 ;; Copyright (C) 1995,96 Free Software Foundation, Inc.
   3
   4 ;; Author: Lars Magne Ingebrigtsen <larsi@ifi.uio.no>
   5 ;;      Masanobu UMEDA <umerin@flab.flab.fujitsu.junet>
   6 ;; Keywords: news, mail
   7
   8 ;; This file is part of GNU Emacs.
   9
  10 ;; GNU Emacs is free software; you can redistribute it and/or modify
  11 ;; it under the terms of the GNU General Public License as published by
  12 ;; the Free Software Foundation; either version 2, or (at your option)
  13 ;; any later version.
  14
  15 ;; GNU Emacs is distributed in the hope that it will be useful,
  16 ;; but WITHOUT ANY WARRANTY; without even the implied warranty of
  17 ;; MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.  See the
  18 ;; GNU General Public License for more details.
  19
  20 ;; You should have received a copy of the GNU General Public License
  21 ;; along with GNU Emacs; see the file COPYING.  If not, write to the
  22 ;; Free Software Foundation, Inc., 59 Temple Place - Suite 330,
  23 ;; Boston, MA 02111-1307, USA.
  24
  25 ;;; Commentary:
  26
  27 ;; For an overview of what the interface functions do, please see the
  28 ;; Gnus sources.
  29
  30 ;;; Code:
  31
  32 (require 'nnheader)
  33 (require 'rmail)
  34 (require 'nnmail)
  35 (eval-when-compile (require 'cl))
  36
  37 (defvar nnbabyl-mbox-file (expand-file-name "~/RMAIL")
  38   "The name of the rmail box file in the users home directory.")
  39
  40 (defvar nnbabyl-active-file (expand-file-name "~/.rmail-active")
  41   "The name of the active file for the rmail box.")
  42
  43 (defvar nnbabyl-get-new-mail t
  44   "If non-nil, nnbabyl will check the incoming mail file and split the mail.")
  45
  46 (defvar nnbabyl-prepare-save-mail-hook nil
  47   "Hook run narrowed to an article before saving.")
  48
  49 \f
  50
  51 (defvar nnbabyl-mail-delimiter "\^_")
  52
  53 (defconst nnbabyl-version "nnbabyl 1.0"
  54   "nnbabyl version.")
  55
  56 (defvar nnbabyl-mbox-buffer nil)
  57 (defvar nnbabyl-current-group nil)
  58 (defvar nnbabyl-status-string "")
  59 (defvar nnbabyl-group-alist nil)
  60 (defvar nnbabyl-active-timestamp nil)
  61
  62 (defvar nnbabyl-previous-buffer-mode nil)
  63
  64 (eval-and-compile
  65   (autoload 'gnus-set-text-properties "gnus-ems"))
  66
  67 \f
  68
  69 (defvar nnbabyl-current-server nil)
  70 (defvar nnbabyl-server-alist nil)
  71 (defvar nnbabyl-server-variables
  72   `((nnbabyl-mbox-file ,nnbabyl-mbox-file)
  73     (nnbabyl-active-file ,nnbabyl-active-file)
  74     (nnbabyl-get-new-mail ,nnbabyl-get-new-mail)
  75     (nnbabyl-current-group nil)
  76     (nnbabyl-status-string "")
  77     (nnbabyl-previous-buffer-mode nil)
  78     (nnbabyl-group-alist nil)))
  79
  80 \f
  81
  82 ;;; Interface functions
  83
  84 (defun nnbabyl-retrieve-headers (sequence &optional newsgroup server fetch-old)
  85   (save-excursion
  86     (set-buffer nntp-server-buffer)
  87     (erase-buffer)
  88     (let ((number (length sequence))
  89           (count 0)
  90           article art-string start stop)
  91       (nnbabyl-possibly-change-newsgroup newsgroup)
  92       (while sequence
  93         (setq article (car sequence))
  94         (setq art-string (nnbabyl-article-string article))
  95         (set-buffer nnbabyl-mbox-buffer)
  96         (if (or (search-forward art-string nil t)
  97                 (search-backward art-string nil t))
  98             (progn
  99               (re-search-backward (concat "^" nnbabyl-mail-delimiter) nil t)
 100               (while (and (not (looking-at ".+:"))
 101                           (zerop (forward-line 1))))
 102               (setq start (point))
 103               (search-forward "\n\n" nil t)
 104               (setq stop (1- (point)))
 105               (set-buffer nntp-server-buffer)
 106               (insert "221 " (int-to-string article) " Article retrieved.\n")
 107               (insert-buffer-substring nnbabyl-mbox-buffer start stop)
 108               (goto-char (point-max))
 109               (insert ".\n")))
 110         (setq sequence (cdr sequence))
 111         (setq count (1+ count))
 112         (and (numberp nnmail-large-newsgroup)
 113              (> number nnmail-large-newsgroup)
 114              (zerop (% count 20))
 115              (nnheader-message 5 "nnbabyl: Receiving headers... %d%%"
 116                                (/ (* count 100) number))))
 117
 118       (and (numberp nnmail-large-newsgroup)
 119            (> number nnmail-large-newsgroup)
 120            (nnheader-message 5 "nnbabyl: Receiving headers...done"))
 121
 122       (set-buffer nntp-server-buffer)
 123       (nnheader-fold-continuation-lines)
 124       'headers)))
 125
 126 (defun nnbabyl-open-server (server &optional defs)
 127   (nnheader-change-server 'nnbabyl server defs)
 128   (cond
 129    ((not (file-exists-p nnbabyl-mbox-file))
 130     (nnbabyl-close-server)
 131     (nnheader-report 'nnbabyl "No such file: %s" nnbabyl-mbox-file))
 132    ((file-directory-p nnbabyl-mbox-file)
 133     (nnbabyl-close-server)
 134     (nnheader-report 'nnbabyl "Not a regular file: %s" nnbabyl-mbox-file))
 135    (t
 136     (nnheader-report 'nnbabyl "Opened server %s using mbox %s" server
 137                      nnbabyl-mbox-file)
 138     t)))
 139
 140 (defun nnbabyl-close-server (&optional server)
 141   ;; Restore buffer mode.
 142   (when (and (nnbabyl-server-opened)
 143              nnbabyl-previous-buffer-mode)
 144     (save-excursion
 145       (set-buffer nnbabyl-mbox-buffer)
 146       (narrow-to-region
 147        (car (car nnbabyl-previous-buffer-mode))
 148        (cdr (car nnbabyl-previous-buffer-mode)))
 149       (funcall (cdr nnbabyl-previous-buffer-mode))))
 150   (setq nnbabyl-current-server nil
 151         nnbabyl-mbox-buffer nil)
 152   t)
 153
 154 (defun nnbabyl-server-opened (&optional server)
 155   (and (equal server nnbabyl-current-server)
 156        nnbabyl-mbox-buffer
 157        (buffer-name nnbabyl-mbox-buffer)
 158        nntp-server-buffer
 159        (buffer-name nntp-server-buffer)))
 160
 161 (defun nnbabyl-status-message (&optional server)
 162   nnbabyl-status-string)
 163
 164 (defun nnbabyl-request-article (article &optional newsgroup server buffer)
 165   (nnbabyl-possibly-change-newsgroup newsgroup)
 166   (save-excursion
 167     (set-buffer nnbabyl-mbox-buffer)
 168     (goto-char (point-min))
 169     (if (search-forward (nnbabyl-article-string article) nil t)
 170         (let (start stop summary-line)
 171           (re-search-backward (concat "^" nnbabyl-mail-delimiter) nil t)
 172           (while (and (not (looking-at ".+:"))
 173                       (zerop (forward-line 1))))
 174           (setq start (point))
 175           (or (and (re-search-forward
 176                     (concat "^" nnbabyl-mail-delimiter) nil t)
 177                    (forward-line -1))
 178               (goto-char (point-max)))
 179           (setq stop (point))
 180           (let ((nntp-server-buffer (or buffer nntp-server-buffer)))
 181             (set-buffer nntp-server-buffer)
 182             (erase-buffer)
 183             (insert-buffer-substring nnbabyl-mbox-buffer start stop)
 184             (goto-char (point-min))
 185             ;; If there is an EOOH header, then we have to remove some
 186             ;; duplicated headers.
 187             (setq summary-line (looking-at "Summary-line:"))
 188             (when (search-forward "\n*** EOOH ***" nil t)
 189               (if summary-line
 190                   ;; The headers to be deleted are located before the
 191                   ;; EOOH line...
 192                   (delete-region (point-min) (progn (forward-line 1)
 193                   (point)))
 194                 ;; ...or after.
 195                 (delete-region (progn (beginning-of-line) (point))
 196                                (or (search-forward "\n\n" nil t)
 197                                    (point)))))
 198             (if (numberp article)
 199                 (cons nnbabyl-current-group article)
 200               (nnbabyl-article-group-number)))))))
 201
 202 (defun nnbabyl-request-group (group &optional server dont-check)
 203   (let ((active (cadr (assoc group nnbabyl-group-alist))))
 204     (save-excursion
 205       (cond
 206        ((null active)
 207         (nnheader-report 'nnbabyl "No such group: %s" group))
 208        ((null (nnbabyl-possibly-change-newsgroup group))
 209         (nnheader-report 'nnbabyl "No such group: %s" group))
 210        (dont-check
 211         (nnheader-report 'nnbabyl "Selected group %s" group)
 212         t)
 213        (t
 214         (nnheader-report 'nnbabyl "Selected group %s" group)
 215         (nnheader-insert "211 %d %d %d %s\n"
 216                          (1+ (- (cdr active) (car active)))
 217                          (car active) (cdr active) group)
 218         t)))))
 219
 220 (defun nnbabyl-request-scan (&optional group server)
 221   (nnbabyl-read-mbox)
 222   (nnmail-get-new-mail
 223    'nnbabyl
 224    (lambda ()
 225      (save-excursion
 226        (set-buffer nnbabyl-mbox-buffer)
 227        (save-buffer)))
 228    nnbabyl-mbox-file group
 229    (lambda ()
 230      (save-excursion
 231        (let ((in-buf (current-buffer)))
 232          (goto-char (point-min))
 233          (while (search-forward "\n\^_\n" nil t)
 234            (delete-char -1))
 235          (set-buffer nnbabyl-mbox-buffer)
 236          (goto-char (point-max))
 237          (search-backward "\n\^_" nil t)
 238          (goto-char (match-end 0))
 239          (insert-buffer-substring in-buf))))))
 240
 241 (defun nnbabyl-close-group (group &optional server)
 242   t)
 243
 244 (defun nnbabyl-request-create-group (group &optional server)
 245   (nnmail-activate 'nnbabyl)
 246   (or (assoc group nnbabyl-group-alist)
 247       (let (active)
 248         (setq nnbabyl-group-alist (cons (list group (setq active (cons 1 0)))
 249                                         nnbabyl-group-alist))
 250         (nnmail-save-active nnbabyl-group-alist nnbabyl-active-file)))
 251   t)
 252
 253 (defun nnbabyl-request-list (&optional server)
 254   (save-excursion
 255     (or (nnmail-find-file nnbabyl-active-file)
 256         (progn
 257           (setq nnbabyl-group-alist (nnmail-get-active))
 258           (nnmail-save-active nnbabyl-group-alist nnbabyl-active-file)
 259           (nnmail-find-file nnbabyl-active-file)))))
 260
 261 (defun nnbabyl-request-newgroups (date &optional server)
 262   (nnbabyl-request-list server))
 263
 264 (defun nnbabyl-request-list-newsgroups (&optional server)
 265   (nnheader-report 'nnbabyl "nnbabyl: LIST NEWSGROUPS is not implemented."))
 266
 267 (defun nnbabyl-request-expire-articles
 268   (articles newsgroup &optional server force)
 269   (nnbabyl-possibly-change-newsgroup newsgroup)
 270   (let* ((is-old t)
 271          rest)
 272     (nnmail-activate 'nnbabyl)
 273
 274     (save-excursion
 275       (set-buffer nnbabyl-mbox-buffer)
 276       (gnus-set-text-properties (point-min) (point-max) nil)
 277       (while (and articles is-old)
 278         (goto-char (point-min))
 279         (if (search-forward (nnbabyl-article-string (car articles)) nil t)
 280             (if (setq is-old
 281                       (nnmail-expired-article-p
 282                        newsgroup
 283                        (buffer-substring
 284                         (point) (progn (end-of-line) (point))) force))
 285                 (progn
 286                   (nnheader-message 5 "Deleting article %d in %s..."
 287                                     (car articles) newsgroup)
 288                   (nnbabyl-delete-mail))
 289               (setq rest (cons (car articles) rest))))
 290         (setq articles (cdr articles)))
 291       (save-buffer)
 292       ;; Find the lowest active article in this group.
 293       (let ((active (nth 1 (assoc newsgroup nnbabyl-group-alist))))
 294         (goto-char (point-min))
 295         (while (and (not (search-forward
 296                           (nnbabyl-article-string (car active)) nil t))
 297                     (<= (car active) (cdr active)))
 298           (setcar active (1+ (car active)))
 299           (goto-char (point-min))))
 300       (nnmail-save-active nnbabyl-group-alist nnbabyl-active-file)
 301       (nconc rest articles))))
 302
 303 (defun nnbabyl-request-move-article
 304   (article group server accept-form &optional last)
 305   (nnbabyl-possibly-change-newsgroup group)
 306   (let ((buf (get-buffer-create " *nnbabyl move*"))
 307         result)
 308     (and
 309      (nnbabyl-request-article article group server)
 310      (save-excursion
 311        (set-buffer buf)
 312        (insert-buffer-substring nntp-server-buffer)
 313        (goto-char (point-min))
 314        (if (re-search-forward
 315             "^X-Gnus-Newsgroup:"
 316             (save-excursion (search-forward "\n\n" nil t) (point)) t)
 317            (delete-region (progn (beginning-of-line) (point))
 318                           (progn (forward-line 1) (point))))
 319        (setq result (eval accept-form))
 320        (kill-buffer (current-buffer))
 321        result)
 322      (save-excursion
 323        (set-buffer nnbabyl-mbox-buffer)
 324        (goto-char (point-min))
 325        (if (search-forward (nnbabyl-article-string article) nil t)
 326            (nnbabyl-delete-mail))
 327        (and last (save-buffer))))
 328     result))
 329
 330 (defun nnbabyl-request-accept-article (group &optional last)
 331   (let ((buf (current-buffer))
 332         result beg)
 333     (and
 334      (nnmail-activate 'nnbabyl)
 335      (save-excursion
 336        (goto-char (point-min))
 337        (search-forward "\n\n" nil t)
 338        (forward-line -1)
 339        (save-excursion
 340          (while (re-search-backward "^X-Gnus-Newsgroup: " beg t)
 341            (delete-region (point) (progn (forward-line 1) (point)))))
 342        (let ((nnmail-split-methods
 343               (if (stringp group) (list (list group ""))
 344                 nnmail-split-methods)))
 345          (setq result (car (nnbabyl-save-mail))))
 346        (set-buffer nnbabyl-mbox-buffer)
 347        (goto-char (point-max))
 348        (search-backward "\n\^_")
 349        (goto-char (match-end 0))
 350        (insert-buffer-substring buf)
 351        (and last (progn
 352                    (save-buffer)
 353                    (nnmail-save-active
 354                     nnbabyl-group-alist nnbabyl-active-file)))
 355        result))))
 356
 357 (defun nnbabyl-request-replace-article (article group buffer)
 358   (nnbabyl-possibly-change-newsgroup group)
 359   (save-excursion
 360     (set-buffer nnbabyl-mbox-buffer)
 361     (goto-char (point-min))
 362     (if (not (search-forward (nnbabyl-article-string article) nil t))
 363         nil
 364       (nnbabyl-delete-mail t t)
 365       (insert-buffer-substring buffer)
 366       (save-buffer)
 367       t)))
 368
 369 (defun nnbabyl-request-delete-group (group &optional force server)
 370   (nnbabyl-possibly-change-newsgroup group)
 371   ;; Delete all articles in GROUP.
 372   (if (not force)
 373       ()                                ; Don't delete the articles.
 374     (save-excursion
 375       (set-buffer nnbabyl-mbox-buffer)
 376       (goto-char (point-min))
 377       ;; Delete all articles in this group.
 378       (let ((ident (concat "\nX-Gnus-Newsgroup: " nnbabyl-current-group ":"))
 379             found)
 380         (while (search-forward ident nil t)
 381           (setq found t)
 382           (nnbabyl-delete-mail))
 383         (and found (save-buffer)))))
 384   ;; Remove the group from all structures.
 385   (setq nnbabyl-group-alist
 386         (delq (assoc group nnbabyl-group-alist) nnbabyl-group-alist)
 387         nnbabyl-current-group nil)
 388   ;; Save the active file.
 389   (nnmail-save-active nnbabyl-group-alist nnbabyl-active-file)
 390   t)
 391
 392 (defun nnbabyl-request-rename-group (group new-name &optional server)
 393   (nnbabyl-possibly-change-newsgroup group)
 394   (save-excursion
 395     (set-buffer nnbabyl-mbox-buffer)
 396     (goto-char (point-min))
 397     (let ((ident (concat "\nX-Gnus-Newsgroup: " nnbabyl-current-group ":"))
 398           (new-ident (concat "\nX-Gnus-Newsgroup: " new-name ":"))
 399           found)
 400       (while (search-forward ident nil t)
 401         (replace-match new-ident t t)
 402         (setq found t))
 403       (and found (save-buffer))))
 404   (let ((entry (assoc group nnbabyl-group-alist)))
 405     (and entry (setcar entry new-name))
 406     (setq nnbabyl-current-group nil)
 407     ;; Save the new group alist.
 408     (nnmail-save-active nnbabyl-group-alist nnbabyl-active-file)
 409     t))
 410
 411 \f
 412 ;;; Internal functions.
 413
 414 ;; If FORCE, delete article no matter how many X-Gnus-Newsgroup
 415 ;; headers there are. If LEAVE-DELIM, don't delete the Unix mbox
 416 ;; delimiter line.
 417 (defun nnbabyl-delete-mail (&optional force leave-delim)
 418   ;; Delete the current X-Gnus-Newsgroup line.
 419   (or force
 420       (delete-region
 421        (progn (beginning-of-line) (point))
 422        (progn (forward-line 1) (point))))
 423   ;; Beginning of the article.
 424   (save-excursion
 425     (save-restriction
 426       (widen)
 427       (narrow-to-region
 428        (save-excursion
 429          (re-search-backward (concat "^" nnbabyl-mail-delimiter) nil t)
 430          (if leave-delim (progn (forward-line 1) (point))
 431            (match-beginning 0)))
 432        (progn
 433          (forward-line 1)
 434          (or (and (re-search-forward (concat "^" nnbabyl-mail-delimiter)
 435                                      nil t)
 436                   (if (and (not (bobp)) leave-delim)
 437                       (progn (forward-line -2) (point))
 438                     (match-beginning 0)))
 439              (point-max))))
 440       (goto-char (point-min))
 441       ;; Only delete the article if no other groups owns it as well.
 442       (if (or force (not (re-search-forward "^X-Gnus-Newsgroup: " nil t)))
 443           (delete-region (point-min) (point-max))))))
 444
 445 (defun nnbabyl-possibly-change-newsgroup (newsgroup)
 446   (if (or (not nnbabyl-mbox-buffer)
 447           (not (buffer-name nnbabyl-mbox-buffer)))
 448       (save-excursion (nnbabyl-read-mbox)))
 449   (or nnbabyl-group-alist
 450       (nnmail-activate 'nnbabyl))
 451   (if newsgroup
 452       (if (assoc newsgroup nnbabyl-group-alist)
 453           (setq nnbabyl-current-group newsgroup)
 454         (nnheader-report 'nnbabyl "No such group in file"))
 455     t))
 456
 457 (defun nnbabyl-article-string (article)
 458   (if (numberp article)
 459       (concat "\nX-Gnus-Newsgroup: " nnbabyl-current-group ":"
 460               (int-to-string article) " ")
 461     (concat "\nMessage-ID: " article)))
 462
 463 (defun nnbabyl-article-group-number ()
 464   (save-excursion
 465     (goto-char (point-min))
 466     (and (re-search-forward "^X-Gnus-Newsgroup: +\\([^:]+\\):\\([0-9]+\\) "
 467                             nil t)
 468          (cons (buffer-substring (match-beginning 1) (match-end 1))
 469                (string-to-int
 470                 (buffer-substring (match-beginning 2) (match-end 2)))))))
 471
 472 (defun nnbabyl-insert-lines ()
 473   "Insert how many lines and chars there are in the body of the mail."
 474   (let (lines chars)
 475     (save-excursion
 476       (goto-char (point-min))
 477       (if (search-forward "\n\n" nil t)
 478           (progn
 479             ;; There may be an EOOH line here...
 480             (if (looking-at "\\*\\*\\* EOOH \\*\\*\\*")
 481                 (search-forward "\n\n" nil t))
 482             (setq chars (- (point-max) (point)))
 483             (setq lines (- (count-lines (point) (point-max)) 1))
 484             ;; Move back to the end of the headers.
 485             (goto-char (point-min))
 486             (search-forward "\n\n" nil t)
 487             (forward-char -1)
 488             (save-excursion
 489               (if (re-search-backward "^Lines: " nil t)
 490                   (delete-region (point) (progn (forward-line 1) (point)))))
 491             (insert (format "Lines: %d\n" lines))
 492             chars)))))
 493
 494 (defun nnbabyl-save-mail ()
 495   ;; Called narrowed to an article.
 496   (let ((group-art (nreverse (nnmail-article-group 'nnbabyl-active-number))))
 497     (nnbabyl-insert-lines)
 498     (nnmail-insert-xref group-art)
 499     (nnbabyl-insert-newsgroup-line group-art)
 500     (run-hooks 'nnbabyl-prepare-save-mail-hook)
 501     group-art))
 502
 503 (defun nnbabyl-insert-newsgroup-line (group-art)
 504   (save-excursion
 505     (goto-char (point-min))
 506     (while (looking-at "From ")
 507       (replace-match "Mail-from: From " t t)
 508       (forward-line 1))
 509     ;; If there is a C-l at the beginning of the narrowed region, this
 510     ;; isn't really a "save", but rather a "scan".
 511     (goto-char (point-min))
 512     (or (looking-at "\^L")
 513         (save-excursion
 514           (insert "\^L\n0, unseen,,\n*** EOOH ***\n")
 515           (goto-char (point-max))
 516           (insert "\^_\n")))
 517     (if (search-forward "\n\n" nil t)
 518         (progn
 519           (forward-char -1)
 520           (while group-art
 521             (insert (format "X-Gnus-Newsgroup: %s:%d   %s\n"
 522                             (car (car group-art)) (cdr (car group-art))
 523                             (current-time-string)))
 524             (setq group-art (cdr group-art)))))
 525     t))
 526
 527 (defun nnbabyl-active-number (group)
 528   ;; Find the next article number in GROUP.
 529   (let ((active (car (cdr (assoc group nnbabyl-group-alist)))))
 530     (if active
 531         (setcdr active (1+ (cdr active)))
 532       ;; This group is new, so we create a new entry for it.
 533       ;; This might be a bit naughty... creating groups on the drop of
 534       ;; a hat, but I don't know...
 535       (setq nnbabyl-group-alist (cons (list group (setq active (cons 1 1)))
 536                                       nnbabyl-group-alist)))
 537     (cdr active)))
 538
 539 (defun nnbabyl-read-mbox ()
 540   (nnmail-activate 'nnbabyl)
 541   (or (file-exists-p nnbabyl-mbox-file)
 542       (save-excursion
 543         (set-buffer (setq nnbabyl-mbox-buffer
 544                           (create-file-buffer nnbabyl-mbox-file)))
 545         (setq buffer-file-name nnbabyl-mbox-file)
 546         (insert "BABYL OPTIONS:\n\n\^_")
 547         (write-region (point-min) (point-max) nnbabyl-mbox-file t 'nomesg)))
 548
 549   (if (and nnbabyl-mbox-buffer
 550            (buffer-name nnbabyl-mbox-buffer)
 551            (save-excursion
 552              (set-buffer nnbabyl-mbox-buffer)
 553              (= (buffer-size) (nth 7 (file-attributes nnbabyl-mbox-file)))))
 554       ()
 555     (save-excursion
 556       (let ((delim (concat "^" nnbabyl-mail-delimiter))
 557             start end)
 558         (set-buffer (setq nnbabyl-mbox-buffer
 559                           (nnheader-find-file-noselect
 560                            nnbabyl-mbox-file nil 'raw)))
 561         ;; Save buffer mode.
 562         (setq nnbabyl-previous-buffer-mode
 563               (cons (cons (point-min) (point-max))
 564                     major-mode))
 565
 566         (buffer-disable-undo (current-buffer))
 567         (widen)
 568         (setq buffer-read-only nil)
 569         (fundamental-mode)
 570
 571         (goto-char (point-min))
 572         (re-search-forward delim nil t)
 573         (setq start (match-end 0))
 574         (while (re-search-forward delim nil t)
 575           (setq end (match-end 0))
 576           (or (search-backward "\nX-Gnus-Newsgroup: " start t)
 577               (progn
 578                 (goto-char end)
 579                 (save-excursion
 580                   (save-restriction
 581                     (goto-char start)
 582                     (narrow-to-region start end)
 583                     (nnbabyl-save-mail)
 584                     (setq end (point-max))))))
 585           (goto-char (setq start end)))
 586         (and (buffer-modified-p (current-buffer)) (save-buffer))
 587         (nnmail-save-active nnbabyl-group-alist nnbabyl-active-file)))))
 588
 589 (defun nnbabyl-remove-incoming-delims ()
 590   (goto-char (point-min))
 591   (while (search-forward "\^_" nil t)
 592     (replace-match "?" t t)))
 593
 594 (provide 'nnbabyl)
 595
 596 ;;; nnbabyl.el ends here