cgit.sxemacs.org Git - gnus/blob - lisp/gnus-srvr.el

   1 ;;; gnus-srvr.el --- virtual server support for Gnus
   2
   3 ;; Copyright (C) 1995, 1996, 1997, 1998, 1999, 2000, 2001, 2002, 2003,
   4 ;;   2004, 2005, 2006, 2007, 2008, 2009, 2010 Free Software Foundation, Inc.
   5
   6 ;; Author: Lars Magne Ingebrigtsen <larsi@gnus.org>
   7 ;; Keywords: news
   8
   9 ;; This file is part of GNU Emacs.
  10
  11 ;; GNU Emacs is free software: you can redistribute it and/or modify
  12 ;; it under the terms of the GNU General Public License as published by
  13 ;; the Free Software Foundation, either version 3 of the License, or
  14 ;; (at your option) any later version.
  15
  16 ;; GNU Emacs is distributed in the hope that it will be useful,
  17 ;; but WITHOUT ANY WARRANTY; without even the implied warranty of
  18 ;; MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.  See the
  19 ;; GNU General Public License for more details.
  20
  21 ;; You should have received a copy of the GNU General Public License
  22 ;; along with GNU Emacs.  If not, see <http://www.gnu.org/licenses/>.
  23
  24 ;;; Commentary:
  25
  26 ;;; Code:
  27
  28 (eval-when-compile (require 'cl))
  29
  30 (require 'gnus)
  31 (require 'gnus-spec)
  32 (require 'gnus-group)
  33 (require 'gnus-int)
  34 (require 'gnus-range)
  35
  36 (defcustom gnus-server-mode-hook nil
  37   "Hook run in `gnus-server-mode' buffers."
  38   :group 'gnus-server
  39   :type 'hook)
  40
  41 (defcustom gnus-server-exit-hook nil
  42   "Hook run when exiting the server buffer."
  43   :group 'gnus-server
  44   :type 'hook)
  45
  46 (defcustom gnus-server-line-format "     {%(%h:%w%)} %s%a\n"
  47   "Format of server lines.
  48 It works along the same lines as a normal formatting string,
  49 with some simple extensions.
  50
  51 The following specs are understood:
  52
  53 %h back end
  54 %n name
  55 %w address
  56 %s status
  57 %a agent covered
  58
  59 General format specifiers can also be used.
  60 See Info node `(gnus)Formatting Variables'."
  61   :link '(custom-manual "(gnus)Formatting Variables")
  62   :group 'gnus-server-visual
  63   :type 'string)
  64
  65 (defcustom gnus-server-mode-line-format "Gnus: %%b"
  66   "The format specification for the server mode line."
  67   :group 'gnus-server-visual
  68   :type 'string)
  69
  70 (defcustom gnus-server-browse-in-group-buffer nil
  71   "Whether server browsing should take place in the group buffer.
  72 If nil, a faster, but more primitive, buffer is used instead."
  73   :version "22.1"
  74   :group 'gnus-server-visual
  75   :type 'boolean)
  76
  77 ;;; Internal variables.
  78
  79 (defvar gnus-inserted-opened-servers nil)
  80
  81 (defvar gnus-server-line-format-alist
  82   `((?h gnus-tmp-how ?s)
  83     (?n gnus-tmp-name ?s)
  84     (?w gnus-tmp-where ?s)
  85     (?s gnus-tmp-status ?s)
  86     (?a gnus-tmp-agent ?s)))
  87
  88 (defvar gnus-server-mode-line-format-alist
  89   `((?S gnus-tmp-news-server ?s)
  90     (?M gnus-tmp-news-method ?s)
  91     (?u gnus-tmp-user-defined ?s)))
  92
  93 (defvar gnus-server-line-format-spec nil)
  94 (defvar gnus-server-mode-line-format-spec nil)
  95 (defvar gnus-server-killed-servers nil)
  96
  97 (defvar gnus-server-mode-map)
  98
  99 (defvar gnus-server-menu-hook nil
 100   "*Hook run after the creation of the server mode menu.")
 101
 102 (defun gnus-server-make-menu-bar ()
 103   (gnus-turn-off-edit-menu 'server)
 104   (unless (boundp 'gnus-server-server-menu)
 105     (easy-menu-define
 106      gnus-server-server-menu gnus-server-mode-map ""
 107      '("Server"
 108        ["Add..." gnus-server-add-server t]
 109        ["Browse" gnus-server-read-server t]
 110        ["Scan" gnus-server-scan-server t]
 111        ["List" gnus-server-list-servers t]
 112        ["Kill" gnus-server-kill-server t]
 113        ["Yank" gnus-server-yank-server t]
 114        ["Copy" gnus-server-copy-server t]
 115        ["Edit" gnus-server-edit-server t]
 116        ["Regenerate" gnus-server-regenerate-server t]
 117        ["Compact" gnus-server-compact-server t]
 118        ["Exit" gnus-server-exit t]))
 119
 120     (easy-menu-define
 121      gnus-server-connections-menu gnus-server-mode-map ""
 122      '("Connections"
 123        ["Open" gnus-server-open-server t]
 124        ["Close" gnus-server-close-server t]
 125        ["Offline" gnus-server-offline-server t]
 126        ["Deny" gnus-server-deny-server t]
 127        "---"
 128        ["Open All" gnus-server-open-all-servers t]
 129        ["Close All" gnus-server-close-all-servers t]
 130        ["Reset All" gnus-server-remove-denials t]))
 131
 132     (gnus-run-hooks 'gnus-server-menu-hook)))
 133
 134 (defvar gnus-server-mode-map nil)
 135 (put 'gnus-server-mode 'mode-class 'special)
 136
 137 (unless gnus-server-mode-map
 138   (setq gnus-server-mode-map (make-sparse-keymap))
 139   (suppress-keymap gnus-server-mode-map)
 140
 141   (gnus-define-keys gnus-server-mode-map
 142     " " gnus-server-read-server-in-server-buffer
 143     "\r" gnus-server-read-server
 144     gnus-mouse-2 gnus-server-pick-server
 145     "q" gnus-server-exit
 146     "l" gnus-server-list-servers
 147     "k" gnus-server-kill-server
 148     "y" gnus-server-yank-server
 149     "c" gnus-server-copy-server
 150     "a" gnus-server-add-server
 151     "e" gnus-server-edit-server
 152     "s" gnus-server-scan-server
 153
 154     "O" gnus-server-open-server
 155     "\M-o" gnus-server-open-all-servers
 156     "C" gnus-server-close-server
 157     "\M-c" gnus-server-close-all-servers
 158     "D" gnus-server-deny-server
 159     "L" gnus-server-offline-server
 160     "R" gnus-server-remove-denials
 161
 162     "n" next-line
 163     "p" previous-line
 164
 165     "g" gnus-server-regenerate-server
 166
 167     "z" gnus-server-compact-server
 168
 169     "\C-c\C-i" gnus-info-find-node
 170     "\C-c\C-b" gnus-bug))
 171
 172 (defface gnus-server-agent
 173   '((((class color) (background light)) (:foreground "PaleTurquoise" :bold t))
 174     (((class color) (background dark)) (:foreground "PaleTurquoise" :bold t))
 175     (t (:bold t)))
 176   "Face used for displaying AGENTIZED servers"
 177   :group 'gnus-server-visual)
 178 ;; backward-compatibility alias
 179 (put 'gnus-server-agent-face 'face-alias 'gnus-server-agent)
 180 (put 'gnus-server-agent-face 'obsolete-face "22.1")
 181
 182 (defface gnus-server-opened
 183   '((((class color) (background light)) (:foreground "Green3" :bold t))
 184     (((class color) (background dark)) (:foreground "Green1" :bold t))
 185     (t (:bold t)))
 186   "Face used for displaying OPENED servers"
 187   :group 'gnus-server-visual)
 188 ;; backward-compatibility alias
 189 (put 'gnus-server-opened-face 'face-alias 'gnus-server-opened)
 190 (put 'gnus-server-opened-face 'obsolete-face "22.1")
 191
 192 (defface gnus-server-closed
 193   '((((class color) (background light)) (:foreground "Steel Blue" :italic t))
 194     (((class color) (background dark))
 195      (:foreground "LightBlue" :italic t))
 196     (t (:italic t)))
 197   "Face used for displaying CLOSED servers"
 198   :group 'gnus-server-visual)
 199 ;; backward-compatibility alias
 200 (put 'gnus-server-closed-face 'face-alias 'gnus-server-closed)
 201 (put 'gnus-server-closed-face 'obsolete-face "22.1")
 202
 203 (defface gnus-server-denied
 204   '((((class color) (background light)) (:foreground "Red" :bold t))
 205     (((class color) (background dark)) (:foreground "Pink" :bold t))
 206     (t (:inverse-video t :bold t)))
 207   "Face used for displaying DENIED servers"
 208   :group 'gnus-server-visual)
 209 ;; backward-compatibility alias
 210 (put 'gnus-server-denied-face 'face-alias 'gnus-server-denied)
 211 (put 'gnus-server-denied-face 'obsolete-face "22.1")
 212
 213 (defface gnus-server-offline
 214   '((((class color) (background light)) (:foreground "Orange" :bold t))
 215     (((class color) (background dark)) (:foreground "Yellow" :bold t))
 216     (t (:inverse-video t :bold t)))
 217   "Face used for displaying OFFLINE servers"
 218   :group 'gnus-server-visual)
 219 ;; backward-compatibility alias
 220 (put 'gnus-server-offline-face 'face-alias 'gnus-server-offline)
 221 (put 'gnus-server-offline-face 'obsolete-face "22.1")
 222
 223 (defvar gnus-server-font-lock-keywords
 224   '(("(\\(agent\\))" 1 'gnus-server-agent)
 225     ("(\\(opened\\))" 1 'gnus-server-opened)
 226     ("(\\(closed\\))" 1 'gnus-server-closed)
 227     ("(\\(offline\\))" 1 'gnus-server-offline)
 228     ("(\\(denied\\))" 1 'gnus-server-denied)))
 229
 230 (defun gnus-server-mode ()
 231   "Major mode for listing and editing servers.
 232
 233 All normal editing commands are switched off.
 234 \\<gnus-server-mode-map>
 235 For more in-depth information on this mode, read the manual
 236 \(`\\[gnus-info-find-node]').
 237
 238 The following commands are available:
 239
 240 \\{gnus-server-mode-map}"
 241   (interactive)
 242   (when (gnus-visual-p 'server-menu 'menu)
 243     (gnus-server-make-menu-bar))
 244   (kill-all-local-variables)
 245   (gnus-simplify-mode-line)
 246   (setq major-mode 'gnus-server-mode)
 247   (setq mode-name "Server")
 248   (gnus-set-default-directory)
 249   (setq mode-line-process nil)
 250   (use-local-map gnus-server-mode-map)
 251   (buffer-disable-undo)
 252   (setq truncate-lines t)
 253   (setq buffer-read-only t)
 254   (if (featurep 'xemacs)
 255       (put 'gnus-server-mode 'font-lock-defaults '(gnus-server-font-lock-keywords t))
 256     (set (make-local-variable 'font-lock-defaults)
 257          '(gnus-server-font-lock-keywords t)))
 258   (gnus-run-mode-hooks 'gnus-server-mode-hook))
 259
 260 (defun gnus-server-insert-server-line (gnus-tmp-name method)
 261   (let* ((gnus-tmp-how (car method))
 262          (gnus-tmp-where (nth 1 method))
 263          (elem (assoc method gnus-opened-servers))
 264          (gnus-tmp-status
 265           (cond
 266            ((eq (nth 1 elem) 'denied) "(denied)")
 267            ((eq (nth 1 elem) 'offline) "(offline)")
 268            (t
 269             (condition-case nil
 270                 (if (or (gnus-server-opened method)
 271                         (eq (nth 1 elem) 'ok))
 272                     "(opened)"
 273                   "(closed)")
 274               ((error) "(error)")))))
 275          (gnus-tmp-agent (if (and gnus-agent
 276                                   (gnus-agent-method-p method))
 277                              " (agent)"
 278                            "")))
 279     (beginning-of-line)
 280     (gnus-add-text-properties
 281      (point)
 282      (prog1 (1+ (point))
 283        ;; Insert the text.
 284        (eval gnus-server-line-format-spec))
 285      (list 'gnus-server (intern gnus-tmp-name)
 286            'gnus-named-server (intern (gnus-method-to-server method t))))))
 287
 288 (defun gnus-enter-server-buffer ()
 289   "Set up the server buffer."
 290   (gnus-server-setup-buffer)
 291   (gnus-configure-windows 'server)
 292   ;; Usually `gnus-configure-windows' will finish with the
 293   ;; `gnus-server-buffer' selected as the current buffer, but not always (I
 294   ;; bumped into it when starting from a dedicated *Group* frame, and
 295   ;; gnus-configure-windows opened *Server* into its own dedicated frame).
 296   (with-current-buffer (get-buffer gnus-server-buffer)
 297     (gnus-server-prepare)))
 298
 299 (defun gnus-server-setup-buffer ()
 300   "Initialize the server buffer."
 301   (unless (get-buffer gnus-server-buffer)
 302     (with-current-buffer (gnus-get-buffer-create gnus-server-buffer)
 303       (gnus-server-mode)
 304       (when gnus-carpal
 305         (gnus-carpal-setup-buffer 'server)))))
 306
 307 (defun gnus-server-prepare ()
 308   (gnus-set-format 'server-mode)
 309   (gnus-set-format 'server t)
 310   (let ((alist gnus-server-alist)
 311         (buffer-read-only nil)
 312         done server op-ser)
 313     (erase-buffer)
 314     (setq gnus-inserted-opened-servers nil)
 315     ;; First we do the real list of servers.
 316     (while alist
 317       (unless (member (cdar alist) done)
 318         (push (cdar alist) done)
 319         (setq server (pop alist))
 320         (when (and server (car server) (cdr server))
 321           (gnus-server-insert-server-line (car server) (cdr server))))
 322       (when (member (cdar alist) done)
 323         (pop alist)))
 324     ;; Then we insert the list of servers that have been opened in
 325     ;; this session.
 326     (dolist (open gnus-opened-servers)
 327       (when (and (not (member (car open) done))
 328                  ;; Just ignore ephemeral servers.
 329                  (not (member (car open) gnus-ephemeral-servers)))
 330         (push (car open) done)
 331         (gnus-server-insert-server-line
 332          (setq op-ser (format "%s:%s" (caar open) (nth 1 (car open))))
 333          (car open))
 334         (push (list op-ser (car open)) gnus-inserted-opened-servers))))
 335   (goto-char (point-min))
 336   (gnus-server-position-point))
 337
 338 (defun gnus-server-server-name ()
 339   (let ((server (get-text-property (point-at-bol) 'gnus-server)))
 340     (and server (symbol-name server))))
 341
 342 (defun gnus-server-named-server ()
 343   "Return a server name that matches one of the names returned by
 344 `gnus-method-to-server'."
 345   (let ((server (get-text-property (point-at-bol) 'gnus-named-server)))
 346     (and server (symbol-name server))))
 347
 348 (defalias 'gnus-server-position-point 'gnus-goto-colon)
 349
 350 (defconst gnus-server-edit-buffer "*Gnus edit server*")
 351
 352 (defun gnus-server-update-server (server)
 353   (with-current-buffer gnus-server-buffer
 354     (let* ((buffer-read-only nil)
 355            (entry (assoc server gnus-server-alist))
 356            (oentry (assoc (gnus-server-to-method server)
 357                           gnus-opened-servers)))
 358       (when entry
 359         (gnus-dribble-enter
 360          (concat "(gnus-server-set-info \"" server "\" '"
 361                  (gnus-prin1-to-string (cdr entry)) ")\n")))
 362       (when (or entry oentry)
 363         ;; Buffer may be narrowed.
 364         (save-restriction
 365           (widen)
 366           (when (gnus-server-goto-server server)
 367             (gnus-delete-line))
 368           (if entry
 369               (gnus-server-insert-server-line (car entry) (cdr entry))
 370             (gnus-server-insert-server-line
 371              (format "%s:%s" (caar oentry) (nth 1 (car oentry)))
 372              (car oentry)))
 373           (gnus-server-position-point))))))
 374
 375 (defun gnus-server-set-info (server info)
 376   ;; Enter a select method into the virtual server alist.
 377   (when (and server info)
 378     (gnus-dribble-enter
 379      (concat "(gnus-server-set-info \"" server "\" '"
 380              (gnus-prin1-to-string info) ")"))
 381     (let* ((server (nth 1 info))
 382            (entry (assoc server gnus-server-alist))
 383            (cached (assoc server gnus-server-method-cache)))
 384       (if cached
 385           (setq gnus-server-method-cache
 386                 (delq cached gnus-server-method-cache)))
 387       (if entry
 388           (progn
 389             ;; Remove the server from `gnus-opened-servers' since
 390             ;; it has never been opened with the new `info' yet.
 391             (gnus-opened-servers-remove (cdr entry))
 392             ;; Don't make a new Lisp object.
 393             (setcar (cdr entry) (car info))
 394             (setcdr (cdr entry) (cdr info)))
 395         (setq gnus-server-alist
 396               (nconc gnus-server-alist (list (cons server info))))))))
 397
 398 ;;; Interactive server functions.
 399
 400 (defun gnus-server-kill-server (server)
 401   "Kill the server on the current line."
 402   (interactive (list (gnus-server-server-name)))
 403   (unless (gnus-server-goto-server server)
 404     (if server (error "No such server: %s" server)
 405       (error "No server on the current line")))
 406   (unless (assoc server gnus-server-alist)
 407     (error "Read-only server %s" server))
 408   (gnus-dribble-touch)
 409   (let ((buffer-read-only nil))
 410     (gnus-delete-line))
 411   (push (assoc server gnus-server-alist) gnus-server-killed-servers)
 412   (setq gnus-server-alist (delq (car gnus-server-killed-servers)
 413                                 gnus-server-alist))
 414   (let ((groups (gnus-groups-from-server server)))
 415     (when (and groups
 416                (gnus-yes-or-no-p
 417                 (format "Kill all %s groups from this server? "
 418                         (length groups))))
 419       (dolist (group groups)
 420         (setq gnus-newsrc-alist
 421               (delq (assoc group gnus-newsrc-alist)
 422                     gnus-newsrc-alist))
 423         (when gnus-group-change-level-function
 424           (funcall gnus-group-change-level-function
 425                    group gnus-level-killed 3)))))
 426   (gnus-server-position-point))
 427
 428 (defun gnus-server-yank-server ()
 429   "Yank the previously killed server."
 430   (interactive)
 431   (unless gnus-server-killed-servers
 432     (error "No killed servers to be yanked"))
 433   (let ((alist gnus-server-alist)
 434         (server (gnus-server-server-name))
 435         (killed (car gnus-server-killed-servers)))
 436     (if (not server)
 437         (setq gnus-server-alist (nconc gnus-server-alist (list killed)))
 438       (if (string= server (caar gnus-server-alist))
 439           (push killed gnus-server-alist)
 440         (while (and (cdr alist)
 441                     (not (string= server (caadr alist))))
 442           (setq alist (cdr alist)))
 443         (if alist
 444             (setcdr alist (cons killed (cdr alist)))
 445           (setq gnus-server-alist (list killed)))))
 446     (gnus-server-update-server (car killed))
 447     (setq gnus-server-killed-servers (cdr gnus-server-killed-servers))
 448     (gnus-server-position-point)))
 449
 450 (defun gnus-server-exit ()
 451   "Return to the group buffer."
 452   (interactive)
 453   (gnus-run-hooks 'gnus-server-exit-hook)
 454   (gnus-kill-buffer (current-buffer))
 455   (gnus-configure-windows 'group t))
 456
 457 (defun gnus-server-list-servers ()
 458   "List all available servers."
 459   (interactive)
 460   (let ((cur (gnus-server-server-name)))
 461     (gnus-server-prepare)
 462     (if cur (gnus-server-goto-server cur)
 463       (goto-char (point-max))
 464       (forward-line -1))
 465     (gnus-server-position-point)))
 466
 467 (defun gnus-server-set-status (method status)
 468   "Make METHOD have STATUS."
 469   (let ((entry (assoc method gnus-opened-servers)))
 470     (if entry
 471         (setcar (cdr entry) status)
 472       (push (list method status) gnus-opened-servers))))
 473
 474 (defun gnus-opened-servers-remove (method)
 475   "Remove METHOD from the list of opened servers."
 476   (setq gnus-opened-servers (delq (assoc method gnus-opened-servers)
 477                                   gnus-opened-servers)))
 478
 479 (defun gnus-server-open-server (server)
 480   "Force an open of SERVER."
 481   (interactive (list (gnus-server-server-name)))
 482   (let ((method (gnus-server-to-method server)))
 483     (unless method
 484       (error "No such server: %s" server))
 485     (gnus-server-set-status method 'ok)
 486     (prog1
 487         (or (gnus-open-server method)
 488             (progn (message "Couldn't open %s" server) nil))
 489       (gnus-server-update-server server)
 490       (gnus-server-position-point))))
 491
 492 (defun gnus-server-open-all-servers ()
 493   "Open all servers."
 494   (interactive)
 495   (dolist (server gnus-inserted-opened-servers)
 496     (gnus-server-open-server (car server))))
 497
 498 (defun gnus-server-close-server (server)
 499   "Close SERVER."
 500   (interactive (list (gnus-server-server-name)))
 501   (let ((method (gnus-server-to-method server)))
 502     (unless method
 503       (error "No such server: %s" server))
 504     (gnus-server-set-status method 'closed)
 505     (prog1
 506         (gnus-close-server method)
 507       (gnus-server-update-server server)
 508       (gnus-server-position-point))))
 509
 510 (defun gnus-server-offline-server (server)
 511   "Set SERVER to offline."
 512   (interactive (list (gnus-server-server-name)))
 513   (let ((method (gnus-server-to-method server)))
 514     (unless method
 515       (error "No such server: %s" server))
 516     (prog1
 517         (gnus-close-server method)
 518       (gnus-server-set-status method 'offline)
 519       (gnus-server-update-server server)
 520       (gnus-server-position-point))))
 521
 522 (defun gnus-server-close-all-servers ()
 523   "Close all servers."
 524   (interactive)
 525   (dolist (server gnus-inserted-opened-servers)
 526     (gnus-server-close-server (car server)))
 527   (dolist (server gnus-server-alist)
 528     (gnus-server-close-server (car server))))
 529
 530 (defun gnus-server-deny-server (server)
 531   "Make sure SERVER will never be attempted opened."
 532   (interactive (list (gnus-server-server-name)))
 533   (let ((method (gnus-server-to-method server)))
 534     (unless method
 535       (error "No such server: %s" server))
 536     (gnus-server-set-status method 'denied))
 537   (gnus-server-update-server server)
 538   (gnus-server-position-point)
 539   t)
 540
 541 (defun gnus-server-remove-denials ()
 542   "Make all denied servers into closed servers."
 543   (interactive)
 544   (dolist (server gnus-opened-servers)
 545     (when (eq (nth 1 server) 'denied)
 546       (setcar (nthcdr 1 server) 'closed)))
 547   (gnus-server-list-servers))
 548
 549 (defun gnus-server-copy-server (from to)
 550   "Copy a server definiton to a new name."
 551   (interactive
 552    (list
 553     (or (gnus-server-server-name)
 554         (error "No server on the current line"))
 555     (read-string "Copy to: ")))
 556   (unless from
 557     (error "No server on current line"))
 558   (unless (and to (not (string= to "")))
 559     (error "No name to copy to"))
 560   (when (assoc to gnus-server-alist)
 561     (error "%s already exists" to))
 562   (unless (gnus-server-to-method from)
 563     (error "%s: no such server" from))
 564   (let ((to-entry (cons from (gnus-copy-sequence
 565                               (gnus-server-to-method from)))))
 566     (setcar to-entry to)
 567     (setcar (nthcdr 2 to-entry) to)
 568     (push to-entry gnus-server-killed-servers)
 569     (gnus-server-yank-server)))
 570
 571 (defun gnus-server-add-server (how where)
 572   (interactive
 573    (list (intern (completing-read "Server method: "
 574                                   gnus-valid-select-methods nil t))
 575          (read-string "Server name: ")))
 576   (when (assq where gnus-server-alist)
 577     (error "Server with that name already defined"))
 578   (push (list where how where) gnus-server-killed-servers)
 579   (gnus-server-yank-server))
 580
 581 (defun gnus-server-goto-server (server)
 582   "Jump to a server line."
 583   (interactive
 584    (list (completing-read "Goto server: " gnus-server-alist nil t)))
 585   (let ((to (text-property-any (point-min) (point-max)
 586                                'gnus-server (intern server))))
 587     (when to
 588       (goto-char to)
 589       (gnus-server-position-point))))
 590
 591 (defun gnus-server-edit-server (server)
 592   "Edit the server on the current line."
 593   (interactive (list (gnus-server-server-name)))
 594   (unless server
 595     (error "No server on current line"))
 596   (unless (assoc server gnus-server-alist)
 597     (error "This server can't be edited"))
 598   (let ((info (cdr (assoc server gnus-server-alist))))
 599     (gnus-close-server info)
 600     (gnus-edit-form
 601      info "Editing the server."
 602      `(lambda (form)
 603         (gnus-server-set-info ,server form)
 604         (gnus-server-list-servers)
 605         (gnus-server-position-point))
 606      'edit-server)))
 607
 608 (defun gnus-server-scan-server (server)
 609   "Request a scan from the current server."
 610   (interactive (list (gnus-server-server-name)))
 611   (let ((method (gnus-server-to-method server)))
 612     (if (not (gnus-get-function method 'request-scan))
 613         (error "Server %s can't scan" (car method))
 614       (gnus-message 3 "Scanning %s..." server)
 615       (gnus-request-scan nil method)
 616       (gnus-message 3 "Scanning %s...done" server))))
 617
 618 (defun gnus-server-read-server-in-server-buffer (server)
 619   "Browse a server in server buffer."
 620   (interactive (list (gnus-server-server-name)))
 621   (let (gnus-server-browse-in-group-buffer)
 622     (gnus-server-read-server server)))
 623
 624 (defun gnus-server-read-server (server)
 625   "Browse a server."
 626   (interactive (list (gnus-server-server-name)))
 627   (let ((buf (current-buffer)))
 628     (prog1
 629         (gnus-browse-foreign-server server buf)
 630       (with-current-buffer buf
 631         (gnus-server-update-server (gnus-server-server-name))
 632         (gnus-server-position-point)))))
 633
 634 (defun gnus-server-pick-server (e)
 635   (interactive "e")
 636   (mouse-set-point e)
 637   (gnus-server-read-server (gnus-server-server-name)))
 638
 639 \f
 640 ;;;
 641 ;;; Browse Server Mode
 642 ;;;
 643
 644 (defvar gnus-browse-menu-hook nil
 645   "*Hook run after the creation of the browse mode menu.")
 646
 647 (defvar gnus-browse-mode-hook nil)
 648 (defvar gnus-browse-mode-map nil)
 649 (put 'gnus-browse-mode 'mode-class 'special)
 650
 651 (unless gnus-browse-mode-map
 652   (setq gnus-browse-mode-map (make-keymap))
 653   (suppress-keymap gnus-browse-mode-map)
 654
 655   (gnus-define-keys
 656       gnus-browse-mode-map
 657     " " gnus-browse-read-group
 658     "=" gnus-browse-select-group
 659     "n" gnus-browse-next-group
 660     "p" gnus-browse-prev-group
 661     "\177" gnus-browse-prev-group
 662     [delete] gnus-browse-prev-group
 663     "N" gnus-browse-next-group
 664     "P" gnus-browse-prev-group
 665     "\M-n" gnus-browse-next-group
 666     "\M-p" gnus-browse-prev-group
 667     "\r" gnus-browse-select-group
 668     "u" gnus-browse-unsubscribe-current-group
 669     "l" gnus-browse-exit
 670     "L" gnus-browse-exit
 671     "q" gnus-browse-exit
 672     "Q" gnus-browse-exit
 673     "d" gnus-browse-describe-group
 674     "\C-c\C-c" gnus-browse-exit
 675     "?" gnus-browse-describe-briefly
 676
 677     "\C-c\C-i" gnus-info-find-node
 678     "\C-c\C-b" gnus-bug))
 679
 680 (defun gnus-browse-make-menu-bar ()
 681   (gnus-turn-off-edit-menu 'browse)
 682   (unless (boundp 'gnus-browse-menu)
 683     (easy-menu-define
 684      gnus-browse-menu gnus-browse-mode-map ""
 685      '("Browse"
 686        ["Subscribe" gnus-browse-unsubscribe-current-group t]
 687        ["Read" gnus-browse-read-group t]
 688        ["Select" gnus-browse-select-group t]
 689        ["Describe" gnus-browse-describe-group t]
 690        ["Next" gnus-browse-next-group t]
 691        ["Prev" gnus-browse-prev-group t]
 692        ["Exit" gnus-browse-exit t]))
 693     (gnus-run-hooks 'gnus-browse-menu-hook)))
 694
 695 (defvar gnus-browse-current-method nil)
 696 (defvar gnus-browse-return-buffer nil)
 697
 698 (defvar gnus-browse-buffer "*Gnus Browse Server*")
 699
 700 (defun gnus-browse-foreign-server (server &optional return-buffer)
 701   "Browse the server SERVER."
 702   (setq gnus-browse-current-method (gnus-server-to-method server))
 703   (setq gnus-browse-return-buffer return-buffer)
 704   (let* ((method gnus-browse-current-method)
 705          (orig-select-method gnus-select-method)
 706          (gnus-select-method method)
 707          groups group)
 708     (gnus-message 5 "Connecting to %s..." (nth 1 method))
 709     (cond
 710      ((not (gnus-check-server method))
 711       (gnus-message
 712        1 "Unable to contact server %s: %s" (nth 1 method)
 713        (gnus-status-message method))
 714       nil)
 715      ((not
 716        (prog2
 717            (gnus-message 6 "Reading active file...")
 718            (gnus-request-list method)
 719          (gnus-message 6 "Reading active file...done")))
 720       (gnus-message
 721        1 "Couldn't request list: %s" (gnus-status-message method))
 722       nil)
 723      (t
 724       (with-current-buffer nntp-server-buffer
 725         (let ((cur (current-buffer)))
 726           (goto-char (point-min))
 727           (unless (string= gnus-ignored-newsgroups "")
 728             (delete-matching-lines gnus-ignored-newsgroups))
 729           ;; We treat NNTP as a special case to avoid problems with
 730           ;; garbage group names like `"foo' that appear in some badly
 731           ;; managed active files. -jh.
 732           (if (eq (car method) 'nntp)
 733               (while (not (eobp))
 734                 (ignore-errors
 735                   (push (cons
 736                          (mm-string-as-unibyte
 737                           (buffer-substring
 738                            (point)
 739                            (progn
 740                              (skip-chars-forward "^ \t")
 741                              (point))))
 742                          (let ((last (read cur)))
 743                            (cons (read cur) last)))
 744                         groups))
 745                 (forward-line))
 746             (while (not (eobp))
 747               (ignore-errors
 748                 (push (cons
 749                        (mm-string-as-unibyte
 750                         (if (eq (char-after) ?\")
 751                             (read cur)
 752                           (let ((p (point)) (name ""))
 753                             (skip-chars-forward "^ \t\\\\")
 754                             (setq name (buffer-substring p (point)))
 755                             (while (eq (char-after) ?\\)
 756                               (setq p (1+ (point)))
 757                               (forward-char 2)
 758                               (skip-chars-forward "^ \t\\\\")
 759                               (setq name (concat name (buffer-substring
 760                                                        p (point)))))
 761                             name)))
 762                        (let ((last (read cur)))
 763                          (cons (read cur) last)))
 764                       groups))
 765               (forward-line)))))
 766       (setq groups (sort groups
 767                          (lambda (l1 l2)
 768                            (string< (car l1) (car l2)))))
 769       (if gnus-server-browse-in-group-buffer
 770           (let* ((gnus-select-method orig-select-method)
 771                  (gnus-group-listed-groups
 772                   (mapcar (lambda (group)
 773                             (let ((name
 774                                    (gnus-group-prefixed-name
 775                                     (car group) method)))
 776                               (gnus-set-active name (cdr group))
 777                               name))
 778                           groups)))
 779             (gnus-configure-windows 'group)
 780             (funcall gnus-group-prepare-function
 781                      gnus-level-killed 'ignore 1 'ignore))
 782         (gnus-get-buffer-create gnus-browse-buffer)
 783         (when gnus-carpal
 784           (gnus-carpal-setup-buffer 'browse))
 785         (gnus-configure-windows 'browse)
 786         (buffer-disable-undo)
 787         (let ((buffer-read-only nil))
 788           (erase-buffer))
 789         (gnus-browse-mode)
 790         (setq mode-line-buffer-identification
 791               (list
 792                (format
 793                 "Gnus: %%b {%s:%s}" (car method) (cadr method))))
 794         (let ((buffer-read-only nil)
 795               name
 796               (prefix (let ((gnus-select-method orig-select-method))
 797                         (gnus-group-prefixed-name "" method))))
 798           (while (setq group (pop groups))
 799             (gnus-add-text-properties
 800              (point)
 801              (prog1 (1+ (point))
 802                (insert
 803                 (format "%c%7d: %s\n"
 804                         (let ((level
 805                                (if (string= prefix "")
 806                                    (gnus-group-level (setq name (car group)))
 807                                  (gnus-group-level
 808                                   (concat prefix (setq name (car group)))))))
 809                           (cond
 810                            ((<= level gnus-level-subscribed) ? )
 811                            ((<= level gnus-level-unsubscribed) ?U)
 812                            ((= level gnus-level-zombie) ?Z)
 813                            (t ?K)))
 814                         (max 0 (- (1+ (cddr group)) (cadr group)))
 815                         ;; Don't decode if name is ASCII
 816                         (if (and (fboundp 'detect-coding-string)
 817                                  (eq (detect-coding-string name t) 'undecided))
 818                             name
 819                           (mm-decode-coding-string
 820                            name
 821                            (inline (gnus-group-name-charset method name)))))))
 822              (list 'gnus-group name)
 823              )))
 824         (switch-to-buffer (current-buffer)))
 825       (goto-char (point-min))
 826       (gnus-group-position-point)
 827       (gnus-message 5 "Connecting to %s...done" (nth 1 method))
 828       t))))
 829
 830 (defun gnus-browse-mode ()
 831   "Major mode for browsing a foreign server.
 832
 833 All normal editing commands are switched off.
 834
 835 \\<gnus-browse-mode-map>
 836 The only things you can do in this buffer is
 837
 838 1) `\\[gnus-browse-unsubscribe-current-group]' to subscribe to a group.
 839 The group will be inserted into the group buffer upon exit from this
 840 buffer.
 841
 842 2) `\\[gnus-browse-read-group]' to read a group ephemerally.
 843
 844 3) `\\[gnus-browse-exit]' to return to the group buffer."
 845   (interactive)
 846   (kill-all-local-variables)
 847   (when (gnus-visual-p 'browse-menu 'menu)
 848     (gnus-browse-make-menu-bar))
 849   (gnus-simplify-mode-line)
 850   (setq major-mode 'gnus-browse-mode)
 851   (setq mode-name "Browse Server")
 852   (setq mode-line-process nil)
 853   (use-local-map gnus-browse-mode-map)
 854   (buffer-disable-undo)
 855   (setq truncate-lines t)
 856   (gnus-set-default-directory)
 857   (setq buffer-read-only t)
 858   (gnus-run-mode-hooks 'gnus-browse-mode-hook))
 859
 860 (defun gnus-browse-read-group (&optional no-article number)
 861   "Enter the group at the current line.
 862 If NUMBER, fetch this number of articles."
 863   (interactive "P")
 864   (let ((group (gnus-browse-group-name)))
 865     (if (or (not (gnus-get-info group))
 866             (gnus-ephemeral-group-p group))
 867         (unless (gnus-group-read-ephemeral-group
 868                  group gnus-browse-current-method nil
 869                  (cons (current-buffer) 'browse)
 870                  nil nil nil number)
 871           (error "Couldn't enter %s" group))
 872       (unless (gnus-group-read-group nil no-article group)
 873         (error "Couldn't enter %s" group)))))
 874
 875 (defun gnus-browse-select-group (&optional number)
 876   "Select the current group.
 877 If NUMBER, fetch this number of articles."
 878   (interactive "P")
 879   (gnus-browse-read-group 'no number))
 880
 881 (defun gnus-browse-next-group (n)
 882   "Go to the next group."
 883   (interactive "p")
 884   (prog1
 885       (forward-line n)
 886     (gnus-group-position-point)))
 887
 888 (defun gnus-browse-prev-group (n)
 889   "Go to the next group."
 890   (interactive "p")
 891   (gnus-browse-next-group (- n)))
 892
 893 (defun gnus-browse-unsubscribe-current-group (arg)
 894   "(Un)subscribe to the next ARG groups."
 895   (interactive "p")
 896   (when (eobp)
 897     (error "No group at current line"))
 898   (let ((ward (if (< arg 0) -1 1))
 899         (arg (abs arg)))
 900     (while (and (> arg 0)
 901                 (not (eobp))
 902                 (gnus-browse-unsubscribe-group)
 903                 (zerop (gnus-browse-next-group ward)))
 904       (decf arg))
 905     (gnus-group-position-point)
 906     (when (/= 0 arg)
 907       (gnus-message 7 "No more newsgroups"))
 908     arg))
 909
 910 (defun gnus-browse-group-name ()
 911   (save-excursion
 912     (beginning-of-line)
 913     (let ((name (get-text-property (point) 'gnus-group)))
 914       (when (re-search-forward ": \\(.*\\)$" (point-at-eol) t)
 915         (concat (gnus-method-to-server-name gnus-browse-current-method) ":"
 916                 (or name
 917                     (match-string-no-properties 1)))))))
 918
 919 (defun gnus-browse-describe-group (group)
 920   "Describe the current group."
 921   (interactive (list (gnus-browse-group-name)))
 922   (gnus-group-describe-group nil group))
 923
 924 (defun gnus-browse-unsubscribe-group ()
 925   "Toggle subscription of the current group in the browse buffer."
 926   (let ((sub nil)
 927         (buffer-read-only nil)
 928         group)
 929     (save-excursion
 930       (beginning-of-line)
 931       ;; If this group it killed, then we want to subscribe it.
 932       (unless (eq (char-after) ? )
 933         (setq sub t))
 934       (setq group (gnus-browse-group-name))
 935       (when (gnus-server-equal gnus-browse-current-method "native")
 936         (setq group (gnus-group-real-name group)))
 937       (if sub
 938           (progn
 939             ;; Make sure the group has been properly removed before we
 940             ;; subscribe to it.
 941             (if (gnus-ephemeral-group-p group)
 942                 (gnus-kill-ephemeral-group group))
 943             ;; We need to discern between killed/zombie groups and
 944             ;; just unsubscribed ones.
 945             (gnus-group-change-level
 946              (or (gnus-group-entry group)
 947                  (list t group gnus-level-default-subscribed
 948                        nil nil (if (gnus-server-equal
 949                                     gnus-browse-current-method "native")
 950                                    nil
 951                                  (gnus-method-simplify
 952                                   gnus-browse-current-method))))
 953              gnus-level-default-subscribed (gnus-group-level group)
 954              (and (car (nth 1 gnus-newsrc-alist))
 955                   (gnus-group-entry (car (nth 1 gnus-newsrc-alist))))
 956              (null (gnus-group-entry group)))
 957             (delete-char 1)
 958             (insert ? ))
 959         (gnus-group-change-level
 960          group gnus-level-unsubscribed gnus-level-default-subscribed)
 961         (delete-char 1)
 962         (insert ?U)))
 963     t))
 964
 965 (defun gnus-browse-exit ()
 966   "Quit browsing and return to the group buffer."
 967   (interactive)
 968   (when (eq major-mode 'gnus-browse-mode)
 969     (gnus-kill-buffer (current-buffer)))
 970   ;; Insert the newly subscribed groups in the group buffer.
 971   (with-current-buffer gnus-group-buffer
 972     (gnus-group-list-groups nil))
 973   (if gnus-browse-return-buffer
 974       (gnus-configure-windows 'server 'force)
 975     (gnus-configure-windows 'group 'force)))
 976
 977 (defun gnus-browse-describe-briefly ()
 978   "Give a one line description of the group mode commands."
 979   (interactive)
 980   (gnus-message 6 "%s"
 981                 (substitute-command-keys "\\<gnus-browse-mode-map>\\[gnus-group-next-group]:Forward  \\[gnus-group-prev-group]:Backward  \\[gnus-browse-exit]:Exit  \\[gnus-info-find-node]:Run Info  \\[gnus-browse-describe-briefly]:This help")))
 982
 983 (defun gnus-server-regenerate-server ()
 984   "Issue a command to the server to regenerate all its data structures."
 985   (interactive)
 986   (let ((server (gnus-server-server-name)))
 987     (unless server
 988       (error "No server on the current line"))
 989     (condition-case ()
 990         (gnus-get-function (gnus-server-to-method server)
 991                            'request-regenerate)
 992       (error
 993         (error "This back end doesn't support regeneration")))
 994     (gnus-message 5 "Requesting regeneration of %s..." server)
 995     (unless (gnus-open-server server)
 996       (error "Couldn't open server"))
 997     (if (gnus-request-regenerate server)
 998         (gnus-message 5 "Requesting regeneration of %s...done" server)
 999       (gnus-message 5 "Couldn't regenerate %s" server))))
1000
1001
1002 ;;;
1003 ;;; Server compaction. -- dvl
1004 ;;;
1005
1006 ;; #### FIXME: this function currently fails to update the Group buffer's
1007 ;; #### appearance.
1008 (defun gnus-server-compact-server ()
1009   "Issue a command to the server to compact all its groups.
1010
1011 Note: currently only implemented in nnml."
1012   (interactive)
1013   (let ((server (gnus-server-server-name)))
1014     (unless server
1015       (error "No server on the current line"))
1016     (condition-case ()
1017         (gnus-get-function (gnus-server-to-method server)
1018                            'request-compact)
1019       (error
1020        (error "This back end doesn't support compaction")))
1021     (gnus-message 5 "\
1022 Requesting compaction of %s... (this may take a long time)"
1023                   server)
1024     (unless (gnus-open-server server)
1025       (error "Couldn't open server"))
1026     (if (not (gnus-request-compact server))
1027         (gnus-message 5 "Couldn't compact %s" server)
1028       (gnus-message 5 "Requesting compaction of %s...done" server)
1029       ;; Invalidate the original article buffer which might be out of date.
1030       ;; #### NOTE: Yes, this might be a bit rude, but since compaction
1031       ;; #### will not happen very often, I think this is acceptable.
1032       (let ((original (get-buffer gnus-original-article-buffer)))
1033         (and original (gnus-kill-buffer original))))))
1034
1035 (provide 'gnus-srvr)
1036
1037 ;;; gnus-srvr.el ends here