cgit.sxemacs.org Git - gnus/blob - lisp/gnus-registry.el

   1 ;;; gnus-registry.el --- article registry for Gnus
   2 ;; Copyright (C) 1996, 1997, 1998, 1999, 2000, 2001, 2002, 2003
   3 ;;        Free Software Foundation, Inc.
   4
   5 ;; Author: Ted Zlatanov <tzz@lifelogs.com>
   6 ;; Keywords: news
   7
   8 ;; This file is part of GNU Emacs.
   9
  10 ;; GNU Emacs is free software; you can redistribute it and/or modify
  11 ;; it under the terms of the GNU General Public License as published by
  12 ;; the Free Software Foundation; either version 2, or (at your option)
  13 ;; any later version.
  14
  15 ;; GNU Emacs is distributed in the hope that it will be useful,
  16 ;; but WITHOUT ANY WARRANTY; without even the implied warranty of
  17 ;; MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.  See the
  18 ;; GNU General Public License for more details.
  19
  20 ;; You should have received a copy of the GNU General Public License
  21 ;; along with GNU Emacs; see the file COPYING.  If not, write to the
  22 ;; Free Software Foundation, Inc., 59 Temple Place - Suite 330,
  23 ;; Boston, MA 02111-1307, USA.
  24
  25 ;;; Commentary:
  26
  27 ;;; Code:
  28
  29 (eval-when-compile (require 'cl))
  30
  31 (require 'gnus)
  32 (require 'gnus-int)
  33 (require 'gnus-sum)
  34 (require 'nnmail)
  35
  36 (defgroup gnus-registry nil
  37   "The Gnus registry."
  38   :group 'gnus)
  39
  40 (defvar gnus-registry-hashtb nil
  41   "*The article registry by Message ID.")
  42
  43 (defvar gnus-registry-headers-hashtb nil
  44   "*The article header registry by Message ID.  Unused for now.")
  45
  46 (defcustom gnus-registry-unfollowed-groups '("delayed" "drafts" "queue")
  47   "List of groups that gnus-registry-split-fancy-with-parent won't follow.
  48 The group names are matched, they don't have to be fully qualified."
  49   :group 'gnus-registry
  50   :type '(repeat string))
  51
  52 (defcustom gnus-registry-unregistered-group-regex "^nntp"
  53   "Group name regex that gnus-registry-register-message-ids won't process."
  54   :group 'gnus-registry
  55   :type 'regexp)
  56
  57 ;; Function(s) missing in Emacs 20
  58 (when (memq nil (mapcar 'fboundp '(puthash)))
  59   (require 'cl)
  60   (unless (fboundp 'puthash)
  61     ;; alias puthash is missing from Emacs 20 cl-extra.el
  62     (defalias 'puthash 'cl-puthash)))
  63
  64 (defun gnus-registry-translate-to-alist ()
  65   (setq gnus-registry-alist (hashtable-to-alist gnus-registry-hashtb)))
  66
  67 (defun gnus-registry-translate-from-alist ()
  68   (setq gnus-registry-hashtb (alist-to-hashtable gnus-registry-alist)))
  69
  70 (defun alist-to-hashtable (alist)
  71   "Build a hashtable from the values in ALIST."
  72   (let ((ht (make-hash-table
  73              :size 4096
  74              :test 'equal)))
  75     (mapc
  76      (lambda (kv-pair)
  77        (puthash (car kv-pair) (cdr kv-pair) ht))
  78      alist)
  79      ht))
  80
  81 (defun hashtable-to-alist (hash)
  82   "Build an alist from the values in HASH."
  83   (let ((list nil))
  84     (maphash
  85      (lambda (key value)
  86        (setq list (cons (cons key value) list)))
  87      hash)
  88     list))
  89
  90 (defun gnus-register-action (action data-header from &optional to method)
  91   (let* ((id (mail-header-id data-header))
  92         (from (gnus-group-guess-full-name from))
  93         (to (if to (gnus-group-guess-full-name to) nil))
  94         (to-name (if to to "the Bit Bucket"))
  95         (old-entry (gethash id gnus-registry-hashtb)))
  96     (gnus-message 5 "Registry: article %s %s from %s to %s"
  97                   id
  98                   (if method "respooling" "going")
  99                   from
 100                   to)
 101
 102     ;; All except copy will need a delete
 103     (gnus-registry-delete-group id from)
 104
 105     (when (equal 'copy action)
 106       (gnus-registry-add-group id from)) ; undo the delete
 107
 108     (gnus-registry-add-group id to)))
 109
 110 (defun gnus-register-spool-action (id group)
 111   ;; do not process the draft IDs
 112 ;  (unless (string-match "totally-fudged-out-message-id" id)
 113 ;    (let ((group (gnus-group-guess-full-name group)))
 114   (when (string-match "\r$" id)
 115     (setq id (substring id 0 -1)))
 116   (gnus-message 5 "Registry: article %s spooled to %s"
 117                 id
 118                 group)
 119   (gnus-registry-add-group id group))
 120 ;)
 121
 122 ;; Function for nn{mail|imap}-split-fancy: look up all references in
 123 ;; the cache and if a match is found, return that group.
 124 (defun gnus-registry-split-fancy-with-parent ()
 125   "Split this message into the same group as its parent.  The parent
 126 is obtained from the registry.  This function can be used as an entry
 127 in `nnmail-split-fancy' or `nnimap-split-fancy', for example like
 128 this: (: gnus-registry-split-fancy-with-parent)
 129
 130 For a message to be split, it looks for the parent message in the
 131 References or In-Reply-To header and then looks in the registry to
 132 see which group that message was put in.  This group is returned.
 133
 134 See the Info node `(gnus)Fancy Mail Splitting' for more details."
 135   (let ((refstr (or (message-fetch-field "references")
 136                     (message-fetch-field "in-reply-to")))
 137         (references nil)
 138         (res nil))
 139     (when refstr
 140       (setq references (nreverse (gnus-split-references refstr)))
 141       (mapcar (lambda (x)
 142                 (setq res (or (gnus-registry-fetch-group x) res))
 143                 (when (or (gnus-registry-grep-in-list
 144                            res
 145                            gnus-registry-unfollowed-groups)
 146                           (gnus-registry-grep-in-list
 147                            res
 148                            nnmail-split-fancy-with-parent-ignore-groups))
 149                   (setq res nil)))
 150               references)
 151       (gnus-message
 152        5
 153        "gnus-registry-split-fancy-with-parent traced %s to group %s"
 154        refstr (if res res "nil"))
 155       res)))
 156
 157 (defun gnus-registry-register-message-ids ()
 158   "Register the Message-ID of every article in the group"
 159   (unless (and gnus-registry-unregistered-group-regex
 160                (string-match gnus-registry-unregistered-group-regex gnus-newsgroup-name))
 161     (dolist (article gnus-newsgroup-articles)
 162       (let ((id (gnus-registry-fetch-message-id-fast article)))
 163         (unless (gnus-registry-fetch-group id)
 164           (gnus-message 9 "Registry: Registering article %d with group %s"
 165                         article gnus-newsgroup-name)
 166           (gnus-registry-add-group (gnus-registry-fetch-message-id-fast article)
 167                                    gnus-newsgroup-name))))))
 168
 169 (defun gnus-registry-fetch-message-id-fast (article)
 170   "Fetch the Message-ID quickly, using the internal gnus-data-list function"
 171   (if (and (numberp article)
 172            (assoc article (gnus-data-list nil)))
 173       (mail-header-id (gnus-data-header (assoc article (gnus-data-list nil))))
 174     nil))
 175
 176 (defun gnus-registry-grep-in-list (word list)
 177   (when word
 178     (memq nil
 179           (mapcar 'not
 180                   (mapcar
 181                    (lambda (x)
 182                      (string-match x word))
 183                    list)))))
 184
 185 (defun gnus-registry-fetch-extra (id)
 186   "Get the extra data of a message, based on the message ID.
 187 Returns the first place where the trail finds a nonstring."
 188   (let ((trail (gethash id gnus-registry-hashtb)))
 189     (dolist (crumb trail)
 190       (unless (stringp crumb)
 191         (return crumb)))))
 192
 193 (defun gnus-registry-store-extra (id extra)
 194   "Store the extra data of a message, based on the message ID.
 195 The message must have at least one group name."
 196   (when (gnus-registry-group-count id)
 197     ;; we now know the trail has at least 1 group name, so it's not empty
 198     (let ((trail (gethash id gnus-registry-hashtb))
 199           (old-extra (gnus-registry-fetch-extra id)))
 200       (puthash id (cons extra (delete old-extra trail))
 201                gnus-registry-hashtb))))
 202
 203 (defun gnus-registry-fetch-group (id)
 204   "Get the group of a message, based on the message ID.
 205 Returns the first place where the trail finds a group name."
 206   (when (gnus-registry-group-count id)
 207     ;; we now know the trail has at least 1 group name
 208     (let ((trail (gethash id gnus-registry-hashtb)))
 209       (dolist (crumb trail)
 210         (when (stringp crumb)
 211           (return crumb))))))
 212
 213 (defun gnus-registry-group-count (id)
 214   "Get the number of groups of a message, based on the message ID."
 215   (let ((trail (gethash id gnus-registry-hashtb)))
 216     (if (and trail (listp trail))
 217         (apply '+ (mapcar (lambda (x) (if (stringp x) 1 0)) trail))
 218       0)))
 219
 220 (defun gnus-registry-delete-group (id group)
 221   "Delete a group for a message, based on the message ID."
 222   (when group
 223     (when id
 224       (let ((trail (gethash id gnus-registry-hashtb))
 225             (group (gnus-group-short-name group)))
 226         (puthash id (if trail
 227                         (delete group trail)
 228                       nil)
 229                  gnus-registry-hashtb))
 230       ;; now, clear the entry if there are no more groups
 231       (unless (gnus-registry-group-count id)
 232         (remhash id gnus-registry-hashtb)))))
 233
 234 (defun gnus-registry-add-group (id group &rest extra)
 235   "Add a group for a message, based on the message ID."
 236   ;; make sure there are no duplicate entries
 237   (when group
 238     (when (and id
 239                (not (string-match "totally-fudged-out-message-id" id)))
 240       (let ((group (gnus-group-short-name group)))
 241         (gnus-registry-delete-group id group)
 242         (let ((trail (gethash id gnus-registry-hashtb)))
 243           (puthash id (if trail
 244                           (cons group trail)
 245                         (list group))
 246                    gnus-registry-hashtb)
 247           (when extra (gnus-registry-store-extra id extra)))))))
 248
 249 (defun gnus-registry-clear ()
 250   "Clear the Gnus registry."
 251   (interactive)
 252   (setq gnus-registry-alist nil
 253         gnus-registry-headers-alist nil)
 254   (gnus-registry-translate-from-alist))
 255
 256 ; also does copy, respool, and crosspost
 257 (add-hook 'gnus-summary-article-move-hook 'gnus-register-action)
 258 (add-hook 'gnus-summary-article-delete-hook 'gnus-register-action)
 259 (add-hook 'gnus-summary-article-expire-hook 'gnus-register-action)
 260 (add-hook 'nnmail-spool-hook 'gnus-register-spool-action)
 261
 262 (add-hook 'gnus-save-newsrc-hook 'gnus-registry-translate-to-alist)
 263 (add-hook 'gnus-read-newsrc-el-hook 'gnus-registry-translate-from-alist)
 264
 265 (add-hook 'gnus-summary-prepare-hook 'gnus-registry-register-message-ids)
 266
 267 ;; TODO: a lot of things
 268
 269 (provide 'gnus-registry)
 270
 271 ;;; gnus-registry.el ends here