cgit.sxemacs.org Git - gnus/blob - lisp/gnus-srvr.el

   1 ;;; gnus-srvr.el --- virtual server support for Gnus
   2 ;; Copyright (C) 1995, 1996, 1997, 1998, 1999, 2000, 2001, 2002, 2003, 2004
   3 ;;        Free Software Foundation, Inc.
   4
   5 ;; Author: Lars Magne Ingebrigtsen <larsi@gnus.org>
   6 ;; Keywords: news
   7
   8 ;; This file is part of GNU Emacs.
   9
  10 ;; GNU Emacs is free software; you can redistribute it and/or modify
  11 ;; it under the terms of the GNU General Public License as published by
  12 ;; the Free Software Foundation; either version 2, or (at your option)
  13 ;; any later version.
  14
  15 ;; GNU Emacs is distributed in the hope that it will be useful,
  16 ;; but WITHOUT ANY WARRANTY; without even the implied warranty of
  17 ;; MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.  See the
  18 ;; GNU General Public License for more details.
  19
  20 ;; You should have received a copy of the GNU General Public License
  21 ;; along with GNU Emacs; see the file COPYING.  If not, write to the
  22 ;; Free Software Foundation, Inc., 59 Temple Place - Suite 330,
  23 ;; Boston, MA 02111-1307, USA.
  24
  25 ;;; Commentary:
  26
  27 ;;; Code:
  28
  29 (eval-when-compile (require 'cl))
  30
  31 (require 'gnus)
  32 (require 'gnus-spec)
  33 (require 'gnus-group)
  34 (require 'gnus-int)
  35 (require 'gnus-range)
  36
  37 (defcustom gnus-server-mode-hook nil
  38   "Hook run in `gnus-server-mode' buffers."
  39   :group 'gnus-server
  40   :type 'hook)
  41
  42 (defcustom gnus-server-exit-hook nil
  43   "Hook run when exiting the server buffer."
  44   :group 'gnus-server
  45   :type 'hook)
  46
  47 (defcustom gnus-server-line-format "     {%(%h:%w%)} %s%a\n"
  48   "Format of server lines.
  49 It works along the same lines as a normal formatting string,
  50 with some simple extensions.
  51
  52 The following specs are understood:
  53
  54 %h back end
  55 %n name
  56 %w address
  57 %s status
  58 %a agent covered
  59
  60 General format specifiers can also be used.
  61 See Info node `(gnus)Formatting Variables'."
  62   :link '(custom-manual "(gnus)Formatting Variables")
  63   :group 'gnus-server-visual
  64   :type 'string)
  65
  66 (defcustom gnus-server-mode-line-format "Gnus: %%b"
  67   "The format specification for the server mode line."
  68   :group 'gnus-server-visual
  69   :type 'string)
  70
  71 (defcustom gnus-server-browse-in-group-buffer nil
  72   "Whether server browsing should take place in the group buffer.
  73 If nil, a faster, but more primitive, buffer is used instead."
  74   :group 'gnus-server-visual
  75   :type 'boolean)
  76
  77 ;;; Internal variables.
  78
  79 (defvar gnus-inserted-opened-servers nil)
  80
  81 (defvar gnus-server-line-format-alist
  82   `((?h gnus-tmp-how ?s)
  83     (?n gnus-tmp-name ?s)
  84     (?w gnus-tmp-where ?s)
  85     (?s gnus-tmp-status ?s)
  86     (?a gnus-tmp-agent ?s)))
  87
  88 (defvar gnus-server-mode-line-format-alist
  89   `((?S gnus-tmp-news-server ?s)
  90     (?M gnus-tmp-news-method ?s)
  91     (?u gnus-tmp-user-defined ?s)))
  92
  93 (defvar gnus-server-line-format-spec nil)
  94 (defvar gnus-server-mode-line-format-spec nil)
  95 (defvar gnus-server-killed-servers nil)
  96
  97 (defvar gnus-server-mode-map)
  98
  99 (defvar gnus-server-menu-hook nil
 100   "*Hook run after the creation of the server mode menu.")
 101
 102 (defun gnus-server-make-menu-bar ()
 103   (gnus-turn-off-edit-menu 'server)
 104   (unless (boundp 'gnus-server-server-menu)
 105     (easy-menu-define
 106      gnus-server-server-menu gnus-server-mode-map ""
 107      '("Server"
 108        ["Add..." gnus-server-add-server t]
 109        ["Browse" gnus-server-read-server t]
 110        ["Scan" gnus-server-scan-server t]
 111        ["List" gnus-server-list-servers t]
 112        ["Kill" gnus-server-kill-server t]
 113        ["Yank" gnus-server-yank-server t]
 114        ["Copy" gnus-server-copy-server t]
 115        ["Edit" gnus-server-edit-server t]
 116        ["Regenerate" gnus-server-regenerate-server t]
 117        ["Exit" gnus-server-exit t]))
 118
 119     (easy-menu-define
 120      gnus-server-connections-menu gnus-server-mode-map ""
 121      '("Connections"
 122        ["Open" gnus-server-open-server t]
 123        ["Close" gnus-server-close-server t]
 124        ["Offline" gnus-server-offline-server t]
 125        ["Deny" gnus-server-deny-server t]
 126        "---"
 127        ["Open All" gnus-server-open-all-servers t]
 128        ["Close All" gnus-server-close-all-servers t]
 129        ["Reset All" gnus-server-remove-denials t]))
 130
 131     (gnus-run-hooks 'gnus-server-menu-hook)))
 132
 133 (defvar gnus-server-mode-map nil)
 134 (put 'gnus-server-mode 'mode-class 'special)
 135
 136 (unless gnus-server-mode-map
 137   (setq gnus-server-mode-map (make-sparse-keymap))
 138   (suppress-keymap gnus-server-mode-map)
 139
 140   (gnus-define-keys gnus-server-mode-map
 141     " " gnus-server-read-server-in-server-buffer
 142     "\r" gnus-server-read-server
 143     gnus-mouse-2 gnus-server-pick-server
 144     "q" gnus-server-exit
 145     "l" gnus-server-list-servers
 146     "k" gnus-server-kill-server
 147     "y" gnus-server-yank-server
 148     "c" gnus-server-copy-server
 149     "a" gnus-server-add-server
 150     "e" gnus-server-edit-server
 151     "s" gnus-server-scan-server
 152
 153     "O" gnus-server-open-server
 154     "\M-o" gnus-server-open-all-servers
 155     "C" gnus-server-close-server
 156     "\M-c" gnus-server-close-all-servers
 157     "D" gnus-server-deny-server
 158     "L" gnus-server-offline-server
 159     "R" gnus-server-remove-denials
 160
 161     "n" next-line
 162     "p" previous-line
 163
 164     "g" gnus-server-regenerate-server
 165
 166     "\C-c\C-i" gnus-info-find-node
 167     "\C-c\C-b" gnus-bug))
 168
 169 (defface gnus-server-agent-face
 170   '((((class color) (background light)) (:foreground "PaleTurquoise" :bold t))
 171     (((class color) (background dark)) (:foreground "PaleTurquoise" :bold t))
 172     (t (:bold t)))
 173   "Face used for displaying AGENTIZED servers"
 174   :group 'gnus-server-visual)
 175
 176 (defface gnus-server-opened-face
 177   '((((class color) (background light)) (:foreground "Green3" :bold t))
 178     (((class color) (background dark)) (:foreground "Green1" :bold t))
 179     (t (:bold t)))
 180   "Face used for displaying OPENED servers"
 181   :group 'gnus-server-visual)
 182
 183 (defface gnus-server-closed-face
 184   '((((class color) (background light)) (:foreground "Steel Blue" :italic t))
 185     (((class color) (background dark))
 186      (:foreground "Light Steel Blue" :italic t))
 187     (t (:italic t)))
 188   "Face used for displaying CLOSED servers"
 189   :group 'gnus-server-visual)
 190
 191 (defface gnus-server-denied-face
 192   '((((class color) (background light)) (:foreground "Red" :bold t))
 193     (((class color) (background dark)) (:foreground "Pink" :bold t))
 194     (t (:inverse-video t :bold t)))
 195   "Face used for displaying DENIED servers"
 196   :group 'gnus-server-visual)
 197
 198 (defface gnus-server-offline-face
 199   '((((class color) (background light)) (:foreground "Orange" :bold t))
 200     (((class color) (background dark)) (:foreground "Yellow" :bold t))
 201     (t (:inverse-video t :bold t)))
 202   "Face used for displaying OFFLINE servers"
 203   :group 'gnus-server-visual)
 204
 205 (defcustom gnus-server-agent-face 'gnus-server-agent-face
 206   "Face name to use on AGENTIZED servers."
 207   :group 'gnus-server-visual
 208   :type 'face)
 209
 210 (defcustom gnus-server-opened-face 'gnus-server-opened-face
 211   "Face name to use on OPENED servers."
 212   :group 'gnus-server-visual
 213   :type 'face)
 214
 215 (defcustom gnus-server-closed-face 'gnus-server-closed-face
 216   "Face name to use on CLOSED servers."
 217   :group 'gnus-server-visual
 218   :type 'face)
 219
 220 (defcustom gnus-server-denied-face 'gnus-server-denied-face
 221   "Face name to use on DENIED servers."
 222   :group 'gnus-server-visual
 223   :type 'face)
 224
 225 (defcustom gnus-server-offline-face 'gnus-server-offline-face
 226   "Face name to use on OFFLINE servers."
 227   :group 'gnus-server-visual
 228   :type 'face)
 229
 230 (defvar gnus-server-font-lock-keywords
 231   (list
 232    '("(\\(agent\\))" 1 gnus-server-agent-face)
 233    '("(\\(opened\\))" 1 gnus-server-opened-face)
 234    '("(\\(closed\\))" 1 gnus-server-closed-face)
 235    '("(\\(offline\\))" 1 gnus-server-offline-face)
 236    '("(\\(denied\\))" 1 gnus-server-denied-face)))
 237
 238 (defun gnus-server-mode ()
 239   "Major mode for listing and editing servers.
 240
 241 All normal editing commands are switched off.
 242 \\<gnus-server-mode-map>
 243 For more in-depth information on this mode, read the manual
 244 \(`\\[gnus-info-find-node]').
 245
 246 The following commands are available:
 247
 248 \\{gnus-server-mode-map}"
 249   (interactive)
 250   (when (gnus-visual-p 'server-menu 'menu)
 251     (gnus-server-make-menu-bar))
 252   (kill-all-local-variables)
 253   (gnus-simplify-mode-line)
 254   (setq major-mode 'gnus-server-mode)
 255   (setq mode-name "Server")
 256   (gnus-set-default-directory)
 257   (setq mode-line-process nil)
 258   (use-local-map gnus-server-mode-map)
 259   (buffer-disable-undo)
 260   (setq truncate-lines t)
 261   (setq buffer-read-only t)
 262   (if (featurep 'xemacs)
 263       (put 'gnus-server-mode 'font-lock-defaults '(gnus-server-font-lock-keywords t))
 264     (set (make-local-variable 'font-lock-defaults)
 265          '(gnus-server-font-lock-keywords t)))
 266   (gnus-run-hooks 'gnus-server-mode-hook))
 267
 268 (defun gnus-server-insert-server-line (gnus-tmp-name method)
 269   (let* ((gnus-tmp-how (car method))
 270          (gnus-tmp-where (nth 1 method))
 271          (elem (assoc method gnus-opened-servers))
 272          (gnus-tmp-status
 273           (cond
 274            ((eq (nth 1 elem) 'denied) "(denied)")
 275            ((eq (nth 1 elem) 'offline) "(offline)")
 276            (t
 277             (condition-case nil
 278                 (if (or (gnus-server-opened method)
 279                         (eq (nth 1 elem) 'ok))
 280                     "(opened)"
 281                   "(closed)")
 282               ((error) "(error)")))))
 283          (gnus-tmp-agent (if (and gnus-agent
 284                                   (gnus-agent-method-p method))
 285                              " (agent)"
 286                            "")))
 287     (beginning-of-line)
 288     (gnus-add-text-properties
 289      (point)
 290      (prog1 (1+ (point))
 291        ;; Insert the text.
 292        (eval gnus-server-line-format-spec))
 293      (list 'gnus-server (intern gnus-tmp-name)
 294            'gnus-named-server (intern (gnus-method-to-server method))))))
 295
 296 (defun gnus-enter-server-buffer ()
 297   "Set up the server buffer."
 298   (gnus-server-setup-buffer)
 299   (gnus-configure-windows 'server)
 300   (gnus-server-prepare))
 301
 302 (defun gnus-server-setup-buffer ()
 303   "Initialize the server buffer."
 304   (unless (get-buffer gnus-server-buffer)
 305     (save-excursion
 306       (set-buffer (gnus-get-buffer-create gnus-server-buffer))
 307       (gnus-server-mode)
 308       (when gnus-carpal
 309         (gnus-carpal-setup-buffer 'server)))))
 310
 311 (defun gnus-server-prepare ()
 312   (gnus-set-format 'server-mode)
 313   (gnus-set-format 'server t)
 314   (let ((alist gnus-server-alist)
 315         (buffer-read-only nil)
 316         (opened gnus-opened-servers)
 317         done server op-ser)
 318     (erase-buffer)
 319     (setq gnus-inserted-opened-servers nil)
 320     ;; First we do the real list of servers.
 321     (while alist
 322       (unless (member (cdar alist) done)
 323         (push (cdar alist) done)
 324         (setq server (pop alist))
 325         (when (and server (car server) (cdr server))
 326           (gnus-server-insert-server-line (car server) (cdr server))))
 327       (when (member (cdar alist) done)
 328         (pop alist)))
 329     ;; Then we insert the list of servers that have been opened in
 330     ;; this session.
 331     (while opened
 332       (when (and (not (member (caar opened) done))
 333                  ;; Just ignore ephemeral servers.
 334                  (not (member (caar opened) gnus-ephemeral-servers)))
 335         (push (caar opened) done)
 336         (gnus-server-insert-server-line
 337          (setq op-ser (format "%s:%s" (caaar opened) (nth 1 (caar opened))))
 338          (caar opened))
 339         (push (list op-ser (caar opened)) gnus-inserted-opened-servers))
 340       (setq opened (cdr opened))))
 341   (goto-char (point-min))
 342   (gnus-server-position-point))
 343
 344 (defun gnus-server-server-name ()
 345   (let ((server (get-text-property (point-at-bol) 'gnus-server)))
 346     (and server (symbol-name server))))
 347
 348 (defun gnus-server-named-server ()
 349   "Return a server name that matches one of the names returned by
 350 `gnus-method-to-server'."
 351   (let ((server (get-text-property (point-at-bol) 'gnus-named-server)))
 352     (and server (symbol-name server))))
 353
 354 (defalias 'gnus-server-position-point 'gnus-goto-colon)
 355
 356 (defconst gnus-server-edit-buffer "*Gnus edit server*")
 357
 358 (defun gnus-server-update-server (server)
 359   (save-excursion
 360     (set-buffer gnus-server-buffer)
 361     (let* ((buffer-read-only nil)
 362            (entry (assoc server gnus-server-alist))
 363            (oentry (assoc (gnus-server-to-method server)
 364                           gnus-opened-servers)))
 365       (when entry
 366         (gnus-dribble-enter
 367          (concat "(gnus-server-set-info \"" server "\" '"
 368                  (gnus-prin1-to-string (cdr entry)) ")\n")))
 369       (when (or entry oentry)
 370         ;; Buffer may be narrowed.
 371         (save-restriction
 372           (widen)
 373           (when (gnus-server-goto-server server)
 374             (gnus-delete-line))
 375           (if entry
 376               (gnus-server-insert-server-line (car entry) (cdr entry))
 377             (gnus-server-insert-server-line
 378              (format "%s:%s" (caar oentry) (nth 1 (car oentry)))
 379              (car oentry)))
 380           (gnus-server-position-point))))))
 381
 382 (defun gnus-server-set-info (server info)
 383   ;; Enter a select method into the virtual server alist.
 384   (when (and server info)
 385     (gnus-dribble-enter
 386      (concat "(gnus-server-set-info \"" server "\" '"
 387              (gnus-prin1-to-string info) ")"))
 388     (let* ((server (nth 1 info))
 389            (entry (assoc server gnus-server-alist))
 390            (cached (assoc server gnus-server-method-cache)))
 391       (if cached
 392           (setq gnus-server-method-cache
 393                 (delq cached gnus-server-method-cache)))
 394       (if entry
 395           (progn
 396             ;; Remove the server from `gnus-opened-servers' since
 397             ;; it has never been opened with the new `info' yet.
 398             (gnus-opened-servers-remove (cdr entry))
 399             (setcdr entry info))
 400         (setq gnus-server-alist
 401               (nconc gnus-server-alist (list (cons server info))))))))
 402
 403 ;;; Interactive server functions.
 404
 405 (defun gnus-server-kill-server (server)
 406   "Kill the server on the current line."
 407   (interactive (list (gnus-server-server-name)))
 408   (unless (gnus-server-goto-server server)
 409     (if server (error "No such server: %s" server)
 410       (error "No server on the current line")))
 411   (unless (assoc server gnus-server-alist)
 412     (error "Read-only server %s" server))
 413   (gnus-dribble-touch)
 414   (let ((buffer-read-only nil))
 415     (gnus-delete-line))
 416   (push (assoc server gnus-server-alist) gnus-server-killed-servers)
 417   (setq gnus-server-alist (delq (car gnus-server-killed-servers)
 418                                 gnus-server-alist))
 419   (let ((groups (gnus-groups-from-server server)))
 420     (when (and groups
 421                (gnus-yes-or-no-p
 422                 (format "Kill all %s groups from this server? "
 423                         (length groups))))
 424       (dolist (group groups)
 425         (setq gnus-newsrc-alist
 426               (delq (assoc group gnus-newsrc-alist)
 427                     gnus-newsrc-alist))
 428         (when gnus-group-change-level-function
 429           (funcall gnus-group-change-level-function
 430                    group gnus-level-killed 3)))))
 431   (gnus-server-position-point))
 432
 433 (defun gnus-server-yank-server ()
 434   "Yank the previously killed server."
 435   (interactive)
 436   (unless gnus-server-killed-servers
 437     (error "No killed servers to be yanked"))
 438   (let ((alist gnus-server-alist)
 439         (server (gnus-server-server-name))
 440         (killed (car gnus-server-killed-servers)))
 441     (if (not server)
 442         (setq gnus-server-alist (nconc gnus-server-alist (list killed)))
 443       (if (string= server (caar gnus-server-alist))
 444           (push killed gnus-server-alist)
 445         (while (and (cdr alist)
 446                     (not (string= server (caadr alist))))
 447           (setq alist (cdr alist)))
 448         (if alist
 449             (setcdr alist (cons killed (cdr alist)))
 450           (setq gnus-server-alist (list killed)))))
 451     (gnus-server-update-server (car killed))
 452     (setq gnus-server-killed-servers (cdr gnus-server-killed-servers))
 453     (gnus-server-position-point)))
 454
 455 (defun gnus-server-exit ()
 456   "Return to the group buffer."
 457   (interactive)
 458   (gnus-run-hooks 'gnus-server-exit-hook)
 459   (gnus-kill-buffer (current-buffer))
 460   (gnus-configure-windows 'group t))
 461
 462 (defun gnus-server-list-servers ()
 463   "List all available servers."
 464   (interactive)
 465   (let ((cur (gnus-server-server-name)))
 466     (gnus-server-prepare)
 467     (if cur (gnus-server-goto-server cur)
 468       (goto-char (point-max))
 469       (forward-line -1))
 470     (gnus-server-position-point)))
 471
 472 (defun gnus-server-set-status (method status)
 473   "Make METHOD have STATUS."
 474   (let ((entry (assoc method gnus-opened-servers)))
 475     (if entry
 476         (setcar (cdr entry) status)
 477       (push (list method status) gnus-opened-servers))))
 478
 479 (defun gnus-opened-servers-remove (method)
 480   "Remove METHOD from the list of opened servers."
 481   (setq gnus-opened-servers (delq (assoc method gnus-opened-servers)
 482                                   gnus-opened-servers)))
 483
 484 (defun gnus-server-open-server (server)
 485   "Force an open of SERVER."
 486   (interactive (list (gnus-server-server-name)))
 487   (let ((method (gnus-server-to-method server)))
 488     (unless method
 489       (error "No such server: %s" server))
 490     (gnus-server-set-status method 'ok)
 491     (prog1
 492         (or (gnus-open-server method)
 493             (progn (message "Couldn't open %s" server) nil))
 494       (gnus-server-update-server server)
 495       (gnus-server-position-point))))
 496
 497 (defun gnus-server-open-all-servers ()
 498   "Open all servers."
 499   (interactive)
 500   (let ((servers gnus-inserted-opened-servers))
 501     (while servers
 502       (gnus-server-open-server (car (pop servers))))))
 503
 504 (defun gnus-server-close-server (server)
 505   "Close SERVER."
 506   (interactive (list (gnus-server-server-name)))
 507   (let ((method (gnus-server-to-method server)))
 508     (unless method
 509       (error "No such server: %s" server))
 510     (gnus-server-set-status method 'closed)
 511     (prog1
 512         (gnus-close-server method)
 513       (gnus-server-update-server server)
 514       (gnus-server-position-point))))
 515
 516 (defun gnus-server-offline-server (server)
 517   "Set SERVER to offline."
 518   (interactive (list (gnus-server-server-name)))
 519   (let ((method (gnus-server-to-method server)))
 520     (unless method
 521       (error "No such server: %s" server))
 522     (prog1
 523         (gnus-close-server method)
 524       (gnus-server-set-status method 'offline)
 525       (gnus-server-update-server server)
 526       (gnus-server-position-point))))
 527
 528 (defun gnus-server-close-all-servers ()
 529   "Close all servers."
 530   (interactive)
 531   (dolist (server gnus-inserted-opened-servers)
 532     (gnus-server-close-server (car server))))
 533
 534 (defun gnus-server-deny-server (server)
 535   "Make sure SERVER will never be attempted opened."
 536   (interactive (list (gnus-server-server-name)))
 537   (let ((method (gnus-server-to-method server)))
 538     (unless method
 539       (error "No such server: %s" server))
 540     (gnus-server-set-status method 'denied))
 541   (gnus-server-update-server server)
 542   (gnus-server-position-point)
 543   t)
 544
 545 (defun gnus-server-remove-denials ()
 546   "Make all denied servers into closed servers."
 547   (interactive)
 548   (dolist (server gnus-opened-servers)
 549     (when (eq (nth 1 server) 'denied)
 550       (setcar (nthcdr 1 server) 'closed)))
 551   (gnus-server-list-servers))
 552
 553 (defun gnus-server-copy-server (from to)
 554   (interactive
 555    (list
 556     (or (gnus-server-server-name)
 557         (error "No server on the current line"))
 558     (read-string "Copy to: ")))
 559   (unless from
 560     (error "No server on current line"))
 561   (unless (and to (not (string= to "")))
 562     (error "No name to copy to"))
 563   (when (assoc to gnus-server-alist)
 564     (error "%s already exists" to))
 565   (unless (gnus-server-to-method from)
 566     (error "%s: no such server" from))
 567   (let ((to-entry (cons from (gnus-copy-sequence
 568                               (gnus-server-to-method from)))))
 569     (setcar to-entry to)
 570     (setcar (nthcdr 2 to-entry) to)
 571     (push to-entry gnus-server-killed-servers)
 572     (gnus-server-yank-server)))
 573
 574 (defun gnus-server-add-server (how where)
 575   (interactive
 576    (list (intern (completing-read "Server method: "
 577                                   gnus-valid-select-methods nil t))
 578          (read-string "Server name: ")))
 579   (when (assq where gnus-server-alist)
 580     (error "Server with that name already defined"))
 581   (push (list where how where) gnus-server-killed-servers)
 582   (gnus-server-yank-server))
 583
 584 (defun gnus-server-goto-server (server)
 585   "Jump to a server line."
 586   (interactive
 587    (list (completing-read "Goto server: " gnus-server-alist nil t)))
 588   (let ((to (text-property-any (point-min) (point-max)
 589                                'gnus-server (intern server))))
 590     (when to
 591       (goto-char to)
 592       (gnus-server-position-point))))
 593
 594 (defun gnus-server-edit-server (server)
 595   "Edit the server on the current line."
 596   (interactive (list (gnus-server-server-name)))
 597   (unless server
 598     (error "No server on current line"))
 599   (unless (assoc server gnus-server-alist)
 600     (error "This server can't be edited"))
 601   (let ((info (cdr (assoc server gnus-server-alist))))
 602     (gnus-close-server info)
 603     (gnus-edit-form
 604      info "Editing the server."
 605      `(lambda (form)
 606         (gnus-server-set-info ,server form)
 607         (gnus-server-list-servers)
 608         (gnus-server-position-point)))))
 609
 610 (defun gnus-server-scan-server (server)
 611   "Request a scan from the current server."
 612   (interactive (list (gnus-server-server-name)))
 613   (let ((method (gnus-server-to-method server)))
 614     (if (not (gnus-get-function method 'request-scan))
 615         (error "Server %s can't scan" (car method))
 616       (gnus-message 3 "Scanning %s..." server)
 617       (gnus-request-scan nil method)
 618       (gnus-message 3 "Scanning %s...done" server))))
 619
 620 (defun gnus-server-read-server-in-server-buffer (server)
 621   "Browse a server in server buffer."
 622   (interactive (list (gnus-server-server-name)))
 623   (let (gnus-server-browse-in-group-buffer)
 624     (gnus-server-read-server server)))
 625
 626 (defun gnus-server-read-server (server)
 627   "Browse a server."
 628   (interactive (list (gnus-server-server-name)))
 629   (let ((buf (current-buffer)))
 630     (prog1
 631         (gnus-browse-foreign-server server buf)
 632       (save-excursion
 633         (set-buffer buf)
 634         (gnus-server-update-server (gnus-server-server-name))
 635         (gnus-server-position-point)))))
 636
 637 (defun gnus-server-pick-server (e)
 638   (interactive "e")
 639   (mouse-set-point e)
 640   (gnus-server-read-server (gnus-server-server-name)))
 641
 642 \f
 643 ;;;
 644 ;;; Browse Server Mode
 645 ;;;
 646
 647 (defvar gnus-browse-menu-hook nil
 648   "*Hook run after the creation of the browse mode menu.")
 649
 650 (defvar gnus-browse-mode-hook nil)
 651 (defvar gnus-browse-mode-map nil)
 652 (put 'gnus-browse-mode 'mode-class 'special)
 653
 654 (unless gnus-browse-mode-map
 655   (setq gnus-browse-mode-map (make-keymap))
 656   (suppress-keymap gnus-browse-mode-map)
 657
 658   (gnus-define-keys
 659       gnus-browse-mode-map
 660     " " gnus-browse-read-group
 661     "=" gnus-browse-select-group
 662     "n" gnus-browse-next-group
 663     "p" gnus-browse-prev-group
 664     "\177" gnus-browse-prev-group
 665     [delete] gnus-browse-prev-group
 666     "N" gnus-browse-next-group
 667     "P" gnus-browse-prev-group
 668     "\M-n" gnus-browse-next-group
 669     "\M-p" gnus-browse-prev-group
 670     "\r" gnus-browse-select-group
 671     "u" gnus-browse-unsubscribe-current-group
 672     "l" gnus-browse-exit
 673     "L" gnus-browse-exit
 674     "q" gnus-browse-exit
 675     "Q" gnus-browse-exit
 676     "d" gnus-browse-describe-group
 677     "\C-c\C-c" gnus-browse-exit
 678     "?" gnus-browse-describe-briefly
 679
 680     "\C-c\C-i" gnus-info-find-node
 681     "\C-c\C-b" gnus-bug))
 682
 683 (defun gnus-browse-make-menu-bar ()
 684   (gnus-turn-off-edit-menu 'browse)
 685   (unless (boundp 'gnus-browse-menu)
 686     (easy-menu-define
 687      gnus-browse-menu gnus-browse-mode-map ""
 688      '("Browse"
 689        ["Subscribe" gnus-browse-unsubscribe-current-group t]
 690        ["Read" gnus-browse-read-group t]
 691        ["Select" gnus-browse-select-group t]
 692        ["Describe" gnus-browse-describe-group t]
 693        ["Next" gnus-browse-next-group t]
 694        ["Prev" gnus-browse-prev-group t]
 695        ["Exit" gnus-browse-exit t]))
 696     (gnus-run-hooks 'gnus-browse-menu-hook)))
 697
 698 (defvar gnus-browse-current-method nil)
 699 (defvar gnus-browse-return-buffer nil)
 700
 701 (defvar gnus-browse-buffer "*Gnus Browse Server*")
 702
 703 (defun gnus-browse-foreign-server (server &optional return-buffer)
 704   "Browse the server SERVER."
 705   (setq gnus-browse-current-method (gnus-server-to-method server))
 706   (setq gnus-browse-return-buffer return-buffer)
 707   (let* ((method gnus-browse-current-method)
 708          (orig-select-method gnus-select-method)
 709          (gnus-select-method method)
 710          groups group)
 711     (gnus-message 5 "Connecting to %s..." (nth 1 method))
 712     (cond
 713      ((not (gnus-check-server method))
 714       (gnus-message
 715        1 "Unable to contact server %s: %s" (nth 1 method)
 716        (gnus-status-message method))
 717       nil)
 718      ((not
 719        (prog2
 720            (gnus-message 6 "Reading active file...")
 721            (gnus-request-list method)
 722          (gnus-message 6 "Reading active file...done")))
 723       (gnus-message
 724        1 "Couldn't request list: %s" (gnus-status-message method))
 725       nil)
 726      (t
 727       (with-current-buffer nntp-server-buffer
 728         (let ((cur (current-buffer)))
 729           (goto-char (point-min))
 730           (unless (string= gnus-ignored-newsgroups "")
 731             (delete-matching-lines gnus-ignored-newsgroups))
 732           ;; We treat NNTP as a special case to avoid problems with
 733           ;; garbage group names like `"foo' that appear in some badly
 734           ;; managed active files. -jh.
 735           (if (eq (car method) 'nntp)
 736               (while (not (eobp))
 737                 (ignore-errors
 738                   (push (cons
 739                          (buffer-substring
 740                           (point)
 741                           (progn
 742                             (skip-chars-forward "^ \t")
 743                             (point)))
 744                          (let ((last (read cur)))
 745                            (cons (read cur) last)))
 746                         groups))
 747                 (forward-line))
 748             (while (not (eobp))
 749               (ignore-errors
 750                 (push (cons
 751                        (if (eq (char-after) ?\")
 752                            (read cur)
 753                          (let ((p (point)) (name ""))
 754                            (skip-chars-forward "^ \t\\\\")
 755                            (setq name (buffer-substring p (point)))
 756                            (while (eq (char-after) ?\\)
 757                              (setq p (1+ (point)))
 758                              (forward-char 2)
 759                              (skip-chars-forward "^ \t\\\\")
 760                              (setq name (concat name (buffer-substring
 761                                                       p (point)))))
 762                            name))
 763                        (let ((last (read cur)))
 764                          (cons (read cur) last)))
 765                       groups))
 766               (forward-line)))))
 767       (setq groups (sort groups
 768                          (lambda (l1 l2)
 769                            (string< (car l1) (car l2)))))
 770       (if gnus-server-browse-in-group-buffer
 771           (let* ((gnus-select-method orig-select-method)
 772                  (gnus-group-listed-groups
 773                   (mapcar (lambda (group)
 774                             (let ((name
 775                                    (gnus-group-prefixed-name
 776                                     (car group) method)))
 777                               (gnus-set-active name (cdr group))
 778                               name))
 779                           groups)))
 780             (gnus-configure-windows 'group)
 781             (funcall gnus-group-prepare-function
 782                      gnus-level-killed 'ignore 1 'ignore))
 783         (gnus-get-buffer-create gnus-browse-buffer)
 784         (when gnus-carpal
 785           (gnus-carpal-setup-buffer 'browse))
 786         (gnus-configure-windows 'browse)
 787         (buffer-disable-undo)
 788         (let ((buffer-read-only nil))
 789           (erase-buffer))
 790         (gnus-browse-mode)
 791         (setq mode-line-buffer-identification
 792               (list
 793                (format
 794                 "Gnus: %%b {%s:%s}" (car method) (cadr method))))
 795         (let ((buffer-read-only nil)
 796               name
 797               (prefix (let ((gnus-select-method orig-select-method))
 798                         (gnus-group-prefixed-name "" method))))
 799           (while (setq group (pop groups))
 800             (gnus-add-text-properties
 801              (point)
 802              (prog1 (1+ (point))
 803                (insert
 804                 (format "%c%7d: %s\n"
 805                         (let ((level
 806                                (if (string= prefix "")
 807                                    (gnus-group-level (setq name (car group)))
 808                                  (gnus-group-level
 809                                   (concat prefix (setq name (car group)))))))
 810                           (cond
 811                            ((<= level gnus-level-subscribed) ? )
 812                            ((<= level gnus-level-unsubscribed) ?U)
 813                            ((= level gnus-level-zombie) ?Z)
 814                            (t ?K)))
 815                         (max 0 (- (1+ (cddr group)) (cadr group)))
 816                         ;; Don't decode if name is ASCII
 817                         (if (and (fboundp 'detect-coding-string)
 818                                  (eq (detect-coding-string name t) 'undecided))
 819                             name
 820                           (mm-decode-coding-string
 821                            name
 822                            (inline (gnus-group-name-charset method name)))))))
 823              (list 'gnus-group name)
 824              )))
 825         (switch-to-buffer (current-buffer)))
 826       (goto-char (point-min))
 827       (gnus-group-position-point)
 828       (gnus-message 5 "Connecting to %s...done" (nth 1 method))
 829       t))))
 830
 831 (defun gnus-browse-mode ()
 832   "Major mode for browsing a foreign server.
 833
 834 All normal editing commands are switched off.
 835
 836 \\<gnus-browse-mode-map>
 837 The only things you can do in this buffer is
 838
 839 1) `\\[gnus-browse-unsubscribe-current-group]' to subscribe to a group.
 840 The group will be inserted into the group buffer upon exit from this
 841 buffer.
 842
 843 2) `\\[gnus-browse-read-group]' to read a group ephemerally.
 844
 845 3) `\\[gnus-browse-exit]' to return to the group buffer."
 846   (interactive)
 847   (kill-all-local-variables)
 848   (when (gnus-visual-p 'browse-menu 'menu)
 849     (gnus-browse-make-menu-bar))
 850   (gnus-simplify-mode-line)
 851   (setq major-mode 'gnus-browse-mode)
 852   (setq mode-name "Browse Server")
 853   (setq mode-line-process nil)
 854   (use-local-map gnus-browse-mode-map)
 855   (buffer-disable-undo)
 856   (setq truncate-lines t)
 857   (gnus-set-default-directory)
 858   (setq buffer-read-only t)
 859   (gnus-run-hooks 'gnus-browse-mode-hook))
 860
 861 (defun gnus-browse-read-group (&optional no-article)
 862   "Enter the group at the current line."
 863   (interactive)
 864   (let ((group (gnus-browse-group-name)))
 865     (if (or (not (gnus-get-info group))
 866             (gnus-ephemeral-group-p group))
 867         (unless (gnus-group-read-ephemeral-group
 868                  group gnus-browse-current-method nil
 869                  (cons (current-buffer) 'browse))
 870           (error "Couldn't enter %s" group))
 871       (unless (gnus-group-read-group nil no-article group)
 872         (error "Couldn't enter %s" group)))))
 873
 874 (defun gnus-browse-select-group ()
 875   "Select the current group."
 876   (interactive)
 877   (gnus-browse-read-group 'no))
 878
 879 (defun gnus-browse-next-group (n)
 880   "Go to the next group."
 881   (interactive "p")
 882   (prog1
 883       (forward-line n)
 884     (gnus-group-position-point)))
 885
 886 (defun gnus-browse-prev-group (n)
 887   "Go to the next group."
 888   (interactive "p")
 889   (gnus-browse-next-group (- n)))
 890
 891 (defun gnus-browse-unsubscribe-current-group (arg)
 892   "(Un)subscribe to the next ARG groups."
 893   (interactive "p")
 894   (when (eobp)
 895     (error "No group at current line"))
 896   (let ((ward (if (< arg 0) -1 1))
 897         (arg (abs arg)))
 898     (while (and (> arg 0)
 899                 (not (eobp))
 900                 (gnus-browse-unsubscribe-group)
 901                 (zerop (gnus-browse-next-group ward)))
 902       (decf arg))
 903     (gnus-group-position-point)
 904     (when (/= 0 arg)
 905       (gnus-message 7 "No more newsgroups"))
 906     arg))
 907
 908 (defun gnus-browse-group-name ()
 909   (save-excursion
 910     (beginning-of-line)
 911     (let ((name (get-text-property (point) 'gnus-group)))
 912       (when (re-search-forward ": \\(.*\\)$" (point-at-eol) t)
 913         (concat (gnus-method-to-server-name gnus-browse-current-method) ":"
 914                 (or name
 915                     (match-string-no-properties 1)))))))
 916
 917 (defun gnus-browse-describe-group (group)
 918   "Describe the current group."
 919   (interactive (list (gnus-browse-group-name)))
 920   (gnus-group-describe-group nil group))
 921
 922 (defun gnus-browse-unsubscribe-group ()
 923   "Toggle subscription of the current group in the browse buffer."
 924   (let ((sub nil)
 925         (buffer-read-only nil)
 926         group)
 927     (save-excursion
 928       (beginning-of-line)
 929       ;; If this group it killed, then we want to subscribe it.
 930       (unless (eq (char-after) ? )
 931         (setq sub t))
 932       (setq group (gnus-browse-group-name))
 933       (when (gnus-server-equal gnus-browse-current-method "native")
 934         (setq group (gnus-group-real-name group)))
 935       (if sub
 936           (progn
 937             ;; Make sure the group has been properly removed before we
 938             ;; subscribe to it.
 939             (gnus-kill-ephemeral-group group)
 940             (gnus-group-change-level
 941              (list t group gnus-level-default-subscribed
 942                    nil nil (if (gnus-server-equal
 943                                 gnus-browse-current-method "native")
 944                                nil
 945                              (gnus-method-simplify
 946                               gnus-browse-current-method)))
 947              gnus-level-default-subscribed (gnus-group-level group)
 948              (and (car (nth 1 gnus-newsrc-alist))
 949                   (gnus-group-entry (car (nth 1 gnus-newsrc-alist))))
 950              t)
 951             (delete-char 1)
 952             (insert ? ))
 953         (gnus-group-change-level
 954          group gnus-level-unsubscribed gnus-level-default-subscribed)
 955         (delete-char 1)
 956         (insert ?U)))
 957     t))
 958
 959 (defun gnus-browse-exit ()
 960   "Quit browsing and return to the group buffer."
 961   (interactive)
 962   (when (eq major-mode 'gnus-browse-mode)
 963     (gnus-kill-buffer (current-buffer)))
 964   ;; Insert the newly subscribed groups in the group buffer.
 965   (save-excursion
 966     (set-buffer gnus-group-buffer)
 967     (gnus-group-list-groups nil))
 968   (if gnus-browse-return-buffer
 969       (gnus-configure-windows 'server 'force)
 970     (gnus-configure-windows 'group 'force)))
 971
 972 (defun gnus-browse-describe-briefly ()
 973   "Give a one line description of the group mode commands."
 974   (interactive)
 975   (gnus-message 6
 976                 (substitute-command-keys "\\<gnus-browse-mode-map>\\[gnus-group-next-group]:Forward  \\[gnus-group-prev-group]:Backward  \\[gnus-browse-exit]:Exit  \\[gnus-info-find-node]:Run Info  \\[gnus-browse-describe-briefly]:This help")))
 977
 978 (defun gnus-server-regenerate-server ()
 979   "Issue a command to the server to regenerate all its data structures."
 980   (interactive)
 981   (let ((server (gnus-server-server-name)))
 982     (unless server
 983       (error "No server on the current line"))
 984     (condition-case ()
 985         (gnus-get-function (gnus-server-to-method server)
 986                            'request-regenerate)
 987       (error
 988         (error "This back end doesn't support regeneration")))
 989     (gnus-message 5 "Requesting regeneration of %s..." server)
 990     (unless (gnus-open-server server)
 991       (error "Couldn't open server"))
 992     (if (gnus-request-regenerate server)
 993         (gnus-message 5 "Requesting regeneration of %s...done" server)
 994       (gnus-message 5 "Couldn't regenerate %s" server))))
 995
 996 (provide 'gnus-srvr)
 997
 998 ;;; arch-tag: c0117f64-27ca-475d-9406-8da6854c7a25
 999 ;;; gnus-srvr.el ends here