cgit.sxemacs.org Git - gnus/blob - lisp/mail-source.el

   1 ;;; mail-source.el --- functions for fetching mail
   2 ;; Copyright (C) 1999, 2000, 2001, 2002 Free Software Foundation, Inc.
   3
   4 ;; Author: Lars Magne Ingebrigtsen <larsi@gnus.org>
   5 ;; Keywords: news, mail
   6
   7 ;; This file is part of GNU Emacs.
   8
   9 ;; GNU Emacs is free software; you can redistribute it and/or modify
  10 ;; it under the terms of the GNU General Public License as published by
  11 ;; the Free Software Foundation; either version 2, or (at your option)
  12 ;; any later version.
  13
  14 ;; GNU Emacs is distributed in the hope that it will be useful,
  15 ;; but WITHOUT ANY WARRANTY; without even the implied warranty of
  16 ;; MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.  See the
  17 ;; GNU General Public License for more details.
  18
  19 ;; You should have received a copy of the GNU General Public License
  20 ;; along with GNU Emacs; see the file COPYING.  If not, write to the
  21 ;; Free Software Foundation, Inc., 59 Temple Place - Suite 330,
  22 ;; Boston, MA 02111-1307, USA.
  23
  24 ;;; Commentary:
  25
  26 ;;; Code:
  27
  28 (eval-when-compile
  29   (require 'cl)
  30   (require 'imap)
  31   (eval-when-compile (defvar display-time-mail-function)))
  32 (eval-and-compile
  33   (autoload 'pop3-movemail "pop3")
  34   (autoload 'pop3-get-message-count "pop3")
  35   (autoload 'nnheader-cancel-timer "nnheader")
  36   (autoload 'nnheader-run-at-time "nnheader"))
  37 (require 'format-spec)
  38 (require 'mm-util)
  39 (require 'message) ;; for `message-directory'
  40
  41 (defgroup mail-source nil
  42   "The mail-fetching library."
  43   :version "21.1"
  44   :group 'gnus)
  45
  46 ;; Define these at compile time to avoid dragging in imap always.
  47 (defconst mail-source-imap-authenticators
  48   (eval-when-compile
  49     (mapcar (lambda (a)
  50               (list 'const (car a)))
  51      imap-authenticator-alist)))
  52 (defconst mail-source-imap-streams
  53   (eval-when-compile
  54     (mapcar (lambda (a)
  55               (list 'const (car a)))
  56      imap-stream-alist)))
  57
  58 (defcustom mail-sources nil
  59   "*Where the mail backends will look for incoming mail.
  60 This variable is a list of mail source specifiers.
  61 See Info node `(gnus)Mail Source Specifiers'."
  62   :group 'mail-source
  63   :type `(repeat
  64           (choice :format "%[Value Menu%] %v"
  65                   :value (file)
  66                   (cons :tag "Spool file"
  67                         (const :format "" file)
  68                         (checklist :tag "Options" :greedy t
  69                                    (group :inline t
  70                                           (const :format "" :value :path)
  71                                           file)))
  72                   (cons :tag "Several files in a directory"
  73                         (const :format "" directory)
  74                         (checklist :tag "Options" :greedy t
  75                                    (group :inline t
  76                                           (const :format "" :value :path)
  77                                           (directory :tag "Path"))
  78                                    (group :inline t
  79                                           (const :format "" :value :suffix)
  80                                           (string :tag "Suffix"))
  81                                    (group :inline t
  82                                           (const :format "" :value :predicate)
  83                                           (function :tag "Predicate"))
  84                                    (group :inline t
  85                                           (const :format "" :value :prescript)
  86                                           (string :tag "Prescript"))
  87                                    (group :inline t
  88                                           (const :format "" :value :postscript)
  89                                           (string :tag "Postscript"))
  90                                    (group :inline t
  91                                           (const :format "" :value :plugged)
  92                                           (boolean :tag "Plugged"))))
  93                   (cons :tag "POP3 server"
  94                         (const :format "" pop)
  95                         (checklist :tag "Options" :greedy t
  96                                    (group :inline t
  97                                           (const :format "" :value :server)
  98                                           (string :tag "Server"))
  99                                    (group :inline t
 100                                           (const :format "" :value :port)
 101                                           (choice :tag "Port"
 102                                                   :value "pop3"
 103                                                   (number :format "%v")
 104                                                   (string :format "%v")))
 105                                    (group :inline t
 106                                           (const :format "" :value :user)
 107                                           (string :tag "User"))
 108                                    (group :inline t
 109                                           (const :format "" :value :password)
 110                                           (string :tag "Password"))
 111                                    (group :inline t
 112                                           (const :format "" :value :program)
 113                                           (string :tag "Program"))
 114                                    (group :inline t
 115                                           (const :format "" :value :prescript)
 116                                           (string :tag "Prescript"))
 117                                    (group :inline t
 118                                           (const :format "" :value :postscript)
 119                                           (string :tag "Postscript"))
 120                                    (group :inline t
 121                                           (const :format "" :value :function)
 122                                           (function :tag "Function"))
 123                                    (group :inline t
 124                                           (const :format ""
 125                                                  :value :authentication)
 126                                           (choice :tag "Authentication"
 127                                                   :value apop
 128                                                   (const password)
 129                                                   (const apop)))
 130                                    (group :inline t
 131                                           (const :format "" :value :plugged)
 132                                           (boolean :tag "Plugged"))))
 133                   (cons :tag "Maildir (qmail, postfix...)"
 134                         (const :format "" maildir)
 135                         (checklist :tag "Options" :greedy t
 136                                    (group :inline t
 137                                           (const :format "" :value :path)
 138                                           (directory :tag "Path"))
 139                                    (group :inline t
 140                                           (const :format "" :value :plugged)
 141                                           (boolean :tag "Plugged"))))
 142                   (cons :tag "IMAP server"
 143                         (const :format "" imap)
 144                         (checklist :tag "Options" :greedy t
 145                                    (group :inline t
 146                                           (const :format "" :value :server)
 147                                           (string :tag "Server"))
 148                                    (group :inline t
 149                                           (const :format "" :value :port)
 150                                           (choice :tag "Port"
 151                                                   :value 143
 152                                                   number string))
 153                                    (group :inline t
 154                                           (const :format "" :value :user)
 155                                           (string :tag "User"))
 156                                    (group :inline t
 157                                           (const :format "" :value :password)
 158                                           (string :tag "Password"))
 159                                    (group :inline t
 160                                           (const :format "" :value :stream)
 161                                           (choice :tag "Stream"
 162                                                   :value network
 163                                                   ,@mail-source-imap-streams))
 164                                    (group :inline t
 165                                           (const :format "" :value :program)
 166                                           (string :tag "Program"))
 167                                    (group :inline t
 168                                           (const :format ""
 169                                                  :value :authenticator)
 170                                           (choice :tag "Authenticator"
 171                                                   :value login
 172                                                   ,@mail-source-imap-authenticators))
 173                                    (group :inline t
 174                                           (const :format "" :value :mailbox)
 175                                           (string :tag "Mailbox"
 176                                                   :value "INBOX"))
 177                                    (group :inline t
 178                                           (const :format "" :value :predicate)
 179                                           (string :tag "Predicate"
 180                                                   :value "UNSEEN UNDELETED"))
 181                                    (group :inline t
 182                                           (const :format "" :value :fetchflag)
 183                                           (string :tag "Fetchflag"
 184                                                   :value  "\\Deleted"))
 185                                    (group :inline t
 186                                           (const :format ""
 187                                                  :value :dontexpunge)
 188                                           (boolean :tag "Dontexpunge"))
 189                                    (group :inline t
 190                                           (const :format "" :value :plugged)
 191                                           (boolean :tag "Plugged"))))
 192                   (cons :tag "Webmail server"
 193                         (const :format "" webmail)
 194                         (checklist :tag "Options" :greedy t
 195                                    (group :inline t
 196                                          (const :format "" :value :subtype)
 197                                          ;; Should be generated from
 198                                          ;; `webmail-type-definition', but we
 199                                          ;; can't require webmail without W3.
 200                                          (choice :tag "Subtype"
 201                                                  :value hotmail
 202                                                  (const hotmail)
 203                                                  (const yahoo)
 204                                                  (const netaddress)
 205                                                  (const netscape)
 206                                                  (const my-deja)))
 207                                    (group :inline t
 208                                           (const :format "" :value :user)
 209                                           (string :tag "User"))
 210                                    (group :inline t
 211                                           (const :format "" :value :password)
 212                                           (string :tag "Password"))
 213                                    (group :inline t
 214                                           (const :format ""
 215                                                  :value :dontexpunge)
 216                                           (boolean :tag "Dontexpunge"))
 217                                    (group :inline t
 218                                           (const :format "" :value :plugged)
 219                                           (boolean :tag "Plugged")))))))
 220
 221 (defcustom mail-source-primary-source nil
 222   "*Primary source for incoming mail.
 223 If non-nil, this maildrop will be checked periodically for new mail."
 224   :group 'mail-source
 225   :type 'sexp)
 226
 227 (defcustom mail-source-flash t
 228   "*If non-nil, flash periodically when mail is available."
 229   :group 'mail-source
 230   :type 'boolean)
 231
 232 (defcustom mail-source-crash-box "~/.emacs-mail-crash-box"
 233   "File where mail will be stored while processing it."
 234   :group 'mail-source
 235   :type 'file)
 236
 237 (defcustom mail-source-directory message-directory
 238   "Directory where files (if any) will be stored."
 239   :group 'mail-source
 240   :type 'directory)
 241
 242 (defcustom mail-source-default-file-modes 384
 243   "Set the mode bits of all new mail files to this integer."
 244   :group 'mail-source
 245   :type 'integer)
 246
 247 (defcustom mail-source-delete-incoming nil
 248   "*If non-nil, delete incoming files after handling."
 249   :group 'mail-source
 250   :type 'boolean)
 251
 252 (defcustom mail-source-incoming-file-prefix "Incoming"
 253   "Prefix for file name for storing incoming mail"
 254   :group 'mail-source
 255   :type 'string)
 256
 257 (defcustom mail-source-report-new-mail-interval 5
 258   "Interval in minutes between checks for new mail."
 259   :group 'mail-source
 260   :type 'number)
 261
 262 (defcustom mail-source-idle-time-delay 5
 263   "Number of idle seconds to wait before checking for new mail."
 264   :group 'mail-source
 265   :type 'number)
 266
 267 (defcustom mail-source-movemail-program nil
 268   "If non-nil, name of program for fetching new mail."
 269   :group 'mail-source
 270   :type '(choice (const nil) string))
 271
 272 ;;; Internal variables.
 273
 274 (defvar mail-source-string ""
 275   "A dynamically bound string that says what the current mail source is.")
 276
 277 (defvar mail-source-new-mail-available nil
 278   "Flag indicating when new mail is available.")
 279
 280 (eval-and-compile
 281   (defvar mail-source-common-keyword-map
 282     '((:plugged))
 283     "Mapping from keywords to default values.
 284 Common keywords should be listed here.")
 285
 286   (defvar mail-source-keyword-map
 287     '((file
 288        (:prescript)
 289        (:prescript-delay)
 290        (:postscript)
 291        (:path (or (getenv "MAIL")
 292                   (expand-file-name (user-login-name) rmail-spool-directory))))
 293       (directory
 294        (:prescript)
 295        (:prescript-delay)
 296        (:postscript)
 297        (:path)
 298        (:suffix ".spool")
 299        (:predicate identity))
 300       (pop
 301        (:prescript)
 302        (:prescript-delay)
 303        (:postscript)
 304        (:server (getenv "MAILHOST"))
 305        (:port 110)
 306        (:user (or (user-login-name) (getenv "LOGNAME") (getenv "USER")))
 307        (:program)
 308        (:function)
 309        (:password)
 310        (:authentication password))
 311       (maildir
 312        (:path (or (getenv "MAILDIR") "~/Maildir/"))
 313        (:subdirs ("new" "cur"))
 314        (:function))
 315       (imap
 316        (:server (getenv "MAILHOST"))
 317        (:port)
 318        (:stream)
 319        (:program)
 320        (:authentication)
 321        (:user (or (user-login-name) (getenv "LOGNAME") (getenv "USER")))
 322        (:password)
 323        (:mailbox "INBOX")
 324        (:predicate "UNSEEN UNDELETED")
 325        (:fetchflag "\\Deleted")
 326        (:dontexpunge))
 327       (webmail
 328        (:subtype hotmail)
 329        (:user (or (user-login-name) (getenv "LOGNAME") (getenv "USER")))
 330        (:password)
 331        (:dontexpunge)
 332        (:authentication password)))
 333     "Mapping from keywords to default values.
 334 All keywords that can be used must be listed here."))
 335
 336 (defvar mail-source-fetcher-alist
 337   '((file mail-source-fetch-file)
 338     (directory mail-source-fetch-directory)
 339     (pop mail-source-fetch-pop)
 340     (maildir mail-source-fetch-maildir)
 341     (imap mail-source-fetch-imap)
 342     (webmail mail-source-fetch-webmail))
 343   "A mapping from source type to fetcher function.")
 344
 345 (defvar mail-source-password-cache nil)
 346
 347 (defvar mail-source-plugged t)
 348
 349 ;;; Functions
 350
 351 (eval-and-compile
 352   (defun mail-source-strip-keyword (keyword)
 353     "Strip the leading colon off the KEYWORD."
 354     (intern (substring (symbol-name keyword) 1))))
 355
 356 (eval-and-compile
 357   (defun mail-source-bind-1 (type)
 358     (let* ((defaults (cdr (assq type mail-source-keyword-map)))
 359            default bind)
 360       (while (setq default (pop defaults))
 361         (push (list (mail-source-strip-keyword (car default))
 362                     nil)
 363               bind))
 364       bind)))
 365
 366 (defmacro mail-source-bind (type-source &rest body)
 367   "Return a `let' form that binds all variables in source TYPE.
 368 TYPE-SOURCE is a list where the first element is the TYPE, and
 369 the second variable is the SOURCE.
 370 At run time, the mail source specifier SOURCE will be inspected,
 371 and the variables will be set according to it.  Variables not
 372 specified will be given default values.
 373
 374 After this is done, BODY will be executed in the scope
 375 of the `let' form.
 376
 377 The variables bound and their default values are described by
 378 the `mail-source-keyword-map' variable."
 379   `(let ,(mail-source-bind-1 (car type-source))
 380      (mail-source-set-1 ,(cadr type-source))
 381      ,@body))
 382
 383 (put 'mail-source-bind 'lisp-indent-function 1)
 384 (put 'mail-source-bind 'edebug-form-spec '(sexp body))
 385
 386 (defun mail-source-set-1 (source)
 387   (let* ((type (pop source))
 388          (defaults (cdr (assq type mail-source-keyword-map)))
 389          default value keyword)
 390     (while (setq default (pop defaults))
 391       (set (mail-source-strip-keyword (setq keyword (car default)))
 392            (if (setq value (plist-get source keyword))
 393                (mail-source-value value)
 394              (mail-source-value (cadr default)))))))
 395
 396 (eval-and-compile
 397   (defun mail-source-bind-common-1 ()
 398     (let* ((defaults mail-source-common-keyword-map)
 399            default bind)
 400       (while (setq default (pop defaults))
 401         (push (list (mail-source-strip-keyword (car default))
 402                     nil)
 403               bind))
 404       bind)))
 405
 406 (defun mail-source-set-common-1 (source)
 407   (let* ((type (pop source))
 408          (defaults mail-source-common-keyword-map)
 409          (defaults-1 (cdr (assq type mail-source-keyword-map)))
 410          default value keyword)
 411     (while (setq default (pop defaults))
 412       (set (mail-source-strip-keyword (setq keyword (car default)))
 413            (if (setq value (plist-get source keyword))
 414                (mail-source-value value)
 415              (if (setq value (assq  keyword defaults-1))
 416                  (mail-source-value (cadr value))
 417                (mail-source-value (cadr default))))))))
 418
 419 (defmacro mail-source-bind-common (source &rest body)
 420   "Return a `let' form that binds all common variables.
 421 See `mail-source-bind'."
 422   `(let ,(mail-source-bind-common-1)
 423      (mail-source-set-common-1 source)
 424      ,@body))
 425
 426 (put 'mail-source-bind-common 'lisp-indent-function 1)
 427 (put 'mail-source-bind-common 'edebug-form-spec '(sexp body))
 428
 429 (defun mail-source-value (value)
 430   "Return the value of VALUE."
 431   (cond
 432    ;; String
 433    ((stringp value)
 434     value)
 435    ;; Function
 436    ((and (listp value)
 437          (functionp (car value)))
 438     (eval value))
 439    ;; Just return the value.
 440    (t
 441     value)))
 442
 443 (defun mail-source-fetch (source callback)
 444   "Fetch mail from SOURCE and call CALLBACK zero or more times.
 445 CALLBACK will be called with the name of the file where (some of)
 446 the mail from SOURCE is put.
 447 Return the number of files that were found."
 448   (mail-source-bind-common source
 449     (if (or mail-source-plugged plugged)
 450         (save-excursion
 451           (let ((function (cadr (assq (car source) mail-source-fetcher-alist)))
 452                 (found 0))
 453             (unless function
 454               (error "%S is an invalid mail source specification" source))
 455             ;; If there's anything in the crash box, we do it first.
 456             (when (file-exists-p mail-source-crash-box)
 457               (message "Processing mail from %s..." mail-source-crash-box)
 458               (setq found (mail-source-callback
 459                            callback mail-source-crash-box)))
 460             (+ found
 461                (if (or debug-on-quit debug-on-error)
 462                    (funcall function source callback)
 463                  (condition-case err
 464                      (funcall function source callback)
 465                    (error
 466                     (unless (yes-or-no-p
 467                              (format "Mail source error (%s).  Continue? "
 468                                      (cadr err)))
 469                       (error "Cannot get new mail"))
 470                     0)))))))))
 471
 472 (eval-and-compile
 473   (if (fboundp 'make-temp-file)
 474       (defalias 'mail-source-make-complex-temp-name 'make-temp-file)
 475     (defun mail-source-make-complex-temp-name (prefix)
 476       (let ((newname (make-temp-name prefix))
 477             (newprefix prefix))
 478         (while (file-exists-p newname)
 479           (setq newprefix (concat newprefix "x"))
 480           (setq newname (make-temp-name newprefix)))
 481         newname))))
 482
 483 (defun mail-source-callback (callback info)
 484   "Call CALLBACK on the mail file, and then remove the mail file.
 485 Pass INFO on to CALLBACK."
 486   (if (or (not (file-exists-p mail-source-crash-box))
 487           (zerop (nth 7 (file-attributes mail-source-crash-box))))
 488       (progn
 489         (when (file-exists-p mail-source-crash-box)
 490           (delete-file mail-source-crash-box))
 491         0)
 492     (prog1
 493         (funcall callback mail-source-crash-box info)
 494       (when (file-exists-p mail-source-crash-box)
 495         ;; Delete or move the incoming mail out of the way.
 496         (if mail-source-delete-incoming
 497             (delete-file mail-source-crash-box)
 498           (let ((incoming
 499                  (mail-source-make-complex-temp-name
 500                   (expand-file-name
 501                    mail-source-incoming-file-prefix
 502                    mail-source-directory))))
 503             (unless (file-exists-p (file-name-directory incoming))
 504               (make-directory (file-name-directory incoming) t))
 505             (rename-file mail-source-crash-box incoming t)))))))
 506
 507 (defun mail-source-movemail (from to)
 508   "Move FROM to TO using movemail."
 509   (if (not (file-writable-p to))
 510       (error "Can't write to crash box %s.  Not moving mail" to)
 511     (let ((to (file-truename (expand-file-name to)))
 512           errors result)
 513       (setq to (file-truename to)
 514             from (file-truename from))
 515       ;; Set TO if have not already done so, and rename or copy
 516       ;; the file FROM to TO if and as appropriate.
 517       (cond
 518        ((file-exists-p to)
 519         ;; The crash box exists already.
 520         t)
 521        ((not (file-exists-p from))
 522         ;; There is no inbox.
 523         (setq to nil))
 524        ((zerop (nth 7 (file-attributes from)))
 525         ;; Empty file.
 526         (setq to nil))
 527        (t
 528         ;; If getting from mail spool directory, use movemail to move
 529         ;; rather than just renaming, so as to interlock with the
 530         ;; mailer.
 531         (unwind-protect
 532             (save-excursion
 533               (setq errors (generate-new-buffer " *mail source loss*"))
 534               (let ((default-directory "/"))
 535                 (setq result
 536                       (apply
 537                        'call-process
 538                        (append
 539                         (list
 540                          (or mail-source-movemail-program
 541                              (expand-file-name "movemail" exec-directory))
 542                          nil errors nil from to)))))
 543               (when (file-exists-p to)
 544                 (set-file-modes to mail-source-default-file-modes))
 545               (if (and (or (not (buffer-modified-p errors))
 546                            (zerop (buffer-size errors)))
 547                        (zerop result))
 548                   ;; No output => movemail won.
 549                   t
 550                 (set-buffer errors)
 551                 ;; There may be a warning about older revisions.  We
 552                 ;; ignore that.
 553                 (goto-char (point-min))
 554                 (if (search-forward "older revision" nil t)
 555                     t
 556                   ;; Probably a real error.
 557                   (subst-char-in-region (point-min) (point-max) ?\n ?\  )
 558                   (goto-char (point-max))
 559                   (skip-chars-backward " \t")
 560                   (delete-region (point) (point-max))
 561                   (goto-char (point-min))
 562                   (when (looking-at "movemail: ")
 563                     (delete-region (point-min) (match-end 0)))
 564                   ;; Result may be a signal description string.
 565                   (unless (yes-or-no-p
 566                            (format "movemail: %s (%s return).  Continue? "
 567                                    (buffer-string) result))
 568                     (error "%s" (buffer-string)))
 569                   (setq to nil)))))))
 570       (when (and errors
 571                  (buffer-name errors))
 572         (kill-buffer errors))
 573       ;; Return whether we moved successfully or not.
 574       to)))
 575
 576 (defun mail-source-movemail-and-remove (from to)
 577   "Move FROM to TO using movemail, then remove FROM if empty."
 578   (or (not (mail-source-movemail from to))
 579       (not (zerop (nth 7 (file-attributes from))))
 580       (delete-file from)))
 581
 582 (defvar mail-source-read-passwd nil)
 583 (defun mail-source-read-passwd (prompt &rest args)
 584   "Read a password using PROMPT.
 585 If ARGS, PROMPT is used as an argument to `format'."
 586   (let ((prompt
 587          (if args
 588              (apply 'format prompt args)
 589            prompt)))
 590     (unless mail-source-read-passwd
 591       (if (or (fboundp 'read-passwd) (load "passwd" t))
 592           (setq mail-source-read-passwd 'read-passwd)
 593         (unless (fboundp 'ange-ftp-read-passwd)
 594           (autoload 'ange-ftp-read-passwd "ange-ftp"))
 595         (setq mail-source-read-passwd 'ange-ftp-read-passwd)))
 596     (funcall mail-source-read-passwd prompt)))
 597
 598 (defun mail-source-fetch-with-program (program)
 599   (zerop (call-process shell-file-name nil nil nil
 600                        shell-command-switch program)))
 601
 602 (defun mail-source-run-script (script spec &optional delay)
 603   (when script
 604     (if (and (symbolp script) (fboundp script))
 605         (funcall script)
 606       (mail-source-call-script
 607        (format-spec script spec))))
 608   (when delay
 609     (sleep-for delay)))
 610
 611 (defun mail-source-call-script (script)
 612   (let ((background nil))
 613     (when (string-match "& *$" script)
 614       (setq script (substring script 0 (match-beginning 0))
 615             background 0))
 616     (call-process shell-file-name nil background nil
 617                   shell-command-switch script)))
 618
 619 ;;;
 620 ;;; Different fetchers
 621 ;;;
 622
 623 (defun mail-source-fetch-file (source callback)
 624   "Fetcher for single-file sources."
 625   (mail-source-bind (file source)
 626     (mail-source-run-script
 627      prescript (format-spec-make ?t mail-source-crash-box)
 628      prescript-delay)
 629     (let ((mail-source-string (format "file:%s" path)))
 630       (if (mail-source-movemail path mail-source-crash-box)
 631           (prog1
 632               (mail-source-callback callback path)
 633             (mail-source-run-script
 634              postscript (format-spec-make ?t mail-source-crash-box)))
 635         0))))
 636
 637 (defun mail-source-fetch-directory (source callback)
 638   "Fetcher for directory sources."
 639   (mail-source-bind (directory source)
 640     (mail-source-run-script
 641      prescript (format-spec-make ?t path)
 642      prescript-delay)
 643     (let ((found 0)
 644           (mail-source-string (format "directory:%s" path)))
 645       (dolist (file (directory-files
 646                      path t (concat (regexp-quote suffix) "$")))
 647         (when (and (file-regular-p file)
 648                    (funcall predicate file)
 649                    (mail-source-movemail file mail-source-crash-box))
 650           (incf found (mail-source-callback callback file))))
 651       (mail-source-run-script
 652        postscript (format-spec-make ?t path))
 653       found)))
 654
 655 (defun mail-source-fetch-pop (source callback)
 656   "Fetcher for single-file sources."
 657   (mail-source-bind (pop source)
 658     (mail-source-run-script
 659      prescript
 660      (format-spec-make ?p password ?t mail-source-crash-box
 661                        ?s server ?P port ?u user)
 662      prescript-delay)
 663     (let ((from (format "%s:%s:%s" server user port))
 664           (mail-source-string (format "pop:%s@%s" user server))
 665           result)
 666       (when (eq authentication 'password)
 667         (setq password
 668               (or password
 669                   (cdr (assoc from mail-source-password-cache))
 670                   (mail-source-read-passwd
 671                    (format "Password for %s at %s: " user server)))))
 672       (when server
 673         (setenv "MAILHOST" server))
 674       (setq result
 675             (cond
 676              (program
 677               (mail-source-fetch-with-program
 678                (format-spec
 679                 program
 680                 (format-spec-make ?p password ?t mail-source-crash-box
 681                                   ?s server ?P port ?u user))))
 682              (function
 683               (funcall function mail-source-crash-box))
 684              ;; The default is to use pop3.el.
 685              (t
 686               (let ((pop3-password password)
 687                     (pop3-maildrop user)
 688                     (pop3-mailhost server)
 689                     (pop3-port port)
 690                     (pop3-authentication-scheme
 691                      (if (eq authentication 'apop) 'apop 'pass)))
 692                 (if (or debug-on-quit debug-on-error)
 693                     (save-excursion (pop3-movemail mail-source-crash-box))
 694                   (condition-case err
 695                       (save-excursion (pop3-movemail mail-source-crash-box))
 696                     (error
 697                      ;; We nix out the password in case the error
 698                      ;; was because of a wrong password being given.
 699                      (setq mail-source-password-cache
 700                            (delq (assoc from mail-source-password-cache)
 701                                  mail-source-password-cache))
 702                      (signal (car err) (cdr err)))))))))
 703       (if result
 704           (progn
 705             (when (eq authentication 'password)
 706               (unless (assoc from mail-source-password-cache)
 707                 (push (cons from password) mail-source-password-cache)))
 708             (prog1
 709                 (mail-source-callback callback server)
 710               ;; Update display-time's mail flag, if relevant.
 711               (if (equal source mail-source-primary-source)
 712                   (setq mail-source-new-mail-available nil))
 713               (mail-source-run-script
 714                postscript
 715                (format-spec-make ?p password ?t mail-source-crash-box
 716                                  ?s server ?P port ?u user))))
 717         ;; We nix out the password in case the error
 718         ;; was because of a wrong password being given.
 719         (setq mail-source-password-cache
 720               (delq (assoc from mail-source-password-cache)
 721                     mail-source-password-cache))
 722         0))))
 723
 724 (defun mail-source-check-pop (source)
 725   "Check whether there is new mail."
 726   (mail-source-bind (pop source)
 727     (let ((from (format "%s:%s:%s" server user port))
 728           (mail-source-string (format "pop:%s@%s" user server))
 729           result)
 730       (when (eq authentication 'password)
 731         (setq password
 732               (or password
 733                   (cdr (assoc from mail-source-password-cache))
 734                   (mail-source-read-passwd
 735                    (format "Password for %s at %s: " user server))))
 736         (unless (assoc from mail-source-password-cache)
 737           (push (cons from password) mail-source-password-cache)))
 738       (when server
 739         (setenv "MAILHOST" server))
 740       (setq result
 741             (cond
 742              ;; No easy way to check whether mail is waiting for these.
 743              (program)
 744              (function)
 745              ;; The default is to use pop3.el.
 746              (t
 747               (let ((pop3-password password)
 748                     (pop3-maildrop user)
 749                     (pop3-mailhost server)
 750                     (pop3-port port)
 751                     (pop3-authentication-scheme
 752                      (if (eq authentication 'apop) 'apop 'pass)))
 753                 (if (or debug-on-quit debug-on-error)
 754                     (save-excursion (pop3-get-message-count))
 755                   (condition-case err
 756                       (save-excursion (pop3-get-message-count))
 757                     (error
 758                      ;; We nix out the password in case the error
 759                      ;; was because of a wrong password being given.
 760                      (setq mail-source-password-cache
 761                            (delq (assoc from mail-source-password-cache)
 762                                  mail-source-password-cache))
 763                      (signal (car err) (cdr err)))))))))
 764       (if result
 765           ;; Inform display-time that we have new mail.
 766           (setq mail-source-new-mail-available (> result 0))
 767         ;; We nix out the password in case the error
 768         ;; was because of a wrong password being given.
 769         (setq mail-source-password-cache
 770               (delq (assoc from mail-source-password-cache)
 771                     mail-source-password-cache)))
 772       result)))
 773
 774 (defun mail-source-new-mail-p ()
 775   "Handler for `display-time' to indicate when new mail is available."
 776   ;; Flash (ie. ring the visible bell) if mail is available.
 777   (if (and mail-source-flash mail-source-new-mail-available)
 778       (let ((visible-bell t))
 779         (ding)))
 780   ;; Only report flag setting; flag is updated on a different schedule.
 781   mail-source-new-mail-available)
 782
 783
 784 (defvar mail-source-report-new-mail nil)
 785 (defvar mail-source-report-new-mail-timer nil)
 786 (defvar mail-source-report-new-mail-idle-timer nil)
 787
 788 (eval-when-compile
 789   (if (featurep 'xemacs)
 790       (require 'itimer)
 791     (require 'timer)))
 792
 793 (defun mail-source-start-idle-timer ()
 794   ;; Start our idle timer if necessary, so we delay the check until the
 795   ;; user isn't typing.
 796   (unless mail-source-report-new-mail-idle-timer
 797     (setq mail-source-report-new-mail-idle-timer
 798           (run-with-idle-timer
 799            mail-source-idle-time-delay
 800            nil
 801            (lambda ()
 802              (unwind-protect
 803                  (mail-source-check-pop mail-source-primary-source)
 804                (setq mail-source-report-new-mail-idle-timer nil)))))
 805     ;; Since idle timers created when Emacs is already in the idle
 806     ;; state don't get activated until Emacs _next_ becomes idle, we
 807     ;; need to force our timer to be considered active now.  We do
 808     ;; this by being naughty and poking the timer internals directly
 809     ;; (element 0 of the vector is nil if the timer is active).
 810     (aset mail-source-report-new-mail-idle-timer 0 nil)))
 811
 812 (defun mail-source-report-new-mail (arg)
 813   "Toggle whether to report when new mail is available.
 814 This only works when `display-time' is enabled."
 815   (interactive "P")
 816   (if (not mail-source-primary-source)
 817       (error "Need to set `mail-source-primary-source' to check for new mail"))
 818   (let ((on (if (null arg)
 819                 (not mail-source-report-new-mail)
 820               (> (prefix-numeric-value arg) 0))))
 821     (setq mail-source-report-new-mail on)
 822     (and mail-source-report-new-mail-timer
 823          (nnheader-cancel-timer mail-source-report-new-mail-timer))
 824     (and mail-source-report-new-mail-idle-timer
 825          (nnheader-cancel-timer mail-source-report-new-mail-idle-timer))
 826     (setq mail-source-report-new-mail-timer nil)
 827     (setq mail-source-report-new-mail-idle-timer nil)
 828     (if on
 829         (progn
 830           (require 'time)
 831           ;; display-time-mail-function is an Emacs 21 feature.
 832           (setq display-time-mail-function #'mail-source-new-mail-p)
 833           ;; Set up the main timer.
 834           (setq mail-source-report-new-mail-timer
 835                 (nnheader-run-at-time
 836                  (* 60 mail-source-report-new-mail-interval)
 837                  (* 60 mail-source-report-new-mail-interval)
 838                  #'mail-source-start-idle-timer))
 839           ;; When you get new mail, clear "Mail" from the mode line.
 840           (add-hook 'nnmail-post-get-new-mail-hook
 841                     'display-time-event-handler)
 842           (message "Mail check enabled"))
 843       (setq display-time-mail-function nil)
 844       (remove-hook 'nnmail-post-get-new-mail-hook
 845                    'display-time-event-handler)
 846       (message "Mail check disabled"))))
 847
 848 (defun mail-source-fetch-maildir (source callback)
 849   "Fetcher for maildir sources."
 850   (mail-source-bind (maildir source)
 851     (let ((found 0)
 852           mail-source-string)
 853       (unless (string-match "/$" path)
 854         (setq path (concat path "/")))
 855       (dolist (subdir subdirs)
 856         (when (file-directory-p (concat path subdir))
 857           (setq mail-source-string (format "maildir:%s%s" path subdir))
 858           (dolist (file (directory-files (concat path subdir) t))
 859             (when (and (not (file-directory-p file))
 860                        (not (if function
 861                                 (funcall function file mail-source-crash-box)
 862                               (let ((coding-system-for-write
 863                                      mm-text-coding-system)
 864                                     (coding-system-for-read
 865                                      mm-text-coding-system))
 866                                 (with-temp-file mail-source-crash-box
 867                                   (insert-file-contents file)
 868                                   (goto-char (point-min))
 869 ;;;                               ;; Unix mail format
 870 ;;;                               (unless (looking-at "\n*From ")
 871 ;;;                                 (insert "From maildir "
 872 ;;;                                         (current-time-string) "\n"))
 873 ;;;                               (while (re-search-forward "^From " nil t)
 874 ;;;                                 (replace-match ">From "))
 875 ;;;                               (goto-char (point-max))
 876 ;;;                               (insert "\n\n")
 877                                   ;; MMDF mail format
 878                                   (insert "\001\001\001\001\n"))
 879                                 (delete-file file)))))
 880               (incf found (mail-source-callback callback file))))))
 881       found)))
 882
 883 (eval-and-compile
 884   (autoload 'imap-open "imap")
 885   (autoload 'imap-authenticate "imap")
 886   (autoload 'imap-mailbox-select "imap")
 887   (autoload 'imap-mailbox-unselect "imap")
 888   (autoload 'imap-mailbox-close "imap")
 889   (autoload 'imap-search "imap")
 890   (autoload 'imap-fetch "imap")
 891   (autoload 'imap-close "imap")
 892   (autoload 'imap-error-text "imap")
 893   (autoload 'imap-message-flags-add "imap")
 894   (autoload 'imap-list-to-message-set "imap")
 895   (autoload 'imap-range-to-message-set "imap")
 896   (autoload 'nnheader-ms-strip-cr "nnheader"))
 897
 898 (defvar mail-source-imap-file-coding-system 'binary
 899   "Coding system for the crashbox made by `mail-source-fetch-imap'.")
 900
 901 (defun mail-source-fetch-imap (source callback)
 902   "Fetcher for imap sources."
 903   (mail-source-bind (imap source)
 904     (let ((from (format "%s:%s:%s" server user port))
 905           (found 0)
 906           (buf (get-buffer-create (generate-new-buffer-name " *imap source*")))
 907           (mail-source-string (format "imap:%s:%s" server mailbox))
 908           (imap-shell-program (or (list program) imap-shell-program))
 909           remove)
 910       (if (and (imap-open server port stream authentication buf)
 911                (imap-authenticate
 912                 user (or (cdr (assoc from mail-source-password-cache))
 913                          password) buf)
 914                (imap-mailbox-select mailbox nil buf))
 915           (let ((coding-system-for-write mail-source-imap-file-coding-system)
 916                 str)
 917             (with-temp-file mail-source-crash-box
 918               ;; Avoid converting 8-bit chars from inserted strings to
 919               ;; multibyte.
 920               (mm-disable-multibyte)
 921               ;; remember password
 922               (with-current-buffer buf
 923                 (when (or imap-password
 924                           (assoc from mail-source-password-cache))
 925                   (push (cons from imap-password) mail-source-password-cache)))
 926               ;; if predicate is nil, use all uids
 927               (dolist (uid (imap-search (or predicate "1:*") buf))
 928                 (when (setq str
 929                             (if (imap-capability 'IMAP4rev1 buf)
 930                                 (caddar (imap-fetch uid "BODY.PEEK[]"
 931                                                     'BODYDETAIL nil buf))
 932                               (imap-fetch uid "RFC822.PEEK" 'RFC822 nil buf)))
 933                   (push uid remove)
 934                   (insert "From imap " (current-time-string) "\n")
 935                   (save-excursion
 936                     (insert str "\n\n"))
 937                   (while (re-search-forward "^From " nil t)
 938                     (replace-match ">From "))
 939                   (goto-char (point-max))))
 940               (nnheader-ms-strip-cr))
 941             (incf found (mail-source-callback callback server))
 942             (when (and remove fetchflag)
 943               (imap-message-flags-add
 944                (imap-range-to-message-set (gnus-compress-sequence remove))
 945                fetchflag nil buf))
 946             (if dontexpunge
 947                 (imap-mailbox-unselect buf)
 948               (imap-mailbox-close nil buf))
 949             (imap-close buf))
 950         (imap-close buf)
 951         ;; We nix out the password in case the error
 952         ;; was because of a wrong password being given.
 953         (setq mail-source-password-cache
 954               (delq (assoc from mail-source-password-cache)
 955                     mail-source-password-cache))
 956         (error (imap-error-text buf)))
 957       (kill-buffer buf)
 958       found)))
 959
 960 (eval-and-compile
 961   (autoload 'webmail-fetch "webmail"))
 962
 963 (defun mail-source-fetch-webmail (source callback)
 964   "Fetch for webmail source."
 965   (mail-source-bind (webmail source)
 966     (let ((mail-source-string (format "webmail:%s:%s" subtype user))
 967           (webmail-newmail-only dontexpunge)
 968           (webmail-move-to-trash-can (not dontexpunge)))
 969       (when (eq authentication 'password)
 970         (setq password
 971               (or password
 972                   (cdr (assoc (format "webmail:%s:%s" subtype user)
 973                               mail-source-password-cache))
 974                   (mail-source-read-passwd
 975                    (format "Password for %s at %s: " user subtype))))
 976         (when (and password
 977                    (not (assoc (format "webmail:%s:%s" subtype user)
 978                                mail-source-password-cache)))
 979           (push (cons (format "webmail:%s:%s" subtype user) password)
 980                 mail-source-password-cache)))
 981       (webmail-fetch mail-source-crash-box subtype user password)
 982       (mail-source-callback callback (symbol-name subtype)))))
 983
 984 (provide 'mail-source)
 985
 986 ;;; mail-source.el ends here