cgit.sxemacs.org Git - gnus/blob - lisp/mail-header.el

   1 ;;; mail-header.el --- Mail header parsing, merging, formatting
   2
   3 ;; Copyright (C) 1996 by Free Software Foundation, Inc.
   4
   5 ;; Author: Erik Naggum <erik@arcana.naggum.no>
   6 ;; Keywords: tools, mail, news
   7
   8 ;; This file is part of GNU Emacs.
   9
  10 ;; GNU Emacs is free software; you can redistribute it and/or modify
  11 ;; it under the terms of the GNU General Public License as published by
  12 ;; the Free Software Foundation; either version 2, or (at your option)
  13 ;; any later version.
  14
  15 ;; GNU Emacs is distributed in the hope that it will be useful,
  16 ;; but WITHOUT ANY WARRANTY; without even the implied warranty of
  17 ;; MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.  See the
  18 ;; GNU General Public License for more details.
  19
  20 ;; You should have received a copy of the GNU General Public License
  21 ;; along with GNU Emacs; see the file COPYING.  If not, write to
  22 ;; the Free Software Foundation, Inc., 59 Temple Place - Suite 330,
  23 ;; Boston, MA 02111-1307, USA.
  24
  25 ;;; Commentary:
  26
  27 ;; This package provides an abstraction to RFC822-style messages, used in
  28 ;; mail news, and some other systems.  The simple syntactic rules for such
  29 ;; headers, such as quoting and line folding, are routinely reimplemented
  30 ;; in many individual packages.  This package removes the need for this
  31 ;; redundancy by representing message headers as association lists,
  32 ;; offering functions to extract the set of headers from a message, to
  33 ;; parse individual headers, to merge sets of headers, and to format a set
  34 ;; of headers.
  35
  36 ;; The car of each element in the message-header alist is a symbol whose
  37 ;; print name is the name of the header, in all lower-case.  The cdr of an
  38 ;; element depends on the operation.  After extracting headers from a
  39 ;; messge, it is a string, the value of the header.  An extracted set of
  40 ;; headers may be parsed further, which may turn it into a list, whose car
  41 ;; is the original value and whose subsequent elements depend on the
  42 ;; header.  For formatting, it is evaluated to obtain the strings to be
  43 ;; inserted.  For merging, one set of headers consists of strings, while
  44 ;; the other set will be evaluated with the symbols in the first set of
  45 ;; headers bound to their respective values.
  46
  47 ;;; Code:
  48
  49 (defun mail-header-extract ()
  50   "Extract headers from current buffer after point.
  51 Returns a header alist, where each element is a cons cell (name . value),
  52 where NAME is a symbol, and VALUE is the string value of the header having
  53 that name."
  54   (let ((message-headers ()) (top (point))
  55         start end)
  56     (while (and (setq start (point))
  57                 (> (skip-chars-forward "^\0- :") 0)
  58                 (= (following-char) ?:)
  59                 (setq end (point))
  60                 (progn (forward-char)
  61                        (> (skip-chars-forward " \t") 0)))
  62       (let ((header (intern (downcase (buffer-substring start end))))
  63             (value (list (buffer-substring
  64                           (point) (progn (end-of-line) (point))))))
  65         (while (progn (forward-char) (> (skip-chars-forward " \t") 0))
  66           (push (buffer-substring (point) (progn (end-of-line) (point)))
  67                 value))
  68         (push (if (cdr value)
  69                   (cons header (mapconcat #'identity (nreverse value) " "))
  70                   (cons header (car value)))
  71               message-headers)))
  72     (goto-char top)
  73     (nreverse message-headers)))
  74
  75 (defun mail-header-extract-no-properties ()
  76   "Extract headers from current buffer after point, without properties.
  77 Returns a header alist, where each element is a cons cell (name . value),
  78 where NAME is a symbol, and VALUE is the string value of the header having
  79 that name."
  80   (mapcar
  81    (lambda (elt)
  82      (set-text-properties 0 (length (cdr elt)) nil (cdr elt))
  83      elt)
  84    (mail-header-extract)))
  85
  86 (defun mail-header-parse (parsing-rules headers)
  87   "Apply PARSING-RULES to HEADERS.
  88 PARSING-RULES is an alist whose keys are header names (symbols) and whose
  89 value is a parsing function.  The function takes one argument, a string,
  90 and return a list of values, which will destructively replace the value
  91 associated with the key in HEADERS, after being prepended with the original
  92 value."
  93   (dolist (rule parsing-rules)
  94     (let ((header (assq (car rule) headers)))
  95       (when header
  96         (if (consp (cdr header))
  97             (setf (cddr header) (funcall (cdr rule) (cadr header)))
  98           (setf (cdr header)
  99                 (cons (cdr header) (funcall (cdr rule) (cdr header))))))))
 100   headers)
 101
 102 (defsubst mail-header (header &optional header-alist)
 103   "Return the value associated with header HEADER in HEADER-ALIST.
 104 If the value is a string, it is the original value of the header.  If the
 105 value is a list, its first element is the original value of the header,
 106 with any subsequent elements bing the result of parsing the value.
 107 If HEADER-ALIST is nil, the dynamically bound variable `headers' is used."
 108   (cdr (assq header (or header-alist headers))))
 109
 110 (defun mail-header-set (header value &optional header-alist)
 111   "Set the value associated with header HEADER to VALUE in HEADER-ALIST.
 112 HEADER-ALIST defaults to the dynamically bound variable `headers' if nil.
 113 See `mail-header' for the semantics of VALUE."
 114   (let* ((alist (or header-alist headers))
 115         (entry (assq header alist)))
 116     (if entry
 117         (setf (cdr entry) value)
 118         (nconc alist (list (cons header value)))))
 119   value)
 120
 121 (defsetf mail-header (header &optional header-alist) (value)
 122   `(mail-header-set ,header ,value ,header-alist))
 123
 124 (defun mail-header-merge (merge-rules headers)
 125   "Return a new header alist with MERGE-RULES applied to HEADERS.
 126 MERGE-RULES is an alist whose keys are header names (symbols) and whose
 127 values are forms to evaluate, the results of which are the new headers.  It
 128 should be a string or a list of string.  The first element may be nil to
 129 denote that the formatting functions must use the remaining elements, or
 130 skip the header altogether if there are no other elements.
 131   The macro `mail-header' can be used to access headers in HEADERS."
 132   (mapcar
 133    (lambda (rule)
 134      (cons (car rule) (eval (cdr rule))))
 135    merge-rules))
 136
 137 (defvar mail-header-format-function
 138   (lambda (header value)
 139     "Function to format headers without a specified formatting function."
 140     (insert (capitalize (symbol-name header))
 141             ": "
 142             (if (consp value) (car value) value)
 143             "\n")))
 144
 145 (defun mail-header-format (format-rules headers)
 146   "Use FORMAT-RULES to format HEADERS and insert into current buffer.
 147 FORMAT-RULES is an alist whose keys are header names (symbols), and whose
 148 values are functions that format the header, the results of which are
 149 inserted, unless it is nil.  The function takes two arguments, the header
 150 symbol, and the value of that header.  If the function itself is nil, the
 151 default action is to insert the value of the header, unless it is nil.
 152 The headers are inserted in the order of the FORMAT-RULES.
 153 A key of t represents any otherwise unmentioned headers.
 154 A key of nil has as its value a list of defaulted headers to ignore."
 155   (let ((ignore (append (cdr (assq nil format-rules))
 156                         (mapcar #'car format-rules))))
 157     (dolist (rule format-rules)
 158       (let* ((header (car rule))
 159             (value (mail-header header)))
 160         (cond ((null header) 'ignore)
 161               ((eq header t)
 162                (dolist (defaulted headers)
 163                  (unless (memq (car defaulted) ignore)
 164                    (let* ((header (car defaulted))
 165                           (value (cdr defaulted)))
 166                      (if (cdr rule)
 167                          (funcall (cdr rule) header value)
 168                          (funcall mail-header-format-function header value))))))
 169               (value
 170                (if (cdr rule)
 171                    (funcall (cdr rule) header value)
 172                    (funcall mail-header-format-function header value))))))
 173     (insert "\n")))
 174
 175 (provide 'mail-header)
 176
 177 ;;; mail-header.el ends here