cgit.sxemacs.org Git - gnus/blob - lisp/mail-source.el

   1 ;;; mail-source.el --- functions for fetching mail
   2 ;; Copyright (C) 1999, 2000, 2001, 2002 Free Software Foundation, Inc.
   3
   4 ;; Author: Lars Magne Ingebrigtsen <larsi@gnus.org>
   5 ;; Keywords: news, mail
   6
   7 ;; This file is part of GNU Emacs.
   8
   9 ;; GNU Emacs is free software; you can redistribute it and/or modify
  10 ;; it under the terms of the GNU General Public License as published by
  11 ;; the Free Software Foundation; either version 2, or (at your option)
  12 ;; any later version.
  13
  14 ;; GNU Emacs is distributed in the hope that it will be useful,
  15 ;; but WITHOUT ANY WARRANTY; without even the implied warranty of
  16 ;; MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.  See the
  17 ;; GNU General Public License for more details.
  18
  19 ;; You should have received a copy of the GNU General Public License
  20 ;; along with GNU Emacs; see the file COPYING.  If not, write to the
  21 ;; Free Software Foundation, Inc., 59 Temple Place - Suite 330,
  22 ;; Boston, MA 02111-1307, USA.
  23
  24 ;;; Commentary:
  25
  26 ;;; Code:
  27
  28 (eval-when-compile
  29   (require 'cl)
  30   (require 'imap)
  31   (eval-when-compile (defvar display-time-mail-function)))
  32 (eval-and-compile
  33   (autoload 'pop3-movemail "pop3")
  34   (autoload 'pop3-get-message-count "pop3")
  35   (autoload 'nnheader-cancel-timer "nnheader")
  36   (autoload 'nnheader-run-at-time "nnheader"))
  37 (require 'format-spec)
  38 (require 'mm-util)
  39 (require 'message) ;; for `message-directory'
  40
  41 (defgroup mail-source nil
  42   "The mail-fetching library."
  43   :version "21.1"
  44   :group 'gnus)
  45
  46 ;; Define these at compile time to avoid dragging in imap always.
  47 (defconst mail-source-imap-authenticators
  48   (eval-when-compile
  49     (mapcar (lambda (a)
  50               (list 'const (car a)))
  51      imap-authenticator-alist)))
  52 (defconst mail-source-imap-streams
  53   (eval-when-compile
  54     (mapcar (lambda (a)
  55               (list 'const (car a)))
  56      imap-stream-alist)))
  57
  58 (defcustom mail-sources nil
  59   "*Where the mail backends will look for incoming mail.
  60 This variable is a list of mail source specifiers.
  61 See Info node `(gnus)Mail Source Specifiers'."
  62   :group 'mail-source
  63   :type `(repeat
  64           (choice :format "%[Value Menu%] %v"
  65                   :value (file)
  66                   (cons :tag "Spool file"
  67                         (const :format "" file)
  68                         (checklist :tag "Options" :greedy t
  69                                    (group :inline t
  70                                           (const :format "" :value :path)
  71                                           file)))
  72                   (cons :tag "Several files in a directory"
  73                         (const :format "" directory)
  74                         (checklist :tag "Options" :greedy t
  75                                    (group :inline t
  76                                           (const :format "" :value :path)
  77                                           (directory :tag "Path"))
  78                                    (group :inline t
  79                                           (const :format "" :value :suffix)
  80                                           (string :tag "Suffix"))
  81                                    (group :inline t
  82                                           (const :format "" :value :predicate)
  83                                           (function :tag "Predicate"))
  84                                    (group :inline t
  85                                           (const :format "" :value :prescript)
  86                                           (string :tag "Prescript"))
  87                                    (group :inline t
  88                                           (const :format "" :value :postscript)
  89                                           (string :tag "Postscript"))
  90                                    (group :inline t
  91                                           (const :format "" :value :plugged)
  92                                           (boolean :tag "Plugged"))))
  93                   (cons :tag "POP3 server"
  94                         (const :format "" pop)
  95                         (checklist :tag "Options" :greedy t
  96                                    (group :inline t
  97                                           (const :format "" :value :server)
  98                                           (string :tag "Server"))
  99                                    (group :inline t
 100                                           (const :format "" :value :port)
 101                                           (choice :tag "Port"
 102                                                   :value "pop3"
 103                                                   (number :format "%v")
 104                                                   (string :format "%v")))
 105                                    (group :inline t
 106                                           (const :format "" :value :user)
 107                                           (string :tag "User"))
 108                                    (group :inline t
 109                                           (const :format "" :value :password)
 110                                           (string :tag "Password"))
 111                                    (group :inline t
 112                                           (const :format "" :value :program)
 113                                           (string :tag "Program"))
 114                                    (group :inline t
 115                                           (const :format "" :value :prescript)
 116                                           (string :tag "Prescript"))
 117                                    (group :inline t
 118                                           (const :format "" :value :postscript)
 119                                           (string :tag "Postscript"))
 120                                    (group :inline t
 121                                           (const :format "" :value :function)
 122                                           (function :tag "Function"))
 123                                    (group :inline t
 124                                           (const :format ""
 125                                                  :value :authentication)
 126                                           (choice :tag "Authentication"
 127                                                   :value apop
 128                                                   (const password)
 129                                                   (const apop)))
 130                                    (group :inline t
 131                                           (const :format "" :value :plugged)
 132                                           (boolean :tag "Plugged"))))
 133                   (cons :tag "Maildir (qmail, postfix...)"
 134                         (const :format "" maildir)
 135                         (checklist :tag "Options" :greedy t
 136                                    (group :inline t
 137                                           (const :format "" :value :path)
 138                                           (directory :tag "Path"))
 139                                    (group :inline t
 140                                           (const :format "" :value :plugged)
 141                                           (boolean :tag "Plugged"))))
 142                   (cons :tag "IMAP server"
 143                         (const :format "" imap)
 144                         (checklist :tag "Options" :greedy t
 145                                    (group :inline t
 146                                           (const :format "" :value :server)
 147                                           (string :tag "Server"))
 148                                    (group :inline t
 149                                           (const :format "" :value :port)
 150                                           (choice :tag "Port"
 151                                                   :value 143
 152                                                   number string))
 153                                    (group :inline t
 154                                           (const :format "" :value :user)
 155                                           (string :tag "User"))
 156                                    (group :inline t
 157                                           (const :format "" :value :password)
 158                                           (string :tag "Password"))
 159                                    (group :inline t
 160                                           (const :format "" :value :stream)
 161                                           (choice :tag "Stream"
 162                                                   :value network
 163                                                   ,@mail-source-imap-streams))
 164                                    (group :inline t
 165                                           (const :format "" :value :program)
 166                                           (string :tag "Program"))
 167                                    (group :inline t
 168                                           (const :format ""
 169                                                  :value :authenticator)
 170                                           (choice :tag "Authenticator"
 171                                                   :value login
 172                                                   ,@mail-source-imap-authenticators))
 173                                    (group :inline t
 174                                           (const :format "" :value :mailbox)
 175                                           (string :tag "Mailbox"
 176                                                   :value "INBOX"))
 177                                    (group :inline t
 178                                           (const :format "" :value :predicate)
 179                                           (string :tag "Predicate"
 180                                                   :value "UNSEEN UNDELETED"))
 181                                    (group :inline t
 182                                           (const :format "" :value :fetchflag)
 183                                           (string :tag "Fetchflag"
 184                                                   :value  "\\Deleted"))
 185                                    (group :inline t
 186                                           (const :format ""
 187                                                  :value :dontexpunge)
 188                                           (boolean :tag "Dontexpunge"))
 189                                    (group :inline t
 190                                           (const :format "" :value :plugged)
 191                                           (boolean :tag "Plugged"))))
 192                   (cons :tag "Webmail server"
 193                         (const :format "" webmail)
 194                         (checklist :tag "Options" :greedy t
 195                                    (group :inline t
 196                                          (const :format "" :value :subtype)
 197                                          ;; Should be generated from
 198                                          ;; `webmail-type-definition', but we
 199                                          ;; can't require webmail without W3.
 200                                          (choice :tag "Subtype"
 201                                                  :value hotmail
 202                                                  (const hotmail)
 203                                                  (const yahoo)
 204                                                  (const netaddress)
 205                                                  (const netscape)
 206                                                  (const my-deja)))
 207                                    (group :inline t
 208                                           (const :format "" :value :user)
 209                                           (string :tag "User"))
 210                                    (group :inline t
 211                                           (const :format "" :value :password)
 212                                           (string :tag "Password"))
 213                                    (group :inline t
 214                                           (const :format ""
 215                                                  :value :dontexpunge)
 216                                           (boolean :tag "Dontexpunge"))
 217                                    (group :inline t
 218                                           (const :format "" :value :plugged)
 219                                           (boolean :tag "Plugged")))))))
 220
 221 (defcustom mail-source-primary-source nil
 222   "*Primary source for incoming mail.
 223 If non-nil, this maildrop will be checked periodically for new mail."
 224   :group 'mail-source
 225   :type 'sexp)
 226
 227 (defcustom mail-source-flash t
 228   "*If non-nil, flash periodically when mail is available."
 229   :group 'mail-source
 230   :type 'boolean)
 231
 232 (defcustom mail-source-crash-box "~/.emacs-mail-crash-box"
 233   "File where mail will be stored while processing it."
 234   :group 'mail-source
 235   :type 'file)
 236
 237 (defcustom mail-source-directory message-directory
 238   "Directory where files (if any) will be stored."
 239   :group 'mail-source
 240   :type 'directory)
 241
 242 (defcustom mail-source-default-file-modes 384
 243   "Set the mode bits of all new mail files to this integer."
 244   :group 'mail-source
 245   :type 'integer)
 246
 247 (defcustom mail-source-delete-incoming nil
 248   "*If non-nil, delete incoming files after handling."
 249   :group 'mail-source
 250   :type 'boolean)
 251
 252 (defcustom mail-source-incoming-file-prefix "Incoming"
 253   "Prefix for file name for storing incoming mail"
 254   :group 'mail-source
 255   :type 'string)
 256
 257 (defcustom mail-source-report-new-mail-interval 5
 258   "Interval in minutes between checks for new mail."
 259   :group 'mail-source
 260   :type 'number)
 261
 262 (defcustom mail-source-idle-time-delay 5
 263   "Number of idle seconds to wait before checking for new mail."
 264   :group 'mail-source
 265   :type 'number)
 266
 267 (defcustom mail-source-movemail-program nil
 268   "If non-nil, name of program for fetching new mail."
 269   :group 'mail-source
 270   :type '(choice (const nil) string))
 271
 272 ;;; Internal variables.
 273
 274 (defvar mail-source-string ""
 275   "A dynamically bound string that says what the current mail source is.")
 276
 277 (defvar mail-source-new-mail-available nil
 278   "Flag indicating when new mail is available.")
 279
 280 (eval-and-compile
 281   (defvar mail-source-common-keyword-map
 282     '((:plugged))
 283     "Mapping from keywords to default values.
 284 Common keywords should be listed here.")
 285
 286   (defvar mail-source-keyword-map
 287     '((file
 288        (:prescript)
 289        (:prescript-delay)
 290        (:postscript)
 291        (:path (or (getenv "MAIL")
 292                   (expand-file-name (user-login-name) rmail-spool-directory))))
 293       (directory
 294        (:prescript)
 295        (:prescript-delay)
 296        (:postscript)
 297        (:path)
 298        (:suffix ".spool")
 299        (:predicate identity))
 300       (pop
 301        (:prescript)
 302        (:prescript-delay)
 303        (:postscript)
 304        (:server (getenv "MAILHOST"))
 305        (:port 110)
 306        (:user (or (user-login-name) (getenv "LOGNAME") (getenv "USER")))
 307        (:program)
 308        (:function)
 309        (:password)
 310        (:authentication password))
 311       (maildir
 312        (:path (or (getenv "MAILDIR") "~/Maildir/"))
 313        (:subdirs ("new" "cur"))
 314        (:function))
 315       (imap
 316        (:server (getenv "MAILHOST"))
 317        (:port)
 318        (:stream)
 319        (:program)
 320        (:authentication)
 321        (:user (or (user-login-name) (getenv "LOGNAME") (getenv "USER")))
 322        (:password)
 323        (:mailbox "INBOX")
 324        (:predicate "UNSEEN UNDELETED")
 325        (:fetchflag "\\Deleted")
 326        (:dontexpunge))
 327       (webmail
 328        (:subtype hotmail)
 329        (:user (or (user-login-name) (getenv "LOGNAME") (getenv "USER")))
 330        (:password)
 331        (:dontexpunge)
 332        (:authentication password)))
 333     "Mapping from keywords to default values.
 334 All keywords that can be used must be listed here."))
 335
 336 (defvar mail-source-fetcher-alist
 337   '((file mail-source-fetch-file)
 338     (directory mail-source-fetch-directory)
 339     (pop mail-source-fetch-pop)
 340     (maildir mail-source-fetch-maildir)
 341     (imap mail-source-fetch-imap)
 342     (webmail mail-source-fetch-webmail))
 343   "A mapping from source type to fetcher function.")
 344
 345 (defvar mail-source-password-cache nil)
 346
 347 (defvar mail-source-plugged t)
 348
 349 ;;; Functions
 350
 351 (eval-and-compile
 352   (defun mail-source-strip-keyword (keyword)
 353     "Strip the leading colon off the KEYWORD."
 354     (intern (substring (symbol-name keyword) 1))))
 355
 356 (eval-and-compile
 357   (defun mail-source-bind-1 (type)
 358     (let* ((defaults (cdr (assq type mail-source-keyword-map)))
 359            default bind)
 360       (while (setq default (pop defaults))
 361         (push (list (mail-source-strip-keyword (car default))
 362                     nil)
 363               bind))
 364       bind)))
 365
 366 (defmacro mail-source-bind (type-source &rest body)
 367   "Return a `let' form that binds all variables in source TYPE.
 368 TYPE-SOURCE is a list where the first element is the TYPE, and
 369 the second variable is the SOURCE.
 370 At run time, the mail source specifier SOURCE will be inspected,
 371 and the variables will be set according to it.  Variables not
 372 specified will be given default values.
 373
 374 After this is done, BODY will be executed in the scope
 375 of the `let' form.
 376
 377 The variables bound and their default values are described by
 378 the `mail-source-keyword-map' variable."
 379   `(let ,(mail-source-bind-1 (car type-source))
 380      (mail-source-set-1 ,(cadr type-source))
 381      ,@body))
 382
 383 (put 'mail-source-bind 'lisp-indent-function 1)
 384 (put 'mail-source-bind 'edebug-form-spec '(sexp body))
 385
 386 (defun mail-source-set-1 (source)
 387   (let* ((type (pop source))
 388          (defaults (cdr (assq type mail-source-keyword-map)))
 389          default value keyword)
 390     (while (setq default (pop defaults))
 391       (set (mail-source-strip-keyword (setq keyword (car default)))
 392            (if (setq value (plist-get source keyword))
 393                (mail-source-value value)
 394              (mail-source-value (cadr default)))))))
 395
 396 (eval-and-compile
 397   (defun mail-source-bind-common-1 ()
 398     (let* ((defaults mail-source-common-keyword-map)
 399            default bind)
 400       (while (setq default (pop defaults))
 401         (push (list (mail-source-strip-keyword (car default))
 402                     nil)
 403               bind))
 404       bind)))
 405
 406 (defun mail-source-set-common-1 (source)
 407   (let* ((type (pop source))
 408          (defaults mail-source-common-keyword-map)
 409          (defaults-1 (cdr (assq type mail-source-keyword-map)))
 410          default value keyword)
 411     (while (setq default (pop defaults))
 412       (set (mail-source-strip-keyword (setq keyword (car default)))
 413            (if (setq value (plist-get source keyword))
 414                (mail-source-value value)
 415              (if (setq value (assq  keyword defaults-1))
 416                  (mail-source-value (cadr value))
 417                (mail-source-value (cadr default))))))))
 418
 419 (defmacro mail-source-bind-common (source &rest body)
 420   "Return a `let' form that binds all common variables.
 421 See `mail-source-bind'."
 422   `(let ,(mail-source-bind-common-1)
 423      (mail-source-set-common-1 source)
 424      ,@body))
 425
 426 (put 'mail-source-bind-common 'lisp-indent-function 1)
 427 (put 'mail-source-bind-common 'edebug-form-spec '(sexp body))
 428
 429 (defun mail-source-value (value)
 430   "Return the value of VALUE."
 431   (cond
 432    ;; String
 433    ((stringp value)
 434     value)
 435    ;; Function
 436    ((and (listp value)
 437          (functionp (car value)))
 438     (eval value))
 439    ;; Just return the value.
 440    (t
 441     value)))
 442
 443 (defun mail-source-fetch (source callback)
 444   "Fetch mail from SOURCE and call CALLBACK zero or more times.
 445 CALLBACK will be called with the name of the file where (some of)
 446 the mail from SOURCE is put.
 447 Return the number of files that were found."
 448   (mail-source-bind-common source
 449     (if (or mail-source-plugged plugged)
 450         (save-excursion
 451           (let ((function (cadr (assq (car source) mail-source-fetcher-alist)))
 452                 (found 0))
 453             (unless function
 454               (error "%S is an invalid mail source specification" source))
 455             ;; If there's anything in the crash box, we do it first.
 456             (when (file-exists-p mail-source-crash-box)
 457               (message "Processing mail from %s..." mail-source-crash-box)
 458               (setq found (mail-source-callback
 459                            callback mail-source-crash-box)))
 460             (+ found
 461                (if (or debug-on-quit debug-on-error)
 462                    (funcall function source callback)
 463                  (condition-case err
 464                      (funcall function source callback)
 465                    (error
 466                     (unless (yes-or-no-p
 467                              (format "Mail source %s error (%s).  Continue? "
 468                                      (if (memq ':password source)
 469                                          (let ((s (copy-sequence source)))
 470                                            (setcar (cdr (memq ':password s))
 471                                                    "********")
 472                                            s)
 473                                        source)
 474                                      (cadr err)))
 475                       (error "Cannot get new mail"))
 476                     0)))))))))
 477
 478 (eval-and-compile
 479   (if (fboundp 'make-temp-file)
 480       (defalias 'mail-source-make-complex-temp-name 'make-temp-file)
 481     (defun mail-source-make-complex-temp-name (prefix)
 482       (let ((newname (make-temp-name prefix))
 483             (newprefix prefix))
 484         (while (file-exists-p newname)
 485           (setq newprefix (concat newprefix "x"))
 486           (setq newname (make-temp-name newprefix)))
 487         newname))))
 488
 489 (defun mail-source-callback (callback info)
 490   "Call CALLBACK on the mail file, and then remove the mail file.
 491 Pass INFO on to CALLBACK."
 492   (if (or (not (file-exists-p mail-source-crash-box))
 493           (zerop (nth 7 (file-attributes mail-source-crash-box))))
 494       (progn
 495         (when (file-exists-p mail-source-crash-box)
 496           (delete-file mail-source-crash-box))
 497         0)
 498     (prog1
 499         (funcall callback mail-source-crash-box info)
 500       (when (file-exists-p mail-source-crash-box)
 501         ;; Delete or move the incoming mail out of the way.
 502         (if mail-source-delete-incoming
 503             (delete-file mail-source-crash-box)
 504           (let ((incoming
 505                  (mail-source-make-complex-temp-name
 506                   (expand-file-name
 507                    mail-source-incoming-file-prefix
 508                    mail-source-directory))))
 509             (unless (file-exists-p (file-name-directory incoming))
 510               (make-directory (file-name-directory incoming) t))
 511             (rename-file mail-source-crash-box incoming t)))))))
 512
 513 (defun mail-source-movemail (from to)
 514   "Move FROM to TO using movemail."
 515   (if (not (file-writable-p to))
 516       (error "Can't write to crash box %s.  Not moving mail" to)
 517     (let ((to (file-truename (expand-file-name to)))
 518           errors result)
 519       (setq to (file-truename to)
 520             from (file-truename from))
 521       ;; Set TO if have not already done so, and rename or copy
 522       ;; the file FROM to TO if and as appropriate.
 523       (cond
 524        ((file-exists-p to)
 525         ;; The crash box exists already.
 526         t)
 527        ((not (file-exists-p from))
 528         ;; There is no inbox.
 529         (setq to nil))
 530        ((zerop (nth 7 (file-attributes from)))
 531         ;; Empty file.
 532         (setq to nil))
 533        (t
 534         ;; If getting from mail spool directory, use movemail to move
 535         ;; rather than just renaming, so as to interlock with the
 536         ;; mailer.
 537         (unwind-protect
 538             (save-excursion
 539               (setq errors (generate-new-buffer " *mail source loss*"))
 540               (let ((default-directory "/"))
 541                 (setq result
 542                       (apply
 543                        'call-process
 544                        (append
 545                         (list
 546                          (or mail-source-movemail-program
 547                              (expand-file-name "movemail" exec-directory))
 548                          nil errors nil from to)))))
 549               (when (file-exists-p to)
 550                 (set-file-modes to mail-source-default-file-modes))
 551               (if (and (or (not (buffer-modified-p errors))
 552                            (zerop (buffer-size errors)))
 553                        (zerop result))
 554                   ;; No output => movemail won.
 555                   t
 556                 (set-buffer errors)
 557                 ;; There may be a warning about older revisions.  We
 558                 ;; ignore that.
 559                 (goto-char (point-min))
 560                 (if (search-forward "older revision" nil t)
 561                     t
 562                   ;; Probably a real error.
 563                   (subst-char-in-region (point-min) (point-max) ?\n ?\  )
 564                   (goto-char (point-max))
 565                   (skip-chars-backward " \t")
 566                   (delete-region (point) (point-max))
 567                   (goto-char (point-min))
 568                   (when (looking-at "movemail: ")
 569                     (delete-region (point-min) (match-end 0)))
 570                   ;; Result may be a signal description string.
 571                   (unless (yes-or-no-p
 572                            (format "movemail: %s (%s return).  Continue? "
 573                                    (buffer-string) result))
 574                     (error "%s" (buffer-string)))
 575                   (setq to nil)))))))
 576       (when (and errors
 577                  (buffer-name errors))
 578         (kill-buffer errors))
 579       ;; Return whether we moved successfully or not.
 580       to)))
 581
 582 (defun mail-source-movemail-and-remove (from to)
 583   "Move FROM to TO using movemail, then remove FROM if empty."
 584   (or (not (mail-source-movemail from to))
 585       (not (zerop (nth 7 (file-attributes from))))
 586       (delete-file from)))
 587
 588 (defvar mail-source-read-passwd nil)
 589 (defun mail-source-read-passwd (prompt &rest args)
 590   "Read a password using PROMPT.
 591 If ARGS, PROMPT is used as an argument to `format'."
 592   (let ((prompt
 593          (if args
 594              (apply 'format prompt args)
 595            prompt)))
 596     (unless mail-source-read-passwd
 597       (if (or (fboundp 'read-passwd) (load "passwd" t))
 598           (setq mail-source-read-passwd 'read-passwd)
 599         (unless (fboundp 'ange-ftp-read-passwd)
 600           (autoload 'ange-ftp-read-passwd "ange-ftp"))
 601         (setq mail-source-read-passwd 'ange-ftp-read-passwd)))
 602     (funcall mail-source-read-passwd prompt)))
 603
 604 (defun mail-source-fetch-with-program (program)
 605   (zerop (call-process shell-file-name nil nil nil
 606                        shell-command-switch program)))
 607
 608 (defun mail-source-run-script (script spec &optional delay)
 609   (when script
 610     (if (and (symbolp script) (fboundp script))
 611         (funcall script)
 612       (mail-source-call-script
 613        (format-spec script spec))))
 614   (when delay
 615     (sleep-for delay)))
 616
 617 (defun mail-source-call-script (script)
 618   (let ((background nil))
 619     (when (string-match "& *$" script)
 620       (setq script (substring script 0 (match-beginning 0))
 621             background 0))
 622     (call-process shell-file-name nil background nil
 623                   shell-command-switch script)))
 624
 625 ;;;
 626 ;;; Different fetchers
 627 ;;;
 628
 629 (defun mail-source-fetch-file (source callback)
 630   "Fetcher for single-file sources."
 631   (mail-source-bind (file source)
 632     (mail-source-run-script
 633      prescript (format-spec-make ?t mail-source-crash-box)
 634      prescript-delay)
 635     (let ((mail-source-string (format "file:%s" path)))
 636       (if (mail-source-movemail path mail-source-crash-box)
 637           (prog1
 638               (mail-source-callback callback path)
 639             (mail-source-run-script
 640              postscript (format-spec-make ?t mail-source-crash-box)))
 641         0))))
 642
 643 (defun mail-source-fetch-directory (source callback)
 644   "Fetcher for directory sources."
 645   (mail-source-bind (directory source)
 646     (mail-source-run-script
 647      prescript (format-spec-make ?t path)
 648      prescript-delay)
 649     (let ((found 0)
 650           (mail-source-string (format "directory:%s" path)))
 651       (dolist (file (directory-files
 652                      path t (concat (regexp-quote suffix) "$")))
 653         (when (and (file-regular-p file)
 654                    (funcall predicate file)
 655                    (mail-source-movemail file mail-source-crash-box))
 656           (incf found (mail-source-callback callback file))))
 657       (mail-source-run-script
 658        postscript (format-spec-make ?t path))
 659       found)))
 660
 661 (defun mail-source-fetch-pop (source callback)
 662   "Fetcher for single-file sources."
 663   (mail-source-bind (pop source)
 664     (mail-source-run-script
 665      prescript
 666      (format-spec-make ?p password ?t mail-source-crash-box
 667                        ?s server ?P port ?u user)
 668      prescript-delay)
 669     (let ((from (format "%s:%s:%s" server user port))
 670           (mail-source-string (format "pop:%s@%s" user server))
 671           result)
 672       (when (eq authentication 'password)
 673         (setq password
 674               (or password
 675                   (cdr (assoc from mail-source-password-cache))
 676                   (mail-source-read-passwd
 677                    (format "Password for %s at %s: " user server)))))
 678       (when server
 679         (setenv "MAILHOST" server))
 680       (setq result
 681             (cond
 682              (program
 683               (mail-source-fetch-with-program
 684                (format-spec
 685                 program
 686                 (format-spec-make ?p password ?t mail-source-crash-box
 687                                   ?s server ?P port ?u user))))
 688              (function
 689               (funcall function mail-source-crash-box))
 690              ;; The default is to use pop3.el.
 691              (t
 692               (let ((pop3-password password)
 693                     (pop3-maildrop user)
 694                     (pop3-mailhost server)
 695                     (pop3-port port)
 696                     (pop3-authentication-scheme
 697                      (if (eq authentication 'apop) 'apop 'pass)))
 698                 (if (or debug-on-quit debug-on-error)
 699                     (save-excursion (pop3-movemail mail-source-crash-box))
 700                   (condition-case err
 701                       (save-excursion (pop3-movemail mail-source-crash-box))
 702                     (error
 703                      ;; We nix out the password in case the error
 704                      ;; was because of a wrong password being given.
 705                      (setq mail-source-password-cache
 706                            (delq (assoc from mail-source-password-cache)
 707                                  mail-source-password-cache))
 708                      (signal (car err) (cdr err)))))))))
 709       (if result
 710           (progn
 711             (when (eq authentication 'password)
 712               (unless (assoc from mail-source-password-cache)
 713                 (push (cons from password) mail-source-password-cache)))
 714             (prog1
 715                 (mail-source-callback callback server)
 716               ;; Update display-time's mail flag, if relevant.
 717               (if (equal source mail-source-primary-source)
 718                   (setq mail-source-new-mail-available nil))
 719               (mail-source-run-script
 720                postscript
 721                (format-spec-make ?p password ?t mail-source-crash-box
 722                                  ?s server ?P port ?u user))))
 723         ;; We nix out the password in case the error
 724         ;; was because of a wrong password being given.
 725         (setq mail-source-password-cache
 726               (delq (assoc from mail-source-password-cache)
 727                     mail-source-password-cache))
 728         0))))
 729
 730 (defun mail-source-check-pop (source)
 731   "Check whether there is new mail."
 732   (mail-source-bind (pop source)
 733     (let ((from (format "%s:%s:%s" server user port))
 734           (mail-source-string (format "pop:%s@%s" user server))
 735           result)
 736       (when (eq authentication 'password)
 737         (setq password
 738               (or password
 739                   (cdr (assoc from mail-source-password-cache))
 740                   (mail-source-read-passwd
 741                    (format "Password for %s at %s: " user server))))
 742         (unless (assoc from mail-source-password-cache)
 743           (push (cons from password) mail-source-password-cache)))
 744       (when server
 745         (setenv "MAILHOST" server))
 746       (setq result
 747             (cond
 748              ;; No easy way to check whether mail is waiting for these.
 749              (program)
 750              (function)
 751              ;; The default is to use pop3.el.
 752              (t
 753               (let ((pop3-password password)
 754                     (pop3-maildrop user)
 755                     (pop3-mailhost server)
 756                     (pop3-port port)
 757                     (pop3-authentication-scheme
 758                      (if (eq authentication 'apop) 'apop 'pass)))
 759                 (if (or debug-on-quit debug-on-error)
 760                     (save-excursion (pop3-get-message-count))
 761                   (condition-case err
 762                       (save-excursion (pop3-get-message-count))
 763                     (error
 764                      ;; We nix out the password in case the error
 765                      ;; was because of a wrong password being given.
 766                      (setq mail-source-password-cache
 767                            (delq (assoc from mail-source-password-cache)
 768                                  mail-source-password-cache))
 769                      (signal (car err) (cdr err)))))))))
 770       (if result
 771           ;; Inform display-time that we have new mail.
 772           (setq mail-source-new-mail-available (> result 0))
 773         ;; We nix out the password in case the error
 774         ;; was because of a wrong password being given.
 775         (setq mail-source-password-cache
 776               (delq (assoc from mail-source-password-cache)
 777                     mail-source-password-cache)))
 778       result)))
 779
 780 (defun mail-source-touch-pop ()
 781   "Open and close a POP connection shortly.
 782 POP server should be defined in `mail-source-primary-source' (which is
 783 preferred) or `mail-sources'.  You may use it for the POP-before-SMTP
 784 authentication.  To do that, you need to set the option
 785 `message-send-mail-function' to `message-smtpmail-send-it' and put the
 786 following line in .gnus file:
 787
 788 \(add-hook 'message-send-mail-hook 'mail-source-touch-pop)
 789 "
 790   (let ((sources (if mail-source-primary-source
 791                      (list mail-source-primary-source)
 792                    mail-sources)))
 793     (while sources
 794       (if (eq 'pop (car (car sources)))
 795           (mail-source-check-pop (car sources)))
 796       (setq sources (cdr sources)))))
 797
 798 (defun mail-source-new-mail-p ()
 799   "Handler for `display-time' to indicate when new mail is available."
 800   ;; Flash (ie. ring the visible bell) if mail is available.
 801   (if (and mail-source-flash mail-source-new-mail-available)
 802       (let ((visible-bell t))
 803         (ding)))
 804   ;; Only report flag setting; flag is updated on a different schedule.
 805   mail-source-new-mail-available)
 806
 807
 808 (defvar mail-source-report-new-mail nil)
 809 (defvar mail-source-report-new-mail-timer nil)
 810 (defvar mail-source-report-new-mail-idle-timer nil)
 811
 812 (eval-when-compile
 813   (if (featurep 'xemacs)
 814       (require 'itimer)
 815     (require 'timer)))
 816
 817 (defun mail-source-start-idle-timer ()
 818   ;; Start our idle timer if necessary, so we delay the check until the
 819   ;; user isn't typing.
 820   (unless mail-source-report-new-mail-idle-timer
 821     (setq mail-source-report-new-mail-idle-timer
 822           (run-with-idle-timer
 823            mail-source-idle-time-delay
 824            nil
 825            (lambda ()
 826              (unwind-protect
 827                  (mail-source-check-pop mail-source-primary-source)
 828                (setq mail-source-report-new-mail-idle-timer nil)))))
 829     ;; Since idle timers created when Emacs is already in the idle
 830     ;; state don't get activated until Emacs _next_ becomes idle, we
 831     ;; need to force our timer to be considered active now.  We do
 832     ;; this by being naughty and poking the timer internals directly
 833     ;; (element 0 of the vector is nil if the timer is active).
 834     (aset mail-source-report-new-mail-idle-timer 0 nil)))
 835
 836 (defun mail-source-report-new-mail (arg)
 837   "Toggle whether to report when new mail is available.
 838 This only works when `display-time' is enabled."
 839   (interactive "P")
 840   (if (not mail-source-primary-source)
 841       (error "Need to set `mail-source-primary-source' to check for new mail"))
 842   (let ((on (if (null arg)
 843                 (not mail-source-report-new-mail)
 844               (> (prefix-numeric-value arg) 0))))
 845     (setq mail-source-report-new-mail on)
 846     (and mail-source-report-new-mail-timer
 847          (nnheader-cancel-timer mail-source-report-new-mail-timer))
 848     (and mail-source-report-new-mail-idle-timer
 849          (nnheader-cancel-timer mail-source-report-new-mail-idle-timer))
 850     (setq mail-source-report-new-mail-timer nil)
 851     (setq mail-source-report-new-mail-idle-timer nil)
 852     (if on
 853         (progn
 854           (require 'time)
 855           ;; display-time-mail-function is an Emacs 21 feature.
 856           (setq display-time-mail-function #'mail-source-new-mail-p)
 857           ;; Set up the main timer.
 858           (setq mail-source-report-new-mail-timer
 859                 (nnheader-run-at-time
 860                  (* 60 mail-source-report-new-mail-interval)
 861                  (* 60 mail-source-report-new-mail-interval)
 862                  #'mail-source-start-idle-timer))
 863           ;; When you get new mail, clear "Mail" from the mode line.
 864           (add-hook 'nnmail-post-get-new-mail-hook
 865                     'display-time-event-handler)
 866           (message "Mail check enabled"))
 867       (setq display-time-mail-function nil)
 868       (remove-hook 'nnmail-post-get-new-mail-hook
 869                    'display-time-event-handler)
 870       (message "Mail check disabled"))))
 871
 872 (defun mail-source-fetch-maildir (source callback)
 873   "Fetcher for maildir sources."
 874   (mail-source-bind (maildir source)
 875     (let ((found 0)
 876           mail-source-string)
 877       (unless (string-match "/$" path)
 878         (setq path (concat path "/")))
 879       (dolist (subdir subdirs)
 880         (when (file-directory-p (concat path subdir))
 881           (setq mail-source-string (format "maildir:%s%s" path subdir))
 882           (dolist (file (directory-files (concat path subdir) t))
 883             (when (and (not (file-directory-p file))
 884                        (not (if function
 885                                 (funcall function file mail-source-crash-box)
 886                               (let ((coding-system-for-write
 887                                      mm-text-coding-system)
 888                                     (coding-system-for-read
 889                                      mm-text-coding-system))
 890                                 (with-temp-file mail-source-crash-box
 891                                   (insert-file-contents file)
 892                                   (goto-char (point-min))
 893 ;;;                               ;; Unix mail format
 894 ;;;                               (unless (looking-at "\n*From ")
 895 ;;;                                 (insert "From maildir "
 896 ;;;                                         (current-time-string) "\n"))
 897 ;;;                               (while (re-search-forward "^From " nil t)
 898 ;;;                                 (replace-match ">From "))
 899 ;;;                               (goto-char (point-max))
 900 ;;;                               (insert "\n\n")
 901                                   ;; MMDF mail format
 902                                   (insert "\001\001\001\001\n"))
 903                                 (delete-file file)))))
 904               (incf found (mail-source-callback callback file))))))
 905       found)))
 906
 907 (eval-and-compile
 908   (autoload 'imap-open "imap")
 909   (autoload 'imap-authenticate "imap")
 910   (autoload 'imap-mailbox-select "imap")
 911   (autoload 'imap-mailbox-unselect "imap")
 912   (autoload 'imap-mailbox-close "imap")
 913   (autoload 'imap-search "imap")
 914   (autoload 'imap-fetch "imap")
 915   (autoload 'imap-close "imap")
 916   (autoload 'imap-error-text "imap")
 917   (autoload 'imap-message-flags-add "imap")
 918   (autoload 'imap-list-to-message-set "imap")
 919   (autoload 'imap-range-to-message-set "imap")
 920   (autoload 'nnheader-ms-strip-cr "nnheader"))
 921
 922 (defvar mail-source-imap-file-coding-system 'binary
 923   "Coding system for the crashbox made by `mail-source-fetch-imap'.")
 924
 925 (defun mail-source-fetch-imap (source callback)
 926   "Fetcher for imap sources."
 927   (mail-source-bind (imap source)
 928     (let ((from (format "%s:%s:%s" server user port))
 929           (found 0)
 930           (buf (get-buffer-create (generate-new-buffer-name " *imap source*")))
 931           (mail-source-string (format "imap:%s:%s" server mailbox))
 932           (imap-shell-program (or (list program) imap-shell-program))
 933           remove)
 934       (if (and (imap-open server port stream authentication buf)
 935                (imap-authenticate
 936                 user (or (cdr (assoc from mail-source-password-cache))
 937                          password) buf)
 938                (imap-mailbox-select mailbox nil buf))
 939           (let ((coding-system-for-write mail-source-imap-file-coding-system)
 940                 str)
 941             (with-temp-file mail-source-crash-box
 942               ;; Avoid converting 8-bit chars from inserted strings to
 943               ;; multibyte.
 944               (mm-disable-multibyte)
 945               ;; remember password
 946               (with-current-buffer buf
 947                 (when (or imap-password
 948                           (assoc from mail-source-password-cache))
 949                   (push (cons from imap-password) mail-source-password-cache)))
 950               ;; if predicate is nil, use all uids
 951               (dolist (uid (imap-search (or predicate "1:*") buf))
 952                 (when (setq str
 953                             (if (imap-capability 'IMAP4rev1 buf)
 954                                 (caddar (imap-fetch uid "BODY.PEEK[]"
 955                                                     'BODYDETAIL nil buf))
 956                               (imap-fetch uid "RFC822.PEEK" 'RFC822 nil buf)))
 957                   (push uid remove)
 958                   (insert "From imap " (current-time-string) "\n")
 959                   (save-excursion
 960                     (insert str "\n\n"))
 961                   (while (re-search-forward "^From " nil t)
 962                     (replace-match ">From "))
 963                   (goto-char (point-max))))
 964               (nnheader-ms-strip-cr))
 965             (incf found (mail-source-callback callback server))
 966             (when (and remove fetchflag)
 967               (imap-message-flags-add
 968                (imap-range-to-message-set (gnus-compress-sequence remove))
 969                fetchflag nil buf))
 970             (if dontexpunge
 971                 (imap-mailbox-unselect buf)
 972               (imap-mailbox-close nil buf))
 973             (imap-close buf))
 974         (imap-close buf)
 975         ;; We nix out the password in case the error
 976         ;; was because of a wrong password being given.
 977         (setq mail-source-password-cache
 978               (delq (assoc from mail-source-password-cache)
 979                     mail-source-password-cache))
 980         (error (imap-error-text buf)))
 981       (kill-buffer buf)
 982       found)))
 983
 984 (eval-and-compile
 985   (autoload 'webmail-fetch "webmail"))
 986
 987 (defun mail-source-fetch-webmail (source callback)
 988   "Fetch for webmail source."
 989   (mail-source-bind (webmail source)
 990     (let ((mail-source-string (format "webmail:%s:%s" subtype user))
 991           (webmail-newmail-only dontexpunge)
 992           (webmail-move-to-trash-can (not dontexpunge)))
 993       (when (eq authentication 'password)
 994         (setq password
 995               (or password
 996                   (cdr (assoc (format "webmail:%s:%s" subtype user)
 997                               mail-source-password-cache))
 998                   (mail-source-read-passwd
 999                    (format "Password for %s at %s: " user subtype))))
1000         (when (and password
1001                    (not (assoc (format "webmail:%s:%s" subtype user)
1002                                mail-source-password-cache)))
1003           (push (cons (format "webmail:%s:%s" subtype user) password)
1004                 mail-source-password-cache)))
1005       (webmail-fetch mail-source-crash-box subtype user password)
1006       (mail-source-callback callback (symbol-name subtype)))))
1007
1008 (provide 'mail-source)
1009
1010 ;;; mail-source.el ends here