cgit.sxemacs.org Git - gnus/blob - lisp/gnus-srvr.el

   1 ;;; gnus-srvr.el --- virtual server support for Gnus
   2 ;; Copyright (C) 1995, 1996, 1997, 1998, 1999, 2000, 2001, 2002, 2003,
   3 ;; 2004, 2005
   4 ;;        Free Software Foundation, Inc.
   5
   6 ;; Author: Lars Magne Ingebrigtsen <larsi@gnus.org>
   7 ;; Keywords: news
   8
   9 ;; This file is part of GNU Emacs.
  10
  11 ;; GNU Emacs is free software; you can redistribute it and/or modify
  12 ;; it under the terms of the GNU General Public License as published by
  13 ;; the Free Software Foundation; either version 2, or (at your option)
  14 ;; any later version.
  15
  16 ;; GNU Emacs is distributed in the hope that it will be useful,
  17 ;; but WITHOUT ANY WARRANTY; without even the implied warranty of
  18 ;; MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.  See the
  19 ;; GNU General Public License for more details.
  20
  21 ;; You should have received a copy of the GNU General Public License
  22 ;; along with GNU Emacs; see the file COPYING.  If not, write to the
  23 ;; Free Software Foundation, Inc., 59 Temple Place - Suite 330,
  24 ;; Boston, MA 02111-1307, USA.
  25
  26 ;;; Commentary:
  27
  28 ;;; Code:
  29
  30 (eval-when-compile (require 'cl))
  31
  32 (require 'gnus)
  33 (require 'gnus-spec)
  34 (require 'gnus-group)
  35 (require 'gnus-int)
  36 (require 'gnus-range)
  37
  38 (defcustom gnus-server-mode-hook nil
  39   "Hook run in `gnus-server-mode' buffers."
  40   :group 'gnus-server
  41   :type 'hook)
  42
  43 (defcustom gnus-server-exit-hook nil
  44   "Hook run when exiting the server buffer."
  45   :group 'gnus-server
  46   :type 'hook)
  47
  48 (defcustom gnus-server-line-format "     {%(%h:%w%)} %s%a\n"
  49   "Format of server lines.
  50 It works along the same lines as a normal formatting string,
  51 with some simple extensions.
  52
  53 The following specs are understood:
  54
  55 %h back end
  56 %n name
  57 %w address
  58 %s status
  59 %a agent covered
  60
  61 General format specifiers can also be used.
  62 See Info node `(gnus)Formatting Variables'."
  63   :link '(custom-manual "(gnus)Formatting Variables")
  64   :group 'gnus-server-visual
  65   :type 'string)
  66
  67 (defcustom gnus-server-mode-line-format "Gnus: %%b"
  68   "The format specification for the server mode line."
  69   :group 'gnus-server-visual
  70   :type 'string)
  71
  72 (defcustom gnus-server-browse-in-group-buffer nil
  73   "Whether server browsing should take place in the group buffer.
  74 If nil, a faster, but more primitive, buffer is used instead."
  75   :version "22.1"
  76   :group 'gnus-server-visual
  77   :type 'boolean)
  78
  79 ;;; Internal variables.
  80
  81 (defvar gnus-inserted-opened-servers nil)
  82
  83 (defvar gnus-server-line-format-alist
  84   `((?h gnus-tmp-how ?s)
  85     (?n gnus-tmp-name ?s)
  86     (?w gnus-tmp-where ?s)
  87     (?s gnus-tmp-status ?s)
  88     (?a gnus-tmp-agent ?s)))
  89
  90 (defvar gnus-server-mode-line-format-alist
  91   `((?S gnus-tmp-news-server ?s)
  92     (?M gnus-tmp-news-method ?s)
  93     (?u gnus-tmp-user-defined ?s)))
  94
  95 (defvar gnus-server-line-format-spec nil)
  96 (defvar gnus-server-mode-line-format-spec nil)
  97 (defvar gnus-server-killed-servers nil)
  98
  99 (defvar gnus-server-mode-map)
 100
 101 (defvar gnus-server-menu-hook nil
 102   "*Hook run after the creation of the server mode menu.")
 103
 104 (defun gnus-server-make-menu-bar ()
 105   (gnus-turn-off-edit-menu 'server)
 106   (unless (boundp 'gnus-server-server-menu)
 107     (easy-menu-define
 108      gnus-server-server-menu gnus-server-mode-map ""
 109      '("Server"
 110        ["Add..." gnus-server-add-server t]
 111        ["Browse" gnus-server-read-server t]
 112        ["Scan" gnus-server-scan-server t]
 113        ["List" gnus-server-list-servers t]
 114        ["Kill" gnus-server-kill-server t]
 115        ["Yank" gnus-server-yank-server t]
 116        ["Copy" gnus-server-copy-server t]
 117        ["Edit" gnus-server-edit-server t]
 118        ["Regenerate" gnus-server-regenerate-server t]
 119        ["Exit" gnus-server-exit t]))
 120
 121     (easy-menu-define
 122      gnus-server-connections-menu gnus-server-mode-map ""
 123      '("Connections"
 124        ["Open" gnus-server-open-server t]
 125        ["Close" gnus-server-close-server t]
 126        ["Offline" gnus-server-offline-server t]
 127        ["Deny" gnus-server-deny-server t]
 128        "---"
 129        ["Open All" gnus-server-open-all-servers t]
 130        ["Close All" gnus-server-close-all-servers t]
 131        ["Reset All" gnus-server-remove-denials t]))
 132
 133     (gnus-run-hooks 'gnus-server-menu-hook)))
 134
 135 (defvar gnus-server-mode-map nil)
 136 (put 'gnus-server-mode 'mode-class 'special)
 137
 138 (unless gnus-server-mode-map
 139   (setq gnus-server-mode-map (make-sparse-keymap))
 140   (suppress-keymap gnus-server-mode-map)
 141
 142   (gnus-define-keys gnus-server-mode-map
 143     " " gnus-server-read-server-in-server-buffer
 144     "\r" gnus-server-read-server
 145     gnus-mouse-2 gnus-server-pick-server
 146     "q" gnus-server-exit
 147     "l" gnus-server-list-servers
 148     "k" gnus-server-kill-server
 149     "y" gnus-server-yank-server
 150     "c" gnus-server-copy-server
 151     "a" gnus-server-add-server
 152     "e" gnus-server-edit-server
 153     "s" gnus-server-scan-server
 154
 155     "O" gnus-server-open-server
 156     "\M-o" gnus-server-open-all-servers
 157     "C" gnus-server-close-server
 158     "\M-c" gnus-server-close-all-servers
 159     "D" gnus-server-deny-server
 160     "L" gnus-server-offline-server
 161     "R" gnus-server-remove-denials
 162
 163     "n" next-line
 164     "p" previous-line
 165
 166     "g" gnus-server-regenerate-server
 167
 168     "\C-c\C-i" gnus-info-find-node
 169     "\C-c\C-b" gnus-bug))
 170
 171 (defface gnus-server-agent-face
 172   '((((class color) (background light)) (:foreground "PaleTurquoise" :bold t))
 173     (((class color) (background dark)) (:foreground "PaleTurquoise" :bold t))
 174     (t (:bold t)))
 175   "Face used for displaying AGENTIZED servers"
 176   :group 'gnus-server-visual)
 177
 178 (defface gnus-server-opened-face
 179   '((((class color) (background light)) (:foreground "Green3" :bold t))
 180     (((class color) (background dark)) (:foreground "Green1" :bold t))
 181     (t (:bold t)))
 182   "Face used for displaying OPENED servers"
 183   :group 'gnus-server-visual)
 184
 185 (defface gnus-server-closed-face
 186   '((((class color) (background light)) (:foreground "Steel Blue" :italic t))
 187     (((class color) (background dark))
 188      (:foreground "Light Steel Blue" :italic t))
 189     (t (:italic t)))
 190   "Face used for displaying CLOSED servers"
 191   :group 'gnus-server-visual)
 192
 193 (defface gnus-server-denied-face
 194   '((((class color) (background light)) (:foreground "Red" :bold t))
 195     (((class color) (background dark)) (:foreground "Pink" :bold t))
 196     (t (:inverse-video t :bold t)))
 197   "Face used for displaying DENIED servers"
 198   :group 'gnus-server-visual)
 199
 200 (defface gnus-server-offline-face
 201   '((((class color) (background light)) (:foreground "Orange" :bold t))
 202     (((class color) (background dark)) (:foreground "Yellow" :bold t))
 203     (t (:inverse-video t :bold t)))
 204   "Face used for displaying OFFLINE servers"
 205   :group 'gnus-server-visual)
 206
 207 (defcustom gnus-server-agent-face 'gnus-server-agent-face
 208   "Face name to use on AGENTIZED servers."
 209   :version "22.1"
 210   :group 'gnus-server-visual
 211   :type 'face)
 212
 213 (defcustom gnus-server-opened-face 'gnus-server-opened-face
 214   "Face name to use on OPENED servers."
 215   :version "22.1"
 216   :group 'gnus-server-visual
 217   :type 'face)
 218
 219 (defcustom gnus-server-closed-face 'gnus-server-closed-face
 220   "Face name to use on CLOSED servers."
 221   :version "22.1"
 222   :group 'gnus-server-visual
 223   :type 'face)
 224
 225 (defcustom gnus-server-denied-face 'gnus-server-denied-face
 226   "Face name to use on DENIED servers."
 227   :version "22.1"
 228   :group 'gnus-server-visual
 229   :type 'face)
 230
 231 (defcustom gnus-server-offline-face 'gnus-server-offline-face
 232   "Face name to use on OFFLINE servers."
 233   :version "22.1"
 234   :group 'gnus-server-visual
 235   :type 'face)
 236
 237 (defvar gnus-server-font-lock-keywords
 238   (list
 239    '("(\\(agent\\))" 1 gnus-server-agent-face)
 240    '("(\\(opened\\))" 1 gnus-server-opened-face)
 241    '("(\\(closed\\))" 1 gnus-server-closed-face)
 242    '("(\\(offline\\))" 1 gnus-server-offline-face)
 243    '("(\\(denied\\))" 1 gnus-server-denied-face)))
 244
 245 (defun gnus-server-mode ()
 246   "Major mode for listing and editing servers.
 247
 248 All normal editing commands are switched off.
 249 \\<gnus-server-mode-map>
 250 For more in-depth information on this mode, read the manual
 251 \(`\\[gnus-info-find-node]').
 252
 253 The following commands are available:
 254
 255 \\{gnus-server-mode-map}"
 256   (interactive)
 257   (when (gnus-visual-p 'server-menu 'menu)
 258     (gnus-server-make-menu-bar))
 259   (kill-all-local-variables)
 260   (gnus-simplify-mode-line)
 261   (setq major-mode 'gnus-server-mode)
 262   (setq mode-name "Server")
 263   (gnus-set-default-directory)
 264   (setq mode-line-process nil)
 265   (use-local-map gnus-server-mode-map)
 266   (buffer-disable-undo)
 267   (setq truncate-lines t)
 268   (setq buffer-read-only t)
 269   (if (featurep 'xemacs)
 270       (put 'gnus-server-mode 'font-lock-defaults '(gnus-server-font-lock-keywords t))
 271     (set (make-local-variable 'font-lock-defaults)
 272          '(gnus-server-font-lock-keywords t)))
 273   (gnus-run-mode-hooks 'gnus-server-mode-hook))
 274
 275 (defun gnus-server-insert-server-line (gnus-tmp-name method)
 276   (let* ((gnus-tmp-how (car method))
 277          (gnus-tmp-where (nth 1 method))
 278          (elem (assoc method gnus-opened-servers))
 279          (gnus-tmp-status
 280           (cond
 281            ((eq (nth 1 elem) 'denied) "(denied)")
 282            ((eq (nth 1 elem) 'offline) "(offline)")
 283            (t
 284             (condition-case nil
 285                 (if (or (gnus-server-opened method)
 286                         (eq (nth 1 elem) 'ok))
 287                     "(opened)"
 288                   "(closed)")
 289               ((error) "(error)")))))
 290          (gnus-tmp-agent (if (and gnus-agent
 291                                   (gnus-agent-method-p method))
 292                              " (agent)"
 293                            "")))
 294     (beginning-of-line)
 295     (gnus-add-text-properties
 296      (point)
 297      (prog1 (1+ (point))
 298        ;; Insert the text.
 299        (eval gnus-server-line-format-spec))
 300      (list 'gnus-server (intern gnus-tmp-name)
 301            'gnus-named-server (intern (gnus-method-to-server method))))))
 302
 303 (defun gnus-enter-server-buffer ()
 304   "Set up the server buffer."
 305   (gnus-server-setup-buffer)
 306   (gnus-configure-windows 'server)
 307   (gnus-server-prepare))
 308
 309 (defun gnus-server-setup-buffer ()
 310   "Initialize the server buffer."
 311   (unless (get-buffer gnus-server-buffer)
 312     (save-excursion
 313       (set-buffer (gnus-get-buffer-create gnus-server-buffer))
 314       (gnus-server-mode)
 315       (when gnus-carpal
 316         (gnus-carpal-setup-buffer 'server)))))
 317
 318 (defun gnus-server-prepare ()
 319   (gnus-set-format 'server-mode)
 320   (gnus-set-format 'server t)
 321   (let ((alist gnus-server-alist)
 322         (buffer-read-only nil)
 323         done server op-ser)
 324     (erase-buffer)
 325     (setq gnus-inserted-opened-servers nil)
 326     ;; First we do the real list of servers.
 327     (while alist
 328       (unless (member (cdar alist) done)
 329         (push (cdar alist) done)
 330         (setq server (pop alist))
 331         (when (and server (car server) (cdr server))
 332           (gnus-server-insert-server-line (car server) (cdr server))))
 333       (when (member (cdar alist) done)
 334         (pop alist)))
 335     ;; Then we insert the list of servers that have been opened in
 336     ;; this session.
 337     (dolist (open gnus-opened-servers)
 338       (when (and (not (member (car open) done))
 339                  ;; Just ignore ephemeral servers.
 340                  (not (member (car open) gnus-ephemeral-servers)))
 341         (push (car open) done)
 342         (gnus-server-insert-server-line
 343          (setq op-ser (format "%s:%s" (caar open) (nth 1 (car open))))
 344          (car open))
 345         (push (list op-ser (car open)) gnus-inserted-opened-servers))))
 346   (goto-char (point-min))
 347   (gnus-server-position-point))
 348
 349 (defun gnus-server-server-name ()
 350   (let ((server (get-text-property (point-at-bol) 'gnus-server)))
 351     (and server (symbol-name server))))
 352
 353 (defun gnus-server-named-server ()
 354   "Return a server name that matches one of the names returned by
 355 `gnus-method-to-server'."
 356   (let ((server (get-text-property (point-at-bol) 'gnus-named-server)))
 357     (and server (symbol-name server))))
 358
 359 (defalias 'gnus-server-position-point 'gnus-goto-colon)
 360
 361 (defconst gnus-server-edit-buffer "*Gnus edit server*")
 362
 363 (defun gnus-server-update-server (server)
 364   (save-excursion
 365     (set-buffer gnus-server-buffer)
 366     (let* ((buffer-read-only nil)
 367            (entry (assoc server gnus-server-alist))
 368            (oentry (assoc (gnus-server-to-method server)
 369                           gnus-opened-servers)))
 370       (when entry
 371         (gnus-dribble-enter
 372          (concat "(gnus-server-set-info \"" server "\" '"
 373                  (gnus-prin1-to-string (cdr entry)) ")\n")))
 374       (when (or entry oentry)
 375         ;; Buffer may be narrowed.
 376         (save-restriction
 377           (widen)
 378           (when (gnus-server-goto-server server)
 379             (gnus-delete-line))
 380           (if entry
 381               (gnus-server-insert-server-line (car entry) (cdr entry))
 382             (gnus-server-insert-server-line
 383              (format "%s:%s" (caar oentry) (nth 1 (car oentry)))
 384              (car oentry)))
 385           (gnus-server-position-point))))))
 386
 387 (defun gnus-server-set-info (server info)
 388   ;; Enter a select method into the virtual server alist.
 389   (when (and server info)
 390     (gnus-dribble-enter
 391      (concat "(gnus-server-set-info \"" server "\" '"
 392              (gnus-prin1-to-string info) ")"))
 393     (let* ((server (nth 1 info))
 394            (entry (assoc server gnus-server-alist))
 395            (cached (assoc server gnus-server-method-cache)))
 396       (if cached
 397           (setq gnus-server-method-cache
 398                 (delq cached gnus-server-method-cache)))
 399       (if entry
 400           (progn
 401             ;; Remove the server from `gnus-opened-servers' since
 402             ;; it has never been opened with the new `info' yet.
 403             (gnus-opened-servers-remove (cdr entry))
 404             ;; Don't make a new Lisp object.
 405             (setcar (cdr entry) (car info))
 406             (setcdr (cdr entry) (cdr info)))
 407         (setq gnus-server-alist
 408               (nconc gnus-server-alist (list (cons server info))))))))
 409
 410 ;;; Interactive server functions.
 411
 412 (defun gnus-server-kill-server (server)
 413   "Kill the server on the current line."
 414   (interactive (list (gnus-server-server-name)))
 415   (unless (gnus-server-goto-server server)
 416     (if server (error "No such server: %s" server)
 417       (error "No server on the current line")))
 418   (unless (assoc server gnus-server-alist)
 419     (error "Read-only server %s" server))
 420   (gnus-dribble-touch)
 421   (let ((buffer-read-only nil))
 422     (gnus-delete-line))
 423   (push (assoc server gnus-server-alist) gnus-server-killed-servers)
 424   (setq gnus-server-alist (delq (car gnus-server-killed-servers)
 425                                 gnus-server-alist))
 426   (let ((groups (gnus-groups-from-server server)))
 427     (when (and groups
 428                (gnus-yes-or-no-p
 429                 (format "Kill all %s groups from this server? "
 430                         (length groups))))
 431       (dolist (group groups)
 432         (setq gnus-newsrc-alist
 433               (delq (assoc group gnus-newsrc-alist)
 434                     gnus-newsrc-alist))
 435         (when gnus-group-change-level-function
 436           (funcall gnus-group-change-level-function
 437                    group gnus-level-killed 3)))))
 438   (gnus-server-position-point))
 439
 440 (defun gnus-server-yank-server ()
 441   "Yank the previously killed server."
 442   (interactive)
 443   (unless gnus-server-killed-servers
 444     (error "No killed servers to be yanked"))
 445   (let ((alist gnus-server-alist)
 446         (server (gnus-server-server-name))
 447         (killed (car gnus-server-killed-servers)))
 448     (if (not server)
 449         (setq gnus-server-alist (nconc gnus-server-alist (list killed)))
 450       (if (string= server (caar gnus-server-alist))
 451           (push killed gnus-server-alist)
 452         (while (and (cdr alist)
 453                     (not (string= server (caadr alist))))
 454           (setq alist (cdr alist)))
 455         (if alist
 456             (setcdr alist (cons killed (cdr alist)))
 457           (setq gnus-server-alist (list killed)))))
 458     (gnus-server-update-server (car killed))
 459     (setq gnus-server-killed-servers (cdr gnus-server-killed-servers))
 460     (gnus-server-position-point)))
 461
 462 (defun gnus-server-exit ()
 463   "Return to the group buffer."
 464   (interactive)
 465   (gnus-run-hooks 'gnus-server-exit-hook)
 466   (gnus-kill-buffer (current-buffer))
 467   (gnus-configure-windows 'group t))
 468
 469 (defun gnus-server-list-servers ()
 470   "List all available servers."
 471   (interactive)
 472   (let ((cur (gnus-server-server-name)))
 473     (gnus-server-prepare)
 474     (if cur (gnus-server-goto-server cur)
 475       (goto-char (point-max))
 476       (forward-line -1))
 477     (gnus-server-position-point)))
 478
 479 (defun gnus-server-set-status (method status)
 480   "Make METHOD have STATUS."
 481   (let ((entry (assoc method gnus-opened-servers)))
 482     (if entry
 483         (setcar (cdr entry) status)
 484       (push (list method status) gnus-opened-servers))))
 485
 486 (defun gnus-opened-servers-remove (method)
 487   "Remove METHOD from the list of opened servers."
 488   (setq gnus-opened-servers (delq (assoc method gnus-opened-servers)
 489                                   gnus-opened-servers)))
 490
 491 (defun gnus-server-open-server (server)
 492   "Force an open of SERVER."
 493   (interactive (list (gnus-server-server-name)))
 494   (let ((method (gnus-server-to-method server)))
 495     (unless method
 496       (error "No such server: %s" server))
 497     (gnus-server-set-status method 'ok)
 498     (prog1
 499         (or (gnus-open-server method)
 500             (progn (message "Couldn't open %s" server) nil))
 501       (gnus-server-update-server server)
 502       (gnus-server-position-point))))
 503
 504 (defun gnus-server-open-all-servers ()
 505   "Open all servers."
 506   (interactive)
 507   (dolist (server gnus-inserted-opened-servers)
 508     (gnus-server-open-server (car server))))
 509
 510 (defun gnus-server-close-server (server)
 511   "Close SERVER."
 512   (interactive (list (gnus-server-server-name)))
 513   (let ((method (gnus-server-to-method server)))
 514     (unless method
 515       (error "No such server: %s" server))
 516     (gnus-server-set-status method 'closed)
 517     (prog1
 518         (gnus-close-server method)
 519       (gnus-server-update-server server)
 520       (gnus-server-position-point))))
 521
 522 (defun gnus-server-offline-server (server)
 523   "Set SERVER to offline."
 524   (interactive (list (gnus-server-server-name)))
 525   (let ((method (gnus-server-to-method server)))
 526     (unless method
 527       (error "No such server: %s" server))
 528     (prog1
 529         (gnus-close-server method)
 530       (gnus-server-set-status method 'offline)
 531       (gnus-server-update-server server)
 532       (gnus-server-position-point))))
 533
 534 (defun gnus-server-close-all-servers ()
 535   "Close all servers."
 536   (interactive)
 537   (dolist (server gnus-inserted-opened-servers)
 538     (gnus-server-close-server (car server))))
 539
 540 (defun gnus-server-deny-server (server)
 541   "Make sure SERVER will never be attempted opened."
 542   (interactive (list (gnus-server-server-name)))
 543   (let ((method (gnus-server-to-method server)))
 544     (unless method
 545       (error "No such server: %s" server))
 546     (gnus-server-set-status method 'denied))
 547   (gnus-server-update-server server)
 548   (gnus-server-position-point)
 549   t)
 550
 551 (defun gnus-server-remove-denials ()
 552   "Make all denied servers into closed servers."
 553   (interactive)
 554   (dolist (server gnus-opened-servers)
 555     (when (eq (nth 1 server) 'denied)
 556       (setcar (nthcdr 1 server) 'closed)))
 557   (gnus-server-list-servers))
 558
 559 (defun gnus-server-copy-server (from to)
 560   (interactive
 561    (list
 562     (or (gnus-server-server-name)
 563         (error "No server on the current line"))
 564     (read-string "Copy to: ")))
 565   (unless from
 566     (error "No server on current line"))
 567   (unless (and to (not (string= to "")))
 568     (error "No name to copy to"))
 569   (when (assoc to gnus-server-alist)
 570     (error "%s already exists" to))
 571   (unless (gnus-server-to-method from)
 572     (error "%s: no such server" from))
 573   (let ((to-entry (cons from (gnus-copy-sequence
 574                               (gnus-server-to-method from)))))
 575     (setcar to-entry to)
 576     (setcar (nthcdr 2 to-entry) to)
 577     (push to-entry gnus-server-killed-servers)
 578     (gnus-server-yank-server)))
 579
 580 (defun gnus-server-add-server (how where)
 581   (interactive
 582    (list (intern (completing-read "Server method: "
 583                                   gnus-valid-select-methods nil t))
 584          (read-string "Server name: ")))
 585   (when (assq where gnus-server-alist)
 586     (error "Server with that name already defined"))
 587   (push (list where how where) gnus-server-killed-servers)
 588   (gnus-server-yank-server))
 589
 590 (defun gnus-server-goto-server (server)
 591   "Jump to a server line."
 592   (interactive
 593    (list (completing-read "Goto server: " gnus-server-alist nil t)))
 594   (let ((to (text-property-any (point-min) (point-max)
 595                                'gnus-server (intern server))))
 596     (when to
 597       (goto-char to)
 598       (gnus-server-position-point))))
 599
 600 (defun gnus-server-edit-server (server)
 601   "Edit the server on the current line."
 602   (interactive (list (gnus-server-server-name)))
 603   (unless server
 604     (error "No server on current line"))
 605   (unless (assoc server gnus-server-alist)
 606     (error "This server can't be edited"))
 607   (let ((info (cdr (assoc server gnus-server-alist))))
 608     (gnus-close-server info)
 609     (gnus-edit-form
 610      info "Editing the server."
 611      `(lambda (form)
 612         (gnus-server-set-info ,server form)
 613         (gnus-server-list-servers)
 614         (gnus-server-position-point)))))
 615
 616 (defun gnus-server-scan-server (server)
 617   "Request a scan from the current server."
 618   (interactive (list (gnus-server-server-name)))
 619   (let ((method (gnus-server-to-method server)))
 620     (if (not (gnus-get-function method 'request-scan))
 621         (error "Server %s can't scan" (car method))
 622       (gnus-message 3 "Scanning %s..." server)
 623       (gnus-request-scan nil method)
 624       (gnus-message 3 "Scanning %s...done" server))))
 625
 626 (defun gnus-server-read-server-in-server-buffer (server)
 627   "Browse a server in server buffer."
 628   (interactive (list (gnus-server-server-name)))
 629   (let (gnus-server-browse-in-group-buffer)
 630     (gnus-server-read-server server)))
 631
 632 (defun gnus-server-read-server (server)
 633   "Browse a server."
 634   (interactive (list (gnus-server-server-name)))
 635   (let ((buf (current-buffer)))
 636     (prog1
 637         (gnus-browse-foreign-server server buf)
 638       (save-excursion
 639         (set-buffer buf)
 640         (gnus-server-update-server (gnus-server-server-name))
 641         (gnus-server-position-point)))))
 642
 643 (defun gnus-server-pick-server (e)
 644   (interactive "e")
 645   (mouse-set-point e)
 646   (gnus-server-read-server (gnus-server-server-name)))
 647
 648 \f
 649 ;;;
 650 ;;; Browse Server Mode
 651 ;;;
 652
 653 (defvar gnus-browse-menu-hook nil
 654   "*Hook run after the creation of the browse mode menu.")
 655
 656 (defvar gnus-browse-mode-hook nil)
 657 (defvar gnus-browse-mode-map nil)
 658 (put 'gnus-browse-mode 'mode-class 'special)
 659
 660 (unless gnus-browse-mode-map
 661   (setq gnus-browse-mode-map (make-keymap))
 662   (suppress-keymap gnus-browse-mode-map)
 663
 664   (gnus-define-keys
 665       gnus-browse-mode-map
 666     " " gnus-browse-read-group
 667     "=" gnus-browse-select-group
 668     "n" gnus-browse-next-group
 669     "p" gnus-browse-prev-group
 670     "\177" gnus-browse-prev-group
 671     [delete] gnus-browse-prev-group
 672     "N" gnus-browse-next-group
 673     "P" gnus-browse-prev-group
 674     "\M-n" gnus-browse-next-group
 675     "\M-p" gnus-browse-prev-group
 676     "\r" gnus-browse-select-group
 677     "u" gnus-browse-unsubscribe-current-group
 678     "l" gnus-browse-exit
 679     "L" gnus-browse-exit
 680     "q" gnus-browse-exit
 681     "Q" gnus-browse-exit
 682     "d" gnus-browse-describe-group
 683     "\C-c\C-c" gnus-browse-exit
 684     "?" gnus-browse-describe-briefly
 685
 686     "\C-c\C-i" gnus-info-find-node
 687     "\C-c\C-b" gnus-bug))
 688
 689 (defun gnus-browse-make-menu-bar ()
 690   (gnus-turn-off-edit-menu 'browse)
 691   (unless (boundp 'gnus-browse-menu)
 692     (easy-menu-define
 693      gnus-browse-menu gnus-browse-mode-map ""
 694      '("Browse"
 695        ["Subscribe" gnus-browse-unsubscribe-current-group t]
 696        ["Read" gnus-browse-read-group t]
 697        ["Select" gnus-browse-select-group t]
 698        ["Describe" gnus-browse-describe-group t]
 699        ["Next" gnus-browse-next-group t]
 700        ["Prev" gnus-browse-prev-group t]
 701        ["Exit" gnus-browse-exit t]))
 702     (gnus-run-hooks 'gnus-browse-menu-hook)))
 703
 704 (defvar gnus-browse-current-method nil)
 705 (defvar gnus-browse-return-buffer nil)
 706
 707 (defvar gnus-browse-buffer "*Gnus Browse Server*")
 708
 709 (defun gnus-browse-foreign-server (server &optional return-buffer)
 710   "Browse the server SERVER."
 711   (setq gnus-browse-current-method (gnus-server-to-method server))
 712   (setq gnus-browse-return-buffer return-buffer)
 713   (let* ((method gnus-browse-current-method)
 714          (orig-select-method gnus-select-method)
 715          (gnus-select-method method)
 716          groups group)
 717     (gnus-message 5 "Connecting to %s..." (nth 1 method))
 718     (cond
 719      ((not (gnus-check-server method))
 720       (gnus-message
 721        1 "Unable to contact server %s: %s" (nth 1 method)
 722        (gnus-status-message method))
 723       nil)
 724      ((not
 725        (prog2
 726            (gnus-message 6 "Reading active file...")
 727            (gnus-request-list method)
 728          (gnus-message 6 "Reading active file...done")))
 729       (gnus-message
 730        1 "Couldn't request list: %s" (gnus-status-message method))
 731       nil)
 732      (t
 733       (with-current-buffer nntp-server-buffer
 734         (let ((cur (current-buffer)))
 735           (goto-char (point-min))
 736           (unless (string= gnus-ignored-newsgroups "")
 737             (delete-matching-lines gnus-ignored-newsgroups))
 738           ;; We treat NNTP as a special case to avoid problems with
 739           ;; garbage group names like `"foo' that appear in some badly
 740           ;; managed active files. -jh.
 741           (if (eq (car method) 'nntp)
 742               (while (not (eobp))
 743                 (ignore-errors
 744                   (push (cons
 745                          (buffer-substring
 746                           (point)
 747                           (progn
 748                             (skip-chars-forward "^ \t")
 749                             (point)))
 750                          (let ((last (read cur)))
 751                            (cons (read cur) last)))
 752                         groups))
 753                 (forward-line))
 754             (while (not (eobp))
 755               (ignore-errors
 756                 (push (cons
 757                        (if (eq (char-after) ?\")
 758                            (read cur)
 759                          (let ((p (point)) (name ""))
 760                            (skip-chars-forward "^ \t\\\\")
 761                            (setq name (buffer-substring p (point)))
 762                            (while (eq (char-after) ?\\)
 763                              (setq p (1+ (point)))
 764                              (forward-char 2)
 765                              (skip-chars-forward "^ \t\\\\")
 766                              (setq name (concat name (buffer-substring
 767                                                       p (point)))))
 768                            name))
 769                        (let ((last (read cur)))
 770                          (cons (read cur) last)))
 771                       groups))
 772               (forward-line)))))
 773       (setq groups (sort groups
 774                          (lambda (l1 l2)
 775                            (string< (car l1) (car l2)))))
 776       (if gnus-server-browse-in-group-buffer
 777           (let* ((gnus-select-method orig-select-method)
 778                  (gnus-group-listed-groups
 779                   (mapcar (lambda (group)
 780                             (let ((name
 781                                    (gnus-group-prefixed-name
 782                                     (car group) method)))
 783                               (gnus-set-active name (cdr group))
 784                               name))
 785                           groups)))
 786             (gnus-configure-windows 'group)
 787             (funcall gnus-group-prepare-function
 788                      gnus-level-killed 'ignore 1 'ignore))
 789         (gnus-get-buffer-create gnus-browse-buffer)
 790         (when gnus-carpal
 791           (gnus-carpal-setup-buffer 'browse))
 792         (gnus-configure-windows 'browse)
 793         (buffer-disable-undo)
 794         (let ((buffer-read-only nil))
 795           (erase-buffer))
 796         (gnus-browse-mode)
 797         (setq mode-line-buffer-identification
 798               (list
 799                (format
 800                 "Gnus: %%b {%s:%s}" (car method) (cadr method))))
 801         (let ((buffer-read-only nil)
 802               name
 803               (prefix (let ((gnus-select-method orig-select-method))
 804                         (gnus-group-prefixed-name "" method))))
 805           (while (setq group (pop groups))
 806             (gnus-add-text-properties
 807              (point)
 808              (prog1 (1+ (point))
 809                (insert
 810                 (format "%c%7d: %s\n"
 811                         (let ((level
 812                                (if (string= prefix "")
 813                                    (gnus-group-level (setq name (car group)))
 814                                  (gnus-group-level
 815                                   (concat prefix (setq name (car group)))))))
 816                           (cond
 817                            ((<= level gnus-level-subscribed) ? )
 818                            ((<= level gnus-level-unsubscribed) ?U)
 819                            ((= level gnus-level-zombie) ?Z)
 820                            (t ?K)))
 821                         (max 0 (- (1+ (cddr group)) (cadr group)))
 822                         ;; Don't decode if name is ASCII
 823                         (if (and (fboundp 'detect-coding-string)
 824                                  (eq (detect-coding-string name t) 'undecided))
 825                             name
 826                           (mm-decode-coding-string
 827                            name
 828                            (inline (gnus-group-name-charset method name)))))))
 829              (list 'gnus-group name)
 830              )))
 831         (switch-to-buffer (current-buffer)))
 832       (goto-char (point-min))
 833       (gnus-group-position-point)
 834       (gnus-message 5 "Connecting to %s...done" (nth 1 method))
 835       t))))
 836
 837 (defun gnus-browse-mode ()
 838   "Major mode for browsing a foreign server.
 839
 840 All normal editing commands are switched off.
 841
 842 \\<gnus-browse-mode-map>
 843 The only things you can do in this buffer is
 844
 845 1) `\\[gnus-browse-unsubscribe-current-group]' to subscribe to a group.
 846 The group will be inserted into the group buffer upon exit from this
 847 buffer.
 848
 849 2) `\\[gnus-browse-read-group]' to read a group ephemerally.
 850
 851 3) `\\[gnus-browse-exit]' to return to the group buffer."
 852   (interactive)
 853   (kill-all-local-variables)
 854   (when (gnus-visual-p 'browse-menu 'menu)
 855     (gnus-browse-make-menu-bar))
 856   (gnus-simplify-mode-line)
 857   (setq major-mode 'gnus-browse-mode)
 858   (setq mode-name "Browse Server")
 859   (setq mode-line-process nil)
 860   (use-local-map gnus-browse-mode-map)
 861   (buffer-disable-undo)
 862   (setq truncate-lines t)
 863   (gnus-set-default-directory)
 864   (setq buffer-read-only t)
 865   (gnus-run-mode-hooks 'gnus-browse-mode-hook))
 866
 867 (defun gnus-browse-read-group (&optional no-article number)
 868   "Enter the group at the current line.
 869 If NUMBER, fetch this number of articles."
 870   (interactive "P")
 871   (let ((group (gnus-browse-group-name)))
 872     (if (or (not (gnus-get-info group))
 873             (gnus-ephemeral-group-p group))
 874         (unless (gnus-group-read-ephemeral-group
 875                  group gnus-browse-current-method nil
 876                  (cons (current-buffer) 'browse)
 877                  nil nil nil number)
 878           (error "Couldn't enter %s" group))
 879       (unless (gnus-group-read-group nil no-article group)
 880         (error "Couldn't enter %s" group)))))
 881
 882 (defun gnus-browse-select-group (&optional number)
 883   "Select the current group.
 884 If NUMBER, fetch this number of articles."
 885   (interactive "P")
 886   (gnus-browse-read-group 'no number))
 887
 888 (defun gnus-browse-next-group (n)
 889   "Go to the next group."
 890   (interactive "p")
 891   (prog1
 892       (forward-line n)
 893     (gnus-group-position-point)))
 894
 895 (defun gnus-browse-prev-group (n)
 896   "Go to the next group."
 897   (interactive "p")
 898   (gnus-browse-next-group (- n)))
 899
 900 (defun gnus-browse-unsubscribe-current-group (arg)
 901   "(Un)subscribe to the next ARG groups."
 902   (interactive "p")
 903   (when (eobp)
 904     (error "No group at current line"))
 905   (let ((ward (if (< arg 0) -1 1))
 906         (arg (abs arg)))
 907     (while (and (> arg 0)
 908                 (not (eobp))
 909                 (gnus-browse-unsubscribe-group)
 910                 (zerop (gnus-browse-next-group ward)))
 911       (decf arg))
 912     (gnus-group-position-point)
 913     (when (/= 0 arg)
 914       (gnus-message 7 "No more newsgroups"))
 915     arg))
 916
 917 (defun gnus-browse-group-name ()
 918   (save-excursion
 919     (beginning-of-line)
 920     (let ((name (get-text-property (point) 'gnus-group)))
 921       (when (re-search-forward ": \\(.*\\)$" (point-at-eol) t)
 922         (concat (gnus-method-to-server-name gnus-browse-current-method) ":"
 923                 (or name
 924                     (match-string-no-properties 1)))))))
 925
 926 (defun gnus-browse-describe-group (group)
 927   "Describe the current group."
 928   (interactive (list (gnus-browse-group-name)))
 929   (gnus-group-describe-group nil group))
 930
 931 (defun gnus-browse-unsubscribe-group ()
 932   "Toggle subscription of the current group in the browse buffer."
 933   (let ((sub nil)
 934         (buffer-read-only nil)
 935         group)
 936     (save-excursion
 937       (beginning-of-line)
 938       ;; If this group it killed, then we want to subscribe it.
 939       (unless (eq (char-after) ? )
 940         (setq sub t))
 941       (setq group (gnus-browse-group-name))
 942       (when (gnus-server-equal gnus-browse-current-method "native")
 943         (setq group (gnus-group-real-name group)))
 944       (if sub
 945           (progn
 946             ;; Make sure the group has been properly removed before we
 947             ;; subscribe to it.
 948             (gnus-kill-ephemeral-group group)
 949             (gnus-group-change-level
 950              (list t group gnus-level-default-subscribed
 951                    nil nil (if (gnus-server-equal
 952                                 gnus-browse-current-method "native")
 953                                nil
 954                              (gnus-method-simplify
 955                               gnus-browse-current-method)))
 956              gnus-level-default-subscribed (gnus-group-level group)
 957              (and (car (nth 1 gnus-newsrc-alist))
 958                   (gnus-group-entry (car (nth 1 gnus-newsrc-alist))))
 959              t)
 960             (delete-char 1)
 961             (insert ? ))
 962         (gnus-group-change-level
 963          group gnus-level-unsubscribed gnus-level-default-subscribed)
 964         (delete-char 1)
 965         (insert ?U)))
 966     t))
 967
 968 (defun gnus-browse-exit ()
 969   "Quit browsing and return to the group buffer."
 970   (interactive)
 971   (when (eq major-mode 'gnus-browse-mode)
 972     (gnus-kill-buffer (current-buffer)))
 973   ;; Insert the newly subscribed groups in the group buffer.
 974   (save-excursion
 975     (set-buffer gnus-group-buffer)
 976     (gnus-group-list-groups nil))
 977   (if gnus-browse-return-buffer
 978       (gnus-configure-windows 'server 'force)
 979     (gnus-configure-windows 'group 'force)))
 980
 981 (defun gnus-browse-describe-briefly ()
 982   "Give a one line description of the group mode commands."
 983   (interactive)
 984   (gnus-message 6
 985                 (substitute-command-keys "\\<gnus-browse-mode-map>\\[gnus-group-next-group]:Forward  \\[gnus-group-prev-group]:Backward  \\[gnus-browse-exit]:Exit  \\[gnus-info-find-node]:Run Info  \\[gnus-browse-describe-briefly]:This help")))
 986
 987 (defun gnus-server-regenerate-server ()
 988   "Issue a command to the server to regenerate all its data structures."
 989   (interactive)
 990   (let ((server (gnus-server-server-name)))
 991     (unless server
 992       (error "No server on the current line"))
 993     (condition-case ()
 994         (gnus-get-function (gnus-server-to-method server)
 995                            'request-regenerate)
 996       (error
 997         (error "This back end doesn't support regeneration")))
 998     (gnus-message 5 "Requesting regeneration of %s..." server)
 999     (unless (gnus-open-server server)
1000       (error "Couldn't open server"))
1001     (if (gnus-request-regenerate server)
1002         (gnus-message 5 "Requesting regeneration of %s...done" server)
1003       (gnus-message 5 "Couldn't regenerate %s" server))))
1004
1005 (provide 'gnus-srvr)
1006
1007 ;;; arch-tag: c0117f64-27ca-475d-9406-8da6854c7a25
1008 ;;; gnus-srvr.el ends here