cgit.sxemacs.org Git - gnus/blob - lisp/gnus-srvr.el

   1 ;;; gnus-srvr.el --- virtual server support for Gnus
   2 ;; Copyright (C) 1995,96 Free Software Foundation, Inc.
   3
   4 ;; Author: Lars Magne Ingebrigtsen <larsi@ifi.uio.no>
   5 ;; Keywords: news
   6
   7 ;; This file is part of GNU Emacs.
   8
   9 ;; GNU Emacs is free software; you can redistribute it and/or modify
  10 ;; it under the terms of the GNU General Public License as published by
  11 ;; the Free Software Foundation; either version 2, or (at your option)
  12 ;; any later version.
  13
  14 ;; GNU Emacs is distributed in the hope that it will be useful,
  15 ;; but WITHOUT ANY WARRANTY; without even the implied warranty of
  16 ;; MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.  See the
  17 ;; GNU General Public License for more details.
  18
  19 ;; You should have received a copy of the GNU General Public License
  20 ;; along with GNU Emacs; see the file COPYING.  If not, write to the
  21 ;; Free Software Foundation, Inc., 59 Temple Place - Suite 330,
  22 ;; Boston, MA 02111-1307, USA.
  23
  24 ;;; Commentary:
  25
  26 ;;; Code:
  27
  28 (require 'gnus-load)
  29 (require 'gnus-spec)
  30 (require 'gnus)
  31 (require 'gnus-group)
  32 (require 'gnus-int)
  33 (require 'gnus-range)
  34
  35 (defvar gnus-server-mode-hook nil
  36   "Hook run in `gnus-server-mode' buffers.")
  37
  38 (defconst gnus-server-line-format "     {%(%h:%w%)} %s\n"
  39   "Format of server lines.
  40 It works along the same lines as a normal formatting string,
  41 with some simple extensions.")
  42
  43 (defvar gnus-server-mode-line-format "Gnus  List of servers"
  44   "The format specification for the server mode line.")
  45
  46 (defvar gnus-server-exit-hook nil
  47   "*Hook run when exiting the server buffer.")
  48
  49 ;;; Internal variables.
  50
  51 (defvar gnus-inserted-opened-servers nil)
  52
  53 (defvar gnus-server-line-format-alist
  54   `((?h how ?s)
  55     (?n name ?s)
  56     (?w where ?s)
  57     (?s status ?s)))
  58
  59 (defvar gnus-server-mode-line-format-alist
  60   `((?S news-server ?s)
  61     (?M news-method ?s)
  62     (?u user-defined ?s)))
  63
  64 (defvar gnus-server-line-format-spec nil)
  65 (defvar gnus-server-mode-line-format-spec nil)
  66 (defvar gnus-server-killed-servers nil)
  67
  68 (defvar gnus-server-mode-map)
  69
  70 (defvar gnus-server-menu-hook nil
  71   "*Hook run after the creation of the server mode menu.")
  72
  73 (defun gnus-server-make-menu-bar ()
  74   (gnus-turn-off-edit-menu 'server)
  75   (unless (boundp 'gnus-server-server-menu)
  76     (easy-menu-define
  77      gnus-server-server-menu gnus-server-mode-map ""
  78      '("Server"
  79        ["Add" gnus-server-add-server t]
  80        ["Browse" gnus-server-read-server t]
  81        ["Scan" gnus-server-scan-server t]
  82        ["List" gnus-server-list-servers t]
  83        ["Kill" gnus-server-kill-server t]
  84        ["Yank" gnus-server-yank-server t]
  85        ["Copy" gnus-server-copy-server t]
  86        ["Edit" gnus-server-edit-server t]
  87        ["Exit" gnus-server-exit t]
  88        ))
  89
  90     (easy-menu-define
  91      gnus-server-connections-menu gnus-server-mode-map ""
  92      '("Connections"
  93        ["Open" gnus-server-open-server t]
  94        ["Close" gnus-server-close-server t]
  95        ["Deny" gnus-server-deny-server t]
  96        "---"
  97        ["Open All" gnus-server-open-all-servers t]
  98        ["Close All" gnus-server-close-all-servers t]
  99        ["Reset All" gnus-server-remove-denials t]
 100        ))
 101
 102     (run-hooks 'gnus-server-menu-hook)))
 103
 104 (defvar gnus-server-mode-map nil)
 105 (put 'gnus-server-mode 'mode-class 'special)
 106
 107 (unless gnus-server-mode-map
 108   (setq gnus-server-mode-map (make-sparse-keymap))
 109   (suppress-keymap gnus-server-mode-map)
 110
 111   (gnus-define-keys
 112    gnus-server-mode-map
 113    " " gnus-server-read-server
 114    "\r" gnus-server-read-server
 115    gnus-mouse-2 gnus-server-pick-server
 116    "q" gnus-server-exit
 117    "l" gnus-server-list-servers
 118    "k" gnus-server-kill-server
 119    "y" gnus-server-yank-server
 120    "c" gnus-server-copy-server
 121    "a" gnus-server-add-server
 122    "e" gnus-server-edit-server
 123    "s" gnus-server-scan-server
 124
 125    "O" gnus-server-open-server
 126    "\M-o" gnus-server-open-all-servers
 127    "C" gnus-server-close-server
 128    "\M-c" gnus-server-close-all-servers
 129    "D" gnus-server-deny-server
 130    "R" gnus-server-remove-denials
 131
 132     "\C-c\C-i" gnus-info-find-node))
 133
 134 (defun gnus-server-mode ()
 135   "Major mode for listing and editing servers.
 136
 137 All normal editing commands are switched off.
 138 \\<gnus-server-mode-map>
 139 For more in-depth information on this mode, read the manual
 140 (`\\[gnus-info-find-node]').
 141
 142 The following commands are available:
 143
 144 \\{gnus-server-mode-map}"
 145   (interactive)
 146   (when (and menu-bar-mode
 147              (gnus-visual-p 'server-menu 'menu))
 148     (gnus-server-make-menu-bar))
 149   (kill-all-local-variables)
 150   (gnus-simplify-mode-line)
 151   (setq major-mode 'gnus-server-mode)
 152   (setq mode-name "Server")
 153   (gnus-set-default-directory)
 154   (setq mode-line-process nil)
 155   (use-local-map gnus-server-mode-map)
 156   (buffer-disable-undo (current-buffer))
 157   (setq truncate-lines t)
 158   (setq buffer-read-only t)
 159   (run-hooks 'gnus-server-mode-hook))
 160
 161 (defun gnus-server-insert-server-line (name method)
 162   (let* ((how (car method))
 163          (where (nth 1 method))
 164          (elem (assoc method gnus-opened-servers))
 165          (status (cond ((eq (nth 1 elem) 'denied)
 166                         "(denied)")
 167                        ((or (gnus-server-opened method)
 168                             (eq (nth 1 elem) 'ok))
 169                         "(opened)")
 170                        (t
 171                         "(closed)"))))
 172     (beginning-of-line)
 173     (gnus-add-text-properties
 174      (point)
 175      (prog1 (1+ (point))
 176        ;; Insert the text.
 177        (eval gnus-server-line-format-spec))
 178      (list 'gnus-server (intern name)))))
 179
 180 (defun gnus-enter-server-buffer ()
 181   "Set up the server buffer."
 182   (gnus-server-setup-buffer)
 183   (gnus-configure-windows 'server)
 184   (gnus-server-prepare))
 185
 186 (defun gnus-server-setup-buffer ()
 187   "Initialize the server buffer."
 188   (unless (get-buffer gnus-server-buffer)
 189     (save-excursion
 190       (set-buffer (get-buffer-create gnus-server-buffer))
 191       (gnus-server-mode)
 192       (when gnus-carpal
 193         (gnus-carpal-setup-buffer 'server)))))
 194
 195 (defun gnus-server-prepare ()
 196   (setq gnus-server-mode-line-format-spec
 197         (gnus-parse-format gnus-server-mode-line-format
 198                            gnus-server-mode-line-format-alist))
 199   (setq gnus-server-line-format-spec
 200         (gnus-parse-format gnus-server-line-format
 201                            gnus-server-line-format-alist t))
 202   (let ((alist gnus-server-alist)
 203         (buffer-read-only nil)
 204         (opened gnus-opened-servers)
 205         done server op-ser)
 206     (erase-buffer)
 207     (setq gnus-inserted-opened-servers nil)
 208     ;; First we do the real list of servers.
 209     (while alist
 210       (push (cdr (setq server (pop alist))) done)
 211       (when (and server (car server) (cdr server))
 212         (gnus-server-insert-server-line (car server) (cdr server))))
 213     ;; Then we insert the list of servers that have been opened in
 214     ;; this session.
 215     (while opened
 216       (unless (member (caar opened) done)
 217         (gnus-server-insert-server-line
 218          (setq op-ser (format "%s:%s" (caaar opened) (nth 1 (caar opened))))
 219          (caar opened))
 220         (push (list op-ser (caar opened)) gnus-inserted-opened-servers))
 221       (setq opened (cdr opened))))
 222   (goto-char (point-min))
 223   (gnus-server-position-point))
 224
 225 (defun gnus-server-server-name ()
 226   (let ((server (get-text-property (gnus-point-at-bol) 'gnus-server)))
 227     (and server (symbol-name server))))
 228
 229 (defalias 'gnus-server-position-point 'gnus-goto-colon)
 230
 231 (defconst gnus-server-edit-buffer "*Gnus edit server*")
 232
 233 (defun gnus-server-update-server (server)
 234   (save-excursion
 235     (set-buffer gnus-server-buffer)
 236     (let* ((buffer-read-only nil)
 237            (entry (assoc server gnus-server-alist))
 238            (oentry (assoc (gnus-server-to-method server)
 239                           gnus-opened-servers)))
 240       (when entry
 241         (gnus-dribble-enter
 242          (concat "(gnus-server-set-info \"" server "\" '"
 243                  (prin1-to-string (cdr entry)) ")
 244 ")))
 245       (when (or entry oentry)
 246         ;; Buffer may be narrowed.
 247         (save-restriction
 248           (widen)
 249           (when (gnus-server-goto-server server)
 250             (gnus-delete-line))
 251           (if entry
 252               (gnus-server-insert-server-line (car entry) (cdr entry))
 253             (gnus-server-insert-server-line
 254              (format "%s:%s" (caar oentry) (nth 1 (car oentry)))
 255              (car oentry)))
 256           (gnus-server-position-point))))))
 257
 258 (defun gnus-server-set-info (server info)
 259   ;; Enter a select method into the virtual server alist.
 260   (when (and server info)
 261     (gnus-dribble-enter
 262      (concat "(gnus-server-set-info \"" server "\" '"
 263              (prin1-to-string info) ")"))
 264     (let* ((server (nth 1 info))
 265            (entry (assoc server gnus-server-alist)))
 266       (if entry (setcdr entry info)
 267         (setq gnus-server-alist
 268               (nconc gnus-server-alist (list (cons server info))))))))
 269
 270 ;;; Interactive server functions.
 271
 272 (defun gnus-server-kill-server (server)
 273   "Kill the server on the current line."
 274   (interactive (list (gnus-server-server-name)))
 275   (unless (gnus-server-goto-server server)
 276     (if server (error "No such server: %s" server)
 277       (error "No server on the current line")))
 278   (unless (assoc server gnus-server-alist)
 279     (error "Read-only server %s" server))
 280   (gnus-dribble-enter "")
 281   (let ((buffer-read-only nil))
 282     (gnus-delete-line))
 283   (push (assoc server gnus-server-alist) gnus-server-killed-servers)
 284   (setq gnus-server-alist (delq (car gnus-server-killed-servers)
 285                                 gnus-server-alist))
 286   (gnus-server-position-point))
 287
 288 (defun gnus-server-yank-server ()
 289   "Yank the previously killed server."
 290   (interactive)
 291   (unless gnus-server-killed-servers
 292     (error "No killed servers to be yanked"))
 293   (let ((alist gnus-server-alist)
 294         (server (gnus-server-server-name))
 295         (killed (car gnus-server-killed-servers)))
 296     (if (not server)
 297         (setq gnus-server-alist (nconc gnus-server-alist (list killed)))
 298       (if (string= server (caar gnus-server-alist))
 299           (push killed gnus-server-alist)
 300         (while (and (cdr alist)
 301                     (not (string= server (caadr alist))))
 302           (setq alist (cdr alist)))
 303         (if alist
 304             (setcdr alist (cons killed (cdr alist)))
 305           (setq gnus-server-alist (list killed)))))
 306     (gnus-server-update-server (car killed))
 307     (setq gnus-server-killed-servers (cdr gnus-server-killed-servers))
 308     (gnus-server-position-point)))
 309
 310 (defun gnus-server-exit ()
 311   "Return to the group buffer."
 312   (interactive)
 313   (kill-buffer (current-buffer))
 314   (switch-to-buffer gnus-group-buffer)
 315   (run-hooks 'gnus-server-exit-hook))
 316
 317 (defun gnus-server-list-servers ()
 318   "List all available servers."
 319   (interactive)
 320   (let ((cur (gnus-server-server-name)))
 321     (gnus-server-prepare)
 322     (if cur (gnus-server-goto-server cur)
 323       (goto-char (point-max))
 324       (forward-line -1))
 325     (gnus-server-position-point)))
 326
 327 (defun gnus-server-set-status (method status)
 328   "Make METHOD have STATUS."
 329   (let ((entry (assoc method gnus-opened-servers)))
 330     (if entry
 331         (setcar (cdr entry) status)
 332       (push (list method status) gnus-opened-servers))))
 333
 334 (defun gnus-opened-servers-remove (method)
 335   "Remove METHOD from the list of opened servers."
 336   (setq gnus-opened-servers (delq (assoc method gnus-opened-servers)
 337                                   gnus-opened-servers)))
 338
 339 (defun gnus-server-open-server (server)
 340   "Force an open of SERVER."
 341   (interactive (list (gnus-server-server-name)))
 342   (let ((method (gnus-server-to-method server)))
 343     (unless method
 344       (error "No such server: %s" server))
 345     (gnus-server-set-status method 'ok)
 346     (prog1
 347         (or (gnus-open-server method)
 348             (progn (message "Couldn't open %s" server) nil))
 349       (gnus-server-update-server server)
 350       (gnus-server-position-point))))
 351
 352 (defun gnus-server-open-all-servers ()
 353   "Open all servers."
 354   (interactive)
 355   (let ((servers gnus-inserted-opened-servers))
 356     (while servers
 357       (gnus-server-open-server (car (pop servers))))))
 358
 359 (defun gnus-server-close-server (server)
 360   "Close SERVER."
 361   (interactive (list (gnus-server-server-name)))
 362   (let ((method (gnus-server-to-method server)))
 363     (unless method
 364       (error "No such server: %s" server))
 365     (gnus-server-set-status method 'closed)
 366     (prog1
 367         (gnus-close-server method)
 368       (gnus-server-update-server server)
 369       (gnus-server-position-point))))
 370
 371 (defun gnus-server-close-all-servers ()
 372   "Close all servers."
 373   (interactive)
 374   (let ((servers gnus-inserted-opened-servers))
 375     (while servers
 376       (gnus-server-close-server (car (pop servers))))))
 377
 378 (defun gnus-server-deny-server (server)
 379   "Make sure SERVER will never be attempted opened."
 380   (interactive (list (gnus-server-server-name)))
 381   (let ((method (gnus-server-to-method server)))
 382     (unless method
 383       (error "No such server: %s" server))
 384     (gnus-server-set-status method 'denied))
 385   (gnus-server-update-server server)
 386   (gnus-server-position-point)
 387   t)
 388
 389 (defun gnus-server-remove-denials ()
 390   "Make all denied servers into closed servers."
 391   (interactive)
 392   (let ((servers gnus-opened-servers))
 393     (while servers
 394       (when (eq (nth 1 (car servers)) 'denied)
 395         (setcar (nthcdr 1 (car servers)) 'closed))
 396       (setq servers (cdr servers))))
 397   (gnus-server-list-servers))
 398
 399 (defun gnus-server-copy-server (from to)
 400   (interactive
 401    (list
 402     (unless (gnus-server-server-name)
 403       (error "No server on the current line"))
 404     (read-string "Copy to: ")))
 405   (unless from
 406     (error "No server on current line"))
 407   (unless (and to (not (string= to "")))
 408     (error "No name to copy to"))
 409   (when (assoc to gnus-server-alist)
 410     (error "%s already exists" to))
 411   (unless (assoc from gnus-server-alist)
 412     (error "%s: no such server" from))
 413   (let ((to-entry (gnus-copy-sequence (assoc from gnus-server-alist))))
 414     (setcar to-entry to)
 415     (setcar (nthcdr 2 to-entry) to)
 416     (push to-entry gnus-server-killed-servers)
 417     (gnus-server-yank-server)))
 418
 419 (defun gnus-server-add-server (how where)
 420   (interactive
 421    (list (intern (completing-read "Server method: "
 422                                   gnus-valid-select-methods nil t))
 423          (read-string "Server name: ")))
 424   (push (list where how where) gnus-server-killed-servers)
 425   (gnus-server-yank-server))
 426
 427 (defun gnus-server-goto-server (server)
 428   "Jump to a server line."
 429   (interactive
 430    (list (completing-read "Goto server: " gnus-server-alist nil t)))
 431   (let ((to (text-property-any (point-min) (point-max)
 432                                'gnus-server (intern server))))
 433     (when to
 434       (goto-char to)
 435       (gnus-server-position-point))))
 436
 437 (defun gnus-server-edit-server (server)
 438   "Edit the server on the current line."
 439   (interactive (list (gnus-server-server-name)))
 440   (unless server
 441     (error "No server on current line"))
 442   (unless (assoc server gnus-server-alist)
 443     (error "This server can't be edited"))
 444   (let ((info (cdr (assoc server gnus-server-alist))))
 445     (gnus-close-server info)
 446     (gnus-edit-form
 447      info "Editing the server."
 448      `(lambda (form)
 449         (gnus-server-set-info ,server form)
 450         (gnus-server-list-servers)
 451         (gnus-server-position-point)))))
 452
 453 (defun gnus-server-scan-server (server)
 454   "Request a scan from the current server."
 455   (interactive (list (gnus-server-server-name)))
 456   (gnus-message 3 "Scanning %s...done" server)
 457   (gnus-request-scan nil (gnus-server-to-method server))
 458   (gnus-message 3 "Scanning %s...done" server))
 459
 460 (defun gnus-server-read-server (server)
 461   "Browse a server."
 462   (interactive (list (gnus-server-server-name)))
 463   (let ((buf (current-buffer)))
 464     (prog1
 465         (gnus-browse-foreign-server (gnus-server-to-method server) buf)
 466       (save-excursion
 467         (set-buffer buf)
 468         (gnus-server-update-server (gnus-server-server-name))
 469         (gnus-server-position-point)))))
 470
 471 (defun gnus-server-pick-server (e)
 472   (interactive "e")
 473   (mouse-set-point e)
 474   (gnus-server-read-server (gnus-server-server-name)))
 475
 476 \f
 477 ;;;
 478 ;;; Browse Server Mode
 479 ;;;
 480
 481 (defvar gnus-browse-menu-hook nil
 482   "*Hook run after the creation of the browse mode menu.")
 483
 484 (defvar gnus-browse-mode-hook nil)
 485 (defvar gnus-browse-mode-map nil)
 486 (put 'gnus-browse-mode 'mode-class 'special)
 487
 488 (unless gnus-browse-mode-map
 489   (setq gnus-browse-mode-map (make-keymap))
 490   (suppress-keymap gnus-browse-mode-map)
 491
 492   (gnus-define-keys
 493    gnus-browse-mode-map
 494    " " gnus-browse-read-group
 495    "=" gnus-browse-select-group
 496    "n" gnus-browse-next-group
 497    "p" gnus-browse-prev-group
 498    "\177" gnus-browse-prev-group
 499    "N" gnus-browse-next-group
 500    "P" gnus-browse-prev-group
 501    "\M-n" gnus-browse-next-group
 502    "\M-p" gnus-browse-prev-group
 503    "\r" gnus-browse-select-group
 504    "u" gnus-browse-unsubscribe-current-group
 505    "l" gnus-browse-exit
 506    "L" gnus-browse-exit
 507    "q" gnus-browse-exit
 508    "Q" gnus-browse-exit
 509    "\C-c\C-c" gnus-browse-exit
 510    "?" gnus-browse-describe-briefly
 511
 512    "\C-c\C-i" gnus-info-find-node))
 513
 514 (defun gnus-browse-make-menu-bar ()
 515   (gnus-turn-off-edit-menu 'browse)
 516   (unless (boundp 'gnus-browse-menu)
 517     (easy-menu-define
 518      gnus-browse-menu gnus-browse-mode-map ""
 519      '("Browse"
 520        ["Subscribe" gnus-browse-unsubscribe-current-group t]
 521        ["Read" gnus-browse-read-group t]
 522        ["Select" gnus-browse-read-group t]
 523        ["Next" gnus-browse-next-group t]
 524        ["Prev" gnus-browse-next-group t]
 525        ["Exit" gnus-browse-exit t]
 526        ))
 527     (run-hooks 'gnus-browse-menu-hook)))
 528
 529 (defvar gnus-browse-current-method nil)
 530 (defvar gnus-browse-return-buffer nil)
 531
 532 (defvar gnus-browse-buffer "*Gnus Browse Server*")
 533
 534 (defun gnus-browse-foreign-server (method &optional return-buffer)
 535   "Browse the server METHOD."
 536   (setq gnus-browse-current-method method)
 537   (setq gnus-browse-return-buffer return-buffer)
 538   (let ((gnus-select-method method)
 539         groups group)
 540     (gnus-message 5 "Connecting to %s..." (nth 1 method))
 541     (cond
 542      ((not (gnus-check-server method))
 543       (gnus-message
 544        1 "Unable to contact server: %s" (gnus-status-message method))
 545       nil)
 546      ((not (gnus-request-list method))
 547       (gnus-message
 548        1 "Couldn't request list: %s" (gnus-status-message method))
 549       nil)
 550      (t
 551       (get-buffer-create gnus-browse-buffer)
 552       (gnus-add-current-to-buffer-list)
 553       (when gnus-carpal
 554         (gnus-carpal-setup-buffer 'browse))
 555       (gnus-configure-windows 'browse)
 556       (buffer-disable-undo (current-buffer))
 557       (let ((buffer-read-only nil))
 558         (erase-buffer))
 559       (gnus-browse-mode)
 560       (setq mode-line-buffer-identification
 561             (list
 562              (format
 563               "Gnus: %%b {%s:%s}" (car method) (cadr method))))
 564       (save-excursion
 565         (set-buffer nntp-server-buffer)
 566         (let ((cur (current-buffer)))
 567           (goto-char (point-min))
 568           (unless (string= gnus-ignored-newsgroups "")
 569             (delete-matching-lines gnus-ignored-newsgroups))
 570           (while (re-search-forward
 571                   "\\(^[^ \t]+\\)[ \t]+[0-9]+[ \t]+[0-9]+" nil t)
 572             (goto-char (match-end 1))
 573             (push (cons (match-string 1)
 574                         (max 0 (- (1+ (read cur)) (read cur))))
 575                   groups))))
 576       (setq groups (sort groups
 577                          (lambda (l1 l2)
 578                            (string< (car l1) (car l2)))))
 579       (let ((buffer-read-only nil))
 580         (while groups
 581           (setq group (car groups))
 582           (insert
 583            (format "K%7d: %s\n" (cdr group) (car group)))
 584           (setq groups (cdr groups))))
 585       (switch-to-buffer (current-buffer))
 586       (goto-char (point-min))
 587       (gnus-group-position-point)
 588       (gnus-message 5 "Connecting to %s...done" (nth 1 method))
 589       t))))
 590
 591 (defun gnus-browse-mode ()
 592   "Major mode for browsing a foreign server.
 593
 594 All normal editing commands are switched off.
 595
 596 \\<gnus-browse-mode-map>
 597 The only things you can do in this buffer is
 598
 599 1) `\\[gnus-browse-unsubscribe-current-group]' to subscribe to a group.
 600 The group will be inserted into the group buffer upon exit from this
 601 buffer.
 602
 603 2) `\\[gnus-browse-read-group]' to read a group ephemerally.
 604
 605 3) `\\[gnus-browse-exit]' to return to the group buffer."
 606   (interactive)
 607   (kill-all-local-variables)
 608   (when (and menu-bar-mode
 609              (gnus-visual-p 'browse-menu 'menu))
 610     (gnus-browse-make-menu-bar))
 611   (gnus-simplify-mode-line)
 612   (setq major-mode 'gnus-browse-mode)
 613   (setq mode-name "Browse Server")
 614   (setq mode-line-process nil)
 615   (use-local-map gnus-browse-mode-map)
 616   (buffer-disable-undo (current-buffer))
 617   (setq truncate-lines t)
 618   (gnus-set-default-directory)
 619   (setq buffer-read-only t)
 620   (run-hooks 'gnus-browse-mode-hook))
 621
 622 (defun gnus-browse-read-group (&optional no-article)
 623   "Enter the group at the current line."
 624   (interactive)
 625   (let ((group (gnus-browse-group-name)))
 626     (unless (gnus-group-read-ephemeral-group
 627              group gnus-browse-current-method nil
 628              (cons (current-buffer) 'browse))
 629       (error "Couldn't enter %s" group))))
 630
 631 (defun gnus-browse-select-group ()
 632   "Select the current group."
 633   (interactive)
 634   (gnus-browse-read-group 'no))
 635
 636 (defun gnus-browse-next-group (n)
 637   "Go to the next group."
 638   (interactive "p")
 639   (prog1
 640       (forward-line n)
 641     (gnus-group-position-point)))
 642
 643 (defun gnus-browse-prev-group (n)
 644   "Go to the next group."
 645   (interactive "p")
 646   (gnus-browse-next-group (- n)))
 647
 648 (defun gnus-browse-unsubscribe-current-group (arg)
 649   "(Un)subscribe to the next ARG groups."
 650   (interactive "p")
 651   (when (eobp)
 652     (error "No group at current line."))
 653   (let ((ward (if (< arg 0) -1 1))
 654         (arg (abs arg)))
 655     (while (and (> arg 0)
 656                 (not (eobp))
 657                 (gnus-browse-unsubscribe-group)
 658                 (zerop (gnus-browse-next-group ward)))
 659       (decf arg))
 660     (gnus-group-position-point)
 661     (when (/= 0 arg)
 662       (gnus-message 7 "No more newsgroups"))
 663     arg))
 664
 665 (defun gnus-browse-group-name ()
 666   (save-excursion
 667     (beginning-of-line)
 668     (when (re-search-forward ": \\(.*\\)$" (gnus-point-at-eol) t)
 669       (gnus-group-prefixed-name (match-string 1) gnus-browse-current-method))))
 670
 671 (defun gnus-browse-unsubscribe-group ()
 672   "Toggle subscription of the current group in the browse buffer."
 673   (let ((sub nil)
 674         (buffer-read-only nil)
 675         group)
 676     (save-excursion
 677       (beginning-of-line)
 678       ;; If this group it killed, then we want to subscribe it.
 679       (when (= (following-char) ?K)
 680         (setq sub t))
 681       (setq group (gnus-browse-group-name))
 682       ;; Make sure the group has been properly removed before we
 683       ;; subscribe to it.
 684       (gnus-kill-ephemeral-group group)
 685       (delete-char 1)
 686       (if sub
 687           (progn
 688             (gnus-group-change-level
 689              (list t group gnus-level-default-subscribed
 690                    nil nil gnus-browse-current-method)
 691              gnus-level-default-subscribed gnus-level-killed
 692              (and (car (nth 1 gnus-newsrc-alist))
 693                   (gnus-gethash (car (nth 1 gnus-newsrc-alist))
 694                                 gnus-newsrc-hashtb))
 695              t)
 696             (insert ? ))
 697         (gnus-group-change-level
 698          group gnus-level-killed gnus-level-default-subscribed)
 699         (insert ?K)))
 700     t))
 701
 702 (defun gnus-browse-exit ()
 703   "Quit browsing and return to the group buffer."
 704   (interactive)
 705   (when (eq major-mode 'gnus-browse-mode)
 706     (kill-buffer (current-buffer)))
 707   ;; Insert the newly subscribed groups in the group buffer.
 708   (save-excursion
 709     (set-buffer gnus-group-buffer)
 710     (gnus-group-list-groups nil))
 711   (if gnus-browse-return-buffer
 712       (gnus-configure-windows 'server 'force)
 713     (gnus-configure-windows 'group 'force)))
 714
 715 (defun gnus-browse-describe-briefly ()
 716   "Give a one line description of the group mode commands."
 717   (interactive)
 718   (gnus-message 6
 719                 (substitute-command-keys "\\<gnus-browse-mode-map>\\[gnus-group-next-group]:Forward  \\[gnus-group-prev-group]:Backward  \\[gnus-browse-exit]:Exit  \\[gnus-info-find-node]:Run Info  \\[gnus-browse-describe-briefly]:This help")))
 720
 721 (provide 'gnus-srvr)
 722
 723 ;;; gnus-srvr.el ends here.