cgit.sxemacs.org Git - gnus/blob - lisp/mml.el

   1 ;;; mml.el --- A package for parsing and validating MML documents
   2 ;; Copyright (C) 1998, 1999, 2000 Free Software Foundation, Inc.
   3
   4 ;; Author: Lars Magne Ingebrigtsen <larsi@gnus.org>
   5 ;; This file is part of GNU Emacs.
   6
   7 ;; GNU Emacs is free software; you can redistribute it and/or modify
   8 ;; it under the terms of the GNU General Public License as published by
   9 ;; the Free Software Foundation; either version 2, or (at your option)
  10 ;; any later version.
  11
  12 ;; GNU Emacs is distributed in the hope that it will be useful,
  13 ;; but WITHOUT ANY WARRANTY; without even the implied warranty of
  14 ;; MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.  See the
  15 ;; GNU General Public License for more details.
  16
  17 ;; You should have received a copy of the GNU General Public License
  18 ;; along with GNU Emacs; see the file COPYING.  If not, write to the
  19 ;; Free Software Foundation, Inc., 59 Temple Place - Suite 330,
  20 ;; Boston, MA 02111-1307, USA.
  21
  22 ;;; Commentary:
  23
  24 ;;; Code:
  25
  26 (require 'mm-util)
  27 (require 'mm-bodies)
  28 (require 'mm-encode)
  29 (require 'mm-decode)
  30 (require 'mml-sec)
  31 (eval-when-compile (require 'cl))
  32
  33 (eval-and-compile
  34   (autoload 'message-make-message-id "message")
  35   (autoload 'gnus-setup-posting-charset "gnus-msg")
  36   (autoload 'message-fetch-field "message")
  37   (autoload 'message-posting-charset "message"))
  38
  39 (defvar mml-generate-multipart-alist nil
  40   "*Alist of multipart generation functions.
  41 Each entry has the form (NAME . FUNCTION), where
  42 NAME is a string containing the name of the part (without the
  43 leading \"/multipart/\"),
  44 FUNCTION is a Lisp function which is called to generate the part.
  45
  46 The Lisp function has to supply the appropriate MIME headers and the
  47 contents of this part.")
  48
  49 (defvar mml-syntax-table
  50   (let ((table (copy-syntax-table emacs-lisp-mode-syntax-table)))
  51     (modify-syntax-entry ?\\ "/" table)
  52     (modify-syntax-entry ?< "(" table)
  53     (modify-syntax-entry ?> ")" table)
  54     (modify-syntax-entry ?@ "w" table)
  55     (modify-syntax-entry ?/ "w" table)
  56     (modify-syntax-entry ?= " " table)
  57     (modify-syntax-entry ?* " " table)
  58     (modify-syntax-entry ?\; " " table)
  59     (modify-syntax-entry ?\' " " table)
  60     table))
  61
  62 (defvar mml-boundary-function 'mml-make-boundary
  63   "A function called to suggest a boundary.
  64 The function may be called several times, and should try to make a new
  65 suggestion each time.  The function is called with one parameter,
  66 which is a number that says how many times the function has been
  67 called for this message.")
  68
  69 (defvar mml-confirmation-set nil
  70   "A list of symbols, each of which disables some warning.
  71 `unknown-encoding': always send messages contain characters with
  72 unknown encoding; `use-ascii': always use ASCII for those characters
  73 with unknown encoding; `multipart': always send messages with more than
  74 one charsets.")
  75
  76 (defvar mml-generate-default-type "text/plain")
  77
  78 (defvar mml-buffer-list nil)
  79
  80 (defun mml-generate-new-buffer (name)
  81   (let ((buf (generate-new-buffer name)))
  82     (push buf mml-buffer-list)
  83     buf))
  84
  85 (defun mml-destroy-buffers ()
  86   (let (kill-buffer-hook)
  87     (mapcar 'kill-buffer mml-buffer-list)
  88     (setq mml-buffer-list nil)))
  89
  90 (defun mml-parse ()
  91   "Parse the current buffer as an MML document."
  92   (goto-char (point-min))
  93   (let ((table (syntax-table)))
  94     (unwind-protect
  95         (progn
  96           (set-syntax-table mml-syntax-table)
  97           (mml-parse-1))
  98       (set-syntax-table table))))
  99
 100 (defun mml-parse-1 ()
 101   "Parse the current buffer as an MML document."
 102   (let (struct tag point contents charsets warn use-ascii no-markup-p raw)
 103     (while (and (not (eobp))
 104                 (not (looking-at "<#/multipart")))
 105       (cond
 106        ((looking-at "<#multipart")
 107         (push (nconc (mml-read-tag) (mml-parse-1)) struct))
 108        ((looking-at "<#external")
 109         (push (nconc (mml-read-tag) (list (cons 'contents (mml-read-part))))
 110               struct))
 111        (t
 112         (if (or (looking-at "<#part") (looking-at "<#mml"))
 113             (setq tag (mml-read-tag)
 114                   no-markup-p nil
 115                   warn nil)
 116           (setq tag (list 'part '(type . "text/plain"))
 117                 no-markup-p t
 118                 warn t))
 119         (setq raw (cdr (assq 'raw tag))
 120               point (point)
 121               contents (mml-read-part (eq 'mml (car tag)))
 122               charsets (if raw nil
 123                          (mm-find-mime-charset-region point (point))))
 124         (when (and (not raw) (memq nil charsets))
 125           (if (or (memq 'unknown-encoding mml-confirmation-set)
 126                   (y-or-n-p
 127                    "Message contains characters with unknown encoding.  Really send?"))
 128               (if (setq use-ascii
 129                         (or (memq 'use-ascii mml-confirmation-set)
 130                             (y-or-n-p "Use ASCII as charset?")))
 131                   (setq charsets (delq nil charsets))
 132                 (setq warn nil))
 133             (error "Edit your message to remove those characters")))
 134         (if (or raw
 135                 (eq 'mml (car tag))
 136                 (< (length charsets) 2))
 137             (if (or (not no-markup-p)
 138                     (string-match "[^ \t\r\n]" contents))
 139                 ;; Don't create blank parts.
 140                 (push (nconc tag (list (cons 'contents contents)))
 141                       struct))
 142           (let ((nstruct (mml-parse-singlepart-with-multiple-charsets
 143                           tag point (point) use-ascii)))
 144             (when (and warn
 145                        (not (memq 'multipart mml-confirmation-set))
 146                        (not
 147                         (y-or-n-p
 148                          (format
 149                           "Warning: Your message contains more than %d parts.  Really send? "
 150                           (length nstruct)))))
 151               (error "Edit your message to use only one charset"))
 152             (setq struct (nconc nstruct struct)))))))
 153     (unless (eobp)
 154       (forward-line 1))
 155     (nreverse struct)))
 156
 157 (defun mml-parse-singlepart-with-multiple-charsets
 158   (orig-tag beg end &optional use-ascii)
 159   (save-excursion
 160     (save-restriction
 161       (narrow-to-region beg end)
 162       (goto-char (point-min))
 163       (let ((current (or (mm-mime-charset (mm-charset-after))
 164                          (and use-ascii 'us-ascii)))
 165             charset struct space newline paragraph)
 166         (while (not (eobp))
 167           (setq charset (mm-mime-charset (mm-charset-after)))
 168           (cond
 169            ;; The charset remains the same.
 170            ((eq charset 'us-ascii))
 171            ((or (and use-ascii (not charset))
 172                 (eq charset current))
 173             (setq space nil
 174                   newline nil
 175                   paragraph nil))
 176            ;; The initial charset was ascii.
 177            ((eq current 'us-ascii)
 178             (setq current charset
 179                   space nil
 180                   newline nil
 181                   paragraph nil))
 182            ;; We have a change in charsets.
 183            (t
 184             (push (append
 185                    orig-tag
 186                    (list (cons 'contents
 187                                (buffer-substring-no-properties
 188                                 beg (or paragraph newline space (point))))))
 189                   struct)
 190             (setq beg (or paragraph newline space (point))
 191                   current charset
 192                   space nil
 193                   newline nil
 194                   paragraph nil)))
 195           ;; Compute places where it might be nice to break the part.
 196           (cond
 197            ((memq (following-char) '(?  ?\t))
 198             (setq space (1+ (point))))
 199            ((and (eq (following-char) ?\n)
 200                  (not (bobp))
 201                  (eq (char-after (1- (point))) ?\n))
 202             (setq paragraph (point)))
 203            ((eq (following-char) ?\n)
 204             (setq newline (1+ (point)))))
 205           (forward-char 1))
 206         ;; Do the final part.
 207         (unless (= beg (point))
 208           (push (append orig-tag
 209                         (list (cons 'contents
 210                                     (buffer-substring-no-properties
 211                                      beg (point)))))
 212                 struct))
 213         struct))))
 214
 215 (defun mml-read-tag ()
 216   "Read a tag and return the contents."
 217   (let (contents name elem val)
 218     (forward-char 2)
 219     (setq name (buffer-substring-no-properties
 220                 (point) (progn (forward-sexp 1) (point))))
 221     (skip-chars-forward " \t\n")
 222     (while (not (looking-at ">"))
 223       (setq elem (buffer-substring-no-properties
 224                   (point) (progn (forward-sexp 1) (point))))
 225       (skip-chars-forward "= \t\n")
 226       (setq val (buffer-substring-no-properties
 227                  (point) (progn (forward-sexp 1) (point))))
 228       (when (string-match "^\"\\(.*\\)\"$" val)
 229         (setq val (match-string 1 val)))
 230       (push (cons (intern elem) val) contents)
 231       (skip-chars-forward " \t\n"))
 232     (forward-char 1)
 233     ;; Don't skip the leading space.
 234     ;;(skip-chars-forward " \t\n")
 235     (cons (intern name) (nreverse contents))))
 236
 237 (defun mml-read-part (&optional mml)
 238   "Return the buffer up till the next part, multipart or closing part or multipart.
 239 If MML is non-nil, return the buffer up till the correspondent mml tag."
 240   (let ((beg (point)) (count 1))
 241     ;; If the tag ended at the end of the line, we go to the next line.
 242     (when (looking-at "[ \t]*\n")
 243       (forward-line 1))
 244     (if mml
 245         (progn
 246           (while (and (> count 0) (not (eobp)))
 247             (if (re-search-forward "<#\\(/\\)?mml." nil t)
 248                 (setq count (+ count (if (match-beginning 1) -1 1)))
 249               (goto-char (point-max))))
 250           (buffer-substring-no-properties beg (if (> count 0)
 251                                                   (point)
 252                                                 (match-beginning 0))))
 253       (if (re-search-forward
 254            "<#\\(/\\)?\\(multipart\\|part\\|external\\|mml\\)." nil t)
 255           (prog1
 256               (buffer-substring-no-properties beg (match-beginning 0))
 257             (if (or (not (match-beginning 1))
 258                     (equal (match-string 2) "multipart"))
 259                 (goto-char (match-beginning 0))
 260               (when (looking-at "[ \t]*\n")
 261                 (forward-line 1))))
 262         (buffer-substring-no-properties beg (goto-char (point-max)))))))
 263
 264 (defvar mml-boundary nil)
 265 (defvar mml-base-boundary "-=-=")
 266 (defvar mml-multipart-number 0)
 267
 268 (defun mml-generate-mime ()
 269   "Generate a MIME message based on the current MML document."
 270   (let ((cont (mml-parse))
 271         (mml-multipart-number mml-multipart-number))
 272     (if (not cont)
 273         nil
 274       (with-temp-buffer
 275         (if (and (consp (car cont))
 276                  (= (length cont) 1))
 277             (mml-generate-mime-1 (car cont))
 278           (mml-generate-mime-1 (nconc (list 'multipart '(type . "mixed"))
 279                                       cont)))
 280         (buffer-string)))))
 281
 282 (defun mml-generate-mime-1 (cont)
 283   (let ((mm-use-ultra-safe-encoding
 284          (or mm-use-ultra-safe-encoding (assq 'sign cont))))
 285     (save-restriction
 286       (narrow-to-region (point) (point))
 287       (cond
 288        ((or (eq (car cont) 'part) (eq (car cont) 'mml))
 289         (let ((raw (cdr (assq 'raw cont)))
 290               coded encoding charset filename type)
 291           (setq type (or (cdr (assq 'type cont)) "text/plain"))
 292           (if (and (not raw)
 293                    (member (car (split-string type "/")) '("text" "message")))
 294               (with-temp-buffer
 295                 (cond
 296                  ((cdr (assq 'buffer cont))
 297                   (insert-buffer-substring (cdr (assq 'buffer cont))))
 298                  ((and (setq filename (cdr (assq 'filename cont)))
 299                        (not (equal (cdr (assq 'nofile cont)) "yes")))
 300                   (mm-insert-file-contents filename))
 301                  ((eq 'mml (car cont))
 302                   (insert (cdr (assq 'contents cont))))
 303                  (t
 304                   (save-restriction
 305                     (narrow-to-region (point) (point))
 306                     (insert (cdr (assq 'contents cont)))
 307                     ;; Remove quotes from quoted tags.
 308                     (goto-char (point-min))
 309                     (while (re-search-forward
 310                             "<#!+/?\\(part\\|multipart\\|external\\|mml\\)" nil t)
 311                       (delete-region (+ (match-beginning 0) 2)
 312                                      (+ (match-beginning 0) 3))))))
 313                 (cond
 314                  ((eq (car cont) 'mml)
 315                   (let ((mml-boundary (funcall mml-boundary-function
 316                                                (incf mml-multipart-number)))
 317                         (mml-generate-default-type "text/plain"))
 318                     (mml-to-mime))
 319                   (let ((mm-7bit-chars (concat mm-7bit-chars "\x1b")))
 320                     ;; ignore 0x1b, it is part of iso-2022-jp
 321                     (setq encoding (mm-body-7-or-8))))
 322                  ((string= (car (split-string type "/")) "message")
 323                   (let ((mm-7bit-chars (concat mm-7bit-chars "\x1b")))
 324                     ;; ignore 0x1b, it is part of iso-2022-jp
 325                     (setq encoding (mm-body-7-or-8))))
 326                  (t
 327                   (setq charset (mm-encode-body))
 328                   (setq encoding (mm-body-encoding
 329                                   charset (cdr (assq 'encoding cont))))))
 330                 (setq coded (buffer-string)))
 331             (mm-with-unibyte-buffer
 332               (cond
 333                ((cdr (assq 'buffer cont))
 334                 (insert-buffer-substring (cdr (assq 'buffer cont))))
 335                ((and (setq filename (cdr (assq 'filename cont)))
 336                      (not (equal (cdr (assq 'nofile cont)) "yes")))
 337                 (let ((coding-system-for-read mm-binary-coding-system))
 338                   (mm-insert-file-contents filename nil nil nil nil t)))
 339                (t
 340                 (insert (cdr (assq 'contents cont)))))
 341               (setq encoding (mm-encode-buffer type)
 342                     coded (buffer-string))))
 343           (mml-insert-mime-headers cont type charset encoding)
 344           (insert "\n")
 345           (insert coded)))
 346        ((eq (car cont) 'external)
 347         (insert "Content-Type: message/external-body")
 348         (let ((parameters (mml-parameter-string
 349                            cont '(expiration size permission)))
 350               (name (cdr (assq 'name cont))))
 351           (when name
 352             (setq name (mml-parse-file-name name))
 353             (if (stringp name)
 354                 (mml-insert-parameter
 355                  (mail-header-encode-parameter "name" name)
 356                  "access-type=local-file")
 357               (mml-insert-parameter
 358                (mail-header-encode-parameter
 359                 "name" (file-name-nondirectory (nth 2 name)))
 360                (mail-header-encode-parameter "site" (nth 1 name))
 361                (mail-header-encode-parameter
 362                 "directory" (file-name-directory (nth 2 name))))
 363               (mml-insert-parameter
 364                (concat "access-type="
 365                        (if (member (nth 0 name) '("ftp@" "anonymous@"))
 366                            "anon-ftp"
 367                          "ftp")))))
 368           (when parameters
 369             (mml-insert-parameter-string
 370              cont '(expiration size permission))))
 371         (insert "\n\n")
 372         (insert "Content-Type: " (cdr (assq 'type cont)) "\n")
 373         (insert "Content-ID: " (message-make-message-id) "\n")
 374         (insert "Content-Transfer-Encoding: "
 375                 (or (cdr (assq 'encoding cont)) "binary"))
 376         (insert "\n\n")
 377         (insert (or (cdr (assq 'contents cont))))
 378         (insert "\n"))
 379        ((eq (car cont) 'multipart)
 380         (let* ((type (or (cdr (assq 'type cont)) "mixed"))
 381                (mml-generate-default-type (if (equal type "digest")
 382                                               "message/rfc822"
 383                                             "text/plain"))
 384                (handler (assoc type mml-generate-multipart-alist)))
 385           (if handler
 386               (funcall (cdr handler) cont)
 387             ;; No specific handler.  Use default one.
 388             (let ((mml-boundary (mml-compute-boundary cont)))
 389               (insert (format "Content-Type: multipart/%s; boundary=\"%s\"\n"
 390                               type mml-boundary))
 391               ;; Skip `multipart' and `type' elements.
 392               (setq cont (cddr cont))
 393               (while cont
 394                 (insert "\n--" mml-boundary "\n")
 395                 (mml-generate-mime-1 (pop cont)))
 396               (insert "\n--" mml-boundary "--\n")))))
 397        (t
 398         (error "Invalid element: %S" cont)))
 399       (let ((item (assoc (cdr (assq 'sign cont)) mml-sign-alist)))
 400         (when item
 401           (funcall (nth 1 item) cont)))
 402       (let ((item (assoc (cdr (assq 'encrypt cont)) mml-encrypt-alist)))
 403         (when item
 404           (funcall (nth 1 item) cont))))))
 405
 406 (defun mml-compute-boundary (cont)
 407   "Return a unique boundary that does not exist in CONT."
 408   (let ((mml-boundary (funcall mml-boundary-function
 409                                (incf mml-multipart-number))))
 410     ;; This function tries again and again until it has found
 411     ;; a unique boundary.
 412     (while (not (catch 'not-unique
 413                   (mml-compute-boundary-1 cont))))
 414     mml-boundary))
 415
 416 (defun mml-compute-boundary-1 (cont)
 417   (let (filename)
 418     (cond
 419      ((eq (car cont) 'part)
 420       (with-temp-buffer
 421         (cond
 422          ((cdr (assq 'buffer cont))
 423           (insert-buffer-substring (cdr (assq 'buffer cont))))
 424          ((and (setq filename (cdr (assq 'filename cont)))
 425                (not (equal (cdr (assq 'nofile cont)) "yes")))
 426           (mm-insert-file-contents filename))
 427          (t
 428           (insert (cdr (assq 'contents cont)))))
 429         (goto-char (point-min))
 430         (when (re-search-forward (concat "^--" (regexp-quote mml-boundary))
 431                                  nil t)
 432           (setq mml-boundary (funcall mml-boundary-function
 433                                       (incf mml-multipart-number)))
 434           (throw 'not-unique nil))))
 435      ((eq (car cont) 'multipart)
 436       (mapcar 'mml-compute-boundary-1 (cddr cont))))
 437     t))
 438
 439 (defun mml-make-boundary (number)
 440   (concat (make-string (% number 60) ?=)
 441           (if (> number 17)
 442               (format "%x" number)
 443             "")
 444           mml-base-boundary))
 445
 446 (defun mml-insert-mime-headers (cont type charset encoding)
 447   (let (parameters disposition description)
 448     (setq parameters
 449           (mml-parameter-string
 450            cont '(name access-type expiration size permission)))
 451     (when (or charset
 452               parameters
 453               (not (equal type mml-generate-default-type)))
 454       (when (consp charset)
 455         (error
 456          "Can't encode a part with several charsets."))
 457       (insert "Content-Type: " type)
 458       (when charset
 459         (insert "; " (mail-header-encode-parameter
 460                       "charset" (symbol-name charset))))
 461       (when parameters
 462         (mml-insert-parameter-string
 463          cont '(name access-type expiration size permission)))
 464       (insert "\n"))
 465     (setq parameters
 466           (mml-parameter-string
 467            cont '(filename creation-date modification-date read-date)))
 468     (when (or (setq disposition (cdr (assq 'disposition cont)))
 469               parameters)
 470       (insert "Content-Disposition: " (or disposition "inline"))
 471       (when parameters
 472         (mml-insert-parameter-string
 473          cont '(filename creation-date modification-date read-date)))
 474       (insert "\n"))
 475     (unless (eq encoding '7bit)
 476       (insert (format "Content-Transfer-Encoding: %s\n" encoding)))
 477     (when (setq description (cdr (assq 'description cont)))
 478       (insert "Content-Description: "
 479               (mail-encode-encoded-word-string description) "\n"))))
 480
 481 (defun mml-parameter-string (cont types)
 482   (let ((string "")
 483         value type)
 484     (while (setq type (pop types))
 485       (when (setq value (cdr (assq type cont)))
 486         ;; Strip directory component from the filename parameter.
 487         (when (eq type 'filename)
 488           (setq value (file-name-nondirectory value)))
 489         (setq string (concat string "; "
 490                              (mail-header-encode-parameter
 491                               (symbol-name type) value)))))
 492     (when (not (zerop (length string)))
 493       string)))
 494
 495 (defun mml-insert-parameter-string (cont types)
 496   (let (value type)
 497     (while (setq type (pop types))
 498       (when (setq value (cdr (assq type cont)))
 499         ;; Strip directory component from the filename parameter.
 500         (when (eq type 'filename)
 501           (setq value (file-name-nondirectory value)))
 502         (mml-insert-parameter
 503          (mail-header-encode-parameter
 504           (symbol-name type) value))))))
 505
 506 (defvar ange-ftp-name-format)
 507 (defvar efs-path-regexp)
 508 (defun mml-parse-file-name (path)
 509   (if (if (boundp 'efs-path-regexp)
 510           (string-match efs-path-regexp path)
 511         (if (boundp 'ange-ftp-name-format)
 512             (string-match (car ange-ftp-name-format) path)))
 513       (list (match-string 1 path) (match-string 2 path)
 514             (substring path (1+ (match-end 2))))
 515     path))
 516
 517 (defun mml-insert-buffer (buffer)
 518   "Insert BUFFER at point and quote any MML markup."
 519   (save-restriction
 520     (narrow-to-region (point) (point))
 521     (insert-buffer-substring buffer)
 522     (mml-quote-region (point-min) (point-max))
 523     (goto-char (point-max))))
 524
 525 ;;;
 526 ;;; Transforming MIME to MML
 527 ;;;
 528
 529 (defun mime-to-mml ()
 530   "Translate the current buffer (which should be a message) into MML."
 531   ;; First decode the head.
 532   (save-restriction
 533     (message-narrow-to-head)
 534     (mail-decode-encoded-word-region (point-min) (point-max)))
 535   (let ((handles (mm-dissect-buffer t)))
 536     (goto-char (point-min))
 537     (search-forward "\n\n" nil t)
 538     (delete-region (point) (point-max))
 539     (if (stringp (car handles))
 540         (mml-insert-mime handles)
 541       (mml-insert-mime handles t))
 542     (mm-destroy-parts handles))
 543   (save-restriction
 544     (message-narrow-to-head)
 545     ;; Remove them, they are confusing.
 546     (message-remove-header "Content-Type")
 547     (message-remove-header "MIME-Version")
 548     (message-remove-header "Content-Transfer-Encoding")))
 549
 550 (defun mml-to-mime ()
 551   "Translate the current buffer from MML to MIME."
 552   (message-encode-message-body)
 553   (save-restriction
 554     (message-narrow-to-headers-or-head)
 555     (let ((mail-parse-charset message-default-charset))
 556       (mail-encode-encoded-word-buffer))))
 557
 558 (defun mml-insert-mime (handle &optional no-markup)
 559   (let (textp buffer mmlp)
 560     ;; Determine type and stuff.
 561     (unless (stringp (car handle))
 562       (unless (setq textp (equal (mm-handle-media-supertype handle) "text"))
 563         (save-excursion
 564           (set-buffer (setq buffer (mml-generate-new-buffer " *mml*")))
 565           (mm-insert-part handle)
 566           (if (setq mmlp (equal (mm-handle-media-type handle)
 567                                 "message/rfc822"))
 568               (mime-to-mml)))))
 569     (if mmlp
 570         (mml-insert-mml-markup handle nil t t)
 571       (unless (and no-markup
 572                    (equal (mm-handle-media-type handle) "text/plain"))
 573         (mml-insert-mml-markup handle buffer textp)))
 574     (cond
 575      (mmlp
 576       (insert-buffer buffer)
 577       (goto-char (point-max))
 578       (insert "<#/mml>\n"))
 579      ((stringp (car handle))
 580       (mapcar 'mml-insert-mime (cdr handle))
 581       (insert "<#/multipart>\n"))
 582      (textp
 583       (let ((text (mm-get-part handle))
 584             (charset (mail-content-type-get
 585                       (mm-handle-type handle) 'charset)))
 586         (insert (mm-decode-string text charset)))
 587       (goto-char (point-max)))
 588      (t
 589       (insert "<#/part>\n")))))
 590
 591 (defun mml-insert-mml-markup (handle &optional buffer nofile mmlp)
 592   "Take a MIME handle and insert an MML tag."
 593   (if (stringp (car handle))
 594       (insert "<#multipart type=" (mm-handle-media-subtype handle)
 595               ">\n")
 596     (if mmlp
 597         (insert "<#mml type=" (mm-handle-media-type handle))
 598       (insert "<#part type=" (mm-handle-media-type handle)))
 599     (dolist (elem (append (cdr (mm-handle-type handle))
 600                           (cdr (mm-handle-disposition handle))))
 601       (insert " " (symbol-name (car elem)) "=\"" (cdr elem) "\""))
 602     (when (mm-handle-disposition handle)
 603       (insert " disposition=" (car (mm-handle-disposition handle))))
 604     (when buffer
 605       (insert " buffer=\"" (buffer-name buffer) "\""))
 606     (when nofile
 607       (insert " nofile=yes"))
 608     (when (mm-handle-description handle)
 609       (insert " description=\"" (mm-handle-description handle) "\""))
 610     (insert ">\n")))
 611
 612 (defun mml-insert-parameter (&rest parameters)
 613   "Insert PARAMETERS in a nice way."
 614   (dolist (param parameters)
 615     (insert ";")
 616     (let ((point (point)))
 617       (insert " " param)
 618       (when (> (current-column) 71)
 619         (goto-char point)
 620         (insert "\n ")
 621         (end-of-line)))))
 622
 623 ;;;
 624 ;;; Mode for inserting and editing MML forms
 625 ;;;
 626
 627 (defvar mml-mode-map
 628   (let ((sign (make-sparse-keymap))
 629         (encrypt (make-sparse-keymap))
 630         (map (make-sparse-keymap))
 631         (main (make-sparse-keymap)))
 632     (define-key sign "p" 'mml-secure-sign-pgpmime)
 633     (define-key sign "s" 'mml-secure-sign-smime)
 634     (define-key encrypt "p" 'mml-secure-encrypt-pgpmime)
 635     (define-key encrypt "s" 'mml-secure-encrypt-smime)
 636     (define-key map "f" 'mml-attach-file)
 637     (define-key map "b" 'mml-attach-buffer)
 638     (define-key map "e" 'mml-attach-external)
 639     (define-key map "q" 'mml-quote-region)
 640     (define-key map "m" 'mml-insert-multipart)
 641     (define-key map "p" 'mml-insert-part)
 642     (define-key map "v" 'mml-validate)
 643     (define-key map "P" 'mml-preview)
 644     (define-key map "s" sign)
 645     (define-key map "c" encrypt)
 646     ;;(define-key map "n" 'mml-narrow-to-part)
 647     (define-key main "\M-m" map)
 648     main))
 649
 650 (easy-menu-define
 651  mml-menu mml-mode-map ""
 652  '("MML"
 653    ("Attach"
 654     ["File" mml-attach-file t]
 655     ["Buffer" mml-attach-buffer t]
 656     ["External" mml-attach-external t])
 657    ("Insert"
 658     ["Multipart" mml-insert-multipart t]
 659     ["Part" mml-insert-part t])
 660    ("Security"
 661     ("Sign"
 662      ["PGP/MIME" mml-secure-sign-pgpmime t]
 663      ["S/MIME" mml-secure-sign-smime t])
 664     ("Encrypt"
 665      ["PGP/MIME" mml-secure-encrypt-pgpmime t]
 666      ["S/MIME" mml-secure-encrypt-smime t]))
 667    ;;["Narrow" mml-narrow-to-part t]
 668    ["Quote" mml-quote-region t]
 669    ["Validate" mml-validate t]
 670    ["Preview" mml-preview t]))
 671
 672 (defvar mml-mode nil
 673   "Minor mode for editing MML.")
 674
 675 (defun mml-mode (&optional arg)
 676   "Minor mode for editing MML.
 677
 678 \\{mml-mode-map}"
 679   (interactive "P")
 680   (when (set (make-local-variable 'mml-mode)
 681              (if (null arg) (not mml-mode)
 682                (> (prefix-numeric-value arg) 0)))
 683     (gnus-add-minor-mode 'mml-mode " MML" mml-mode-map)
 684     (easy-menu-add mml-menu mml-mode-map)
 685     (run-hooks 'mml-mode-hook)))
 686
 687 ;;;
 688 ;;; Helper functions for reading MIME stuff from the minibuffer and
 689 ;;; inserting stuff to the buffer.
 690 ;;;
 691
 692 (defun mml-minibuffer-read-file (prompt)
 693   (let ((file (read-file-name prompt nil nil t)))
 694     ;; Prevent some common errors.  This is inspired by similar code in
 695     ;; VM.
 696     (when (file-directory-p file)
 697       (error "%s is a directory, cannot attach" file))
 698     (unless (file-exists-p file)
 699       (error "No such file: %s" file))
 700     (unless (file-readable-p file)
 701       (error "Permission denied: %s" file))
 702     file))
 703
 704 (defun mml-minibuffer-read-type (name &optional default)
 705   (mailcap-parse-mimetypes)
 706   (let* ((default (or default
 707                       (mm-default-file-encoding name)
 708                       ;; Perhaps here we should check what the file
 709                       ;; looks like, and offer text/plain if it looks
 710                       ;; like text/plain.
 711                       "application/octet-stream"))
 712          (string (completing-read
 713                   (format "Content type (default %s): " default)
 714                   (mapcar 'list (mailcap-mime-types)))))
 715     (if (not (equal string ""))
 716         string
 717       default)))
 718
 719 (defun mml-minibuffer-read-description ()
 720   (let ((description (read-string "One line description: ")))
 721     (when (string-match "\\`[ \t]*\\'" description)
 722       (setq description nil))
 723     description))
 724
 725 (defun mml-quote-region (beg end)
 726   "Quote the MML tags in the region."
 727   (interactive "r")
 728   (save-excursion
 729     (save-restriction
 730       ;; Temporarily narrow the region to defend from changes
 731       ;; invalidating END.
 732       (narrow-to-region beg end)
 733       (goto-char (point-min))
 734       ;; Quote parts.
 735       (while (re-search-forward
 736               "<#!*/?\\(multipart\\|part\\|external\\|mml\\)" nil t)
 737         ;; Insert ! after the #.
 738         (goto-char (+ (match-beginning 0) 2))
 739         (insert "!")))))
 740
 741 (defun mml-insert-tag (name &rest plist)
 742   "Insert an MML tag described by NAME and PLIST."
 743   (when (symbolp name)
 744     (setq name (symbol-name name)))
 745   (insert "<#" name)
 746   (while plist
 747     (let ((key (pop plist))
 748           (value (pop plist)))
 749       (when value
 750         ;; Quote VALUE if it contains suspicious characters.
 751         (when (string-match "[\"'\\~/*;() \t\n]" value)
 752           (setq value (prin1-to-string value)))
 753         (insert (format " %s=%s" key value)))))
 754   (insert ">\n"))
 755
 756 (defun mml-insert-empty-tag (name &rest plist)
 757   "Insert an empty MML tag described by NAME and PLIST."
 758   (when (symbolp name)
 759     (setq name (symbol-name name)))
 760   (apply #'mml-insert-tag name plist)
 761   (insert "<#/" name ">\n"))
 762
 763 ;;; Attachment functions.
 764
 765 (defun mml-attach-file (file &optional type description)
 766   "Attach a file to the outgoing MIME message.
 767 The file is not inserted or encoded until you send the message with
 768 `\\[message-send-and-exit]' or `\\[message-send]'.
 769
 770 FILE is the name of the file to attach.  TYPE is its content-type, a
 771 string of the form \"type/subtype\".  DESCRIPTION is a one-line
 772 description of the attachment."
 773   (interactive
 774    (let* ((file (mml-minibuffer-read-file "Attach file: "))
 775           (type (mml-minibuffer-read-type file))
 776           (description (mml-minibuffer-read-description)))
 777      (list file type description)))
 778   (mml-insert-empty-tag 'part 'type type 'filename file
 779                         'disposition "attachment" 'description description))
 780
 781 (defun mml-attach-buffer (buffer &optional type description)
 782   "Attach a buffer to the outgoing MIME message.
 783 See `mml-attach-file' for details of operation."
 784   (interactive
 785    (let* ((buffer (read-buffer "Attach buffer: "))
 786           (type (mml-minibuffer-read-type buffer "text/plain"))
 787           (description (mml-minibuffer-read-description)))
 788      (list buffer type description)))
 789   (mml-insert-empty-tag 'part 'type type 'buffer buffer
 790                         'disposition "attachment" 'description description))
 791
 792 (defun mml-attach-external (file &optional type description)
 793   "Attach an external file into the buffer.
 794 FILE is an ange-ftp/efs specification of the part location.
 795 TYPE is the MIME type to use."
 796   (interactive
 797    (let* ((file (mml-minibuffer-read-file "Attach external file: "))
 798           (type (mml-minibuffer-read-type file))
 799           (description (mml-minibuffer-read-description)))
 800      (list file type description)))
 801   (mml-insert-empty-tag 'external 'type type 'name file
 802                         'disposition "attachment" 'description description))
 803
 804 (defun mml-insert-multipart (&optional type)
 805   (interactive (list (completing-read "Multipart type (default mixed): "
 806                                       '(("mixed") ("alternative") ("digest") ("parallel")
 807                                         ("signed") ("encrypted"))
 808                                       nil nil "mixed")))
 809   (or type
 810       (setq type "mixed"))
 811   (mml-insert-empty-tag "multipart" 'type type)
 812   (forward-line -1))
 813
 814 (defun mml-insert-part (&optional type)
 815   (interactive
 816    (list (mml-minibuffer-read-type "")))
 817   (mml-insert-tag 'part 'type type 'disposition "inline")
 818   (forward-line -1))
 819
 820 (defun mml-preview (&optional raw)
 821   "Display current buffer with Gnus, in a new buffer.
 822 If RAW, don't highlight the article."
 823   (interactive "P")
 824   (let ((buf (current-buffer))
 825         (message-options message-options)
 826         (message-posting-charset (or (gnus-setup-posting-charset
 827                                       (save-restriction
 828                                         (message-narrow-to-headers-or-head)
 829                                         (message-fetch-field "Newsgroups")))
 830                                      message-posting-charset)))
 831     (message-options-set-recipient)
 832     (switch-to-buffer (generate-new-buffer
 833                        (concat (if raw "*Raw MIME preview of "
 834                                  "*MIME preview of ") (buffer-name))))
 835     (erase-buffer)
 836     (insert-buffer buf)
 837     (if (re-search-forward
 838          (concat "^" (regexp-quote mail-header-separator) "\n") nil t)
 839         (replace-match "\n"))
 840     (mml-to-mime)
 841     (if raw
 842         (when (fboundp 'set-buffer-multibyte)
 843           (let ((s (buffer-string)))
 844             ;; Insert the content into unibyte buffer.
 845             (erase-buffer)
 846             (mm-disable-multibyte)
 847             (insert s)))
 848       (let ((gnus-newsgroup-charset (car message-posting-charset)))
 849         (run-hooks 'gnus-article-decode-hook)
 850         (let ((gnus-newsgroup-name "dummy"))
 851           (gnus-article-prepare-display))))
 852     (fundamental-mode)
 853     (setq buffer-read-only t)
 854     (goto-char (point-min))))
 855
 856 (defun mml-validate ()
 857   "Validate the current MML document."
 858   (interactive)
 859   (mml-parse))
 860
 861 (provide 'mml)
 862
 863 ;;; mml.el ends here