cgit.sxemacs.org Git - gnus/blob - lisp/mm-util.el

   1 ;;; mm-util.el --- Utility functions for Mule and low level things
   2 ;; Copyright (C) 1998, 1999, 2000, 2001, 2002, 2003, 2004
   3 ;;   Free Software Foundation, Inc.
   4
   5 ;; Author: Lars Magne Ingebrigtsen <larsi@gnus.org>
   6 ;;      MORIOKA Tomohiko <morioka@jaist.ac.jp>
   7 ;; This file is part of GNU Emacs.
   8
   9 ;; GNU Emacs is free software; you can redistribute it and/or modify
  10 ;; it under the terms of the GNU General Public License as published by
  11 ;; the Free Software Foundation; either version 2, or (at your option)
  12 ;; any later version.
  13
  14 ;; GNU Emacs is distributed in the hope that it will be useful,
  15 ;; but WITHOUT ANY WARRANTY; without even the implied warranty of
  16 ;; MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.  See the
  17 ;; GNU General Public License for more details.
  18
  19 ;; You should have received a copy of the GNU General Public License
  20 ;; along with GNU Emacs; see the file COPYING.  If not, write to the
  21 ;; Free Software Foundation, Inc., 59 Temple Place - Suite 330,
  22 ;; Boston, MA 02111-1307, USA.
  23
  24 ;;; Commentary:
  25
  26 ;;; Code:
  27
  28 (eval-when-compile (require 'cl))
  29 (require 'mail-prsvr)
  30
  31 (eval-and-compile
  32   (mapcar
  33    (lambda (elem)
  34      (let ((nfunc (intern (format "mm-%s" (car elem)))))
  35        (if (fboundp (car elem))
  36            (defalias nfunc (car elem))
  37          (defalias nfunc (cdr elem)))))
  38    '((decode-coding-string . (lambda (s a) s))
  39      (encode-coding-string . (lambda (s a) s))
  40      (encode-coding-region . ignore)
  41      (coding-system-list . ignore)
  42      (decode-coding-region . ignore)
  43      (char-int . identity)
  44      (coding-system-equal . equal)
  45      (annotationp . ignore)
  46      (set-buffer-file-coding-system . ignore)
  47      (read-charset
  48       . (lambda (prompt)
  49           "Return a charset."
  50           (intern
  51            (completing-read
  52             prompt
  53             (mapcar (lambda (e) (list (symbol-name (car e))))
  54                     mm-mime-mule-charset-alist)
  55             nil t))))
  56      (subst-char-in-string
  57       . (lambda (from to string &optional inplace) ;; stolen (and renamed) from nnheader.el
  58           "Replace characters in STRING from FROM to TO.
  59           Unless optional argument INPLACE is non-nil, return a new string."
  60           (let ((string (if inplace string (copy-sequence string)))
  61                 (len (length string))
  62                 (idx 0))
  63             ;; Replace all occurrences of FROM with TO.
  64             (while (< idx len)
  65               (when (= (aref string idx) from)
  66                 (aset string idx to))
  67               (setq idx (1+ idx)))
  68             string)))
  69      (replace-in-string
  70       . (lambda (string regexp rep &optional literal)
  71           "See `replace-regexp-in-string', only the order of args differs."
  72           (replace-regexp-in-string regexp rep string nil literal)))
  73      (string-as-unibyte . identity)
  74      (string-make-unibyte . identity)
  75      (string-as-multibyte . identity)
  76      (multibyte-string-p . ignore)
  77      ;; It is not a MIME function, but some MIME functions use it.
  78      (make-temp-file . (lambda (prefix &optional dir-flag)
  79                          (let ((file (expand-file-name
  80                                       (make-temp-name prefix)
  81                                       (if (fboundp 'temp-directory)
  82                                           (temp-directory)
  83                                         temporary-file-directory))))
  84                            (if dir-flag
  85                                (make-directory file))
  86                            file)))
  87      (insert-byte . insert-char)
  88      (multibyte-char-to-unibyte . identity))))
  89
  90 (eval-and-compile
  91   (defalias 'mm-char-or-char-int-p
  92     (cond
  93      ((fboundp 'char-or-char-int-p) 'char-or-char-int-p)
  94      ((fboundp 'char-valid-p) 'char-valid-p)
  95      (t 'identity))))
  96
  97 ;; Fixme:  This seems always to be used to read a MIME charset, so it
  98 ;; should be re-named and fixed (in Emacs) to offer completion only on
  99 ;; proper charset names (base coding systems which have a
 100 ;; mime-charset defined).  XEmacs doesn't believe in mime-charset;
 101 ;; test with
 102 ;;   `(or (coding-system-get 'iso-8859-1 'mime-charset)
 103 ;;        (coding-system-get 'iso-8859-1 :mime-charset))'
 104 ;; Actually, there should be an `mm-coding-system-mime-charset'.
 105 (eval-and-compile
 106   (defalias 'mm-read-coding-system
 107     (cond
 108      ((fboundp 'read-coding-system)
 109       (if (and (featurep 'xemacs)
 110                (<= (string-to-number emacs-version) 21.1))
 111           (lambda (prompt &optional default-coding-system)
 112             (read-coding-system prompt))
 113         'read-coding-system))
 114      (t (lambda (prompt &optional default-coding-system)
 115           "Prompt the user for a coding system."
 116           (completing-read
 117            prompt (mapcar (lambda (s) (list (symbol-name (car s))))
 118                           mm-mime-mule-charset-alist)))))))
 119
 120 (defvar mm-coding-system-list nil)
 121 (defun mm-get-coding-system-list ()
 122   "Get the coding system list."
 123   (or mm-coding-system-list
 124       (setq mm-coding-system-list (mm-coding-system-list))))
 125
 126 (defun mm-coding-system-p (cs)
 127   "Return non-nil if CS is a symbol naming a coding system.
 128 In XEmacs, also return non-nil if CS is a coding system object.
 129 If CS is available, return CS itself in Emacs, and return a coding
 130 system object in XEmacs."
 131   (if (fboundp 'find-coding-system)
 132       (find-coding-system cs)
 133     (if (fboundp 'coding-system-p)
 134         (when (coding-system-p cs)
 135           cs)
 136       ;; Is this branch ever actually useful?
 137       (car (memq cs (mm-get-coding-system-list))))))
 138
 139 (defvar mm-charset-synonym-alist
 140   `(
 141     ;; Not in XEmacs, but it's not a proper MIME charset anyhow.
 142     ,@(unless (mm-coding-system-p 'x-ctext)
 143        '((x-ctext . ctext)))
 144     ;; ISO-8859-15 is very similar to ISO-8859-1.  But it's _different_!
 145     ,@(unless (mm-coding-system-p 'iso-8859-15)
 146        '((iso-8859-15 . iso-8859-1)))
 147     ;; BIG-5HKSCS is similar to, but different than, BIG-5.
 148     ,@(unless (mm-coding-system-p 'big5-hkscs)
 149         '((big5-hkscs . big5)))
 150     ;; Windows-1252 is actually a superset of Latin-1.  See also
 151     ;; `gnus-article-dumbquotes-map'.
 152     ,@(unless (mm-coding-system-p 'windows-1252)
 153        (if (mm-coding-system-p 'cp1252)
 154            '((windows-1252 . cp1252))
 155          '((windows-1252 . iso-8859-1))))
 156     ;; Windows-1250 is a variant of Latin-2 heavily used by Microsoft
 157     ;; Outlook users in Czech republic. Use this to allow reading of their
 158     ;; e-mails. cp1250 should be defined by M-x codepage-setup.
 159     ,@(if (and (not (mm-coding-system-p 'windows-1250))
 160                (mm-coding-system-p 'cp1250))
 161           '((windows-1250 . cp1250)))
 162     ;; A Microsoft misunderstanding.
 163     ,@(unless (mm-coding-system-p 'ks_c_5601-1987)
 164         (if (mm-coding-system-p 'cp949)
 165             '((ks_c_5601-1987 . cp949))
 166           '((ks_c_5601-1987 . euc-kr))))
 167     )
 168   "A mapping from invalid charset names to the real charset names.")
 169
 170 (defvar mm-binary-coding-system
 171   (cond
 172    ((mm-coding-system-p 'binary) 'binary)
 173    ((mm-coding-system-p 'no-conversion) 'no-conversion)
 174    (t nil))
 175   "100% binary coding system.")
 176
 177 (defvar mm-text-coding-system
 178   (or (if (memq system-type '(windows-nt ms-dos ms-windows))
 179           (and (mm-coding-system-p 'raw-text-dos) 'raw-text-dos)
 180         (and (mm-coding-system-p 'raw-text) 'raw-text))
 181       mm-binary-coding-system)
 182   "Text-safe coding system (For removing ^M).")
 183
 184 (defvar mm-text-coding-system-for-write nil
 185   "Text coding system for write.")
 186
 187 (defvar mm-auto-save-coding-system
 188   (cond
 189    ((mm-coding-system-p 'utf-8-emacs)   ; Mule 7
 190     (if (memq system-type '(windows-nt ms-dos ms-windows))
 191         (if (mm-coding-system-p 'utf-8-emacs-dos)
 192             'utf-8-emacs-dos mm-binary-coding-system)
 193       'utf-8-emacs))
 194    ((mm-coding-system-p 'emacs-mule)
 195     (if (memq system-type '(windows-nt ms-dos ms-windows))
 196         (if (mm-coding-system-p 'emacs-mule-dos)
 197             'emacs-mule-dos mm-binary-coding-system)
 198       'emacs-mule))
 199    ((mm-coding-system-p 'escape-quoted) 'escape-quoted)
 200    (t mm-binary-coding-system))
 201   "Coding system of auto save file.")
 202
 203 (defvar mm-universal-coding-system mm-auto-save-coding-system
 204   "The universal coding system.")
 205
 206 ;; Fixme: some of the cars here aren't valid MIME charsets.  That
 207 ;; should only matter with XEmacs, though.
 208 (defvar mm-mime-mule-charset-alist
 209   `((us-ascii ascii)
 210     (iso-8859-1 latin-iso8859-1)
 211     (iso-8859-2 latin-iso8859-2)
 212     (iso-8859-3 latin-iso8859-3)
 213     (iso-8859-4 latin-iso8859-4)
 214     (iso-8859-5 cyrillic-iso8859-5)
 215     ;; Non-mule (X)Emacs uses the last mule-charset for 8bit characters.
 216     ;; The fake mule-charset, gnus-koi8-r, tells Gnus that the default
 217     ;; charset is koi8-r, not iso-8859-5.
 218     (koi8-r cyrillic-iso8859-5 gnus-koi8-r)
 219     (iso-8859-6 arabic-iso8859-6)
 220     (iso-8859-7 greek-iso8859-7)
 221     (iso-8859-8 hebrew-iso8859-8)
 222     (iso-8859-9 latin-iso8859-9)
 223     (iso-8859-14 latin-iso8859-14)
 224     (iso-8859-15 latin-iso8859-15)
 225     (viscii vietnamese-viscii-lower)
 226     (iso-2022-jp latin-jisx0201 japanese-jisx0208 japanese-jisx0208-1978)
 227     (euc-kr korean-ksc5601)
 228     (gb2312 chinese-gb2312)
 229     (big5 chinese-big5-1 chinese-big5-2)
 230     (tibetan tibetan)
 231     (thai-tis620 thai-tis620)
 232     (iso-2022-7bit ethiopic arabic-1-column arabic-2-column)
 233     (iso-2022-jp-2 latin-iso8859-1 greek-iso8859-7
 234                    latin-jisx0201 japanese-jisx0208-1978
 235                    chinese-gb2312 japanese-jisx0208
 236                    korean-ksc5601 japanese-jisx0212)
 237     (iso-2022-int-1 latin-iso8859-1 greek-iso8859-7
 238                     latin-jisx0201 japanese-jisx0208-1978
 239                     chinese-gb2312 japanese-jisx0208
 240                     korean-ksc5601 japanese-jisx0212
 241                     chinese-cns11643-1 chinese-cns11643-2)
 242     (iso-2022-int-1 latin-iso8859-1 latin-iso8859-2
 243                     cyrillic-iso8859-5 greek-iso8859-7
 244                     latin-jisx0201 japanese-jisx0208-1978
 245                     chinese-gb2312 japanese-jisx0208
 246                     korean-ksc5601 japanese-jisx0212
 247                     chinese-cns11643-1 chinese-cns11643-2
 248                     chinese-cns11643-3 chinese-cns11643-4
 249                     chinese-cns11643-5 chinese-cns11643-6
 250                     chinese-cns11643-7)
 251     (iso-2022-jp-3 latin-jisx0201 japanese-jisx0208-1978 japanese-jisx0208
 252                    japanese-jisx0213-1 japanese-jisx0213-2)
 253     (shift_jis latin-jisx0201 katakana-jisx0201 japanese-jisx0208)
 254     ,(if (or (not (fboundp 'charsetp)) ;; non-Mule case
 255              (charsetp 'unicode-a)
 256              (not (mm-coding-system-p 'mule-utf-8)))
 257          '(utf-8 unicode-a unicode-b unicode-c unicode-d unicode-e)
 258        ;; If we have utf-8 we're in Mule 5+.
 259        (append '(utf-8)
 260                (delete 'ascii
 261                        (coding-system-get 'mule-utf-8 'safe-charsets)))))
 262   "Alist of MIME-charset/MULE-charsets.")
 263
 264 ;; Correct by construction, but should be unnecessary:
 265 ;; XEmacs hates it.
 266 (when (and (not (featurep 'xemacs))
 267            (fboundp 'coding-system-list)
 268            (fboundp 'sort-coding-systems))
 269   (setq mm-mime-mule-charset-alist
 270         (apply
 271          'nconc
 272          (mapcar
 273           (lambda (cs)
 274             (when (and (or (coding-system-get cs :mime-charset) ; Emacs 22
 275                            (coding-system-get cs 'mime-charset))
 276                        (not (eq t (coding-system-get cs 'safe-charsets))))
 277               (list (cons (or (coding-system-get cs :mime-charset)
 278                               (coding-system-get cs 'mime-charset))
 279                           (delq 'ascii
 280                                 (coding-system-get cs 'safe-charsets))))))
 281           (sort-coding-systems (coding-system-list 'base-only))))))
 282
 283 (defvar mm-hack-charsets '(iso-8859-15 iso-2022-jp-2)
 284   "A list of special charsets.
 285 Valid elements include:
 286 `iso-8859-15'    convert ISO-8859-1, -9 to ISO-8859-15 if ISO-8859-15 exists.
 287 `iso-2022-jp-2'  convert ISO-2022-jp to ISO-2022-jp-2 if ISO-2022-jp-2 exists."
 288 )
 289
 290 (defvar mm-iso-8859-15-compatible
 291   '((iso-8859-1 "\xA4\xA6\xA8\xB4\xB8\xBC\xBD\xBE")
 292     (iso-8859-9 "\xA4\xA6\xA8\xB4\xB8\xBC\xBD\xBE\xD0\xDD\xDE\xF0\xFD\xFE"))
 293   "ISO-8859-15 exchangeable coding systems and inconvertible characters.")
 294
 295 (defvar mm-iso-8859-x-to-15-table
 296   (and (fboundp 'coding-system-p)
 297        (mm-coding-system-p 'iso-8859-15)
 298        (mapcar
 299         (lambda (cs)
 300           (if (mm-coding-system-p (car cs))
 301               (let ((c (string-to-char
 302                         (decode-coding-string "\341" (car cs)))))
 303                 (cons (char-charset c)
 304                       (cons
 305                        (- (string-to-char
 306                            (decode-coding-string "\341" 'iso-8859-15)) c)
 307                        (string-to-list (decode-coding-string (car (cdr cs))
 308                                                              (car cs))))))
 309             '(gnus-charset 0)))
 310         mm-iso-8859-15-compatible))
 311   "A table of the difference character between ISO-8859-X and ISO-8859-15.")
 312
 313 (defcustom mm-coding-system-priorities
 314   (if (boundp 'current-language-environment)
 315       (let ((lang (symbol-value 'current-language-environment)))
 316         (cond ((string= lang "Japanese")
 317                ;; Japanese users may prefer iso-2022-jp to shift_jis.
 318                '(iso-2022-jp iso-2022-jp-2 shift_jis iso-8859-1 utf-8)))))
 319   "Preferred coding systems for encoding outgoing messages.
 320
 321 More than one suitable coding system may be found for some text.
 322 By default, the coding system with the highest priority is used
 323 to encode outgoing messages (see `sort-coding-systems').  If this
 324 variable is set, it overrides the default priority."
 325   :type '(repeat (symbol :tag "Coding system"))
 326   :group 'mime)
 327
 328 ;; ??
 329 (defvar mm-use-find-coding-systems-region
 330   (fboundp 'find-coding-systems-region)
 331   "Use `find-coding-systems-region' to find proper coding systems.
 332
 333 Setting it to nil is useful on Emacsen supporting Unicode if sending
 334 mail with multiple parts is preferred to sending a Unicode one.")
 335
 336 ;;; Internal variables:
 337
 338 ;;; Functions:
 339
 340 (defun mm-mule-charset-to-mime-charset (charset)
 341   "Return the MIME charset corresponding to the given Mule CHARSET."
 342   (if (and (fboundp 'find-coding-systems-for-charsets)
 343            (fboundp 'sort-coding-systems))
 344       (let ((css (sort (sort-coding-systems
 345                         (find-coding-systems-for-charsets (list charset)))
 346                        'mm-sort-coding-systems-predicate))
 347             cs mime)
 348         (while (and (not mime)
 349                     css)
 350           (when (setq cs (pop css))
 351             (setq mime (or (coding-system-get cs :mime-charset)
 352                            (coding-system-get cs 'mime-charset)))))
 353         mime)
 354     (let ((alist (mapcar (lambda (cs)
 355                            (assq cs mm-mime-mule-charset-alist))
 356                          (sort (mapcar 'car mm-mime-mule-charset-alist)
 357                                'mm-sort-coding-systems-predicate)))
 358           out)
 359       (while alist
 360         (when (memq charset (cdar alist))
 361           (setq out (caar alist)
 362                 alist nil))
 363         (pop alist))
 364       out)))
 365
 366 (defun mm-charset-to-coding-system (charset &optional lbt)
 367   "Return coding-system corresponding to CHARSET.
 368 CHARSET is a symbol naming a MIME charset.
 369 If optional argument LBT (`unix', `dos' or `mac') is specified, it is
 370 used as the line break code type of the coding system."
 371   (when (stringp charset)
 372     (setq charset (intern (downcase charset))))
 373   (when lbt
 374     (setq charset (intern (format "%s-%s" charset lbt))))
 375   (cond
 376    ((null charset)
 377     charset)
 378    ;; Running in a non-MULE environment.
 379    ((or (null (mm-get-coding-system-list))
 380         (not (fboundp 'coding-system-get)))
 381     charset)
 382    ;; ascii
 383    ((eq charset 'us-ascii)
 384     'ascii)
 385    ;; Check to see whether we can handle this charset.  (This depends
 386    ;; on there being some coding system matching each `mime-charset'
 387    ;; property defined, as there should be.)
 388    ((and (mm-coding-system-p charset)
 389 ;;; Doing this would potentially weed out incorrect charsets.
 390 ;;;      charset
 391 ;;;      (eq charset (coding-system-get charset 'mime-charset))
 392          )
 393     charset)
 394    ;; Translate invalid charsets.
 395    ((let ((cs (cdr (assq charset mm-charset-synonym-alist))))
 396       (and cs (mm-coding-system-p cs) cs)))
 397    ;; Last resort: search the coding system list for entries which
 398    ;; have the right mime-charset in case the canonical name isn't
 399    ;; defined (though it should be).
 400    ((let (cs)
 401       ;; mm-get-coding-system-list returns a list of cs without lbt.
 402       ;; Do we need -lbt?
 403       (dolist (c (mm-get-coding-system-list))
 404         (if (and (null cs)
 405                  (eq charset (or (coding-system-get c :mime-charset)
 406                                  (coding-system-get c 'mime-charset))))
 407             (setq cs c)))
 408       cs))))
 409
 410 (eval-and-compile
 411   (defvar mm-emacs-mule (and (not (featurep 'xemacs))
 412                              (boundp 'default-enable-multibyte-characters)
 413                              default-enable-multibyte-characters
 414                              (fboundp 'set-buffer-multibyte))
 415     "True in Emacs with Mule.")
 416
 417   (if mm-emacs-mule
 418       (defun mm-enable-multibyte ()
 419         "Set the multibyte flag of the current buffer.
 420 Only do this if the default value of `enable-multibyte-characters' is
 421 non-nil.  This is a no-op in XEmacs."
 422         (set-buffer-multibyte 'to))
 423     (defalias 'mm-enable-multibyte 'ignore))
 424
 425   (if mm-emacs-mule
 426       (defun mm-disable-multibyte ()
 427         "Unset the multibyte flag of in the current buffer.
 428 This is a no-op in XEmacs."
 429         (set-buffer-multibyte nil))
 430     (defalias 'mm-disable-multibyte 'ignore)))
 431
 432 (defun mm-preferred-coding-system (charset)
 433   ;; A typo in some Emacs versions.
 434   (or (get-charset-property charset 'preferred-coding-system)
 435       (get-charset-property charset 'prefered-coding-system)))
 436
 437 ;; Mule charsets shouldn't be used.
 438 (defsubst mm-guess-charset ()
 439   "Guess Mule charset from the language environment."
 440   (or
 441    mail-parse-mule-charset ;; cached mule-charset
 442    (progn
 443      (setq mail-parse-mule-charset
 444            (and (boundp 'current-language-environment)
 445                 (car (last
 446                       (assq 'charset
 447                             (assoc current-language-environment
 448                                    language-info-alist))))))
 449      (if (or (not mail-parse-mule-charset)
 450              (eq mail-parse-mule-charset 'ascii))
 451          (setq mail-parse-mule-charset
 452                (or (car (last (assq mail-parse-charset
 453                                     mm-mime-mule-charset-alist)))
 454                    ;; default
 455                    'latin-iso8859-1)))
 456      mail-parse-mule-charset)))
 457
 458 (defun mm-charset-after (&optional pos)
 459   "Return charset of a character in current buffer at position POS.
 460 If POS is nil, it defauls to the current point.
 461 If POS is out of range, the value is nil.
 462 If the charset is `composition', return the actual one."
 463   (let ((char (char-after pos)) charset)
 464     (if (< (mm-char-int char) 128)
 465         (setq charset 'ascii)
 466       ;; charset-after is fake in some Emacsen.
 467       (setq charset (and (fboundp 'char-charset) (char-charset char)))
 468       (if (eq charset 'composition)     ; Mule 4
 469           (let ((p (or pos (point))))
 470             (cadr (find-charset-region p (1+ p))))
 471         (if (and charset (not (memq charset '(ascii eight-bit-control
 472                                                     eight-bit-graphic))))
 473             charset
 474           (mm-guess-charset))))))
 475
 476 (defun mm-mime-charset (charset)
 477   "Return the MIME charset corresponding to the given Mule CHARSET."
 478   (if (eq charset 'unknown)
 479       (error "The message contains non-printable characters, please use attachment"))
 480   (if (and (fboundp 'coding-system-get) (fboundp 'get-charset-property))
 481       ;; This exists in Emacs 20.
 482       (or
 483        (and (mm-preferred-coding-system charset)
 484             (or (coding-system-get
 485                  (mm-preferred-coding-system charset) :mime-charset)
 486                 (coding-system-get
 487                  (mm-preferred-coding-system charset) 'mime-charset)))
 488        (and (eq charset 'ascii)
 489             'us-ascii)
 490        (mm-preferred-coding-system charset)
 491        (mm-mule-charset-to-mime-charset charset))
 492     ;; This is for XEmacs.
 493     (mm-mule-charset-to-mime-charset charset)))
 494
 495 (defun mm-delete-duplicates (list)
 496   "Simple substitute for CL `delete-duplicates', testing with `equal'."
 497   (let (result head)
 498     (while list
 499       (setq head (car list))
 500       (setq list (delete head list))
 501       (setq result (cons head result)))
 502     (nreverse result)))
 503
 504 ;; Fixme:  This is used in places when it should be testing the
 505 ;; default multibyteness.  See mm-default-multibyte-p.
 506 (eval-and-compile
 507   (if (and (not (featurep 'xemacs))
 508            (boundp 'enable-multibyte-characters))
 509       (defun mm-multibyte-p ()
 510         "Non-nil if multibyte is enabled in the current buffer."
 511         enable-multibyte-characters)
 512     (defun mm-multibyte-p () (featurep 'mule))))
 513
 514 (defun mm-default-multibyte-p ()
 515   "Return non-nil if the session is multibyte.
 516 This affects whether coding conversion should be attempted generally."
 517   (if (featurep 'mule)
 518       (if (boundp 'default-enable-multibyte-characters)
 519           default-enable-multibyte-characters
 520         t)))
 521
 522 (defun mm-iso-8859-x-to-15-region (&optional b e)
 523   (if (fboundp 'char-charset)
 524       (let (charset item c inconvertible)
 525         (save-restriction
 526           (if e (narrow-to-region b e))
 527           (goto-char (point-min))
 528           (skip-chars-forward "\0-\177")
 529           (while (not (eobp))
 530             (cond
 531              ((not (setq item (assq (char-charset (setq c (char-after)))
 532                                     mm-iso-8859-x-to-15-table)))
 533               (forward-char))
 534              ((memq c (cdr (cdr item)))
 535               (setq inconvertible t)
 536               (forward-char))
 537              (t
 538               (insert-before-markers (prog1 (+ c (car (cdr item)))
 539                                        (delete-char 1)))))
 540             (skip-chars-forward "\0-\177")))
 541         (not inconvertible))))
 542
 543 (defun mm-sort-coding-systems-predicate (a b)
 544   (let ((priorities (mapcar 'mm-coding-system-p
 545                             ;; Note: invalid entries are dropped silently
 546                             mm-coding-system-priorities)))
 547     (and (setq a (mm-coding-system-p a))
 548          (if (setq b (mm-coding-system-p b))
 549              (> (length (memq (coding-system-base a) priorities))
 550                 (length (memq (coding-system-base b) priorities)))
 551            t))))
 552
 553 (defun mm-find-mime-charset-region (b e &optional hack-charsets)
 554   "Return the MIME charsets needed to encode the region between B and E.
 555 nil means ASCII, a single-element list represents an appropriate MIME
 556 charset, and a longer list means no appropriate charset."
 557   (let (charsets)
 558     ;; The return possibilities of this function are a mess...
 559     (or (and (mm-multibyte-p)
 560              mm-use-find-coding-systems-region
 561              ;; Find the mime-charset of the most preferred coding
 562              ;; system that has one.
 563              (let ((systems (find-coding-systems-region b e)))
 564                (when mm-coding-system-priorities
 565                  (setq systems
 566                        (sort systems 'mm-sort-coding-systems-predicate)))
 567                (setq systems (delq 'compound-text systems))
 568                (unless (equal systems '(undecided))
 569                  (while systems
 570                    (let* ((head (pop systems))
 571                           (cs (or (coding-system-get head :mime-charset)
 572                                   (coding-system-get head 'mime-charset))))
 573                      ;; The mime-charset (`x-ctext') of
 574                      ;; `compound-text' is not in the IANA list.  We
 575                      ;; shouldn't normally use anything here with a
 576                      ;; mime-charset having an `x-' prefix.
 577                      ;; Fixme:  Allow this to be overridden, since
 578                      ;; there is existing use of x-ctext.
 579                      ;; Also people apparently need the coding system
 580                      ;; `iso-2022-jp-3' (which Mule-UCS defines with
 581                      ;; mime-charset, though it's not valid).
 582                      (if (and cs
 583                               (not (string-match "^[Xx]-" (symbol-name cs)))
 584                               ;; UTF-16 of any variety is invalid for
 585                               ;; text parts and, unfortunately, has
 586                               ;; mime-charset defined both in Mule-UCS
 587                               ;; and versions of Emacs.  (The name
 588                               ;; might be `mule-utf-16...'  or
 589                               ;; `utf-16...'.)
 590                               (not (string-match "utf-16" (symbol-name cs))))
 591                          (setq systems nil
 592                                charsets (list cs))))))
 593                charsets))
 594         ;; Otherwise we're not multibyte, we're XEmacs, or a single
 595         ;; coding system won't cover it.
 596         (setq charsets
 597               (mm-delete-duplicates
 598                (mapcar 'mm-mime-charset
 599                        (delq 'ascii
 600                              (mm-find-charset-region b e))))))
 601     (if (and (> (length charsets) 1)
 602              (memq 'iso-8859-15 charsets)
 603              (memq 'iso-8859-15 hack-charsets)
 604              (save-excursion (mm-iso-8859-x-to-15-region b e)))
 605         (mapcar (lambda (x) (setq charsets (delq (car x) charsets)))
 606                 mm-iso-8859-15-compatible))
 607     (if (and (memq 'iso-2022-jp-2 charsets)
 608              (memq 'iso-2022-jp-2 hack-charsets))
 609         (setq charsets (delq 'iso-2022-jp charsets)))
 610     charsets))
 611
 612 (defmacro mm-with-unibyte-buffer (&rest forms)
 613   "Create a temporary buffer, and evaluate FORMS there like `progn'.
 614 Use unibyte mode for this."
 615   `(let (default-enable-multibyte-characters)
 616      (with-temp-buffer ,@forms)))
 617 (put 'mm-with-unibyte-buffer 'lisp-indent-function 0)
 618 (put 'mm-with-unibyte-buffer 'edebug-form-spec '(body))
 619
 620 (defmacro mm-with-multibyte-buffer (&rest forms)
 621   "Create a temporary buffer, and evaluate FORMS there like `progn'.
 622 Use multibyte mode for this."
 623   `(let ((default-enable-multibyte-characters t))
 624      (with-temp-buffer ,@forms)))
 625 (put 'mm-with-multibyte-buffer 'lisp-indent-function 0)
 626 (put 'mm-with-multibyte-buffer 'edebug-form-spec '(body))
 627
 628 (defmacro mm-with-unibyte-current-buffer (&rest forms)
 629   "Evaluate FORMS with current buffer temporarily made unibyte.
 630 Also bind `default-enable-multibyte-characters' to nil.
 631 Equivalent to `progn' in XEmacs"
 632   (let ((multibyte (make-symbol "multibyte"))
 633         (buffer (make-symbol "buffer")))
 634     `(if mm-emacs-mule
 635          (let ((,multibyte enable-multibyte-characters)
 636                (,buffer (current-buffer)))
 637            (unwind-protect
 638                (let (default-enable-multibyte-characters)
 639                  (set-buffer-multibyte nil)
 640                  ,@forms)
 641              (set-buffer ,buffer)
 642              (set-buffer-multibyte ,multibyte)))
 643        (let (default-enable-multibyte-characters)
 644          ,@forms))))
 645 (put 'mm-with-unibyte-current-buffer 'lisp-indent-function 0)
 646 (put 'mm-with-unibyte-current-buffer 'edebug-form-spec '(body))
 647
 648 (defmacro mm-with-unibyte (&rest forms)
 649   "Eval the FORMS with the default value of `enable-multibyte-characters' nil."
 650   `(let (default-enable-multibyte-characters)
 651      ,@forms))
 652 (put 'mm-with-unibyte 'lisp-indent-function 0)
 653 (put 'mm-with-unibyte 'edebug-form-spec '(body))
 654
 655 (defmacro mm-with-multibyte (&rest forms)
 656   "Eval the FORMS with the default value of `enable-multibyte-characters' t."
 657   `(let ((default-enable-multibyte-characters t))
 658      ,@forms))
 659 (put 'mm-with-multibyte 'lisp-indent-function 0)
 660 (put 'mm-with-multibyte 'edebug-form-spec '(body))
 661
 662 (defun mm-find-charset-region (b e)
 663   "Return a list of Emacs charsets in the region B to E."
 664   (cond
 665    ((and (mm-multibyte-p)
 666          (fboundp 'find-charset-region))
 667     ;; Remove composition since the base charsets have been included.
 668     ;; Remove eight-bit-*, treat them as ascii.
 669     (let ((css (find-charset-region b e)))
 670       (mapcar (lambda (cs) (setq css (delq cs css)))
 671               '(composition eight-bit-control eight-bit-graphic
 672                             control-1))
 673       css))
 674    (t
 675     ;; We are in a unibyte buffer or XEmacs non-mule, so we futz around a bit.
 676     (save-excursion
 677       (save-restriction
 678         (narrow-to-region b e)
 679         (goto-char (point-min))
 680         (skip-chars-forward "\0-\177")
 681         (if (eobp)
 682             '(ascii)
 683           (let (charset)
 684             (setq charset
 685                   (and (boundp 'current-language-environment)
 686                        (car (last (assq 'charset
 687                                         (assoc current-language-environment
 688                                                language-info-alist))))))
 689             (if (eq charset 'ascii) (setq charset nil))
 690             (or charset
 691                 (setq charset
 692                       (car (last (assq mail-parse-charset
 693                                        mm-mime-mule-charset-alist)))))
 694             (list 'ascii (or charset 'latin-iso8859-1)))))))))
 695
 696 (defun mm-auto-mode-alist ()
 697   "Return an `auto-mode-alist' with only the .gz (etc) thingies."
 698   (let ((alist auto-mode-alist)
 699         out)
 700     (while alist
 701       (when (listp (cdar alist))
 702         (push (car alist) out))
 703       (pop alist))
 704     (nreverse out)))
 705
 706 (defvar mm-inhibit-file-name-handlers
 707   '(jka-compr-handler image-file-handler)
 708   "A list of handlers doing (un)compression (etc) thingies.")
 709
 710 (defun mm-insert-file-contents (filename &optional visit beg end replace
 711                                          inhibit)
 712   "Like `insert-file-contents', but only reads in the file.
 713 A buffer may be modified in several ways after reading into the buffer due
 714 to advanced Emacs features, such as file-name-handlers, format decoding,
 715 `find-file-hooks', etc.
 716 If INHIBIT is non-nil, inhibit `mm-inhibit-file-name-handlers'.
 717   This function ensures that none of these modifications will take place."
 718   (let ((format-alist nil)
 719         (auto-mode-alist (if inhibit nil (mm-auto-mode-alist)))
 720         (default-major-mode 'fundamental-mode)
 721         (enable-local-variables nil)
 722         (after-insert-file-functions nil)
 723         (enable-local-eval nil)
 724         (find-file-hooks nil)
 725         (inhibit-file-name-operation (if inhibit
 726                                          'insert-file-contents
 727                                        inhibit-file-name-operation))
 728         (inhibit-file-name-handlers
 729          (if inhibit
 730              (append mm-inhibit-file-name-handlers
 731                      inhibit-file-name-handlers)
 732            inhibit-file-name-handlers)))
 733     (insert-file-contents filename visit beg end replace)))
 734
 735 (defun mm-append-to-file (start end filename &optional codesys inhibit)
 736   "Append the contents of the region to the end of file FILENAME.
 737 When called from a function, expects three arguments,
 738 START, END and FILENAME.  START and END are buffer positions
 739 saying what text to write.
 740 Optional fourth argument specifies the coding system to use when
 741 encoding the file.
 742 If INHIBIT is non-nil, inhibit `mm-inhibit-file-name-handlers'."
 743   (let ((coding-system-for-write
 744          (or codesys mm-text-coding-system-for-write
 745              mm-text-coding-system))
 746         (inhibit-file-name-operation (if inhibit
 747                                          'append-to-file
 748                                        inhibit-file-name-operation))
 749         (inhibit-file-name-handlers
 750          (if inhibit
 751              (append mm-inhibit-file-name-handlers
 752                      inhibit-file-name-handlers)
 753            inhibit-file-name-handlers)))
 754     (write-region start end filename t 'no-message)
 755     (message "Appended to %s" filename)))
 756
 757 (defun mm-write-region (start end filename &optional append visit lockname
 758                               coding-system inhibit)
 759
 760   "Like `write-region'.
 761 If INHIBIT is non-nil, inhibit `mm-inhibit-file-name-handlers'."
 762   (let ((coding-system-for-write
 763          (or coding-system mm-text-coding-system-for-write
 764              mm-text-coding-system))
 765         (inhibit-file-name-operation (if inhibit
 766                                          'write-region
 767                                        inhibit-file-name-operation))
 768         (inhibit-file-name-handlers
 769          (if inhibit
 770              (append mm-inhibit-file-name-handlers
 771                      inhibit-file-name-handlers)
 772            inhibit-file-name-handlers)))
 773     (write-region start end filename append visit lockname)))
 774
 775 (defun mm-image-load-path (&optional package)
 776   (let (dir result)
 777     (dolist (path load-path (nreverse result))
 778       (when (and path
 779                  (file-directory-p
 780                   (setq dir (concat (file-name-directory
 781                                      (directory-file-name path))
 782                                     "etc/" (or package "gnus/")))))
 783         (push dir result))
 784       (push path result))))
 785
 786 ;; Fixme: This doesn't look useful where it's used.
 787 (if (fboundp 'detect-coding-region)
 788     (defun mm-detect-coding-region (start end)
 789       "Like `detect-coding-region' except returning the best one."
 790       (let ((coding-systems
 791              (detect-coding-region (point) (point-max))))
 792         (or (car-safe coding-systems)
 793             coding-systems)))
 794   (defun mm-detect-coding-region (start end)
 795     (let ((point (point)))
 796       (goto-char start)
 797       (skip-chars-forward "\0-\177" end)
 798       (prog1
 799           (if (eq (point) end) 'ascii (mm-guess-charset))
 800         (goto-char point)))))
 801
 802 (if (fboundp 'coding-system-get)
 803     (defun mm-detect-mime-charset-region (start end)
 804       "Detect MIME charset of the text in the region between START and END."
 805       (let ((cs (mm-detect-coding-region start end)))
 806         (coding-system-get cs 'mime-charset)))
 807   (defun mm-detect-mime-charset-region (start end)
 808     "Detect MIME charset of the text in the region between START and END."
 809     (let ((cs (mm-detect-coding-region start end)))
 810       cs)))
 811
 812
 813 (provide 'mm-util)
 814
 815 ;;; arch-tag: 94dc5388-825d-4fd1-bfa5-2100aa351238
 816 ;;; mm-util.el ends here