cgit.sxemacs.org Git - gnus/blob - lisp/mml1991.el

   1 ;;; mml1991.el --- Old PGP message format (RFC 1991) support for MML
   2
   3 ;; Copyright (C) 1998, 1999, 2000, 2001, 2002, 2003, 2004,
   4 ;;   2005, 2006, 2007, 2008 Free Software Foundation, Inc.
   5
   6 ;; Author: Sascha Ldecke <sascha@meta-x.de>,
   7 ;;      Simon Josefsson <simon@josefsson.org> (Mailcrypt interface, Gnus glue)
   8 ;; Keywords PGP
   9
  10 ;; This file is part of GNU Emacs.
  11
  12 ;; GNU Emacs is free software: you can redistribute it and/or modify
  13 ;; it under the terms of the GNU General Public License as published by
  14 ;; the Free Software Foundation, either version 3 of the License, or
  15 ;; (at your option) any later version.
  16
  17 ;; GNU Emacs is distributed in the hope that it will be useful,
  18 ;; but WITHOUT ANY WARRANTY; without even the implied warranty of
  19 ;; MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.  See the
  20 ;; GNU General Public License for more details.
  21
  22 ;; You should have received a copy of the GNU General Public License
  23 ;; along with GNU Emacs.  If not, see <http://www.gnu.org/licenses/>.
  24
  25 ;;; Commentary:
  26
  27 ;;; Code:
  28
  29 ;; For Emacs < 22.2.
  30 (eval-and-compile
  31   (unless (fboundp 'declare-function) (defmacro declare-function (&rest r))))
  32
  33 (eval-when-compile
  34   (require 'cl)
  35   (require 'mm-util))
  36
  37 (require 'mml-sec)
  38
  39 (defvar mc-pgp-always-sign)
  40
  41 (autoload 'quoted-printable-decode-region "qp")
  42 (autoload 'quoted-printable-encode-region "qp")
  43
  44 (autoload 'mm-decode-content-transfer-encoding "mm-bodies")
  45 (autoload 'mm-encode-content-transfer-encoding "mm-bodies")
  46 (autoload 'message-options-get "message")
  47 (autoload 'message-options-set "message")
  48
  49 (defvar mml1991-use mml2015-use
  50   "The package used for PGP.")
  51
  52 (defvar mml1991-function-alist
  53   '((mailcrypt mml1991-mailcrypt-sign
  54                mml1991-mailcrypt-encrypt)
  55     (gpg mml1991-gpg-sign
  56          mml1991-gpg-encrypt)
  57     (pgg mml1991-pgg-sign
  58          mml1991-pgg-encrypt)
  59     (epg mml1991-epg-sign
  60          mml1991-epg-encrypt))
  61   "Alist of PGP functions.")
  62
  63 (defvar mml1991-verbose mml-secure-verbose
  64   "If non-nil, ask the user about the current operation more verbosely.")
  65
  66 (defvar mml1991-cache-passphrase mml-secure-cache-passphrase
  67   "If t, cache passphrase.")
  68
  69 (defvar mml1991-passphrase-cache-expiry mml-secure-passphrase-cache-expiry
  70   "How many seconds the passphrase is cached.
  71 Whether the passphrase is cached at all is controlled by
  72 `mml1991-cache-passphrase'.")
  73
  74 (defvar mml1991-signers nil
  75   "A list of your own key ID which will be used to sign a message.")
  76
  77 (defvar mml1991-encrypt-to-self nil
  78   "If t, add your own key ID to recipient list when encryption.")
  79
  80 ;;; mailcrypt wrapper
  81
  82 (eval-and-compile
  83   (autoload 'mc-sign-generic "mc-toplev"))
  84
  85 (defvar mml1991-decrypt-function 'mailcrypt-decrypt)
  86 (defvar mml1991-verify-function 'mailcrypt-verify)
  87
  88 (defun mml1991-mailcrypt-sign (cont)
  89   (let ((text (current-buffer))
  90         headers signature
  91         (result-buffer (get-buffer-create "*GPG Result*")))
  92     ;; Save MIME Content[^ ]+: headers from signing
  93     (goto-char (point-min))
  94     (while (looking-at "^Content[^ ]+:") (forward-line))
  95     (unless (bobp)
  96       (setq headers (buffer-string))
  97       (delete-region (point-min) (point)))
  98     (goto-char (point-max))
  99     (unless (bolp)
 100       (insert "\n"))
 101     (quoted-printable-decode-region (point-min) (point-max))
 102     (with-temp-buffer
 103       (setq signature (current-buffer))
 104       (insert-buffer-substring text)
 105       (unless (mc-sign-generic (message-options-get 'message-sender)
 106                                nil nil nil nil)
 107         (unless (> (point-max) (point-min))
 108           (pop-to-buffer result-buffer)
 109           (error "Sign error")))
 110       (goto-char (point-min))
 111       (while (re-search-forward "\r+$" nil t)
 112         (replace-match "" t t))
 113       (quoted-printable-encode-region (point-min) (point-max))
 114       (set-buffer text)
 115       (delete-region (point-min) (point-max))
 116       (if headers (insert headers))
 117       (insert "\n")
 118       (insert-buffer-substring signature)
 119       (goto-char (point-max)))))
 120
 121 (declare-function mc-encrypt-generic "ext:mc-toplev"
 122                   (&optional recipients scheme start end from sign))
 123
 124 (defun mml1991-mailcrypt-encrypt (cont &optional sign)
 125   (let ((text (current-buffer))
 126         (mc-pgp-always-sign
 127          (or mc-pgp-always-sign
 128              sign
 129              (eq t (or (message-options-get 'message-sign-encrypt)
 130                        (message-options-set
 131                         'message-sign-encrypt
 132                         (or (y-or-n-p "Sign the message? ")
 133                             'not))))
 134              'never))
 135         cipher
 136         (result-buffer (get-buffer-create "*GPG Result*")))
 137     ;; Strip MIME Content[^ ]: headers since it will be ASCII ARMOURED
 138     (goto-char (point-min))
 139     (while (looking-at "^Content[^ ]+:") (forward-line))
 140     (unless (bobp)
 141       (delete-region (point-min) (point)))
 142     (mm-with-unibyte-current-buffer
 143       (with-temp-buffer
 144         (setq cipher (current-buffer))
 145         (insert-buffer-substring text)
 146         (unless (mc-encrypt-generic
 147                  (or
 148                   (message-options-get 'message-recipients)
 149                   (message-options-set 'message-recipients
 150                                        (read-string "Recipients: ")))
 151                  nil
 152                  (point-min) (point-max)
 153                  (message-options-get 'message-sender)
 154                  'sign)
 155           (unless (> (point-max) (point-min))
 156             (pop-to-buffer result-buffer)
 157             (error "Encrypt error")))
 158         (goto-char (point-min))
 159         (while (re-search-forward "\r+$" nil t)
 160           (replace-match "" t t))
 161         (set-buffer text)
 162         (delete-region (point-min) (point-max))
 163         ;;(insert "Content-Type: application/pgp-encrypted\n\n")
 164         ;;(insert "Version: 1\n\n")
 165         (insert "\n")
 166         (insert-buffer-substring cipher)
 167         (goto-char (point-max))))))
 168
 169 ;;; gpg wrapper
 170
 171 (eval-and-compile
 172   (autoload 'gpg-sign-cleartext "gpg"))
 173
 174 (declare-function gpg-sign-encrypt "ext:gpg"
 175                   (plaintext ciphertext result recipients &optional
 176                              passphrase sign-with-key armor textmode))
 177 (declare-function gpg-encrypt "ext:gpg"
 178                   (plaintext ciphertext result recipients &optional
 179                              passphrase armor textmode))
 180
 181 (defun mml1991-gpg-sign (cont)
 182   (let ((text (current-buffer))
 183         headers signature
 184         (result-buffer (get-buffer-create "*GPG Result*")))
 185     ;; Save MIME Content[^ ]+: headers from signing
 186     (goto-char (point-min))
 187     (while (looking-at "^Content[^ ]+:") (forward-line))
 188     (unless (bobp)
 189       (setq headers (buffer-string))
 190       (delete-region (point-min) (point)))
 191     (goto-char (point-max))
 192     (unless (bolp)
 193       (insert "\n"))
 194     (quoted-printable-decode-region (point-min) (point-max))
 195     (with-temp-buffer
 196       (unless (gpg-sign-cleartext text (setq signature (current-buffer))
 197                                   result-buffer
 198                                   nil
 199                                   (message-options-get 'message-sender))
 200         (unless (> (point-max) (point-min))
 201           (pop-to-buffer result-buffer)
 202           (error "Sign error")))
 203       (goto-char (point-min))
 204       (while (re-search-forward "\r+$" nil t)
 205         (replace-match "" t t))
 206       (quoted-printable-encode-region (point-min) (point-max))
 207       (set-buffer text)
 208       (delete-region (point-min) (point-max))
 209       (if headers (insert headers))
 210       (insert "\n")
 211       (insert-buffer-substring signature)
 212       (goto-char (point-max)))))
 213
 214 (defun mml1991-gpg-encrypt (cont &optional sign)
 215   (let ((text (current-buffer))
 216         cipher
 217         (result-buffer (get-buffer-create "*GPG Result*")))
 218     ;; Strip MIME Content[^ ]: headers since it will be ASCII ARMOURED
 219     (goto-char (point-min))
 220     (while (looking-at "^Content[^ ]+:") (forward-line))
 221     (unless (bobp)
 222       (delete-region (point-min) (point)))
 223     (mm-with-unibyte-current-buffer
 224       (with-temp-buffer
 225         (flet ((gpg-encrypt-func
 226                 (sign plaintext ciphertext result recipients &optional
 227                       passphrase sign-with-key armor textmode)
 228                 (if sign
 229                     (gpg-sign-encrypt
 230                      plaintext ciphertext result recipients passphrase
 231                      sign-with-key armor textmode)
 232                   (gpg-encrypt
 233                    plaintext ciphertext result recipients passphrase
 234                    armor textmode))))
 235           (unless (gpg-encrypt-func
 236                    sign
 237                    text (setq cipher (current-buffer))
 238                    result-buffer
 239                    (split-string
 240                     (or
 241                      (message-options-get 'message-recipients)
 242                      (message-options-set 'message-recipients
 243                                           (read-string "Recipients: ")))
 244                     "[ \f\t\n\r\v,]+")
 245                    nil
 246                    (message-options-get 'message-sender)
 247                    t t) ; armor & textmode
 248             (unless (> (point-max) (point-min))
 249               (pop-to-buffer result-buffer)
 250               (error "Encrypt error"))))
 251         (goto-char (point-min))
 252         (while (re-search-forward "\r+$" nil t)
 253           (replace-match "" t t))
 254         (set-buffer text)
 255         (delete-region (point-min) (point-max))
 256         ;;(insert "Content-Type: application/pgp-encrypted\n\n")
 257         ;;(insert "Version: 1\n\n")
 258         (insert "\n")
 259         (insert-buffer-substring cipher)
 260         (goto-char (point-max))))))
 261
 262 ;; pgg wrapper
 263
 264 (defvar pgg-default-user-id)
 265 (defvar pgg-errors-buffer)
 266 (defvar pgg-output-buffer)
 267
 268 (defun mml1991-pgg-sign (cont)
 269   (let ((pgg-text-mode t)
 270         (pgg-default-user-id (or (message-options-get 'mml-sender)
 271                                  pgg-default-user-id))
 272         headers cte)
 273     ;; Don't sign headers.
 274     (goto-char (point-min))
 275     (when (re-search-forward "^$" nil t)
 276       (setq headers (buffer-substring (point-min) (point)))
 277       (save-restriction
 278         (narrow-to-region (point-min) (point))
 279         (setq cte (mail-fetch-field "content-transfer-encoding")))
 280       (forward-line 1)
 281       (delete-region (point-min) (point))
 282       (when cte
 283         (setq cte (intern (downcase cte)))
 284         (mm-decode-content-transfer-encoding cte)))
 285     (unless (pgg-sign-region (point-min) (point-max) t)
 286       (pop-to-buffer pgg-errors-buffer)
 287       (error "Encrypt error"))
 288     (delete-region (point-min) (point-max))
 289     (mm-with-unibyte-current-buffer
 290       (insert-buffer-substring pgg-output-buffer)
 291       (goto-char (point-min))
 292       (while (re-search-forward "\r+$" nil t)
 293         (replace-match "" t t))
 294       (when cte
 295         (mm-encode-content-transfer-encoding cte))
 296       (goto-char (point-min))
 297       (when headers
 298         (insert headers))
 299       (insert "\n"))
 300     t))
 301
 302 (defun mml1991-pgg-encrypt (cont &optional sign)
 303   (goto-char (point-min))
 304   (when (re-search-forward "^$" nil t)
 305     (let ((cte (save-restriction
 306                  (narrow-to-region (point-min) (point))
 307                  (mail-fetch-field "content-transfer-encoding"))))
 308       ;; Strip MIME headers since it will be ASCII armoured.
 309       (forward-line 1)
 310       (delete-region (point-min) (point))
 311       (when cte
 312         (mm-decode-content-transfer-encoding (intern (downcase cte))))))
 313   (unless (let ((pgg-text-mode t))
 314             (pgg-encrypt-region
 315              (point-min) (point-max)
 316              (split-string
 317               (or
 318                (message-options-get 'message-recipients)
 319                (message-options-set 'message-recipients
 320                                     (read-string "Recipients: ")))
 321               "[ \f\t\n\r\v,]+")
 322              sign))
 323     (pop-to-buffer pgg-errors-buffer)
 324     (error "Encrypt error"))
 325   (delete-region (point-min) (point-max))
 326   (insert "\n")
 327   (insert-buffer-substring pgg-output-buffer)
 328   t)
 329
 330 ;; epg wrapper
 331
 332 (defvar epg-user-id-alist)
 333 (defvar password-cache-expiry)
 334
 335 (eval-and-compile
 336   (autoload 'epg-make-context "epg")
 337   (autoload 'epg-passphrase-callback-function "epg")
 338   (autoload 'epa-select-keys "epa")
 339   (autoload 'epg-list-keys "epg")
 340   (autoload 'epg-context-set-armor "epg")
 341   (autoload 'epg-context-set-textmode "epg")
 342   (autoload 'epg-context-set-signers "epg")
 343   (autoload 'epg-context-set-passphrase-callback "epg")
 344   (autoload 'epg-sign-string "epg")
 345   (autoload 'epg-encrypt-string "epg")
 346   (autoload 'epg-configuration "epg-config")
 347   (autoload 'epg-expand-group "epg-config"))
 348
 349 (defvar mml1991-epg-secret-key-id-list nil)
 350
 351 (defun mml1991-epg-passphrase-callback (context key-id ignore)
 352   (if (eq key-id 'SYM)
 353       (epg-passphrase-callback-function context key-id nil)
 354     (let* ((entry (assoc key-id epg-user-id-alist))
 355            (passphrase
 356             (password-read
 357              (format "GnuPG passphrase for %s: "
 358                      (if entry
 359                          (cdr entry)
 360                        key-id))
 361              (if (eq key-id 'PIN)
 362                  "PIN"
 363                key-id))))
 364       (when passphrase
 365         (let ((password-cache-expiry mml1991-passphrase-cache-expiry))
 366           (password-cache-add key-id passphrase))
 367         (setq mml1991-epg-secret-key-id-list
 368               (cons key-id mml1991-epg-secret-key-id-list))
 369         (copy-sequence passphrase)))))
 370
 371 (defun mml1991-epg-sign (cont)
 372   (let ((context (epg-make-context))
 373         headers cte signers signature)
 374     (if mml1991-verbose
 375         (setq signers (epa-select-keys context "Select keys for signing.
 376 If no one is selected, default secret key is used.  "
 377                                        mml1991-signers t))
 378       (if mml1991-signers
 379           (setq signers (mapcar (lambda (name)
 380                                   (car (epg-list-keys context name t)))
 381                                 mml1991-signers))))
 382     (epg-context-set-armor context t)
 383     (epg-context-set-textmode context t)
 384     (epg-context-set-signers context signers)
 385     (if mml1991-cache-passphrase
 386         (epg-context-set-passphrase-callback
 387          context
 388          #'mml1991-epg-passphrase-callback))
 389     ;; Don't sign headers.
 390     (goto-char (point-min))
 391     (when (re-search-forward "^$" nil t)
 392       (setq headers (buffer-substring (point-min) (point)))
 393       (save-restriction
 394         (narrow-to-region (point-min) (point))
 395         (setq cte (mail-fetch-field "content-transfer-encoding")))
 396       (forward-line 1)
 397       (delete-region (point-min) (point))
 398       (when cte
 399         (setq cte (intern (downcase cte)))
 400         (mm-decode-content-transfer-encoding cte)))
 401     (condition-case error
 402         (setq signature (epg-sign-string context (buffer-string) 'clear)
 403               mml1991-epg-secret-key-id-list nil)
 404       (error
 405        (while mml1991-epg-secret-key-id-list
 406          (password-cache-remove (car mml1991-epg-secret-key-id-list))
 407          (setq mml1991-epg-secret-key-id-list
 408                (cdr mml1991-epg-secret-key-id-list)))
 409        (signal (car error) (cdr error))))
 410     (delete-region (point-min) (point-max))
 411     (mm-with-unibyte-current-buffer
 412       (insert signature)
 413       (goto-char (point-min))
 414       (while (re-search-forward "\r+$" nil t)
 415         (replace-match "" t t))
 416       (when cte
 417         (mm-encode-content-transfer-encoding cte))
 418       (goto-char (point-min))
 419       (when headers
 420         (insert headers))
 421       (insert "\n"))
 422     t))
 423
 424 (defun mml1991-epg-encrypt (cont &optional sign)
 425   (goto-char (point-min))
 426   (when (re-search-forward "^$" nil t)
 427     (let ((cte (save-restriction
 428                  (narrow-to-region (point-min) (point))
 429                  (mail-fetch-field "content-transfer-encoding"))))
 430       ;; Strip MIME headers since it will be ASCII armoured.
 431       (forward-line 1)
 432       (delete-region (point-min) (point))
 433       (when cte
 434         (mm-decode-content-transfer-encoding (intern (downcase cte))))))
 435   (let ((context (epg-make-context))
 436         (recipients
 437          (if (message-options-get 'message-recipients)
 438              (split-string
 439               (message-options-get 'message-recipients)
 440               "[ \f\t\n\r\v,]+")))
 441         cipher signers config)
 442     ;; We should remove this check if epg-0.0.6 is released.
 443     (if (and (condition-case nil
 444                  (require 'epg-config)
 445                (error))
 446              (functionp #'epg-expand-group))
 447         (setq config (epg-configuration)
 448               recipients
 449               (apply #'nconc
 450                      (mapcar (lambda (recipient)
 451                                (or (epg-expand-group config recipient)
 452                                    (list recipient)))
 453                              recipients))))
 454     (if mml1991-verbose
 455         (setq recipients
 456               (epa-select-keys context "Select recipients for encryption.
 457 If no one is selected, symmetric encryption will be performed.  "
 458                                recipients))
 459       (setq recipients
 460             (delq nil (mapcar (lambda (name)
 461                                 (car (epg-list-keys context name)))
 462                               recipients))))
 463     (if mml1991-encrypt-to-self
 464         (if mml1991-signers
 465             (setq recipients
 466                   (nconc recipients
 467                          (mapcar (lambda (name)
 468                                    (car (epg-list-keys context name)))
 469                                  mml1991-signers)))
 470           (error "mml1991-signers not set")))
 471     (when sign
 472       (if mml1991-verbose
 473           (setq signers (epa-select-keys context "Select keys for signing.
 474 If no one is selected, default secret key is used.  "
 475                                          mml1991-signers t))
 476         (if mml1991-signers
 477             (setq signers (mapcar (lambda (name)
 478                                     (car (epg-list-keys context name t)))
 479                                   mml1991-signers))))
 480       (epg-context-set-signers context signers))
 481     (epg-context-set-armor context t)
 482     (epg-context-set-textmode context t)
 483     (if mml1991-cache-passphrase
 484         (epg-context-set-passphrase-callback
 485          context
 486          #'mml1991-epg-passphrase-callback))
 487     (condition-case error
 488         (setq cipher
 489               (epg-encrypt-string context (buffer-string) recipients sign)
 490               mml1991-epg-secret-key-id-list nil)
 491       (error
 492        (while mml1991-epg-secret-key-id-list
 493          (password-cache-remove (car mml1991-epg-secret-key-id-list))
 494          (setq mml1991-epg-secret-key-id-list
 495                (cdr mml1991-epg-secret-key-id-list)))
 496        (signal (car error) (cdr error))))
 497     (delete-region (point-min) (point-max))
 498     (insert "\n" cipher))
 499   t)
 500
 501 ;;;###autoload
 502 (defun mml1991-encrypt (cont &optional sign)
 503   (let ((func (nth 2 (assq mml1991-use mml1991-function-alist))))
 504     (if func
 505         (funcall func cont sign)
 506       (error "Cannot find encrypt function"))))
 507
 508 ;;;###autoload
 509 (defun mml1991-sign (cont)
 510   (let ((func (nth 1 (assq mml1991-use mml1991-function-alist))))
 511     (if func
 512         (funcall func cont)
 513       (error "Cannot find sign function"))))
 514
 515 (provide 'mml1991)
 516
 517 ;; Local Variables:
 518 ;; coding: iso-8859-1
 519 ;; End:
 520
 521 ;; arch-tag: e542be18-ab28-4393-9b33-97fe9cf30706
 522 ;;; mml1991.el ends here