cgit.sxemacs.org Git - gnus/blob - lisp/mm-decode.el

   1 ;;; mm-decode.el --- Functions for decoding MIME things
   2 ;; Copyright (C) 1998, 1999, 2000, 2001, 2002, 2003, 2004
   3 ;;        Free Software Foundation, Inc.
   4
   5 ;; Author: Lars Magne Ingebrigtsen <larsi@gnus.org>
   6 ;;      MORIOKA Tomohiko <morioka@jaist.ac.jp>
   7 ;; This file is part of GNU Emacs.
   8
   9 ;; GNU Emacs is free software; you can redistribute it and/or modify
  10 ;; it under the terms of the GNU General Public License as published by
  11 ;; the Free Software Foundation; either version 2, or (at your option)
  12 ;; any later version.
  13
  14 ;; GNU Emacs is distributed in the hope that it will be useful,
  15 ;; but WITHOUT ANY WARRANTY; without even the implied warranty of
  16 ;; MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.  See the
  17 ;; GNU General Public License for more details.
  18
  19 ;; You should have received a copy of the GNU General Public License
  20 ;; along with GNU Emacs; see the file COPYING.  If not, write to the
  21 ;; Free Software Foundation, Inc., 59 Temple Place - Suite 330,
  22 ;; Boston, MA 02111-1307, USA.
  23
  24 ;;; Commentary:
  25
  26 ;;; Code:
  27
  28 (require 'mail-parse)
  29 (require 'mailcap)
  30 (require 'mm-bodies)
  31 (eval-when-compile (require 'cl)
  32                    (require 'term))
  33
  34 (eval-and-compile
  35   (autoload 'mm-inline-partial "mm-partial")
  36   (autoload 'mm-inline-external-body "mm-extern")
  37   (autoload 'mm-insert-inline "mm-view"))
  38
  39 (add-hook 'gnus-exit-gnus-hook 'mm-destroy-postponed-undisplay-list)
  40
  41 (defgroup mime-display ()
  42   "Display of MIME in mail and news articles."
  43   :link '(custom-manual "(emacs-mime)Display Customization")
  44   :version "21.1"
  45   :group 'mail
  46   :group 'news
  47   :group 'multimedia)
  48
  49 (defgroup mime-security ()
  50   "MIME security in mail and news articles."
  51   :link '(custom-manual "(emacs-mime)Display Customization")
  52   :group 'mail
  53   :group 'news
  54   :group 'multimedia)
  55
  56 ;;; Convenience macros.
  57
  58 (defmacro mm-handle-buffer (handle)
  59   `(nth 0 ,handle))
  60 (defmacro mm-handle-type (handle)
  61   `(nth 1 ,handle))
  62 (defsubst mm-handle-media-type (handle)
  63   (if (stringp (car handle))
  64       (car handle)
  65     (car (mm-handle-type handle))))
  66 (defsubst mm-handle-media-supertype (handle)
  67   (car (split-string (mm-handle-media-type handle) "/")))
  68 (defsubst mm-handle-media-subtype (handle)
  69   (cadr (split-string (mm-handle-media-type handle) "/")))
  70 (defmacro mm-handle-encoding (handle)
  71   `(nth 2 ,handle))
  72 (defmacro mm-handle-undisplayer (handle)
  73   `(nth 3 ,handle))
  74 (defmacro mm-handle-set-undisplayer (handle function)
  75   `(setcar (nthcdr 3 ,handle) ,function))
  76 (defmacro mm-handle-disposition (handle)
  77   `(nth 4 ,handle))
  78 (defmacro mm-handle-description (handle)
  79   `(nth 5 ,handle))
  80 (defmacro mm-handle-cache (handle)
  81   `(nth 6 ,handle))
  82 (defmacro mm-handle-set-cache (handle contents)
  83   `(setcar (nthcdr 6 ,handle) ,contents))
  84 (defmacro mm-handle-id (handle)
  85   `(nth 7 ,handle))
  86 (defmacro mm-handle-multipart-original-buffer (handle)
  87   `(get-text-property 0 'buffer (car ,handle)))
  88 (defmacro mm-handle-multipart-from (handle)
  89   `(get-text-property 0 'from (car ,handle)))
  90 (defmacro mm-handle-multipart-ctl-parameter (handle parameter)
  91   `(get-text-property 0 ,parameter (car ,handle)))
  92
  93 (defmacro mm-make-handle (&optional buffer type encoding undisplayer
  94                                     disposition description cache
  95                                     id)
  96   `(list ,buffer ,type ,encoding ,undisplayer
  97          ,disposition ,description ,cache ,id))
  98
  99 (defcustom mm-text-html-renderer
 100   (cond ((locate-library "w3") 'w3)
 101         ((executable-find "w3m") (if (locate-library "w3m")
 102                                      'w3m
 103                                    'w3m-standalone))
 104         ((executable-find "links") 'links)
 105         ((executable-find "lynx") 'lynx)
 106         (t 'html2text))
 107   "Render of HTML contents.
 108 It is one of defined renderer types, or a rendering function.
 109 The defined renderer types are:
 110 `w3'   : use Emacs/W3;
 111 `w3m'  : use emacs-w3m;
 112 `w3m-standalone': use w3m;
 113 `links': use links;
 114 `lynx' : use lynx;
 115 `html2text' : use html2text;
 116 nil    : use external viewer."
 117   :type '(choice (const w3)
 118                  (const w3m)
 119                  (const w3m-standalone)
 120                  (const links)
 121                  (const lynx)
 122                  (const html2text)
 123                  (const nil)
 124                  (function))
 125   :version "21.3"
 126   :group 'mime-display)
 127
 128 (defvar mm-inline-text-html-renderer nil
 129   "Function used for rendering inline HTML contents.
 130 It is suggested to customize `mm-text-html-renderer' instead.")
 131
 132 (defcustom mm-inline-text-html-with-images nil
 133   "If non-nil, Gnus will allow retrieving images in HTML contents with
 134 the <img> tags.  It has no effect on Emacs/w3.  See also the
 135 documentation for the `mm-w3m-safe-url-regexp' variable."
 136   :type 'boolean
 137   :group 'mime-display)
 138
 139 (defcustom mm-w3m-safe-url-regexp "\\`cid:"
 140   "Regexp matching URLs which are considered to be safe.
 141 Some HTML mails might contain a nasty trick used by spammers, using
 142 the <img> tag which is far more evil than the [Click Here!] button.
 143 It is most likely intended to check whether the ominous spam mail has
 144 reached your eyes or not, in which case the spammer knows for sure
 145 that your email address is valid.  It is done by embedding an
 146 identifier string into a URL that you might automatically retrieve
 147 when displaying the image.  The default value is \"\\\\`cid:\" which only
 148 matches parts embedded to the Multipart/Related type MIME contents and
 149 Gnus will never connect to the spammer's site arbitrarily.  You may
 150 set this variable to nil if you consider all urls to be safe."
 151   :type '(choice (regexp :tag "Regexp")
 152                  (const :tag "All URLs are safe" nil))
 153   :group 'mime-display)
 154
 155 (defcustom mm-inline-text-html-with-w3m-keymap t
 156   "If non-nil, use emacs-w3m command keys in the article buffer."
 157   :type 'boolean
 158   :group 'mime-display)
 159
 160 (defcustom mm-enable-external t
 161   "Indicate whether external MIME handlers should be used.
 162
 163 If t, all defined external MIME handlers are used.  If nil, files are saved by
 164 `mailcap-save-binary-file'.  If it is the symbol `ask', you are prompted
 165 before the external MIME handler is invoked."
 166   :version "21.4"
 167   :type '(choice (const :tag "Always" t)
 168                  (const :tag "Never" nil)
 169                  (const :tag "Ask" ask))
 170   :group 'mime-display)
 171
 172 (defcustom mm-inline-media-tests
 173   '(("image/p?jpeg"
 174      mm-inline-image
 175      (lambda (handle)
 176        (mm-valid-and-fit-image-p 'jpeg handle)))
 177     ("image/png"
 178      mm-inline-image
 179      (lambda (handle)
 180        (mm-valid-and-fit-image-p 'png handle)))
 181     ("image/gif"
 182      mm-inline-image
 183      (lambda (handle)
 184        (mm-valid-and-fit-image-p 'gif handle)))
 185     ("image/tiff"
 186      mm-inline-image
 187      (lambda (handle)
 188        (mm-valid-and-fit-image-p 'tiff handle)) )
 189     ("image/xbm"
 190      mm-inline-image
 191      (lambda (handle)
 192        (mm-valid-and-fit-image-p 'xbm handle)))
 193     ("image/x-xbitmap"
 194      mm-inline-image
 195      (lambda (handle)
 196        (mm-valid-and-fit-image-p 'xbm handle)))
 197     ("image/xpm"
 198      mm-inline-image
 199      (lambda (handle)
 200        (mm-valid-and-fit-image-p 'xpm handle)))
 201     ("image/x-xpixmap"
 202      mm-inline-image
 203      (lambda (handle)
 204        (mm-valid-and-fit-image-p 'xpm handle)))
 205     ("image/bmp"
 206      mm-inline-image
 207      (lambda (handle)
 208        (mm-valid-and-fit-image-p 'bmp handle)))
 209     ("image/x-portable-bitmap"
 210      mm-inline-image
 211      (lambda (handle)
 212        (mm-valid-and-fit-image-p 'pbm handle)))
 213     ("text/plain" mm-inline-text identity)
 214     ("text/enriched" mm-inline-text identity)
 215     ("text/richtext" mm-inline-text identity)
 216     ("text/x-patch" mm-display-patch-inline
 217      (lambda (handle)
 218        (locate-library "diff-mode")))
 219     ("application/emacs-lisp" mm-display-elisp-inline identity)
 220     ("application/x-emacs-lisp" mm-display-elisp-inline identity)
 221     ("text/html"
 222      mm-inline-text-html
 223      (lambda (handle)
 224        (or mm-inline-text-html-renderer
 225            mm-text-html-renderer)))
 226     ("text/x-vcard"
 227      mm-inline-text-vcard
 228      (lambda (handle)
 229        (or (featurep 'vcard)
 230            (locate-library "vcard"))))
 231     ("message/delivery-status" mm-inline-text identity)
 232     ("message/rfc822" mm-inline-message identity)
 233     ("message/partial" mm-inline-partial identity)
 234     ("message/external-body" mm-inline-external-body identity)
 235     ("text/.*" mm-inline-text identity)
 236     ("audio/wav" mm-inline-audio
 237      (lambda (handle)
 238        (and (or (featurep 'nas-sound) (featurep 'native-sound))
 239             (device-sound-enabled-p))))
 240     ("audio/au"
 241      mm-inline-audio
 242      (lambda (handle)
 243        (and (or (featurep 'nas-sound) (featurep 'native-sound))
 244             (device-sound-enabled-p))))
 245     ("application/pgp-signature" ignore identity)
 246     ("application/x-pkcs7-signature" ignore identity)
 247     ("application/pkcs7-signature" ignore identity)
 248     ("application/x-pkcs7-mime" ignore identity)
 249     ("application/pkcs7-mime" ignore identity)
 250     ("multipart/alternative" ignore identity)
 251     ("multipart/mixed" ignore identity)
 252     ("multipart/related" ignore identity)
 253     ;; Disable audio and image
 254     ("audio/.*" ignore ignore)
 255     ("image/.*" ignore ignore)
 256     ;; Default to displaying as text
 257     (".*" mm-inline-text mm-readable-p))
 258   "Alist of media types/tests saying whether types can be displayed inline."
 259   :type '(repeat (list (regexp :tag "MIME type")
 260                        (function :tag "Display function")
 261                        (function :tag "Display test")))
 262   :group 'mime-display)
 263
 264 (defcustom mm-inlined-types
 265   '("image/.*" "text/.*" "message/delivery-status" "message/rfc822"
 266     "message/partial" "message/external-body" "application/emacs-lisp"
 267     "application/x-emacs-lisp"
 268     "application/pgp-signature" "application/x-pkcs7-signature"
 269     "application/pkcs7-signature" "application/x-pkcs7-mime"
 270     "application/pkcs7-mime")
 271   "List of media types that are to be displayed inline.
 272 See also `mm-inline-media-tests', which says how to display a media
 273 type inline."
 274   :type '(repeat string)
 275   :group 'mime-display)
 276
 277 (defcustom mm-keep-viewer-alive-types
 278   '("application/postscript" "application/msword" "application/vnd.ms-excel"
 279     "application/pdf" "application/x-dvi")
 280   "List of media types for which the external viewer will not be killed
 281 when selecting a different article."
 282   :type '(repeat string)
 283   :group 'mime-display)
 284
 285 (defcustom mm-automatic-display
 286   '("text/plain" "text/enriched" "text/richtext" "text/html"
 287     "text/x-vcard" "image/.*" "message/delivery-status" "multipart/.*"
 288     "message/rfc822" "text/x-patch" "application/pgp-signature"
 289     "application/emacs-lisp" "application/x-emacs-lisp"
 290     "application/x-pkcs7-signature"
 291     "application/pkcs7-signature" "application/x-pkcs7-mime"
 292     "application/pkcs7-mime")
 293   "A list of MIME types to be displayed automatically."
 294   :type '(repeat string)
 295   :group 'mime-display)
 296
 297 (defcustom mm-attachment-override-types '("text/x-vcard"
 298                                           "application/pkcs7-mime"
 299                                           "application/x-pkcs7-mime"
 300                                           "application/pkcs7-signature"
 301                                           "application/x-pkcs7-signature")
 302   "Types to have \"attachment\" ignored if they can be displayed inline."
 303   :type '(repeat string)
 304   :group 'mime-display)
 305
 306 (defcustom mm-inline-override-types nil
 307   "Types to be treated as attachments even if they can be displayed inline."
 308   :type '(repeat string)
 309   :group 'mime-display)
 310
 311 (defcustom mm-automatic-external-display nil
 312   "List of MIME type regexps that will be displayed externally automatically."
 313   :type '(repeat string)
 314   :group 'mime-display)
 315
 316 (defcustom mm-discouraged-alternatives nil
 317   "List of MIME types that are discouraged when viewing multipart/alternative.
 318 Viewing agents are supposed to view the last possible part of a message,
 319 as that is supposed to be the richest.  However, users may prefer other
 320 types instead, and this list says what types are most unwanted.  If,
 321 for instance, text/html parts are very unwanted, and text/richtext are
 322 somewhat unwanted, then the value of this variable should be set
 323 to:
 324
 325  (\"text/html\" \"text/richtext\")"
 326   :type '(repeat string)
 327   :group 'mime-display)
 328
 329 (defcustom mm-tmp-directory
 330   (if (fboundp 'temp-directory)
 331       (temp-directory)
 332     (if (boundp 'temporary-file-directory)
 333         temporary-file-directory
 334       "/tmp/"))
 335   "Where mm will store its temporary files."
 336   :type 'directory
 337   :group 'mime-display)
 338
 339 (defcustom mm-inline-large-images nil
 340   "If non-nil, then all images fit in the buffer."
 341   :type 'boolean
 342   :group 'mime-display)
 343
 344 (defvar mm-file-name-rewrite-functions
 345   '(mm-file-name-delete-control mm-file-name-delete-gotchas)
 346   "*List of functions used for rewriting file names of MIME parts.
 347 Each function takes a file name as input and returns a file name.
 348
 349 Ready-made functions include
 350 `mm-file-name-delete-control'
 351 `mm-file-name-delete-gotchas'
 352 `mm-file-name-delete-whitespace',
 353 `mm-file-name-trim-whitespace',
 354 `mm-file-name-collapse-whitespace',
 355 `mm-file-name-replace-whitespace',
 356 `capitalize', `downcase', `upcase', and
 357 `upcase-initials'.")
 358
 359 (defvar mm-path-name-rewrite-functions nil
 360   "*List of functions for rewriting the full file names of MIME parts.
 361 This is used when viewing parts externally, and is meant for
 362 transforming the absolute name so that non-compliant programs can find
 363 the file where it's saved.
 364
 365 Each function takes a file name as input and returns a file name.")
 366
 367 (defvar mm-file-name-replace-whitespace nil
 368   "String used for replacing whitespace characters; default is `\"_\"'.")
 369
 370 (defcustom mm-default-directory nil
 371   "The default directory where mm will save files.
 372 If not set, `default-directory' will be used."
 373   :type '(choice directory (const :tag "Default" nil))
 374   :group 'mime-display)
 375
 376 (defcustom mm-attachment-file-modes 384
 377   "Set the mode bits of saved attachments to this integer."
 378   :type 'integer
 379   :group 'mime-display)
 380
 381 (defcustom mm-external-terminal-program "xterm"
 382   "The program to start an external terminal."
 383   :type 'string
 384   :group 'mime-display)
 385
 386 ;;; Internal variables.
 387
 388 (defvar mm-last-shell-command "")
 389 (defvar mm-content-id-alist nil)
 390 (defvar mm-postponed-undisplay-list nil)
 391
 392 ;; According to RFC2046, in particular, in a digest, the default
 393 ;; Content-Type value for a body part is changed from "text/plain" to
 394 ;; "message/rfc822".
 395 (defvar mm-dissect-default-type "text/plain")
 396
 397 (autoload 'mml2015-verify "mml2015")
 398 (autoload 'mml2015-verify-test "mml2015")
 399 (autoload 'mml-smime-verify "mml-smime")
 400 (autoload 'mml-smime-verify-test "mml-smime")
 401
 402 (defvar mm-verify-function-alist
 403   '(("application/pgp-signature" mml2015-verify "PGP" mml2015-verify-test)
 404     ("application/x-gnus-pgp-signature" mm-uu-pgp-signed-extract-1 "PGP"
 405      mm-uu-pgp-signed-test)
 406     ("application/pkcs7-signature" mml-smime-verify "S/MIME"
 407      mml-smime-verify-test)
 408     ("application/x-pkcs7-signature" mml-smime-verify "S/MIME"
 409      mml-smime-verify-test)))
 410
 411 (defcustom mm-verify-option 'never
 412   "Option of verifying signed parts.
 413 `never', not verify; `always', always verify;
 414 `known', only verify known protocols.  Otherwise, ask user."
 415   :type '(choice (item always)
 416                  (item never)
 417                  (item :tag "only known protocols" known)
 418                  (item :tag "ask" nil))
 419   :group 'mime-security)
 420
 421 (autoload 'mml2015-decrypt "mml2015")
 422 (autoload 'mml2015-decrypt-test "mml2015")
 423
 424 (defvar mm-decrypt-function-alist
 425   '(("application/pgp-encrypted" mml2015-decrypt "PGP" mml2015-decrypt-test)
 426     ("application/x-gnus-pgp-encrypted" mm-uu-pgp-encrypted-extract-1 "PGP"
 427      mm-uu-pgp-encrypted-test)))
 428
 429 (defcustom mm-decrypt-option nil
 430   "Option of decrypting encrypted parts.
 431 `never', not decrypt; `always', always decrypt;
 432 `known', only decrypt known protocols.  Otherwise, ask user."
 433   :type '(choice (item always)
 434                  (item never)
 435                  (item :tag "only known protocols" known)
 436                  (item :tag "ask" nil))
 437   :group 'mime-security)
 438
 439 (defvar mm-viewer-completion-map
 440   (let ((map (make-sparse-keymap 'mm-viewer-completion-map)))
 441     (set-keymap-parent map minibuffer-local-completion-map)
 442     map)
 443   "Keymap for input viewer with completion.")
 444
 445 ;; Should we bind other key to minibuffer-complete-word?
 446 (define-key mm-viewer-completion-map " " 'self-insert-command)
 447
 448 (defvar mm-viewer-completion-map
 449   (let ((map (make-sparse-keymap 'mm-viewer-completion-map)))
 450     (set-keymap-parent map minibuffer-local-completion-map)
 451     map)
 452   "Keymap for input viewer with completion.")
 453
 454 ;; Should we bind other key to minibuffer-complete-word?
 455 (define-key mm-viewer-completion-map " " 'self-insert-command)
 456
 457 ;;; The functions.
 458
 459 (defun mm-alist-to-plist (alist)
 460   "Convert association list ALIST into the equivalent property-list form.
 461 The plist is returned.  This converts from
 462
 463 \((a . 1) (b . 2) (c . 3))
 464
 465 into
 466
 467 \(a 1 b 2 c 3)
 468
 469 The original alist is not modified.  See also `destructive-alist-to-plist'."
 470   (let (plist)
 471     (while alist
 472       (let ((el (car alist)))
 473         (setq plist (cons (cdr el) (cons (car el) plist))))
 474       (setq alist (cdr alist)))
 475     (nreverse plist)))
 476
 477 (defun mm-keep-viewer-alive-p (handle)
 478   "Say whether external viewer for HANDLE should stay alive."
 479   (let ((types mm-keep-viewer-alive-types)
 480         (type (mm-handle-media-type handle))
 481         ty)
 482     (catch 'found
 483       (while (setq ty (pop types))
 484         (when (string-match ty type)
 485           (throw 'found t))))))
 486
 487 (defun mm-handle-set-external-undisplayer (handle function)
 488   "Set the undisplayer for HANDLE to FUNCTION.
 489 Postpone undisplaying of viewers for types in
 490 `mm-keep-viewer-alive-types'."
 491   (if (mm-keep-viewer-alive-p handle)
 492       (let ((new-handle (copy-sequence handle)))
 493         (mm-handle-set-undisplayer new-handle function)
 494         (mm-handle-set-undisplayer handle nil)
 495         (push new-handle mm-postponed-undisplay-list))
 496     (mm-handle-set-undisplayer handle function)))
 497
 498 (defun mm-destroy-postponed-undisplay-list ()
 499   (when mm-postponed-undisplay-list
 500     (message "Destroying external MIME viewers")
 501     (mm-destroy-parts mm-postponed-undisplay-list)))
 502
 503 (defun mm-dissect-buffer (&optional no-strict-mime loose-mime)
 504   "Dissect the current buffer and return a list of MIME handles."
 505   (save-excursion
 506     (let (ct ctl type subtype cte cd description id result from)
 507       (save-restriction
 508         (mail-narrow-to-head)
 509         (when (or no-strict-mime
 510                   loose-mime
 511                   (mail-fetch-field "mime-version"))
 512           (setq ct (mail-fetch-field "content-type")
 513                 ctl (ignore-errors (mail-header-parse-content-type ct))
 514                 cte (mail-fetch-field "content-transfer-encoding")
 515                 cd (mail-fetch-field "content-disposition")
 516                 description (mail-fetch-field "content-description")
 517                 from (mail-fetch-field "from")
 518                 id (mail-fetch-field "content-id"))
 519           ;; FIXME: In some circumstances, this code is running within
 520           ;; an unibyte macro.  mail-extract-address-components
 521           ;; creates unibyte buffers. This `if', though not a perfect
 522           ;; solution, avoids most of them.
 523           (if from
 524               (setq from (cadr (mail-extract-address-components from))))))
 525       (if (or (not ctl)
 526               (not (string-match "/" (car ctl))))
 527           (mm-dissect-singlepart
 528            (list mm-dissect-default-type)
 529            (and cte (intern (downcase (mail-header-strip cte))))
 530            no-strict-mime
 531            (and cd (ignore-errors (mail-header-parse-content-disposition cd)))
 532            description)
 533         (setq type (split-string (car ctl) "/"))
 534         (setq subtype (cadr type)
 535               type (pop type))
 536         (setq
 537          result
 538          (cond
 539           ((equal type "multipart")
 540            (let ((mm-dissect-default-type (if (equal subtype "digest")
 541                                               "message/rfc822"
 542                                             "text/plain"))
 543                  (start (cdr (assq 'start (cdr ctl)))))
 544              (add-text-properties 0 (length (car ctl))
 545                                   (mm-alist-to-plist (cdr ctl)) (car ctl))
 546
 547              ;; what really needs to be done here is a way to link a
 548              ;; MIME handle back to it's parent MIME handle (in a multilevel
 549              ;; MIME article).  That would probably require changing
 550              ;; the mm-handle API so we simply store the multipart buffert
 551              ;; name as a text property of the "multipart/whatever" string.
 552              (add-text-properties 0 (length (car ctl))
 553                                   (list 'buffer (mm-copy-to-buffer)
 554                                         'from from
 555                                         'start start)
 556                                   (car ctl))
 557              (cons (car ctl) (mm-dissect-multipart ctl))))
 558           (t
 559            (mm-possibly-verify-or-decrypt
 560             (mm-dissect-singlepart
 561              ctl
 562              (and cte (intern (downcase (mail-header-strip cte))))
 563              no-strict-mime
 564              (and cd (ignore-errors
 565                        (mail-header-parse-content-disposition cd)))
 566              description id)
 567             ctl))))
 568         (when id
 569           (when (string-match " *<\\(.*\\)> *" id)
 570             (setq id (match-string 1 id)))
 571           (push (cons id result) mm-content-id-alist))
 572         result))))
 573
 574 (defun mm-dissect-singlepart (ctl cte &optional force cdl description id)
 575   (when (or force
 576             (if (equal "text/plain" (car ctl))
 577                 ;; FIXME: This is a kludge.  Proper fix is to make
 578                 ;; gnus-display-mime invoke mm-uu-dissect on all
 579                 ;; textual MIME parts, and stop using mm-fill-flowed
 580                 ;; here.
 581                 (and mm-fill-flowed (assoc 'format ctl))
 582               t))
 583     (mm-make-handle
 584      (mm-copy-to-buffer) ctl cte nil cdl description nil id)))
 585
 586 (defun mm-dissect-multipart (ctl)
 587   (goto-char (point-min))
 588   (let* ((boundary (concat "\n--" (mail-content-type-get ctl 'boundary)))
 589          (close-delimiter (concat (regexp-quote boundary) "--[ \t]*$"))
 590          start parts
 591          (end (save-excursion
 592                 (goto-char (point-max))
 593                 (if (re-search-backward close-delimiter nil t)
 594                     (match-beginning 0)
 595                   (point-max)))))
 596     (setq boundary (concat (regexp-quote boundary) "[ \t]*$"))
 597     (while (and (< (point) end) (re-search-forward boundary end t))
 598       (goto-char (match-beginning 0))
 599       (when start
 600         (save-excursion
 601           (save-restriction
 602             (narrow-to-region start (point))
 603             (setq parts (nconc (list (mm-dissect-buffer t)) parts)))))
 604       (end-of-line 2)
 605       (or (looking-at boundary)
 606           (forward-line 1))
 607       (setq start (point)))
 608     (when (and start (< start end))
 609       (save-excursion
 610         (save-restriction
 611           (narrow-to-region start end)
 612           (setq parts (nconc (list (mm-dissect-buffer t)) parts)))))
 613     (mm-possibly-verify-or-decrypt (nreverse parts) ctl)))
 614
 615 (defun mm-copy-to-buffer ()
 616   "Copy the contents of the current buffer to a fresh buffer."
 617   (save-excursion
 618     (let ((obuf (current-buffer))
 619           beg)
 620       (goto-char (point-min))
 621       (search-forward-regexp "^\n" nil t)
 622       (setq beg (point))
 623       (set-buffer (generate-new-buffer " *mm*"))
 624       (insert-buffer-substring obuf beg)
 625       (current-buffer))))
 626
 627 (defun mm-display-parts (handle &optional no-default)
 628   (if (stringp (car handle))
 629       (mapcar 'mm-display-parts (cdr handle))
 630     (if (bufferp (car handle))
 631         (save-restriction
 632           (narrow-to-region (point) (point))
 633           (mm-display-part handle)
 634           (goto-char (point-max)))
 635       (mapcar 'mm-display-parts handle))))
 636
 637 (defun mm-display-part (handle &optional no-default)
 638   "Display the MIME part represented by HANDLE.
 639 Returns nil if the part is removed; inline if displayed inline;
 640 external if displayed external."
 641   (save-excursion
 642     (mailcap-parse-mailcaps)
 643     (if (mm-handle-displayed-p handle)
 644         (mm-remove-part handle)
 645       (let* ((type (mm-handle-media-type handle))
 646              (method (mailcap-mime-info type))
 647              (filename (or (mail-content-type-get
 648                             (mm-handle-disposition handle) 'filename)
 649                            (mail-content-type-get
 650                             (mm-handle-type handle) 'name)
 651                            "<file>"))
 652              (external mm-enable-external))
 653         (if (and (mm-inlinable-p handle)
 654                  (mm-inlined-p handle))
 655             (progn
 656               (forward-line 1)
 657               (mm-display-inline handle)
 658               'inline)
 659           (when (or method
 660                     (not no-default))
 661             (if (and (not method)
 662                      (equal "text" (car (split-string type))))
 663                 (progn
 664                   (forward-line 1)
 665                   (mm-insert-inline handle (mm-get-part handle))
 666                   'inline)
 667               (if (and method ;; If nil, we always use "save".
 668                        (stringp method) ;; 'mailcap-save-binary-file
 669                        (or (eq mm-enable-external t)
 670                            (and (eq mm-enable-external 'ask)
 671                                 (y-or-n-p
 672                                  (concat
 673                                   "Display part (" type
 674                                   ") using external program"
 675                                   ;; Can non-string method ever happen?
 676                                   (if (stringp method)
 677                                       (concat
 678                                        " \"" (format method filename) "\"")
 679                                     "")
 680                                   "? ")))))
 681                   (setq external t)
 682                 (setq external nil))
 683               (if external
 684                   (mm-display-external
 685                    handle (or method 'mailcap-save-binary-file))
 686                 (mm-display-external
 687                  handle 'mailcap-save-binary-file)))))))))
 688
 689 (defun mm-display-external (handle method)
 690   "Display HANDLE using METHOD."
 691   (let ((outbuf (current-buffer)))
 692     (mm-with-unibyte-buffer
 693       (if (functionp method)
 694           (let ((cur (current-buffer)))
 695             (if (eq method 'mailcap-save-binary-file)
 696                 (progn
 697                   (set-buffer (generate-new-buffer " *mm*"))
 698                   (setq method nil))
 699               (mm-insert-part handle)
 700               (let ((win (get-buffer-window cur t)))
 701                 (when win
 702                   (select-window win)))
 703               (switch-to-buffer (generate-new-buffer " *mm*")))
 704             (buffer-disable-undo)
 705             (mm-set-buffer-file-coding-system mm-binary-coding-system)
 706             (insert-buffer-substring cur)
 707             (goto-char (point-min))
 708             (when method
 709               (message "Viewing with %s" method))
 710             (let ((mm (current-buffer))
 711                   (non-viewer (assq 'non-viewer
 712                                     (mailcap-mime-info
 713                                      (mm-handle-media-type handle) t))))
 714               (unwind-protect
 715                   (if method
 716                       (funcall method)
 717                     (mm-save-part handle))
 718                 (when (and (not non-viewer)
 719                            method)
 720                   (mm-handle-set-undisplayer handle mm)))))
 721         ;; The function is a string to be executed.
 722         (mm-insert-part handle)
 723         (let* ((dir (mm-make-temp-file
 724                      (expand-file-name "emm." mm-tmp-directory) 'dir))
 725                (filename (or
 726                           (mail-content-type-get
 727                            (mm-handle-disposition handle) 'filename)
 728                           (mail-content-type-get
 729                            (mm-handle-type handle) 'name)))
 730                (mime-info (mailcap-mime-info
 731                            (mm-handle-media-type handle) t))
 732                (needsterm (or (assoc "needsterm" mime-info)
 733                               (assoc "needsterminal" mime-info)))
 734                (copiousoutput (assoc "copiousoutput" mime-info))
 735                file buffer)
 736           ;; We create a private sub-directory where we store our files.
 737           (set-file-modes dir 448)
 738           (if filename
 739               (setq file (expand-file-name
 740                           (gnus-map-function mm-file-name-rewrite-functions
 741                                              (file-name-nondirectory filename))
 742                           dir))
 743             (setq file (mm-make-temp-file (expand-file-name "mm." dir))))
 744           (let ((coding-system-for-write mm-binary-coding-system))
 745             (write-region (point-min) (point-max) file nil 'nomesg))
 746           (message "Viewing with %s" method)
 747           (cond
 748            (needsterm
 749             (let ((command (mm-mailcap-command
 750                             method file (mm-handle-type handle))))
 751               (unwind-protect
 752                   (if window-system
 753                       (start-process "*display*" nil
 754                                      mm-external-terminal-program
 755                                      "-e" shell-file-name
 756                                      shell-command-switch command)
 757                     (require 'term)
 758                     (require 'gnus-win)
 759                     (set-buffer
 760                      (setq buffer
 761                            (make-term "display"
 762                                       shell-file-name
 763                                       nil
 764                                       shell-command-switch command)))
 765                     (term-mode)
 766                     (term-char-mode)
 767                     (set-process-sentinel
 768                      (get-buffer-process buffer)
 769                      `(lambda (process state)
 770                         (if (eq 'exit (process-status process))
 771                             (gnus-configure-windows
 772                              ',gnus-current-window-configuration))))
 773                     (gnus-configure-windows 'display-term))
 774                 (mm-handle-set-external-undisplayer handle (cons file buffer)))
 775               (message "Displaying %s..." command))
 776             'external)
 777            (copiousoutput
 778             (with-current-buffer outbuf
 779               (forward-line 1)
 780               (mm-insert-inline
 781                handle
 782                (unwind-protect
 783                    (progn
 784                      (call-process shell-file-name nil
 785                                    (setq buffer
 786                                          (generate-new-buffer " *mm*"))
 787                                    nil
 788                                    shell-command-switch
 789                                    (mm-mailcap-command
 790                                     method file (mm-handle-type handle)))
 791                      (if (buffer-live-p buffer)
 792                          (save-excursion
 793                            (set-buffer buffer)
 794                            (buffer-string))))
 795                  (progn
 796                    (ignore-errors (delete-file file))
 797                    (ignore-errors (delete-directory
 798                                    (file-name-directory file)))
 799                    (ignore-errors (kill-buffer buffer))))))
 800             'inline)
 801            (t
 802             (let ((command (mm-mailcap-command
 803                             method file (mm-handle-type handle))))
 804               (unwind-protect
 805                   (start-process "*display*"
 806                                  (setq buffer
 807                                        (generate-new-buffer " *mm*"))
 808                                  shell-file-name
 809                                  shell-command-switch command)
 810                 (mm-handle-set-external-undisplayer
 811                  handle (cons file buffer)))
 812               (message "Displaying %s..." command))
 813             'external)))))))
 814
 815 (defun mm-mailcap-command (method file type-list)
 816   (let ((ctl (cdr type-list))
 817         (beg 0)
 818         (uses-stdin t)
 819         out sub total)
 820     (while (string-match "%{\\([^}]+\\)}\\|'%s'\\|\"%s\"\\|%s\\|%t\\|%%"
 821                          method beg)
 822       (push (substring method beg (match-beginning 0)) out)
 823       (setq beg (match-end 0)
 824             total (match-string 0 method)
 825             sub (match-string 1 method))
 826       (cond
 827        ((string= total "%%")
 828         (push "%" out))
 829        ((or (string= total "%s")
 830             ;; We do our own quoting.
 831             (string= total "'%s'")
 832             (string= total "\"%s\""))
 833         (setq uses-stdin nil)
 834         (push (shell-quote-argument
 835                (gnus-map-function mm-path-name-rewrite-functions file)) out))
 836        ((string= total "%t")
 837         (push (shell-quote-argument (car type-list)) out))
 838        (t
 839         (push (shell-quote-argument (or (cdr (assq (intern sub) ctl)) "")) out))))
 840     (push (substring method beg (length method)) out)
 841     (when uses-stdin
 842       (push "<" out)
 843       (push (shell-quote-argument
 844              (gnus-map-function mm-path-name-rewrite-functions file))
 845             out))
 846     (mapconcat 'identity (nreverse out) "")))
 847
 848 (defun mm-remove-parts (handles)
 849   "Remove the displayed MIME parts represented by HANDLES."
 850   (if (and (listp handles)
 851            (bufferp (car handles)))
 852       (mm-remove-part handles)
 853     (let (handle)
 854       (while (setq handle (pop handles))
 855         (cond
 856          ((stringp handle)
 857           (when (buffer-live-p (get-text-property 0 'buffer handle))
 858             (kill-buffer (get-text-property 0 'buffer handle))))
 859          ((and (listp handle)
 860                (stringp (car handle)))
 861           (mm-remove-parts (cdr handle)))
 862          (t
 863           (mm-remove-part handle)))))))
 864
 865 (defun mm-destroy-parts (handles)
 866   "Remove the displayed MIME parts represented by HANDLES."
 867   (if (and (listp handles)
 868            (bufferp (car handles)))
 869       (mm-destroy-part handles)
 870     (let (handle)
 871       (while (setq handle (pop handles))
 872         (cond
 873          ((stringp handle)
 874           (when (buffer-live-p (get-text-property 0 'buffer handle))
 875             (kill-buffer (get-text-property 0 'buffer handle))))
 876          ((and (listp handle)
 877                (stringp (car handle)))
 878           (mm-destroy-parts handle))
 879          (t
 880           (mm-destroy-part handle)))))))
 881
 882 (defun mm-remove-part (handle)
 883   "Remove the displayed MIME part represented by HANDLE."
 884   (when (listp handle)
 885     (let ((object (mm-handle-undisplayer handle)))
 886       (ignore-errors
 887         (cond
 888          ;; Internally displayed part.
 889          ((mm-annotationp object)
 890           (delete-annotation object))
 891          ((or (functionp object)
 892               (and (listp object)
 893                    (eq (car object) 'lambda)))
 894           (funcall object))
 895          ;; Externally displayed part.
 896          ((consp object)
 897           (condition-case ()
 898               (while (get-buffer-process (cdr object))
 899                 (interrupt-process (get-buffer-process (cdr object)))
 900                 (message "Waiting for external displayer to die...")
 901                 (sit-for 1))
 902             (quit)
 903             (error))
 904           (ignore-errors (and (cdr object) (kill-buffer (cdr object))))
 905           (message "Waiting for external displayer to die...done")
 906           (ignore-errors (delete-file (car object)))
 907           (ignore-errors (delete-directory (file-name-directory
 908                                             (car object)))))
 909          ((bufferp object)
 910           (when (buffer-live-p object)
 911             (kill-buffer object)))))
 912       (mm-handle-set-undisplayer handle nil))))
 913
 914 (defun mm-display-inline (handle)
 915   (let* ((type (mm-handle-media-type handle))
 916          (function (cadr (mm-assoc-string-match mm-inline-media-tests type))))
 917     (funcall function handle)
 918     (goto-char (point-min))))
 919
 920 (defun mm-assoc-string-match (alist type)
 921   (dolist (elem alist)
 922     (when (string-match (car elem) type)
 923       (return elem))))
 924
 925 (defun mm-automatic-display-p (handle)
 926   "Say whether the user wants HANDLE to be displayed automatically."
 927   (let ((methods mm-automatic-display)
 928         (type (mm-handle-media-type handle))
 929         method result)
 930     (while (setq method (pop methods))
 931       (when (and (not (mm-inline-override-p handle))
 932                  (string-match method type))
 933         (setq result t
 934               methods nil)))
 935     result))
 936
 937 (defun mm-inlinable-p (handle)
 938   "Say whether HANDLE can be displayed inline."
 939   (let ((alist mm-inline-media-tests)
 940         (type (mm-handle-media-type handle))
 941         test)
 942     (while alist
 943       (when (string-match (caar alist) type)
 944         (setq test (caddar alist)
 945               alist nil)
 946         (setq test (funcall test handle)))
 947       (pop alist))
 948     test))
 949
 950 (defun mm-inlined-p (handle)
 951   "Say whether the user wants HANDLE to be displayed inline."
 952   (let ((methods mm-inlined-types)
 953         (type (mm-handle-media-type handle))
 954         method result)
 955     (while (setq method (pop methods))
 956       (when (and (not (mm-inline-override-p handle))
 957                  (string-match method type))
 958         (setq result t
 959               methods nil)))
 960     result))
 961
 962 (defun mm-attachment-override-p (handle)
 963   "Say whether HANDLE should have attachment behavior overridden."
 964   (let ((types mm-attachment-override-types)
 965         (type (mm-handle-media-type handle))
 966         ty)
 967     (catch 'found
 968       (while (setq ty (pop types))
 969         (when (and (string-match ty type)
 970                    (mm-inlinable-p handle))
 971           (throw 'found t))))))
 972
 973 (defun mm-inline-override-p (handle)
 974   "Say whether HANDLE should have inline behavior overridden."
 975   (let ((types mm-inline-override-types)
 976         (type (mm-handle-media-type handle))
 977         ty)
 978     (catch 'found
 979       (while (setq ty (pop types))
 980         (when (string-match ty type)
 981           (throw 'found t))))))
 982
 983 (defun mm-automatic-external-display-p (type)
 984   "Return the user-defined method for TYPE."
 985   (let ((methods mm-automatic-external-display)
 986         method result)
 987     (while (setq method (pop methods))
 988       (when (string-match method type)
 989         (setq result t
 990               methods nil)))
 991     result))
 992
 993 (defun mm-destroy-part (handle)
 994   "Destroy the data structures connected to HANDLE."
 995   (when (listp handle)
 996     (mm-remove-part handle)
 997     (when (buffer-live-p (mm-handle-buffer handle))
 998       (kill-buffer (mm-handle-buffer handle)))))
 999
1000 (defun mm-handle-displayed-p (handle)
1001   "Say whether HANDLE is displayed or not."
1002   (mm-handle-undisplayer handle))
1003
1004 ;;;
1005 ;;; Functions for outputting parts
1006 ;;;
1007
1008 (defun mm-get-part (handle)
1009   "Return the contents of HANDLE as a string."
1010   (mm-with-unibyte-buffer
1011     (insert (with-current-buffer (mm-handle-buffer handle)
1012               (mm-with-unibyte-current-buffer
1013                 (buffer-string))))
1014     (mm-decode-content-transfer-encoding
1015      (mm-handle-encoding handle)
1016      (mm-handle-media-type handle))
1017     (buffer-string)))
1018
1019 (defun mm-insert-part (handle)
1020   "Insert the contents of HANDLE in the current buffer."
1021   (let ((cur (current-buffer)))
1022     (save-excursion
1023       (if (member (mm-handle-media-supertype handle) '("text" "message"))
1024           (with-temp-buffer
1025             (insert-buffer-substring (mm-handle-buffer handle))
1026             (prog1
1027                 (mm-decode-content-transfer-encoding
1028                  (mm-handle-encoding handle)
1029                  (mm-handle-media-type handle))
1030               (let ((temp (current-buffer)))
1031                 (set-buffer cur)
1032                 (insert-buffer-substring temp))))
1033         (mm-with-unibyte-buffer
1034           (insert-buffer-substring (mm-handle-buffer handle))
1035           (prog1
1036               (mm-decode-content-transfer-encoding
1037                (mm-handle-encoding handle)
1038                (mm-handle-media-type handle))
1039             (let ((temp (current-buffer)))
1040               (set-buffer cur)
1041               (insert-buffer-substring temp))))))))
1042
1043 (defun mm-file-name-delete-whitespace (file-name)
1044   "Remove all whitespace characters from FILE-NAME."
1045   (while (string-match "\\s-+" file-name)
1046     (setq file-name (replace-match "" t t file-name)))
1047   file-name)
1048
1049 (defun mm-file-name-trim-whitespace (file-name)
1050   "Remove leading and trailing whitespace characters from FILE-NAME."
1051   (when (string-match "\\`\\s-+" file-name)
1052     (setq file-name (substring file-name (match-end 0))))
1053   (when (string-match "\\s-+\\'" file-name)
1054     (setq file-name (substring file-name 0 (match-beginning 0))))
1055   file-name)
1056
1057 (defun mm-file-name-collapse-whitespace (file-name)
1058   "Collapse multiple whitespace characters in FILE-NAME."
1059   (while (string-match "\\s-\\s-+" file-name)
1060     (setq file-name (replace-match " " t t file-name)))
1061   file-name)
1062
1063 (defun mm-file-name-replace-whitespace (file-name)
1064   "Replace whitespace characters in FILE-NAME with underscores.
1065 Set the option `mm-file-name-replace-whitespace' to any other
1066 string if you do not like underscores."
1067   (let ((s (or mm-file-name-replace-whitespace "_")))
1068     (while (string-match "\\s-" file-name)
1069       (setq file-name (replace-match s t t file-name))))
1070   file-name)
1071
1072 (defun mm-file-name-delete-control (filename)
1073   "Delete control characters from FILENAME."
1074   (gnus-replace-in-string filename "[\x00-\x1f\x7f]" ""))
1075
1076 (defun mm-file-name-delete-gotchas (filename)
1077   "Delete shell gotchas from FILENAME."
1078   (setq filename (gnus-replace-in-string filename "[<>|]" ""))
1079   (gnus-replace-in-string filename "^[.-]+" ""))
1080
1081 (defun mm-save-part (handle)
1082   "Write HANDLE to a file."
1083   (let* ((name (mail-content-type-get (mm-handle-type handle) 'name))
1084          (filename (mail-content-type-get
1085                     (mm-handle-disposition handle) 'filename))
1086          file)
1087     (when filename
1088       (setq filename (gnus-map-function mm-file-name-rewrite-functions
1089                                         (file-name-nondirectory filename))))
1090     (setq file
1091           (mm-with-multibyte
1092             (read-file-name "Save MIME part to: "
1093                             (or mm-default-directory default-directory)
1094                             nil nil (or filename name ""))))
1095     (setq mm-default-directory (file-name-directory file))
1096     (and (or (not (file-exists-p file))
1097              (yes-or-no-p (format "File %s already exists; overwrite? "
1098                                   file)))
1099          (progn
1100            (mm-save-part-to-file handle file)
1101            file))))
1102
1103 (defun mm-save-part-to-file (handle file)
1104   (mm-with-unibyte-buffer
1105     (mm-insert-part handle)
1106     (let ((coding-system-for-write 'binary)
1107           (current-file-modes (default-file-modes))
1108           ;; Don't re-compress .gz & al.  Arguably we should make
1109           ;; `file-name-handler-alist' nil, but that would chop
1110           ;; ange-ftp, which is reasonable to use here.
1111           (inhibit-file-name-operation 'write-region)
1112           (inhibit-file-name-handlers
1113            (cons 'jka-compr-handler inhibit-file-name-handlers)))
1114       (set-default-file-modes mm-attachment-file-modes)
1115       (unwind-protect
1116           (write-region (point-min) (point-max) file)
1117         (set-default-file-modes current-file-modes)))))
1118
1119 (defun mm-pipe-part (handle)
1120   "Pipe HANDLE to a process."
1121   (let* ((name (mail-content-type-get (mm-handle-type handle) 'name))
1122          (command
1123           (read-string "Shell command on MIME part: " mm-last-shell-command)))
1124     (mm-with-unibyte-buffer
1125       (mm-insert-part handle)
1126       (let ((coding-system-for-write 'binary))
1127         (shell-command-on-region (point-min) (point-max) command nil)))))
1128
1129 (defun mm-interactively-view-part (handle)
1130   "Display HANDLE using METHOD."
1131   (let* ((type (mm-handle-media-type handle))
1132          (methods
1133           (mapcar (lambda (i) (list (cdr (assoc 'viewer i))))
1134                   (mailcap-mime-info type 'all)))
1135          (method (let ((minibuffer-local-completion-map
1136                         mm-viewer-completion-map))
1137                    (completing-read "Viewer: " methods))))
1138     (when (string= method "")
1139       (error "No method given"))
1140     (if (string-match "^[^% \t]+$" method)
1141         (setq method (concat method " %s")))
1142     (mm-display-external handle method)))
1143
1144 (defun mm-preferred-alternative (handles &optional preferred)
1145   "Say which of HANDLES are preferred."
1146   (let ((prec (if preferred (list preferred)
1147                 (mm-preferred-alternative-precedence handles)))
1148         p h result type handle)
1149     (while (setq p (pop prec))
1150       (setq h handles)
1151       (while h
1152         (setq handle (car h))
1153         (setq type (mm-handle-media-type handle))
1154         (when (and (equal p type)
1155                    (mm-automatic-display-p handle)
1156                    (or (stringp (car handle))
1157                        (not (mm-handle-disposition handle))
1158                        (equal (car (mm-handle-disposition handle))
1159                               "inline")))
1160           (setq result handle
1161                 h nil
1162                 prec nil))
1163         (pop h)))
1164     result))
1165
1166 (defun mm-preferred-alternative-precedence (handles)
1167   "Return the precedence based on HANDLES and `mm-discouraged-alternatives'."
1168   (let ((seq (nreverse (mapcar #'mm-handle-media-type
1169                                handles))))
1170     (dolist (disc (reverse mm-discouraged-alternatives))
1171       (dolist (elem (copy-sequence seq))
1172         (when (string-match disc elem)
1173           (setq seq (nconc (delete elem seq) (list elem))))))
1174     seq))
1175
1176 (defun mm-get-content-id (id)
1177   "Return the handle(s) referred to by ID."
1178   (cdr (assoc id mm-content-id-alist)))
1179
1180 (defconst mm-image-type-regexps
1181   '(("/\\*.*XPM.\\*/" . xpm)
1182     ("P[1-6]" . pbm)
1183     ("GIF8" . gif)
1184     ("\377\330" . jpeg)
1185     ("\211PNG\r\n" . png)
1186     ("#define" . xbm)
1187     ("\\(MM\0\\*\\)\\|\\(II\\*\0\\)" . tiff)
1188     ("%!PS" . postscript))
1189   "Alist of (REGEXP . IMAGE-TYPE) pairs used to auto-detect image types.
1190 When the first bytes of an image file match REGEXP, it is assumed to
1191 be of image type IMAGE-TYPE.")
1192
1193 ;; Steal from image.el. image-type-from-data suffers multi-line matching bug.
1194 (defun mm-image-type-from-buffer ()
1195   "Determine the image type from data in the current buffer.
1196 Value is a symbol specifying the image type or nil if type cannot
1197 be determined."
1198   (let ((types mm-image-type-regexps)
1199         type)
1200     (goto-char (point-min))
1201     (while (and types (null type))
1202       (let ((regexp (car (car types)))
1203             (image-type (cdr (car types))))
1204         (when (looking-at regexp)
1205           (setq type image-type))
1206         (setq types (cdr types))))
1207     type))
1208
1209 (defun mm-get-image (handle)
1210   "Return an image instance based on HANDLE."
1211   (let ((type (mm-handle-media-subtype handle))
1212         spec)
1213     ;; Allow some common translations.
1214     (setq type
1215           (cond
1216            ((equal type "x-pixmap")
1217             "xpm")
1218            ((equal type "x-xbitmap")
1219             "xbm")
1220            ((equal type "x-portable-bitmap")
1221             "pbm")
1222            (t type)))
1223     (or (mm-handle-cache handle)
1224         (mm-with-unibyte-buffer
1225           (mm-insert-part handle)
1226           (prog1
1227               (setq spec
1228                     (ignore-errors
1229                       ;; Avoid testing `make-glyph' since W3 may define
1230                       ;; a bogus version of it.
1231                       (if (fboundp 'create-image)
1232                           (create-image (buffer-string)
1233                                         (or (mm-image-type-from-buffer)
1234                                             (intern type))
1235                                         'data-p)
1236                         (mm-create-image-xemacs type))))
1237             (mm-handle-set-cache handle spec))))))
1238
1239 (defun mm-create-image-xemacs (type)
1240   (cond
1241    ((equal type "xbm")
1242     ;; xbm images require special handling, since
1243     ;; the only way to create glyphs from these
1244     ;; (without a ton of work) is to write them
1245     ;; out to a file, and then create a file
1246     ;; specifier.
1247     (let ((file (mm-make-temp-file
1248                  (expand-file-name "emm.xbm"
1249                                    mm-tmp-directory))))
1250       (unwind-protect
1251           (progn
1252             (write-region (point-min) (point-max) file)
1253             (make-glyph (list (cons 'x file))))
1254         (ignore-errors
1255           (delete-file file)))))
1256    (t
1257     (make-glyph
1258      (vector
1259       (or (mm-image-type-from-buffer)
1260           (intern type))
1261       :data (buffer-string))))))
1262
1263 (defun mm-image-fit-p (handle)
1264   "Say whether the image in HANDLE will fit the current window."
1265   (let ((image (mm-get-image handle)))
1266     (if (fboundp 'glyph-width)
1267         ;; XEmacs' glyphs can actually tell us about their width, so
1268         ;; lets be nice and smart about them.
1269         (or mm-inline-large-images
1270             (and (< (glyph-width image) (window-pixel-width))
1271                  (< (glyph-height image) (window-pixel-height))))
1272       (let* ((size (image-size image))
1273              (w (car size))
1274              (h (cdr size)))
1275         (or mm-inline-large-images
1276             (and (< h (1- (window-height))) ; Don't include mode line.
1277                  (< w (window-width))))))))
1278
1279 (defun mm-valid-image-format-p (format)
1280   "Say whether FORMAT can be displayed natively by Emacs."
1281   (cond
1282    ;; Handle XEmacs
1283    ((fboundp 'valid-image-instantiator-format-p)
1284     (valid-image-instantiator-format-p format))
1285    ;; Handle Emacs 21
1286    ((fboundp 'image-type-available-p)
1287     (and (display-graphic-p)
1288          (image-type-available-p format)))
1289    ;; Nobody else can do images yet.
1290    (t
1291     nil)))
1292
1293 (defun mm-valid-and-fit-image-p (format handle)
1294   "Say whether FORMAT can be displayed natively and HANDLE fits the window."
1295   (and (mm-valid-image-format-p format)
1296        (mm-image-fit-p handle)))
1297
1298 (defun mm-find-part-by-type (handles type &optional notp recursive)
1299   "Search in HANDLES for part with TYPE.
1300 If NOTP, returns first non-matching part.
1301 If RECURSIVE, search recursively."
1302   (let (handle)
1303     (while handles
1304       (if (and recursive (stringp (caar handles)))
1305           (if (setq handle (mm-find-part-by-type (cdar handles) type
1306                                                  notp recursive))
1307               (setq handles nil))
1308         (if (if notp
1309                 (not (equal (mm-handle-media-type (car handles)) type))
1310               (equal (mm-handle-media-type (car handles)) type))
1311             (setq handle (car handles)
1312                   handles nil)))
1313       (setq handles (cdr handles)))
1314     handle))
1315
1316 (defun mm-find-raw-part-by-type (ctl type &optional notp)
1317   (goto-char (point-min))
1318   (let* ((boundary (concat "--" (mm-handle-multipart-ctl-parameter ctl
1319                                                                    'boundary)))
1320          (close-delimiter (concat "^" (regexp-quote boundary) "--[ \t]*$"))
1321          start
1322          (end (save-excursion
1323                 (goto-char (point-max))
1324                 (if (re-search-backward close-delimiter nil t)
1325                     (match-beginning 0)
1326                   (point-max))))
1327          result)
1328     (setq boundary (concat "^" (regexp-quote boundary) "[ \t]*$"))
1329     (while (and (not result)
1330                 (re-search-forward boundary end t))
1331       (goto-char (match-beginning 0))
1332       (when start
1333         (save-excursion
1334           (save-restriction
1335             (narrow-to-region start (1- (point)))
1336             (when (let ((ctl (ignore-errors
1337                                (mail-header-parse-content-type
1338                                 (mail-fetch-field "content-type")))))
1339                     (if notp
1340                         (not (equal (car ctl) type))
1341                       (equal (car ctl) type)))
1342               (setq result (buffer-string))))))
1343       (forward-line 1)
1344       (setq start (point)))
1345     (when (and (not result) start)
1346       (save-excursion
1347         (save-restriction
1348           (narrow-to-region start end)
1349           (when (let ((ctl (ignore-errors
1350                              (mail-header-parse-content-type
1351                               (mail-fetch-field "content-type")))))
1352                   (if notp
1353                       (not (equal (car ctl) type))
1354                     (equal (car ctl) type)))
1355             (setq result (buffer-string))))))
1356     result))
1357
1358 (defvar mm-security-handle nil)
1359
1360 (defsubst mm-set-handle-multipart-parameter (handle parameter value)
1361   ;; HANDLE could be a CTL.
1362   (when handle
1363     (put-text-property 0 (length (car handle)) parameter value
1364                        (car handle))))
1365
1366 (defun mm-possibly-verify-or-decrypt (parts ctl)
1367   (let ((type (car ctl))
1368         (subtype (cadr (split-string (car ctl) "/")))
1369         (mm-security-handle ctl) ;; (car CTL) is the type.
1370         protocol func functest)
1371     (cond
1372      ((or (equal type "application/x-pkcs7-mime")
1373           (equal type "application/pkcs7-mime"))
1374       (with-temp-buffer
1375         (when (and (cond
1376                     ((eq mm-decrypt-option 'never) nil)
1377                     ((eq mm-decrypt-option 'always) t)
1378                     ((eq mm-decrypt-option 'known) t)
1379                     (t (y-or-n-p
1380                         (format "Decrypt (S/MIME) part? "))))
1381                    (mm-view-pkcs7 parts))
1382           (setq parts (mm-dissect-buffer t)))))
1383      ((equal subtype "signed")
1384       (unless (and (setq protocol
1385                          (mm-handle-multipart-ctl-parameter ctl 'protocol))
1386                    (not (equal protocol "multipart/mixed")))
1387         ;; The message is broken or draft-ietf-openpgp-multsig-01.
1388         (let ((protocols mm-verify-function-alist))
1389           (while protocols
1390             (if (and (or (not (setq functest (nth 3 (car protocols))))
1391                          (funcall functest parts ctl))
1392                      (mm-find-part-by-type parts (caar protocols) nil t))
1393                 (setq protocol (caar protocols)
1394                       protocols nil)
1395               (setq protocols (cdr protocols))))))
1396       (setq func (nth 1 (assoc protocol mm-verify-function-alist)))
1397       (when (cond
1398              ((eq mm-verify-option 'never) nil)
1399              ((eq mm-verify-option 'always) t)
1400              ((eq mm-verify-option 'known)
1401               (and func
1402                    (or (not (setq functest
1403                                   (nth 3 (assoc protocol
1404                                                 mm-verify-function-alist))))
1405                        (funcall functest parts ctl))))
1406              (t
1407               (y-or-n-p
1408                (format "Verify signed (%s) part? "
1409                        (or (nth 2 (assoc protocol mm-verify-function-alist))
1410                            (format "protocol=%s" protocol))))))
1411         (save-excursion
1412           (if func
1413               (funcall func parts ctl)
1414             (mm-set-handle-multipart-parameter
1415              mm-security-handle 'gnus-details
1416              (format "Unknown sign protocol (%s)" protocol))))))
1417      ((equal subtype "encrypted")
1418       (unless (setq protocol
1419                     (mm-handle-multipart-ctl-parameter ctl 'protocol))
1420         ;; The message is broken.
1421         (let ((parts parts))
1422           (while parts
1423             (if (assoc (mm-handle-media-type (car parts))
1424                        mm-decrypt-function-alist)
1425                 (setq protocol (mm-handle-media-type (car parts))
1426                       parts nil)
1427               (setq parts (cdr parts))))))
1428       (setq func (nth 1 (assoc protocol mm-decrypt-function-alist)))
1429       (when (cond
1430              ((eq mm-decrypt-option 'never) nil)
1431              ((eq mm-decrypt-option 'always) t)
1432              ((eq mm-decrypt-option 'known)
1433               (and func
1434                    (or (not (setq functest
1435                                   (nth 3 (assoc protocol
1436                                                 mm-decrypt-function-alist))))
1437                        (funcall functest parts ctl))))
1438              (t
1439               (y-or-n-p
1440                (format "Decrypt (%s) part? "
1441                        (or (nth 2 (assoc protocol mm-decrypt-function-alist))
1442                            (format "protocol=%s" protocol))))))
1443         (save-excursion
1444           (if func
1445               (setq parts (funcall func parts ctl))
1446             (mm-set-handle-multipart-parameter
1447              mm-security-handle 'gnus-details
1448              (format "Unknown encrypt protocol (%s)" protocol))))))
1449      (t nil))
1450     parts))
1451
1452 (defun mm-multiple-handles (handles)
1453   (and (listp handles)
1454        (> (length handles) 1)
1455        (or (listp (car handles))
1456            (stringp (car handles)))))
1457
1458 (defun mm-complicated-handles (handles)
1459   (and (listp (car handles))
1460        (> (length handles) 1)))
1461
1462 (defun mm-merge-handles (handles1 handles2)
1463   (append
1464    (if (listp (car handles1))
1465        handles1
1466      (list handles1))
1467    (if (listp (car handles2))
1468        handles2
1469      (list handles2))))
1470
1471 (defun mm-readable-p (handle)
1472   "Say whether the content of HANDLE is readable."
1473   (and (< (with-current-buffer (mm-handle-buffer handle)
1474             (buffer-size)) 10000)
1475        (mm-with-unibyte-buffer
1476          (mm-insert-part handle)
1477          (and (eq (mm-body-7-or-8) '7bit)
1478               (not (mm-long-lines-p 76))))))
1479
1480 (provide 'mm-decode)
1481
1482 ;;; arch-tag: 4f35d360-56b8-4030-9388-3ed82d359b9b
1483 ;;; mm-decode.el ends here