cgit.sxemacs.org Git - gnus/blob - lisp/gnus-srvr.el

   1 ;;; gnus-srvr.el --- virtual server support for Gnus
   2
   3 ;; Copyright (C) 1995, 1996, 1997, 1998, 1999, 2000, 2001, 2002, 2003,
   4 ;;   2004, 2005, 2006, 2007 Free Software Foundation, Inc.
   5
   6 ;; Author: Lars Magne Ingebrigtsen <larsi@gnus.org>
   7 ;; Keywords: news
   8
   9 ;; This file is part of GNU Emacs.
  10
  11 ;; GNU Emacs is free software; you can redistribute it and/or modify
  12 ;; it under the terms of the GNU General Public License as published by
  13 ;; the Free Software Foundation; either version 2, or (at your option)
  14 ;; any later version.
  15
  16 ;; GNU Emacs is distributed in the hope that it will be useful,
  17 ;; but WITHOUT ANY WARRANTY; without even the implied warranty of
  18 ;; MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.  See the
  19 ;; GNU General Public License for more details.
  20
  21 ;; You should have received a copy of the GNU General Public License
  22 ;; along with GNU Emacs; see the file COPYING.  If not, write to the
  23 ;; Free Software Foundation, Inc., 51 Franklin Street, Fifth Floor,
  24 ;; Boston, MA 02110-1301, USA.
  25
  26 ;;; Commentary:
  27
  28 ;;; Code:
  29
  30 (eval-when-compile (require 'cl))
  31
  32 (require 'gnus)
  33 (require 'gnus-spec)
  34 (require 'gnus-group)
  35 (require 'gnus-int)
  36 (require 'gnus-range)
  37
  38 (defcustom gnus-server-mode-hook nil
  39   "Hook run in `gnus-server-mode' buffers."
  40   :group 'gnus-server
  41   :type 'hook)
  42
  43 (defcustom gnus-server-exit-hook nil
  44   "Hook run when exiting the server buffer."
  45   :group 'gnus-server
  46   :type 'hook)
  47
  48 (defcustom gnus-server-line-format "     {%(%h:%w%)} %s%a\n"
  49   "Format of server lines.
  50 It works along the same lines as a normal formatting string,
  51 with some simple extensions.
  52
  53 The following specs are understood:
  54
  55 %h back end
  56 %n name
  57 %w address
  58 %s status
  59 %a agent covered
  60
  61 General format specifiers can also be used.
  62 See Info node `(gnus)Formatting Variables'."
  63   :link '(custom-manual "(gnus)Formatting Variables")
  64   :group 'gnus-server-visual
  65   :type 'string)
  66
  67 (defcustom gnus-server-mode-line-format "Gnus: %%b"
  68   "The format specification for the server mode line."
  69   :group 'gnus-server-visual
  70   :type 'string)
  71
  72 (defcustom gnus-server-browse-in-group-buffer nil
  73   "Whether server browsing should take place in the group buffer.
  74 If nil, a faster, but more primitive, buffer is used instead."
  75   :version "22.1"
  76   :group 'gnus-server-visual
  77   :type 'boolean)
  78
  79 ;;; Internal variables.
  80
  81 (defvar gnus-inserted-opened-servers nil)
  82
  83 (defvar gnus-server-line-format-alist
  84   `((?h gnus-tmp-how ?s)
  85     (?n gnus-tmp-name ?s)
  86     (?w gnus-tmp-where ?s)
  87     (?s gnus-tmp-status ?s)
  88     (?a gnus-tmp-agent ?s)))
  89
  90 (defvar gnus-server-mode-line-format-alist
  91   `((?S gnus-tmp-news-server ?s)
  92     (?M gnus-tmp-news-method ?s)
  93     (?u gnus-tmp-user-defined ?s)))
  94
  95 (defvar gnus-server-line-format-spec nil)
  96 (defvar gnus-server-mode-line-format-spec nil)
  97 (defvar gnus-server-killed-servers nil)
  98
  99 (defvar gnus-server-mode-map)
 100
 101 (defvar gnus-server-menu-hook nil
 102   "*Hook run after the creation of the server mode menu.")
 103
 104 (defun gnus-server-make-menu-bar ()
 105   (gnus-turn-off-edit-menu 'server)
 106   (unless (boundp 'gnus-server-server-menu)
 107     (easy-menu-define
 108      gnus-server-server-menu gnus-server-mode-map ""
 109      '("Server"
 110        ["Add..." gnus-server-add-server t]
 111        ["Browse" gnus-server-read-server t]
 112        ["Scan" gnus-server-scan-server t]
 113        ["List" gnus-server-list-servers t]
 114        ["Kill" gnus-server-kill-server t]
 115        ["Yank" gnus-server-yank-server t]
 116        ["Copy" gnus-server-copy-server t]
 117        ["Edit" gnus-server-edit-server t]
 118        ["Regenerate" gnus-server-regenerate-server t]
 119        ["Compact" gnus-server-compact-server t]
 120        ["Exit" gnus-server-exit t]))
 121
 122     (easy-menu-define
 123      gnus-server-connections-menu gnus-server-mode-map ""
 124      '("Connections"
 125        ["Open" gnus-server-open-server t]
 126        ["Close" gnus-server-close-server t]
 127        ["Offline" gnus-server-offline-server t]
 128        ["Deny" gnus-server-deny-server t]
 129        "---"
 130        ["Open All" gnus-server-open-all-servers t]
 131        ["Close All" gnus-server-close-all-servers t]
 132        ["Reset All" gnus-server-remove-denials t]))
 133
 134     (gnus-run-hooks 'gnus-server-menu-hook)))
 135
 136 (defvar gnus-server-mode-map nil)
 137 (put 'gnus-server-mode 'mode-class 'special)
 138
 139 (unless gnus-server-mode-map
 140   (setq gnus-server-mode-map (make-sparse-keymap))
 141   (suppress-keymap gnus-server-mode-map)
 142
 143   (gnus-define-keys gnus-server-mode-map
 144     " " gnus-server-read-server-in-server-buffer
 145     "\r" gnus-server-read-server
 146     gnus-mouse-2 gnus-server-pick-server
 147     "q" gnus-server-exit
 148     "l" gnus-server-list-servers
 149     "k" gnus-server-kill-server
 150     "y" gnus-server-yank-server
 151     "c" gnus-server-copy-server
 152     "a" gnus-server-add-server
 153     "e" gnus-server-edit-server
 154     "s" gnus-server-scan-server
 155
 156     "O" gnus-server-open-server
 157     "\M-o" gnus-server-open-all-servers
 158     "C" gnus-server-close-server
 159     "\M-c" gnus-server-close-all-servers
 160     "D" gnus-server-deny-server
 161     "L" gnus-server-offline-server
 162     "R" gnus-server-remove-denials
 163
 164     "n" next-line
 165     "p" previous-line
 166
 167     "g" gnus-server-regenerate-server
 168
 169     "z" gnus-server-compact-server
 170
 171     "\C-c\C-i" gnus-info-find-node
 172     "\C-c\C-b" gnus-bug))
 173
 174 (defface gnus-server-agent
 175   '((((class color) (background light)) (:foreground "PaleTurquoise" :bold t))
 176     (((class color) (background dark)) (:foreground "PaleTurquoise" :bold t))
 177     (t (:bold t)))
 178   "Face used for displaying AGENTIZED servers"
 179   :group 'gnus-server-visual)
 180 ;; backward-compatibility alias
 181 (put 'gnus-server-agent-face 'face-alias 'gnus-server-agent)
 182
 183 (defface gnus-server-opened
 184   '((((class color) (background light)) (:foreground "Green3" :bold t))
 185     (((class color) (background dark)) (:foreground "Green1" :bold t))
 186     (t (:bold t)))
 187   "Face used for displaying OPENED servers"
 188   :group 'gnus-server-visual)
 189 ;; backward-compatibility alias
 190 (put 'gnus-server-opened-face 'face-alias 'gnus-server-opened)
 191
 192 (defface gnus-server-closed
 193   '((((class color) (background light)) (:foreground "Steel Blue" :italic t))
 194     (((class color) (background dark))
 195      (:foreground "LightBlue" :italic t))
 196     (t (:italic t)))
 197   "Face used for displaying CLOSED servers"
 198   :group 'gnus-server-visual)
 199 ;; backward-compatibility alias
 200 (put 'gnus-server-closed-face 'face-alias 'gnus-server-closed)
 201
 202 (defface gnus-server-denied
 203   '((((class color) (background light)) (:foreground "Red" :bold t))
 204     (((class color) (background dark)) (:foreground "Pink" :bold t))
 205     (t (:inverse-video t :bold t)))
 206   "Face used for displaying DENIED servers"
 207   :group 'gnus-server-visual)
 208 ;; backward-compatibility alias
 209 (put 'gnus-server-denied-face 'face-alias 'gnus-server-denied)
 210
 211 (defface gnus-server-offline
 212   '((((class color) (background light)) (:foreground "Orange" :bold t))
 213     (((class color) (background dark)) (:foreground "Yellow" :bold t))
 214     (t (:inverse-video t :bold t)))
 215   "Face used for displaying OFFLINE servers"
 216   :group 'gnus-server-visual)
 217 ;; backward-compatibility alias
 218 (put 'gnus-server-offline-face 'face-alias 'gnus-server-offline)
 219
 220 (defvar gnus-server-font-lock-keywords
 221   '(("(\\(agent\\))" 1 'gnus-server-agent)
 222     ("(\\(opened\\))" 1 'gnus-server-opened)
 223     ("(\\(closed\\))" 1 'gnus-server-closed)
 224     ("(\\(offline\\))" 1 'gnus-server-offline)
 225     ("(\\(denied\\))" 1 'gnus-server-denied)))
 226
 227 (defun gnus-server-mode ()
 228   "Major mode for listing and editing servers.
 229
 230 All normal editing commands are switched off.
 231 \\<gnus-server-mode-map>
 232 For more in-depth information on this mode, read the manual
 233 \(`\\[gnus-info-find-node]').
 234
 235 The following commands are available:
 236
 237 \\{gnus-server-mode-map}"
 238   (interactive)
 239   (when (gnus-visual-p 'server-menu 'menu)
 240     (gnus-server-make-menu-bar))
 241   (kill-all-local-variables)
 242   (gnus-simplify-mode-line)
 243   (setq major-mode 'gnus-server-mode)
 244   (setq mode-name "Server")
 245   (gnus-set-default-directory)
 246   (setq mode-line-process nil)
 247   (use-local-map gnus-server-mode-map)
 248   (buffer-disable-undo)
 249   (setq truncate-lines t)
 250   (setq buffer-read-only t)
 251   (if (featurep 'xemacs)
 252       (put 'gnus-server-mode 'font-lock-defaults '(gnus-server-font-lock-keywords t))
 253     (set (make-local-variable 'font-lock-defaults)
 254          '(gnus-server-font-lock-keywords t)))
 255   (gnus-run-mode-hooks 'gnus-server-mode-hook))
 256
 257 (defun gnus-server-insert-server-line (gnus-tmp-name method)
 258   (let* ((gnus-tmp-how (car method))
 259          (gnus-tmp-where (nth 1 method))
 260          (elem (assoc method gnus-opened-servers))
 261          (gnus-tmp-status
 262           (cond
 263            ((eq (nth 1 elem) 'denied) "(denied)")
 264            ((eq (nth 1 elem) 'offline) "(offline)")
 265            (t
 266             (condition-case nil
 267                 (if (or (gnus-server-opened method)
 268                         (eq (nth 1 elem) 'ok))
 269                     "(opened)"
 270                   "(closed)")
 271               ((error) "(error)")))))
 272          (gnus-tmp-agent (if (and gnus-agent
 273                                   (gnus-agent-method-p method))
 274                              " (agent)"
 275                            "")))
 276     (beginning-of-line)
 277     (gnus-add-text-properties
 278      (point)
 279      (prog1 (1+ (point))
 280        ;; Insert the text.
 281        (eval gnus-server-line-format-spec))
 282      (list 'gnus-server (intern gnus-tmp-name)
 283            'gnus-named-server (intern (gnus-method-to-server method))))))
 284
 285 (defun gnus-enter-server-buffer ()
 286   "Set up the server buffer."
 287   (gnus-server-setup-buffer)
 288   (gnus-configure-windows 'server)
 289   (gnus-server-prepare))
 290
 291 (defun gnus-server-setup-buffer ()
 292   "Initialize the server buffer."
 293   (unless (get-buffer gnus-server-buffer)
 294     (save-excursion
 295       (set-buffer (gnus-get-buffer-create gnus-server-buffer))
 296       (gnus-server-mode)
 297       (when gnus-carpal
 298         (gnus-carpal-setup-buffer 'server)))))
 299
 300 (defun gnus-server-prepare ()
 301   (gnus-set-format 'server-mode)
 302   (gnus-set-format 'server t)
 303   (let ((alist gnus-server-alist)
 304         (buffer-read-only nil)
 305         done server op-ser)
 306     (erase-buffer)
 307     (setq gnus-inserted-opened-servers nil)
 308     ;; First we do the real list of servers.
 309     (while alist
 310       (unless (member (cdar alist) done)
 311         (push (cdar alist) done)
 312         (setq server (pop alist))
 313         (when (and server (car server) (cdr server))
 314           (gnus-server-insert-server-line (car server) (cdr server))))
 315       (when (member (cdar alist) done)
 316         (pop alist)))
 317     ;; Then we insert the list of servers that have been opened in
 318     ;; this session.
 319     (dolist (open gnus-opened-servers)
 320       (when (and (not (member (car open) done))
 321                  ;; Just ignore ephemeral servers.
 322                  (not (member (car open) gnus-ephemeral-servers)))
 323         (push (car open) done)
 324         (gnus-server-insert-server-line
 325          (setq op-ser (format "%s:%s" (caar open) (nth 1 (car open))))
 326          (car open))
 327         (push (list op-ser (car open)) gnus-inserted-opened-servers))))
 328   (goto-char (point-min))
 329   (gnus-server-position-point))
 330
 331 (defun gnus-server-server-name ()
 332   (let ((server (get-text-property (point-at-bol) 'gnus-server)))
 333     (and server (symbol-name server))))
 334
 335 (defun gnus-server-named-server ()
 336   "Return a server name that matches one of the names returned by
 337 `gnus-method-to-server'."
 338   (let ((server (get-text-property (point-at-bol) 'gnus-named-server)))
 339     (and server (symbol-name server))))
 340
 341 (defalias 'gnus-server-position-point 'gnus-goto-colon)
 342
 343 (defconst gnus-server-edit-buffer "*Gnus edit server*")
 344
 345 (defun gnus-server-update-server (server)
 346   (save-excursion
 347     (set-buffer gnus-server-buffer)
 348     (let* ((buffer-read-only nil)
 349            (entry (assoc server gnus-server-alist))
 350            (oentry (assoc (gnus-server-to-method server)
 351                           gnus-opened-servers)))
 352       (when entry
 353         (gnus-dribble-enter
 354          (concat "(gnus-server-set-info \"" server "\" '"
 355                  (gnus-prin1-to-string (cdr entry)) ")\n")))
 356       (when (or entry oentry)
 357         ;; Buffer may be narrowed.
 358         (save-restriction
 359           (widen)
 360           (when (gnus-server-goto-server server)
 361             (gnus-delete-line))
 362           (if entry
 363               (gnus-server-insert-server-line (car entry) (cdr entry))
 364             (gnus-server-insert-server-line
 365              (format "%s:%s" (caar oentry) (nth 1 (car oentry)))
 366              (car oentry)))
 367           (gnus-server-position-point))))))
 368
 369 (defun gnus-server-set-info (server info)
 370   ;; Enter a select method into the virtual server alist.
 371   (when (and server info)
 372     (gnus-dribble-enter
 373      (concat "(gnus-server-set-info \"" server "\" '"
 374              (gnus-prin1-to-string info) ")"))
 375     (let* ((server (nth 1 info))
 376            (entry (assoc server gnus-server-alist))
 377            (cached (assoc server gnus-server-method-cache)))
 378       (if cached
 379           (setq gnus-server-method-cache
 380                 (delq cached gnus-server-method-cache)))
 381       (if entry
 382           (progn
 383             ;; Remove the server from `gnus-opened-servers' since
 384             ;; it has never been opened with the new `info' yet.
 385             (gnus-opened-servers-remove (cdr entry))
 386             ;; Don't make a new Lisp object.
 387             (setcar (cdr entry) (car info))
 388             (setcdr (cdr entry) (cdr info)))
 389         (setq gnus-server-alist
 390               (nconc gnus-server-alist (list (cons server info))))))))
 391
 392 ;;; Interactive server functions.
 393
 394 (defun gnus-server-kill-server (server)
 395   "Kill the server on the current line."
 396   (interactive (list (gnus-server-server-name)))
 397   (unless (gnus-server-goto-server server)
 398     (if server (error "No such server: %s" server)
 399       (error "No server on the current line")))
 400   (unless (assoc server gnus-server-alist)
 401     (error "Read-only server %s" server))
 402   (gnus-dribble-touch)
 403   (let ((buffer-read-only nil))
 404     (gnus-delete-line))
 405   (push (assoc server gnus-server-alist) gnus-server-killed-servers)
 406   (setq gnus-server-alist (delq (car gnus-server-killed-servers)
 407                                 gnus-server-alist))
 408   (let ((groups (gnus-groups-from-server server)))
 409     (when (and groups
 410                (gnus-yes-or-no-p
 411                 (format "Kill all %s groups from this server? "
 412                         (length groups))))
 413       (dolist (group groups)
 414         (setq gnus-newsrc-alist
 415               (delq (assoc group gnus-newsrc-alist)
 416                     gnus-newsrc-alist))
 417         (when gnus-group-change-level-function
 418           (funcall gnus-group-change-level-function
 419                    group gnus-level-killed 3)))))
 420   (gnus-server-position-point))
 421
 422 (defun gnus-server-yank-server ()
 423   "Yank the previously killed server."
 424   (interactive)
 425   (unless gnus-server-killed-servers
 426     (error "No killed servers to be yanked"))
 427   (let ((alist gnus-server-alist)
 428         (server (gnus-server-server-name))
 429         (killed (car gnus-server-killed-servers)))
 430     (if (not server)
 431         (setq gnus-server-alist (nconc gnus-server-alist (list killed)))
 432       (if (string= server (caar gnus-server-alist))
 433           (push killed gnus-server-alist)
 434         (while (and (cdr alist)
 435                     (not (string= server (caadr alist))))
 436           (setq alist (cdr alist)))
 437         (if alist
 438             (setcdr alist (cons killed (cdr alist)))
 439           (setq gnus-server-alist (list killed)))))
 440     (gnus-server-update-server (car killed))
 441     (setq gnus-server-killed-servers (cdr gnus-server-killed-servers))
 442     (gnus-server-position-point)))
 443
 444 (defun gnus-server-exit ()
 445   "Return to the group buffer."
 446   (interactive)
 447   (gnus-run-hooks 'gnus-server-exit-hook)
 448   (gnus-kill-buffer (current-buffer))
 449   (gnus-configure-windows 'group t))
 450
 451 (defun gnus-server-list-servers ()
 452   "List all available servers."
 453   (interactive)
 454   (let ((cur (gnus-server-server-name)))
 455     (gnus-server-prepare)
 456     (if cur (gnus-server-goto-server cur)
 457       (goto-char (point-max))
 458       (forward-line -1))
 459     (gnus-server-position-point)))
 460
 461 (defun gnus-server-set-status (method status)
 462   "Make METHOD have STATUS."
 463   (let ((entry (assoc method gnus-opened-servers)))
 464     (if entry
 465         (setcar (cdr entry) status)
 466       (push (list method status) gnus-opened-servers))))
 467
 468 (defun gnus-opened-servers-remove (method)
 469   "Remove METHOD from the list of opened servers."
 470   (setq gnus-opened-servers (delq (assoc method gnus-opened-servers)
 471                                   gnus-opened-servers)))
 472
 473 (defun gnus-server-open-server (server)
 474   "Force an open of SERVER."
 475   (interactive (list (gnus-server-server-name)))
 476   (let ((method (gnus-server-to-method server)))
 477     (unless method
 478       (error "No such server: %s" server))
 479     (gnus-server-set-status method 'ok)
 480     (prog1
 481         (or (gnus-open-server method)
 482             (progn (message "Couldn't open %s" server) nil))
 483       (gnus-server-update-server server)
 484       (gnus-server-position-point))))
 485
 486 (defun gnus-server-open-all-servers ()
 487   "Open all servers."
 488   (interactive)
 489   (dolist (server gnus-inserted-opened-servers)
 490     (gnus-server-open-server (car server))))
 491
 492 (defun gnus-server-close-server (server)
 493   "Close SERVER."
 494   (interactive (list (gnus-server-server-name)))
 495   (let ((method (gnus-server-to-method server)))
 496     (unless method
 497       (error "No such server: %s" server))
 498     (gnus-server-set-status method 'closed)
 499     (prog1
 500         (gnus-close-server method)
 501       (gnus-server-update-server server)
 502       (gnus-server-position-point))))
 503
 504 (defun gnus-server-offline-server (server)
 505   "Set SERVER to offline."
 506   (interactive (list (gnus-server-server-name)))
 507   (let ((method (gnus-server-to-method server)))
 508     (unless method
 509       (error "No such server: %s" server))
 510     (prog1
 511         (gnus-close-server method)
 512       (gnus-server-set-status method 'offline)
 513       (gnus-server-update-server server)
 514       (gnus-server-position-point))))
 515
 516 (defun gnus-server-close-all-servers ()
 517   "Close all servers."
 518   (interactive)
 519   (dolist (server gnus-inserted-opened-servers)
 520     (gnus-server-close-server (car server))))
 521
 522 (defun gnus-server-deny-server (server)
 523   "Make sure SERVER will never be attempted opened."
 524   (interactive (list (gnus-server-server-name)))
 525   (let ((method (gnus-server-to-method server)))
 526     (unless method
 527       (error "No such server: %s" server))
 528     (gnus-server-set-status method 'denied))
 529   (gnus-server-update-server server)
 530   (gnus-server-position-point)
 531   t)
 532
 533 (defun gnus-server-remove-denials ()
 534   "Make all denied servers into closed servers."
 535   (interactive)
 536   (dolist (server gnus-opened-servers)
 537     (when (eq (nth 1 server) 'denied)
 538       (setcar (nthcdr 1 server) 'closed)))
 539   (gnus-server-list-servers))
 540
 541 (defun gnus-server-copy-server (from to)
 542   (interactive
 543    (list
 544     (or (gnus-server-server-name)
 545         (error "No server on the current line"))
 546     (read-string "Copy to: ")))
 547   (unless from
 548     (error "No server on current line"))
 549   (unless (and to (not (string= to "")))
 550     (error "No name to copy to"))
 551   (when (assoc to gnus-server-alist)
 552     (error "%s already exists" to))
 553   (unless (gnus-server-to-method from)
 554     (error "%s: no such server" from))
 555   (let ((to-entry (cons from (gnus-copy-sequence
 556                               (gnus-server-to-method from)))))
 557     (setcar to-entry to)
 558     (setcar (nthcdr 2 to-entry) to)
 559     (push to-entry gnus-server-killed-servers)
 560     (gnus-server-yank-server)))
 561
 562 (defun gnus-server-add-server (how where)
 563   (interactive
 564    (list (intern (completing-read "Server method: "
 565                                   gnus-valid-select-methods nil t))
 566          (read-string "Server name: ")))
 567   (when (assq where gnus-server-alist)
 568     (error "Server with that name already defined"))
 569   (push (list where how where) gnus-server-killed-servers)
 570   (gnus-server-yank-server))
 571
 572 (defun gnus-server-goto-server (server)
 573   "Jump to a server line."
 574   (interactive
 575    (list (completing-read "Goto server: " gnus-server-alist nil t)))
 576   (let ((to (text-property-any (point-min) (point-max)
 577                                'gnus-server (intern server))))
 578     (when to
 579       (goto-char to)
 580       (gnus-server-position-point))))
 581
 582 (defun gnus-server-edit-server (server)
 583   "Edit the server on the current line."
 584   (interactive (list (gnus-server-server-name)))
 585   (unless server
 586     (error "No server on current line"))
 587   (unless (assoc server gnus-server-alist)
 588     (error "This server can't be edited"))
 589   (let ((info (cdr (assoc server gnus-server-alist))))
 590     (gnus-close-server info)
 591     (gnus-edit-form
 592      info "Editing the server."
 593      `(lambda (form)
 594         (gnus-server-set-info ,server form)
 595         (gnus-server-list-servers)
 596         (gnus-server-position-point))
 597      'edit-server)))
 598
 599 (defun gnus-server-scan-server (server)
 600   "Request a scan from the current server."
 601   (interactive (list (gnus-server-server-name)))
 602   (let ((method (gnus-server-to-method server)))
 603     (if (not (gnus-get-function method 'request-scan))
 604         (error "Server %s can't scan" (car method))
 605       (gnus-message 3 "Scanning %s..." server)
 606       (gnus-request-scan nil method)
 607       (gnus-message 3 "Scanning %s...done" server))))
 608
 609 (defun gnus-server-read-server-in-server-buffer (server)
 610   "Browse a server in server buffer."
 611   (interactive (list (gnus-server-server-name)))
 612   (let (gnus-server-browse-in-group-buffer)
 613     (gnus-server-read-server server)))
 614
 615 (defun gnus-server-read-server (server)
 616   "Browse a server."
 617   (interactive (list (gnus-server-server-name)))
 618   (let ((buf (current-buffer)))
 619     (prog1
 620         (gnus-browse-foreign-server server buf)
 621       (save-excursion
 622         (set-buffer buf)
 623         (gnus-server-update-server (gnus-server-server-name))
 624         (gnus-server-position-point)))))
 625
 626 (defun gnus-server-pick-server (e)
 627   (interactive "e")
 628   (mouse-set-point e)
 629   (gnus-server-read-server (gnus-server-server-name)))
 630
 631 \f
 632 ;;;
 633 ;;; Browse Server Mode
 634 ;;;
 635
 636 (defvar gnus-browse-menu-hook nil
 637   "*Hook run after the creation of the browse mode menu.")
 638
 639 (defvar gnus-browse-mode-hook nil)
 640 (defvar gnus-browse-mode-map nil)
 641 (put 'gnus-browse-mode 'mode-class 'special)
 642
 643 (unless gnus-browse-mode-map
 644   (setq gnus-browse-mode-map (make-keymap))
 645   (suppress-keymap gnus-browse-mode-map)
 646
 647   (gnus-define-keys
 648       gnus-browse-mode-map
 649     " " gnus-browse-read-group
 650     "=" gnus-browse-select-group
 651     "n" gnus-browse-next-group
 652     "p" gnus-browse-prev-group
 653     "\177" gnus-browse-prev-group
 654     [delete] gnus-browse-prev-group
 655     "N" gnus-browse-next-group
 656     "P" gnus-browse-prev-group
 657     "\M-n" gnus-browse-next-group
 658     "\M-p" gnus-browse-prev-group
 659     "\r" gnus-browse-select-group
 660     "u" gnus-browse-unsubscribe-current-group
 661     "l" gnus-browse-exit
 662     "L" gnus-browse-exit
 663     "q" gnus-browse-exit
 664     "Q" gnus-browse-exit
 665     "d" gnus-browse-describe-group
 666     "\C-c\C-c" gnus-browse-exit
 667     "?" gnus-browse-describe-briefly
 668
 669     "\C-c\C-i" gnus-info-find-node
 670     "\C-c\C-b" gnus-bug))
 671
 672 (defun gnus-browse-make-menu-bar ()
 673   (gnus-turn-off-edit-menu 'browse)
 674   (unless (boundp 'gnus-browse-menu)
 675     (easy-menu-define
 676      gnus-browse-menu gnus-browse-mode-map ""
 677      '("Browse"
 678        ["Subscribe" gnus-browse-unsubscribe-current-group t]
 679        ["Read" gnus-browse-read-group t]
 680        ["Select" gnus-browse-select-group t]
 681        ["Describe" gnus-browse-describe-group t]
 682        ["Next" gnus-browse-next-group t]
 683        ["Prev" gnus-browse-prev-group t]
 684        ["Exit" gnus-browse-exit t]))
 685     (gnus-run-hooks 'gnus-browse-menu-hook)))
 686
 687 (defvar gnus-browse-current-method nil)
 688 (defvar gnus-browse-return-buffer nil)
 689
 690 (defvar gnus-browse-buffer "*Gnus Browse Server*")
 691
 692 (defun gnus-browse-foreign-server (server &optional return-buffer)
 693   "Browse the server SERVER."
 694   (setq gnus-browse-current-method (gnus-server-to-method server))
 695   (setq gnus-browse-return-buffer return-buffer)
 696   (let* ((method gnus-browse-current-method)
 697          (orig-select-method gnus-select-method)
 698          (gnus-select-method method)
 699          groups group)
 700     (gnus-message 5 "Connecting to %s..." (nth 1 method))
 701     (cond
 702      ((not (gnus-check-server method))
 703       (gnus-message
 704        1 "Unable to contact server %s: %s" (nth 1 method)
 705        (gnus-status-message method))
 706       nil)
 707      ((not
 708        (prog2
 709            (gnus-message 6 "Reading active file...")
 710            (gnus-request-list method)
 711          (gnus-message 6 "Reading active file...done")))
 712       (gnus-message
 713        1 "Couldn't request list: %s" (gnus-status-message method))
 714       nil)
 715      (t
 716       (with-current-buffer nntp-server-buffer
 717         (let ((cur (current-buffer)))
 718           (goto-char (point-min))
 719           (unless (string= gnus-ignored-newsgroups "")
 720             (delete-matching-lines gnus-ignored-newsgroups))
 721           ;; We treat NNTP as a special case to avoid problems with
 722           ;; garbage group names like `"foo' that appear in some badly
 723           ;; managed active files. -jh.
 724           (if (eq (car method) 'nntp)
 725               (while (not (eobp))
 726                 (ignore-errors
 727                   (push (cons
 728                          (mm-string-as-unibyte
 729                           (buffer-substring
 730                            (point)
 731                            (progn
 732                              (skip-chars-forward "^ \t")
 733                              (point))))
 734                          (let ((last (read cur)))
 735                            (cons (read cur) last)))
 736                         groups))
 737                 (forward-line))
 738             (while (not (eobp))
 739               (ignore-errors
 740                 (push (cons
 741                        (mm-string-as-unibyte
 742                         (if (eq (char-after) ?\")
 743                             (read cur)
 744                           (let ((p (point)) (name ""))
 745                             (skip-chars-forward "^ \t\\\\")
 746                             (setq name (buffer-substring p (point)))
 747                             (while (eq (char-after) ?\\)
 748                               (setq p (1+ (point)))
 749                               (forward-char 2)
 750                               (skip-chars-forward "^ \t\\\\")
 751                               (setq name (concat name (buffer-substring
 752                                                        p (point)))))
 753                             name)))
 754                        (let ((last (read cur)))
 755                          (cons (read cur) last)))
 756                       groups))
 757               (forward-line)))))
 758       (setq groups (sort groups
 759                          (lambda (l1 l2)
 760                            (string< (car l1) (car l2)))))
 761       (if gnus-server-browse-in-group-buffer
 762           (let* ((gnus-select-method orig-select-method)
 763                  (gnus-group-listed-groups
 764                   (mapcar (lambda (group)
 765                             (let ((name
 766                                    (gnus-group-prefixed-name
 767                                     (car group) method)))
 768                               (gnus-set-active name (cdr group))
 769                               name))
 770                           groups)))
 771             (gnus-configure-windows 'group)
 772             (funcall gnus-group-prepare-function
 773                      gnus-level-killed 'ignore 1 'ignore))
 774         (gnus-get-buffer-create gnus-browse-buffer)
 775         (when gnus-carpal
 776           (gnus-carpal-setup-buffer 'browse))
 777         (gnus-configure-windows 'browse)
 778         (buffer-disable-undo)
 779         (let ((buffer-read-only nil))
 780           (erase-buffer))
 781         (gnus-browse-mode)
 782         (setq mode-line-buffer-identification
 783               (list
 784                (format
 785                 "Gnus: %%b {%s:%s}" (car method) (cadr method))))
 786         (let ((buffer-read-only nil)
 787               name
 788               (prefix (let ((gnus-select-method orig-select-method))
 789                         (gnus-group-prefixed-name "" method))))
 790           (while (setq group (pop groups))
 791             (gnus-add-text-properties
 792              (point)
 793              (prog1 (1+ (point))
 794                (insert
 795                 (format "%c%7d: %s\n"
 796                         (let ((level
 797                                (if (string= prefix "")
 798                                    (gnus-group-level (setq name (car group)))
 799                                  (gnus-group-level
 800                                   (concat prefix (setq name (car group)))))))
 801                           (cond
 802                            ((<= level gnus-level-subscribed) ? )
 803                            ((<= level gnus-level-unsubscribed) ?U)
 804                            ((= level gnus-level-zombie) ?Z)
 805                            (t ?K)))
 806                         (max 0 (- (1+ (cddr group)) (cadr group)))
 807                         ;; Don't decode if name is ASCII
 808                         (if (and (fboundp 'detect-coding-string)
 809                                  (eq (detect-coding-string name t) 'undecided))
 810                             name
 811                           (mm-decode-coding-string
 812                            name
 813                            (inline (gnus-group-name-charset method name)))))))
 814              (list 'gnus-group name)
 815              )))
 816         (switch-to-buffer (current-buffer)))
 817       (goto-char (point-min))
 818       (gnus-group-position-point)
 819       (gnus-message 5 "Connecting to %s...done" (nth 1 method))
 820       t))))
 821
 822 (defun gnus-browse-mode ()
 823   "Major mode for browsing a foreign server.
 824
 825 All normal editing commands are switched off.
 826
 827 \\<gnus-browse-mode-map>
 828 The only things you can do in this buffer is
 829
 830 1) `\\[gnus-browse-unsubscribe-current-group]' to subscribe to a group.
 831 The group will be inserted into the group buffer upon exit from this
 832 buffer.
 833
 834 2) `\\[gnus-browse-read-group]' to read a group ephemerally.
 835
 836 3) `\\[gnus-browse-exit]' to return to the group buffer."
 837   (interactive)
 838   (kill-all-local-variables)
 839   (when (gnus-visual-p 'browse-menu 'menu)
 840     (gnus-browse-make-menu-bar))
 841   (gnus-simplify-mode-line)
 842   (setq major-mode 'gnus-browse-mode)
 843   (setq mode-name "Browse Server")
 844   (setq mode-line-process nil)
 845   (use-local-map gnus-browse-mode-map)
 846   (buffer-disable-undo)
 847   (setq truncate-lines t)
 848   (gnus-set-default-directory)
 849   (setq buffer-read-only t)
 850   (gnus-run-mode-hooks 'gnus-browse-mode-hook))
 851
 852 (defun gnus-browse-read-group (&optional no-article number)
 853   "Enter the group at the current line.
 854 If NUMBER, fetch this number of articles."
 855   (interactive "P")
 856   (let ((group (gnus-browse-group-name)))
 857     (if (or (not (gnus-get-info group))
 858             (gnus-ephemeral-group-p group))
 859         (unless (gnus-group-read-ephemeral-group
 860                  group gnus-browse-current-method nil
 861                  (cons (current-buffer) 'browse)
 862                  nil nil nil number)
 863           (error "Couldn't enter %s" group))
 864       (unless (gnus-group-read-group nil no-article group)
 865         (error "Couldn't enter %s" group)))))
 866
 867 (defun gnus-browse-select-group (&optional number)
 868   "Select the current group.
 869 If NUMBER, fetch this number of articles."
 870   (interactive "P")
 871   (gnus-browse-read-group 'no number))
 872
 873 (defun gnus-browse-next-group (n)
 874   "Go to the next group."
 875   (interactive "p")
 876   (prog1
 877       (forward-line n)
 878     (gnus-group-position-point)))
 879
 880 (defun gnus-browse-prev-group (n)
 881   "Go to the next group."
 882   (interactive "p")
 883   (gnus-browse-next-group (- n)))
 884
 885 (defun gnus-browse-unsubscribe-current-group (arg)
 886   "(Un)subscribe to the next ARG groups."
 887   (interactive "p")
 888   (when (eobp)
 889     (error "No group at current line"))
 890   (let ((ward (if (< arg 0) -1 1))
 891         (arg (abs arg)))
 892     (while (and (> arg 0)
 893                 (not (eobp))
 894                 (gnus-browse-unsubscribe-group)
 895                 (zerop (gnus-browse-next-group ward)))
 896       (decf arg))
 897     (gnus-group-position-point)
 898     (when (/= 0 arg)
 899       (gnus-message 7 "No more newsgroups"))
 900     arg))
 901
 902 (defun gnus-browse-group-name ()
 903   (save-excursion
 904     (beginning-of-line)
 905     (let ((name (get-text-property (point) 'gnus-group)))
 906       (when (re-search-forward ": \\(.*\\)$" (point-at-eol) t)
 907         (concat (gnus-method-to-server-name gnus-browse-current-method) ":"
 908                 (or name
 909                     (match-string-no-properties 1)))))))
 910
 911 (defun gnus-browse-describe-group (group)
 912   "Describe the current group."
 913   (interactive (list (gnus-browse-group-name)))
 914   (gnus-group-describe-group nil group))
 915
 916 (defun gnus-browse-unsubscribe-group ()
 917   "Toggle subscription of the current group in the browse buffer."
 918   (let ((sub nil)
 919         (buffer-read-only nil)
 920         group)
 921     (save-excursion
 922       (beginning-of-line)
 923       ;; If this group it killed, then we want to subscribe it.
 924       (unless (eq (char-after) ? )
 925         (setq sub t))
 926       (setq group (gnus-browse-group-name))
 927       (when (gnus-server-equal gnus-browse-current-method "native")
 928         (setq group (gnus-group-real-name group)))
 929       (if sub
 930           (progn
 931             ;; Make sure the group has been properly removed before we
 932             ;; subscribe to it.
 933             (if (gnus-ephemeral-group-p group)
 934                 (gnus-kill-ephemeral-group group))
 935             ;; We need to discern between killed/zombie groups and
 936             ;; just unsubscribed ones.
 937             (gnus-group-change-level
 938              (or (gnus-group-entry group)
 939                  (list t group gnus-level-default-subscribed
 940                        nil nil (if (gnus-server-equal
 941                                     gnus-browse-current-method "native")
 942                                    nil
 943                                  (gnus-method-simplify
 944                                   gnus-browse-current-method))))
 945              gnus-level-default-subscribed (gnus-group-level group)
 946              (and (car (nth 1 gnus-newsrc-alist))
 947                   (gnus-group-entry (car (nth 1 gnus-newsrc-alist))))
 948              (null (gnus-group-entry group)))
 949             (delete-char 1)
 950             (insert ? ))
 951         (gnus-group-change-level
 952          group gnus-level-unsubscribed gnus-level-default-subscribed)
 953         (delete-char 1)
 954         (insert ?U)))
 955     t))
 956
 957 (defun gnus-browse-exit ()
 958   "Quit browsing and return to the group buffer."
 959   (interactive)
 960   (when (eq major-mode 'gnus-browse-mode)
 961     (gnus-kill-buffer (current-buffer)))
 962   ;; Insert the newly subscribed groups in the group buffer.
 963   (save-excursion
 964     (set-buffer gnus-group-buffer)
 965     (gnus-group-list-groups nil))
 966   (if gnus-browse-return-buffer
 967       (gnus-configure-windows 'server 'force)
 968     (gnus-configure-windows 'group 'force)))
 969
 970 (defun gnus-browse-describe-briefly ()
 971   "Give a one line description of the group mode commands."
 972   (interactive)
 973   (gnus-message 6
 974                 (substitute-command-keys "\\<gnus-browse-mode-map>\\[gnus-group-next-group]:Forward  \\[gnus-group-prev-group]:Backward  \\[gnus-browse-exit]:Exit  \\[gnus-info-find-node]:Run Info  \\[gnus-browse-describe-briefly]:This help")))
 975
 976 (defun gnus-server-regenerate-server ()
 977   "Issue a command to the server to regenerate all its data structures."
 978   (interactive)
 979   (let ((server (gnus-server-server-name)))
 980     (unless server
 981       (error "No server on the current line"))
 982     (condition-case ()
 983         (gnus-get-function (gnus-server-to-method server)
 984                            'request-regenerate)
 985       (error
 986         (error "This back end doesn't support regeneration")))
 987     (gnus-message 5 "Requesting regeneration of %s..." server)
 988     (unless (gnus-open-server server)
 989       (error "Couldn't open server"))
 990     (if (gnus-request-regenerate server)
 991         (gnus-message 5 "Requesting regeneration of %s...done" server)
 992       (gnus-message 5 "Couldn't regenerate %s" server))))
 993
 994
 995 ;;;
 996 ;;; Server compaction. -- dvl
 997 ;;;
 998
 999 ;; #### FIXME: this function currently fails to update the Group buffer's
1000 ;; #### appearance.
1001 (defun gnus-server-compact-server ()
1002   "Issue a command to the server to compact all its groups.
1003
1004 Note: currently only implemented in nnml."
1005   (interactive)
1006   (let ((server (gnus-server-server-name)))
1007     (unless server
1008       (error "No server on the current line"))
1009     (condition-case ()
1010         (gnus-get-function (gnus-server-to-method server)
1011                            'request-compact)
1012       (error
1013        (error "This back end doesn't support compaction")))
1014     (gnus-message 5 "\
1015 Requesting compaction of %s... (this may take a long time)"
1016                   server)
1017     (unless (gnus-open-server server)
1018       (error "Couldn't open server"))
1019     (if (not (gnus-request-compact server))
1020         (gnus-message 5 "Couldn't compact %s" server)
1021       (gnus-message 5 "Requesting compaction of %s...done" server)
1022       ;; Invalidate the original article buffer which might be out of date.
1023       ;; #### NOTE: Yes, this might be a bit rude, but since compaction
1024       ;; #### will not happen very often, I think this is acceptable.
1025       (let ((original (get-buffer gnus-original-article-buffer)))
1026         (and original (gnus-kill-buffer original))))))
1027
1028 (provide 'gnus-srvr)
1029
1030 ;;; arch-tag: c0117f64-27ca-475d-9406-8da6854c7a25
1031 ;;; gnus-srvr.el ends here