cgit.sxemacs.org Git - gnus/blob - lisp/mm-url.el

   1 ;;; mm-url.el --- a wrapper of url functions/commands for Gnus
   2 ;; Copyright (C) 2001, 2002, 2003 Free Software Foundation, Inc.
   3
   4 ;; Author: Shenghuo Zhu <zsh@cs.rochester.edu>
   5
   6 ;; This file is part of GNU Emacs.
   7
   8 ;; GNU Emacs is free software; you can redistribute it and/or modify
   9 ;; it under the terms of the GNU General Public License as published
  10 ;; by the Free Software Foundation; either version 2, or (at your
  11 ;; option) any later version.
  12
  13 ;; GNU Emacs is distributed in the hope that it will be useful, but
  14 ;; WITHOUT ANY WARRANTY; without even the implied warranty of
  15 ;; MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.  See the GNU
  16 ;; General Public License for more details.
  17
  18 ;; You should have received a copy of the GNU General Public License
  19 ;; along with GNU Emacs; see the file COPYING.  If not, write to the
  20 ;; Free Software Foundation, Inc., 59 Temple Place - Suite 330,
  21 ;; Boston, MA 02111-1307, USA.
  22
  23 ;;; Commentary:
  24
  25 ;; Some codes are stolen from w3 and url packages. Some are moved from
  26 ;; nnweb.
  27
  28 ;; TODO: Support POST, cookie.
  29
  30 ;;; Code:
  31
  32 (eval-when-compile (require 'cl))
  33
  34 (require 'mm-util)
  35 (require 'gnus)
  36
  37 (eval-and-compile
  38   (autoload 'executable-find "executable"))
  39
  40 (eval-when-compile
  41   (require 'timer))
  42
  43 (defgroup mm-url nil
  44   "A wrapper of url package and external url command for Gnus."
  45   :group 'gnus)
  46
  47 (defcustom mm-url-use-external (not
  48                                 (condition-case nil
  49                                     (require 'url)
  50                                   (error nil)))
  51   "*If not-nil, use external grab program `mm-url-program'."
  52   :type 'boolean
  53   :group 'mm-url)
  54
  55 (defvar mm-url-predefined-programs
  56   '((wget "wget" "-q" "-O" "-")
  57     (w3m  "w3m" "-dump_source")
  58     (lynx "lynx" "-source")
  59     (curl "curl")))
  60
  61 (defcustom mm-url-program
  62   (cond
  63    ((executable-find "wget") 'wget)
  64    ((executable-find "w3m") 'w3m)
  65    ((executable-find "lynx") 'lynx)
  66    ((executable-find "curl") 'curl)
  67    (t "GET"))
  68   "The url grab program.
  69 Likely values are `wget', `w3m', `lynx' and `curl'."
  70   :type '(choice
  71           (symbol :tag "wget" wget)
  72           (symbol :tag "w3m" w3m)
  73           (symbol :tag "lynx" lynx)
  74           (symbol :tag "curl" curl)
  75           (string :tag "other"))
  76   :group 'mm-url)
  77
  78 (defcustom mm-url-arguments nil
  79   "The arguments for `mm-url-program'."
  80   :type '(repeat string)
  81   :group 'mm-url)
  82
  83 \f
  84 ;;; Internal variables
  85
  86 (defvar mm-url-package-name
  87   (gnus-replace-in-string
  88    (gnus-replace-in-string gnus-version " v.*$" "")
  89    " " "-"))
  90
  91 (defvar mm-url-package-version gnus-version-number)
  92
  93 ;; Stolen from w3.
  94 (defvar mm-url-html-entities
  95   '(
  96     ;;(excl        .  33)
  97     (quot        .  34)
  98     ;;(num         .  35)
  99     ;;(dollar      .  36)
 100     ;;(percent     .  37)
 101     (amp         .  38)
 102     (rsquo       .  39)                 ; should be U+8217
 103     ;;(apos        .  39)
 104     ;;(lpar        .  40)
 105     ;;(rpar        .  41)
 106     ;;(ast         .  42)
 107     ;;(plus        .  43)
 108     ;;(comma       .  44)
 109     ;;(period      .  46)
 110     ;;(colon       .  58)
 111     ;;(semi        .  59)
 112     (lt          .  60)
 113     ;;(equals      .  61)
 114     (gt          .  62)
 115     ;;(quest       .  63)
 116     ;;(commat      .  64)
 117     ;;(lsqb        .  91)
 118     ;;(rsqb        .  93)
 119     (uarr        .  94)                 ; should be U+8593
 120     ;;(lowbar      .  95)
 121     (lsquo       .  96)                 ; should be U+8216
 122     (lcub        . 123)
 123     ;;(verbar      . 124)
 124     (rcub        . 125)
 125     (tilde       . 126)
 126     (nbsp        . 160)
 127     (iexcl       . 161)
 128     (cent        . 162)
 129     (pound       . 163)
 130     (curren      . 164)
 131     (yen         . 165)
 132     (brvbar      . 166)
 133     (sect        . 167)
 134     (uml         . 168)
 135     (copy        . 169)
 136     (ordf        . 170)
 137     (laquo       . 171)
 138     (not         . 172)
 139     (shy         . 173)
 140     (reg         . 174)
 141     (macr        . 175)
 142     (deg         . 176)
 143     (plusmn      . 177)
 144     (sup2        . 178)
 145     (sup3        . 179)
 146     (acute       . 180)
 147     (micro       . 181)
 148     (para        . 182)
 149     (middot      . 183)
 150     (cedil       . 184)
 151     (sup1        . 185)
 152     (ordm        . 186)
 153     (raquo       . 187)
 154     (frac14      . 188)
 155     (frac12      . 189)
 156     (frac34      . 190)
 157     (iquest      . 191)
 158     (Agrave      . 192)
 159     (Aacute      . 193)
 160     (Acirc       . 194)
 161     (Atilde      . 195)
 162     (Auml        . 196)
 163     (Aring       . 197)
 164     (AElig       . 198)
 165     (Ccedil      . 199)
 166     (Egrave      . 200)
 167     (Eacute      . 201)
 168     (Ecirc       . 202)
 169     (Euml        . 203)
 170     (Igrave      . 204)
 171     (Iacute      . 205)
 172     (Icirc       . 206)
 173     (Iuml        . 207)
 174     (ETH         . 208)
 175     (Ntilde      . 209)
 176     (Ograve      . 210)
 177     (Oacute      . 211)
 178     (Ocirc       . 212)
 179     (Otilde      . 213)
 180     (Ouml        . 214)
 181     (times       . 215)
 182     (Oslash      . 216)
 183     (Ugrave      . 217)
 184     (Uacute      . 218)
 185     (Ucirc       . 219)
 186     (Uuml        . 220)
 187     (Yacute      . 221)
 188     (THORN       . 222)
 189     (szlig       . 223)
 190     (agrave      . 224)
 191     (aacute      . 225)
 192     (acirc       . 226)
 193     (atilde      . 227)
 194     (auml        . 228)
 195     (aring       . 229)
 196     (aelig       . 230)
 197     (ccedil      . 231)
 198     (egrave      . 232)
 199     (eacute      . 233)
 200     (ecirc       . 234)
 201     (euml        . 235)
 202     (igrave      . 236)
 203     (iacute      . 237)
 204     (icirc       . 238)
 205     (iuml        . 239)
 206     (eth         . 240)
 207     (ntilde      . 241)
 208     (ograve      . 242)
 209     (oacute      . 243)
 210     (ocirc       . 244)
 211     (otilde      . 245)
 212     (ouml        . 246)
 213     (divide      . 247)
 214     (oslash      . 248)
 215     (ugrave      . 249)
 216     (uacute      . 250)
 217     (ucirc       . 251)
 218     (uuml        . 252)
 219     (yacute      . 253)
 220     (thorn       . 254)
 221     (yuml        . 255)
 222
 223     ;; Special handling of these
 224     (frac56      . "5/6")
 225     (frac16      . "1/6")
 226     (frac45      . "4/5")
 227     (frac35      . "3/5")
 228     (frac25      . "2/5")
 229     (frac15      . "1/5")
 230     (frac23      . "2/3")
 231     (frac13      . "1/3")
 232     (frac78      . "7/8")
 233     (frac58      . "5/8")
 234     (frac38      . "3/8")
 235     (frac18      . "1/8")
 236
 237     ;; The following 5 entities are not mentioned in the HTML 2.0
 238     ;; standard, nor in any other HTML proposed standard of which I
 239     ;; am aware.  I am not even sure they are ISO entity names.  ***
 240     ;; Hence, some arrangement should be made to give a bad HTML
 241     ;; message when they are seen.
 242     (ndash       .  45)
 243     (mdash       .  45)
 244     (emsp        .  32)
 245     (ensp        .  32)
 246     (sim         . 126)
 247     (le          . "<=")
 248     (agr         . "alpha")
 249     (rdquo       . "''")
 250     (ldquo       . "``")
 251     (trade       . "(TM)")
 252     ;; To be done
 253     ;; (shy      . ????) ; soft hyphen
 254     )
 255   "*An assoc list of entity names and how to actually display them.")
 256
 257 (defconst mm-url-unreserved-chars
 258   '(
 259     ?a ?b ?c ?d ?e ?f ?g ?h ?i ?j ?k ?l ?m ?n ?o ?p ?q ?r ?s ?t ?u ?v ?w ?x ?y ?z
 260     ?A ?B ?C ?D ?E ?F ?G ?H ?I ?J ?K ?L ?M ?N ?O ?P ?Q ?R ?S ?T ?U ?V ?W ?X ?Y ?Z
 261     ?0 ?1 ?2 ?3 ?4 ?5 ?6 ?7 ?8 ?9
 262     ?- ?_ ?. ?! ?~ ?* ?' ?\( ?\))
 263   "A list of characters that are _NOT_ reserved in the URL spec.
 264 This is taken from RFC 2396.")
 265
 266 (defun mm-url-load-url ()
 267   "Load `url-insert-file-contents'."
 268   (unless (condition-case ()
 269               (require 'url-handlers)
 270             (error nil))
 271     ;; w3-4.0pre0.46 or earlier version.
 272     (require 'w3-vars)
 273     (require 'url)))
 274
 275 (defun mm-url-insert-file-contents (url)
 276   (if mm-url-use-external
 277       (progn
 278         (if (string-match "^file:/+" url)
 279             (insert-file-contents (substring url (1- (match-end 0))))
 280           (mm-url-insert-file-contents-external url))
 281         (goto-char (point-min))
 282         (list url (buffer-size)))
 283     (mm-url-load-url)
 284     (let ((name buffer-file-name)
 285           (url-request-extra-headers (list (cons "Connection" "Close")))
 286           (url-package-name (or mm-url-package-name
 287                                 url-package-name))
 288           (url-package-version (or mm-url-package-version
 289                                    url-package-version))
 290           result)
 291       (setq result (url-insert-file-contents url))
 292       (save-excursion
 293         (goto-char (point-min))
 294         (while (re-search-forward "\r 1000\r ?" nil t)
 295           (replace-match "")))
 296       (setq buffer-file-name name)
 297       (if (and (fboundp 'url-generic-parse-url)
 298                (listp result))
 299           (setq url-current-object (url-generic-parse-url
 300                                     (car result))))
 301       result)))
 302
 303 (defun mm-url-insert-file-contents-external (url)
 304   (let (program args)
 305     (if (symbolp mm-url-program)
 306         (let ((item (cdr (assq mm-url-program mm-url-predefined-programs))))
 307           (setq program (car item)
 308                 args (append (cdr item) (list url))))
 309       (setq program mm-url-program
 310             args (append mm-url-arguments (list url))))
 311     (apply 'call-process program nil t nil args)))
 312
 313 (defvar mm-url-timeout 30
 314   "The number of seconds before timing out an URL fetch.")
 315
 316 (defvar mm-url-retries 10
 317   "The number of retries after timing out when fetching an URL.")
 318
 319 (defun mm-url-insert (url &optional follow-refresh)
 320   "Insert the contents from an URL in the current buffer.
 321 If FOLLOW-REFRESH is non-nil, redirect refresh url in META."
 322   (let ((times mm-url-retries)
 323         (done nil)
 324         (first t)
 325         result)
 326     (while (and (not (zerop (decf times)))
 327                 (not done))
 328       (with-timeout (mm-url-timeout)
 329         (unless first
 330           (message "Trying again (%s)..." (- mm-url-retries times)))
 331         (setq first nil)
 332         (if follow-refresh
 333             (save-restriction
 334               (narrow-to-region (point) (point))
 335               (mm-url-insert-file-contents url)
 336               (goto-char (point-min))
 337               (when (re-search-forward
 338                      "<meta[ \t\r\n]*http-equiv=\"Refresh\"[^>]*URL=\\([^\"]+\\)\"" nil t)
 339                 (let ((url (match-string 1)))
 340                   (delete-region (point-min) (point-max))
 341                   (setq result (mm-url-insert url t)))))
 342           (setq result (mm-url-insert-file-contents url)))
 343         (setq done t)))
 344     result))
 345
 346 (defun mm-url-decode-entities ()
 347   "Decode all HTML entities."
 348   (goto-char (point-min))
 349   (while (re-search-forward "&\\(#[0-9]+\\|[a-z]+\\);" nil t)
 350     (let ((elem (if (eq (aref (match-string 1) 0) ?\#)
 351                         (let ((c
 352                                (string-to-number (substring
 353                                                   (match-string 1) 1))))
 354                           (if (mm-char-or-char-int-p c) c 32))
 355                       (or (cdr (assq (intern (match-string 1))
 356                                      mm-url-html-entities))
 357                           ?#))))
 358       (unless (stringp elem)
 359         (setq elem (char-to-string elem)))
 360       (replace-match elem t t))))
 361
 362 (defun mm-url-decode-entities-nbsp ()
 363   "Decode all HTML entities and &nbsp; to a space."
 364   (let ((mm-url-html-entities (cons '(nbsp . 32) mm-url-html-entities)))
 365     (mm-url-decode-entities)))
 366
 367 (defun mm-url-decode-entities-string (string)
 368   (with-temp-buffer
 369     (insert string)
 370     (mm-url-decode-entities)
 371     (buffer-string)))
 372
 373 (defun mm-url-form-encode-xwfu (chunk)
 374   "Escape characters in a string for application/x-www-form-urlencoded.
 375 Blasphemous crap because someone didn't think %20 was good enough for encoding
 376 spaces.  Die Die Die."
 377   ;; This will get rid of the 'attributes' specified by the file type,
 378   ;; which are useless for an application/x-www-form-urlencoded form.
 379   (if (consp chunk)
 380       (setq chunk (cdr chunk)))
 381
 382   (mapconcat
 383    (lambda (char)
 384      (cond
 385       ((= char ?  ) "+")
 386       ((memq char mm-url-unreserved-chars) (char-to-string char))
 387       (t (upcase (format "%%%02x" char)))))
 388    ;; Fixme: Should this actually be accepting multibyte?  Is there a
 389    ;; better way in XEmacs?
 390    (if (featurep 'mule)
 391        (encode-coding-string chunk
 392                              (if (fboundp 'find-coding-systems-string)
 393                                  (car (find-coding-systems-string chunk))
 394                                  buffer-file-coding-system))
 395      chunk)
 396    ""))
 397
 398 (defun mm-url-encode-www-form-urlencoded (pairs)
 399   "Return PAIRS encoded for forms."
 400   (mapconcat
 401    (lambda (data)
 402      (concat (mm-url-form-encode-xwfu (car data)) "="
 403              (mm-url-form-encode-xwfu (cdr data))))
 404    pairs "&"))
 405
 406 (defun mm-url-fetch-form (url pairs)
 407   "Fetch a form from URL with PAIRS as the data using the POST method."
 408   (mm-url-load-url)
 409   (let ((url-request-data (mm-url-encode-www-form-urlencoded pairs))
 410         (url-request-method "POST")
 411         (url-request-extra-headers
 412          '(("Content-type" . "application/x-www-form-urlencoded"))))
 413     (url-insert-file-contents url)
 414     (setq buffer-file-name nil))
 415   t)
 416
 417 (defun mm-url-fetch-simple (url content)
 418   (mm-url-load-url)
 419   (let ((url-request-data content)
 420         (url-request-method "POST")
 421         (url-request-extra-headers
 422          '(("Content-type" . "application/x-www-form-urlencoded"))))
 423     (url-insert-file-contents url)
 424     (setq buffer-file-name nil))
 425   t)
 426
 427 (defun mm-url-remove-markup ()
 428   "Remove all HTML markup, leaving just plain text."
 429   (goto-char (point-min))
 430   (while (search-forward "<!--" nil t)
 431     (delete-region (match-beginning 0)
 432                    (or (search-forward "-->" nil t)
 433                        (point-max))))
 434   (goto-char (point-min))
 435   (while (re-search-forward "<[^>]+>" nil t)
 436     (replace-match "" t t)))
 437
 438 (provide 'mm-url)
 439
 440 ;;; mm-url.el ends here