cgit.sxemacs.org Git - gnus/blob - lisp/gnus-xmas.el

   1 ;;; gnus-xmas.el --- Gnus functions for XEmacs
   2 ;; Copyright (C) 1995,96,97 Free Software Foundation, Inc.
   3
   4 ;; Author: Lars Magne Ingebrigtsen <larsi@ifi.uio.no>
   5 ;; Keywords: news
   6
   7 ;; This file is part of GNU Emacs.
   8
   9 ;; GNU Emacs is free software; you can redistribute it and/or modify
  10 ;; it under the terms of the GNU General Public License as published by
  11 ;; the Free Software Foundation; either version 2, or (at your option)
  12 ;; any later version.
  13
  14 ;; GNU Emacs is distributed in the hope that it will be useful,
  15 ;; but WITHOUT ANY WARRANTY; without even the implied warranty of
  16 ;; MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.  See the
  17 ;; GNU General Public License for more details.
  18
  19 ;; You should have received a copy of the GNU General Public License
  20 ;; along with GNU Emacs; see the file COPYING.  If not, write to the
  21 ;; Free Software Foundation, Inc., 59 Temple Place - Suite 330,
  22 ;; Boston, MA 02111-1307, USA.
  23
  24 ;;; Commentary:
  25
  26 ;;; Code:
  27
  28 (require 'text-props)
  29 (defvar menu-bar-mode (featurep 'menubar))
  30 (require 'messagexmas)
  31
  32 (defvar gnus-xmas-glyph-directory nil
  33   "*Directory where Gnus logos and icons are located.
  34 If this variable is nil, Gnus will try to locate the directory
  35 automatically.")
  36
  37 (defvar gnus-xmas-logo-color-alist
  38   '((flame "#cc3300" "#ff2200")
  39     (pine "#c0cc93" "#f8ffb8")
  40     (moss "#a1cc93" "#d2ffb8")
  41     (irish "#04cc90" "#05ff97")
  42     (sky "#049acc" "#05deff")
  43     (tin "#6886cc" "#82b6ff")
  44     (velvet "#7c68cc" "#8c82ff")
  45     (grape "#b264cc" "#cf7df")
  46     (labia "#cc64c2" "#fd7dff")
  47     (berry "#cc6485" "#ff7db5")
  48     (neutral "#b4b4b4" "#878787")
  49     (september "#bf9900" "#ffcc00"))
  50   "Color alist used for the Gnus logo.")
  51
  52 (defvar gnus-xmas-logo-color-style 'flame
  53   "Color styles used for the Gnus logo.")
  54
  55 (defvar gnus-xmas-logo-colors
  56   (cdr (assq gnus-xmas-logo-color-style gnus-xmas-logo-color-alist))
  57   "Colors used for the Gnus logo.")
  58
  59 (defvar gnus-article-x-face-command
  60   (if (featurep 'xface)
  61       'gnus-xmas-article-display-xface
  62     "{ echo '/* Width=48, Height=48 */'; uncompface; } | icontopbm | xv -quit -")
  63   "String or function to be executed to display an X-Face header.
  64 If it is a string, the command will be executed in a sub-shell
  65 asynchronously.  The compressed face will be piped to this command.")
  66
  67 ;;; Internal variables.
  68
  69 ;; Don't warn about these undefined variables.
  70
  71 (defvar gnus-group-mode-hook)
  72 (defvar gnus-summary-mode-hook)
  73 (defvar gnus-article-mode-hook)
  74
  75 ;;defined in gnus.el
  76 (defvar gnus-active-hashtb)
  77 (defvar gnus-article-buffer)
  78 (defvar gnus-auto-center-summary)
  79 (defvar gnus-buffer-list)
  80 (defvar gnus-current-headers)
  81 (defvar gnus-level-killed)
  82 (defvar gnus-level-zombie)
  83 (defvar gnus-newsgroup-bookmarks)
  84 (defvar gnus-newsgroup-dependencies)
  85 (defvar gnus-newsgroup-selected-overlay)
  86 (defvar gnus-newsrc-hashtb)
  87 (defvar gnus-read-mark)
  88 (defvar gnus-refer-article-method)
  89 (defvar gnus-reffed-article-number)
  90 (defvar gnus-unread-mark)
  91 (defvar gnus-version)
  92 (defvar gnus-view-pseudos)
  93 (defvar gnus-view-pseudos-separately)
  94 (defvar gnus-visual)
  95 (defvar gnus-zombie-list)
  96 ;;defined in gnus-msg.el
  97 (defvar gnus-article-copy)
  98 (defvar gnus-check-before-posting)
  99 ;;defined in gnus-vis.el
 100 (defvar gnus-article-button-face)
 101 (defvar gnus-article-mouse-face)
 102 (defvar gnus-summary-selected-face)
 103 (defvar gnus-group-reading-menu)
 104 (defvar gnus-group-group-menu)
 105 (defvar gnus-group-misc-menu)
 106 (defvar gnus-summary-article-menu)
 107 (defvar gnus-summary-thread-menu)
 108 (defvar gnus-summary-misc-menu)
 109 (defvar gnus-summary-post-menu)
 110 (defvar gnus-summary-kill-menu)
 111 (defvar gnus-article-article-menu)
 112 (defvar gnus-article-treatment-menu)
 113 (defvar gnus-mouse-2)
 114 (defvar standard-display-table)
 115 (defvar gnus-tree-minimize-window)
 116
 117 (defun gnus-xmas-set-text-properties (start end props &optional buffer)
 118   "You should NEVER use this function.  It is ideologically blasphemous.
 119 It is provided only to ease porting of broken FSF Emacs programs."
 120   (if (stringp buffer)
 121       nil
 122     (map-extents (lambda (extent ignored)
 123                    (remove-text-properties
 124                     start end
 125                     (list (extent-property extent 'text-prop) nil)
 126                     buffer))
 127                  buffer start end nil nil 'text-prop)
 128     (gnus-add-text-properties start end props buffer)))
 129
 130 (defun gnus-xmas-highlight-selected-summary ()
 131   ;; Highlight selected article in summary buffer
 132   (when gnus-summary-selected-face
 133     (when gnus-newsgroup-selected-overlay
 134       (delete-extent gnus-newsgroup-selected-overlay))
 135     (setq gnus-newsgroup-selected-overlay
 136           (make-extent (gnus-point-at-bol) (gnus-point-at-eol)))
 137     (set-extent-face gnus-newsgroup-selected-overlay
 138                      gnus-summary-selected-face)))
 139
 140 (defvar gnus-xmas-force-redisplay nil
 141   "If non-nil, force a redisplay before recentering the summary buffer.
 142 This is ugly, but it works around a bug in `window-displayed-height'.")
 143
 144 (defun gnus-xmas-switch-horizontal-scrollbar-off ()
 145   (when (featurep 'scrollbar)
 146     (set-specifier scrollbar-height (cons (current-buffer) 0))))
 147
 148 (defun gnus-xmas-summary-recenter ()
 149   "\"Center\" point in the summary window.
 150 If `gnus-auto-center-summary' is nil, or the article buffer isn't
 151 displayed, no centering will be performed."
 152   ;; Suggested by earle@mahendo.JPL.NASA.GOV (Greg Earle).
 153   ;; Recenter only when requested.  Suggested by popovich@park.cs.columbia.edu.
 154   ;; Force redisplay to get properly computed window height.
 155   (when gnus-xmas-force-redisplay
 156     (sit-for 0))
 157   (when gnus-auto-center-summary
 158     (let* ((height (if (fboundp 'window-displayed-height)
 159                        (window-displayed-height)
 160                      (- (window-height) 2)))
 161            (top (cond ((< height 4) 0)
 162                       ((< height 7) 1)
 163                       (t 2)))
 164            (bottom (save-excursion (goto-char (point-max))
 165                                    (forward-line (- height))
 166                                    (point)))
 167            (window (get-buffer-window (current-buffer))))
 168       (when (get-buffer-window gnus-article-buffer)
 169         ;; Only do recentering when the article buffer is displayed,
 170         ;; Set the window start to either `bottom', which is the biggest
 171         ;; possible valid number, or the second line from the top,
 172         ;; whichever is the least.
 173         (set-window-start
 174          window (min bottom (save-excursion (forward-line (- top)) (point)))))
 175       ;; Do horizontal recentering while we're at it.
 176       (when (and (get-buffer-window (current-buffer) t)
 177                  (not (eq gnus-auto-center-summary 'vertical)))
 178         (let ((selected (selected-window)))
 179           (select-window (get-buffer-window (current-buffer) t))
 180           (gnus-summary-position-point)
 181           (gnus-horizontal-recenter)
 182           (select-window selected))))))
 183
 184 (defun gnus-xmas-summary-set-display-table ()
 185   ;; Setup the display table -- like `gnus-summary-setup-display-table',
 186   ;; but done in an XEmacsish way.
 187   (let ((table (make-display-table))
 188         (default-table (specifier-instance current-display-table))
 189         (i 32))
 190     ;; Nix out all the control chars...
 191     (while (>= (setq i (1- i)) 0)
 192       (aset table i [??]))
 193     ;; ... but not newline and cr, of course.  (cr is necessary for the
 194     ;; selective display).
 195     (aset table ?\n nil)
 196     (aset table ?\r nil)
 197     ;; We nix out any glyphs over 126 that are not set already.
 198     (let ((i 256))
 199       (while (>= (setq i (1- i)) 127)
 200         ;; Only modify if the default entry is nil.
 201         (when (or (not default-table)
 202                   (not (aref default-table i)))
 203           (aset table i [??]))))
 204     ;; Can't use `set-specifier' because of a bug in 19.14 and earlier
 205     (add-spec-to-specifier current-display-table table (current-buffer) nil)))
 206
 207 (defun gnus-xmas-add-hook (hook function &optional append local)
 208   (add-hook hook function))
 209
 210 (defun gnus-xmas-add-text-properties (start end props &optional object)
 211   (add-text-properties start end props object)
 212   (put-text-property start end 'start-closed nil object))
 213
 214 (defun gnus-xmas-put-text-property (start end prop value &optional object)
 215   (put-text-property start end prop value object)
 216   (put-text-property start end 'start-closed nil object))
 217
 218 (defun gnus-xmas-extent-start-open (point)
 219   (map-extents (lambda (extent arg)
 220                  (set-extent-property extent 'start-open t))
 221                nil point (min (1+ (point)) (point-max))))
 222
 223 (defun gnus-xmas-article-push-button (event)
 224   "Check text under the mouse pointer for a callback function.
 225 If the text under the mouse pointer has a `gnus-callback' property,
 226 call it with the value of the `gnus-data' text property."
 227   (interactive "e")
 228   (set-buffer (window-buffer (event-window event)))
 229   (let* ((pos (event-closest-point event))
 230          (data (get-text-property pos 'gnus-data))
 231          (fun (get-text-property pos 'gnus-callback)))
 232     (when fun
 233       (funcall fun data))))
 234
 235 (defun gnus-xmas-move-overlay (extent start end &optional buffer)
 236   (set-extent-endpoints extent start end))
 237
 238 ;; Fixed by Christopher Davis <ckd@loiosh.kei.com>.
 239 (defun gnus-xmas-article-add-button (from to fun &optional data)
 240   "Create a button between FROM and TO with callback FUN and data DATA."
 241   (when gnus-article-button-face
 242     (gnus-overlay-put (gnus-make-overlay from to)
 243                       'face gnus-article-button-face))
 244   (gnus-add-text-properties
 245    from to
 246    (nconc
 247     (and gnus-article-mouse-face
 248          (list 'mouse-face gnus-article-mouse-face))
 249     (list 'gnus-callback fun)
 250     (and data (list 'gnus-data data))
 251     (list 'highlight t))))
 252
 253 (defun gnus-xmas-window-top-edge (&optional window)
 254   (nth 1 (window-pixel-edges window)))
 255
 256 (defun gnus-xmas-tree-minimize ()
 257   (when (and gnus-tree-minimize-window
 258              (not (one-window-p)))
 259     (let* ((window-min-height 2)
 260            (height (1+ (count-lines (point-min) (point-max))))
 261            (min (max (1- window-min-height) height))
 262            (tot (if (numberp gnus-tree-minimize-window)
 263                     (min gnus-tree-minimize-window min)
 264                   min))
 265            (win (get-buffer-window (current-buffer)))
 266            (wh (and win (1- (window-height win)))))
 267       (when (and win
 268                  (not (eq tot wh)))
 269         (let ((selected (selected-window)))
 270           (select-window win)
 271           (enlarge-window (- tot wh))
 272           (select-window selected))))))
 273
 274 ;; Select the lowest window on the frame.
 275 (defun gnus-xmas-appt-select-lowest-window ()
 276   (let* ((lowest-window (selected-window))
 277          (bottom-edge (car (cdr (cdr (cdr (window-pixel-edges))))))
 278          (last-window (previous-window))
 279          (window-search t))
 280     (while window-search
 281       (let* ((this-window (next-window))
 282              (next-bottom-edge (car (cdr (cdr (cdr
 283                                                (window-pixel-edges
 284                                                 this-window)))))))
 285         (when (< bottom-edge next-bottom-edge)
 286           (setq bottom-edge next-bottom-edge)
 287           (setq lowest-window this-window))
 288
 289         (select-window this-window)
 290         (when (eq last-window this-window)
 291           (select-window lowest-window)
 292           (setq window-search nil))))))
 293
 294 (defmacro gnus-xmas-menu-add (type &rest menus)
 295   `(gnus-xmas-menu-add-1 ',type ',menus))
 296 (put 'gnus-xmas-menu-add 'lisp-indent-function 1)
 297
 298 (defun gnus-xmas-menu-add-1 (type menus)
 299   (when (and menu-bar-mode
 300              (gnus-visual-p (intern (format "%s-menu" type)) 'menu))
 301     (while menus
 302       (easy-menu-add (symbol-value (pop menus))))))
 303
 304 (defun gnus-xmas-group-menu-add ()
 305   (gnus-xmas-menu-add group
 306     gnus-group-reading-menu gnus-group-group-menu gnus-group-misc-menu))
 307
 308 (defun gnus-xmas-summary-menu-add ()
 309   (gnus-xmas-menu-add summary
 310     gnus-summary-misc-menu gnus-summary-kill-menu
 311     gnus-summary-article-menu gnus-summary-thread-menu
 312     gnus-summary-post-menu ))
 313
 314 (defun gnus-xmas-article-menu-add ()
 315   (gnus-xmas-menu-add article
 316     gnus-article-article-menu gnus-article-treatment-menu))
 317
 318 (defun gnus-xmas-score-menu-add ()
 319   (gnus-xmas-menu-add score
 320     gnus-score-menu))
 321
 322 (defun gnus-xmas-pick-menu-add ()
 323   (gnus-xmas-menu-add pick
 324     gnus-pick-menu))
 325
 326 (defun gnus-xmas-topic-menu-add ()
 327   (gnus-xmas-menu-add topic
 328     gnus-topic-menu))
 329
 330 (defun gnus-xmas-binary-menu-add ()
 331   (gnus-xmas-menu-add binary
 332     gnus-binary-menu))
 333
 334 (defun gnus-xmas-tree-menu-add ()
 335   (gnus-xmas-menu-add tree
 336     gnus-tree-menu))
 337
 338 (defun gnus-xmas-server-menu-add ()
 339   (gnus-xmas-menu-add menu
 340     gnus-server-server-menu gnus-server-connections-menu))
 341
 342 (defun gnus-xmas-browse-menu-add ()
 343   (gnus-xmas-menu-add browse
 344     gnus-browse-menu))
 345
 346 (defun gnus-xmas-grouplens-menu-add ()
 347   (gnus-xmas-menu-add grouplens
 348     gnus-grouplens-menu))
 349
 350 (defun gnus-xmas-read-event-char ()
 351   "Get the next event."
 352   (let ((event (next-command-event)))
 353     (sit-for 0)
 354     ;; We junk all non-key events.  Is this naughty?
 355     (while (not (or (key-press-event-p event)
 356                     (button-press-event-p event)))
 357       (dispatch-event event)
 358       (setq event (next-command-event)))
 359     (cons (and (key-press-event-p event)
 360                (event-to-character event))
 361           event)))
 362
 363 (defun gnus-xmas-group-remove-excess-properties ()
 364   (let ((end (point))
 365         (beg (progn (forward-line -1) (point))))
 366     (remove-text-properties (1+ beg) end '(gnus-group nil))
 367     (remove-text-properties
 368      beg end
 369      '(gnus-topic nil gnus-topic-level nil gnus-topic-visible nil))
 370     (goto-char end)
 371     (map-extents
 372      (lambda (e ma)
 373        (set-extent-property e 'start-closed t))
 374      (current-buffer) beg end)))
 375
 376 (defun gnus-xmas-topic-remove-excess-properties ()
 377   (let ((end (point))
 378         (beg (progn (forward-line -1) (point))))
 379     (remove-text-properties beg end '(gnus-group nil gnus-unread nil))
 380     (remove-text-properties (1+ beg) end '(gnus-topic nil))
 381     (goto-char end)))
 382
 383 (defun gnus-xmas-seconds-since-epoch (date)
 384   "Return a floating point number that says how many seconds have lapsed between Jan 1 12:00:00 1970 and DATE."
 385   (let* ((tdate (mapcar (lambda (ti) (and ti (string-to-int ti)))
 386                         (timezone-parse-date date)))
 387          (ttime (mapcar (lambda (ti) (and ti (string-to-int ti)))
 388                         (timezone-parse-time
 389                          (aref (timezone-parse-date date) 3))))
 390          (edate (mapcar (lambda (ti) (and ti (string-to-int ti)))
 391                         (timezone-parse-date "Jan 1 12:00:00 1970")))
 392          (tday (- (timezone-absolute-from-gregorian
 393                    (nth 1 tdate) (nth 2 tdate) (nth 0 tdate))
 394                   (timezone-absolute-from-gregorian
 395                    (nth 1 edate) (nth 2 edate) (nth 0 edate)))))
 396     (+ (nth 2 ttime)
 397        (* (nth 1 ttime) 60)
 398        (* (float (nth 0 ttime)) 60 60)
 399        (* (float tday) 60 60 24))))
 400
 401 (defun gnus-xmas-define ()
 402   (setq gnus-mouse-2 [button2])
 403
 404   (unless (memq 'underline (face-list))
 405     (and (fboundp 'make-face)
 406          (funcall (intern "make-face") 'underline)))
 407   ;; Must avoid calling set-face-underline-p directly, because it
 408   ;; is a defsubst in emacs19, and will make the .elc files non
 409   ;; portable!
 410   (unless (face-differs-from-default-p 'underline)
 411     (funcall (intern "set-face-underline-p") 'underline t))
 412
 413   (cond
 414    ((fboundp 'char-or-char-int-p)
 415     ;; Handle both types of marks for XEmacs-20.x.
 416     (fset 'gnus-characterp 'char-or-char-int-p))
 417    ;; V19 of XEmacs, probably.
 418    (t
 419     (fset 'gnus-characterp 'characterp)))
 420
 421   (fset 'gnus-make-overlay 'make-extent)
 422   (fset 'gnus-overlay-put 'set-extent-property)
 423   (fset 'gnus-move-overlay 'gnus-xmas-move-overlay)
 424   (fset 'gnus-overlay-end 'extent-end-position)
 425   (fset 'gnus-extent-detached-p 'extent-detached-p)
 426   (fset 'gnus-add-text-properties 'gnus-xmas-add-text-properties)
 427   (fset 'gnus-put-text-property 'gnus-xmas-put-text-property)
 428
 429   (require 'text-props)
 430   (if (and (<= emacs-major-version 19)
 431            (< emacs-minor-version 14))
 432       (fset 'gnus-set-text-properties 'gnus-xmas-set-text-properties))
 433
 434   (when (fboundp 'turn-off-scroll-in-place)
 435     (add-hook 'gnus-article-mode-hook 'turn-off-scroll-in-place))
 436
 437   (unless (boundp 'standard-display-table)
 438     (setq standard-display-table nil))
 439
 440   (defvar gnus-mouse-face-prop 'highlight)
 441
 442   (unless (fboundp 'encode-time)
 443     (defun encode-time (sec minute hour day month year &optional zone)
 444       (let ((seconds
 445              (gnus-xmas-seconds-since-epoch
 446               (timezone-make-arpa-date
 447                year month day (timezone-make-time-string hour minute sec)
 448                zone))))
 449         (list (floor (/ seconds (expt 2 16)))
 450               (round (mod seconds (expt 2 16)))))))
 451
 452   (defun gnus-byte-code (func)
 453     "Return a form that can be `eval'ed based on FUNC."
 454     (let ((fval (symbol-function func)))
 455       (if (compiled-function-p fval)
 456           (list 'funcall fval)
 457         (cons 'progn (cdr (cdr fval))))))
 458
 459   (fset 'gnus-x-color-values
 460         (if (fboundp 'x-color-values)
 461             'x-color-values
 462           (lambda (color)
 463             (color-instance-rgb-components
 464              (make-color-instance color))))))
 465
 466 (defun gnus-xmas-redefine ()
 467   "Redefine lots of Gnus functions for XEmacs."
 468   (fset 'gnus-summary-set-display-table 'gnus-xmas-summary-set-display-table)
 469   (fset 'gnus-visual-turn-off-edit-menu 'identity)
 470   (fset 'gnus-summary-recenter 'gnus-xmas-summary-recenter)
 471   (fset 'gnus-extent-start-open 'gnus-xmas-extent-start-open)
 472   (fset 'gnus-article-push-button 'gnus-xmas-article-push-button)
 473   (fset 'gnus-article-add-button 'gnus-xmas-article-add-button)
 474   (fset 'gnus-window-top-edge 'gnus-xmas-window-top-edge)
 475   (fset 'gnus-read-event-char 'gnus-xmas-read-event-char)
 476   (fset 'gnus-group-startup-message 'gnus-xmas-group-startup-message)
 477   (fset 'gnus-tree-minimize 'gnus-xmas-tree-minimize)
 478   (fset 'gnus-appt-select-lowest-window
 479         'gnus-xmas-appt-select-lowest-window)
 480   (fset 'gnus-mail-strip-quoted-names 'gnus-xmas-mail-strip-quoted-names)
 481   (fset 'gnus-add-hook 'gnus-xmas-add-hook)
 482   (fset 'gnus-character-to-event 'character-to-event)
 483   (fset 'gnus-mode-line-buffer-identification
 484         'gnus-xmas-mode-line-buffer-identification)
 485   (fset 'gnus-key-press-event-p 'key-press-event-p)
 486   (fset 'gnus-region-active-p 'region-active-p)
 487
 488   (add-hook 'gnus-group-mode-hook 'gnus-xmas-group-menu-add)
 489   (add-hook 'gnus-summary-mode-hook 'gnus-xmas-summary-menu-add)
 490   (add-hook 'gnus-article-mode-hook 'gnus-xmas-article-menu-add)
 491   (add-hook 'gnus-score-mode-hook 'gnus-xmas-score-menu-add)
 492
 493   (add-hook 'gnus-pick-mode-hook 'gnus-xmas-pick-menu-add)
 494   (add-hook 'gnus-topic-mode-hook 'gnus-xmas-topic-menu-add)
 495   (add-hook 'gnus-tree-mode-hook 'gnus-xmas-tree-menu-add)
 496   (add-hook 'gnus-binary-mode-hook 'gnus-xmas-binary-menu-add)
 497   (add-hook 'gnus-grouplens-mode-hook 'gnus-xmas-grouplens-menu-add)
 498   (add-hook 'gnus-server-mode-hook 'gnus-xmas-server-menu-add)
 499   (add-hook 'gnus-browse-mode-hook 'gnus-xmas-browse-menu-add)
 500
 501   (add-hook 'gnus-group-mode-hook 'gnus-xmas-setup-group-toolbar)
 502   (add-hook 'gnus-summary-mode-hook 'gnus-xmas-setup-summary-toolbar)
 503
 504   (add-hook 'gnus-summary-mode-hook 'gnus-xmas-switch-horizontal-scrollbar-off)
 505
 506   (when (and (<= emacs-major-version 19)
 507              (<= emacs-minor-version 13))
 508     (setq gnus-article-x-face-too-ugly (when (eq (device-type) 'tty)
 509                                          "."))
 510     (fset 'gnus-highlight-selected-summary
 511           'gnus-xmas-highlight-selected-summary)
 512     (fset 'gnus-group-remove-excess-properties
 513           'gnus-xmas-group-remove-excess-properties)
 514     (fset 'gnus-topic-remove-excess-properties
 515           'gnus-xmas-topic-remove-excess-properties)
 516     (fset 'gnus-mode-line-buffer-identification 'identity)
 517     (unless (boundp 'shell-command-switch)
 518       (setq shell-command-switch "-c"))))
 519
 520
 521 ;;; XEmacs logo and toolbar.
 522
 523 (defun gnus-xmas-group-startup-message (&optional x y)
 524   "Insert startup message in current buffer."
 525   ;; Insert the message.
 526   (setq gnus-xmas-glyph-directory (message-xmas-find-glyph-directory "gnus"))
 527   (erase-buffer)
 528   (let ((logo (and gnus-xmas-glyph-directory
 529                    (concat
 530                     (file-name-as-directory gnus-xmas-glyph-directory)
 531                     "gnus."
 532                     (if (featurep 'xpm) "xpm" "xbm"))))
 533         (xpm-color-symbols
 534          (and (featurep 'xpm)
 535               (append `(("thing" ,(car gnus-xmas-logo-colors))
 536                         ("shadow" ,(cadr gnus-xmas-logo-colors)))
 537                       xpm-color-symbols))))
 538     (if (and (featurep 'xpm)
 539              (not (equal (device-type) 'tty))
 540              logo
 541              (file-exists-p logo))
 542         (progn
 543           (setq logo (make-glyph logo))
 544           (insert " ")
 545           (set-extent-begin-glyph (make-extent (point) (point)) logo)
 546           (goto-char (point-min))
 547           (while (not (eobp))
 548             (insert (make-string (/ (max (- (window-width) (or x 35)) 0) 2)
 549                                  ? ))
 550             (forward-line 1))
 551           (goto-char (point-min))
 552           (let* ((pheight (+ 20 (count-lines (point-min) (point-max))))
 553                  (wheight (window-height))
 554                  (rest (- wheight pheight)))
 555             (insert (make-string (max 0 (* 2 (/ rest 3))) ?\n))))
 556
 557       (insert
 558        (format "              %s
 559           _    ___ _             _
 560           _ ___ __ ___  __    _ ___
 561           __   _     ___    __  ___
 562               _           ___     _
 563              _  _ __             _
 564              ___   __            _
 565                    __           _
 566                     _      _   _
 567                    _      _    _
 568                       _  _    _
 569                   __  ___
 570                  _   _ _     _
 571                 _   _
 572               _    _
 573              _    _
 574             _
 575           __
 576
 577 "
 578                ""))
 579       ;; And then hack it.
 580       (gnus-indent-rigidly (point-min) (point-max)
 581                            (/ (max (- (window-width) (or x 46)) 0) 2))
 582       (goto-char (point-min))
 583       (forward-line 1)
 584       (let* ((pheight (count-lines (point-min) (point-max)))
 585              (wheight (window-height))
 586              (rest (- wheight pheight)))
 587         (insert (make-string (max 0 (* 2 (/ rest 3))) ?\n))))
 588     ;; Fontify some.
 589     (goto-char (point-min))
 590     (put-text-property (point-min) (point-max) 'face 'gnus-splash-face)
 591     (goto-char (point-min))
 592     (setq modeline-buffer-identification
 593           (list (concat gnus-version ": *Group*")))
 594     (set-buffer-modified-p t)))
 595
 596
 597 ;;; The toolbar.
 598
 599 (defvar gnus-use-toolbar (if (featurep 'toolbar)
 600                              'default-toolbar
 601                            nil)
 602   "*If nil, do not use a toolbar.
 603 If it is non-nil, it must be a toolbar.  The five legal values are
 604 `default-toolbar', `top-toolbar', `bottom-toolbar',
 605 `right-toolbar', and `left-toolbar'.")
 606
 607 (defvar gnus-group-toolbar
 608   '([gnus-group-get-new-news gnus-group-get-new-news t "Get new news"]
 609     [gnus-group-get-new-news-this-group
 610      gnus-group-get-new-news-this-group t "Get new news in this group"]
 611     [gnus-group-catchup-current
 612      gnus-group-catchup-current t "Catchup group"]
 613     [gnus-group-describe-group
 614      gnus-group-describe-group t "Describe group"]
 615     [gnus-group-unsubscribe gnus-group-unsubscribe t "Unsubscribe group"]
 616     [gnus-group-subscribe gnus-group-subscribe t "Subscribe group"]
 617     [gnus-group-kill-group gnus-group-kill-group t "Kill group"]
 618     [gnus-group-exit gnus-group-exit t "Exit Gnus"]
 619     )
 620   "The group buffer toolbar.")
 621
 622 (defvar gnus-summary-toolbar
 623   '([gnus-summary-prev-unread
 624      gnus-summary-prev-page-or-article t "Page up"]
 625     [gnus-summary-next-unread
 626      gnus-summary-next-page t "Page down"]
 627     [gnus-summary-post-news
 628      gnus-summary-post-news t "Post an article"]
 629     [gnus-summary-followup-with-original
 630      gnus-summary-followup-with-original t
 631      "Post a followup and yank the original"]
 632     [gnus-summary-followup
 633      gnus-summary-followup t "Post a followup"]
 634     [gnus-summary-reply-with-original
 635      gnus-summary-reply-with-original t "Mail a reply and yank the original"]
 636     [gnus-summary-reply
 637      gnus-summary-reply t "Mail a reply"]
 638     [gnus-summary-caesar-message
 639      gnus-summary-caesar-message t "Rot 13"]
 640     [gnus-uu-decode-uu
 641      gnus-uu-decode-uu t "Decode uuencoded articles"]
 642     [gnus-summary-save-article-file
 643      gnus-summary-save-article-file t "Save article in file"]
 644     [gnus-summary-save-article
 645      gnus-summary-save-article t "Save article"]
 646     [gnus-uu-post-news
 647      gnus-uu-post-news t "Post an uuencoded article"]
 648     [gnus-summary-cancel-article
 649      gnus-summary-cancel-article t "Cancel article"]
 650     [gnus-summary-catchup
 651      gnus-summary-catchup t "Catchup"]
 652     [gnus-summary-catchup-and-exit
 653      gnus-summary-catchup-and-exit t "Catchup and exit"]
 654     [gnus-summary-exit gnus-summary-exit t "Exit this summary"]
 655     )
 656   "The summary buffer toolbar.")
 657
 658 (defvar gnus-summary-mail-toolbar
 659   '(
 660     [gnus-summary-prev-unread
 661      gnus-summary-prev-unread-article t "Prev unread article"]
 662     [gnus-summary-next-unread
 663      gnus-summary-next-unread-article t "Next unread article"]
 664     [gnus-summary-mail-reply gnus-summary-reply t "Reply"]
 665 ;    [gnus-summary-mail-get gnus-mail-get t "Message get"]
 666     [gnus-summary-mail-originate gnus-summary-post-news t "Originate"]
 667     [gnus-summary-mail-save gnus-summary-save-article t "Save"]
 668     [gnus-summary-mail-copy gnus-summary-copy-article t "Copy message"]
 669 ;    [gnus-summary-mail-delete gnus-summary-delete-article t "Delete message"]
 670     [gnus-summary-mail-forward gnus-summary-mail-forward t "Forward message"]
 671 ;    [gnus-summary-mail-spell gnus-mail-spell t "Spell"]
 672 ;    [gnus-summary-mail-help gnus-mail-help  t "Message help"]
 673     [gnus-summary-caesar-message
 674      gnus-summary-caesar-message t "Rot 13"]
 675     [gnus-uu-decode-uu
 676      gnus-uu-decode-uu t "Decode uuencoded articles"]
 677     [gnus-summary-save-article-file
 678      gnus-summary-save-article-file t "Save article in file"]
 679     [gnus-summary-save-article
 680      gnus-summary-save-article t "Save article"]
 681     [gnus-summary-catchup
 682      gnus-summary-catchup t "Catchup"]
 683     [gnus-summary-catchup-and-exit
 684      gnus-summary-catchup-and-exit t "Catchup and exit"]
 685     [gnus-summary-exit gnus-summary-exit t "Exit this summary"]
 686     )
 687   "The summary buffer mail toolbar.")
 688
 689 (defun gnus-xmas-setup-group-toolbar ()
 690   (and gnus-use-toolbar
 691        (message-xmas-setup-toolbar gnus-group-toolbar nil "gnus")
 692        (set-specifier (symbol-value gnus-use-toolbar)
 693                       (cons (current-buffer) gnus-group-toolbar))))
 694
 695 (defun gnus-xmas-setup-summary-toolbar ()
 696   (let ((bar (if (gnus-news-group-p gnus-newsgroup-name)
 697                  gnus-summary-toolbar gnus-summary-mail-toolbar)))
 698     (and gnus-use-toolbar
 699          (message-xmas-setup-toolbar bar nil "gnus")
 700          (set-specifier (symbol-value gnus-use-toolbar)
 701                         (cons (current-buffer) bar)))))
 702
 703 (defun gnus-xmas-mail-strip-quoted-names (address)
 704   "Protect mail-strip-quoted-names from NIL input.
 705 XEmacs compatibility workaround."
 706   (if (null address)
 707       nil
 708     (mail-strip-quoted-names address)))
 709
 710 (defun gnus-xmas-call-region (command &rest args)
 711   (apply
 712    'call-process-region (point-min) (point-max) command t '(t nil) nil
 713    args))
 714
 715 (unless (find-face 'gnus-x-face)
 716   (copy-face 'default 'gnus-x-face)
 717   (set-face-foreground 'gnus-x-face "black")
 718   (set-face-background 'gnus-x-face "white"))
 719
 720 (defun gnus-xmas-article-display-xface (beg end)
 721   "Display any XFace headers in the current article."
 722   (save-excursion
 723     (let (xface-glyph)
 724       (if (featurep 'xface)
 725           (setq xface-glyph
 726                 (make-glyph (vector 'xface :data
 727                                     (concat "X-Face: "
 728                                             (buffer-substring beg end)))))
 729         (let ((cur (current-buffer)))
 730           (save-excursion
 731             (gnus-set-work-buffer)
 732             (insert (format "%s" (buffer-substring beg end cur)))
 733             (gnus-xmas-call-region "uncompface")
 734             (goto-char (point-min))
 735             (insert "/* Width=48, Height=48 */\n")
 736             (gnus-xmas-call-region "icontopbm")
 737             (gnus-xmas-call-region "ppmtoxpm")
 738             (setq xface-glyph
 739                   (make-glyph
 740                    (vector 'xpm :data (buffer-string )))))))
 741       (set-glyph-face xface-glyph 'gnus-x-face)
 742       (goto-char (point-min))
 743       (re-search-forward "^From:" nil t)
 744       (set-extent-begin-glyph
 745        (make-extent (point) (1+ (point))) xface-glyph))))
 746
 747 (defvar gnus-xmas-pointer-glyph
 748   (progn
 749     (setq gnus-xmas-glyph-directory (message-xmas-find-glyph-directory "gnus"))
 750     (make-pointer-glyph (concat gnus-xmas-glyph-directory "gnus-pointer."
 751                                 (if (featurep 'xpm) "xpm" "xbm")))))
 752
 753 (defvar gnus-xmas-modeline-left-extent
 754   (let ((ext (copy-extent modeline-buffer-id-left-extent)))
 755     ;(set-extent-property ext 'pointer gnus-xmas-pointer-glyph)
 756     ext))
 757
 758 (defvar gnus-xmas-modeline-right-extent
 759   (let ((ext (copy-extent modeline-buffer-id-right-extent)))
 760     ;(set-extent-property ext 'pointer gnus-xmas-pointer-glyph)
 761     ext))
 762
 763 (defvar gnus-xmas-modeline-glyph
 764   (progn
 765     (setq gnus-xmas-glyph-directory (message-xmas-find-glyph-directory "gnus"))
 766     (let* ((file (concat gnus-xmas-glyph-directory "gnus-pointer."
 767                          (if (featurep 'xpm) "xpm" "xbm")))
 768            (glyph (make-glyph file)))
 769       (when (and (featurep 'x)
 770                  (file-exists-p file))
 771         (set-glyph-face glyph 'modeline-buffer-id)
 772         (set-glyph-property glyph 'image (cons 'tty "Gnus:"))
 773         glyph))))
 774
 775 (defun gnus-xmas-mode-line-buffer-identification (line)
 776   (let ((line (car line))
 777         chop)
 778     (cond
 779      ;; This is some weird type of id.
 780      ((not (stringp line))
 781       (list line))
 782      ;; This is non-standard, so we just pass it through.
 783      ((not (string-match "^Gnus:" line))
 784       (list line))
 785      ;; We have a standard line, so we colorize and glyphize it a bit.
 786      (t
 787       (setq chop (match-end 0))
 788       (list
 789        (if gnus-xmas-modeline-glyph
 790            (cons gnus-xmas-modeline-left-extent gnus-xmas-modeline-glyph)
 791          (cons gnus-xmas-modeline-left-extent (substring line 0 chop)))
 792        (cons gnus-xmas-modeline-right-extent (substring line chop)))))))
 793
 794 (defun gnus-xmas-splash ()
 795   (when (eq (device-type) 'x)
 796     (gnus-splash)))
 797
 798 (provide 'gnus-xmas)
 799
 800 ;;; gnus-xmas.el ends here