cgit.sxemacs.org Git - gnus/blob - lisp/gnus-spec.el

   1 ;;; gnus-spec.el --- format spec functions for Gnus  -*- coding: iso-latin-1 -*-
   2 ;; Copyright (C) 1996, 1997, 1998, 1999, 2000
   3 ;;        Free Software Foundation, Inc.
   4
   5 ;; Author: Lars Magne Ingebrigtsen <larsi@gnus.org>
   6 ;; Keywords: news
   7
   8 ;; This file is part of GNU Emacs.
   9
  10 ;; GNU Emacs is free software; you can redistribute it and/or modify
  11 ;; it under the terms of the GNU General Public License as published by
  12 ;; the Free Software Foundation; either version 2, or (at your option)
  13 ;; any later version.
  14
  15 ;; GNU Emacs is distributed in the hope that it will be useful,
  16 ;; but WITHOUT ANY WARRANTY; without even the implied warranty of
  17 ;; MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.  See the
  18 ;; GNU General Public License for more details.
  19
  20 ;; You should have received a copy of the GNU General Public License
  21 ;; along with GNU Emacs; see the file COPYING.  If not, write to the
  22 ;; Free Software Foundation, Inc., 59 Temple Place - Suite 330,
  23 ;; Boston, MA 02111-1307, USA.
  24
  25 ;;; Commentary:
  26
  27 ;;; Code:
  28
  29 (eval-when-compile (require 'cl))
  30
  31 (require 'gnus)
  32
  33 (defcustom gnus-use-correct-string-widths t
  34   "*If non-nil, use correct functions for dealing with wide characters."
  35   :group 'gnus-format
  36   :type 'boolean)
  37
  38 ;;; Internal variables.
  39
  40 (defvar gnus-summary-mark-positions nil)
  41 (defvar gnus-group-mark-positions nil)
  42 (defvar gnus-group-indentation "")
  43
  44 ;; Format specs.  The chunks below are the machine-generated forms
  45 ;; that are to be evaled as the result of the default format strings.
  46 ;; We write them in here to get them byte-compiled.  That way the
  47 ;; default actions will be quite fast, while still retaining the full
  48 ;; flexibility of the user-defined format specs.
  49
  50 ;; First we have lots of dummy defvars to let the compiler know these
  51 ;; are really dynamic variables.
  52
  53 (defvar gnus-tmp-unread)
  54 (defvar gnus-tmp-replied)
  55 (defvar gnus-tmp-score-char)
  56 (defvar gnus-tmp-indentation)
  57 (defvar gnus-tmp-opening-bracket)
  58 (defvar gnus-tmp-lines)
  59 (defvar gnus-tmp-name)
  60 (defvar gnus-tmp-closing-bracket)
  61 (defvar gnus-tmp-subject-or-nil)
  62 (defvar gnus-tmp-subject)
  63 (defvar gnus-tmp-marked)
  64 (defvar gnus-tmp-marked-mark)
  65 (defvar gnus-tmp-subscribed)
  66 (defvar gnus-tmp-process-marked)
  67 (defvar gnus-tmp-number-of-unread)
  68 (defvar gnus-tmp-group-name)
  69 (defvar gnus-tmp-group)
  70 (defvar gnus-tmp-article-number)
  71 (defvar gnus-tmp-unread-and-unselected)
  72 (defvar gnus-tmp-news-method)
  73 (defvar gnus-tmp-news-server)
  74 (defvar gnus-tmp-article-number)
  75 (defvar gnus-mouse-face)
  76 (defvar gnus-mouse-face-prop)
  77
  78 (defun gnus-summary-line-format-spec ()
  79   (insert gnus-tmp-unread gnus-tmp-replied
  80           gnus-tmp-score-char gnus-tmp-indentation)
  81   (gnus-put-text-property
  82    (point)
  83    (progn
  84      (insert
  85       gnus-tmp-opening-bracket
  86       (format "%4d: %-20s"
  87               gnus-tmp-lines
  88               (if (> (length gnus-tmp-name) 20)
  89                   (substring gnus-tmp-name 0 20)
  90                 gnus-tmp-name))
  91       gnus-tmp-closing-bracket)
  92      (point))
  93    gnus-mouse-face-prop gnus-mouse-face)
  94   (insert " " gnus-tmp-subject-or-nil "\n"))
  95
  96 (defvar gnus-summary-line-format-spec
  97   (gnus-byte-code 'gnus-summary-line-format-spec))
  98
  99 (defun gnus-summary-dummy-line-format-spec ()
 100   (insert "*  ")
 101   (gnus-put-text-property
 102    (point)
 103    (progn
 104      (insert ":                          :")
 105      (point))
 106    gnus-mouse-face-prop gnus-mouse-face)
 107   (insert " " gnus-tmp-subject "\n"))
 108
 109 (defvar gnus-summary-dummy-line-format-spec
 110   (gnus-byte-code 'gnus-summary-dummy-line-format-spec))
 111
 112 (defun gnus-group-line-format-spec ()
 113   (insert gnus-tmp-marked-mark gnus-tmp-subscribed
 114           gnus-tmp-process-marked
 115           gnus-group-indentation
 116           (format "%5s: " gnus-tmp-number-of-unread))
 117   (gnus-put-text-property
 118    (point)
 119    (progn
 120      (insert gnus-tmp-group "\n")
 121      (1- (point)))
 122    gnus-mouse-face-prop gnus-mouse-face))
 123 (defvar gnus-group-line-format-spec
 124   (gnus-byte-code 'gnus-group-line-format-spec))
 125
 126 (defvar gnus-format-specs
 127   `((version . ,emacs-version)
 128     (gnus-version . ,(gnus-continuum-version))
 129     (group "%M\%S\%p\%P\%5y: %(%g%)%l\n" ,gnus-group-line-format-spec)
 130     (summary-dummy "*  %(:                          :%) %S\n"
 131                    ,gnus-summary-dummy-line-format-spec)
 132     (summary "%U\%R\%z\%I\%(%[%4L: %-23,23n%]%) %s\n"
 133              ,gnus-summary-line-format-spec))
 134   "Alist of format specs.")
 135
 136 (defvar gnus-article-mode-line-format-spec nil)
 137 (defvar gnus-summary-mode-line-format-spec nil)
 138 (defvar gnus-group-mode-line-format-spec nil)
 139
 140 ;;; Phew.  All that gruft is over with, fortunately.
 141
 142 ;;;###autoload
 143 (defun gnus-update-format (var)
 144   "Update the format specification near point."
 145   (interactive
 146    (list
 147     (save-excursion
 148       (eval-defun nil)
 149       ;; Find the end of the current word.
 150       (re-search-forward "[ \t\n]" nil t)
 151       ;; Search backward.
 152       (when (re-search-backward "\\(gnus-[-a-z]+-line-format\\)" nil t)
 153         (match-string 1)))))
 154   (let* ((type (intern (progn (string-match "gnus-\\([-a-z]+\\)-line" var)
 155                               (match-string 1 var))))
 156          (entry (assq type gnus-format-specs))
 157          value spec)
 158     (when entry
 159       (setq gnus-format-specs (delq entry gnus-format-specs)))
 160     (set
 161      (intern (format "%s-spec" var))
 162      (gnus-parse-format (setq value (symbol-value (intern var)))
 163                         (symbol-value (intern (format "%s-alist" var)))
 164                         (not (string-match "mode" var))))
 165     (setq spec (symbol-value (intern (format "%s-spec" var))))
 166     (push (list type value spec) gnus-format-specs)
 167
 168     (pop-to-buffer "*Gnus Format*")
 169     (erase-buffer)
 170     (lisp-interaction-mode)
 171     (insert (pp-to-string spec))))
 172
 173 (defun gnus-update-format-specifications (&optional force &rest types)
 174   "Update all (necessary) format specifications."
 175   ;; Make the indentation array.
 176   ;; See whether all the stored info needs to be flushed.
 177   (when (or force
 178             (not (equal (gnus-continuum-version)
 179                         (cdr (assq 'gnus-version gnus-format-specs))))
 180             (not (equal emacs-version
 181                         (cdr (assq 'version gnus-format-specs)))))
 182     (setq gnus-format-specs nil))
 183
 184   ;; Go through all the formats and see whether they need updating.
 185   (let (new-format entry type val)
 186     (while (setq type (pop types))
 187       ;; Jump to the proper buffer to find out the value of the
 188       ;; variable, if possible.  (It may be buffer-local.)
 189       (save-excursion
 190         (let ((buffer (intern (format "gnus-%s-buffer" type)))
 191               val)
 192           (when (and (boundp buffer)
 193                      (setq val (symbol-value buffer))
 194                      (gnus-buffer-exists-p val))
 195             (set-buffer val))
 196           (setq new-format (symbol-value
 197                             (intern (format "gnus-%s-line-format" type)))))
 198         (setq entry (cdr (assq type gnus-format-specs)))
 199         (if (and (car entry)
 200                  (equal (car entry) new-format))
 201             ;; Use the old format.
 202             (set (intern (format "gnus-%s-line-format-spec" type))
 203                  (cadr entry))
 204           ;; This is a new format.
 205           (setq val
 206                 (if (not (stringp new-format))
 207                     ;; This is a function call or something.
 208                     new-format
 209                   ;; This is a "real" format.
 210                   (gnus-parse-format
 211                    new-format
 212                    (symbol-value
 213                     (intern (format "gnus-%s-line-format-alist" type)))
 214                    (not (string-match "mode$" (symbol-name type))))))
 215           ;; Enter the new format spec into the list.
 216           (if entry
 217               (progn
 218                 (setcar (cdr entry) val)
 219                 (setcar entry new-format))
 220             (push (list type new-format val) gnus-format-specs))
 221           (set (intern (format "gnus-%s-line-format-spec" type)) val)))))
 222
 223   (unless (assq 'version gnus-format-specs)
 224     (push (cons 'version emacs-version) gnus-format-specs)))
 225
 226 (defvar gnus-mouse-face-0 'highlight)
 227 (defvar gnus-mouse-face-1 'highlight)
 228 (defvar gnus-mouse-face-2 'highlight)
 229 (defvar gnus-mouse-face-3 'highlight)
 230 (defvar gnus-mouse-face-4 'highlight)
 231
 232 (defun gnus-mouse-face-function (form type)
 233   `(gnus-put-text-property
 234     (point) (progn ,@form (point))
 235     gnus-mouse-face-prop
 236     ,(if (equal type 0)
 237          'gnus-mouse-face
 238        `(quote ,(symbol-value (intern (format "gnus-mouse-face-%d" type)))))))
 239
 240 (defvar gnus-face-0 'bold)
 241 (defvar gnus-face-1 'italic)
 242 (defvar gnus-face-2 'bold-italic)
 243 (defvar gnus-face-3 'bold)
 244 (defvar gnus-face-4 'bold)
 245
 246 (defun gnus-face-face-function (form type)
 247   `(gnus-add-text-properties
 248     (point) (progn ,@form (point))
 249     '(gnus-face t face ,(symbol-value (intern (format "gnus-face-%d" type))))))
 250
 251 (defun gnus-balloon-face-function (form type)
 252   `(gnus-put-text-property
 253     (point) (progn ,@form (point))
 254     'balloon-help
 255     ,(intern (format "gnus-balloon-face-%d" type))))
 256
 257 (defun gnus-spec-tab (column)
 258   (if (> column 0)
 259       `(insert (make-string (max (- ,column (current-column)) 0) ? ))
 260     `(progn
 261        (if (> (current-column) ,(abs column))
 262            (delete-region (point)
 263                           (- (point) (- (current-column) ,(abs column))))
 264          (insert (make-string (max (- ,(abs column) (current-column)) 0)
 265                               ? ))))))
 266
 267 (defun gnus-correct-length (string)
 268   "Return the correct width of STRING."
 269   (let ((length 0))
 270     (mapcar (lambda (char) (incf length (gnus-char-width char))) string)
 271     length))
 272
 273 (defun gnus-correct-substring (string start &optional end)
 274   (let ((wstart 0)
 275         (wend 0)
 276         (wseek 0)
 277         (seek 0)
 278         (length (length string))
 279         (string (concat string "\0")))
 280     ;; Find the start position.
 281     (while (and (< seek length)
 282                 (< wseek start))
 283       (incf wseek (gnus-char-width (aref string seek)))
 284       (incf seek))
 285     (setq wstart seek)
 286     ;; Find the end position.
 287     (while (and (<= seek length)
 288                 (or (not end)
 289                     (<= wseek end)))
 290       (incf wseek (gnus-char-width (aref string seek)))
 291       (incf seek))
 292     (setq wend seek)
 293     (substring string wstart (1- wend))))
 294
 295 (defun gnus-tilde-max-form (el max-width)
 296   "Return a form that limits EL to MAX-WIDTH."
 297   (let ((max (abs max-width))
 298         (length-fun (if gnus-use-correct-string-widths
 299                       'gnus-correct-length
 300                     'length))
 301         (substring-fun (if gnus-use-correct-string-widths
 302                        'gnus-correct-substring
 303                      'substring)))
 304     (if (symbolp el)
 305         `(if (> (,length-fun ,el) ,max)
 306              ,(if (< max-width 0)
 307                   `(,substring-fun ,el (- (,length-fun ,el) ,max))
 308                 `(,substring-fun ,el 0 ,max))
 309            ,el)
 310       `(let ((val (eval ,el)))
 311          (if (> (,length-fun val) ,max)
 312              ,(if (< max-width 0)
 313                   `(,substring-fun val (- (,length-fun val) ,max))
 314                 `(,substring-fun val 0 ,max))
 315            val)))))
 316
 317 (defun gnus-tilde-cut-form (el cut-width)
 318   "Return a form that cuts CUT-WIDTH off of EL."
 319   (let ((cut (abs cut-width))
 320         (length-fun (if gnus-use-correct-string-widths
 321                       'gnus-correct-length
 322                     'length))
 323         (substring-fun (if gnus-use-correct-string-widths
 324                        'gnus-correct-substring
 325                      'substring)))
 326     (if (symbolp el)
 327         `(if (> (,length-fun ,el) ,cut)
 328              ,(if (< cut-width 0)
 329                   `(,substring-fun ,el 0 (- (,length-fun ,el) ,cut))
 330                 `(,substring-fun ,el ,cut))
 331            ,el)
 332       `(let ((val (eval ,el)))
 333          (if (> (,length-fun val) ,cut)
 334              ,(if (< cut-width 0)
 335                   `(,substring-fun val 0 (- (,length-fun val) ,cut))
 336                 `(,substring-fun val ,cut))
 337            val)))))
 338
 339 (defun gnus-tilde-ignore-form (el ignore-value)
 340   "Return a form that is blank when EL is IGNORE-VALUE."
 341   (if (symbolp el)
 342       `(if (equal ,el ,ignore-value)
 343            "" ,el)
 344     `(let ((val (eval ,el)))
 345        (if (equal val ,ignore-value)
 346            "" val))))
 347
 348 (defun gnus-parse-format (format spec-alist &optional insert)
 349   ;; This function parses the FORMAT string with the help of the
 350   ;; SPEC-ALIST and returns a list that can be eval'ed to return the
 351   ;; string.  If the FORMAT string contains the specifiers %( and %)
 352   ;; the text between them will have the mouse-face text property.
 353   ;; If the FORMAT string contains the specifiers %[ and %], the text between
 354   ;; them will have the balloon-help text property.
 355   (let ((case-fold-search nil))
 356     (if (string-match
 357        "\\`\\(.*\\)%[0-9]?[{(«]\\(.*\\)%[0-9]?[»})]\\(.*\n?\\)\\'"
 358        format)
 359       (gnus-parse-complex-format format spec-alist)
 360       ;; This is a simple format.
 361       (gnus-parse-simple-format format spec-alist insert))))
 362
 363 (defun gnus-parse-complex-format (format spec-alist)
 364   (save-excursion
 365     (gnus-set-work-buffer)
 366     (insert format)
 367     (goto-char (point-min))
 368     (while (re-search-forward "\"" nil t)
 369       (replace-match "\\\"" nil t))
 370     (goto-char (point-min))
 371     (insert "(\"")
 372     ;; Convert all font specs into font spec lists.
 373     (while (re-search-forward "%\\([0-9]+\\)?\\([«»{}()]\\)" nil t)
 374       (let ((number (if (match-beginning 1)
 375                         (match-string 1) "0"))
 376             (delim (aref (match-string 2) 0)))
 377         (if (or (= delim ?\()
 378                 (= delim ?\{)
 379                 (= delim ?\«))
 380             (replace-match (concat "\"("
 381                                    (cond ((= delim ?\() "mouse")
 382                                          ((= delim ?\{) "face")
 383                                          (t "balloon"))
 384                                    " " number " \"")
 385                            t t)
 386           (replace-match "\")\""))))
 387     (goto-char (point-max))
 388     (insert "\")")
 389     ;; Convert point position commands.
 390     (goto-char (point-min))
 391     (let ((case-fold-search nil))
 392       (while (re-search-forward "%\\([-0-9]+\\)?C" nil t)
 393         (replace-match "\"(point)\"" t t)))
 394     ;; Convert TAB commands.
 395     (goto-char (point-min))
 396     (while (re-search-forward "%\\([-0-9]+\\)=" nil t)
 397       (replace-match (format "\"(tab %s)\"" (match-string 1)) t t))
 398     ;; Convert the buffer into the spec.
 399     (goto-char (point-min))
 400     (let ((form (read (current-buffer))))
 401       ;; If the first element is '(point), we just remove it.
 402       (when (equal (car form) '(point))
 403         (pop form))
 404       (cons 'progn (gnus-complex-form-to-spec form spec-alist)))))
 405
 406 (defun gnus-complex-form-to-spec (form spec-alist)
 407   (delq nil
 408         (mapcar
 409          (lambda (sform)
 410            (cond
 411             ((stringp sform)
 412              (gnus-parse-simple-format sform spec-alist t))
 413             ((eq (car sform) 'point)
 414              `(gnus-put-text-property (1- (point)) (point) 'gnus-position t))
 415             ((eq (car sform) 'tab)
 416              (gnus-spec-tab (cadr sform)))
 417             (t
 418              (funcall (intern (format "gnus-%s-face-function" (car sform)))
 419                       (gnus-complex-form-to-spec (cddr sform) spec-alist)
 420                       (nth 1 sform)))))
 421          form)))
 422
 423 (defun gnus-parse-simple-format (format spec-alist &optional insert)
 424   ;; This function parses the FORMAT string with the help of the
 425   ;; SPEC-ALIST and returns a list that can be eval'ed to return a
 426   ;; string.
 427   (let ((max-width 0)
 428         spec flist fstring elem result dontinsert user-defined
 429         type value pad-width spec-beg cut-width ignore-value
 430         tilde-form tilde elem-type)
 431     (save-excursion
 432       (gnus-set-work-buffer)
 433       (insert format)
 434       (goto-char (point-min))
 435       (while (re-search-forward "%" nil t)
 436         (setq user-defined nil
 437               spec-beg nil
 438               pad-width nil
 439               max-width nil
 440               cut-width nil
 441               ignore-value nil
 442               tilde-form nil)
 443         (setq spec-beg (1- (point)))
 444
 445         ;; Parse this spec fully.
 446         (while
 447             (cond
 448              ((looking-at "\\([-.0-9]+\\)\\(,[-0-9]+\\)?")
 449               (setq pad-width (string-to-number (match-string 1)))
 450               (when (match-beginning 2)
 451                 (setq max-width (string-to-number (buffer-substring
 452                                                    (1+ (match-beginning 2))
 453                                                    (match-end 2)))))
 454               (goto-char (match-end 0)))
 455              ((looking-at "~")
 456               (forward-char 1)
 457               (setq tilde (read (current-buffer))
 458                     type (car tilde)
 459                     value (cadr tilde))
 460               (cond
 461                ((memq type '(pad pad-left))
 462                 (setq pad-width value))
 463                ((eq type 'pad-right)
 464                 (setq pad-width (- value)))
 465                ((memq type '(max-right max))
 466                 (setq max-width value))
 467                ((eq type 'max-left)
 468                 (setq max-width (- value)))
 469                ((memq type '(cut cut-left))
 470                 (setq cut-width value))
 471                ((eq type 'cut-right)
 472                 (setq cut-width (- value)))
 473                ((eq type 'ignore)
 474                 (setq ignore-value
 475                       (if (stringp value) value (format "%s" value))))
 476                ((eq type 'form)
 477                 (setq tilde-form value))
 478                (t
 479                 (error "Unknown tilde type: %s" tilde)))
 480               t)
 481              (t
 482               nil)))
 483         ;; User-defined spec -- find the spec name.
 484         (when (eq (setq spec (char-after)) ?u)
 485           (forward-char 1)
 486           (setq user-defined (char-after)))
 487         (forward-char 1)
 488         (delete-region spec-beg (point))
 489
 490         ;; Now we have all the relevant data on this spec, so
 491         ;; we start doing stuff.
 492         (insert "%")
 493         (if (eq spec ?%)
 494             ;; "%%" just results in a "%".
 495             (insert "%")
 496           (cond
 497            ;; Do tilde forms.
 498            ((eq spec ?@)
 499             (setq elem (list tilde-form ?s)))
 500            ;; Treat user defined format specifiers specially.
 501            (user-defined
 502             (setq elem
 503                   (list
 504                    (list (intern (format "gnus-user-format-function-%c"
 505                                          user-defined))
 506                          'gnus-tmp-header)
 507                    ?s)))
 508            ;; Find the specification from `spec-alist'.
 509            ((setq elem (cdr (assq spec spec-alist))))
 510            (t
 511             (setq elem '("*" ?s))))
 512           (setq elem-type (cadr elem))
 513           ;; Insert the new format elements.
 514           (when pad-width
 515             (insert (number-to-string pad-width)))
 516           ;; Create the form to be evaled.
 517           (if (or max-width cut-width ignore-value)
 518               (progn
 519                 (insert ?s)
 520                 (let ((el (car elem)))
 521                   (cond ((= (cadr elem) ?c)
 522                          (setq el (list 'char-to-string el)))
 523                         ((= (cadr elem) ?d)
 524                          (setq el (list 'int-to-string el))))
 525                   (when ignore-value
 526                     (setq el (gnus-tilde-ignore-form el ignore-value)))
 527                   (when cut-width
 528                     (setq el (gnus-tilde-cut-form el cut-width)))
 529                   (when max-width
 530                     (setq el (gnus-tilde-max-form el max-width)))
 531                   (push el flist)))
 532             (insert elem-type)
 533             (push (car elem) flist))))
 534       (setq fstring (buffer-string)))
 535
 536     ;; Do some postprocessing to increase efficiency.
 537     (setq
 538      result
 539      (cond
 540       ;; Emptyness.
 541       ((string= fstring "")
 542        nil)
 543       ;; Not a format string.
 544       ((not (string-match "%" fstring))
 545        (list fstring))
 546       ;; A format string with just a single string spec.
 547       ((string= fstring "%s")
 548        (list (car flist)))
 549       ;; A single character.
 550       ((string= fstring "%c")
 551        (list (car flist)))
 552       ;; A single number.
 553       ((string= fstring "%d")
 554        (setq dontinsert)
 555        (if insert
 556            (list `(princ ,(car flist)))
 557          (list `(int-to-string ,(car flist)))))
 558       ;; Just lots of chars and strings.
 559       ((string-match "\\`\\(%[cs]\\)+\\'" fstring)
 560        (nreverse flist))
 561       ;; A single string spec at the beginning of the spec.
 562       ((string-match "\\`%[sc][^%]+\\'" fstring)
 563        (list (car flist) (substring fstring 2)))
 564       ;; A single string spec in the middle of the spec.
 565       ((string-match "\\`\\([^%]+\\)%[sc]\\([^%]+\\)\\'" fstring)
 566        (list (match-string 1 fstring) (car flist) (match-string 2 fstring)))
 567       ;; A single string spec in the end of the spec.
 568       ((string-match "\\`\\([^%]+\\)%[sc]\\'" fstring)
 569        (list (match-string 1 fstring) (car flist)))
 570       ;; A more complex spec.
 571       (t
 572        (list (cons 'format (cons fstring (nreverse flist)))))))
 573
 574     (if insert
 575         (when result
 576           (if dontinsert
 577               result
 578             (cons 'insert result)))
 579       (cond ((stringp result)
 580              result)
 581             ((consp result)
 582              (cons 'concat result))
 583             (t "")))))
 584
 585 (defun gnus-eval-format (format &optional alist props)
 586   "Eval the format variable FORMAT, using ALIST.
 587 If PROPS, insert the result."
 588   (let ((form (gnus-parse-format format alist props)))
 589     (if props
 590         (gnus-add-text-properties (point) (progn (eval form) (point)) props)
 591       (eval form))))
 592
 593 (defun gnus-compile ()
 594   "Byte-compile the user-defined format specs."
 595   (interactive)
 596   (require 'bytecomp)
 597   (let ((entries gnus-format-specs)
 598         (byte-compile-warnings '(unresolved callargs redefine))
 599         entry gnus-tmp-func)
 600     (save-excursion
 601       (gnus-message 7 "Compiling format specs...")
 602
 603       (while entries
 604         (setq entry (pop entries))
 605         (if (memq (car entry) '(gnus-version version))
 606             (setq gnus-format-specs (delq entry gnus-format-specs))
 607           (let ((form (caddr entry)))
 608             (when (and (listp form)
 609                        ;; Under GNU Emacs, it's (byte-code ...)
 610                        (not (eq 'byte-code (car form)))
 611                        ;; Under XEmacs, it's (funcall #<compiled-function ...>)
 612                        (not (and (eq 'funcall (car form))
 613                                  (byte-code-function-p (cadr form)))))
 614               (defalias 'gnus-tmp-func `(lambda () ,form))
 615               (byte-compile 'gnus-tmp-func)
 616               (setcar (cddr entry) (gnus-byte-code 'gnus-tmp-func))))))
 617
 618       (push (cons 'version emacs-version) gnus-format-specs)
 619       ;; Mark the .newsrc.eld file as "dirty".
 620       (gnus-dribble-touch)
 621       (gnus-message 7 "Compiling user specs...done"))))
 622
 623 (defun gnus-set-format (type &optional insertable)
 624   (set (intern (format "gnus-%s-line-format-spec" type))
 625        (gnus-parse-format
 626         (symbol-value (intern (format "gnus-%s-line-format" type)))
 627         (symbol-value (intern (format "gnus-%s-line-format-alist" type)))
 628         insertable)))
 629
 630 (provide 'gnus-spec)
 631
 632 ;; Local Variables:
 633 ;; coding: iso-8859-1
 634 ;; End:
 635
 636 ;;; gnus-spec.el ends here