cgit.sxemacs.org Git - gnus/blob - lisp/mm-view.el

   1 ;;; mm-view.el --- Functions for viewing MIME objects
   2 ;; Copyright (C) 1998, 1999, 2000 Free Software Foundation, Inc.
   3
   4 ;; Author: Lars Magne Ingebrigtsen <larsi@gnus.org>
   5 ;; This file is part of GNU Emacs.
   6
   7 ;; GNU Emacs is free software; you can redistribute it and/or modify
   8 ;; it under the terms of the GNU General Public License as published by
   9 ;; the Free Software Foundation; either version 2, or (at your option)
  10 ;; any later version.
  11
  12 ;; GNU Emacs is distributed in the hope that it will be useful,
  13 ;; but WITHOUT ANY WARRANTY; without even the implied warranty of
  14 ;; MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.  See the
  15 ;; GNU General Public License for more details.
  16
  17 ;; You should have received a copy of the GNU General Public License
  18 ;; along with GNU Emacs; see the file COPYING.  If not, write to the
  19 ;; Free Software Foundation, Inc., 59 Temple Place - Suite 330,
  20 ;; Boston, MA 02111-1307, USA.
  21
  22 ;;; Commentary:
  23
  24 ;;; Code:
  25
  26 (eval-when-compile (require 'cl))
  27 (require 'mail-parse)
  28 (require 'mailcap)
  29 (require 'mm-bodies)
  30 (require 'mm-decode)
  31
  32 (eval-and-compile
  33   (autoload 'gnus-article-prepare-display "gnus-art")
  34   (autoload 'vcard-parse-string "vcard")
  35   (autoload 'vcard-format-string "vcard")
  36   (autoload 'fill-flowed "flow-fill")
  37   (autoload 'diff-mode "diff-mode"))
  38
  39 ;;;
  40 ;;; Functions for displaying various formats inline
  41 ;;;
  42 (defun mm-inline-image-emacs (handle)
  43   (let ((b (point-marker))
  44         buffer-read-only)
  45     (insert "\n")
  46     (put-image (mm-get-image handle) b "x")
  47     (mm-handle-set-undisplayer
  48      handle
  49      `(lambda () (remove-images ,b (1+ ,b))))))
  50
  51 (defun mm-inline-image-xemacs (handle)
  52   (let ((b (point))
  53         (annot (make-annotation (mm-get-image handle) nil 'text))
  54         buffer-read-only)
  55     (insert "\n")
  56     (mm-handle-set-undisplayer
  57      handle
  58      `(lambda ()
  59         (let (buffer-read-only)
  60           (delete-annotation ,annot)
  61           (delete-region ,(set-marker (make-marker) b)
  62                          ,(set-marker (make-marker) (point))))))
  63     (set-extent-property annot 'mm t)
  64     (set-extent-property annot 'duplicable t)))
  65
  66 (eval-and-compile
  67   (if (string-match "XEmacs" (emacs-version))
  68       (fset 'mm-inline-image 'mm-inline-image-xemacs)
  69     (fset 'mm-inline-image 'mm-inline-image-emacs)))
  70
  71 (defvar mm-w3-setup nil)
  72 (defun mm-setup-w3 ()
  73   (unless mm-w3-setup
  74     (require 'w3)
  75     (w3-do-setup)
  76     (require 'url)
  77     (require 'w3-vars)
  78     (require 'url-vars)
  79     (setq mm-w3-setup t)))
  80
  81 (defun mm-inline-text (handle)
  82   (let ((type (mm-handle-media-subtype handle))
  83         text buffer-read-only)
  84     (cond
  85      ((equal type "html")
  86       (mm-setup-w3)
  87       (setq text (mm-get-part handle))
  88       (let ((b (point))
  89             (url-standalone-mode t)
  90             (url-current-object
  91              (url-generic-parse-url (format "cid:%s" (mm-handle-id handle))))
  92             (width (window-width))
  93             (charset (mail-content-type-get
  94                       (mm-handle-type handle) 'charset)))
  95         (save-excursion
  96           (insert text)
  97           (save-restriction
  98             (narrow-to-region b (point))
  99             (goto-char (point-min))
 100             (if (or (and (boundp 'w3-meta-content-type-charset-regexp)
 101                          (re-search-forward
 102                           w3-meta-content-type-charset-regexp nil t))
 103                     (and (boundp 'w3-meta-charset-content-type-regexp)
 104                          (re-search-forward
 105                           w3-meta-charset-content-type-regexp nil t)))
 106                 (setq charset (or (w3-coding-system-for-mime-charset
 107                                    (buffer-substring-no-properties
 108                                     (match-beginning 2)
 109                                     (match-end 2)))
 110                                   charset)))
 111             (delete-region (point-min) (point-max))
 112             (insert (mm-decode-string text charset))
 113             (save-window-excursion
 114               (save-restriction
 115                 (let ((w3-strict-width width)
 116                       (url-standalone-mode t))
 117                   (condition-case var
 118                       (w3-region (point-min) (point-max))
 119                     (error)))))
 120             (mm-handle-set-undisplayer
 121              handle
 122              `(lambda ()
 123                 (let (buffer-read-only)
 124                   (if (functionp 'remove-specifier)
 125                       (mapcar (lambda (prop)
 126                                 (remove-specifier
 127                                  (face-property 'default prop)
 128                                  (current-buffer)))
 129                               '(background background-pixmap foreground)))
 130                   (delete-region ,(point-min-marker)
 131                                  ,(point-max-marker)))))))))
 132      ((or (equal type "enriched")
 133           (equal type "richtext"))
 134       (save-excursion
 135         (mm-with-unibyte-buffer
 136           (mm-insert-part handle)
 137           (save-window-excursion
 138             (enriched-decode (point-min) (point-max))
 139             (setq text (buffer-string)))))
 140       (mm-insert-inline handle text))
 141      ((equal type "x-vcard")
 142       (mm-insert-inline
 143        handle
 144        (concat "\n-- \n"
 145                (if (fboundp 'vcard-pretty-print)
 146                    (vcard-pretty-print (mm-get-part handle))
 147                  (vcard-format-string
 148                   (vcard-parse-string (mm-get-part handle)
 149                                       'vcard-standard-filter))))))
 150      (t
 151       (let ((b (point))
 152             (charset (mail-content-type-get
 153                       (mm-handle-type handle) 'charset)))
 154         (if (eq charset 'gnus-decoded)
 155             (mm-insert-part handle)
 156           (insert (mm-decode-string (mm-get-part handle) charset)))
 157         (when (and (equal type "plain")
 158                    (equal (cdr (assoc 'format (mm-handle-type handle)))
 159                           "flowed"))
 160           (save-restriction
 161             (narrow-to-region b (point))
 162             (goto-char b)
 163             (fill-flowed)
 164             (goto-char (point-max))))
 165         (save-restriction
 166           (narrow-to-region b (point))
 167           (set-text-properties (point-min) (point-max) nil)
 168           (mm-handle-set-undisplayer
 169            handle
 170            `(lambda ()
 171               (let (buffer-read-only)
 172                 (delete-region ,(point-min-marker)
 173                                ,(point-max-marker)))))))))))
 174
 175 (defun mm-insert-inline (handle text)
 176   "Insert TEXT inline from HANDLE."
 177   (let ((b (point)))
 178     (insert text)
 179     (mm-handle-set-undisplayer
 180      handle
 181      `(lambda ()
 182         (let (buffer-read-only)
 183           (delete-region ,(set-marker (make-marker) b)
 184                          ,(set-marker (make-marker) (point))))))))
 185
 186 (defun mm-inline-audio (handle)
 187   (message "Not implemented"))
 188
 189 (defun mm-view-sound-file ()
 190   (message "Not implemented"))
 191
 192 (defun mm-w3-prepare-buffer ()
 193   (require 'w3)
 194   (let ((url-standalone-mode t))
 195     (w3-prepare-buffer)))
 196
 197 (defun mm-view-message ()
 198   (mm-enable-multibyte)
 199   (let (handles)
 200     (let (gnus-article-mime-handles)
 201       ;; Double decode problem may happen.  See mm-inline-message.
 202       (run-hooks 'gnus-article-decode-hook)
 203       (gnus-article-prepare-display)
 204       (setq handles gnus-article-mime-handles))
 205     (when handles
 206       (setq gnus-article-mime-handles
 207             (nconc gnus-article-mime-handles
 208                    (if (listp (car handles))
 209                        handles (list handles))))))
 210   (fundamental-mode)
 211   (goto-char (point-min)))
 212
 213 (defun mm-inline-message (handle)
 214   (let ((b (point))
 215         (charset (mail-content-type-get
 216                   (mm-handle-type handle) 'charset))
 217         gnus-displaying-mime handles)
 218     (when (and charset
 219                (stringp charset))
 220       (setq charset (intern (downcase charset)))
 221       (when (eq charset 'us-ascii)
 222         (setq charset nil)))
 223     (save-excursion
 224       (save-restriction
 225         (narrow-to-region b b)
 226         (mm-insert-part handle)
 227         (let (gnus-article-mime-handles
 228               ;; disable prepare hook
 229               gnus-article-prepare-hook
 230               (gnus-newsgroup-charset
 231                (or charset gnus-newsgroup-charset)))
 232           (run-hooks 'gnus-article-decode-hook)
 233           (gnus-article-prepare-display)
 234           (setq handles gnus-article-mime-handles))
 235         (goto-char (point-max))
 236         (unless (bolp)
 237           (insert "\n"))
 238         (insert "----------\n\n")
 239         (when handles
 240           (setq gnus-article-mime-handles
 241                 (nconc gnus-article-mime-handles
 242                        (if (listp (car handles))
 243                            handles (list handles)))))
 244         (mm-handle-set-undisplayer
 245          handle
 246          `(lambda ()
 247             (let (buffer-read-only)
 248               (condition-case nil
 249                   ;; This is only valid on XEmacs.
 250                   (mapcar (lambda (prop)
 251                             (remove-specifier
 252                              (face-property 'default prop) (current-buffer)))
 253                           '(background background-pixmap foreground))
 254                 (error nil))
 255               (delete-region ,(point-min-marker) ,(point-max-marker)))))))))
 256
 257 (defun mm-display-patch-inline (handle)
 258   (let (text)
 259     (with-temp-buffer
 260       (mm-insert-part handle)
 261       (diff-mode)
 262       (font-lock-fontify-buffer)
 263       (when (fboundp 'extent-list)
 264         (map-extents (lambda (ext ignored)
 265                        (set-extent-property ext 'duplicable t)
 266                        nil)
 267                      nil nil nil nil nil 'text-prop))
 268       (setq text (buffer-string)))
 269     (mm-insert-inline handle text)))
 270
 271 (provide 'mm-view)
 272
 273 ;; mm-view.el ends here