cgit.sxemacs.org Git - gnus/blob - lisp/mm-util.el

   1 ;;; mm-util.el --- Utility functions for Mule and low level things
   2 ;; Copyright (C) 1998, 1999, 2000, 2001, 2002, 2003, 2004
   3 ;;   Free Software Foundation, Inc.
   4
   5 ;; Author: Lars Magne Ingebrigtsen <larsi@gnus.org>
   6 ;;      MORIOKA Tomohiko <morioka@jaist.ac.jp>
   7 ;; This file is part of GNU Emacs.
   8
   9 ;; GNU Emacs is free software; you can redistribute it and/or modify
  10 ;; it under the terms of the GNU General Public License as published by
  11 ;; the Free Software Foundation; either version 2, or (at your option)
  12 ;; any later version.
  13
  14 ;; GNU Emacs is distributed in the hope that it will be useful,
  15 ;; but WITHOUT ANY WARRANTY; without even the implied warranty of
  16 ;; MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.  See the
  17 ;; GNU General Public License for more details.
  18
  19 ;; You should have received a copy of the GNU General Public License
  20 ;; along with GNU Emacs; see the file COPYING.  If not, write to the
  21 ;; Free Software Foundation, Inc., 59 Temple Place - Suite 330,
  22 ;; Boston, MA 02111-1307, USA.
  23
  24 ;;; Commentary:
  25
  26 ;;; Code:
  27
  28 (eval-when-compile (require 'cl))
  29 (require 'mail-prsvr)
  30
  31 (eval-and-compile
  32   (mapcar
  33    (lambda (elem)
  34      (let ((nfunc (intern (format "mm-%s" (car elem)))))
  35        (if (fboundp (car elem))
  36            (defalias nfunc (car elem))
  37          (defalias nfunc (cdr elem)))))
  38    '((decode-coding-string . (lambda (s a) s))
  39      (encode-coding-string . (lambda (s a) s))
  40      (encode-coding-region . ignore)
  41      (coding-system-list . ignore)
  42      (decode-coding-region . ignore)
  43      (char-int . identity)
  44      (coding-system-equal . equal)
  45      (annotationp . ignore)
  46      (set-buffer-file-coding-system . ignore)
  47      (read-charset
  48       . (lambda (prompt)
  49           "Return a charset."
  50           (intern
  51            (completing-read
  52             prompt
  53             (mapcar (lambda (e) (list (symbol-name (car e))))
  54                     mm-mime-mule-charset-alist)
  55             nil t))))
  56      (subst-char-in-string
  57       . (lambda (from to string &optional inplace) ;; stolen (and renamed) from nnheader.el
  58           "Replace characters in STRING from FROM to TO.
  59           Unless optional argument INPLACE is non-nil, return a new string."
  60           (let ((string (if inplace string (copy-sequence string)))
  61                 (len (length string))
  62                 (idx 0))
  63             ;; Replace all occurrences of FROM with TO.
  64             (while (< idx len)
  65               (when (= (aref string idx) from)
  66                 (aset string idx to))
  67               (setq idx (1+ idx)))
  68             string)))
  69      (replace-in-string
  70       . (lambda (string regexp rep &optional literal)
  71           "See `replace-regexp-in-string', only the order of args differs."
  72           (replace-regexp-in-string regexp rep string nil literal)))
  73      (string-as-unibyte . identity)
  74      (string-make-unibyte . identity)
  75      (string-as-multibyte . identity)
  76      (multibyte-string-p . ignore)
  77      ;; It is not a MIME function, but some MIME functions use it.
  78      (make-temp-file . (lambda (prefix &optional dir-flag)
  79                          (let ((file (expand-file-name
  80                                       (make-temp-name prefix)
  81                                       (if (fboundp 'temp-directory)
  82                                           (temp-directory)
  83                                         temporary-file-directory))))
  84                            (if dir-flag
  85                                (make-directory file))
  86                            file)))
  87      (insert-byte . insert-char)
  88      (multibyte-char-to-unibyte . identity))))
  89
  90 (eval-and-compile
  91   (defalias 'mm-char-or-char-int-p
  92     (cond
  93      ((fboundp 'char-or-char-int-p) 'char-or-char-int-p)
  94      ((fboundp 'char-valid-p) 'char-valid-p)
  95      (t 'identity))))
  96
  97 ;; Fixme:  This seems always to be used to read a MIME charset, so it
  98 ;; should be re-named and fixed (in Emacs) to offer completion only on
  99 ;; proper charset names (base coding systems which have a
 100 ;; mime-charset defined).  XEmacs doesn't believe in mime-charset;
 101 ;; test with
 102 ;;   `(or (coding-system-get 'iso-8859-1 'mime-charset)
 103 ;;        (coding-system-get 'iso-8859-1 :mime-charset))'
 104 ;; Actually, there should be an `mm-coding-system-mime-charset'.
 105 (eval-and-compile
 106   (defalias 'mm-read-coding-system
 107     (cond
 108      ((fboundp 'read-coding-system)
 109       (if (and (featurep 'xemacs)
 110                (<= (string-to-number emacs-version) 21.1))
 111           (lambda (prompt &optional default-coding-system)
 112             (read-coding-system prompt))
 113         'read-coding-system))
 114      (t (lambda (prompt &optional default-coding-system)
 115           "Prompt the user for a coding system."
 116           (completing-read
 117            prompt (mapcar (lambda (s) (list (symbol-name (car s))))
 118                           mm-mime-mule-charset-alist)))))))
 119
 120 (defvar mm-coding-system-list nil)
 121 (defun mm-get-coding-system-list ()
 122   "Get the coding system list."
 123   (or mm-coding-system-list
 124       (setq mm-coding-system-list (mm-coding-system-list))))
 125
 126 (defun mm-coding-system-p (cs)
 127   "Return non-nil if CS is a symbol naming a coding system.
 128 In XEmacs, also return non-nil if CS is a coding system object.
 129 If CS is available, return CS itself in Emacs, and return a coding
 130 system object in XEmacs."
 131   (if (fboundp 'find-coding-system)
 132       (find-coding-system cs)
 133     (if (fboundp 'coding-system-p)
 134         (when (coding-system-p cs)
 135           cs)
 136       ;; Is this branch ever actually useful?
 137       (car (memq cs (mm-get-coding-system-list))))))
 138
 139 (defvar mm-charset-synonym-alist
 140   `(
 141     ;; Not in XEmacs, but it's not a proper MIME charset anyhow.
 142     ,@(unless (mm-coding-system-p 'x-ctext)
 143        '((x-ctext . ctext)))
 144     ;; ISO-8859-15 is very similar to ISO-8859-1.  But it's _different_!
 145     ,@(unless (mm-coding-system-p 'iso-8859-15)
 146        '((iso-8859-15 . iso-8859-1)))
 147     ;; BIG-5HKSCS is similar to, but different than, BIG-5.
 148     ,@(unless (mm-coding-system-p 'big5-hkscs)
 149         '((big5-hkscs . big5)))
 150     ;; Windows-1252 is actually a superset of Latin-1.  See also
 151     ;; `gnus-article-dumbquotes-map'.
 152     ,@(unless (mm-coding-system-p 'windows-1252)
 153        (if (mm-coding-system-p 'cp1252)
 154            '((windows-1252 . cp1252))
 155          '((windows-1252 . iso-8859-1))))
 156     ;; Windows-1250 is a variant of Latin-2 heavily used by Microsoft
 157     ;; Outlook users in Czech republic. Use this to allow reading of their
 158     ;; e-mails. cp1250 should be defined by M-x codepage-setup.
 159     ,@(if (and (not (mm-coding-system-p 'windows-1250))
 160                (mm-coding-system-p 'cp1250))
 161           '((windows-1250 . cp1250)))
 162     ;; A Microsoft misunderstanding.
 163     ,@(unless (mm-coding-system-p 'ks_c_5601-1987)
 164         (if (mm-coding-system-p 'cp949)
 165             '((ks_c_5601-1987 . cp949))
 166           '((ks_c_5601-1987 . euc-kr))))
 167     )
 168   "A mapping from invalid charset names to the real charset names.")
 169
 170 (defvar mm-binary-coding-system
 171   (cond
 172    ((mm-coding-system-p 'binary) 'binary)
 173    ((mm-coding-system-p 'no-conversion) 'no-conversion)
 174    (t nil))
 175   "100% binary coding system.")
 176
 177 (defvar mm-text-coding-system
 178   (or (if (memq system-type '(windows-nt ms-dos ms-windows))
 179           (and (mm-coding-system-p 'raw-text-dos) 'raw-text-dos)
 180         (and (mm-coding-system-p 'raw-text) 'raw-text))
 181       mm-binary-coding-system)
 182   "Text-safe coding system (For removing ^M).")
 183
 184 (defvar mm-text-coding-system-for-write nil
 185   "Text coding system for write.")
 186
 187 (defvar mm-auto-save-coding-system
 188   (cond
 189    ((mm-coding-system-p 'utf-8-emacs)   ; Mule 7
 190     (if (memq system-type '(windows-nt ms-dos ms-windows))
 191         (if (mm-coding-system-p 'utf-8-emacs-dos)
 192             'utf-8-emacs-dos mm-binary-coding-system)
 193       'utf-8-emacs))
 194    ((mm-coding-system-p 'emacs-mule)
 195     (if (memq system-type '(windows-nt ms-dos ms-windows))
 196         (if (mm-coding-system-p 'emacs-mule-dos)
 197             'emacs-mule-dos mm-binary-coding-system)
 198       'emacs-mule))
 199    ((mm-coding-system-p 'escape-quoted) 'escape-quoted)
 200    (t mm-binary-coding-system))
 201   "Coding system of auto save file.")
 202
 203 (defvar mm-universal-coding-system mm-auto-save-coding-system
 204   "The universal coding system.")
 205
 206 ;; Fixme: some of the cars here aren't valid MIME charsets.  That
 207 ;; should only matter with XEmacs, though.
 208 (defvar mm-mime-mule-charset-alist
 209   `((us-ascii ascii)
 210     (iso-8859-1 latin-iso8859-1)
 211     (iso-8859-2 latin-iso8859-2)
 212     (iso-8859-3 latin-iso8859-3)
 213     (iso-8859-4 latin-iso8859-4)
 214     (iso-8859-5 cyrillic-iso8859-5)
 215     ;; Non-mule (X)Emacs uses the last mule-charset for 8bit characters.
 216     ;; The fake mule-charset, gnus-koi8-r, tells Gnus that the default
 217     ;; charset is koi8-r, not iso-8859-5.
 218     (koi8-r cyrillic-iso8859-5 gnus-koi8-r)
 219     (iso-8859-6 arabic-iso8859-6)
 220     (iso-8859-7 greek-iso8859-7)
 221     (iso-8859-8 hebrew-iso8859-8)
 222     (iso-8859-9 latin-iso8859-9)
 223     (iso-8859-14 latin-iso8859-14)
 224     (iso-8859-15 latin-iso8859-15)
 225     (viscii vietnamese-viscii-lower)
 226     (iso-2022-jp latin-jisx0201 japanese-jisx0208 japanese-jisx0208-1978)
 227     (euc-kr korean-ksc5601)
 228     (gb2312 chinese-gb2312)
 229     (big5 chinese-big5-1 chinese-big5-2)
 230     (tibetan tibetan)
 231     (thai-tis620 thai-tis620)
 232     (windows-1251 cyrillic-iso8859-5)
 233     (iso-2022-7bit ethiopic arabic-1-column arabic-2-column)
 234     (iso-2022-jp-2 latin-iso8859-1 greek-iso8859-7
 235                    latin-jisx0201 japanese-jisx0208-1978
 236                    chinese-gb2312 japanese-jisx0208
 237                    korean-ksc5601 japanese-jisx0212)
 238     (iso-2022-int-1 latin-iso8859-1 greek-iso8859-7
 239                     latin-jisx0201 japanese-jisx0208-1978
 240                     chinese-gb2312 japanese-jisx0208
 241                     korean-ksc5601 japanese-jisx0212
 242                     chinese-cns11643-1 chinese-cns11643-2)
 243     (iso-2022-int-1 latin-iso8859-1 latin-iso8859-2
 244                     cyrillic-iso8859-5 greek-iso8859-7
 245                     latin-jisx0201 japanese-jisx0208-1978
 246                     chinese-gb2312 japanese-jisx0208
 247                     korean-ksc5601 japanese-jisx0212
 248                     chinese-cns11643-1 chinese-cns11643-2
 249                     chinese-cns11643-3 chinese-cns11643-4
 250                     chinese-cns11643-5 chinese-cns11643-6
 251                     chinese-cns11643-7)
 252     (iso-2022-jp-3 latin-jisx0201 japanese-jisx0208-1978 japanese-jisx0208
 253                    japanese-jisx0213-1 japanese-jisx0213-2)
 254     (shift_jis latin-jisx0201 katakana-jisx0201 japanese-jisx0208)
 255     ,(if (or (not (fboundp 'charsetp)) ;; non-Mule case
 256              (charsetp 'unicode-a)
 257              (not (mm-coding-system-p 'mule-utf-8)))
 258          '(utf-8 unicode-a unicode-b unicode-c unicode-d unicode-e)
 259        ;; If we have utf-8 we're in Mule 5+.
 260        (append '(utf-8)
 261                (delete 'ascii
 262                        (coding-system-get 'mule-utf-8 'safe-charsets)))))
 263   "Alist of MIME-charset/MULE-charsets.")
 264
 265 ;; Correct by construction, but should be unnecessary:
 266 ;; XEmacs hates it.
 267 (when (and (not (featurep 'xemacs))
 268            (fboundp 'coding-system-list)
 269            (fboundp 'sort-coding-systems))
 270   (setq mm-mime-mule-charset-alist
 271         (apply
 272          'nconc
 273          (mapcar
 274           (lambda (cs)
 275             (when (and (or (coding-system-get cs :mime-charset) ; Emacs 22
 276                            (coding-system-get cs 'mime-charset))
 277                        (not (eq t (coding-system-get cs 'safe-charsets))))
 278               (list (cons (or (coding-system-get cs :mime-charset)
 279                               (coding-system-get cs 'mime-charset))
 280                           (delq 'ascii
 281                                 (coding-system-get cs 'safe-charsets))))))
 282           (sort-coding-systems (coding-system-list 'base-only))))))
 283
 284 (defvar mm-hack-charsets '(iso-8859-15 iso-2022-jp-2)
 285   "A list of special charsets.
 286 Valid elements include:
 287 `iso-8859-15'    convert ISO-8859-1, -9 to ISO-8859-15 if ISO-8859-15 exists.
 288 `iso-2022-jp-2'  convert ISO-2022-jp to ISO-2022-jp-2 if ISO-2022-jp-2 exists."
 289 )
 290
 291 (defvar mm-iso-8859-15-compatible
 292   '((iso-8859-1 "\xA4\xA6\xA8\xB4\xB8\xBC\xBD\xBE")
 293     (iso-8859-9 "\xA4\xA6\xA8\xB4\xB8\xBC\xBD\xBE\xD0\xDD\xDE\xF0\xFD\xFE"))
 294   "ISO-8859-15 exchangeable coding systems and inconvertible characters.")
 295
 296 (defvar mm-iso-8859-x-to-15-table
 297   (and (fboundp 'coding-system-p)
 298        (mm-coding-system-p 'iso-8859-15)
 299        (mapcar
 300         (lambda (cs)
 301           (if (mm-coding-system-p (car cs))
 302               (let ((c (string-to-char
 303                         (decode-coding-string "\341" (car cs)))))
 304                 (cons (char-charset c)
 305                       (cons
 306                        (- (string-to-char
 307                            (decode-coding-string "\341" 'iso-8859-15)) c)
 308                        (string-to-list (decode-coding-string (car (cdr cs))
 309                                                              (car cs))))))
 310             '(gnus-charset 0)))
 311         mm-iso-8859-15-compatible))
 312   "A table of the difference character between ISO-8859-X and ISO-8859-15.")
 313
 314 (defcustom mm-coding-system-priorities
 315   (if (boundp 'current-language-environment)
 316       (let ((lang (symbol-value 'current-language-environment)))
 317         (cond ((string= lang "Japanese")
 318                ;; Japanese users may prefer iso-2022-jp to shift_jis.
 319                '(iso-2022-jp iso-2022-jp-2 shift_jis iso-8859-1 utf-8)))))
 320   "Preferred coding systems for encoding outgoing messages.
 321
 322 More than one suitable coding system may be found for some text.
 323 By default, the coding system with the highest priority is used
 324 to encode outgoing messages (see `sort-coding-systems').  If this
 325 variable is set, it overrides the default priority."
 326   :type '(repeat (symbol :tag "Coding system"))
 327   :group 'mime)
 328
 329 ;; ??
 330 (defvar mm-use-find-coding-systems-region
 331   (fboundp 'find-coding-systems-region)
 332   "Use `find-coding-systems-region' to find proper coding systems.
 333
 334 Setting it to nil is useful on Emacsen supporting Unicode if sending
 335 mail with multiple parts is preferred to sending a Unicode one.")
 336
 337 ;;; Internal variables:
 338
 339 ;;; Functions:
 340
 341 (defun mm-mule-charset-to-mime-charset (charset)
 342   "Return the MIME charset corresponding to the given Mule CHARSET."
 343   (if (and (fboundp 'find-coding-systems-for-charsets)
 344            (fboundp 'sort-coding-systems))
 345       (let ((css (sort (sort-coding-systems
 346                         (find-coding-systems-for-charsets (list charset)))
 347                        'mm-sort-coding-systems-predicate))
 348             cs mime)
 349         (while (and (not mime)
 350                     css)
 351           (when (setq cs (pop css))
 352             (setq mime (or (coding-system-get cs :mime-charset)
 353                            (coding-system-get cs 'mime-charset)))))
 354         mime)
 355     (let ((alist (mapcar (lambda (cs)
 356                            (assq cs mm-mime-mule-charset-alist))
 357                          (sort (mapcar 'car mm-mime-mule-charset-alist)
 358                                'mm-sort-coding-systems-predicate)))
 359           out)
 360       (while alist
 361         (when (memq charset (cdar alist))
 362           (setq out (caar alist)
 363                 alist nil))
 364         (pop alist))
 365       out)))
 366
 367 (defun mm-charset-to-coding-system (charset &optional lbt)
 368   "Return coding-system corresponding to CHARSET.
 369 CHARSET is a symbol naming a MIME charset.
 370 If optional argument LBT (`unix', `dos' or `mac') is specified, it is
 371 used as the line break code type of the coding system."
 372   (when (stringp charset)
 373     (setq charset (intern (downcase charset))))
 374   (when lbt
 375     (setq charset (intern (format "%s-%s" charset lbt))))
 376   (cond
 377    ((null charset)
 378     charset)
 379    ;; Running in a non-MULE environment.
 380    ((or (null (mm-get-coding-system-list))
 381         (not (fboundp 'coding-system-get)))
 382     charset)
 383    ;; ascii
 384    ((eq charset 'us-ascii)
 385     'ascii)
 386    ;; Check to see whether we can handle this charset.  (This depends
 387    ;; on there being some coding system matching each `mime-charset'
 388    ;; property defined, as there should be.)
 389    ((and (mm-coding-system-p charset)
 390 ;;; Doing this would potentially weed out incorrect charsets.
 391 ;;;      charset
 392 ;;;      (eq charset (coding-system-get charset 'mime-charset))
 393          )
 394     charset)
 395    ;; Translate invalid charsets.
 396    ((let ((cs (cdr (assq charset mm-charset-synonym-alist))))
 397       (and cs (mm-coding-system-p cs) cs)))
 398    ;; Last resort: search the coding system list for entries which
 399    ;; have the right mime-charset in case the canonical name isn't
 400    ;; defined (though it should be).
 401    ((let (cs)
 402       ;; mm-get-coding-system-list returns a list of cs without lbt.
 403       ;; Do we need -lbt?
 404       (dolist (c (mm-get-coding-system-list))
 405         (if (and (null cs)
 406                  (eq charset (or (coding-system-get c :mime-charset)
 407                                  (coding-system-get c 'mime-charset))))
 408             (setq cs c)))
 409       cs))))
 410
 411 (eval-and-compile
 412   (defvar mm-emacs-mule (and (not (featurep 'xemacs))
 413                              (boundp 'default-enable-multibyte-characters)
 414                              default-enable-multibyte-characters
 415                              (fboundp 'set-buffer-multibyte))
 416     "True in Emacs with Mule.")
 417
 418   (if mm-emacs-mule
 419       (defun mm-enable-multibyte ()
 420         "Set the multibyte flag of the current buffer.
 421 Only do this if the default value of `enable-multibyte-characters' is
 422 non-nil.  This is a no-op in XEmacs."
 423         (set-buffer-multibyte 'to))
 424     (defalias 'mm-enable-multibyte 'ignore))
 425
 426   (if mm-emacs-mule
 427       (defun mm-disable-multibyte ()
 428         "Unset the multibyte flag of in the current buffer.
 429 This is a no-op in XEmacs."
 430         (set-buffer-multibyte nil))
 431     (defalias 'mm-disable-multibyte 'ignore)))
 432
 433 (defun mm-preferred-coding-system (charset)
 434   ;; A typo in some Emacs versions.
 435   (or (get-charset-property charset 'preferred-coding-system)
 436       (get-charset-property charset 'prefered-coding-system)))
 437
 438 ;; Mule charsets shouldn't be used.
 439 (defsubst mm-guess-charset ()
 440   "Guess Mule charset from the language environment."
 441   (or
 442    mail-parse-mule-charset ;; cached mule-charset
 443    (progn
 444      (setq mail-parse-mule-charset
 445            (and (boundp 'current-language-environment)
 446                 (car (last
 447                       (assq 'charset
 448                             (assoc current-language-environment
 449                                    language-info-alist))))))
 450      (if (or (not mail-parse-mule-charset)
 451              (eq mail-parse-mule-charset 'ascii))
 452          (setq mail-parse-mule-charset
 453                (or (car (last (assq mail-parse-charset
 454                                     mm-mime-mule-charset-alist)))
 455                    ;; default
 456                    'latin-iso8859-1)))
 457      mail-parse-mule-charset)))
 458
 459 (defun mm-charset-after (&optional pos)
 460   "Return charset of a character in current buffer at position POS.
 461 If POS is nil, it defauls to the current point.
 462 If POS is out of range, the value is nil.
 463 If the charset is `composition', return the actual one."
 464   (let ((char (char-after pos)) charset)
 465     (if (< (mm-char-int char) 128)
 466         (setq charset 'ascii)
 467       ;; charset-after is fake in some Emacsen.
 468       (setq charset (and (fboundp 'char-charset) (char-charset char)))
 469       (if (eq charset 'composition)     ; Mule 4
 470           (let ((p (or pos (point))))
 471             (cadr (find-charset-region p (1+ p))))
 472         (if (and charset (not (memq charset '(ascii eight-bit-control
 473                                                     eight-bit-graphic))))
 474             charset
 475           (mm-guess-charset))))))
 476
 477 (defun mm-mime-charset (charset)
 478   "Return the MIME charset corresponding to the given Mule CHARSET."
 479   (if (eq charset 'unknown)
 480       (error "The message contains non-printable characters, please use attachment"))
 481   (if (and (fboundp 'coding-system-get) (fboundp 'get-charset-property))
 482       ;; This exists in Emacs 20.
 483       (or
 484        (and (mm-preferred-coding-system charset)
 485             (or (coding-system-get
 486                  (mm-preferred-coding-system charset) :mime-charset)
 487                 (coding-system-get
 488                  (mm-preferred-coding-system charset) 'mime-charset)))
 489        (and (eq charset 'ascii)
 490             'us-ascii)
 491        (mm-preferred-coding-system charset)
 492        (mm-mule-charset-to-mime-charset charset))
 493     ;; This is for XEmacs.
 494     (mm-mule-charset-to-mime-charset charset)))
 495
 496 (defun mm-delete-duplicates (list)
 497   "Simple substitute for CL `delete-duplicates', testing with `equal'."
 498   (let (result head)
 499     (while list
 500       (setq head (car list))
 501       (setq list (delete head list))
 502       (setq result (cons head result)))
 503     (nreverse result)))
 504
 505 ;; Fixme:  This is used in places when it should be testing the
 506 ;; default multibyteness.  See mm-default-multibyte-p.
 507 (eval-and-compile
 508   (if (and (not (featurep 'xemacs))
 509            (boundp 'enable-multibyte-characters))
 510       (defun mm-multibyte-p ()
 511         "Non-nil if multibyte is enabled in the current buffer."
 512         enable-multibyte-characters)
 513     (defun mm-multibyte-p () (featurep 'mule))))
 514
 515 (defun mm-default-multibyte-p ()
 516   "Return non-nil if the session is multibyte.
 517 This affects whether coding conversion should be attempted generally."
 518   (if (featurep 'mule)
 519       (if (boundp 'default-enable-multibyte-characters)
 520           default-enable-multibyte-characters
 521         t)))
 522
 523 (defun mm-iso-8859-x-to-15-region (&optional b e)
 524   (if (fboundp 'char-charset)
 525       (let (charset item c inconvertible)
 526         (save-restriction
 527           (if e (narrow-to-region b e))
 528           (goto-char (point-min))
 529           (skip-chars-forward "\0-\177")
 530           (while (not (eobp))
 531             (cond
 532              ((not (setq item (assq (char-charset (setq c (char-after)))
 533                                     mm-iso-8859-x-to-15-table)))
 534               (forward-char))
 535              ((memq c (cdr (cdr item)))
 536               (setq inconvertible t)
 537               (forward-char))
 538              (t
 539               (insert-before-markers (prog1 (+ c (car (cdr item)))
 540                                        (delete-char 1)))))
 541             (skip-chars-forward "\0-\177")))
 542         (not inconvertible))))
 543
 544 (defun mm-sort-coding-systems-predicate (a b)
 545   (let ((priorities
 546          (mapcar (lambda (cs)
 547                    ;; Note: invalid entries are dropped silently
 548                    (and (setq cs (mm-coding-system-p cs))
 549                         (coding-system-base cs)))
 550                  mm-coding-system-priorities)))
 551     (and (setq a (mm-coding-system-p a))
 552          (if (setq b (mm-coding-system-p b))
 553              (> (length (memq (coding-system-base a) priorities))
 554                 (length (memq (coding-system-base b) priorities)))
 555            t))))
 556
 557 (defun mm-find-mime-charset-region (b e &optional hack-charsets)
 558   "Return the MIME charsets needed to encode the region between B and E.
 559 nil means ASCII, a single-element list represents an appropriate MIME
 560 charset, and a longer list means no appropriate charset."
 561   (let (charsets)
 562     ;; The return possibilities of this function are a mess...
 563     (or (and (mm-multibyte-p)
 564              mm-use-find-coding-systems-region
 565              ;; Find the mime-charset of the most preferred coding
 566              ;; system that has one.
 567              (let ((systems (find-coding-systems-region b e)))
 568                (when mm-coding-system-priorities
 569                  (setq systems
 570                        (sort systems 'mm-sort-coding-systems-predicate)))
 571                (setq systems (delq 'compound-text systems))
 572                (unless (equal systems '(undecided))
 573                  (while systems
 574                    (let* ((head (pop systems))
 575                           (cs (or (coding-system-get head :mime-charset)
 576                                   (coding-system-get head 'mime-charset))))
 577                      ;; The mime-charset (`x-ctext') of
 578                      ;; `compound-text' is not in the IANA list.  We
 579                      ;; shouldn't normally use anything here with a
 580                      ;; mime-charset having an `x-' prefix.
 581                      ;; Fixme:  Allow this to be overridden, since
 582                      ;; there is existing use of x-ctext.
 583                      ;; Also people apparently need the coding system
 584                      ;; `iso-2022-jp-3' (which Mule-UCS defines with
 585                      ;; mime-charset, though it's not valid).
 586                      (if (and cs
 587                               (not (string-match "^[Xx]-" (symbol-name cs)))
 588                               ;; UTF-16 of any variety is invalid for
 589                               ;; text parts and, unfortunately, has
 590                               ;; mime-charset defined both in Mule-UCS
 591                               ;; and versions of Emacs.  (The name
 592                               ;; might be `mule-utf-16...'  or
 593                               ;; `utf-16...'.)
 594                               (not (string-match "utf-16" (symbol-name cs))))
 595                          (setq systems nil
 596                                charsets (list cs))))))
 597                charsets))
 598         ;; Otherwise we're not multibyte, we're XEmacs, or a single
 599         ;; coding system won't cover it.
 600         (setq charsets
 601               (mm-delete-duplicates
 602                (mapcar 'mm-mime-charset
 603                        (delq 'ascii
 604                              (mm-find-charset-region b e))))))
 605     (if (and (> (length charsets) 1)
 606              (memq 'iso-8859-15 charsets)
 607              (memq 'iso-8859-15 hack-charsets)
 608              (save-excursion (mm-iso-8859-x-to-15-region b e)))
 609         (mapcar (lambda (x) (setq charsets (delq (car x) charsets)))
 610                 mm-iso-8859-15-compatible))
 611     (if (and (memq 'iso-2022-jp-2 charsets)
 612              (memq 'iso-2022-jp-2 hack-charsets))
 613         (setq charsets (delq 'iso-2022-jp charsets)))
 614     charsets))
 615
 616 (defmacro mm-with-unibyte-buffer (&rest forms)
 617   "Create a temporary buffer, and evaluate FORMS there like `progn'.
 618 Use unibyte mode for this."
 619   `(let (default-enable-multibyte-characters)
 620      (with-temp-buffer ,@forms)))
 621 (put 'mm-with-unibyte-buffer 'lisp-indent-function 0)
 622 (put 'mm-with-unibyte-buffer 'edebug-form-spec '(body))
 623
 624 (defmacro mm-with-multibyte-buffer (&rest forms)
 625   "Create a temporary buffer, and evaluate FORMS there like `progn'.
 626 Use multibyte mode for this."
 627   `(let ((default-enable-multibyte-characters t))
 628      (with-temp-buffer ,@forms)))
 629 (put 'mm-with-multibyte-buffer 'lisp-indent-function 0)
 630 (put 'mm-with-multibyte-buffer 'edebug-form-spec '(body))
 631
 632 (defmacro mm-with-unibyte-current-buffer (&rest forms)
 633   "Evaluate FORMS with current buffer temporarily made unibyte.
 634 Also bind `default-enable-multibyte-characters' to nil.
 635 Equivalent to `progn' in XEmacs"
 636   (let ((multibyte (make-symbol "multibyte"))
 637         (buffer (make-symbol "buffer")))
 638     `(if mm-emacs-mule
 639          (let ((,multibyte enable-multibyte-characters)
 640                (,buffer (current-buffer)))
 641            (unwind-protect
 642                (let (default-enable-multibyte-characters)
 643                  (set-buffer-multibyte nil)
 644                  ,@forms)
 645              (set-buffer ,buffer)
 646              (set-buffer-multibyte ,multibyte)))
 647        (let (default-enable-multibyte-characters)
 648          ,@forms))))
 649 (put 'mm-with-unibyte-current-buffer 'lisp-indent-function 0)
 650 (put 'mm-with-unibyte-current-buffer 'edebug-form-spec '(body))
 651
 652 (defmacro mm-with-unibyte (&rest forms)
 653   "Eval the FORMS with the default value of `enable-multibyte-characters' nil."
 654   `(let (default-enable-multibyte-characters)
 655      ,@forms))
 656 (put 'mm-with-unibyte 'lisp-indent-function 0)
 657 (put 'mm-with-unibyte 'edebug-form-spec '(body))
 658
 659 (defmacro mm-with-multibyte (&rest forms)
 660   "Eval the FORMS with the default value of `enable-multibyte-characters' t."
 661   `(let ((default-enable-multibyte-characters t))
 662      ,@forms))
 663 (put 'mm-with-multibyte 'lisp-indent-function 0)
 664 (put 'mm-with-multibyte 'edebug-form-spec '(body))
 665
 666 (defun mm-find-charset-region (b e)
 667   "Return a list of Emacs charsets in the region B to E."
 668   (cond
 669    ((and (mm-multibyte-p)
 670          (fboundp 'find-charset-region))
 671     ;; Remove composition since the base charsets have been included.
 672     ;; Remove eight-bit-*, treat them as ascii.
 673     (let ((css (find-charset-region b e)))
 674       (mapcar (lambda (cs) (setq css (delq cs css)))
 675               '(composition eight-bit-control eight-bit-graphic
 676                             control-1))
 677       css))
 678    (t
 679     ;; We are in a unibyte buffer or XEmacs non-mule, so we futz around a bit.
 680     (save-excursion
 681       (save-restriction
 682         (narrow-to-region b e)
 683         (goto-char (point-min))
 684         (skip-chars-forward "\0-\177")
 685         (if (eobp)
 686             '(ascii)
 687           (let (charset)
 688             (setq charset
 689                   (and (boundp 'current-language-environment)
 690                        (car (last (assq 'charset
 691                                         (assoc current-language-environment
 692                                                language-info-alist))))))
 693             (if (eq charset 'ascii) (setq charset nil))
 694             (or charset
 695                 (setq charset
 696                       (car (last (assq mail-parse-charset
 697                                        mm-mime-mule-charset-alist)))))
 698             (list 'ascii (or charset 'latin-iso8859-1)))))))))
 699
 700 (defun mm-auto-mode-alist ()
 701   "Return an `auto-mode-alist' with only the .gz (etc) thingies."
 702   (let ((alist auto-mode-alist)
 703         out)
 704     (while alist
 705       (when (listp (cdar alist))
 706         (push (car alist) out))
 707       (pop alist))
 708     (nreverse out)))
 709
 710 (defvar mm-inhibit-file-name-handlers
 711   '(jka-compr-handler image-file-handler)
 712   "A list of handlers doing (un)compression (etc) thingies.")
 713
 714 (defun mm-insert-file-contents (filename &optional visit beg end replace
 715                                          inhibit)
 716   "Like `insert-file-contents', but only reads in the file.
 717 A buffer may be modified in several ways after reading into the buffer due
 718 to advanced Emacs features, such as file-name-handlers, format decoding,
 719 `find-file-hooks', etc.
 720 If INHIBIT is non-nil, inhibit `mm-inhibit-file-name-handlers'.
 721   This function ensures that none of these modifications will take place."
 722   (let ((format-alist nil)
 723         (auto-mode-alist (if inhibit nil (mm-auto-mode-alist)))
 724         (default-major-mode 'fundamental-mode)
 725         (enable-local-variables nil)
 726         (after-insert-file-functions nil)
 727         (enable-local-eval nil)
 728         (find-file-hooks nil)
 729         (inhibit-file-name-operation (if inhibit
 730                                          'insert-file-contents
 731                                        inhibit-file-name-operation))
 732         (inhibit-file-name-handlers
 733          (if inhibit
 734              (append mm-inhibit-file-name-handlers
 735                      inhibit-file-name-handlers)
 736            inhibit-file-name-handlers)))
 737     (insert-file-contents filename visit beg end replace)))
 738
 739 (defun mm-append-to-file (start end filename &optional codesys inhibit)
 740   "Append the contents of the region to the end of file FILENAME.
 741 When called from a function, expects three arguments,
 742 START, END and FILENAME.  START and END are buffer positions
 743 saying what text to write.
 744 Optional fourth argument specifies the coding system to use when
 745 encoding the file.
 746 If INHIBIT is non-nil, inhibit `mm-inhibit-file-name-handlers'."
 747   (let ((coding-system-for-write
 748          (or codesys mm-text-coding-system-for-write
 749              mm-text-coding-system))
 750         (inhibit-file-name-operation (if inhibit
 751                                          'append-to-file
 752                                        inhibit-file-name-operation))
 753         (inhibit-file-name-handlers
 754          (if inhibit
 755              (append mm-inhibit-file-name-handlers
 756                      inhibit-file-name-handlers)
 757            inhibit-file-name-handlers)))
 758     (write-region start end filename t 'no-message)
 759     (message "Appended to %s" filename)))
 760
 761 (defun mm-write-region (start end filename &optional append visit lockname
 762                               coding-system inhibit)
 763
 764   "Like `write-region'.
 765 If INHIBIT is non-nil, inhibit `mm-inhibit-file-name-handlers'."
 766   (let ((coding-system-for-write
 767          (or coding-system mm-text-coding-system-for-write
 768              mm-text-coding-system))
 769         (inhibit-file-name-operation (if inhibit
 770                                          'write-region
 771                                        inhibit-file-name-operation))
 772         (inhibit-file-name-handlers
 773          (if inhibit
 774              (append mm-inhibit-file-name-handlers
 775                      inhibit-file-name-handlers)
 776            inhibit-file-name-handlers)))
 777     (write-region start end filename append visit lockname)))
 778
 779 (defun mm-image-load-path (&optional package)
 780   (let (dir result)
 781     (dolist (path load-path (nreverse result))
 782       (when (and path
 783                  (file-directory-p
 784                   (setq dir (concat (file-name-directory
 785                                      (directory-file-name path))
 786                                     "etc/" (or package "gnus/")))))
 787         (push dir result))
 788       (push path result))))
 789
 790 ;; Fixme: This doesn't look useful where it's used.
 791 (if (fboundp 'detect-coding-region)
 792     (defun mm-detect-coding-region (start end)
 793       "Like `detect-coding-region' except returning the best one."
 794       (let ((coding-systems
 795              (detect-coding-region (point) (point-max))))
 796         (or (car-safe coding-systems)
 797             coding-systems)))
 798   (defun mm-detect-coding-region (start end)
 799     (let ((point (point)))
 800       (goto-char start)
 801       (skip-chars-forward "\0-\177" end)
 802       (prog1
 803           (if (eq (point) end) 'ascii (mm-guess-charset))
 804         (goto-char point)))))
 805
 806 (if (fboundp 'coding-system-get)
 807     (defun mm-detect-mime-charset-region (start end)
 808       "Detect MIME charset of the text in the region between START and END."
 809       (let ((cs (mm-detect-coding-region start end)))
 810         (coding-system-get cs 'mime-charset)))
 811   (defun mm-detect-mime-charset-region (start end)
 812     "Detect MIME charset of the text in the region between START and END."
 813     (let ((cs (mm-detect-coding-region start end)))
 814       cs)))
 815
 816
 817 (provide 'mm-util)
 818
 819 ;;; arch-tag: 94dc5388-825d-4fd1-bfa5-2100aa351238
 820 ;;; mm-util.el ends here