cgit.sxemacs.org Git - gnus/blob - lisp/mml.el

   1 ;;; mml.el --- A package for parsing and validating MML documents
   2
   3 ;; Copyright (C) 1998, 1999, 2000, 2001, 2002, 2003, 2004,
   4 ;;   2005 Free Software Foundation, Inc.
   5
   6 ;; Author: Lars Magne Ingebrigtsen <larsi@gnus.org>
   7 ;; This file is part of GNU Emacs.
   8
   9 ;; GNU Emacs is free software; you can redistribute it and/or modify
  10 ;; it under the terms of the GNU General Public License as published by
  11 ;; the Free Software Foundation; either version 2, or (at your option)
  12 ;; any later version.
  13
  14 ;; GNU Emacs is distributed in the hope that it will be useful,
  15 ;; but WITHOUT ANY WARRANTY; without even the implied warranty of
  16 ;; MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.  See the
  17 ;; GNU General Public License for more details.
  18
  19 ;; You should have received a copy of the GNU General Public License
  20 ;; along with GNU Emacs; see the file COPYING.  If not, write to the
  21 ;; Free Software Foundation, Inc., 51 Franklin Street, Fifth Floor,
  22 ;; Boston, MA 02110-1301, USA.
  23
  24 ;;; Commentary:
  25
  26 ;;; Code:
  27
  28 (require 'mm-util)
  29 (require 'mm-bodies)
  30 (require 'mm-encode)
  31 (require 'mm-decode)
  32 (require 'mml-sec)
  33 (eval-when-compile (require 'cl))
  34
  35 (eval-and-compile
  36   (autoload 'message-make-message-id "message")
  37   (autoload 'gnus-setup-posting-charset "gnus-msg")
  38   (autoload 'gnus-make-local-hook "gnus-util")
  39   (autoload 'message-fetch-field "message")
  40   (autoload 'message-mark-active-p "message")
  41   (autoload 'message-info "message")
  42   (autoload 'fill-flowed-encode "flow-fill")
  43   (autoload 'message-posting-charset "message"))
  44
  45 (eval-when-compile
  46   (autoload 'dnd-get-local-file-name "dnd"))
  47
  48 (defvar gnus-article-mime-handles)
  49 (defvar gnus-mouse-2)
  50 (defvar gnus-newsrc-hashtb)
  51 (defvar message-default-charset)
  52 (defvar message-deletable-headers)
  53 (defvar message-options)
  54 (defvar message-posting-charset)
  55 (defvar message-required-mail-headers)
  56 (defvar message-required-news-headers)
  57
  58 (defcustom mml-content-type-parameters
  59   '(name access-type expiration size permission format)
  60   "*A list of acceptable parameters in MML tag.
  61 These parameters are generated in Content-Type header if exists."
  62   :version "22.1"
  63   :type '(repeat (symbol :tag "Parameter"))
  64   :group 'message)
  65
  66 (defcustom mml-content-disposition-parameters
  67   '(filename creation-date modification-date read-date)
  68   "*A list of acceptable parameters in MML tag.
  69 These parameters are generated in Content-Disposition header if exists."
  70   :version "22.1"
  71   :type '(repeat (symbol :tag "Parameter"))
  72   :group 'message)
  73
  74 (defcustom mml-insert-mime-headers-always nil
  75   "If non-nil, always put Content-Type: text/plain at top of empty parts.
  76 It is necessary to work against a bug in certain clients."
  77   :version "22.1"
  78   :type 'boolean
  79   :group 'message)
  80
  81 (defvar mml-tweak-type-alist nil
  82   "A list of (TYPE . FUNCTION) for tweaking MML parts.
  83 TYPE is a string containing a regexp to match the MIME type.  FUNCTION
  84 is a Lisp function which is called with the MML handle to tweak the
  85 part.  This variable is used only when no TWEAK parameter exists in
  86 the MML handle.")
  87
  88 (defvar mml-tweak-function-alist nil
  89   "A list of (NAME . FUNCTION) for tweaking MML parts.
  90 NAME is a string containing the name of the TWEAK parameter in the MML
  91 handle.  FUNCTION is a Lisp function which is called with the MML
  92 handle to tweak the part.")
  93
  94 (defvar mml-tweak-sexp-alist
  95   '((mml-externalize-attachments . mml-tweak-externalize-attachments))
  96   "A list of (SEXP . FUNCTION) for tweaking MML parts.
  97 SEXP is an s-expression.  If the evaluation of SEXP is non-nil, FUNCTION
  98 is called.  FUNCTION is a Lisp function which is called with the MML
  99 handle to tweak the part.")
 100
 101 (defvar mml-externalize-attachments nil
 102   "*If non-nil, local-file attachments are generated as external parts.")
 103
 104 (defvar mml-generate-multipart-alist nil
 105   "*Alist of multipart generation functions.
 106 Each entry has the form (NAME . FUNCTION), where
 107 NAME is a string containing the name of the part (without the
 108 leading \"/multipart/\"),
 109 FUNCTION is a Lisp function which is called to generate the part.
 110
 111 The Lisp function has to supply the appropriate MIME headers and the
 112 contents of this part.")
 113
 114 (defvar mml-syntax-table
 115   (let ((table (copy-syntax-table emacs-lisp-mode-syntax-table)))
 116     (modify-syntax-entry ?\\ "/" table)
 117     (modify-syntax-entry ?< "(" table)
 118     (modify-syntax-entry ?> ")" table)
 119     (modify-syntax-entry ?@ "w" table)
 120     (modify-syntax-entry ?/ "w" table)
 121     (modify-syntax-entry ?= " " table)
 122     (modify-syntax-entry ?* " " table)
 123     (modify-syntax-entry ?\; " " table)
 124     (modify-syntax-entry ?\' " " table)
 125     table))
 126
 127 (defvar mml-boundary-function 'mml-make-boundary
 128   "A function called to suggest a boundary.
 129 The function may be called several times, and should try to make a new
 130 suggestion each time.  The function is called with one parameter,
 131 which is a number that says how many times the function has been
 132 called for this message.")
 133
 134 (defvar mml-confirmation-set nil
 135   "A list of symbols, each of which disables some warning.
 136 `unknown-encoding': always send messages contain characters with
 137 unknown encoding; `use-ascii': always use ASCII for those characters
 138 with unknown encoding; `multipart': always send messages with more than
 139 one charsets.")
 140
 141 (defvar mml-generate-default-type "text/plain"
 142   "Content type by which the Content-Type header can be omitted.
 143 The Content-Type header will not be put in the MIME part if the type
 144 equals the value and there's no parameter (e.g. charset, format, etc.)
 145 and `mml-insert-mime-headers-always' is nil.  The value will be bound
 146 to \"message/rfc822\" when encoding an article to be forwarded as a MIME
 147 part.  This is for the internal use, you should never modify the value.")
 148
 149 (defvar mml-buffer-list nil)
 150
 151 (defun mml-generate-new-buffer (name)
 152   (let ((buf (generate-new-buffer name)))
 153     (push buf mml-buffer-list)
 154     buf))
 155
 156 (defun mml-destroy-buffers ()
 157   (let (kill-buffer-hook)
 158     (mapc 'kill-buffer mml-buffer-list)
 159     (setq mml-buffer-list nil)))
 160
 161 (defun mml-parse ()
 162   "Parse the current buffer as an MML document."
 163   (save-excursion
 164     (goto-char (point-min))
 165     (with-syntax-table mml-syntax-table
 166       (mml-parse-1))))
 167
 168 (defun mml-parse-1 ()
 169   "Parse the current buffer as an MML document."
 170   (let (struct tag point contents charsets warn use-ascii no-markup-p raw)
 171     (while (and (not (eobp))
 172                 (not (looking-at "<#/multipart")))
 173       (cond
 174        ((looking-at "<#secure")
 175         ;; The secure part is essentially a meta-meta tag, which
 176         ;; expands to either a part tag if there are no other parts in
 177         ;; the document or a multipart tag if there are other parts
 178         ;; included in the message
 179         (let* (secure-mode
 180                (taginfo (mml-read-tag))
 181                (keyfile (cdr (assq 'keyfile taginfo)))
 182                (certfile (cdr (assq 'certfile taginfo)))
 183                (recipients (cdr (assq 'recipients taginfo)))
 184                (sender (cdr (assq 'sender taginfo)))
 185                (location (cdr (assq 'tag-location taginfo)))
 186                (mode (cdr (assq 'mode taginfo)))
 187                (method (cdr (assq 'method taginfo)))
 188                tags)
 189           (save-excursion
 190             (if (re-search-forward
 191                  "<#/?\\(multipart\\|part\\|external\\|mml\\)." nil t)
 192                 (setq secure-mode "multipart")
 193               (setq secure-mode "part")))
 194           (save-excursion
 195             (goto-char location)
 196             (re-search-forward "<#secure[^\n]*>\n"))
 197           (delete-region (match-beginning 0) (match-end 0))
 198           (cond ((string= mode "sign")
 199                  (setq tags (list "sign" method)))
 200                 ((string= mode "encrypt")
 201                  (setq tags (list "encrypt" method)))
 202                 ((string= mode "signencrypt")
 203                  (setq tags (list "sign" method "encrypt" method))))
 204           (eval `(mml-insert-tag ,secure-mode
 205                                  ,@tags
 206                                  ,(if keyfile "keyfile")
 207                                  ,keyfile
 208                                  ,(if certfile "certfile")
 209                                  ,certfile
 210                                  ,(if recipients "recipients")
 211                                  ,recipients
 212                                  ,(if sender "sender")
 213                                  ,sender))
 214           ;; restart the parse
 215           (goto-char location)))
 216        ((looking-at "<#multipart")
 217         (push (nconc (mml-read-tag) (mml-parse-1)) struct))
 218        ((looking-at "<#external")
 219         (push (nconc (mml-read-tag) (list (cons 'contents (mml-read-part))))
 220               struct))
 221        (t
 222         (if (or (looking-at "<#part") (looking-at "<#mml"))
 223             (setq tag (mml-read-tag)
 224                   no-markup-p nil
 225                   warn nil)
 226           (setq tag (list 'part '(type . "text/plain"))
 227                 no-markup-p t
 228                 warn t))
 229         (setq raw (cdr (assq 'raw tag))
 230               point (point)
 231               contents (mml-read-part (eq 'mml (car tag)))
 232               charsets (cond
 233                         (raw nil)
 234                         ((assq 'charset tag)
 235                          (list
 236                           (intern (downcase (cdr (assq 'charset tag))))))
 237                         (t
 238                          (mm-find-mime-charset-region point (point)
 239                                                       mm-hack-charsets))))
 240         (when (and (not raw) (memq nil charsets))
 241           (if (or (memq 'unknown-encoding mml-confirmation-set)
 242                   (message-options-get 'unknown-encoding)
 243                   (and (y-or-n-p "\
 244 Message contains characters with unknown encoding.  Really send? ")
 245                        (message-options-set 'unknown-encoding t)))
 246               (if (setq use-ascii
 247                         (or (memq 'use-ascii mml-confirmation-set)
 248                             (message-options-get 'use-ascii)
 249                             (and (y-or-n-p "Use ASCII as charset? ")
 250                                  (message-options-set 'use-ascii t))))
 251                   (setq charsets (delq nil charsets))
 252                 (setq warn nil))
 253             (error "Edit your message to remove those characters")))
 254         (if (or raw
 255                 (eq 'mml (car tag))
 256                 (< (length charsets) 2))
 257             (if (or (not no-markup-p)
 258                     (string-match "[^ \t\r\n]" contents))
 259                 ;; Don't create blank parts.
 260                 (push (nconc tag (list (cons 'contents contents)))
 261                       struct))
 262           (let ((nstruct (mml-parse-singlepart-with-multiple-charsets
 263                           tag point (point) use-ascii)))
 264             (when (and warn
 265                        (not (memq 'multipart mml-confirmation-set))
 266                        (not (message-options-get 'multipart))
 267                        (not (and (y-or-n-p (format "\
 268 A message part needs to be split into %d charset parts.  Really send? "
 269                                                    (length nstruct)))
 270                                  (message-options-set 'multipart t))))
 271               (error "Edit your message to use only one charset"))
 272             (setq struct (nconc nstruct struct)))))))
 273     (unless (eobp)
 274       (forward-line 1))
 275     (nreverse struct)))
 276
 277 (defun mml-parse-singlepart-with-multiple-charsets
 278   (orig-tag beg end &optional use-ascii)
 279   (save-excursion
 280     (save-restriction
 281       (narrow-to-region beg end)
 282       (goto-char (point-min))
 283       (let ((current (or (mm-mime-charset (mm-charset-after))
 284                          (and use-ascii 'us-ascii)))
 285             charset struct space newline paragraph)
 286         (while (not (eobp))
 287           (setq charset (mm-mime-charset (mm-charset-after)))
 288           (cond
 289            ;; The charset remains the same.
 290            ((eq charset 'us-ascii))
 291            ((or (and use-ascii (not charset))
 292                 (eq charset current))
 293             (setq space nil
 294                   newline nil
 295                   paragraph nil))
 296            ;; The initial charset was ascii.
 297            ((eq current 'us-ascii)
 298             (setq current charset
 299                   space nil
 300                   newline nil
 301                   paragraph nil))
 302            ;; We have a change in charsets.
 303            (t
 304             (push (append
 305                    orig-tag
 306                    (list (cons 'contents
 307                                (buffer-substring-no-properties
 308                                 beg (or paragraph newline space (point))))))
 309                   struct)
 310             (setq beg (or paragraph newline space (point))
 311                   current charset
 312                   space nil
 313                   newline nil
 314                   paragraph nil)))
 315           ;; Compute places where it might be nice to break the part.
 316           (cond
 317            ((memq (following-char) '(?  ?\t))
 318             (setq space (1+ (point))))
 319            ((and (eq (following-char) ?\n)
 320                  (not (bobp))
 321                  (eq (char-after (1- (point))) ?\n))
 322             (setq paragraph (point)))
 323            ((eq (following-char) ?\n)
 324             (setq newline (1+ (point)))))
 325           (forward-char 1))
 326         ;; Do the final part.
 327         (unless (= beg (point))
 328           (push (append orig-tag
 329                         (list (cons 'contents
 330                                     (buffer-substring-no-properties
 331                                      beg (point)))))
 332                 struct))
 333         struct))))
 334
 335 (defun mml-read-tag ()
 336   "Read a tag and return the contents."
 337   (let ((orig-point (point))
 338         contents name elem val)
 339     (forward-char 2)
 340     (setq name (buffer-substring-no-properties
 341                 (point) (progn (forward-sexp 1) (point))))
 342     (skip-chars-forward " \t\n")
 343     (while (not (looking-at ">[ \t]*\n?"))
 344       (setq elem (buffer-substring-no-properties
 345                   (point) (progn (forward-sexp 1) (point))))
 346       (skip-chars-forward "= \t\n")
 347       (setq val (buffer-substring-no-properties
 348                  (point) (progn (forward-sexp 1) (point))))
 349       (when (string-match "^\"\\(.*\\)\"$" val)
 350         (setq val (match-string 1 val)))
 351       (push (cons (intern elem) val) contents)
 352       (skip-chars-forward " \t\n"))
 353     (goto-char (match-end 0))
 354     ;; Don't skip the leading space.
 355     ;;(skip-chars-forward " \t\n")
 356     ;; Put the tag location into the returned contents
 357     (setq contents (append (list (cons 'tag-location orig-point)) contents))
 358     (cons (intern name) (nreverse contents))))
 359
 360 (defun mml-buffer-substring-no-properties-except-hard-newlines (start end)
 361   (let ((str (buffer-substring-no-properties start end))
 362         (bufstart start) tmp)
 363     (while (setq tmp (text-property-any start end 'hard 't))
 364       (set-text-properties (- tmp bufstart) (- tmp bufstart -1)
 365                            '(hard t) str)
 366       (setq start (1+ tmp)))
 367     str))
 368
 369 (defun mml-read-part (&optional mml)
 370   "Return the buffer up till the next part, multipart or closing part or multipart.
 371 If MML is non-nil, return the buffer up till the correspondent mml tag."
 372   (let ((beg (point)) (count 1))
 373     ;; If the tag ended at the end of the line, we go to the next line.
 374     (when (looking-at "[ \t]*\n")
 375       (forward-line 1))
 376     (if mml
 377         (progn
 378           (while (and (> count 0) (not (eobp)))
 379             (if (re-search-forward "<#\\(/\\)?mml." nil t)
 380                 (setq count (+ count (if (match-beginning 1) -1 1)))
 381               (goto-char (point-max))))
 382           (mml-buffer-substring-no-properties-except-hard-newlines
 383            beg (if (> count 0)
 384                    (point)
 385                  (match-beginning 0))))
 386       (if (re-search-forward
 387            "<#\\(/\\)?\\(multipart\\|part\\|external\\|mml\\)." nil t)
 388           (prog1
 389               (mml-buffer-substring-no-properties-except-hard-newlines
 390                beg (match-beginning 0))
 391             (if (or (not (match-beginning 1))
 392                     (equal (match-string 2) "multipart"))
 393                 (goto-char (match-beginning 0))
 394               (when (looking-at "[ \t]*\n")
 395                 (forward-line 1))))
 396         (mml-buffer-substring-no-properties-except-hard-newlines
 397          beg (goto-char (point-max)))))))
 398
 399 (defvar mml-boundary nil)
 400 (defvar mml-base-boundary "-=-=")
 401 (defvar mml-multipart-number 0)
 402
 403 (defun mml-generate-mime ()
 404   "Generate a MIME message based on the current MML document."
 405   (let ((cont (mml-parse))
 406         (mml-multipart-number mml-multipart-number))
 407     (if (not cont)
 408         nil
 409       (with-temp-buffer
 410         (if (and (consp (car cont))
 411                  (= (length cont) 1))
 412             (mml-generate-mime-1 (car cont))
 413           (mml-generate-mime-1 (nconc (list 'multipart '(type . "mixed"))
 414                                       cont)))
 415         (buffer-string)))))
 416
 417 (defun mml-generate-mime-1 (cont)
 418   (let ((mm-use-ultra-safe-encoding
 419          (or mm-use-ultra-safe-encoding (assq 'sign cont))))
 420     (save-restriction
 421       (narrow-to-region (point) (point))
 422       (mml-tweak-part cont)
 423       (cond
 424        ((or (eq (car cont) 'part) (eq (car cont) 'mml))
 425         (let* ((raw (cdr (assq 'raw cont)))
 426                (filename (cdr (assq 'filename cont)))
 427                (type (or (cdr (assq 'type cont))
 428                          (if filename
 429                              (or (mm-default-file-encoding filename)
 430                                  "application/octet-stream")
 431                            "text/plain")))
 432                (charset (cdr (assq 'charset cont)))
 433                (coding (mm-charset-to-coding-system charset))
 434                encoding flowed coded)
 435           (cond ((eq coding 'ascii)
 436                  (setq charset nil
 437                        coding nil))
 438                 (charset
 439                  (setq charset (intern (downcase charset)))))
 440           (if (and (not raw)
 441                    (member (car (split-string type "/")) '("text" "message")))
 442               (progn
 443                 (with-temp-buffer
 444                   (cond
 445                    ((cdr (assq 'buffer cont))
 446                     (insert-buffer-substring (cdr (assq 'buffer cont))))
 447                    ((and filename
 448                          (not (equal (cdr (assq 'nofile cont)) "yes")))
 449                     (let ((coding-system-for-read coding))
 450                       (mm-insert-file-contents filename)))
 451                    ((eq 'mml (car cont))
 452                     (insert (cdr (assq 'contents cont))))
 453                    (t
 454                     (save-restriction
 455                       (narrow-to-region (point) (point))
 456                       (insert (cdr (assq 'contents cont)))
 457                       ;; Remove quotes from quoted tags.
 458                       (goto-char (point-min))
 459                       (while (re-search-forward
 460                               "<#!+/?\\(part\\|multipart\\|external\\|mml\\)"
 461                               nil t)
 462                         (delete-region (+ (match-beginning 0) 2)
 463                                        (+ (match-beginning 0) 3))))))
 464                   (cond
 465                    ((eq (car cont) 'mml)
 466                     (let ((mml-boundary (mml-compute-boundary cont))
 467                           ;; It is necessary for the case where this
 468                           ;; function is called recursively since
 469                           ;; `m-g-d-t' will be bound to "message/rfc822"
 470                           ;; when encoding an article to be forwarded.
 471                           (mml-generate-default-type "text/plain"))
 472                       (mml-to-mime))
 473                     (let ((mm-7bit-chars (concat mm-7bit-chars "\x1b")))
 474                       ;; ignore 0x1b, it is part of iso-2022-jp
 475                       (setq encoding (mm-body-7-or-8))))
 476                    ((string= (car (split-string type "/")) "message")
 477                     (let ((mm-7bit-chars (concat mm-7bit-chars "\x1b")))
 478                       ;; ignore 0x1b, it is part of iso-2022-jp
 479                       (setq encoding (mm-body-7-or-8))))
 480                    (t
 481                     ;; Only perform format=flowed filling on text/plain
 482                     ;; parts where there either isn't a format parameter
 483                     ;; in the mml tag or it says "flowed" and there
 484                     ;; actually are hard newlines in the text.
 485                     (let (use-hard-newlines)
 486                       (when (and (string= type "text/plain")
 487                                  (not (string= (cdr (assq 'sign cont)) "pgp"))
 488                                  (or (null (assq 'format cont))
 489                                      (string= (cdr (assq 'format cont))
 490                                               "flowed"))
 491                                  (setq use-hard-newlines
 492                                        (text-property-any
 493                                         (point-min) (point-max) 'hard 't)))
 494                         (fill-flowed-encode)
 495                         ;; Indicate that `mml-insert-mime-headers' should
 496                         ;; insert a "; format=flowed" string unless the
 497                         ;; user has already specified it.
 498                         (setq flowed (null (assq 'format cont)))))
 499                     (setq charset (mm-encode-body charset))
 500                     (setq encoding (mm-body-encoding
 501                                     charset (cdr (assq 'encoding cont))))))
 502                   (setq coded (buffer-string)))
 503                 (mml-insert-mime-headers cont type charset encoding flowed)
 504                 (insert "\n")
 505                 (insert coded))
 506             (mm-with-unibyte-buffer
 507               (cond
 508                ((cdr (assq 'buffer cont))
 509                 (insert (with-current-buffer (cdr (assq 'buffer cont))
 510                           (mm-with-unibyte-current-buffer
 511                             (buffer-string)))))
 512                ((and filename
 513                      (not (equal (cdr (assq 'nofile cont)) "yes")))
 514                 (let ((coding-system-for-read mm-binary-coding-system))
 515                   (mm-insert-file-contents filename nil nil nil nil t))
 516                 (unless charset
 517                   (setq charset (mm-coding-system-to-mime-charset
 518                                  (mm-find-buffer-file-coding-system
 519                                   filename)))))
 520                (t
 521                 (insert (cdr (assq 'contents cont)))))
 522               (setq encoding (mm-encode-buffer type)
 523                     coded (mm-string-as-multibyte (buffer-string))))
 524             (mml-insert-mime-headers cont type charset encoding nil)
 525             (insert "\n")
 526             (mm-with-unibyte-current-buffer
 527               (insert coded)))))
 528        ((eq (car cont) 'external)
 529         (insert "Content-Type: message/external-body")
 530         (let ((parameters (mml-parameter-string
 531                            cont '(expiration size permission)))
 532               (name (cdr (assq 'name cont)))
 533               (url (cdr (assq 'url cont))))
 534           (when name
 535             (setq name (mml-parse-file-name name))
 536             (if (stringp name)
 537                 (mml-insert-parameter
 538                  (mail-header-encode-parameter "name" name)
 539                  "access-type=local-file")
 540               (mml-insert-parameter
 541                (mail-header-encode-parameter
 542                 "name" (file-name-nondirectory (nth 2 name)))
 543                (mail-header-encode-parameter "site" (nth 1 name))
 544                (mail-header-encode-parameter
 545                 "directory" (file-name-directory (nth 2 name))))
 546               (mml-insert-parameter
 547                (concat "access-type="
 548                        (if (member (nth 0 name) '("ftp@" "anonymous@"))
 549                            "anon-ftp"
 550                          "ftp")))))
 551           (when url
 552             (mml-insert-parameter
 553              (mail-header-encode-parameter "url" url)
 554              "access-type=url"))
 555           (when parameters
 556             (mml-insert-parameter-string
 557              cont '(expiration size permission)))
 558           (insert "\n\n")
 559           (insert "Content-Type: "
 560                   (or (cdr (assq 'type cont))
 561                       (if name
 562                           (or (mm-default-file-encoding name)
 563                               "application/octet-stream")
 564                         "text/plain"))
 565                   "\n")
 566           (insert "Content-ID: " (message-make-message-id) "\n")
 567           (insert "Content-Transfer-Encoding: "
 568                   (or (cdr (assq 'encoding cont)) "binary"))
 569           (insert "\n\n")
 570           (insert (or (cdr (assq 'contents cont))))
 571           (insert "\n")))
 572        ((eq (car cont) 'multipart)
 573         (let* ((type (or (cdr (assq 'type cont)) "mixed"))
 574                (mml-generate-default-type (if (equal type "digest")
 575                                               "message/rfc822"
 576                                             "text/plain"))
 577                (handler (assoc type mml-generate-multipart-alist)))
 578           (if handler
 579               (funcall (cdr handler) cont)
 580             ;; No specific handler.  Use default one.
 581             (let ((mml-boundary (mml-compute-boundary cont)))
 582               (insert (format "Content-Type: multipart/%s; boundary=\"%s\""
 583                               type mml-boundary)
 584                       (if (cdr (assq 'start cont))
 585                           (format "; start=\"%s\"\n" (cdr (assq 'start cont)))
 586                         "\n"))
 587               (let ((cont cont) part)
 588                 (while (setq part (pop cont))
 589                   ;; Skip `multipart' and attributes.
 590                   (when (and (consp part) (consp (cdr part)))
 591                     (insert "\n--" mml-boundary "\n")
 592                     (mml-generate-mime-1 part))))
 593               (insert "\n--" mml-boundary "--\n")))))
 594        (t
 595         (error "Invalid element: %S" cont)))
 596       ;; handle sign & encrypt tags in a semi-smart way.
 597       (let ((sign-item (assoc (cdr (assq 'sign cont)) mml-sign-alist))
 598             (encrypt-item (assoc (cdr (assq 'encrypt cont))
 599                                  mml-encrypt-alist))
 600             sender recipients)
 601         (when (or sign-item encrypt-item)
 602           (when (setq sender (cdr (assq 'sender cont)))
 603             (message-options-set 'mml-sender sender)
 604             (message-options-set 'message-sender sender))
 605           (if (setq recipients (cdr (assq 'recipients cont)))
 606               (message-options-set 'message-recipients recipients))
 607           (let ((style (mml-signencrypt-style
 608                         (first (or sign-item encrypt-item)))))
 609             ;; check if: we're both signing & encrypting, both methods
 610             ;; are the same (why would they be different?!), and that
 611             ;; the signencrypt style allows for combined operation.
 612             (if (and sign-item encrypt-item (equal (first sign-item)
 613                                                    (first encrypt-item))
 614                      (equal style 'combined))
 615                 (funcall (nth 1 encrypt-item) cont t)
 616               ;; otherwise, revert to the old behavior.
 617               (when sign-item
 618                 (funcall (nth 1 sign-item) cont))
 619               (when encrypt-item
 620                 (funcall (nth 1 encrypt-item) cont)))))))))
 621
 622 (defun mml-compute-boundary (cont)
 623   "Return a unique boundary that does not exist in CONT."
 624   (let ((mml-boundary (funcall mml-boundary-function
 625                                (incf mml-multipart-number))))
 626     ;; This function tries again and again until it has found
 627     ;; a unique boundary.
 628     (while (not (catch 'not-unique
 629                   (mml-compute-boundary-1 cont))))
 630     mml-boundary))
 631
 632 (defun mml-compute-boundary-1 (cont)
 633   (let (filename)
 634     (cond
 635      ((eq (car cont) 'part)
 636       (with-temp-buffer
 637         (cond
 638          ((cdr (assq 'buffer cont))
 639           (insert-buffer-substring (cdr (assq 'buffer cont))))
 640          ((and (setq filename (cdr (assq 'filename cont)))
 641                (not (equal (cdr (assq 'nofile cont)) "yes")))
 642           (mm-insert-file-contents filename nil nil nil nil t))
 643          (t
 644           (insert (cdr (assq 'contents cont)))))
 645         (goto-char (point-min))
 646         (when (re-search-forward (concat "^--" (regexp-quote mml-boundary))
 647                                  nil t)
 648           (setq mml-boundary (funcall mml-boundary-function
 649                                       (incf mml-multipart-number)))
 650           (throw 'not-unique nil))))
 651      ((eq (car cont) 'multipart)
 652       (mapc 'mml-compute-boundary-1 (cddr cont))))
 653     t))
 654
 655 (defun mml-make-boundary (number)
 656   (concat (make-string (% number 60) ?=)
 657           (if (> number 17)
 658               (format "%x" number)
 659             "")
 660           mml-base-boundary))
 661
 662 (defun mml-insert-mime-headers (cont type charset encoding flowed)
 663   (let (parameters id disposition description)
 664     (setq parameters
 665           (mml-parameter-string
 666            cont mml-content-type-parameters))
 667     (when (or charset
 668               parameters
 669               flowed
 670               (not (equal type mml-generate-default-type))
 671               mml-insert-mime-headers-always)
 672       (when (consp charset)
 673         (error
 674          "Can't encode a part with several charsets"))
 675       (insert "Content-Type: " type)
 676       (when charset
 677         (insert "; " (mail-header-encode-parameter
 678                       "charset" (symbol-name charset))))
 679       (when flowed
 680         (insert "; format=flowed"))
 681       (when parameters
 682         (mml-insert-parameter-string
 683          cont mml-content-type-parameters))
 684       (insert "\n"))
 685     (when (setq id (cdr (assq 'id cont)))
 686       (insert "Content-ID: " id "\n"))
 687     (setq parameters
 688           (mml-parameter-string
 689            cont mml-content-disposition-parameters))
 690     (when (or (setq disposition (cdr (assq 'disposition cont)))
 691               parameters)
 692       (insert "Content-Disposition: " (or disposition "inline"))
 693       (when parameters
 694         (mml-insert-parameter-string
 695          cont mml-content-disposition-parameters))
 696       (insert "\n"))
 697     (unless (eq encoding '7bit)
 698       (insert (format "Content-Transfer-Encoding: %s\n" encoding)))
 699     (when (setq description (cdr (assq 'description cont)))
 700       (insert "Content-Description: "
 701               (mail-encode-encoded-word-string description) "\n"))))
 702
 703 (defun mml-parameter-string (cont types)
 704   (let ((string "")
 705         value type)
 706     (while (setq type (pop types))
 707       (when (setq value (cdr (assq type cont)))
 708         ;; Strip directory component from the filename parameter.
 709         (when (eq type 'filename)
 710           (setq value (file-name-nondirectory value)))
 711         (setq string (concat string "; "
 712                              (mail-header-encode-parameter
 713                               (symbol-name type) value)))))
 714     (when (not (zerop (length string)))
 715       string)))
 716
 717 (defun mml-insert-parameter-string (cont types)
 718   (let (value type)
 719     (while (setq type (pop types))
 720       (when (setq value (cdr (assq type cont)))
 721         ;; Strip directory component from the filename parameter.
 722         (when (eq type 'filename)
 723           (setq value (file-name-nondirectory value)))
 724         (mml-insert-parameter
 725          (mail-header-encode-parameter
 726           (symbol-name type) value))))))
 727
 728 (eval-when-compile
 729   (defvar ange-ftp-name-format)
 730   (defvar efs-path-regexp))
 731 (defun mml-parse-file-name (path)
 732   (if (if (boundp 'efs-path-regexp)
 733           (string-match efs-path-regexp path)
 734         (if (boundp 'ange-ftp-name-format)
 735             (string-match (car ange-ftp-name-format) path)))
 736       (list (match-string 1 path) (match-string 2 path)
 737             (substring path (1+ (match-end 2))))
 738     path))
 739
 740 (defun mml-insert-buffer (buffer)
 741   "Insert BUFFER at point and quote any MML markup."
 742   (save-restriction
 743     (narrow-to-region (point) (point))
 744     (insert-buffer-substring buffer)
 745     (mml-quote-region (point-min) (point-max))
 746     (goto-char (point-max))))
 747
 748 ;;;
 749 ;;; Transforming MIME to MML
 750 ;;;
 751
 752 (defun mime-to-mml (&optional handles)
 753   "Translate the current buffer (which should be a message) into MML.
 754 If HANDLES is non-nil, use it instead reparsing the buffer."
 755   ;; First decode the head.
 756   (save-restriction
 757     (message-narrow-to-head)
 758     (let ((rfc2047-quote-decoded-words-containing-tspecials t))
 759       (mail-decode-encoded-word-region (point-min) (point-max))))
 760   (unless handles
 761     (setq handles (mm-dissect-buffer t)))
 762   (goto-char (point-min))
 763   (search-forward "\n\n" nil t)
 764   (delete-region (point) (point-max))
 765   (if (stringp (car handles))
 766       (mml-insert-mime handles)
 767     (mml-insert-mime handles t))
 768   (mm-destroy-parts handles)
 769   (save-restriction
 770     (message-narrow-to-head)
 771     ;; Remove them, they are confusing.
 772     (message-remove-header "Content-Type")
 773     (message-remove-header "MIME-Version")
 774     (message-remove-header "Content-Disposition")
 775     (message-remove-header "Content-Transfer-Encoding")))
 776
 777 (defun mml-to-mime ()
 778   "Translate the current buffer from MML to MIME."
 779   (message-encode-message-body)
 780   (save-restriction
 781     (message-narrow-to-headers-or-head)
 782     ;; Skip past any From_ headers.
 783     (while (looking-at "From ")
 784       (forward-line 1))
 785     (let ((mail-parse-charset message-default-charset))
 786       (mail-encode-encoded-word-buffer))))
 787
 788 (defun mml-insert-mime (handle &optional no-markup)
 789   (let (textp buffer mmlp)
 790     ;; Determine type and stuff.
 791     (unless (stringp (car handle))
 792       (unless (setq textp (equal (mm-handle-media-supertype handle) "text"))
 793         (save-excursion
 794           (set-buffer (setq buffer (mml-generate-new-buffer " *mml*")))
 795           (mm-insert-part handle)
 796           (if (setq mmlp (equal (mm-handle-media-type handle)
 797                                 "message/rfc822"))
 798               (mime-to-mml)))))
 799     (if mmlp
 800         (mml-insert-mml-markup handle nil t t)
 801       (unless (and no-markup
 802                    (equal (mm-handle-media-type handle) "text/plain"))
 803         (mml-insert-mml-markup handle buffer textp)))
 804     (cond
 805      (mmlp
 806       (insert-buffer-substring buffer)
 807       (goto-char (point-max))
 808       (insert "<#/mml>\n"))
 809      ((stringp (car handle))
 810       (mapcar 'mml-insert-mime (cdr handle))
 811       (insert "<#/multipart>\n"))
 812      (textp
 813       (let ((charset (mail-content-type-get
 814                       (mm-handle-type handle) 'charset))
 815             (start (point)))
 816         (if (eq charset 'gnus-decoded)
 817             (mm-insert-part handle)
 818           (insert (mm-decode-string (mm-get-part handle) charset)))
 819         (mml-quote-region start (point)))
 820       (goto-char (point-max)))
 821      (t
 822       (insert "<#/part>\n")))))
 823
 824 (defun mml-insert-mml-markup (handle &optional buffer nofile mmlp)
 825   "Take a MIME handle and insert an MML tag."
 826   (if (stringp (car handle))
 827       (progn
 828         (insert "<#multipart type=" (mm-handle-media-subtype handle))
 829         (let ((start (mm-handle-multipart-ctl-parameter handle 'start)))
 830           (when start
 831             (insert " start=\"" start "\"")))
 832         (insert ">\n"))
 833     (if mmlp
 834         (insert "<#mml type=" (mm-handle-media-type handle))
 835       (insert "<#part type=" (mm-handle-media-type handle)))
 836     (dolist (elem (append (cdr (mm-handle-type handle))
 837                           (cdr (mm-handle-disposition handle))))
 838       (unless (symbolp (cdr elem))
 839         (insert " " (symbol-name (car elem)) "=\"" (cdr elem) "\"")))
 840     (when (mm-handle-id handle)
 841       (insert " id=\"" (mm-handle-id handle) "\""))
 842     (when (mm-handle-disposition handle)
 843       (insert " disposition=" (car (mm-handle-disposition handle))))
 844     (when buffer
 845       (insert " buffer=\"" (buffer-name buffer) "\""))
 846     (when nofile
 847       (insert " nofile=yes"))
 848     (when (mm-handle-description handle)
 849       (insert " description=\"" (mm-handle-description handle) "\""))
 850     (insert ">\n")))
 851
 852 (defun mml-insert-parameter (&rest parameters)
 853   "Insert PARAMETERS in a nice way."
 854   (dolist (param parameters)
 855     (insert ";")
 856     (let ((point (point)))
 857       (insert " " param)
 858       (when (> (current-column) 71)
 859         (goto-char point)
 860         (insert "\n")
 861         (end-of-line)))))
 862
 863 ;;;
 864 ;;; Mode for inserting and editing MML forms
 865 ;;;
 866
 867 (defvar mml-mode-map
 868   (let ((sign (make-sparse-keymap))
 869         (encrypt (make-sparse-keymap))
 870         (signpart (make-sparse-keymap))
 871         (encryptpart (make-sparse-keymap))
 872         (map (make-sparse-keymap))
 873         (main (make-sparse-keymap)))
 874     (define-key map "\C-s" 'mml-secure-message-sign)
 875     (define-key map "\C-c" 'mml-secure-message-encrypt)
 876     (define-key map "\C-e" 'mml-secure-message-sign-encrypt)
 877     (define-key map "\C-p\C-s" 'mml-secure-sign)
 878     (define-key map "\C-p\C-c" 'mml-secure-encrypt)
 879     (define-key sign "p" 'mml-secure-message-sign-pgpmime)
 880     (define-key sign "o" 'mml-secure-message-sign-pgp)
 881     (define-key sign "s" 'mml-secure-message-sign-smime)
 882     (define-key signpart "p" 'mml-secure-sign-pgpmime)
 883     (define-key signpart "o" 'mml-secure-sign-pgp)
 884     (define-key signpart "s" 'mml-secure-sign-smime)
 885     (define-key encrypt "p" 'mml-secure-message-encrypt-pgpmime)
 886     (define-key encrypt "o" 'mml-secure-message-encrypt-pgp)
 887     (define-key encrypt "s" 'mml-secure-message-encrypt-smime)
 888     (define-key encryptpart "p" 'mml-secure-encrypt-pgpmime)
 889     (define-key encryptpart "o" 'mml-secure-encrypt-pgp)
 890     (define-key encryptpart "s" 'mml-secure-encrypt-smime)
 891     (define-key map "\C-n" 'mml-unsecure-message)
 892     (define-key map "f" 'mml-attach-file)
 893     (define-key map "b" 'mml-attach-buffer)
 894     (define-key map "e" 'mml-attach-external)
 895     (define-key map "q" 'mml-quote-region)
 896     (define-key map "m" 'mml-insert-multipart)
 897     (define-key map "p" 'mml-insert-part)
 898     (define-key map "v" 'mml-validate)
 899     (define-key map "P" 'mml-preview)
 900     (define-key map "s" sign)
 901     (define-key map "S" signpart)
 902     (define-key map "c" encrypt)
 903     (define-key map "C" encryptpart)
 904     ;;(define-key map "n" 'mml-narrow-to-part)
 905     ;; `M-m' conflicts with `back-to-indentation'.
 906     ;; (define-key main "\M-m" map)
 907     (define-key main "\C-c\C-m" map)
 908     main))
 909
 910 (easy-menu-define
 911   mml-menu mml-mode-map ""
 912   `("Attachments"
 913     ["Attach File..." mml-attach-file
 914      ,@(if (featurep 'xemacs) '(t)
 915          '(:help "Attach a file at point"))]
 916     ["Attach Buffer..." mml-attach-buffer
 917      ,@(if (featurep 'xemacs) '(t)
 918          '(:help "Attach a buffer to the outgoing MIME message"))]
 919     ["Attach External..." mml-attach-external
 920      ,@(if (featurep 'xemacs) '(t)
 921          '(:help "Attach reference to file"))]
 922     ;;
 923     ("Change Security Method"
 924      ["PGP/MIME"
 925       (lambda () (interactive) (setq mml-secure-method "pgpmime"))
 926       ,@(if (featurep 'xemacs) nil
 927           '(:help "Set Security Method to PGP/MIME"))
 928       :style radio
 929       :selected (equal mml-secure-method "pgpmime") ]
 930      ["S/MIME"
 931       (lambda () (interactive) (setq mml-secure-method "smime"))
 932       ,@(if (featurep 'xemacs) nil
 933           '(:help "Set Security Method to S/MIME"))
 934       :style radio
 935       :selected (equal mml-secure-method "smime") ]
 936      ["Inline PGP"
 937       (lambda () (interactive) (setq mml-secure-method "pgp"))
 938       ,@(if (featurep 'xemacs) nil
 939           '(:help "Set Security Method to inline PGP"))
 940       :style radio
 941       :selected (equal mml-secure-method "pgp") ] )
 942     ;;
 943     ["Sign Message" mml-secure-message-sign t]
 944     ["Encrypt Message" mml-secure-message-encrypt t]
 945     ["Sign and Encrypt Message" mml-secure-message-sign-encrypt t]
 946     ["Encrypt/Sign off" mml-unsecure-message
 947      ,@(if (featurep 'xemacs) '(t)
 948          '(:help "Don't Encrypt/Sign Message"))]
 949     ;; Maybe we could remove these, because people who write MML most probably
 950     ;; don't use the menu:
 951     ["Insert Part..." mml-insert-part
 952      :active (message-in-body-p)]
 953     ["Insert Multipart..." mml-insert-multipart
 954      :active (message-in-body-p)]
 955     ;;
 956     ;; Do we have separate encrypt and encrypt/sign commands for parts?
 957     ["Sign Part" mml-secure-sign t]
 958     ["Encrypt Part" mml-secure-encrypt t]
 959     ;;["Narrow" mml-narrow-to-part t]
 960     ["Quote MML in region" mml-quote-region
 961      :active (message-mark-active-p)
 962      ,@(if (featurep 'xemacs) nil
 963          '(:help "Quote MML tags in region"))]
 964     ["Validate MML" mml-validate t]
 965     ["Preview" mml-preview t]
 966     "----"
 967     ["Emacs MIME manual" (lambda () (interactive) (message-info 4))
 968      ,@(if (featurep 'xemacs) '(t)
 969          '(:help "Display the Emacs MIME manual"))]
 970     ["PGG manual" (lambda () (interactive) (message-info 16))
 971      ,@(if (featurep 'xemacs) '(t)
 972          '(:help "Display the PGG manual"))]))
 973
 974 (defvar mml-mode nil
 975   "Minor mode for editing MML.")
 976
 977 (defun mml-mode (&optional arg)
 978   "Minor mode for editing MML.
 979 MML is the MIME Meta Language, a minor mode for composing MIME articles.
 980 See Info node `(emacs-mime)Composing'.
 981
 982 \\{mml-mode-map}"
 983   (interactive "P")
 984   (when (set (make-local-variable 'mml-mode)
 985              (if (null arg) (not mml-mode)
 986                (> (prefix-numeric-value arg) 0)))
 987     (add-minor-mode 'mml-mode " MML" mml-mode-map)
 988     (easy-menu-add mml-menu mml-mode-map)
 989     (when (boundp 'dnd-protocol-alist)
 990       (set (make-local-variable 'dnd-protocol-alist)
 991            (append mml-dnd-protocol-alist
 992                    (symbol-value 'dnd-protocol-alist))))
 993     (run-hooks 'mml-mode-hook)))
 994
 995 ;;;
 996 ;;; Helper functions for reading MIME stuff from the minibuffer and
 997 ;;; inserting stuff to the buffer.
 998 ;;;
 999
1000 (defun mml-minibuffer-read-file (prompt)
1001   (let* ((completion-ignored-extensions nil)
1002          (file (read-file-name prompt nil nil t)))
1003     ;; Prevent some common errors.  This is inspired by similar code in
1004     ;; VM.
1005     (when (file-directory-p file)
1006       (error "%s is a directory, cannot attach" file))
1007     (unless (file-exists-p file)
1008       (error "No such file: %s" file))
1009     (unless (file-readable-p file)
1010       (error "Permission denied: %s" file))
1011     file))
1012
1013 (defun mml-minibuffer-read-type (name &optional default)
1014   (mailcap-parse-mimetypes)
1015   (let* ((default (or default
1016                       (mm-default-file-encoding name)
1017                       ;; Perhaps here we should check what the file
1018                       ;; looks like, and offer text/plain if it looks
1019                       ;; like text/plain.
1020                       "application/octet-stream"))
1021          (string (completing-read
1022                   (format "Content type (default %s): " default)
1023                   (mapcar 'list (mailcap-mime-types)))))
1024     (if (not (equal string ""))
1025         string
1026       default)))
1027
1028 (defun mml-minibuffer-read-description ()
1029   (let ((description (read-string "One line description: ")))
1030     (when (string-match "\\`[ \t]*\\'" description)
1031       (setq description nil))
1032     description))
1033
1034 (defun mml-minibuffer-read-disposition (type &optional default)
1035   (unless default (setq default
1036                         (if (and (string-match "\\`text/" type)
1037                                  (not (string-match "\\`text/rtf\\'" type)))
1038                             "inline"
1039                           "attachment")))
1040   (let ((disposition (completing-read
1041                       (format "Disposition (default %s): " default)
1042                       '(("attachment") ("inline") (""))
1043                       nil t nil nil default)))
1044     (if (not (equal disposition ""))
1045         disposition
1046       default)))
1047
1048 (defun mml-quote-region (beg end)
1049   "Quote the MML tags in the region."
1050   (interactive "r")
1051   (save-excursion
1052     (save-restriction
1053       ;; Temporarily narrow the region to defend from changes
1054       ;; invalidating END.
1055       (narrow-to-region beg end)
1056       (goto-char (point-min))
1057       ;; Quote parts.
1058       (while (re-search-forward
1059               "<#!*/?\\(multipart\\|part\\|external\\|mml\\)" nil t)
1060         ;; Insert ! after the #.
1061         (goto-char (+ (match-beginning 0) 2))
1062         (insert "!")))))
1063
1064 (defun mml-insert-tag (name &rest plist)
1065   "Insert an MML tag described by NAME and PLIST."
1066   (when (symbolp name)
1067     (setq name (symbol-name name)))
1068   (insert "<#" name)
1069   (while plist
1070     (let ((key (pop plist))
1071           (value (pop plist)))
1072       (when value
1073         ;; Quote VALUE if it contains suspicious characters.
1074         (when (string-match "[\"'\\~/*;() \t\n]" value)
1075           (setq value (with-output-to-string
1076                         (let (print-escape-nonascii)
1077                           (prin1 value)))))
1078         (insert (format " %s=%s" key value)))))
1079   (insert ">\n"))
1080
1081 (defun mml-insert-empty-tag (name &rest plist)
1082   "Insert an empty MML tag described by NAME and PLIST."
1083   (when (symbolp name)
1084     (setq name (symbol-name name)))
1085   (apply #'mml-insert-tag name plist)
1086   (insert "<#/" name ">\n"))
1087
1088 ;;; Attachment functions.
1089
1090 (defcustom mml-dnd-protocol-alist
1091   '(("^file:///" . mml-dnd-attach-file)
1092     ("^file://"  . dnd-open-file)
1093     ("^file:"    . mml-dnd-attach-file))
1094   "The functions to call when a drop in `mml-mode' is made.
1095 See `dnd-protocol-alist' for more information.  When nil, behave
1096 as in other buffers."
1097   :type '(choice (repeat (cons (regexp) (function)))
1098                  (const :tag "Behave as in other buffers" nil))
1099   :version "23.0" ;; No Gnus
1100   :group 'message)
1101
1102 (defcustom mml-dnd-attach-options nil
1103   "Which options should be queried when attaching a file via drag and drop.
1104
1105 If it is a list, valid members are `type', `description' and
1106 `disposition'.  `disposition' implies `type'.  If it is nil,
1107 don't ask for options.  If it is t, ask the user whether or not
1108 to specify options."
1109   :type '(choice
1110           (const :tag "Non" nil)
1111           (const :tag "Query" t)
1112           (list :value (type description disposition)
1113            (set :inline t
1114                 (const type)
1115                 (const description)
1116                 (const disposition))))
1117   :version "23.0" ;; No Gnus
1118   :group 'message)
1119
1120 (defun mml-attach-file (file &optional type description disposition)
1121   "Attach a file to the outgoing MIME message.
1122 The file is not inserted or encoded until you send the message with
1123 `\\[message-send-and-exit]' or `\\[message-send]'.
1124
1125 FILE is the name of the file to attach.  TYPE is its
1126 content-type, a string of the form \"type/subtype\".  DESCRIPTION
1127 is a one-line description of the attachment.  The DISPOSITION
1128 specifies how the attachment is intended to be displayed.  It can
1129 be either \"inline\" (displayed automatically within the message
1130 body) or \"attachment\" (separate from the body)."
1131   (interactive
1132    (let* ((file (mml-minibuffer-read-file "Attach file: "))
1133           (type (mml-minibuffer-read-type file))
1134           (description (mml-minibuffer-read-description))
1135           (disposition (mml-minibuffer-read-disposition type)))
1136      (list file type description disposition)))
1137   (save-excursion
1138     (unless (message-in-body-p) (goto-char (point-max)))
1139     (mml-insert-empty-tag 'part
1140                           'type type
1141                           'filename file
1142                           'disposition (or disposition "attachment")
1143                           'description description)))
1144
1145 (defun mml-dnd-attach-file (uri action)
1146   "Attach a drag and drop file.
1147
1148 Ask for type, description or disposition according to
1149 `mml-dnd-attach-options'."
1150   (let ((file (dnd-get-local-file-name uri t)))
1151     (when (and file (file-regular-p file))
1152       (let ((mml-dnd-attach-options mml-dnd-attach-options)
1153             type description disposition)
1154         (setq mml-dnd-attach-options
1155               (when (and (eq mml-dnd-attach-options t)
1156                          (not
1157                           (y-or-n-p
1158                            "Use default type, disposition and description? ")))
1159                 '(type description disposition)))
1160         (when (or (memq 'type mml-dnd-attach-options)
1161                   (memq 'disposition mml-dnd-attach-options))
1162           (setq type (mml-minibuffer-read-type file)))
1163         (when (memq 'description mml-dnd-attach-options)
1164           (setq description (mml-minibuffer-read-description)))
1165         (when (memq 'disposition mml-dnd-attach-options)
1166           (setq disposition (mml-minibuffer-read-disposition type)))
1167         (mml-attach-file file type description disposition)))))
1168
1169 (defun mml-attach-buffer (buffer &optional type description)
1170   "Attach a buffer to the outgoing MIME message.
1171 See `mml-attach-file' for details of operation."
1172   (interactive
1173    (let* ((buffer (read-buffer "Attach buffer: "))
1174           (type (mml-minibuffer-read-type buffer "text/plain"))
1175           (description (mml-minibuffer-read-description)))
1176      (list buffer type description)))
1177   (save-excursion
1178     (unless (message-in-body-p) (goto-char (point-max)))
1179     (mml-insert-empty-tag 'part 'type type 'buffer buffer
1180                           'disposition "attachment"
1181                           'description description)))
1182
1183 (defun mml-attach-external (file &optional type description)
1184   "Attach an external file into the buffer.
1185 FILE is an ange-ftp/efs specification of the part location.
1186 TYPE is the MIME type to use."
1187   (interactive
1188    (let* ((file (mml-minibuffer-read-file "Attach external file: "))
1189           (type (mml-minibuffer-read-type file))
1190           (description (mml-minibuffer-read-description)))
1191      (list file type description)))
1192   (save-excursion
1193     (unless (message-in-body-p) (goto-char (point-max)))
1194     (mml-insert-empty-tag 'external 'type type 'name file
1195                           'disposition "attachment" 'description description)))
1196
1197 (defun mml-insert-multipart (&optional type)
1198   (interactive (list (completing-read "Multipart type (default mixed): "
1199                                       '(("mixed") ("alternative") ("digest") ("parallel")
1200                                         ("signed") ("encrypted"))
1201                                       nil nil "mixed")))
1202   (or type
1203       (setq type "mixed"))
1204   (mml-insert-empty-tag "multipart" 'type type)
1205   (forward-line -1))
1206
1207 (defun mml-insert-part (&optional type)
1208   (interactive
1209    (list (mml-minibuffer-read-type "")))
1210   (mml-insert-tag 'part 'type type 'disposition "inline")
1211   (forward-line -1))
1212
1213 (defun mml-preview-insert-mail-followup-to ()
1214   "Insert a Mail-Followup-To header before previewing an article.
1215 Should be adopted if code in `message-send-mail' is changed."
1216   (when (and (message-mail-p)
1217              (message-subscribed-p)
1218              (not (mail-fetch-field "mail-followup-to"))
1219              (message-make-mail-followup-to))
1220     (message-position-on-field "Mail-Followup-To" "X-Draft-From")
1221     (insert (message-make-mail-followup-to))))
1222
1223 (defvar mml-preview-buffer nil)
1224
1225 (defun mml-preview (&optional raw)
1226   "Display current buffer with Gnus, in a new buffer.
1227 If RAW, display a raw encoded MIME message.
1228
1229 The window layout for the preview buffer is controled by the variables
1230 `special-display-buffer-names', `special-display-regexps', or
1231 `gnus-buffer-configuration' (the first match made will be used),
1232 or the `pop-to-buffer' function."
1233   (interactive "P")
1234   (setq mml-preview-buffer (generate-new-buffer
1235                             (concat (if raw "*Raw MIME preview of "
1236                                       "*MIME preview of ") (buffer-name))))
1237   (save-excursion
1238     (let* ((buf (current-buffer))
1239            (message-options message-options)
1240            (message-this-is-mail (message-mail-p))
1241            (message-this-is-news (message-news-p))
1242            (message-posting-charset (or (gnus-setup-posting-charset
1243                                          (save-restriction
1244                                            (message-narrow-to-headers-or-head)
1245                                            (message-fetch-field "Newsgroups")))
1246                                         message-posting-charset)))
1247       (message-options-set-recipient)
1248       (when (boundp 'gnus-buffers)
1249         (push mml-preview-buffer gnus-buffers))
1250       (save-restriction
1251         (widen)
1252         (set-buffer mml-preview-buffer)
1253         (erase-buffer)
1254         (insert-buffer-substring buf))
1255       (mml-preview-insert-mail-followup-to)
1256       (let ((message-deletable-headers (if (message-news-p)
1257                                            nil
1258                                          message-deletable-headers)))
1259         (message-generate-headers
1260          (copy-sequence (if (message-news-p)
1261                             message-required-news-headers
1262                           message-required-mail-headers))))
1263       (if (re-search-forward
1264            (concat "^" (regexp-quote mail-header-separator) "\n") nil t)
1265           (replace-match "\n"))
1266       (let ((mail-header-separator ""));; mail-header-separator is removed.
1267         (message-sort-headers)
1268         (mml-to-mime))
1269       (if raw
1270           (when (fboundp 'set-buffer-multibyte)
1271             (let ((s (buffer-string)))
1272               ;; Insert the content into unibyte buffer.
1273               (erase-buffer)
1274               (mm-disable-multibyte)
1275               (insert s)))
1276         (let ((gnus-newsgroup-charset (car message-posting-charset))
1277               gnus-article-prepare-hook gnus-original-article-buffer)
1278           (run-hooks 'gnus-article-decode-hook)
1279           (let ((gnus-newsgroup-name "dummy")
1280                 (gnus-newsrc-hashtb (or gnus-newsrc-hashtb
1281                                         (gnus-make-hashtable 5))))
1282             (gnus-article-prepare-display))))
1283       ;; Disable article-mode-map.
1284       (use-local-map nil)
1285       (gnus-make-local-hook 'kill-buffer-hook)
1286       (add-hook 'kill-buffer-hook
1287                 (lambda ()
1288                   (mm-destroy-parts gnus-article-mime-handles)) nil t)
1289       (setq buffer-read-only t)
1290       (local-set-key "q" (lambda () (interactive) (kill-buffer nil)))
1291       (local-set-key "=" (lambda () (interactive) (delete-other-windows)))
1292       (local-set-key "\r"
1293                      (lambda ()
1294                        (interactive)
1295                        (widget-button-press (point))))
1296       (local-set-key gnus-mouse-2
1297                      (lambda (event)
1298                        (interactive "@e")
1299                        (widget-button-press (widget-event-point event) event)))
1300       (goto-char (point-min))))
1301   (if (and (not (mm-special-display-p (buffer-name mml-preview-buffer)))
1302            (boundp 'gnus-buffer-configuration)
1303            (assq 'mml-preview gnus-buffer-configuration))
1304       (let ((gnus-message-buffer (current-buffer)))
1305         (gnus-configure-windows 'mml-preview))
1306     (pop-to-buffer mml-preview-buffer)))
1307
1308 (defun mml-validate ()
1309   "Validate the current MML document."
1310   (interactive)
1311   (mml-parse))
1312
1313 (defun mml-tweak-part (cont)
1314   "Tweak a MML part."
1315   (let ((tweak (cdr (assq 'tweak cont)))
1316         func)
1317     (cond
1318      (tweak
1319       (setq func
1320             (or (cdr (assoc tweak mml-tweak-function-alist))
1321                 (intern tweak))))
1322      (mml-tweak-type-alist
1323       (let ((alist mml-tweak-type-alist)
1324             (type (or (cdr (assq 'type cont)) "text/plain")))
1325         (while alist
1326           (if (string-match (caar alist) type)
1327               (setq func (cdar alist)
1328                     alist nil)
1329             (setq alist (cdr alist)))))))
1330     (if func
1331         (funcall func cont)
1332       cont)
1333     (let ((alist mml-tweak-sexp-alist))
1334       (while alist
1335         (if (eval (caar alist))
1336             (funcall (cdar alist) cont))
1337         (setq alist (cdr alist)))))
1338   cont)
1339
1340 (defun mml-tweak-externalize-attachments (cont)
1341   "Tweak attached files as external parts."
1342   (let (filename-cons)
1343     (when (and (eq (car cont) 'part)
1344                (not (cdr (assq 'buffer cont)))
1345                (and (setq filename-cons (assq 'filename cont))
1346                     (not (equal (cdr (assq 'nofile cont)) "yes"))))
1347       (setcar cont 'external)
1348       (setcar filename-cons 'name))))
1349
1350 (provide 'mml)
1351
1352 ;;; arch-tag: 583c96cf-1ffe-451b-a5e5-4733ae9ddd12
1353 ;;; mml.el ends here